lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2003 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "translator-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "auto-change-iterator.hh"
  78 #include "ly-modules.hh"
  79 #include "music-sequence.hh"
  80 #include "input-smob.hh"
  81 #include "event.hh"
  82 #include "text-item.hh"
  83 #include "music-list.hh"
  84
  85 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  86
  87 Music *property_op_to_music (SCM op);
  88 Music *context_spec_music (SCM type, SCM id, Music * m, SCM ops_);
  89 SCM get_next_unique_context ();
  90
  91 #define YYERROR_VERBOSE 1
  92
  93 My_lily_parser* my_lily_parser;
  94 #define YYPARSE_PARAM my_lily_parser
  95 #define YYLEX_PARAM my_lily_parser
  96 #define THIS\
  97         ((My_lily_parser *) my_lily_parser)
  98
  99 #define yyerror THIS->parser_error
 100
 101 /*
 102   Add symbols to the  TAGS field of a music object.
 103 */
 104
 105 void
 106 tag_music (Music*m,  SCM tag, Input ip)
 107 {
 108         SCM tags = m->get_mus_property ("tags");
 109         if (gh_symbol_p (tag))
 110                 tags = scm_cons (tag, tags);
 111         else if (gh_list_p (tag))
 112                 tags = gh_append2 (tag, tags);
 113         else
 114                 ip.warning (_("Tag must be symbol or list of symbols."));
 115
 116         m->set_mus_property ("tags", tags);
 117 }
 118
 119
 120
 121 bool
 122 regular_identifier_b (SCM id)
 123 {
 124   String str = ly_scm2string (id);
 125   char const *s = str.to_str0 () ;
 126
 127   bool v = true;
 128   while (*s && v)
 129    {
 130         v = v && isalpha (*s);
 131         s++;
 132    }
 133   return v;
 134 }
 135
 136 SCM
 137 make_simple_markup (SCM a)
 138 {
 139         static SCM simple;
 140         if (!simple)
 141         simple = scm_c_eval_string ("simple-markup");
 142
 143         return scm_list_n (simple, a, SCM_UNDEFINED);
 144 }
 145
 146
 147 bool
 148 is_duration_b (int t)
 149 {
 150   return t && t == 1 << intlog2 (t);
 151 }
 152
 153 void
 154 set_music_properties (Music *p, SCM a)
 155 {
 156   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 157         {
 158         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 159         }
 160 }
 161
 162 SCM
 163 make_chord_step (int step, int alter)
 164 {
 165         if (step == 7)
 166                 alter += FLAT;
 167
 168         while(step < 0)
 169                 step += 7;
 170         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 171         return m.smobbed_copy ();
 172 }
 173
 174
 175 SCM
 176 make_chord (SCM pitch, SCM dur, SCM modification_list)
 177 {
 178         static SCM chord_ctor;
 179         if (!chord_ctor)
 180                 chord_ctor= scm_c_eval_string ("construct-chord");
 181         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 182         scm_gc_protect_object (ch);
 183         return ch;
 184 }
 185
 186 /*
 187   Todo: actually also use apply iso. call too ...
 188 */
 189 bool
 190 ly_input_procedure_p (SCM x)
 191 {
 192         return gh_procedure_p (x)
 193                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 194 }
 195
 196 Music*
 197 set_property_music (SCM sym, SCM value)
 198 {
 199         Music * p = MY_MAKE_MUSIC("PropertySet");
 200         p->set_mus_property ("symbol", sym);
 201         p->set_mus_property ("value", value);
 202         return p;
 203 }
 204
 205 %}
 206
 207 /* We use SCMs to do strings, because it saves us the trouble of
 208 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 209 of the parse stack onto the heap. */
 210
 211
 212 %union {
 213         String * string;
 214     Music *music;
 215     Score *score;
 216     Music_output_def * outputdef;
 217     SCM scm;
 218     int i;
 219 }
 220 %{
 221
 222 int
 223 yylex (YYSTYPE *s,  void * v)
 224 {
 225         My_lily_parser   *pars = (My_lily_parser*) v;
 226         My_lily_lexer * lex = pars->lexer_;
 227
 228         lex->lexval = (void*) s;
 229         lex->prepare_for_next_token();
 230         return lex->yylex ();
 231 }
 232
 233
 234 %}
 235
 236 %pure_parser
 237
 238
 239 %token ACCEPTS
 240 %token ADDLYRICS
 241 %token ALIAS
 242 %token ALTERNATIVE
 243 %token APPLY
 244 %token APPLYCONTEXT
 245 %token APPLYOUTPUT
 246 %token AUTOCHANGE
 247 %token BAR
 248 %token BREATHE
 249 %token CHANGE
 250 %token CHORDMODIFIERS
 251 %token CHORDS
 252 %token LESSLESS
 253 %token MOREMORE
 254 %token CLEF
 255 %token COMMANDSPANREQUEST
 256 %token CONSISTS
 257 %token CONSISTSEND
 258 %token CONTEXT
 259 %token DEFAULT
 260 %token DENIES
 261 %token DESCRIPTION
 262 %token EXTENDER
 263 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 264 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 265 %token GRACE
 266 %token ACCIACCATURA
 267 %token APPOGGIATURA
 268 %token GROBDESCRIPTIONS
 269 %token HEADER
 270 %token HYPHEN
 271 %token INVALID
 272 %token KEY
 273 %token LYRICS
 274 %token MARK
 275 %token MIDI
 276 %token MULTI_MEASURE_REST
 277 %token NAME
 278 %token NEWCONTEXT
 279 %token NOTES
 280 %token OCTAVE
 281 %token ONCE
 282 %token OVERRIDE SET REVERT
 283 %token PAPER
 284 %token PARTCOMBINE
 285 %token PARTIAL
 286 %token PITCHNAMES
 287 %token PROPERTY
 288 %token RELATIVE
 289 %token REMOVE
 290 %token REPEAT
 291 %token REST
 292 %token SCM_T
 293 %token SCORE
 294 %token SEQUENTIAL
 295 %token SIMULTANEOUS
 296 %token SKIP
 297 %token SPANREQUEST
 298 %token TAG
 299 %token TEMPO
 300 %token TIMES
 301 %token TIME_T
 302 %token TRANSLATOR
 303 %token TRANSPOSE
 304 %token TYPE
 305 %token UNSET
 306 %token WITH
 307
 308 /* escaped */
 309 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 310 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 311 %token E_BACKSLASH
 312 %token <i> E_UNSIGNED
 313 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 314 %token FIGURE_SPACE
 315
 316 %type <i>       exclamations questions dots optional_rest
 317 %type <i>        bass_mod
 318 %type <scm>     grace_head
 319 %type <scm>     context_mod_list
 320 %type <scm>     lyric_element
 321 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 322 %token <i>      DIGIT
 323 %token <scm>    NOTENAME_PITCH
 324 %token <scm>    TONICNAME_PITCH
 325 %token <scm>    CHORDMODIFIER_PITCH
 326 %token <scm>    DURATION_IDENTIFIER
 327 %token <scm>    FRACTION
 328 %token <id>     IDENTIFIER
 329 %token <scm>    CHORDNAMES
 330 %token <scm>    CHORD_MODIFIER
 331 %token <scm>    SCORE_IDENTIFIER
 332 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 333 %token <scm>    NUMBER_IDENTIFIER
 334 %token <scm>    EVENT_IDENTIFIER
 335 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 336 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 337 %token <scm>    RESTNAME
 338 %token <scm>    STRING
 339 %token <scm>    SCM_T
 340 %token <i>      UNSIGNED
 341 %token <scm>   REAL
 342
 343 %token MARKUP
 344 %token <scm> MARKUP_HEAD_MARKUP0
 345 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 346 %token <scm> MARKUP_HEAD_SCM0
 347 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 348 %token <scm> MARKUP_HEAD_SCM0_SCM1
 349 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 350 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 351
 352 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 353 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 354
 355 %type <outputdef> output_def
 356 %type <scm>     lilypond_header lilypond_header_body
 357 %type <music>   open_event close_event
 358 %type <i>       sub_quotes sup_quotes
 359 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 360 %type <music>   Repeated_music
 361 %type <scm>     Alternative_music
 362 %type <i>       tremolo_type
 363 %type <i>       bare_int  bare_unsigned
 364 %type <i>       script_dir
 365 %type <scm>     identifier_init
 366
 367 %type <music> note_chord_element chord_body chord_body_element
 368 %type <scm>  chord_body_elements
 369 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 370
 371 %type <scm>   post_events
 372 %type <music> gen_text_def direction_less_event direction_reqd_event
 373 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 374 %type <scm>    steno_tonic_pitch
 375 %type <scm>     duration_length fraction
 376
 377 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 378
 379 %type <scm>  embedded_scm scalar
 380 %type <music>   Music Sequential_music Simultaneous_music
 381 %type <music>   relative_music re_rhythmed_music part_combined_music
 382 %type <music>   music_property_def context_change
 383 %type <scm> Music_list
 384 %type <scm> property_operation context_mod translator_mod optional_context_mod
 385 %type <outputdef>  music_output_def_body
 386 %type <music> shorthand_command_req
 387 %type <music>   post_event tagged_post_event
 388 %type <music> command_req verbose_command_req
 389 %type <music> hyphen_req
 390 %type <music> string_number_event
 391 %type <scm>     string bare_number number_expression number_term number_factor
 392 %type <score>   score_block score_body
 393
 394 %type <scm>     translator_spec_block translator_spec_body
 395 %type <music>   tempo_event
 396 %type <scm> notenames_body notenames_block chordmodifiers_block
 397 %type <scm>     script_abbreviation
 398
 399
 400
 401 %left '-' '+'
 402
 403 /* We don't assign precedence to / and *, because we might need varied
 404 prec levels in different prods */
 405
 406 %left UNARY_MINUS
 407
 408 %%
 409
 410 lilypond:       /* empty */
 411         | lilypond toplevel_expression {}
 412         | lilypond assignment  { }
 413         | lilypond error {
 414                 THIS->error_level_  = 1;
 415         }
 416         | lilypond INVALID      {
 417                 THIS->error_level_  = 1;
 418         }
 419         ;
 420
 421 toplevel_expression:
 422         notenames_block                 {
 423                 THIS->lexer_->pitchname_tab_ =  $1;
 424         }
 425         | chordmodifiers_block                  {
 426                 THIS->lexer_->chordmodifier_tab_  = $1;
 427         }
 428         | lilypond_header {
 429                 THIS->input_file_->header_ = $1;
 430         }
 431         | score_block {
 432                 Score * sc = $1;
 433
 434                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 435
 436                 Path p = split_path (THIS->output_basename_);
 437                 int *c =  &THIS->input_file_->score_count_;
 438                 if (*c)
 439                         {
 440                         p.base += "-" + to_string (*c);
 441                         }
 442
 443                 (*c)++;
 444                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 445
 446                 for (int i=0; i < sc->defs_.size (); i++)
 447                         default_rendering (sc->music_, sc->defs_[i]->self_scm(),head, outname);
 448
 449                 if (sc->defs_.empty ())
 450                 {
 451                    Music_output_def *id =
 452                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 453                                 ("$defaultpaper"));
 454
 455                    id = id ? id->clone () : new Paper_def;
 456
 457                    default_rendering (sc->music_, id->self_scm(), head, outname);
 458
 459                    scm_gc_unprotect_object (id->self_scm ());
 460                 }
 461                 scm_gc_unprotect_object (sc->self_scm());
 462         }
 463         | output_def {
 464                 if (dynamic_cast<Paper_def*> ($1))
 465                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultpaper"), $1->self_scm ());
 466                 else if (dynamic_cast<Midi_def*> ($1))
 467                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultmidi"), $1->self_scm ());
 468         }
 469         ;
 470
 471 embedded_scm:
 472         SCM_T
 473         | SCM_IDENTIFIER
 474         ;
 475
 476
 477 chordmodifiers_block:
 478         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 479         ;
 480
 481 notenames_block:
 482         PITCHNAMES notenames_body   {  $$ = $2; }
 483         ;
 484
 485 notenames_body:
 486         embedded_scm    {
 487           int i = scm_ilength ($1);
 488
 489           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 490           for (SCM s = $1; gh_pair_p (s); s = ly_cdr (s)) {
 491                 SCM pt = ly_cdar (s);
 492                 scm_hashq_set_x (tab, ly_caar (s), pt);
 493           }
 494           $$ = tab;
 495         }
 496         ;
 497
 498 lilypond_header_body:
 499         {
 500                 $$ = ly_make_anonymous_module ();
 501                 THIS->lexer_->add_scope ($$);
 502         }
 503         | lilypond_header_body assignment  {
 504
 505         }
 506         ;
 507
 508 lilypond_header:
 509         HEADER '{' lilypond_header_body '}'     {
 510                 $$ = THIS->lexer_-> remove_scope();
 511         }
 512         ;
 513
 514
 515 /*
 516         DECLARATIONS
 517 */
 518 assignment:
 519         STRING {
 520                 THIS->push_spot ();
 521         }
 522         /* cont */ '=' identifier_init  {
 523
 524         /*
 525                 Should find generic way of associating input with objects.
 526         */
 527                 Input ip = THIS->pop_spot ();
 528
 529                 if (! regular_identifier_b ($1))
 530                 {
 531                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 532                 }
 533
 534                 THIS->lexer_->set_identifier ($1, $4);
 535
 536 /*
 537  TODO: devise standard for protection in parser.
 538
 539   The parser stack lives on the C-stack, which means that
 540 all objects can be unprotected as soon as they're here.
 541
 542 */
 543         }
 544         | embedded_scm { }
 545         ;
 546
 547
 548
 549 identifier_init:
 550         score_block {
 551                 $$ = $1->self_scm ();
 552                 scm_gc_unprotect_object ($$);
 553         }
 554         | full_markup {
 555                 $$ = $1;
 556         }
 557         | output_def {
 558                 $$ = $1->self_scm ();
 559                 scm_gc_unprotect_object ($$);
 560         }
 561         | translator_spec_block {
 562                 $$ = $1;
 563         }
 564         | Music  {
 565                 $$ = $1->self_scm ();
 566                 scm_gc_unprotect_object ($$);
 567         }
 568         | post_event {
 569                 $$ = $1->self_scm ();
 570                 scm_gc_unprotect_object ($$);
 571         }
 572         | number_expression {
 573                 $$ = $1;
 574         }
 575         | string {
 576                 $$ = $1;
 577         }
 578         | embedded_scm  {
 579                 $$ = $1;
 580         }
 581         ;
 582
 583 translator_spec_block:
 584         TRANSLATOR '{' translator_spec_body '}'
 585                 {
 586                 $$ = $3;
 587         }
 588         ;
 589
 590 translator_spec_body:
 591         /**/ {
 592                 $$ = Context_def::make_scm ();
 593                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 594         }
 595         | TRANSLATOR_IDENTIFIER {
 596                 $$ = $1;
 597                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 598         }
 599         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 600                 Context_def*td = unsmob_context_def($$);
 601
 602                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 603                         SCM tag = gh_caar (p);
 604                         td->add_context_mod (scm_list_n (ly_symbol2scm ("assign"),
 605                                                         tag, ly_cdar (p), SCM_UNDEFINED));
 606                 }
 607         }
 608         | translator_spec_body context_mod {
 609                 unsmob_context_def ($$)->add_context_mod ($2);
 610         }
 611         ;
 612
 613 /*
 614         SCORE
 615 */
 616 score_block:
 617         SCORE {
 618                 THIS->push_spot ();
 619         }
 620         /*cont*/ '{' score_body '}'     {
 621                 THIS->pop_spot ();
 622                 $$ = $4;
 623
 624         }
 625         ;
 626
 627 score_body:
 628         Music   {
 629                 $$ = new Score;
 630
 631                 $$->set_spot (THIS->here_input ());
 632                 SCM m = $1->self_scm ();
 633                 scm_gc_unprotect_object (m);
 634
 635                 /*
 636                         guh.
 637                 */
 638                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 639                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 640                         m = gh_call1 (gh_car (check_funcs), m);
 641                 $$->music_ = m;
 642
 643         }
 644         | SCORE_IDENTIFIER {
 645                 $$ = unsmob_score ($1);
 646                 $$->set_spot (THIS->here_input ());
 647         }
 648         | score_body lilypond_header    {
 649                 $$->header_ = $2;
 650         }
 651         | score_body output_def {
 652                 $$->defs_.push ($2);
 653         }
 654         | score_body error {
 655
 656         }
 657         ;
 658
 659
 660 /*
 661         MIDI
 662 */
 663 output_def:
 664         music_output_def_body '}' {
 665                 $$ = $1;
 666                 THIS-> lexer_-> remove_scope ();
 667         }
 668         ;
 669
 670 music_output_def_body:
 671         MIDI '{'    {
 672                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 673
 674
 675                 Midi_def* p =0;
 676                 if (id)
 677                         p = dynamic_cast<Midi_def*> (id->clone ());
 678                 else
 679                         p = new Midi_def;
 680
 681                 $$ = p;
 682                 THIS->lexer_->add_scope (p->scope_);
 683         }
 684         | PAPER '{'     {
 685                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 686                   Paper_def *p = 0;
 687                 if (id)
 688                         p = dynamic_cast<Paper_def*> (id->clone ());
 689                 else
 690                         p = new Paper_def;
 691
 692                 THIS->lexer_->add_scope (p->scope_);
 693                 $$ = p;
 694         }
 695         | PAPER '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 696                 Music_output_def * o =  unsmob_music_output_def ($3);
 697                 $$ =o;
 698
 699                 THIS->lexer_->add_scope (o->scope_);
 700         }
 701         | MIDI '{' MUSIC_OUTPUT_DEF_IDENTIFIER  {
 702                 Music_output_def * o =  unsmob_music_output_def ($3);
 703                 $$ = o;
 704
 705                 THIS->lexer_->add_scope (o->scope_);
 706         }
 707         | music_output_def_body assignment  {
 708
 709         }
 710         | music_output_def_body translator_spec_block   {
 711                 $$->assign_translator ($2);
 712
 713         }
 714         | music_output_def_body tempo_event  {
 715                 /*
 716                         junk this ? there already is tempo stuff in
 717                         music.
 718                 */
 719                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 720                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 721                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 722                 if (md)
 723                         md->set_tempo (d->get_length (), m);
 724         }
 725         | music_output_def_body error {
 726
 727         }
 728         ;
 729
 730 tempo_event:
 731         TEMPO steno_duration '=' bare_unsigned  {
 732                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 733                 $$->set_mus_property ("tempo-unit", $2);
 734                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 735         }
 736         ;
 737
 738 /*
 739 The representation of a  list is the
 740
 741   (LIST . LAST-CONS)
 742
 743  to have  efficient append.
 744 */
 745 Music_list:
 746         /* empty */ {
 747                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 748         }
 749         | Music_list Music {
 750                 SCM s = $$;
 751                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 752                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 753                 if (gh_pair_p (ly_cdr (s)))
 754                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 755                 else
 756                         gh_set_car_x (s, c); /* set first cons */
 757                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 758         }
 759         | Music_list error {
 760         }
 761         ;
 762
 763
 764 Music:
 765         Simple_music
 766         | Composite_music
 767         ;
 768
 769 Alternative_music:
 770         /* empty */ {
 771                 $$ = SCM_EOL;
 772         }
 773         | ALTERNATIVE '{' Music_list '}' {
 774                 $$ = $3;
 775         }
 776         ;
 777
 778 Repeated_music:
 779         REPEAT string bare_unsigned Music Alternative_music
 780         {
 781                 Music *beg = $4;
 782                 int times = $3;
 783                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 784                 if (times < scm_ilength (alts)) {
 785                   unsmob_music (gh_car (alts))
 786                     ->origin ()->warning (
 787                     _("More alternatives than repeats.  Junking excess alternatives."));
 788                   alts = ly_truncate_list (times, alts);
 789                 }
 790
 791
 792                 static SCM proc;
 793                 if (!proc)
 794                         proc = scm_c_eval_string ("make-repeated-music");
 795
 796                 SCM mus = scm_call_1 (proc, $2);
 797                 scm_gc_protect_object (mus); // UGH.
 798                 Music *r =unsmob_music (mus);
 799                 if (beg)
 800                         {
 801                         r-> set_mus_property ("element", beg->self_scm ());
 802                         scm_gc_unprotect_object (beg->self_scm ());
 803                         }
 804                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 805
 806                 r-> set_mus_property ("elements",alts);
 807                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 808                         /*
 809                         we can not get durations and other stuff correct down the line, so we have to
 810                         add to the duration log here.
 811                         */
 812                         static SCM func;
 813
 814                         if (!func)
 815                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 816
 817                         int dots = ($3 % 3) ? 0 : 1;
 818                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 819
 820                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 821
 822                         if (seq) {
 823                                 int list_len =scm_ilength (seq->music_list ());
 824                                 if (list_len != 2)
 825                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 826                                 shift -= 1;
 827                                 r->compress (Moment (Rational (1,list_len)));
 828                                 }
 829                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 830
 831                 }
 832                 r->set_spot (*$4->origin ());
 833
 834                 $$ = r;
 835         }
 836         ;
 837
 838 Sequential_music:
 839         SEQUENTIAL '{' Music_list '}'           {
 840                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 841                 $$->set_mus_property ("elements", ly_car ($3));
 842                 $$->set_spot(THIS->here_input());
 843         }
 844         | '{' Music_list '}'            {
 845                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 846                 $$->set_mus_property ("elements", ly_car ($2));
 847                 $$->set_spot(THIS->here_input());
 848         }
 849         ;
 850
 851 Simultaneous_music:
 852         SIMULTANEOUS '{' Music_list '}'{
 853                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 854                 $$->set_mus_property ("elements", ly_car ($3));
 855                 $$->set_spot(THIS->here_input());
 856
 857         }
 858         | simul_open Music_list simul_close     {
 859                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 860                 $$->set_mus_property ("elements", ly_car ($2));
 861                 $$->set_spot(THIS->here_input());
 862         }
 863         ;
 864
 865 Simple_music:
 866         event_chord             { $$ = $1; }
 867         | APPLYOUTPUT embedded_scm {
 868                 if (!ly_input_procedure_p ($2))
 869                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 870                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 871                 $$->set_mus_property ("procedure", $2);
 872                 $$->set_spot (THIS->here_input());
 873         }
 874         | APPLYCONTEXT embedded_scm {
 875                 if (!ly_input_procedure_p ($2))
 876                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 877                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 878                 $$->set_mus_property ("procedure", $2);
 879                 $$->set_spot (THIS->here_input());
 880         }
 881         | MUSIC_IDENTIFIER {
 882                 $$ = unsmob_music ($1);
 883         }
 884         | music_property_def
 885         | context_change
 886         ;
 887
 888
 889 optional_context_mod:
 890         /**/ { $$ = SCM_EOL; }
 891         | WITH '{' context_mod_list '}'  { $$ = $3; }
 892         ;
 893
 894 grace_head:
 895         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 896         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 897         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 898         ;
 899
 900 context_mod_list:
 901         /* */  { $$ = SCM_EOL; }
 902         | context_mod_list context_mod  {
 903                  $$ = gh_cons ($2, $1);
 904         }
 905         ;
 906
 907 Composite_music:
 908         AUTOCHANGE STRING Music {
 909                 Music*chm = MY_MAKE_MUSIC("AutoChangeMusic");
 910                 chm->set_mus_property ("element", $3->self_scm ());
 911                 chm->set_mus_property ("iterator-ctor", Auto_change_iterator::constructor_proc);
 912
 913                 scm_gc_unprotect_object ($3->self_scm ());
 914                 chm->set_mus_property ("what", scm_string_to_symbol ($2));
 915
 916                 $$ = chm;
 917                 chm->set_spot (*$3->origin ());
 918         }
 919         | grace_head Music {
 920 #if 1
 921         /*
 922                 The other version is for easier debugging  of
 923                 Sequential_music_iterator in combination with grace notes.
 924         */
 925
 926 /*
 927
 928 TODO: should distinguish between both grace types in the
 929 basic music objects too, since the meaning is different.
 930
 931 */
 932
 933                 String start_str = "start" + ly_scm2string ($1) + "Music";
 934                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 935
 936                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 937                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 938
 939                 Music *startm = unsmob_music (start);
 940                 Music *stopm = unsmob_music (stop);
 941
 942                 SCM ms = SCM_EOL;
 943                 if (stopm) {
 944                         stopm = stopm->clone ();
 945                         ms = scm_cons (stopm->self_scm (), ms);
 946                         scm_gc_unprotect_object (stopm->self_scm ());
 947                 }
 948                 ms = scm_cons ($2->self_scm (), ms);
 949                 scm_gc_unprotect_object ($2->self_scm());
 950                 if (startm) {
 951                         startm = startm->clone ();
 952                         ms = scm_cons (startm->self_scm () , ms);
 953                         scm_gc_unprotect_object (startm->self_scm ());
 954                 }
 955
 956
 957                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 958                 seq->set_mus_property ("elements", ms);
 959
 960
 961                 $$ = MY_MAKE_MUSIC("GraceMusic");
 962                 $$->set_mus_property ("element", seq->self_scm ());
 963                 scm_gc_unprotect_object (seq->self_scm ());
 964 #else
 965                 $$ = MY_MAKE_MUSIC("GraceMusic");
 966                 $$->set_mus_property ("element", $2->self_scm ());
 967                 scm_gc_unprotect_object ($2->self_scm ());
 968 #endif
 969         }
 970         | CONTEXT string '=' string optional_context_mod Music {
 971                 $$ = context_spec_music ($2, $4, $6, $5);
 972
 973         }
 974         | CONTEXT STRING optional_context_mod Music {
 975                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 976         }
 977         | NEWCONTEXT string optional_context_mod Music {
 978                 $$ = context_spec_music ($2, get_next_unique_context (),
 979                                          $4, $3);
 980         }
 981
 982         | TIMES {
 983                 THIS->push_spot ();
 984         }
 985         /* CONTINUED */
 986                 fraction Music
 987
 988         {
 989                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 990                 Music *mp = $4;
 991
 992                 $$= MY_MAKE_MUSIC("TimeScaledMusic");
 993                 $$->set_spot (THIS->pop_spot ());
 994
 995                 $$->set_mus_property ("element", mp->self_scm ());
 996                 scm_gc_unprotect_object (mp->self_scm ());
 997                 $$->set_mus_property ("numerator", gh_int2scm (n));
 998                 $$->set_mus_property ("denominator", gh_int2scm (d));
 999                 $$->compress (Moment (Rational (n,d)));
1000
1001         }
1002         | Repeated_music                { $$ = $1; }
1003         | Simultaneous_music            { $$ = $1; }
1004         | Sequential_music              { $$ = $1; }
1005         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1006                 $$ = MY_MAKE_MUSIC("TransposedMusic");
1007                 Music *p = $4;
1008                 Pitch from = *unsmob_pitch ($2);
1009                 Pitch to = *unsmob_pitch ($3);
1010
1011                 p->transpose (interval (from, to));
1012                 $$->set_mus_property ("element", p->self_scm ());
1013                 scm_gc_unprotect_object (p->self_scm ());
1014         }
1015         | APPLY embedded_scm Music  {
1016                 if (!ly_input_procedure_p ($2))
1017                         {
1018                         THIS->parser_error (_ ("\\apply takes function argument"));
1019                         $$ = $3;
1020                         }
1021                 else
1022                         {
1023                         SCM ret = gh_call1 ($2, $3->self_scm ());
1024                         Music *m = unsmob_music (ret);
1025                         if (!m) {
1026                                 THIS->parser_error ("\\apply must return a Music");
1027                                 m = MY_MAKE_MUSIC("Music");
1028                                 }
1029                         $$ = m;
1030                         }
1031         }
1032         | NOTES
1033                 { THIS->lexer_->push_note_state (); }
1034         Music
1035                 { $$ = $3;
1036                   THIS->lexer_->pop_state ();
1037                 }
1038         | FIGURES
1039                 { THIS->lexer_->push_figuredbass_state (); }
1040         Music
1041                 {
1042                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1043                   chm->set_mus_property ("element", $3->self_scm ());
1044                   $$ = chm;
1045                   scm_gc_unprotect_object ($3->self_scm());
1046
1047                   THIS->lexer_->pop_state ();
1048         }
1049         | CHORDS
1050                 { THIS->lexer_->push_chord_state (); }
1051         Music
1052                 {
1053                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1054                   chm->set_mus_property ("element", $3->self_scm ());
1055                   scm_gc_unprotect_object ($3->self_scm());
1056                   $$ = chm;
1057
1058                   THIS->lexer_->pop_state ();
1059         }
1060         | LYRICS
1061                 { THIS->lexer_->push_lyric_state (); }
1062         Music
1063                 {
1064                   $$ = $3;
1065                   THIS->lexer_->pop_state ();
1066         }
1067         | relative_music        { $$ = $1; }
1068         | re_rhythmed_music     { $$ = $1; }
1069         | part_combined_music   { $$ = $1; }
1070         | TAG embedded_scm Music {
1071                 tag_music ($3, $2, THIS->here_input ());
1072                 $$ = $3;
1073         }
1074         ;
1075
1076 relative_music:
1077         RELATIVE absolute_pitch Music {
1078                 Music * p = $3;
1079                 Pitch pit = *unsmob_pitch ($2);
1080                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1081
1082                 $$->set_mus_property ("element", p->self_scm ());
1083                 scm_gc_unprotect_object (p->self_scm ());
1084
1085
1086                 Pitch retpitch = p->to_relative_octave (pit);
1087                 if (lily_1_8_relative)
1088                         $$->set_mus_property ("last-pitch", retpitch.smobbed_copy ());
1089         }
1090         ;
1091
1092 re_rhythmed_music:
1093         ADDLYRICS Music Music {
1094         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1095           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1096           scm_gc_unprotect_object ($3->self_scm ());
1097           scm_gc_unprotect_object ($2->self_scm ());
1098           $$ = l;
1099         }
1100         ;
1101
1102 part_combined_music:
1103         PARTCOMBINE STRING Music Music {
1104                 Music * p= MY_MAKE_MUSIC("PartCombineMusic");
1105                 p->set_mus_property ("what", scm_string_to_symbol ($2));
1106                 p->set_mus_property ("elements", gh_list ($3->self_scm (),$4->self_scm (), SCM_UNDEFINED));
1107
1108                 scm_gc_unprotect_object ($3->self_scm ());
1109                 scm_gc_unprotect_object ($4->self_scm ());
1110
1111                 $$ = p;
1112         }
1113         ;
1114
1115 context_change:
1116         CHANGE STRING '=' STRING  {
1117                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1118                 t-> set_mus_property ("change-to-type", scm_string_to_symbol ($2));
1119                 t-> set_mus_property ("change-to-id", $4);
1120
1121                 $$ = t;
1122                 $$->set_spot (THIS->here_input ());
1123         }
1124         ;
1125
1126 property_operation:
1127         STRING '='  scalar {
1128                 $$ = scm_list_n (ly_symbol2scm ("assign"),
1129                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1130         }
1131         | STRING UNSET {
1132                 $$ = scm_list_n (ly_symbol2scm ("unset"),
1133                         scm_string_to_symbol ($1), SCM_UNDEFINED);
1134         }
1135         | STRING SET embedded_scm '=' embedded_scm {
1136                 $$ = scm_list_n (ly_symbol2scm ("poppush"),
1137                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1138         }
1139         | STRING OVERRIDE embedded_scm '=' embedded_scm {
1140                 $$ = scm_list_n (ly_symbol2scm ("push"),
1141                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1142         }
1143         | STRING REVERT embedded_scm {
1144                 $$ = scm_list_n (ly_symbol2scm ("pop"),
1145                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1146         }
1147         ;
1148
1149 translator_mod:
1150         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1151         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1152         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1153
1154         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1155         | DENIES { $$ = ly_symbol2scm ("denies"); }
1156
1157         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1158         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1159         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1160         | NAME { $$ = ly_symbol2scm ("context-name"); }
1161         ;
1162
1163 context_mod:
1164         property_operation { $$ = $1; }
1165         | translator_mod STRING {
1166                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
1167         }
1168         ;
1169
1170 music_property_def:
1171         PROPERTY STRING '.' property_operation {
1172                 Music * t = property_op_to_music ($4);
1173                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1174
1175                 csm->set_mus_property ("element", t->self_scm ());
1176                 scm_gc_unprotect_object (t->self_scm ());
1177
1178                 $$ = csm;
1179                 $$->set_spot (THIS->here_input ());
1180
1181                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1182         }
1183         | ONCE music_property_def {
1184                 $$ = $2;
1185                 SCM e = $2->get_mus_property ("element");
1186                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1187         }
1188         ;
1189
1190
1191 scalar:
1192         string          { $$ = $1; }
1193         | bare_int      { $$ = gh_int2scm ($1); }
1194         | embedded_scm  { $$ = $1; }
1195         | full_markup {  $$ = $1; }
1196         | DIGIT { $$ = gh_int2scm ($1); }
1197         ;
1198
1199 /*
1200 This is a trick:
1201
1202 Adding pre_events to the simple_element
1203 makes the choice between
1204
1205   string:  STRING
1206
1207 and
1208
1209   simple_element: STRING
1210
1211 a single shift/reduction conflict.
1212
1213 nevertheless, this is not very clean, and we should find a different
1214 solution.
1215
1216 */
1217 pre_events: {
1218                 THIS->push_spot ();
1219         }
1220         ;
1221
1222 event_chord:
1223         pre_events simple_element post_events   {
1224                 SCM elts = $2-> get_mus_property ("elements");
1225
1226                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1227
1228                 $2->set_mus_property ("elements", elts);
1229                 $$ = $2;
1230         }
1231         | command_element
1232         | note_chord_element
1233         ;
1234
1235
1236 note_chord_element:
1237         chord_body optional_notemode_duration post_events
1238         {
1239                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1240                 SCM es = $1->get_mus_property ("elements");
1241                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1242
1243                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1244                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1245                 es = gh_append2 (es, postevs);
1246
1247                 $1-> set_mus_property ("elements", es);
1248                 $$ = $1;
1249         }
1250         ;
1251
1252 chord_open: '<'
1253         ;
1254
1255 chord_close: '>'
1256         ;
1257
1258 simul_open: LESSLESS
1259         ;
1260
1261 simul_close: MOREMORE
1262         ;
1263
1264 chord_body:
1265         chord_open chord_body_elements chord_close
1266         {
1267                 $$ = MY_MAKE_MUSIC("EventChord");
1268                 $$->set_mus_property ("elements",
1269                         scm_reverse_x ($2, SCM_EOL));
1270         }
1271         ;
1272
1273 chord_body_elements:
1274         /* empty */             { $$ = SCM_EOL; }
1275         | chord_body_elements chord_body_element {
1276                 $$ = gh_cons ($2->self_scm(), $1);
1277                 scm_gc_unprotect_object ($2->self_scm());
1278         }
1279         ;
1280
1281 chord_body_element:
1282         pitch exclamations questions post_events
1283         {
1284                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1285                 n->set_mus_property ("pitch", $1);
1286                 if ($3 % 2)
1287                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1288                 if ($2 % 2 || $3 % 2)
1289                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1290
1291                 SCM arts = scm_reverse_x ($4, SCM_EOL);
1292                 n->set_mus_property ("articulations", arts);
1293
1294                 $$ = n;
1295         }
1296         ;
1297
1298 command_element:
1299         command_req {
1300                 $$ = MY_MAKE_MUSIC("EventChord");
1301                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1302                 scm_gc_unprotect_object ($1->self_scm());
1303
1304                 $$-> set_spot (THIS->here_input ());
1305                 $1-> set_spot (THIS->here_input ());
1306         }
1307         | OCTAVE { THIS->push_spot (); }
1308           pitch {
1309                 Music *l = MY_MAKE_MUSIC("RelativeOctaveCheck");
1310                 $$ = l;
1311                 $$->set_spot (THIS->pop_spot ());
1312                 $$->set_mus_property ("pitch", $3);
1313         }
1314         | E_LEFTSQUARE {
1315                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1316                 l->set_mus_property ("span-direction", gh_int2scm (START));
1317                 l->set_spot (THIS->here_input ());
1318
1319                 $$ = MY_MAKE_MUSIC("EventChord");
1320                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1321                 scm_gc_unprotect_object (l->self_scm());
1322                 $$->set_spot (THIS->here_input ());
1323         }
1324         | E_RIGHTSQUARE {
1325                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1326                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1327                 l->set_spot (THIS->here_input ());
1328
1329                 $$ = MY_MAKE_MUSIC("EventChord");
1330                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1331                 $$->set_spot (THIS->here_input ());
1332                 scm_gc_unprotect_object (l->self_scm());
1333         }
1334         | E_BACKSLASH {
1335                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1336                 $$->set_spot (THIS->here_input ());
1337         }
1338         | '|'      {
1339
1340                 $$ = MY_MAKE_MUSIC("BarCheck");
1341                 $$->set_spot (THIS->here_input ());
1342         }
1343         | BAR STRING                    {
1344                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1345
1346                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1347                 csm->set_mus_property ("element", t->self_scm ());
1348                 scm_gc_unprotect_object (t->self_scm ());
1349
1350                 $$ = csm;
1351                 $$->set_spot (THIS->here_input ());
1352
1353                 csm->set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1354         }
1355         | PARTIAL duration_length       {
1356                 Moment m = - unsmob_duration ($2)->get_length ();
1357                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1358
1359                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1360                 sp->set_mus_property ("element", p->self_scm ());
1361                 scm_gc_unprotect_object (p->self_scm ());
1362
1363                 $$ =sp ;
1364                 sp-> set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1365         }
1366         | CLEF STRING  {
1367                 static SCM proc ;
1368                 if (!proc)
1369                         proc = scm_c_eval_string ("make-clef-set");
1370
1371                 SCM result = scm_call_1 (proc, $2);
1372                 scm_gc_protect_object (result);
1373                 $$ = unsmob_music (result);
1374         }
1375         | TIME_T fraction  {
1376                 static SCM proc;
1377                 if (!proc)
1378                         proc = scm_c_eval_string ("make-time-signature-set");
1379
1380                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1381                 scm_gc_protect_object (result);
1382                 $$ = unsmob_music (result);
1383         }
1384         ;
1385
1386 command_req:
1387         shorthand_command_req   { $$ = $1; }
1388         | verbose_command_req   { $$ = $1; }
1389         ;
1390
1391 shorthand_command_req:
1392         hyphen_req {
1393                 $$ = $1;
1394         }
1395         | BREATHE {
1396                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1397         }
1398         | E_TILDE {
1399                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1400         }
1401         ;
1402
1403 verbose_command_req:
1404         MARK DEFAULT  {
1405                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1406                 $$ = m;
1407         }
1408         | MARK scalar {
1409                 Music *m = MY_MAKE_MUSIC("MarkEvent");
1410                 m->set_mus_property ("label", $2);
1411                 $$ = m;
1412         }
1413         | SKIP duration_length {
1414                 Music * skip = MY_MAKE_MUSIC("SkipEvent");
1415                 skip->set_mus_property ("duration", $2);
1416
1417                 $$ = skip;
1418         }
1419         | tempo_event {
1420                 $$ = $1;
1421         }
1422         | KEY DEFAULT {
1423                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1424                 $$ = key;
1425         }
1426         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1427
1428                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1429                 if (scm_ilength ($3) > 0)
1430                 {
1431                         key->set_mus_property ("pitch-alist", $3);
1432                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1433                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1434                 } else {
1435                         THIS->parser_error (_("Second argument must be pitch list."));
1436                 }
1437
1438                 $$ = key;
1439         }
1440         ;
1441
1442 post_events:
1443         /* empty */ {
1444                 $$ = SCM_EOL;
1445         }
1446         | post_events post_event {
1447                 $2->set_spot (THIS->here_input ());
1448                 $$ = gh_cons ($2->self_scm(), $$);
1449                 scm_gc_unprotect_object ($2->self_scm());
1450         }
1451         | post_events tagged_post_event {
1452                 $2 -> set_spot (THIS->here_input ());
1453                 $$ = scm_cons ($2->self_scm(), $$);
1454                 scm_gc_unprotect_object ($2->self_scm());
1455         }
1456         ;
1457
1458
1459 tagged_post_event:
1460         '-' TAG embedded_scm post_event {
1461                 tag_music ($4, $3, THIS->here_input ());
1462                 $$ = $4;
1463         }
1464         ;
1465
1466 post_event:
1467         direction_less_event {
1468                 $$ = $1;
1469         }
1470         | EXTENDER {
1471                 if (!THIS->lexer_->lyric_state_b ())
1472                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1473                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1474         }
1475         | script_dir direction_reqd_event {
1476                 if ($1)
1477                         $2->set_mus_property ("direction", gh_int2scm ($1));
1478                 $$ = $2;
1479         }
1480         | script_dir direction_less_event {
1481                 if ($1)
1482                         $2->set_mus_property ("direction", gh_int2scm ($1));
1483                 $$ = $2;
1484         }
1485         | string_number_event
1486         ;
1487
1488 string_number_event:
1489         E_UNSIGNED {
1490                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1491                 s->set_mus_property ("string-number",  gh_int2scm($1));
1492                 s->set_spot (THIS->here_input ());
1493                 $$ = s;
1494         }
1495         ;
1496
1497
1498 direction_less_event:
1499         '['  {
1500
1501
1502 /*
1503
1504 TODO: should take all these defs out of the parser, adn make use
1505 configurable, i.e.
1506
1507
1508 (set-articulation '~ "trill")
1509
1510 */
1511                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1512                 m->set_spot (THIS->here_input());
1513                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1514                 $$ = m;
1515         }
1516         | ']'  {
1517                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1518                 m->set_spot (THIS->here_input());
1519                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1520                 $$ = m;
1521         }
1522         | '~' {
1523                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1524                 m->set_spot (THIS->here_input());
1525                 $$ = m;
1526         }
1527         | close_event {
1528                 $$ = $1;
1529                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1530                         gh_int2scm (START));
1531         }
1532         | open_event {
1533                 $$ = $1;
1534                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1535                         gh_int2scm (STOP));
1536         }
1537         | EVENT_IDENTIFIER      {
1538                 $$ = unsmob_music ($1);
1539         }
1540         | tremolo_type  {
1541                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1542                a->set_spot (THIS->here_input ());
1543                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1544                $$ = a;
1545         }
1546         ;
1547
1548 direction_reqd_event:
1549         gen_text_def {
1550                 $$ = $1;
1551         }
1552         | script_abbreviation {
1553                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1554                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1555                 if (gh_string_p (s))
1556                         a->set_mus_property ("articulation-type", s);
1557                 else THIS->parser_error (_ ("Expecting string as script definition"));
1558                 $$ = a;
1559         }
1560         ;
1561
1562 sup_quotes:
1563         '\'' {
1564                 $$ = 1;
1565         }
1566         | sup_quotes '\'' {
1567                 $$ ++;
1568         }
1569         ;
1570
1571 sub_quotes:
1572         ',' {
1573                 $$ = 1;
1574         }
1575         | sub_quotes ',' {
1576                 $$ ++ ;
1577         }
1578         ;
1579
1580 steno_pitch:
1581         NOTENAME_PITCH  {
1582                 $$ = $1;
1583         }
1584         | NOTENAME_PITCH sup_quotes     {
1585                 Pitch p = *unsmob_pitch ($1);
1586                 p = p.transposed (Pitch ($2,0,0));
1587                 $$ = p.smobbed_copy ();
1588         }
1589         | NOTENAME_PITCH sub_quotes      {
1590                 Pitch p =* unsmob_pitch ($1);
1591                 p = p.transposed (Pitch (-$2,0,0));
1592                 $$ = p.smobbed_copy ();
1593         }
1594         ;
1595
1596 /*
1597 ugh. duplication
1598 */
1599
1600 steno_tonic_pitch:
1601         TONICNAME_PITCH {
1602                 $$ = $1;
1603         }
1604         | TONICNAME_PITCH sup_quotes    {
1605                 Pitch p = *unsmob_pitch ($1);
1606                 p = p.transposed (Pitch ($2,0,0));
1607                 $$ = p.smobbed_copy ();
1608         }
1609         | TONICNAME_PITCH sub_quotes     {
1610                 Pitch p =* unsmob_pitch ($1);
1611
1612                 p = p.transposed (Pitch (-$2,0,0));
1613                 $$ = p.smobbed_copy ();
1614         }
1615         ;
1616
1617 pitch:
1618         steno_pitch {
1619                 $$ = $1;
1620         }
1621         ;
1622
1623 pitch_also_in_chords:
1624         pitch
1625         | steno_tonic_pitch
1626         ;
1627
1628 hyphen_req:
1629         HYPHEN {
1630                 if (!THIS->lexer_->lyric_state_b ())
1631                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1632                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1633         }
1634         ;
1635
1636 close_event:
1637         '('     {
1638                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1639                 $$ = s;
1640                 s->set_spot (THIS->here_input());
1641         }
1642         | E_OPEN        {
1643                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1644                 $$ = s;
1645                 s->set_spot (THIS->here_input());
1646         }
1647         | E_SMALLER {
1648                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1649                 $$ = s;
1650                 s->set_spot (THIS->here_input());
1651         }
1652         | E_BIGGER {
1653                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1654                 $$ = s;
1655                 s->set_spot (THIS->here_input());
1656         }
1657         ;
1658
1659
1660 open_event:
1661         E_EXCLAMATION   {
1662                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1663                 s->set_spot (THIS->here_input());
1664
1665                 $$ = s;
1666         }
1667         | ')'   {
1668                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1669                 $$ = s;
1670                 s->set_spot (THIS->here_input());
1671
1672         }
1673         | E_CLOSE       {
1674                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1675                 $$ = s;
1676                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1677                 s->set_spot (THIS->here_input());
1678         }
1679         ;
1680
1681 gen_text_def:
1682         full_markup {
1683                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1684                 t->set_mus_property ("text", $1);
1685                 t->set_spot (THIS->here_input ());
1686                 $$ = t;
1687         }
1688         | string {
1689                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1690                 t->set_mus_property ("text", make_simple_markup ($1));
1691                 t->set_spot (THIS->here_input ());
1692                 $$ = t;
1693
1694         }
1695         | DIGIT {
1696                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1697                 t->set_mus_property ("digit",  gh_int2scm ($1));
1698                 t->set_spot (THIS->here_input ());
1699                 $$ = t;
1700         }
1701         ;
1702
1703 script_abbreviation:
1704         '^'             {
1705                 $$ = scm_makfrom0str ("Hat");
1706         }
1707         | '+'           {
1708                 $$ = scm_makfrom0str ("Plus");
1709         }
1710         | '-'           {
1711                 $$ = scm_makfrom0str ("Dash");
1712         }
1713         | '|'           {
1714                 $$ = scm_makfrom0str ("Bar");
1715         }
1716         | '>'           {
1717                 $$ = scm_makfrom0str ("Larger");
1718         }
1719         | '.'           {
1720                 $$ = scm_makfrom0str ("Dot");
1721         }
1722         | '_' {
1723                 $$ = scm_makfrom0str ("Underscore");
1724         }
1725         ;
1726
1727 script_dir:
1728         '_'     { $$ = DOWN; }
1729         | '^'   { $$ = UP; }
1730         | '-'   { $$ = CENTER; }
1731         ;
1732
1733
1734 absolute_pitch:
1735         steno_pitch     {
1736                 $$ = $1;
1737         }
1738         ;
1739
1740 duration_length:
1741         multiplied_duration {
1742                 $$ = $1;
1743         }
1744         ;
1745
1746 optional_notemode_duration:
1747         {
1748                 Duration dd = THIS->default_duration_;
1749                 $$ = dd.smobbed_copy ();
1750
1751                 THIS->beam_check ($$);
1752         }
1753         | multiplied_duration   {
1754                 $$ = $1;
1755                 THIS->default_duration_ = *unsmob_duration ($$);
1756
1757                 THIS->beam_check ($$);
1758         }
1759         ;
1760
1761 steno_duration:
1762         bare_unsigned dots              {
1763                 int l = 0;
1764                 if (!is_duration_b ($1))
1765                         THIS->parser_error (_f ("not a duration: %d", $1));
1766                 else
1767                         l =  intlog2 ($1);
1768
1769                 $$ = Duration (l, $2).smobbed_copy ();
1770         }
1771         | DURATION_IDENTIFIER dots      {
1772                 Duration *d =unsmob_duration ($1);
1773                 Duration k (d->duration_log (),d->dot_count () + $2);
1774
1775                 *d = k;
1776                 $$ = $1;
1777         }
1778         ;
1779
1780
1781
1782
1783 multiplied_duration:
1784         steno_duration {
1785                 $$ = $1;
1786         }
1787         | multiplied_duration '*' bare_unsigned {
1788                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1789         }
1790         | multiplied_duration '*' FRACTION {
1791                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1792
1793                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1794         }
1795         ;
1796
1797 fraction:
1798         FRACTION { $$ = $1; }
1799         | UNSIGNED '/' UNSIGNED {
1800                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1801         }
1802         ;
1803
1804 dots:
1805         /* empty */     {
1806                 $$ = 0;
1807         }
1808         | dots '.' {
1809                 $$ ++;
1810         }
1811         ;
1812
1813
1814 tremolo_type:
1815         ':'     {
1816                 $$ =0;
1817         }
1818         | ':' bare_unsigned {
1819                 if (!is_duration_b ($2))
1820                         THIS->parser_error (_f ("not a duration: %d", $2));
1821                 $$ = $2;
1822         }
1823         ;
1824
1825
1826
1827 /*****************************************************************
1828                 BASS FIGURES
1829 *****************************************************************/
1830 bass_number:
1831         DIGIT   {
1832                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1833         }
1834         | UNSIGNED {
1835                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1836         }
1837         | STRING { $$ =  $1; }
1838         ;
1839
1840 bass_mod:
1841         '-'     { $$ = -2; }
1842         | '+'   { $$ = 2; }
1843         | '!'   { $$ = 0; }
1844         ;
1845
1846 bass_figure:
1847         FIGURE_SPACE {
1848                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1849                 $$ = bfr->self_scm();
1850                 scm_gc_unprotect_object ($$);
1851         }
1852         | bass_number  {
1853                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1854                 $$ = bfr->self_scm();
1855
1856                 bfr->set_mus_property ("figure", $1);
1857
1858                 scm_gc_unprotect_object ($$);
1859         }
1860         | bass_figure bass_mod {
1861                 Music *m = unsmob_music ($1);
1862                 if ($2) {
1863                         SCM salter =m->get_mus_property ("alteration");
1864                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1865                         m->set_mus_property ("alteration",
1866                                 gh_int2scm (alter + $2));
1867                 } else {
1868                         m->set_mus_property ("alteration", gh_int2scm (0));
1869                 }
1870         }
1871         ;
1872
1873 br_bass_figure:
1874         '[' bass_figure {
1875                 $$ = $2;
1876                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1877         }
1878         | bass_figure   {
1879                 $$ = $1;
1880         }
1881         | br_bass_figure ']' {
1882                 $$ = $1;
1883                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1884         }
1885         ;
1886
1887 figure_list:
1888         /**/            {
1889                 $$ = SCM_EOL;
1890         }
1891         | figure_list br_bass_figure {
1892                 $$ = scm_cons ($2, $1);
1893         }
1894         ;
1895
1896 figure_spec:
1897         FIGURE_OPEN figure_list FIGURE_CLOSE {
1898                 Music * m = MY_MAKE_MUSIC("EventChord");
1899                 $2 = scm_reverse_x ($2, SCM_EOL);
1900                 m->set_mus_property ("elements",  $2);
1901                 $$ = m->self_scm ();
1902         }
1903         ;
1904
1905
1906 optional_rest:
1907         /**/   { $$ = 0; }
1908         | REST { $$ = 1; }
1909         ;
1910
1911 simple_element:
1912         pitch exclamations questions optional_notemode_duration optional_rest {
1913
1914                 Input i = THIS->pop_spot ();
1915                 if (!THIS->lexer_->note_state_b ())
1916                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1917
1918                 Music *n = 0;
1919                 if ($5)
1920                         n =  MY_MAKE_MUSIC("RestEvent");
1921                 else
1922                         n =  MY_MAKE_MUSIC("NoteEvent");
1923
1924                 n->set_mus_property ("pitch", $1);
1925                 n->set_mus_property ("duration", $4);
1926
1927
1928                 if ($3 % 2)
1929                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1930                 if ($2 % 2 || $3 % 2)
1931                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1932
1933                 Music *v = MY_MAKE_MUSIC("EventChord");
1934                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1935                 scm_gc_unprotect_object (n->self_scm());
1936
1937                 v->set_spot (i);
1938                 n->set_spot (i);
1939                 $$ = v;
1940         }
1941         | figure_spec optional_notemode_duration {
1942                 Music * m = unsmob_music ($1);
1943                 Input i = THIS->pop_spot ();
1944                 m->set_spot (i);
1945                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
1946                 {
1947                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
1948                 }
1949                 $$ = m;
1950         }
1951         | RESTNAME optional_notemode_duration           {
1952
1953                 Input i = THIS->pop_spot ();
1954                 Music * ev = 0;
1955                 if (ly_scm2string ($1) =="s") {
1956                         /* Space */
1957                         ev = MY_MAKE_MUSIC("SkipEvent");
1958                   }
1959                 else {
1960                         ev = MY_MAKE_MUSIC("RestEvent");
1961
1962                     }
1963                 ev->set_mus_property ("duration" ,$2);
1964                 ev->set_spot (i);
1965                 Music * velt = MY_MAKE_MUSIC("EventChord");
1966                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
1967                 velt->set_spot (i);
1968
1969                 $$ = velt;
1970         }
1971         | MULTI_MEASURE_REST optional_notemode_duration         {
1972                 THIS->pop_spot ();
1973
1974                 static SCM proc ;
1975                 if (!proc)
1976                         proc = scm_c_eval_string ("make-multi-measure-rest");
1977
1978                 SCM mus = scm_call_2 (proc, $2,
1979                         make_input (THIS->here_input()));
1980                 scm_gc_protect_object (mus);
1981                 $$ = unsmob_music (mus);
1982         }
1983
1984         | lyric_element optional_notemode_duration      {
1985                 Input i = THIS->pop_spot ();
1986                 if (!THIS->lexer_->lyric_state_b ())
1987                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1988
1989                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
1990                 lreq->set_mus_property ("text", $1);
1991                 lreq->set_mus_property ("duration",$2);
1992                 lreq->set_spot (i);
1993                 Music * velt = MY_MAKE_MUSIC("EventChord");
1994                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
1995
1996                 $$= velt;
1997         }
1998         | new_chord {
1999                 THIS->pop_spot ();
2000
2001                 if (!THIS->lexer_->chord_state_b ())
2002                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2003                 $$ = unsmob_music ($1);
2004         }
2005         ;
2006
2007 lyric_element:
2008         full_markup { $$ = $1; }
2009         | STRING {  $$ = $1 ; }
2010         ;
2011
2012 new_chord:
2013         steno_tonic_pitch optional_notemode_duration   {
2014                 $$ = make_chord ($1, $2, SCM_EOL);
2015         }
2016         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2017                 SCM its = scm_reverse_x ($4, SCM_EOL);
2018                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2019         }
2020         ;
2021
2022 chord_items:
2023         /**/ {
2024                 $$ = SCM_EOL;
2025         }
2026         | chord_items chord_item {
2027                 $$ = gh_cons ($2, $$);
2028         }
2029         ;
2030
2031 chord_separator:
2032         CHORD_COLON {
2033                 $$ = ly_symbol2scm ("chord-colon");
2034         }
2035         | CHORD_CARET {
2036                 $$ = ly_symbol2scm ("chord-caret");
2037         }
2038         | CHORD_SLASH steno_tonic_pitch {
2039                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2040         }
2041         | CHORD_BASS steno_tonic_pitch {
2042                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2043         }
2044         ;
2045
2046 chord_item:
2047         chord_separator {
2048                 $$ = $1;
2049         }
2050         | step_numbers {
2051                 $$ = scm_reverse_x ($1, SCM_EOL);
2052         }
2053         | CHORD_MODIFIER  {
2054                 $$ = $1;
2055         }
2056         ;
2057
2058 step_numbers:
2059         step_number { $$ = gh_cons ($1, SCM_EOL); }
2060         | step_numbers '.' step_number {
2061                 $$ = gh_cons ($3, $$);
2062         }
2063         ;
2064
2065 step_number:
2066         bare_unsigned {
2067                 $$ = make_chord_step ($1, 0);
2068         }
2069         | bare_unsigned '+' {
2070                 $$ = make_chord_step ($1, SHARP);
2071         }
2072         | bare_unsigned CHORD_MINUS {
2073                 $$ = make_chord_step ($1, FLAT);
2074         }
2075         ;
2076
2077 /*
2078         UTILITIES
2079
2080 TODO: should deprecate in favor of Scheme?
2081
2082  */
2083 number_expression:
2084         number_expression '+' number_term {
2085                 $$ = scm_sum ($1, $3);
2086         }
2087         | number_expression '-' number_term {
2088                 $$ = scm_difference ($1, $3);
2089         }
2090         | number_term
2091         ;
2092
2093 number_term:
2094         number_factor {
2095                 $$ = $1;
2096         }
2097         | number_factor '*' number_factor {
2098                 $$ = scm_product ($1, $3);
2099         }
2100         | number_factor '/' number_factor {
2101                 $$ = scm_divide ($1, $3);
2102         }
2103         ;
2104
2105 number_factor:
2106         '-'  number_factor { /* %prec UNARY_MINUS */
2107                 $$ = scm_difference ($2, SCM_UNDEFINED);
2108         }
2109         | bare_number
2110         ;
2111
2112
2113 bare_number:
2114         UNSIGNED        {
2115                 $$ = gh_int2scm ($1);
2116         }
2117         | REAL          {
2118                 $$ = $1;
2119         }
2120         | NUMBER_IDENTIFIER             {
2121                 $$ = $1;
2122         }
2123         | REAL NUMBER_IDENTIFIER        {
2124                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2125         }
2126         | UNSIGNED NUMBER_IDENTIFIER    {
2127                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2128         }
2129         ;
2130
2131
2132 bare_unsigned:
2133         UNSIGNED {
2134                         $$ = $1;
2135         }
2136         | DIGIT {
2137                 $$ = $1;
2138         }
2139         ;
2140
2141 bare_int:
2142         bare_number {
2143                 if (scm_integer_p ($1) == SCM_BOOL_T)
2144                 {
2145                         int k = gh_scm2int ($1);
2146                         $$ = k;
2147                 } else
2148                 {
2149                         THIS->parser_error (_ ("need integer number arg"));
2150                         $$ = 0;
2151                 }
2152         }
2153         | '-' bare_int {
2154                 $$ = -$2;
2155         }
2156         ;
2157
2158
2159 string:
2160         STRING          {
2161                 $$ = $1;
2162         }
2163         | STRING_IDENTIFIER     {
2164                 $$ = $1;
2165         }
2166         | string '+' string {
2167                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2168         }
2169         ;
2170
2171
2172 exclamations:
2173                 { $$ = 0; }
2174         | exclamations '!'      { $$ ++; }
2175         ;
2176
2177 questions:
2178                 { $$ = 0; }
2179         | questions '?' { $$ ++; }
2180         ;
2181
2182
2183
2184 full_markup:
2185         MARKUP_IDENTIFIER {
2186                 $$ = $1;
2187         }
2188         | MARKUP
2189                 { THIS->lexer_->push_markup_state (); }
2190         markup
2191                 { $$ = $3;
2192                   THIS->lexer_->pop_state ();
2193                 }
2194         ;
2195
2196
2197 /*
2198 This should be done more dynamically if possible.
2199 */
2200 markup:
2201         STRING {
2202                 $$ = make_simple_markup ($1);
2203         }
2204         | MARKUP_HEAD_MARKUP0 markup {
2205                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2206         }
2207         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2208                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2209         }
2210         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2211                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2212         }
2213         | markup_line {
2214                 $$ = $1;
2215         }
2216         | MARKUP_HEAD_LIST0 markup_list {
2217                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2218         }
2219         | MARKUP_HEAD_SCM0 embedded_scm {
2220                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2221         }
2222         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2223                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2224         }
2225         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2226                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2227         }
2228         | MARKUP_IDENTIFIER {
2229                 $$ = $1;
2230         }
2231
2232         ;
2233
2234 markup_list:
2235         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2236         ;
2237
2238 markup_line:
2239         '{' markup_list_body '}' {
2240                 static SCM line ;
2241                 if (!line)
2242                         line = scm_c_eval_string ("line-markup");
2243
2244                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2245         }
2246         ;
2247
2248 markup_list_body:
2249         /**/ {  $$ = SCM_EOL; }
2250         | markup_list_body markup {
2251                 $$ = gh_cons ($2, $1) ;
2252         }
2253         ;
2254
2255
2256 %%
2257
2258 void
2259 My_lily_parser::set_yydebug (bool )
2260 {
2261 #if 0
2262         yydebug = 1;
2263 #endif
2264 }
2265
2266 extern My_lily_parser * current_parser;
2267
2268 void
2269 My_lily_parser::do_yyparse ()
2270 {
2271         current_parser = this;;
2272         yyparse ((void*)this);
2273 }
2274
2275
2276 /*
2277 Should make this optional?    It will also complain when you do
2278
2279         [s4]
2280
2281 which is entirely legitimate.
2282
2283 Or we can scrap it. Barchecks should detect wrong durations, and
2284 skipTypesetting speeds it up a lot.
2285 */
2286
2287 void
2288 My_lily_parser::beam_check (SCM dur)
2289 {
2290   Duration *d = unsmob_duration (dur);
2291   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2292     {
2293       Music * m = unsmob_music (last_beam_start_);
2294       m->origin ()->warning (_("Suspect duration found following this beam"));
2295     }
2296   last_beam_start_ = SCM_EOL;
2297 }
2298
2299
2300
2301
2302 /*
2303
2304 It is a little strange to have this function in this file, but
2305 otherwise, we have to import music classes into the lexer.
2306
2307 */
2308 int
2309 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2310 {
2311         if (gh_string_p (sid)) {
2312                 *destination = sid;
2313                 return STRING_IDENTIFIER;
2314         } else if (gh_number_p (sid)) {
2315                 *destination = sid;
2316                 return NUMBER_IDENTIFIER;
2317         } else if (unsmob_context_def (sid)) {
2318                 *destination = unsmob_context_def (sid)->clone_scm();
2319                 return TRANSLATOR_IDENTIFIER;
2320         } else if (unsmob_score (sid)) {
2321                 Score *sc =  new Score (*unsmob_score (sid));
2322                 *destination =sc->self_scm ();
2323                 return SCORE_IDENTIFIER;
2324         } else if (Music * mus =unsmob_music (sid)) {
2325                 *destination = unsmob_music (sid)->clone ()->self_scm();
2326                 unsmob_music (*destination)->
2327                         set_mus_property ("origin", make_input (last_input_));
2328                 return dynamic_cast<Event*> (mus)
2329                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2330         } else if (unsmob_duration (sid)) {
2331                 *destination = unsmob_duration (sid)->smobbed_copy();
2332                 return DURATION_IDENTIFIER;
2333         } else if (unsmob_music_output_def (sid)) {
2334                 Music_output_def *p = unsmob_music_output_def (sid);
2335                 p = p->clone ();
2336
2337                 *destination = p->self_scm();
2338                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2339         } else if (Text_item::markup_p (sid)) {
2340                 *destination = sid;
2341                 return MARKUP_IDENTIFIER;
2342         }
2343
2344         return -1;
2345 }
2346
2347 Music *
2348 property_op_to_music (SCM op)
2349 {
2350         Music * m = 0;
2351         SCM tag = gh_car (op);
2352         SCM symbol  = gh_cadr (op);
2353         SCM args = gh_cddr (op);
2354         SCM grob_val = SCM_UNDEFINED;
2355         SCM grob_sym = SCM_UNDEFINED;
2356         SCM val = SCM_UNDEFINED;
2357
2358         if (tag == ly_symbol2scm ("assign"))
2359                 {
2360                 m =  MY_MAKE_MUSIC("PropertySet");
2361                 val = gh_car (args);
2362                 }
2363         else if (tag == ly_symbol2scm ("unset"))
2364                 m =  MY_MAKE_MUSIC("PropertyUnset");
2365         else if (tag == ly_symbol2scm ("poppush")
2366                  || tag == ly_symbol2scm ("push"))
2367                 {
2368                 m  = MY_MAKE_MUSIC("OverrideProperty");
2369                 grob_sym = gh_car (args);
2370                 grob_val = gh_cadr (args);
2371                 }
2372         else if (tag == ly_symbol2scm ("pop")) {
2373                 m = MY_MAKE_MUSIC("RevertProperty");
2374                 grob_sym = gh_car (args);
2375                 }
2376
2377         m->set_mus_property ("symbol", symbol);
2378
2379         if (val != SCM_UNDEFINED)
2380                 m->set_mus_property ("value", val);
2381         if (grob_val != SCM_UNDEFINED)
2382                 m->set_mus_property ("grob-value", grob_val);
2383
2384         if (grob_sym != SCM_UNDEFINED)
2385                 {
2386                 bool itc = internal_type_checking_global_b;
2387                 /* UGH.
2388                 */
2389                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2390                 if (autobeam)
2391                         internal_type_checking_global_b = false;
2392                 m->set_mus_property ("grob-property", grob_sym);
2393                 if (autobeam)
2394                         internal_type_checking_global_b = itc;
2395                 }
2396
2397         if (op == ly_symbol2scm ("poppush"))
2398                 m->set_mus_property ("pop-first", SCM_BOOL_T);
2399
2400
2401         return m;
2402 }
2403
2404 Music*
2405 context_spec_music (SCM type, SCM id, Music * m, SCM ops)
2406 {
2407         Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
2408
2409         csm->set_mus_property ("element", m->self_scm ());
2410         scm_gc_unprotect_object (m->self_scm ());
2411
2412         csm->set_mus_property ("context-type", scm_string_to_symbol (type));
2413         csm->set_mus_property ("property-operations", ops);
2414
2415         if (gh_string_p (id))
2416                 csm->set_mus_property ("context-id", id);
2417         return csm;
2418 }
2419
2420
2421 SCM
2422 get_next_unique_context ()
2423 {
2424         static int new_context_count;
2425
2426         char s[1024];
2427         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2428
2429         return scm_makfrom0str (s);
2430 }