lily/parser.yy

   1 /*
   2   This file is part of LilyPond, the GNU music typesetter.
   3
   4   Copyright (C) 1997--2009 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5                  Jan Nieuwenhuizen <janneke@gnu.org>
   6
   7   LilyPond is free software: you can redistribute it and/or modify
   8   it under the terms of the GNU General Public License as published by
   9   the Free Software Foundation, either version 3 of the License, or
  10   (at your option) any later version.
  11
  12   LilyPond is distributed in the hope that it will be useful,
  13   but WITHOUT ANY WARRANTY; without even the implied warranty of
  14   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15   GNU General Public License for more details.
  16
  17   You should have received a copy of the GNU General Public License
  18   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  19 */
  20
  21 %{
  22
  23 #define YYDEBUG 1
  24 #define YYERROR_VERBOSE 1
  25 #define YYPARSE_PARAM my_lily_parser
  26 #define YYLEX_PARAM my_lily_parser
  27 #define PARSER ((Lily_parser *) my_lily_parser)
  28
  29 #define yyerror PARSER->parser_error
  30
  31 /* We use custom location type: Input objects */
  32 #define YYLTYPE Input
  33 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  34         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  35
  36
  37 %}
  38
  39 /* We use SCMs to do strings, because it saves us the trouble of
  40 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  41 of the parse stack onto the heap. */
  42
  43 %left PREC_TOP
  44 %left ADDLYRICS
  45 %left PREC_BOT
  46
  47 %expect 1
  48
  49 /* One shift/reduce problem
  50
  51 1.  \repeat
  52         \repeat .. \alternative
  53
  54     \repeat { \repeat .. \alternative }
  55
  56 or
  57
  58     \repeat { \repeat } \alternative
  59 */
  60
  61
  62 %pure_parser
  63 %locations
  64
  65
  66
  67 %{ // -*-Fundamental-*-
  68
  69 /*
  70 FIXME:
  71
  72    * The rules for who is protecting what are very shady.  Uniformise
  73      this.
  74
  75    * There are too many lexical modes?
  76 */
  77
  78 #include "config.hh"
  79
  80 #include <cctype>
  81 #include <cstdlib>
  82 #include <cstdio>
  83 using namespace std;
  84
  85 #include "book.hh"
  86 #include "context-def.hh"
  87 #include "dimensions.hh"
  88 #include "file-path.hh"
  89 #include "input.hh"
  90 #include "international.hh"
  91 #include "lily-guile.hh"
  92 #include "lily-lexer.hh"
  93 #include "lily-parser.hh"
  94 #include "main.hh"
  95 #include "misc.hh"
  96 #include "music.hh"
  97 #include "music.hh"
  98 #include "output-def.hh"
  99 #include "paper-book.hh"
 100 #include "program-option.hh"
 101 #include "scm-hash.hh"
 102 #include "score.hh"
 103 #include "text-interface.hh"
 104 #include "warn.hh"
 105
 106 %}
 107
 108
 109 %union {
 110         Book *book;
 111         Output_def *outputdef;
 112         SCM scm;
 113         std::string *string;
 114         Music *music;
 115         Score *score;
 116         int i;
 117 }
 118
 119 %{
 120
 121 #define MY_MAKE_MUSIC(x, spot)  make_music_with_input (ly_symbol2scm (x), spot)
 122
 123 /* ES TODO:
 124 - Don't use lily module, create a new module instead.
 125 - delay application of the function
 126 */
 127 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 128   scm_apply_0 (proc, args)
 129 /* Syntactic Sugar. */
 130 #define MAKE_SYNTAX(name, location, ...)        \
 131   LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (PARSER->self_scm (), make_input (location), __VA_ARGS__, SCM_UNDEFINED));
 132
 133 SCM get_next_unique_context_id ();
 134 SCM get_next_unique_lyrics_context_id ();
 135
 136 #undef _
 137 #if !HAVE_GETTEXT
 138 #define _(x) x
 139 #else
 140 #include <libintl.h>
 141 #define _(x) gettext (x)
 142 #endif
 143
 144
 145 static Music *make_music_with_input (SCM name, Input where);
 146 SCM make_music_relative (Pitch start, SCM music, Input loc);
 147 SCM run_music_function (Lily_parser *, SCM expr);
 148 SCM get_first_context_id (SCM type, Music *m);
 149 SCM make_chord_elements (SCM pitch, SCM dur, SCM modification_list);
 150 SCM make_chord_step (int step, Rational alter);
 151 SCM make_simple_markup (SCM a);
 152 bool is_duration (int t);
 153 bool is_regular_identifier (SCM id);
 154 bool ly_input_procedure_p (SCM x);
 155 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 156 void set_music_properties (Music *p, SCM a);
 157
 158 %}
 159
 160 /* The third option is an alias that will be used to display the
 161    syntax error.  Bison CVS now correctly handles backslash escapes.
 162
 163    FIXME: Bison needs to translate some of these, eg, STRING.
 164
 165 */
 166
 167 /* Keyword tokens with plain escaped name.  */
 168 %token ACCEPTS "\\accepts"
 169 %token ADDLYRICS "\\addlyrics"
 170 %token ALIAS "\\alias"
 171 %token ALTERNATIVE "\\alternative"
 172 %token BOOK "\\book"
 173 %token BOOKPART "\\bookpart"
 174 %token CHANGE "\\change"
 175 %token CHORDMODE "\\chordmode"
 176 %token CHORDS "\\chords"
 177 %token CONSISTS "\\consists"
 178 %token CONTEXT "\\context"
 179 %token DEFAULT "\\default"
 180 %token DEFAULTCHILD "\\defaultchild"
 181 %token DENIES "\\denies"
 182 %token DESCRIPTION "\\description"
 183 %token DRUMMODE "\\drummode"
 184 %token DRUMS "\\drums"
 185 %token FIGUREMODE "\\figuremode"
 186 %token FIGURES "\\figures"
 187 %token GROBDESCRIPTIONS "\\grobdescriptions"
 188 %token HEADER "\\header"
 189 %token INVALID "\\invalid"
 190 %token KEY "\\key"
 191 %token LAYOUT "\\layout"
 192 %token LYRICMODE "\\lyricmode"
 193 %token LYRICS "\\lyrics"
 194 %token LYRICSTO "\\lyricsto"
 195 %token MARK "\\mark"
 196 %token MARKUP "\\markup"
 197 %token MARKUPLINES "\\markuplines"
 198 %token MIDI "\\midi"
 199 %token NAME "\\name"
 200 %token NOTEMODE "\\notemode"
 201 %token OBJECTID "\\objectid"
 202 %token OCTAVE "\\octave"
 203 %token ONCE "\\once"
 204 %token OVERRIDE "\\override"
 205 %token PAPER "\\paper"
 206 %token PARTIAL "\\partial"
 207 %token RELATIVE "\\relative"
 208 %token REMOVE "\\remove"
 209 %token REPEAT "\\repeat"
 210 %token REST "\\rest"
 211 %token REVERT "\\revert"
 212 %token SCORE "\\score"
 213 %token SEQUENTIAL "\\sequential"
 214 %token SET "\\set"
 215 %token SIMULTANEOUS "\\simultaneous"
 216 %token SKIP "\\skip"
 217 %token TEMPO "\\tempo"
 218 %token TIMES "\\times"
 219 %token TRANSPOSE "\\transpose"
 220 %token TYPE "\\type"
 221 %token UNSET "\\unset"
 222 %token WITH "\\with"
 223
 224 /* Keyword token exceptions.  */
 225 %token TIME_T "\\time"
 226 %token NEWCONTEXT "\\new"
 227
 228
 229 /* Other string tokens.  */
 230
 231 %token CHORD_BASS "/+"
 232 %token CHORD_CARET "^"
 233 %token CHORD_COLON ":"
 234 %token CHORD_MINUS "-"
 235 %token CHORD_SLASH "/"
 236 %token ANGLE_OPEN "<"
 237 %token ANGLE_CLOSE ">"
 238 %token DOUBLE_ANGLE_OPEN "<<"
 239 %token DOUBLE_ANGLE_CLOSE ">>"
 240 %token E_BACKSLASH "\\"
 241 %token E_ANGLE_CLOSE "\\>"
 242 %token E_CHAR "\\C[haracter]"
 243 %token E_CLOSE "\\)"
 244 %token E_EXCLAMATION "\\!"
 245 %token E_BRACKET_OPEN "\\["
 246 %token E_OPEN "\\("
 247 %token E_BRACKET_CLOSE "\\]"
 248 %token E_ANGLE_OPEN "\\<"
 249 %token E_PLUS "\\+"
 250 %token E_TILDE "\\~"
 251 %token EXTENDER "__"
 252
 253 /*
 254 If we give names, Bison complains.
 255 */
 256 %token FIGURE_CLOSE /* "\\>" */
 257 %token FIGURE_OPEN /* "\\<" */
 258 %token FIGURE_SPACE "_"
 259 %token HYPHEN "--"
 260
 261 %token CHORDMODIFIERS
 262 %token LYRIC_MARKUP
 263 %token MULTI_MEASURE_REST
 264
 265
 266 %token <i> DIGIT
 267 %token <i> E_UNSIGNED
 268 %token <i> UNSIGNED
 269
 270 /* Artificial tokens, for more generic function syntax */
 271 %token <i> EXPECT_MARKUP;
 272 %token <i> EXPECT_MUSIC;
 273 %token <i> EXPECT_SCM;
 274 /* After the last argument. */
 275 %token <i> EXPECT_NO_MORE_ARGS;
 276
 277 %token <scm> BOOK_IDENTIFIER
 278 %token <scm> CHORDMODIFIER_PITCH
 279 %token <scm> CHORD_MODIFIER
 280 %token <scm> CHORD_REPETITION
 281 %token <scm> CONTEXT_DEF_IDENTIFIER
 282 %token <scm> DRUM_PITCH
 283 %token <scm> DURATION_IDENTIFIER
 284 %token <scm> EVENT_IDENTIFIER
 285 %token <scm> FRACTION
 286 %token <scm> LYRICS_STRING
 287 %token <scm> LYRIC_MARKUP_IDENTIFIER
 288 %token <scm> MARKUP_HEAD_EMPTY
 289 %token <scm> MARKUP_HEAD_LIST0
 290 %token <scm> MARKUP_HEAD_MARKUP0
 291 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 292 %token <scm> MARKUP_HEAD_SCM0
 293 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 294 %token <scm> MARKUP_HEAD_SCM0_SCM1
 295 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 296 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2_MARKUP3
 297 %token <scm> MARKUP_HEAD_SCM0_MARKUP1_MARKUP2
 298 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 299 %token <scm> MARKUP_LIST_HEAD_EMPTY
 300 %token <scm> MARKUP_LIST_HEAD_LIST0
 301 %token <scm> MARKUP_LIST_HEAD_SCM0
 302 %token <scm> MARKUP_LIST_HEAD_SCM0_LIST1
 303 %token <scm> MARKUP_LIST_HEAD_SCM0_SCM1_LIST2
 304 %token <scm> MARKUP_IDENTIFIER
 305 %token <scm> MUSIC_FUNCTION
 306 %token <scm> MUSIC_IDENTIFIER
 307 %token <scm> NOTENAME_PITCH
 308 %token <scm> NUMBER_IDENTIFIER
 309 %token <scm> OUTPUT_DEF_IDENTIFIER
 310 %token <scm> REAL
 311 %token <scm> RESTNAME
 312 %token <scm> SCM_IDENTIFIER
 313 %token <scm> SCM_TOKEN
 314 %token <scm> SCORE_IDENTIFIER
 315 %token <scm> STRING
 316 %token <scm> STRING_IDENTIFIER
 317 %token <scm> TONICNAME_PITCH
 318
 319
 320 %type <book> book_block
 321 %type <book> book_body
 322 %type <book> bookpart_block
 323 %type <book> bookpart_body
 324
 325 %type <i> bare_unsigned
 326 %type <scm> figured_bass_alteration
 327 %type <i> dots
 328 %type <i> exclamations
 329 %type <i> optional_rest
 330 %type <i> questions
 331 %type <i> script_dir
 332 %type <i> sub_quotes
 333 %type <i> sup_quotes
 334 %type <i> tremolo_type
 335
 336 /* Music */
 337 %type <scm> composite_music
 338 %type <scm> grouped_music_list
 339 %type <scm> music
 340 %type <scm> prefix_composite_music
 341 %type <scm> repeated_music
 342 %type <scm> sequential_music
 343 %type <scm> simple_music
 344 %type <scm> simultaneous_music
 345 %type <scm> chord_body
 346 %type <scm> chord_body_element
 347 %type <scm> command_element
 348 %type <scm> command_event
 349 %type <scm> context_change
 350 %type <scm> direction_less_event
 351 %type <scm> direction_reqd_event
 352 %type <scm> event_chord
 353 %type <scm> gen_text_def
 354 %type <scm> music_property_def
 355 %type <scm> note_chord_element
 356 %type <scm> post_event
 357 %type <scm> re_rhythmed_music
 358 %type <scm> relative_music
 359 %type <scm> simple_element
 360 %type <scm> simple_music_property_def
 361 %type <scm> string_number_event
 362 %type <scm> tempo_event
 363
 364 %type <outputdef> output_def_body
 365 %type <outputdef> output_def_head
 366 %type <outputdef> output_def_head_with_mode_switch
 367 %type <outputdef> output_def
 368 %type <outputdef> paper_block
 369
 370 %type <scm> alternative_music
 371 %type <scm> generic_prefix_music_scm
 372 %type <scm> music_list
 373 %type <scm> absolute_pitch
 374 %type <scm> assignment_id
 375 %type <scm> bare_number
 376 %type <scm> unsigned_number
 377 %type <scm> bass_figure
 378 %type <scm> figured_bass_modification
 379 %type <scm> br_bass_figure
 380 %type <scm> bass_number
 381 %type <scm> chord_body_elements
 382 %type <scm> chord_item
 383 %type <scm> chord_items
 384 %type <scm> chord_separator
 385 %type <scm> context_def_mod
 386 %type <scm> context_def_spec_block
 387 %type <scm> context_def_spec_body
 388 %type <scm> context_mod
 389 %type <scm> context_mod_list
 390 %type <scm> context_prop_spec
 391 %type <scm> direction_less_char
 392 %type <scm> duration_length
 393 %type <scm> embedded_scm
 394 %type <scm> figure_list
 395 %type <scm> figure_spec
 396 %type <scm> fraction
 397 %type <scm> full_markup
 398 %type <scm> full_markup_list
 399 %type <scm> function_scm_argument
 400 %type <scm> function_arglist
 401 %type <scm> function_arglist_music_last
 402 %type <scm> function_arglist_nonmusic_last
 403 %type <scm> function_arglist_nonmusic
 404 %type <scm> identifier_init
 405 %type <scm> lilypond_header
 406 %type <scm> lilypond_header_body
 407 %type <scm> lyric_element
 408 %type <scm> lyric_markup
 409 %type <scm> markup
 410 %type <scm> markup_braced_list
 411 %type <scm> markup_braced_list_body
 412 %type <scm> markup_composed_list
 413 %type <scm> markup_command_list
 414 %type <scm> markup_head_1_item
 415 %type <scm> markup_head_1_list
 416 %type <scm> markup_list
 417 %type <scm> markup_top
 418 %type <scm> mode_changing_head
 419 %type <scm> mode_changing_head_with_context
 420 %type <scm> multiplied_duration
 421 %type <scm> music_function_identifier_musicless_prefix
 422 %type <scm> music_function_event
 423 %type <scm> music_function_chord_body
 424 %type <scm> new_chord
 425 %type <scm> new_lyrics
 426 %type <scm> number_expression
 427 %type <scm> number_factor
 428 %type <scm> number_term
 429 %type <scm> object_id_setting
 430 %type <scm> octave_check
 431 %type <scm> optional_context_mod
 432 %type <scm> optional_id
 433 %type <scm> optional_notemode_duration
 434 %type <scm> pitch
 435 %type <scm> pitch_also_in_chords
 436 %type <scm> post_events
 437 %type <scm> property_operation
 438 %type <scm> property_path property_path_revved
 439 %type <scm> scalar
 440 %type <scm> script_abbreviation
 441 %type <scm> simple_chord_elements
 442 %type <scm> simple_markup
 443 %type <scm> simple_string
 444 %type <scm> steno_duration
 445 %type <scm> steno_pitch
 446 %type <scm> steno_tonic_pitch
 447 %type <scm> step_number
 448 %type <scm> step_numbers
 449 %type <scm> string
 450
 451 %type <score> score_block
 452 %type <score> score_body
 453
 454
 455 %left '-' '+'
 456
 457 /* We don't assign precedence to / and *, because we might need varied
 458 prec levels in different prods */
 459
 460 %left UNARY_MINUS
 461
 462 %%
 463
 464 lilypond:       /* empty */
 465         | lilypond toplevel_expression {
 466         }
 467         | lilypond assignment {
 468         }
 469         | lilypond error {
 470                 PARSER->error_level_ = 1;
 471         }
 472         | lilypond INVALID      {
 473                 PARSER->error_level_ = 1;
 474         }
 475         ;
 476
 477
 478 object_id_setting:
 479         OBJECTID STRING { $$ = $2; }
 480         ;
 481
 482 toplevel_expression:
 483         lilypond_header {
 484                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 485         }
 486         | book_block {
 487                 Book *book = $1;
 488                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-book-handler");
 489                 scm_call_2 (proc, PARSER->self_scm (), book->self_scm ());
 490                 book->unprotect ();
 491         }
 492         | bookpart_block {
 493                 Book *bookpart = $1;
 494                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 495                 scm_call_2 (proc, PARSER->self_scm (), bookpart->self_scm ());
 496                 bookpart->unprotect ();
 497         }
 498         | score_block {
 499                 Score *score = $1;
 500
 501                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-score-handler");
 502                 scm_call_2 (proc, PARSER->self_scm (), score->self_scm ());
 503                 score->unprotect ();
 504         }
 505         | composite_music {
 506                 Music *music = unsmob_music ($1);
 507                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-music-handler");
 508                 scm_call_2 (proc, PARSER->self_scm (), music->self_scm ());
 509         }
 510         | full_markup {
 511                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 512                 scm_call_2 (proc, PARSER->self_scm (), scm_list_1 ($1));
 513         }
 514         | full_markup_list {
 515                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 516                 scm_call_2 (proc, PARSER->self_scm (), $1);
 517         }
 518         | output_def {
 519                 SCM id = SCM_EOL;
 520                 Output_def * od = $1;
 521
 522                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 523                         id = ly_symbol2scm ("$defaultpaper");
 524                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 525                         id = ly_symbol2scm ("$defaultmidi");
 526                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 527                         id = ly_symbol2scm ("$defaultlayout");
 528
 529                 PARSER->lexer_->set_identifier (id, od->self_scm ());
 530                 od->unprotect();
 531         }
 532         ;
 533
 534 embedded_scm:
 535         SCM_TOKEN
 536         | SCM_IDENTIFIER
 537         ;
 538
 539
 540 lilypond_header_body:
 541         {
 542                 $$ = get_header (PARSER);
 543                 PARSER->lexer_->add_scope ($$);
 544         }
 545         | lilypond_header_body assignment  {
 546
 547         }
 548         ;
 549
 550 lilypond_header:
 551         HEADER '{' lilypond_header_body '}'     {
 552                 $$ = PARSER->lexer_->remove_scope ();
 553         }
 554         ;
 555
 556 /*
 557         DECLARATIONS
 558 */
 559 assignment_id:
 560         STRING          { $$ = $1; }
 561         | LYRICS_STRING { $$ = $1; }
 562         ;
 563
 564 assignment:
 565         assignment_id '=' identifier_init  {
 566                 PARSER->lexer_->set_identifier ($1, $3);
 567
 568 /*
 569  TODO: devise standard for protection in parser.
 570
 571   The parser stack lives on the C-stack, which means that
 572 all objects can be unprotected as soon as they're here.
 573
 574 */
 575         }
 576         | embedded_scm { }
 577         ;
 578
 579
 580 identifier_init:
 581         score_block {
 582                 $$ = $1->self_scm ();
 583                 $1->unprotect ();
 584         }
 585         | book_block {
 586                 $$ = $1->self_scm ();
 587                 $1->unprotect ();
 588         }
 589         | bookpart_block {
 590                 $$ = $1->self_scm ();
 591                 $1->unprotect ();
 592         }
 593         | output_def {
 594                 $$ = $1->self_scm ();
 595                 $1->unprotect ();
 596         }
 597         | context_def_spec_block {
 598                 $$ = $1;
 599         }
 600         | music  {
 601                 /* Hack: Create event-chord around standalone events.
 602                    Prevents the identifier from being interpreted as a post-event. */
 603                 Music *mus = unsmob_music ($1);
 604                 bool is_event = mus &&
 605                         (scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
 606                                 != SCM_BOOL_F);
 607                 if (!is_event)
 608                         $$ = $1;
 609                 else
 610                         $$ = MAKE_SYNTAX ("event-chord", @$, scm_list_1 ($1));
 611         }
 612         | post_event {
 613                 $$ = $1;
 614         }
 615         | number_expression {
 616                 $$ = $1;
 617         }
 618         | string {
 619                 $$ = $1;
 620         }
 621         | embedded_scm {
 622                 $$ = $1;
 623         }
 624         | full_markup {
 625                 $$ = $1;
 626         }
 627         | DIGIT {
 628                 $$ = scm_from_int ($1);
 629         }
 630         ;
 631
 632 context_def_spec_block:
 633         CONTEXT '{' context_def_spec_body '}'
 634                 {
 635                 $$ = $3;
 636         }
 637         ;
 638
 639 context_def_spec_body:
 640         /**/ {
 641                 $$ = Context_def::make_scm ();
 642                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 643         }
 644         | CONTEXT_DEF_IDENTIFIER {
 645                 $$ = $1;
 646                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 647         }
 648         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 649                 Context_def*td = unsmob_context_def ($$);
 650
 651                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 652                         SCM tag = scm_caar (p);
 653
 654                         /* TODO: should make new tag "grob-definition" ? */
 655                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 656                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 657                 }
 658         }
 659         | context_def_spec_body context_mod {
 660                 unsmob_context_def ($$)->add_context_mod ($2);
 661         }
 662         ;
 663
 664
 665
 666 book_block:
 667         BOOK '{' book_body '}'  {
 668                 $$ = $3;
 669                 pop_paper (PARSER);
 670                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 671         }
 672         ;
 673
 674 /* FIXME:
 675    * Use 'handlers' like for toplevel-* stuff?
 676    * grok \layout and \midi?  */
 677 book_body:
 678         {
 679                 $$ = new Book;
 680                 init_papers (PARSER);
 681                 $$->origin ()->set_spot (@$);
 682                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (PARSER->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 683                 $$->paper_->unprotect ();
 684                 push_paper (PARSER, $$->paper_);
 685                 $$->header_ = PARSER->lexer_->lookup_identifier ("$defaultheader");
 686                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$->self_scm ());
 687                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-output-suffix"), SCM_BOOL_F);
 688                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-filename"), SCM_BOOL_F);
 689         }
 690         | BOOK_IDENTIFIER {
 691                 $$ = unsmob_book ($1);
 692                 $$->protect ();
 693                 $$->origin ()->set_spot (@$);
 694                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 695         }
 696         | book_body paper_block {
 697                 $$->paper_ = $2;
 698                 $2->unprotect ();
 699                 set_paper (PARSER, $2);
 700         }
 701         | book_body bookpart_block {
 702                 Book *bookpart = $2;
 703                 SCM proc = PARSER->lexer_->lookup_identifier ("book-bookpart-handler");
 704                 scm_call_2 (proc, $$->self_scm (), bookpart->self_scm ());
 705                 bookpart->unprotect ();
 706         }
 707         | book_body score_block {
 708                 Score *score = $2;
 709                 SCM proc = PARSER->lexer_->lookup_identifier ("book-score-handler");
 710                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 711                 score->unprotect ();
 712         }
 713         | book_body composite_music {
 714                 Music *music = unsmob_music ($2);
 715                 SCM proc = PARSER->lexer_->lookup_identifier ("book-music-handler");
 716                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 717         }
 718         | book_body full_markup {
 719                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 720                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 721         }
 722         | book_body full_markup_list {
 723                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 724                 scm_call_2 (proc, $$->self_scm (), $2);
 725         }
 726         | book_body lilypond_header {
 727                 $$->header_ = $2;
 728         }
 729         | book_body error {
 730                 $$->paper_ = 0;
 731                 $$->scores_ = SCM_EOL;
 732                 $$->bookparts_ = SCM_EOL;
 733         }
 734         | book_body object_id_setting {
 735                 $$->user_key_ = ly_scm2string ($2);
 736         }
 737         ;
 738
 739 bookpart_block:
 740         BOOKPART '{' bookpart_body '}' {
 741                 $$ = $3;
 742                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 743         }
 744         ;
 745
 746 bookpart_body:
 747         {
 748                 $$ = new Book;
 749                 $$->origin ()->set_spot (@$);
 750                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$->self_scm ());
 751         }
 752         | BOOK_IDENTIFIER {
 753                 $$ = unsmob_book ($1);
 754                 $$->protect ();
 755                 $$->origin ()->set_spot (@$);
 756                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 757         }
 758         | bookpart_body paper_block {
 759                 $$->paper_ = $2;
 760                 $2->unprotect ();
 761         }
 762         | bookpart_body score_block {
 763                 Score *score = $2;
 764                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-score-handler");
 765                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 766                 score->unprotect ();
 767         }
 768         | bookpart_body composite_music {
 769                 Music *music = unsmob_music ($2);
 770                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-music-handler");
 771                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 772         }
 773         | bookpart_body full_markup {
 774                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 775                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 776         }
 777         | bookpart_body full_markup_list {
 778                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 779                 scm_call_2 (proc, $$->self_scm (), $2);
 780         }
 781         | bookpart_body lilypond_header {
 782                 $$->header_ = $2;
 783         }
 784         | bookpart_body error {
 785                 $$->paper_ = 0;
 786                 $$->scores_ = SCM_EOL;
 787         }
 788         | bookpart_body object_id_setting {
 789                 $$->user_key_ = ly_scm2string ($2);
 790         }
 791         ;
 792
 793 score_block:
 794         SCORE '{' score_body '}'        {
 795                 $$ = $3;
 796         }
 797         ;
 798
 799 score_body:
 800         music {
 801                 SCM m = $1;
 802                 SCM scorify = ly_lily_module_constant ("scorify-music");
 803                 SCM score = scm_call_2 (scorify, m, PARSER->self_scm ());
 804
 805                 // pass ownernship to C++ again.
 806                 $$ = unsmob_score (score);
 807                 $$->protect ();
 808                 $$->origin ()->set_spot (@$);
 809         }
 810         | SCORE_IDENTIFIER {
 811                 $$ = unsmob_score ($1);
 812                 $$->protect ();
 813                 $$->origin ()->set_spot (@$);
 814         }
 815         | score_body object_id_setting {
 816                 $$->user_key_ = ly_scm2string ($2);
 817         }
 818         | score_body lilypond_header    {
 819                 $$->set_header ($2);
 820         }
 821         | score_body output_def {
 822                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 823                 {
 824                         PARSER->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 825
 826                 }
 827                 else
 828                 {
 829                         $$->add_output_def ($2);
 830                 }
 831                 $2->unprotect ();
 832         }
 833         | score_body error {
 834                 $$->error_found_ = true;
 835         }
 836         ;
 837
 838
 839 /*
 840         OUTPUT DEF
 841 */
 842
 843 paper_block:
 844         output_def {
 845                 $$ = $1;
 846                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 847                 {
 848                         PARSER->parser_error (@1, _ ("need \\paper for paper block"));
 849                         $1->unprotect ();
 850                         $$ = get_paper (PARSER);
 851                 }
 852         }
 853         ;
 854
 855
 856 output_def:
 857         output_def_body '}' {
 858                 $$ = $1;
 859
 860                 PARSER->lexer_->remove_scope ();
 861                 PARSER->lexer_->pop_state ();
 862         }
 863         ;
 864
 865 output_def_head:
 866         PAPER {
 867                 $$ = get_paper (PARSER);
 868                 $$->input_origin_ = @$;
 869                 PARSER->lexer_->add_scope ($$->scope_);
 870         }
 871         | MIDI    {
 872                 Output_def *p = get_midi (PARSER);
 873                 $$ = p;
 874                 PARSER->lexer_->add_scope (p->scope_);
 875         }
 876         | LAYOUT        {
 877                 Output_def *p = get_layout (PARSER);
 878
 879                 PARSER->lexer_->add_scope (p->scope_);
 880                 $$ = p;
 881         }
 882         ;
 883
 884 output_def_head_with_mode_switch:
 885         output_def_head {
 886                 PARSER->lexer_->push_initial_state ();
 887                 $$ = $1;
 888         }
 889         ;
 890
 891 output_def_body:
 892         output_def_head_with_mode_switch '{' {
 893                 $$ = $1;
 894                 $$->input_origin_.set_spot (@$);
 895         }
 896         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 897                 $1->unprotect ();
 898
 899                 Output_def *o = unsmob_output_def ($3);
 900                 o->input_origin_.set_spot (@$);
 901                 $$ = o;
 902                 $$->protect ();
 903                 PARSER->lexer_->remove_scope ();
 904                 PARSER->lexer_->add_scope (o->scope_);
 905         }
 906         | output_def_body assignment  {
 907
 908         }
 909         | output_def_body context_def_spec_block        {
 910                 assign_context_def ($$, $2);
 911         }
 912         | output_def_body error {
 913
 914         }
 915         ;
 916
 917 tempo_event:
 918         TEMPO steno_duration '=' bare_unsigned  {
 919                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_BOOL_F, $2, scm_int2num ($4));
 920         }
 921         | TEMPO string steno_duration '=' bare_unsigned {
 922                 $$ = MAKE_SYNTAX ("tempo", @$, make_simple_markup($2), $3, scm_int2num ($5));
 923         }
 924         | TEMPO full_markup steno_duration '=' bare_unsigned    {
 925                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, scm_int2num ($5));
 926         }
 927         | TEMPO string {
 928                 $$ = MAKE_SYNTAX ("tempoText", @$, make_simple_markup($2) );
 929         }
 930         | TEMPO full_markup {
 931                 $$ = MAKE_SYNTAX ("tempoText", @$, $2 );
 932         }
 933         ;
 934
 935 /*
 936 The representation of a  list is the
 937
 938   (LIST . LAST-CONS)
 939
 940  to have efficient append.  */
 941
 942 music_list:
 943         /* empty */ {
 944                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 945         }
 946         | music_list music {
 947                 SCM s = $$;
 948                 SCM c = scm_cons ($2, SCM_EOL);
 949
 950                 if (scm_is_pair (scm_cdr (s)))
 951                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 952                 else
 953                         scm_set_car_x (s, c); /* set first cons */
 954                 scm_set_cdr_x (s, c);  /* remember last cell */
 955         }
 956         | music_list embedded_scm {
 957
 958         }
 959         | music_list error {
 960                 Music *m = MY_MAKE_MUSIC("Music", @$);
 961                 // ugh. code dup
 962                 m->set_property ("error-found", SCM_BOOL_T);
 963                 SCM s = $$;
 964                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 965                 m->unprotect (); /* UGH */
 966
 967                 if (scm_is_pair (scm_cdr (s)))
 968                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 969                 else
 970                         scm_set_car_x (s, c); /* set first cons */
 971                 scm_set_cdr_x (s, c);  /* remember last cell */
 972         }
 973         ;
 974
 975 music:
 976         simple_music
 977         | composite_music
 978         ;
 979
 980 alternative_music:
 981         /* empty */ {
 982                 $$ = SCM_EOL;
 983         }
 984         | ALTERNATIVE '{' music_list '}' {
 985                 $$ = scm_car ($3);
 986         }
 987         ;
 988
 989
 990 repeated_music:
 991         REPEAT simple_string unsigned_number music alternative_music
 992         {
 993                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $5);
 994         }
 995         ;
 996
 997 sequential_music:
 998         SEQUENTIAL '{' music_list '}'           {
 999                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($3));
1000         }
1001         | '{' music_list '}'            {
1002                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($2));
1003         }
1004         ;
1005
1006 simultaneous_music:
1007         SIMULTANEOUS '{' music_list '}'{
1008                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($3));
1009         }
1010         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1011                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($2));
1012         }
1013         ;
1014
1015 simple_music:
1016         event_chord
1017         | MUSIC_IDENTIFIER
1018         | music_property_def
1019         | context_change
1020         ;
1021
1022 optional_context_mod:
1023         /**/ { $$ = SCM_EOL; }
1024         | WITH { PARSER->lexer_->push_initial_state (); }
1025         '{' context_mod_list '}'
1026         {
1027                 PARSER->lexer_->pop_state ();
1028                 $$ = $4;
1029         }
1030         ;
1031
1032 context_mod_list:
1033         /* */  { $$ = SCM_EOL; }
1034         | context_mod_list context_mod  {
1035                  $$ = scm_cons ($2, $1);
1036         }
1037         ;
1038
1039 composite_music:
1040         prefix_composite_music { $$ = $1; }
1041         | grouped_music_list { $$ = $1; }
1042         ;
1043
1044 grouped_music_list:
1045         simultaneous_music              { $$ = $1; }
1046         | sequential_music              { $$ = $1; }
1047         ;
1048
1049 function_scm_argument:
1050         embedded_scm
1051         | simple_string
1052         ;
1053
1054 /* An argument list. If a function \foo expects scm scm music, then the lexer expands \foo into the token sequence:
1055  MUSIC_FUNCTION EXPECT_MUSIC EXPECT_SCM EXPECT_SCM
1056 and this rule returns the reversed list of arguments. */
1057
1058 function_arglist_music_last:
1059         EXPECT_MUSIC function_arglist music {
1060                 $$ = scm_cons ($3, $2);
1061         }
1062         ;
1063
1064 function_arglist_nonmusic_last:
1065         EXPECT_MARKUP function_arglist full_markup {
1066                 $$ = scm_cons ($3, $2);
1067         }
1068         | EXPECT_MARKUP function_arglist simple_string {
1069                 $$ = scm_cons ($3, $2);
1070         }
1071         | EXPECT_SCM function_arglist function_scm_argument {
1072                 $$ = scm_cons ($3, $2);
1073         }
1074         ;
1075
1076 function_arglist_nonmusic: EXPECT_NO_MORE_ARGS {
1077                 $$ = SCM_EOL;
1078         }
1079         | EXPECT_MARKUP function_arglist_nonmusic full_markup {
1080                 $$ = scm_cons ($3, $2);
1081         }
1082         | EXPECT_MARKUP function_arglist_nonmusic simple_string {
1083                 $$ = scm_cons ($3, $2);
1084         }
1085         | EXPECT_SCM function_arglist_nonmusic function_scm_argument {
1086                 $$ = scm_cons ($3, $2);
1087         }
1088         ;
1089
1090 function_arglist: EXPECT_NO_MORE_ARGS {
1091                 /* This is for 0-ary functions, so they don't need to
1092                    read a lookahead token */
1093                 $$ = SCM_EOL;
1094         }
1095         | function_arglist_music_last
1096         | function_arglist_nonmusic_last
1097         ;
1098
1099 generic_prefix_music_scm:
1100         MUSIC_FUNCTION function_arglist {
1101                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
1102         }
1103         ;
1104
1105
1106 optional_id:
1107         /**/ { $$ = SCM_EOL; }
1108         | '=' simple_string {
1109                 $$ = $2;
1110         }
1111         ;
1112
1113
1114 prefix_composite_music:
1115         generic_prefix_music_scm {
1116                 $$ = run_music_function (PARSER, $1);
1117         }
1118         | CONTEXT simple_string optional_id optional_context_mod music {
1119                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, $4, SCM_BOOL_F);
1120         }
1121         | NEWCONTEXT simple_string optional_id optional_context_mod music {
1122                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, $4, SCM_BOOL_T);
1123         }
1124
1125         | TIMES fraction music {
1126                 $$ = MAKE_SYNTAX ("time-scaled-music", @$, $2, $3);
1127         }
1128         | repeated_music                { $$ = $1; }
1129         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords music {
1130                 Pitch from = *unsmob_pitch ($2);
1131                 Pitch to = *unsmob_pitch ($3);
1132                 SCM pitch = pitch_interval (from, to).smobbed_copy ();
1133                 $$ = MAKE_SYNTAX ("transpose-music", @$, pitch, $4);
1134         }
1135         | mode_changing_head grouped_music_list {
1136                 if ($1 == ly_symbol2scm ("chords"))
1137                 {
1138                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
1139                 }
1140                 else
1141                 {
1142                   $$ = $2;
1143                 }
1144                 PARSER->lexer_->pop_state ();
1145         }
1146         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1147                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, $3, $2, SCM_BOOL_T);
1148                 if ($1 == ly_symbol2scm ("ChordNames"))
1149                 {
1150                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1151                 }
1152                 PARSER->lexer_->pop_state ();
1153         }
1154         | relative_music        { $$ = $1; }
1155         | re_rhythmed_music     { $$ = $1; }
1156         ;
1157
1158 mode_changing_head:
1159         NOTEMODE {
1160                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1161                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1162
1163                 $$ = ly_symbol2scm ("notes");
1164         }
1165         | DRUMMODE
1166                 {
1167                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1168                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1169
1170                 $$ = ly_symbol2scm ("drums");
1171         }
1172         | FIGUREMODE {
1173                 PARSER->lexer_->push_figuredbass_state ();
1174
1175                 $$ = ly_symbol2scm ("figures");
1176         }
1177         | CHORDMODE {
1178                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1179                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1180                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1181                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1182                 $$ = ly_symbol2scm ("chords");
1183
1184         }
1185         | LYRICMODE
1186                 { PARSER->lexer_->push_lyric_state ();
1187                 $$ = ly_symbol2scm ("lyrics");
1188         }
1189         ;
1190
1191 mode_changing_head_with_context:
1192         DRUMS {
1193                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1194                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1195
1196                 $$ = ly_symbol2scm ("DrumStaff");
1197         }
1198         | FIGURES {
1199                 PARSER->lexer_->push_figuredbass_state ();
1200
1201                 $$ = ly_symbol2scm ("FiguredBass");
1202         }
1203         | CHORDS {
1204                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1205                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1206                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1207                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1208                 $$ = ly_symbol2scm ("ChordNames");
1209         }
1210         | LYRICS
1211                 { PARSER->lexer_->push_lyric_state ();
1212                 $$ = ly_symbol2scm ("Lyrics");
1213         }
1214         ;
1215
1216
1217 relative_music:
1218         RELATIVE absolute_pitch music {
1219                 Pitch start = *unsmob_pitch ($2);
1220                 $$ = make_music_relative (start, $3, @$);
1221         }
1222         | RELATIVE composite_music {
1223                 Pitch middle_c (0, 0, 0);
1224                 $$ = make_music_relative (middle_c, $2, @$);
1225         }
1226         ;
1227
1228 new_lyrics:
1229         ADDLYRICS { PARSER->lexer_->push_lyric_state (); }
1230         /*cont */
1231         grouped_music_list {
1232         /* Can also use music at the expensive of two S/Rs similar to
1233            \repeat \alternative */
1234                 PARSER->lexer_->pop_state ();
1235
1236                 $$ = scm_cons ($3, SCM_EOL);
1237         }
1238         | new_lyrics ADDLYRICS {
1239                 PARSER->lexer_->push_lyric_state ();
1240         } grouped_music_list {
1241                 PARSER->lexer_->pop_state ();
1242                 $$ = scm_cons ($4, $1);
1243         }
1244         ;
1245
1246 re_rhythmed_music:
1247         grouped_music_list new_lyrics {
1248                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1249         }
1250         | LYRICSTO simple_string {
1251                 PARSER->lexer_->push_lyric_state ();
1252         } music {
1253                 PARSER->lexer_->pop_state ();
1254                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
1255         }
1256         ;
1257
1258 context_change:
1259         CHANGE STRING '=' STRING  {
1260                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
1261         }
1262         ;
1263
1264
1265 property_path_revved:
1266         embedded_scm {
1267                 $$ = scm_cons ($1, SCM_EOL);
1268         }
1269         | property_path_revved embedded_scm {
1270                 $$ = scm_cons ($2, $1);
1271         }
1272         ;
1273
1274 property_path:
1275         property_path_revved  {
1276                 $$ = scm_reverse_x ($1, SCM_EOL);
1277         }
1278         ;
1279
1280 property_operation:
1281         STRING '=' scalar {
1282                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1283                         scm_string_to_symbol ($1), $3);
1284         }
1285         | UNSET simple_string {
1286                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1287                         scm_string_to_symbol ($2));
1288         }
1289         | OVERRIDE simple_string property_path '=' scalar {
1290                 $$ = scm_append (scm_list_2 (scm_list_3 (ly_symbol2scm ("push"),
1291                                                         scm_string_to_symbol ($2), $5),
1292                                              $3));
1293         }
1294         | REVERT simple_string embedded_scm {
1295                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1296                         scm_string_to_symbol ($2), $3);
1297         }
1298         ;
1299
1300 context_def_mod:
1301         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1302         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1303
1304         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1305         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1306         | DENIES { $$ = ly_symbol2scm ("denies"); }
1307
1308         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1309         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1310         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1311         | NAME { $$ = ly_symbol2scm ("context-name"); }
1312         ;
1313
1314 context_mod:
1315         property_operation { $$ = $1; }
1316         | context_def_mod STRING {
1317                 $$ = scm_list_2 ($1, $2);
1318         }
1319         ;
1320
1321 context_prop_spec:
1322         simple_string {
1323                 if (!is_regular_identifier ($1))
1324                 {
1325                         @$.error (_("Grob name should be alphanumeric"));
1326                 }
1327
1328                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1329                         scm_string_to_symbol ($1));
1330         }
1331         | simple_string '.' simple_string {
1332                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1333                         scm_string_to_symbol ($3));
1334         }
1335         ;
1336
1337 simple_music_property_def:
1338         OVERRIDE context_prop_spec property_path '=' scalar {
1339                 $$ = scm_append (scm_list_2 (scm_list_n (scm_car ($2),
1340                                 ly_symbol2scm ("OverrideProperty"),
1341                                 scm_cadr ($2),
1342                                 $5, SCM_UNDEFINED),
1343                                 $3));
1344         }
1345         | REVERT context_prop_spec embedded_scm {
1346                 $$ = scm_list_4 (scm_car ($2),
1347                         ly_symbol2scm ("RevertProperty"),
1348                         scm_cadr ($2),
1349                         $3);
1350         }
1351         | SET context_prop_spec '=' scalar {
1352                 $$ = scm_list_4 (scm_car ($2),
1353                         ly_symbol2scm ("PropertySet"),
1354                         scm_cadr ($2),
1355                         $4);
1356         }
1357         | UNSET context_prop_spec {
1358                 $$ = scm_list_3 (scm_car ($2),
1359                         ly_symbol2scm ("PropertyUnset"),
1360                         scm_cadr ($2));
1361         }
1362         ;
1363
1364 music_property_def:
1365         simple_music_property_def {
1366                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_F, $1)));
1367         }
1368         | ONCE simple_music_property_def {
1369                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_T, $2)));
1370         }
1371         ;
1372
1373 string:
1374         STRING {
1375                 $$ = $1;
1376         }
1377         | STRING_IDENTIFIER {
1378                 $$ = $1;
1379         }
1380         | string '+' string {
1381                 $$ = scm_string_append (scm_list_2 ($1, $3));
1382         }
1383         ;
1384
1385 simple_string: STRING {
1386                 $$ = $1;
1387         }
1388         | LYRICS_STRING {
1389                 $$ = $1;
1390         }
1391         | STRING_IDENTIFIER {
1392                 $$ = $1;
1393         }
1394         ;
1395
1396 scalar: string {
1397                 $$ = $1;
1398         }
1399         | LYRICS_STRING {
1400                 $$ = $1;
1401         }
1402         | bare_number {
1403                 $$ = $1;
1404         }
1405         | embedded_scm {
1406                 $$ = $1;
1407         }
1408         | full_markup {
1409                 $$ = $1;
1410         }
1411         | DIGIT {
1412                 $$ = scm_from_int ($1);
1413         }
1414         ;
1415
1416 event_chord:
1417         /* TODO: Create a special case that avoids the creation of
1418            EventChords around simple_elements that have no post_events?
1419          */
1420         /* event_chords like simple notes, note chords, etc, are
1421            saved into PARSER->lexer_->chord_repetition_ so that
1422            the chord repetition mechanism can copy them when a
1423            chord repetition symbol is found
1424         */
1425         simple_chord_elements post_events       {
1426                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
1427
1428                 Input i;
1429                 /* why is this giving wrong start location? -ns
1430                  * i = @$; */
1431                 i.set_location (@1, @2);
1432                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
1433                 PARSER->lexer_->chord_repetition_.last_chord_ = $$;
1434         }
1435         | CHORD_REPETITION optional_notemode_duration post_events {
1436                 Input i;
1437                 i.set_location (@1, @3);
1438                 $$ = MAKE_SYNTAX ("repetition-chord", i,
1439                                   PARSER->lexer_->chord_repetition_.last_chord_,
1440                                   PARSER->lexer_->chord_repetition_.repetition_function_,
1441                                   $2, $3);
1442         }
1443         | MULTI_MEASURE_REST optional_notemode_duration post_events {
1444                 Input i;
1445                 i.set_location (@1, @3);
1446                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2, $3);
1447         }
1448         | command_element
1449         | note_chord_element    {
1450                 PARSER->lexer_->chord_repetition_.last_chord_ = $$;
1451         }
1452         ;
1453
1454
1455 note_chord_element:
1456         chord_body optional_notemode_duration post_events
1457         {
1458                 Music *m = unsmob_music ($1);
1459                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1460                 SCM es = m->get_property ("elements");
1461                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1462
1463                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1464                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1465                 es = ly_append2 (es, postevs);
1466
1467                 m-> set_property ("elements", es);
1468                 m->set_spot (@$);
1469                 $$ = m->self_scm ();
1470         }
1471         ;
1472
1473 chord_body:
1474         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
1475         {
1476                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
1477         }
1478         ;
1479
1480 chord_body_elements:
1481         /* empty */             { $$ = SCM_EOL; }
1482         | chord_body_elements chord_body_element {
1483                 $$ = scm_cons ($2, $1);
1484         }
1485         ;
1486
1487 chord_body_element:
1488         pitch exclamations questions octave_check post_events
1489         {
1490                 int q = $3;
1491                 int ex = $2;
1492                 SCM check = $4;
1493                 SCM post = $5;
1494
1495                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1496                 n->set_property ("pitch", $1);
1497                 if (q % 2)
1498                         n->set_property ("cautionary", SCM_BOOL_T);
1499                 if (ex % 2 || q % 2)
1500                         n->set_property ("force-accidental", SCM_BOOL_T);
1501
1502                 if (scm_is_pair (post)) {
1503                         SCM arts = scm_reverse_x (post, SCM_EOL);
1504                         n->set_property ("articulations", arts);
1505                 }
1506                 if (scm_is_number (check))
1507                 {
1508                         int q = scm_to_int (check);
1509                         n->set_property ("absolute-octave", scm_from_int (q-1));
1510                 }
1511
1512                 $$ = n->unprotect ();
1513         }
1514         | DRUM_PITCH post_events {
1515                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1516                 n->set_property ("duration", $2);
1517                 n->set_property ("drum-type", $1);
1518
1519                 if (scm_is_pair ($2)) {
1520                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1521                         n->set_property ("articulations", arts);
1522                 }
1523                 $$ = n->unprotect ();
1524         }
1525         | music_function_chord_body {
1526                 $$ = run_music_function (PARSER, $1);
1527         }
1528         ;
1529
1530 music_function_identifier_musicless_prefix: MUSIC_FUNCTION {
1531                 SCM sig = scm_object_property (yylval.scm, ly_symbol2scm ("music-function-signature"));
1532                 if (scm_is_pair (sig) && to_boolean (scm_memq (ly_music_p_proc, scm_cdr (scm_reverse (sig)))))
1533                 {
1534                         PARSER->parser_error (@$, "Music function applied to event may not have a Music argument, except as the last argument.");
1535                 }
1536         }
1537         ;
1538
1539 music_function_chord_body:
1540         /* We could allow chord functions to have multiple music arguments,
1541            but it's more consistent with music_function_event if we
1542            prohibit it here too */
1543         music_function_identifier_musicless_prefix EXPECT_MUSIC function_arglist_nonmusic chord_body_element {
1544                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($3, scm_list_1 ($4)));
1545         }
1546         | music_function_identifier_musicless_prefix function_arglist_nonmusic {
1547                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
1548         }
1549         ;
1550
1551 music_function_event:
1552         /* Post-events can only have the last argument as music, without this
1553            restriction we get a shift/reduce conflict from e.g.
1554            c8-\partcombine c8 -. */
1555         music_function_identifier_musicless_prefix EXPECT_MUSIC function_arglist_nonmusic post_event {
1556                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($3, scm_list_1 ($4)));
1557         }
1558         | music_function_identifier_musicless_prefix function_arglist_nonmusic {
1559                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
1560         }
1561         ;
1562
1563 command_element:
1564         command_event {
1565                 $$ = $1;
1566         }
1567         | SKIP duration_length {
1568                 $$ = MAKE_SYNTAX ("skip-music", @$, $2);
1569         }
1570         | E_BRACKET_OPEN {
1571                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1572                 m->set_property ("span-direction", scm_from_int (START));
1573                 $$ = m->unprotect();
1574         }
1575         | E_BRACKET_CLOSE {
1576                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1577                 m->set_property ("span-direction", scm_from_int (STOP));
1578                 $$ = m->unprotect ();
1579         }
1580         | E_BACKSLASH {
1581                 $$ = MAKE_SYNTAX ("voice-separator", @$, SCM_UNDEFINED);
1582         }
1583         | '|'      {
1584                 SCM pipe = PARSER->lexer_->lookup_identifier ("pipeSymbol");
1585
1586                 Music *m = unsmob_music (pipe);
1587                 if (m)
1588                 {
1589                         m = m->clone ();
1590                         m->set_spot (@$);
1591                         $$ = m->unprotect ();
1592                 }
1593                 else
1594                         $$ = MAKE_SYNTAX ("bar-check", @$, SCM_UNDEFINED);
1595
1596         }
1597         | PARTIAL duration_length       {
1598                 Moment m = - unsmob_duration ($2)->get_length ();
1599                 $$ = MAKE_SYNTAX ("property-operation", @$, SCM_BOOL_F, ly_symbol2scm ("Timing"), ly_symbol2scm ("PropertySet"), ly_symbol2scm ("measurePosition"), m.smobbed_copy ());
1600                 $$ = MAKE_SYNTAX ("context-specification", @$, ly_symbol2scm ("Score"), SCM_BOOL_F, $$, SCM_EOL, SCM_BOOL_F);
1601         }
1602
1603         | TIME_T fraction  {
1604                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1605
1606                 $$ = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1607         }
1608         | MARK scalar {
1609                 SCM proc = ly_lily_module_constant ("make-mark-set");
1610
1611                 $$ = scm_call_1 (proc, $2);
1612         }
1613         ;
1614
1615 command_event:
1616         E_TILDE {
1617                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent", @$)->unprotect ();
1618         }
1619         | MARK DEFAULT  {
1620                 Music *m = MY_MAKE_MUSIC ("MarkEvent", @$);
1621                 $$ = m->unprotect ();
1622         }
1623         | tempo_event {
1624                 $$ = $1;
1625         }
1626         | KEY DEFAULT {
1627                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1628                 $$ = key->unprotect ();
1629         }
1630         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1631
1632                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1633                 if (scm_ilength ($3) > 0)
1634                 {
1635                         key->set_property ("pitch-alist", $3);
1636                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1637                         key->transpose (* unsmob_pitch ($2));
1638                 } else {
1639                         PARSER->parser_error (@3, _ ("second argument must be pitch list"));
1640                 }
1641
1642                 $$ = key->unprotect ();
1643         }
1644         ;
1645
1646
1647 post_events:
1648         /* empty */ {
1649                 $$ = SCM_EOL;
1650         }
1651         | post_events post_event {
1652                 unsmob_music ($2)->set_spot (@2);
1653                 $$ = scm_cons ($2, $$);
1654         }
1655         ;
1656
1657 post_event:
1658         direction_less_event {
1659                 $$ = $1;
1660         }
1661         | '-' music_function_event {
1662                 $$ = run_music_function (PARSER, $2);
1663         }
1664         | HYPHEN {
1665                 if (!PARSER->lexer_->is_lyric_state ())
1666                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1667                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
1668         }
1669         | EXTENDER {
1670                 if (!PARSER->lexer_->is_lyric_state ())
1671                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1672                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
1673         }
1674         | script_dir direction_reqd_event {
1675                 if ($1)
1676                 {
1677                         Music *m = unsmob_music ($2);
1678                         m->set_property ("direction", scm_from_int ($1));
1679                 }
1680                 $$ = $2;
1681         }
1682         | script_dir direction_less_event {
1683                 if ($1)
1684                 {
1685                         Music *m = unsmob_music ($2);
1686                         m->set_property ("direction", scm_from_int ($1));
1687                 }
1688                 $$ = $2;
1689         }
1690         | string_number_event
1691         ;
1692
1693 string_number_event:
1694         E_UNSIGNED {
1695                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
1696                 s->set_property ("string-number", scm_from_int ($1));
1697                 $$ = s->unprotect ();
1698         }
1699         ;
1700
1701 direction_less_char:
1702         '['  {
1703                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1704         }
1705         | ']'  {
1706                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1707         }
1708         | '~'  {
1709                 $$ = ly_symbol2scm ("tildeSymbol");
1710         }
1711         | '('  {
1712                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1713         }
1714         | ')'  {
1715                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1716         }
1717         | E_EXCLAMATION  {
1718                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1719         }
1720         | E_OPEN  {
1721                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1722         }
1723         | E_CLOSE  {
1724                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1725         }
1726         | E_ANGLE_CLOSE  {
1727                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1728         }
1729         | E_ANGLE_OPEN  {
1730                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1731         }
1732         ;
1733
1734 direction_less_event:
1735         direction_less_char {
1736                 SCM predefd = PARSER->lexer_->lookup_identifier_symbol ($1);
1737                 Music *m = 0;
1738                 if (unsmob_music (predefd))
1739                 {
1740                         m = unsmob_music (predefd)->clone ();
1741                         m->set_spot (@$);
1742                 }
1743                 else
1744                 {
1745                         m = MY_MAKE_MUSIC ("Music", @$);
1746                 }
1747                 $$ = m->unprotect ();
1748         }
1749         | EVENT_IDENTIFIER      {
1750                 $$ = $1;
1751         }
1752         | tremolo_type  {
1753                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
1754                a->set_property ("tremolo-type", scm_from_int ($1));
1755                $$ = a->unprotect ();
1756         }
1757         ;
1758
1759 direction_reqd_event:
1760         gen_text_def {
1761                 $$ = $1;
1762         }
1763         | script_abbreviation {
1764                 SCM s = PARSER->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1765                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
1766                 if (scm_is_string (s))
1767                         a->set_property ("articulation-type", s);
1768                 else PARSER->parser_error (@1, _ ("expecting string as script definition"));
1769                 $$ = a->unprotect ();
1770         }
1771         ;
1772
1773 octave_check:
1774         /**/ { $$ = SCM_EOL; }
1775         | '='  { $$ = scm_from_int (0); }
1776         | '=' sub_quotes { $$ = scm_from_int (-$2); }
1777         | '=' sup_quotes { $$ = scm_from_int ($2); }
1778         ;
1779
1780 sup_quotes:
1781         '\'' {
1782                 $$ = 1;
1783         }
1784         | sup_quotes '\'' {
1785                 $$ ++;
1786         }
1787         ;
1788
1789 sub_quotes:
1790         ',' {
1791                 $$ = 1;
1792         }
1793         | sub_quotes ',' {
1794                 $$++;
1795         }
1796         ;
1797
1798 steno_pitch:
1799         NOTENAME_PITCH  {
1800                 $$ = $1;
1801         }
1802         | NOTENAME_PITCH sup_quotes     {
1803                 Pitch p = *unsmob_pitch ($1);
1804                 p = p.transposed (Pitch ($2,0,0));
1805                 $$ = p.smobbed_copy ();
1806         }
1807         | NOTENAME_PITCH sub_quotes      {
1808                 Pitch p =* unsmob_pitch ($1);
1809                 p = p.transposed (Pitch (-$2,0,0));
1810                 $$ = p.smobbed_copy ();
1811         }
1812         ;
1813
1814 /*
1815 ugh. duplication
1816 */
1817
1818 steno_tonic_pitch:
1819         TONICNAME_PITCH {
1820                 $$ = $1;
1821         }
1822         | TONICNAME_PITCH sup_quotes    {
1823                 Pitch p = *unsmob_pitch ($1);
1824                 p = p.transposed (Pitch ($2,0,0));
1825                 $$ = p.smobbed_copy ();
1826         }
1827         | TONICNAME_PITCH sub_quotes     {
1828                 Pitch p = *unsmob_pitch ($1);
1829
1830                 p = p.transposed (Pitch (-$2,0,0));
1831                 $$ = p.smobbed_copy ();
1832         }
1833         ;
1834
1835 pitch:
1836         steno_pitch {
1837                 $$ = $1;
1838         }
1839         ;
1840
1841 pitch_also_in_chords:
1842         pitch
1843         | steno_tonic_pitch
1844         ;
1845
1846 gen_text_def:
1847         full_markup {
1848                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
1849                 t->set_property ("text", $1);
1850                 $$ = t->unprotect ();
1851         }
1852         | string {
1853                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
1854                 t->set_property ("text",
1855                         make_simple_markup ($1));
1856                 $$ = t->unprotect ();
1857         }
1858         | DIGIT {
1859                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
1860                 t->set_property ("digit", scm_from_int ($1));
1861                 $$ = t->unprotect ();
1862         }
1863         ;
1864
1865 script_abbreviation:
1866         '^'             {
1867                 $$ = scm_from_locale_string ("Hat");
1868         }
1869         | '+'           {
1870                 $$ = scm_from_locale_string ("Plus");
1871         }
1872         | '-'           {
1873                 $$ = scm_from_locale_string ("Dash");
1874         }
1875         | '|'           {
1876                 $$ = scm_from_locale_string ("Bar");
1877         }
1878         | ANGLE_CLOSE   {
1879                 $$ = scm_from_locale_string ("Larger");
1880         }
1881         | '.'           {
1882                 $$ = scm_from_locale_string ("Dot");
1883         }
1884         | '_' {
1885                 $$ = scm_from_locale_string ("Underscore");
1886         }
1887         ;
1888
1889 script_dir:
1890         '_'     { $$ = DOWN; }
1891         | '^'   { $$ = UP; }
1892         | '-'   { $$ = CENTER; }
1893         ;
1894
1895
1896 absolute_pitch:
1897         steno_pitch     {
1898                 $$ = $1;
1899         }
1900         ;
1901
1902 duration_length:
1903         multiplied_duration {
1904                 $$ = $1;
1905         }
1906         ;
1907
1908 optional_notemode_duration:
1909         {
1910                 Duration dd = PARSER->default_duration_;
1911                 $$ = dd.smobbed_copy ();
1912         }
1913         | multiplied_duration   {
1914                 $$ = $1;
1915                 PARSER->default_duration_ = *unsmob_duration ($$);
1916         }
1917         ;
1918
1919 steno_duration:
1920         bare_unsigned dots              {
1921                 int len = 0;
1922                 if (!is_duration ($1))
1923                         PARSER->parser_error (@1, _f ("not a duration: %d", $1));
1924                 else
1925                         len = intlog2 ($1);
1926
1927                 $$ = Duration (len, $2).smobbed_copy ();
1928         }
1929         | DURATION_IDENTIFIER dots      {
1930                 Duration *d = unsmob_duration ($1);
1931                 Duration k (d->duration_log (), d->dot_count () + $2);
1932                 *d = k;
1933                 $$ = $1;
1934         }
1935         ;
1936
1937 multiplied_duration:
1938         steno_duration {
1939                 $$ = $1;
1940         }
1941         | multiplied_duration '*' bare_unsigned {
1942                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1943         }
1944         | multiplied_duration '*' FRACTION {
1945                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
1946
1947                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1948         }
1949         ;
1950
1951 fraction:
1952         FRACTION { $$ = $1; }
1953         | UNSIGNED '/' UNSIGNED {
1954                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
1955         }
1956         ;
1957
1958 dots:
1959         /* empty */     {
1960                 $$ = 0;
1961         }
1962         | dots '.' {
1963                 $$ ++;
1964         }
1965         ;
1966
1967 tremolo_type:
1968         ':'     {
1969                 $$ = 0;
1970         }
1971         | ':' bare_unsigned {
1972                 if (!is_duration ($2))
1973                         PARSER->parser_error (@2, _f ("not a duration: %d", $2));
1974                 $$ = $2;
1975         }
1976         ;
1977
1978 bass_number:
1979         DIGIT   {
1980                 $$ = scm_from_int ($1);
1981         }
1982         | UNSIGNED {
1983                 $$ = scm_from_int ($1);
1984         }
1985         | STRING { $$ = $1; }
1986         | full_markup { $$ = $1; }
1987         ;
1988
1989 figured_bass_alteration:
1990         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
1991         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
1992         | '!'   { $$ = scm_from_int (0); }
1993         ;
1994
1995 bass_figure:
1996         FIGURE_SPACE {
1997                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
1998                 $$ = bfr->unprotect ();
1999         }
2000         | bass_number  {
2001                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2002                 $$ = bfr->self_scm ();
2003
2004                 if (scm_is_number ($1))
2005                         bfr->set_property ("figure", $1);
2006                 else if (Text_interface::is_markup ($1))
2007                         bfr->set_property ("text", $1);
2008
2009                 bfr->unprotect ();
2010         }
2011         | bass_figure ']' {
2012                 $$ = $1;
2013                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2014         }
2015         | bass_figure figured_bass_alteration {
2016                 Music *m = unsmob_music ($1);
2017                 if (scm_to_double ($2)) {
2018                         SCM salter = m->get_property ("alteration");
2019                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
2020                         m->set_property ("alteration",
2021                                          scm_sum (alter, $2));
2022                 } else {
2023                         m->set_property ("alteration", scm_from_int (0));
2024                 }
2025         }
2026         | bass_figure figured_bass_modification  {
2027                 Music *m = unsmob_music ($1);
2028                 if ($2 == ly_symbol2scm ("plus"))
2029                         {
2030                         m->set_property ("augmented", SCM_BOOL_T);
2031                         }
2032                 else if ($2 == ly_symbol2scm ("slash"))
2033                         {
2034                         m->set_property ("diminished", SCM_BOOL_T);
2035                         }
2036                 else if ($2 == ly_symbol2scm ("exclamation"))
2037                         {
2038                         m->set_property ("no-continuation", SCM_BOOL_T);
2039                         }
2040                 else if ($2 == ly_symbol2scm ("backslash"))
2041                         {
2042                         m->set_property ("augmented-slash", SCM_BOOL_T);
2043                         }
2044         }
2045         ;
2046
2047
2048 figured_bass_modification:
2049         E_PLUS          {
2050                 $$ = ly_symbol2scm ("plus");
2051         }
2052         | E_EXCLAMATION {
2053                 $$ = ly_symbol2scm ("exclamation");
2054         }
2055         | '/'           {
2056                 $$ = ly_symbol2scm ("slash");
2057         }
2058         | E_BACKSLASH {
2059                 $$ = ly_symbol2scm ("backslash");
2060         }
2061         ;
2062
2063 br_bass_figure:
2064         bass_figure {
2065                 $$ = $1;
2066         }
2067         | '[' bass_figure {
2068                 $$ = $2;
2069                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2070         }
2071         ;
2072
2073 figure_list:
2074         /**/            {
2075                 $$ = SCM_EOL;
2076         }
2077         | figure_list br_bass_figure {
2078                 $$ = scm_cons ($2, $1);
2079         }
2080         ;
2081
2082 figure_spec:
2083         FIGURE_OPEN figure_list FIGURE_CLOSE {
2084                 $$ = scm_reverse_x ($2, SCM_EOL);
2085         }
2086         ;
2087
2088
2089 optional_rest:
2090         /**/   { $$ = 0; }
2091         | REST { $$ = 1; }
2092         ;
2093
2094 simple_element:
2095         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2096                 if (!PARSER->lexer_->is_note_state ())
2097                         PARSER->parser_error (@1, _ ("have to be in Note mode for notes"));
2098
2099                 Music *n = 0;
2100                 if ($6)
2101                         n = MY_MAKE_MUSIC ("RestEvent", @$);
2102                 else
2103                         n = MY_MAKE_MUSIC ("NoteEvent", @$);
2104
2105                 n->set_property ("pitch", $1);
2106                 n->set_property ("duration", $5);
2107
2108                 if (scm_is_number ($4))
2109                 {
2110                         int q = scm_to_int ($4);
2111                         n->set_property ("absolute-octave", scm_from_int (q-1));
2112                 }
2113
2114                 if ($3 % 2)
2115                         n->set_property ("cautionary", SCM_BOOL_T);
2116                 if ($2 % 2 || $3 % 2)
2117                         n->set_property ("force-accidental", SCM_BOOL_T);
2118
2119                 $$ = n->unprotect ();
2120         }
2121         | DRUM_PITCH optional_notemode_duration {
2122                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2123                 n->set_property ("duration", $2);
2124                 n->set_property ("drum-type", $1);
2125
2126                 $$ = n->unprotect ();
2127         }
2128         | RESTNAME optional_notemode_duration           {
2129                 Music *ev = 0;
2130                 if (ly_scm2string ($1) == "s") {
2131                         /* Space */
2132                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
2133                   }
2134                 else {
2135                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
2136
2137                     }
2138                 ev->set_property ("duration", $2);
2139                 $$ = ev->unprotect ();
2140         }
2141         | lyric_element optional_notemode_duration      {
2142                 if (!PARSER->lexer_->is_lyric_state ())
2143                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2144
2145                 Music *levent = MY_MAKE_MUSIC ("LyricEvent", @$);
2146                 levent->set_property ("text", $1);
2147                 levent->set_property ("duration",$2);
2148                 $$= levent->unprotect ();
2149         }
2150         ;
2151
2152 simple_chord_elements:
2153         simple_element  {
2154                 $$ = scm_list_1 ($1);
2155         }
2156         | new_chord {
2157                 if (!PARSER->lexer_->is_chord_state ())
2158                         PARSER->parser_error (@1, _ ("have to be in Chord mode for chords"));
2159                 $$ = $1;
2160         }
2161         | figure_spec optional_notemode_duration {
2162                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
2163                 {
2164                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2165                 }
2166                 $$ = $1;
2167         }
2168         ;
2169
2170 lyric_element:
2171         lyric_markup {
2172                 $$ = $1;
2173         }
2174         | LYRICS_STRING {
2175                 $$ = $1;
2176         }
2177         ;
2178
2179 new_chord:
2180         steno_tonic_pitch optional_notemode_duration   {
2181                 $$ = make_chord_elements ($1, $2, SCM_EOL);
2182         }
2183         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2184                 SCM its = scm_reverse_x ($4, SCM_EOL);
2185                 $$ = make_chord_elements ($1, $2, scm_cons ($3, its));
2186         }
2187         ;
2188
2189 chord_items:
2190         /**/ {
2191                 $$ = SCM_EOL;
2192         }
2193         | chord_items chord_item {
2194                 $$ = scm_cons ($2, $$);
2195         }
2196         ;
2197
2198 chord_separator:
2199         CHORD_COLON {
2200                 $$ = ly_symbol2scm ("chord-colon");
2201         }
2202         | CHORD_CARET {
2203                 $$ = ly_symbol2scm ("chord-caret");
2204         }
2205         | CHORD_SLASH steno_tonic_pitch {
2206                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2207         }
2208         | CHORD_BASS steno_tonic_pitch {
2209                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2210         }
2211         ;
2212
2213 chord_item:
2214         chord_separator {
2215                 $$ = $1;
2216         }
2217         | step_numbers {
2218                 $$ = scm_reverse_x ($1, SCM_EOL);
2219         }
2220         | CHORD_MODIFIER  {
2221                 $$ = $1;
2222         }
2223         ;
2224
2225 step_numbers:
2226         step_number { $$ = scm_cons ($1, SCM_EOL); }
2227         | step_numbers '.' step_number {
2228                 $$ = scm_cons ($3, $$);
2229         }
2230         ;
2231
2232 step_number:
2233         bare_unsigned {
2234                 $$ = make_chord_step ($1, 0);
2235         }
2236         | bare_unsigned '+' {
2237                 $$ = make_chord_step ($1, SHARP_ALTERATION);
2238         }
2239         | bare_unsigned CHORD_MINUS {
2240                 $$ = make_chord_step ($1, FLAT_ALTERATION);
2241         }
2242         ;
2243
2244 /*
2245         UTILITIES
2246
2247 TODO: should deprecate in favor of Scheme?
2248
2249  */
2250 number_expression:
2251         number_expression '+' number_term {
2252                 $$ = scm_sum ($1, $3);
2253         }
2254         | number_expression '-' number_term {
2255                 $$ = scm_difference ($1, $3);
2256         }
2257         | number_term
2258         ;
2259
2260 number_term:
2261         number_factor {
2262                 $$ = $1;
2263         }
2264         | number_factor '*' number_factor {
2265                 $$ = scm_product ($1, $3);
2266         }
2267         | number_factor '/' number_factor {
2268                 $$ = scm_divide ($1, $3);
2269         }
2270         ;
2271
2272 number_factor:
2273         '-'  number_factor { /* %prec UNARY_MINUS */
2274                 $$ = scm_difference ($2, SCM_UNDEFINED);
2275         }
2276         | bare_number
2277         ;
2278
2279
2280 bare_number:
2281         UNSIGNED        {
2282                 $$ = scm_from_int ($1);
2283         }
2284         | REAL          {
2285                 $$ = $1;
2286         }
2287         | NUMBER_IDENTIFIER             {
2288                 $$ = $1;
2289         }
2290         | REAL NUMBER_IDENTIFIER        {
2291                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2292         }
2293         | UNSIGNED NUMBER_IDENTIFIER    {
2294                 $$ = scm_from_double ($1 *scm_to_double ($2));
2295         }
2296         ;
2297
2298
2299 bare_unsigned:
2300         UNSIGNED {
2301                         $$ = $1;
2302         }
2303         | DIGIT {
2304                 $$ = $1;
2305         }
2306         ;
2307
2308 unsigned_number:
2309         bare_unsigned  { $$ = scm_from_int ($1); }
2310         | NUMBER_IDENTIFIER {
2311                 $$ = $1;
2312         }
2313         ;
2314
2315
2316 exclamations:
2317                 { $$ = 0; }
2318         | exclamations '!'      { $$ ++; }
2319         ;
2320
2321 questions:
2322                 { $$ = 0; }
2323         | questions '?' { $$ ++; }
2324         ;
2325
2326 /*
2327 This should be done more dynamically if possible.
2328 */
2329
2330 lyric_markup:
2331         LYRIC_MARKUP_IDENTIFIER {
2332                 $$ = $1;
2333         }
2334         | LYRIC_MARKUP
2335                 { PARSER->lexer_->push_markup_state (); }
2336         markup_top {
2337                 $$ = $3;
2338                 PARSER->lexer_->pop_state ();
2339         }
2340         ;
2341
2342 full_markup_list:
2343         MARKUPLINES
2344                 { PARSER->lexer_->push_markup_state (); }
2345         markup_list {
2346                 $$ = $3;
2347                 PARSER->lexer_->pop_state ();
2348         }
2349         ;
2350
2351 full_markup:
2352         MARKUP_IDENTIFIER {
2353                 $$ = $1;
2354         }
2355         | MARKUP
2356                 { PARSER->lexer_->push_markup_state (); }
2357         markup_top {
2358                 $$ = $3;
2359                 PARSER->lexer_->pop_state ();
2360         }
2361         ;
2362
2363 markup_top:
2364         markup_list {
2365                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2366         }
2367         | markup_head_1_list simple_markup      {
2368                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2369         }
2370         | simple_markup {
2371                 $$ = $1;
2372         }
2373         ;
2374
2375 markup_list:
2376         markup_composed_list {
2377                 $$ = $1;
2378         }
2379         | markup_braced_list {
2380                 $$ = $1;
2381         }
2382         | markup_command_list {
2383                 $$ = scm_list_1 ($1);
2384         }
2385         ;
2386
2387 markup_composed_list:
2388         markup_head_1_list markup_braced_list {
2389                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2390
2391         }
2392         ;
2393
2394 markup_braced_list:
2395         '{' markup_braced_list_body '}' {
2396                 $$ = scm_reverse_x ($2, SCM_EOL);
2397         }
2398         ;
2399
2400 markup_braced_list_body:
2401         /* empty */     {  $$ = SCM_EOL; }
2402         | markup_braced_list_body markup {
2403                 $$ = scm_cons ($2, $1);
2404         }
2405         | markup_braced_list_body markup_list {
2406                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2407         }
2408         ;
2409
2410 markup_command_list:
2411         MARKUP_LIST_HEAD_EMPTY  {
2412                 $$ = scm_list_1 ($1);
2413         }
2414         | MARKUP_LIST_HEAD_LIST0 markup_list    {
2415                 $$ = scm_list_2 ($1, $2);
2416         }
2417         | MARKUP_LIST_HEAD_SCM0 embedded_scm    {
2418                 $$ = scm_list_2 ($1, $2);
2419         }
2420         | MARKUP_LIST_HEAD_SCM0_LIST1 embedded_scm markup_list  {
2421                 $$ = scm_list_3 ($1, $2, $3);
2422         }
2423         | MARKUP_LIST_HEAD_SCM0_SCM1_LIST2 embedded_scm embedded_scm markup_list        {
2424                 $$ = scm_list_4 ($1, $2, $3, $4);
2425         }
2426         ;
2427
2428 markup_head_1_item:
2429         MARKUP_HEAD_MARKUP0     {
2430                 $$ = scm_list_1 ($1);
2431         }
2432         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2433                 $$ = scm_list_2 ($1, $2);
2434         }
2435         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2436                 $$ = scm_list_3 ($1, $2, $3);
2437         }
2438         ;
2439
2440 markup_head_1_list:
2441         markup_head_1_item      {
2442                 $$ = scm_list_1 ($1);
2443         }
2444         | markup_head_1_list markup_head_1_item {
2445                 $$ = scm_cons ($2, $1);
2446         }
2447         ;
2448
2449 simple_markup:
2450         STRING {
2451                 $$ = make_simple_markup ($1);
2452         }
2453         | MARKUP_IDENTIFIER {
2454                 $$ = $1;
2455         }
2456         | LYRIC_MARKUP_IDENTIFIER {
2457                 $$ = $1;
2458         }
2459         | STRING_IDENTIFIER {
2460                 $$ = $1;
2461         }
2462         | SCORE {
2463                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
2464                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
2465         } '{' score_body '}' {
2466                 Score * sc = $4;
2467                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2468                 sc->unprotect ();
2469                 PARSER->lexer_->pop_state ();
2470         }
2471         | MARKUP_HEAD_SCM0 embedded_scm {
2472                 $$ = scm_list_2 ($1, $2);
2473         }
2474         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2475                 $$ = scm_list_4 ($1, $2, $3, $4);
2476         }
2477         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2478                 $$ = scm_list_3 ($1, $2, $3);
2479         }
2480         | MARKUP_HEAD_SCM0_MARKUP1_MARKUP2 embedded_scm markup markup {
2481                 $$ = scm_list_4 ($1, $2, $3, $4);
2482         }
2483         | MARKUP_HEAD_SCM0_SCM1_MARKUP2_MARKUP3 embedded_scm embedded_scm markup markup {
2484                 $$ = scm_list_5 ($1, $2, $3, $4, $5);
2485         }
2486         | MARKUP_HEAD_EMPTY {
2487                 $$ = scm_list_1 ($1);
2488         }
2489         | MARKUP_HEAD_LIST0 markup_list {
2490                 $$ = scm_list_2 ($1,$2);
2491         }
2492         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2493                 $$ = scm_list_3 ($1, $2, $3);
2494         }
2495         ;
2496
2497 markup:
2498         markup_head_1_list simple_markup        {
2499                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2500                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2501         }
2502         | simple_markup {
2503                 $$ = $1;
2504         }
2505         ;
2506
2507 %%
2508
2509 void
2510 Lily_parser::set_yydebug (bool x)
2511 {
2512         yydebug = x;
2513 }
2514
2515 void
2516 Lily_parser::do_yyparse ()
2517 {
2518         yyparse ((void*)this);
2519 }
2520
2521
2522
2523
2524
2525 /*
2526
2527 It is a little strange to have this function in this file, but
2528 otherwise, we have to import music classes into the lexer.
2529
2530 */
2531 int
2532 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2533 {
2534         if (scm_is_string (sid)) {
2535                 *destination = sid;
2536                 return STRING_IDENTIFIER;
2537         } else if (unsmob_book (sid)) {
2538                 Book *book =  unsmob_book (sid)->clone ();
2539                 *destination = book->self_scm ();
2540                 book->unprotect ();
2541
2542                 return BOOK_IDENTIFIER;
2543         } else if (scm_is_number (sid)) {
2544                 *destination = sid;
2545                 return NUMBER_IDENTIFIER;
2546         } else if (unsmob_context_def (sid)) {
2547                 Context_def *def= unsmob_context_def (sid)->clone ();
2548
2549                 *destination = def->self_scm ();
2550                 def->unprotect ();
2551
2552                 return CONTEXT_DEF_IDENTIFIER;
2553         } else if (unsmob_score (sid)) {
2554                 Score *score = new Score (*unsmob_score (sid));
2555                 *destination = score->self_scm ();
2556
2557                 score->unprotect ();
2558                 return SCORE_IDENTIFIER;
2559         } else if (Music *mus = unsmob_music (sid)) {
2560                 mus = mus->clone ();
2561                 *destination = mus->self_scm ();
2562                 unsmob_music (*destination)->
2563                         set_property ("origin", make_input (last_input_));
2564
2565                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2566                         != SCM_BOOL_F;
2567
2568                 mus->unprotect ();
2569                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2570         } else if (unsmob_duration (sid)) {
2571                 *destination = unsmob_duration (sid)->smobbed_copy ();
2572                 return DURATION_IDENTIFIER;
2573         } else if (unsmob_output_def (sid)) {
2574                 Output_def *p = unsmob_output_def (sid);
2575                 p = p->clone ();
2576
2577                 *destination = p->self_scm ();
2578                 p->unprotect ();
2579                 return OUTPUT_DEF_IDENTIFIER;
2580         } else if (Text_interface::is_markup (sid)) {
2581                 *destination = sid;
2582                 if (is_lyric_state ())
2583                         return LYRIC_MARKUP_IDENTIFIER;
2584                 return MARKUP_IDENTIFIER;
2585         }
2586
2587         return -1;
2588 }
2589
2590 SCM
2591 get_next_unique_context_id ()
2592 {
2593         return scm_from_locale_string ("$uniqueContextId");
2594 }
2595
2596
2597 SCM
2598 get_next_unique_lyrics_context_id ()
2599 {
2600         static int new_context_count;
2601         char s[128];
2602         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2603         return scm_from_locale_string (s);
2604 }
2605
2606
2607 SCM
2608 run_music_function (Lily_parser *parser, SCM expr)
2609 {
2610         SCM func = scm_car (expr);
2611         Input *loc = unsmob_input (scm_cadr (expr));
2612         SCM args = scm_cddr (expr);
2613         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2614
2615         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2616
2617         if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr (expr), sig, args)))
2618         {
2619                 parser->error_level_ = 1;
2620                 return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("void-music"), scm_list_2 (parser->self_scm (), make_input (*loc)));
2621         }
2622
2623         SCM syntax_args = scm_list_4 (parser->self_scm (), make_input (*loc), func, args);
2624         return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("music-function"), syntax_args);
2625 }
2626
2627 bool
2628 is_regular_identifier (SCM id)
2629 {
2630   string str = ly_scm2string (id);
2631   char const *s = str.c_str ();
2632
2633   bool v = true;
2634 #if 0
2635   isalpha (*s);
2636   s++;
2637 #endif
2638   while (*s && v)
2639    {
2640         v = v && isalnum (*s);
2641         s++;
2642    }
2643   return v;
2644 }
2645
2646 Music *
2647 make_music_with_input (SCM name, Input where)
2648 {
2649        Music *m = make_music_by_name (name);
2650        m->set_spot (where);
2651        return m;
2652 }
2653
2654 SCM
2655 get_first_context_id (SCM type, Music *m)
2656 {
2657         SCM id = m->get_property ("context-id");
2658         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2659             && scm_is_string (m->get_property ("context-id"))
2660             && scm_c_string_length (id) > 0)
2661         {
2662                 return id;
2663         }
2664         return SCM_EOL;
2665 }
2666
2667 SCM
2668 make_simple_markup (SCM a)
2669 {
2670         return a;
2671 }
2672
2673 bool
2674 is_duration (int t)
2675 {
2676   return t && t == 1 << intlog2 (t);
2677 }
2678
2679 void
2680 set_music_properties (Music *p, SCM a)
2681 {
2682   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2683         p->set_property (scm_caar (k), scm_cdar (k));
2684 }
2685
2686
2687 SCM
2688 make_chord_step (int step, Rational alter)
2689 {
2690         if (step == 7)
2691                 alter += FLAT_ALTERATION;
2692
2693         while (step < 0)
2694                 step += 7;
2695         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2696         return m.smobbed_copy ();
2697 }
2698
2699
2700 SCM
2701 make_chord_elements (SCM pitch, SCM dur, SCM modification_list)
2702 {
2703         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
2704         return scm_call_3 (chord_ctor, pitch, dur, modification_list);
2705 }
2706
2707
2708 /* Todo: actually also use apply iso. call too ...  */
2709 bool
2710 ly_input_procedure_p (SCM x)
2711 {
2712         return ly_is_procedure (x)
2713                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2714 }
2715
2716 SCM
2717 make_music_relative (Pitch start, SCM music, Input loc)
2718 {
2719         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic", loc);
2720         relative->set_property ("element", music);
2721
2722         Music *m = unsmob_music (music);
2723         Pitch last = m->to_relative_octave (start);
2724         if (lily_1_8_relative)
2725                 m->set_property ("last-pitch", last.smobbed_copy ());
2726         return relative->unprotect ();
2727 }
2728
2729 int
2730 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2731 {
2732         Lily_parser *pars = (Lily_parser*) v;
2733         Lily_lexer *lex = pars->lexer_;
2734
2735         lex->lexval = (void*) s;
2736         lex->lexloc = loc;
2737         lex->prepare_for_next_token ();
2738         return lex->yylex ();
2739 }