lily/parser.yy

   1 /*
   2   This file is part of LilyPond, the GNU music typesetter.
   3
   4   Copyright (C) 1997--2011 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5                  Jan Nieuwenhuizen <janneke@gnu.org>
   6
   7   LilyPond is free software: you can redistribute it and/or modify
   8   it under the terms of the GNU General Public License as published by
   9   the Free Software Foundation, either version 3 of the License, or
  10   (at your option) any later version.
  11
  12   LilyPond is distributed in the hope that it will be useful,
  13   but WITHOUT ANY WARRANTY; without even the implied warranty of
  14   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15   GNU General Public License for more details.
  16
  17   You should have received a copy of the GNU General Public License
  18   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  19 */
  20
  21 %{
  22
  23 #define YYDEBUG 1
  24 #define YYERROR_VERBOSE 1
  25 #define YYPARSE_PARAM my_lily_parser
  26 #define YYLEX_PARAM my_lily_parser
  27 #define PARSER ((Lily_parser *) my_lily_parser)
  28
  29 #define yyerror PARSER->parser_error
  30
  31 /* We use custom location type: Input objects */
  32 #define YYLTYPE Input
  33 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  34         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  35
  36
  37 %}
  38
  39 /* We use SCMs to do strings, because it saves us the trouble of
  40 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  41 of the parse stack onto the heap. */
  42
  43 %left PREC_TOP
  44 %left ADDLYRICS
  45 %left PREC_BOT
  46
  47 %expect 1
  48
  49 /* One shift/reduce problem
  50
  51 1.  \repeat
  52         \repeat .. \alternative
  53
  54     \repeat { \repeat .. \alternative }
  55
  56 or
  57
  58     \repeat { \repeat } \alternative
  59 */
  60
  61
  62 %pure_parser
  63 %locations
  64
  65
  66
  67 %{ // -*-Fundamental-*-
  68
  69 /*
  70 FIXME:
  71
  72    * The rules for who is protecting what are very shady.  Uniformise
  73      this.
  74
  75    * There are too many lexical modes?
  76 */
  77
  78 #include "config.hh"
  79
  80 #include <cctype>
  81 #include <cstdlib>
  82 #include <cstdio>
  83 using namespace std;
  84
  85 #include "book.hh"
  86 #include "context-def.hh"
  87 #include "context-mod.hh"
  88 #include "dimensions.hh"
  89 #include "file-path.hh"
  90 #include "input.hh"
  91 #include "international.hh"
  92 #include "lily-guile.hh"
  93 #include "lily-lexer.hh"
  94 #include "lily-parser.hh"
  95 #include "main.hh"
  96 #include "misc.hh"
  97 #include "music.hh"
  98 #include "music.hh"
  99 #include "output-def.hh"
 100 #include "paper-book.hh"
 101 #include "program-option.hh"
 102 #include "scm-hash.hh"
 103 #include "score.hh"
 104 #include "text-interface.hh"
 105 #include "warn.hh"
 106
 107 %}
 108
 109
 110 %union {
 111         Book *book;
 112         Output_def *outputdef;
 113         SCM scm;
 114         std::string *string;
 115         Music *music;
 116         Score *score;
 117         int i;
 118 }
 119
 120 %{
 121
 122 #define MY_MAKE_MUSIC(x, spot)  make_music_with_input (ly_symbol2scm (x), spot)
 123
 124 /* ES TODO:
 125 - Don't use lily module, create a new module instead.
 126 - delay application of the function
 127 */
 128 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 129   scm_apply_0 (proc, args)
 130 /* Syntactic Sugar. */
 131 #define MAKE_SYNTAX(name, location, ...)        \
 132   LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (PARSER->self_scm (), make_input (location), __VA_ARGS__, SCM_UNDEFINED));
 133
 134 SCM get_next_unique_context_id ();
 135 SCM get_next_unique_lyrics_context_id ();
 136
 137 #undef _
 138 #if !HAVE_GETTEXT
 139 #define _(x) x
 140 #else
 141 #include <libintl.h>
 142 #define _(x) gettext (x)
 143 #endif
 144
 145
 146 static Music *make_music_with_input (SCM name, Input where);
 147 SCM make_music_relative (Pitch start, SCM music, Input loc);
 148 SCM run_music_function (Lily_parser *, SCM expr);
 149 SCM get_first_context_id (SCM type, Music *m);
 150 SCM make_chord_elements (SCM pitch, SCM dur, SCM modification_list);
 151 SCM make_chord_step (int step, Rational alter);
 152 SCM make_simple_markup (SCM a);
 153 bool is_duration (int t);
 154 bool is_regular_identifier (SCM id);
 155 bool ly_input_procedure_p (SCM x);
 156 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 157 void set_music_properties (Music *p, SCM a);
 158
 159 %}
 160
 161 /* The third option is an alias that will be used to display the
 162    syntax error.  Bison CVS now correctly handles backslash escapes.
 163
 164    FIXME: Bison needs to translate some of these, eg, STRING.
 165
 166 */
 167
 168 /* Keyword tokens with plain escaped name.  */
 169 %token ACCEPTS "\\accepts"
 170 %token ADDLYRICS "\\addlyrics"
 171 %token ALIAS "\\alias"
 172 %token ALTERNATIVE "\\alternative"
 173 %token BOOK "\\book"
 174 %token BOOKPART "\\bookpart"
 175 %token CHANGE "\\change"
 176 %token CHORDMODE "\\chordmode"
 177 %token CHORDS "\\chords"
 178 %token CONSISTS "\\consists"
 179 %token CONTEXT "\\context"
 180 %token DEFAULT "\\default"
 181 %token DEFAULTCHILD "\\defaultchild"
 182 %token DENIES "\\denies"
 183 %token DESCRIPTION "\\description"
 184 %token DRUMMODE "\\drummode"
 185 %token DRUMS "\\drums"
 186 %token FIGUREMODE "\\figuremode"
 187 %token FIGURES "\\figures"
 188 %token GROBDESCRIPTIONS "\\grobdescriptions"
 189 %token HEADER "\\header"
 190 %token INVALID "\\invalid"
 191 %token KEY "\\key"
 192 %token LAYOUT "\\layout"
 193 %token LYRICMODE "\\lyricmode"
 194 %token LYRICS "\\lyrics"
 195 %token LYRICSTO "\\lyricsto"
 196 %token MARK "\\mark"
 197 %token MARKUP "\\markup"
 198 %token MARKUPLINES "\\markuplines"
 199 %token MIDI "\\midi"
 200 %token NAME "\\name"
 201 %token NOTEMODE "\\notemode"
 202 %token OCTAVE "\\octave"
 203 %token ONCE "\\once"
 204 %token OVERRIDE "\\override"
 205 %token PAPER "\\paper"
 206 %token PARTIAL "\\partial"
 207 %token RELATIVE "\\relative"
 208 %token REMOVE "\\remove"
 209 %token REPEAT "\\repeat"
 210 %token REST "\\rest"
 211 %token REVERT "\\revert"
 212 %token SCORE "\\score"
 213 %token SEQUENTIAL "\\sequential"
 214 %token SET "\\set"
 215 %token SIMULTANEOUS "\\simultaneous"
 216 %token SKIP "\\skip"
 217 %token TEMPO "\\tempo"
 218 %token TIMES "\\times"
 219 %token TRANSPOSE "\\transpose"
 220 %token TYPE "\\type"
 221 %token UNSET "\\unset"
 222 %token WITH "\\with"
 223
 224 /* Keyword token exceptions.  */
 225 %token TIME_T "\\time"
 226 %token NEWCONTEXT "\\new"
 227
 228
 229 /* Other string tokens.  */
 230
 231 %token CHORD_BASS "/+"
 232 %token CHORD_CARET "^"
 233 %token CHORD_COLON ":"
 234 %token CHORD_MINUS "-"
 235 %token CHORD_SLASH "/"
 236 %token ANGLE_OPEN "<"
 237 %token ANGLE_CLOSE ">"
 238 %token DOUBLE_ANGLE_OPEN "<<"
 239 %token DOUBLE_ANGLE_CLOSE ">>"
 240 %token E_BACKSLASH "\\"
 241 %token E_ANGLE_CLOSE "\\>"
 242 %token E_CHAR "\\C[haracter]"
 243 %token E_CLOSE "\\)"
 244 %token E_EXCLAMATION "\\!"
 245 %token E_BRACKET_OPEN "\\["
 246 %token E_OPEN "\\("
 247 %token E_BRACKET_CLOSE "\\]"
 248 %token E_ANGLE_OPEN "\\<"
 249 %token E_PLUS "\\+"
 250 %token E_TILDE "\\~"
 251 %token EXTENDER "__"
 252
 253 /*
 254 If we give names, Bison complains.
 255 */
 256 %token FIGURE_CLOSE /* "\\>" */
 257 %token FIGURE_OPEN /* "\\<" */
 258 %token FIGURE_SPACE "_"
 259 %token HYPHEN "--"
 260
 261 %token CHORDMODIFIERS
 262 %token LYRIC_MARKUP
 263 %token MULTI_MEASURE_REST
 264
 265
 266 %token <i> DIGIT
 267 %token <i> E_UNSIGNED
 268 %token <i> UNSIGNED
 269
 270 /* Artificial tokens, for more generic function syntax */
 271 %token <i> EXPECT_MARKUP;
 272 %token <i> EXPECT_MUSIC;
 273 %token <i> EXPECT_SCM;
 274 %token <i> EXPECT_MARKUP_LIST
 275 /* After the last argument. */
 276 %token <i> EXPECT_NO_MORE_ARGS;
 277
 278 %token <scm> BOOK_IDENTIFIER
 279 %token <scm> CHORDMODIFIER_PITCH
 280 %token <scm> CHORD_MODIFIER
 281 %token <scm> CHORD_REPETITION
 282 %token <scm> CONTEXT_DEF_IDENTIFIER
 283 %token <scm> CONTEXT_MOD_IDENTIFIER
 284 %token <scm> DRUM_PITCH
 285 %token <scm> DURATION_IDENTIFIER
 286 %token <scm> EVENT_IDENTIFIER
 287 %token <scm> FRACTION
 288 %token <scm> LYRICS_STRING
 289 %token <scm> LYRIC_MARKUP_IDENTIFIER
 290 %token <scm> MARKUP_FUNCTION
 291 %token <scm> MARKUP_LIST_FUNCTION
 292 %token <scm> MARKUP_IDENTIFIER
 293 %token <scm> MARKUPLINES_IDENTIFIER
 294 %token <scm> MUSIC_FUNCTION
 295 %token <scm> MUSIC_IDENTIFIER
 296 %token <scm> NOTENAME_PITCH
 297 %token <scm> NUMBER_IDENTIFIER
 298 %token <scm> OUTPUT_DEF_IDENTIFIER
 299 %token <scm> REAL
 300 %token <scm> RESTNAME
 301 %token <scm> SCM_IDENTIFIER
 302 %token <scm> SCM_TOKEN
 303 %token <scm> SCORE_IDENTIFIER
 304 %token <scm> STRING
 305 %token <scm> STRING_IDENTIFIER
 306 %token <scm> TONICNAME_PITCH
 307
 308
 309 %type <book> book_block
 310 %type <book> book_body
 311 %type <book> bookpart_block
 312 %type <book> bookpart_body
 313
 314 %type <i> bare_unsigned
 315 %type <scm> figured_bass_alteration
 316 %type <i> dots
 317 %type <i> exclamations
 318 %type <i> optional_rest
 319 %type <i> questions
 320 %type <i> script_dir
 321 %type <i> sub_quotes
 322 %type <i> sup_quotes
 323 %type <i> tremolo_type
 324
 325 /* Music */
 326 %type <scm> composite_music
 327 %type <scm> grouped_music_list
 328 %type <scm> music
 329 %type <scm> prefix_composite_music
 330 %type <scm> repeated_music
 331 %type <scm> sequential_music
 332 %type <scm> simple_music
 333 %type <scm> simultaneous_music
 334 %type <scm> chord_body
 335 %type <scm> chord_body_element
 336 %type <scm> command_element
 337 %type <scm> command_event
 338 %type <scm> context_modification
 339 %type <scm> context_change
 340 %type <scm> direction_less_event
 341 %type <scm> direction_reqd_event
 342 %type <scm> event_chord
 343 %type <scm> gen_text_def
 344 %type <scm> music_property_def
 345 %type <scm> note_chord_element
 346 %type <scm> post_event
 347 %type <scm> re_rhythmed_music
 348 %type <scm> relative_music
 349 %type <scm> simple_element
 350 %type <scm> simple_music_property_def
 351 %type <scm> string_number_event
 352 %type <scm> tempo_event
 353
 354 %type <outputdef> output_def_body
 355 %type <outputdef> output_def_head
 356 %type <outputdef> output_def_head_with_mode_switch
 357 %type <outputdef> output_def
 358 %type <outputdef> paper_block
 359
 360 %type <scm> alternative_music
 361 %type <scm> generic_prefix_music_scm
 362 %type <scm> music_list
 363 %type <scm> absolute_pitch
 364 %type <scm> assignment_id
 365 %type <scm> bare_number
 366 %type <scm> unsigned_number
 367 %type <scm> bass_figure
 368 %type <scm> figured_bass_modification
 369 %type <scm> br_bass_figure
 370 %type <scm> bass_number
 371 %type <scm> chord_body_elements
 372 %type <scm> chord_item
 373 %type <scm> chord_items
 374 %type <scm> chord_separator
 375 %type <scm> context_def_mod
 376 %type <scm> context_def_spec_block
 377 %type <scm> context_def_spec_body
 378 %type <scm> context_mod
 379 %type <scm> context_mod_list
 380 %type <scm> context_prop_spec
 381 %type <scm> direction_less_char
 382 %type <scm> duration_length
 383 %type <scm> embedded_scm
 384 %type <scm> figure_list
 385 %type <scm> figure_spec
 386 %type <scm> fraction
 387 %type <scm> full_markup
 388 %type <scm> full_markup_list
 389 %type <scm> function_scm_argument
 390 %type <scm> function_arglist
 391 %type <scm> function_arglist_music_last
 392 %type <scm> function_arglist_nonmusic_last
 393 %type <scm> function_arglist_nonmusic
 394 %type <scm> identifier_init
 395 %type <scm> lilypond_header
 396 %type <scm> lilypond_header_body
 397 %type <scm> lyric_element
 398 %type <scm> lyric_markup
 399 %type <scm> markup
 400 %type <scm> markup_braced_list
 401 %type <scm> markup_braced_list_body
 402 %type <scm> markup_composed_list
 403 %type <scm> markup_command_list
 404 %type <scm> markup_command_list_arguments
 405 %type <scm> markup_command_basic_arguments
 406 %type <scm> markup_head_1_item
 407 %type <scm> markup_head_1_list
 408 %type <scm> markup_list
 409 %type <scm> markup_top
 410 %type <scm> mode_changing_head
 411 %type <scm> mode_changing_head_with_context
 412 %type <scm> multiplied_duration
 413 %type <scm> music_function_identifier_musicless_prefix
 414 %type <scm> music_function_event
 415 %type <scm> music_function_chord_body
 416 %type <scm> new_chord
 417 %type <scm> new_lyrics
 418 %type <scm> number_expression
 419 %type <scm> number_factor
 420 %type <scm> number_term
 421 %type <scm> octave_check
 422 %type <scm> optional_context_mod
 423 %type <scm> optional_id
 424 %type <scm> optional_notemode_duration
 425 %type <scm> pitch
 426 %type <scm> pitch_also_in_chords
 427 %type <scm> post_events
 428 %type <scm> property_operation
 429 %type <scm> property_path property_path_revved
 430 %type <scm> scalar
 431 %type <scm> script_abbreviation
 432 %type <scm> simple_chord_elements
 433 %type <scm> simple_markup
 434 %type <scm> simple_string
 435 %type <scm> steno_duration
 436 %type <scm> steno_pitch
 437 %type <scm> steno_tonic_pitch
 438 %type <scm> step_number
 439 %type <scm> step_numbers
 440 %type <scm> string
 441 %type <scm> tempo_range
 442
 443 %type <score> score_block
 444 %type <score> score_body
 445
 446
 447 %left '-' '+'
 448
 449 /* We don't assign precedence to / and *, because we might need varied
 450 prec levels in different prods */
 451
 452 %left UNARY_MINUS
 453
 454 %%
 455
 456 lilypond:       /* empty */
 457         | lilypond toplevel_expression {
 458         }
 459         | lilypond assignment {
 460         }
 461         | lilypond error {
 462                 PARSER->error_level_ = 1;
 463         }
 464         | lilypond INVALID      {
 465                 PARSER->error_level_ = 1;
 466         }
 467         ;
 468
 469
 470 toplevel_expression:
 471         lilypond_header {
 472                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 473         }
 474         | book_block {
 475                 Book *book = $1;
 476                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-book-handler");
 477                 scm_call_2 (proc, PARSER->self_scm (), book->self_scm ());
 478                 book->unprotect ();
 479         }
 480         | bookpart_block {
 481                 Book *bookpart = $1;
 482                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 483                 scm_call_2 (proc, PARSER->self_scm (), bookpart->self_scm ());
 484                 bookpart->unprotect ();
 485         }
 486         | score_block {
 487                 Score *score = $1;
 488
 489                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-score-handler");
 490                 scm_call_2 (proc, PARSER->self_scm (), score->self_scm ());
 491                 score->unprotect ();
 492         }
 493         | composite_music {
 494                 Music *music = unsmob_music ($1);
 495                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-music-handler");
 496                 scm_call_2 (proc, PARSER->self_scm (), music->self_scm ());
 497         }
 498         | full_markup {
 499                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 500                 scm_call_2 (proc, PARSER->self_scm (), scm_list_1 ($1));
 501         }
 502         | full_markup_list {
 503                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 504                 scm_call_2 (proc, PARSER->self_scm (), $1);
 505         }
 506         | output_def {
 507                 SCM id = SCM_EOL;
 508                 Output_def * od = $1;
 509
 510                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 511                         id = ly_symbol2scm ("$defaultpaper");
 512                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 513                         id = ly_symbol2scm ("$defaultmidi");
 514                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 515                         id = ly_symbol2scm ("$defaultlayout");
 516
 517                 PARSER->lexer_->set_identifier (id, od->self_scm ());
 518                 od->unprotect();
 519         }
 520         ;
 521
 522 embedded_scm:
 523         SCM_TOKEN
 524         | SCM_IDENTIFIER
 525         ;
 526
 527
 528 lilypond_header_body:
 529         {
 530                 $$ = get_header (PARSER);
 531                 PARSER->lexer_->add_scope ($$);
 532         }
 533         | lilypond_header_body assignment  {
 534
 535         }
 536         ;
 537
 538 lilypond_header:
 539         HEADER '{' lilypond_header_body '}'     {
 540                 $$ = PARSER->lexer_->remove_scope ();
 541         }
 542         ;
 543
 544 /*
 545         DECLARATIONS
 546 */
 547 assignment_id:
 548         STRING          { $$ = $1; }
 549         | LYRICS_STRING { $$ = $1; }
 550         ;
 551
 552 assignment:
 553         assignment_id '=' identifier_init  {
 554                 PARSER->lexer_->set_identifier ($1, $3);
 555         }
 556         | assignment_id property_path '=' identifier_init {
 557                 SCM path = scm_cons (scm_string_to_symbol ($1), $2);
 558                 PARSER->lexer_->set_identifier (path, $4);
 559         ;
 560 /*
 561  TODO: devise standard for protection in parser.
 562
 563   The parser stack lives on the C-stack, which means that
 564 all objects can be unprotected as soon as they're here.
 565
 566 */
 567         }
 568         | embedded_scm { }
 569         ;
 570
 571
 572 identifier_init:
 573         score_block {
 574                 $$ = $1->self_scm ();
 575                 $1->unprotect ();
 576         }
 577         | book_block {
 578                 $$ = $1->self_scm ();
 579                 $1->unprotect ();
 580         }
 581         | bookpart_block {
 582                 $$ = $1->self_scm ();
 583                 $1->unprotect ();
 584         }
 585         | output_def {
 586                 $$ = $1->self_scm ();
 587                 $1->unprotect ();
 588         }
 589         | context_def_spec_block {
 590                 $$ = $1;
 591         }
 592         | music  {
 593                 /* Hack: Create event-chord around standalone events.
 594                    Prevents the identifier from being interpreted as a post-event. */
 595                 Music *mus = unsmob_music ($1);
 596                 bool is_event = mus &&
 597                         (scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
 598                                 != SCM_BOOL_F);
 599                 if (!is_event)
 600                         $$ = $1;
 601                 else
 602                         $$ = MAKE_SYNTAX ("event-chord", @$, scm_list_1 ($1));
 603         }
 604         | post_event {
 605                 $$ = $1;
 606         }
 607         | number_expression {
 608                 $$ = $1;
 609         }
 610         | string {
 611                 $$ = $1;
 612         }
 613         | embedded_scm {
 614                 $$ = $1;
 615         }
 616         | full_markup {
 617                 $$ = $1;
 618         }
 619         | full_markup_list {
 620                 $$ = $1;
 621         }
 622         | DIGIT {
 623                 $$ = scm_from_int ($1);
 624         }
 625         | context_modification {
 626                 $$ = $1;
 627         }
 628         ;
 629
 630 context_def_spec_block:
 631         CONTEXT '{' context_def_spec_body '}'
 632                 {
 633                 $$ = $3;
 634         }
 635         ;
 636
 637 context_def_spec_body:
 638         /**/ {
 639                 $$ = Context_def::make_scm ();
 640                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 641         }
 642         | CONTEXT_DEF_IDENTIFIER {
 643                 $$ = $1;
 644                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 645         }
 646         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 647                 Context_def*td = unsmob_context_def ($$);
 648
 649                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 650                         SCM tag = scm_caar (p);
 651
 652                         /* TODO: should make new tag "grob-definition" ? */
 653                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 654                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 655                 }
 656         }
 657         | context_def_spec_body context_mod {
 658                 unsmob_context_def ($$)->add_context_mod ($2);
 659         }
 660         | context_def_spec_body context_modification {
 661                 Context_def *td = unsmob_context_def ($$);
 662                 SCM new_mods = unsmob_context_mod ($2)->get_mods ();
 663                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 664                     td->add_context_mod (scm_car (m));
 665                 }
 666         }
 667         ;
 668
 669
 670
 671 book_block:
 672         BOOK '{' book_body '}'  {
 673                 $$ = $3;
 674                 pop_paper (PARSER);
 675                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 676         }
 677         ;
 678
 679 /* FIXME:
 680    * Use 'handlers' like for toplevel-* stuff?
 681    * grok \layout and \midi?  */
 682 book_body:
 683         {
 684                 $$ = new Book;
 685                 init_papers (PARSER);
 686                 $$->origin ()->set_spot (@$);
 687                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (PARSER->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 688                 $$->paper_->unprotect ();
 689                 push_paper (PARSER, $$->paper_);
 690                 $$->header_ = PARSER->lexer_->lookup_identifier ("$defaultheader");
 691                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$->self_scm ());
 692                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-output-suffix"), SCM_BOOL_F);
 693                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-filename"), SCM_BOOL_F);
 694         }
 695         | BOOK_IDENTIFIER {
 696                 $$ = unsmob_book ($1);
 697                 $$->protect ();
 698                 $$->origin ()->set_spot (@$);
 699                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 700         }
 701         | book_body paper_block {
 702                 $$->paper_ = $2;
 703                 $2->unprotect ();
 704                 set_paper (PARSER, $2);
 705         }
 706         | book_body bookpart_block {
 707                 Book *bookpart = $2;
 708                 SCM proc = PARSER->lexer_->lookup_identifier ("book-bookpart-handler");
 709                 scm_call_2 (proc, $$->self_scm (), bookpart->self_scm ());
 710                 bookpart->unprotect ();
 711         }
 712         | book_body score_block {
 713                 Score *score = $2;
 714                 SCM proc = PARSER->lexer_->lookup_identifier ("book-score-handler");
 715                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 716                 score->unprotect ();
 717         }
 718         | book_body composite_music {
 719                 Music *music = unsmob_music ($2);
 720                 SCM proc = PARSER->lexer_->lookup_identifier ("book-music-handler");
 721                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 722         }
 723         | book_body full_markup {
 724                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 725                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 726         }
 727         | book_body full_markup_list {
 728                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 729                 scm_call_2 (proc, $$->self_scm (), $2);
 730         }
 731         | book_body lilypond_header {
 732                 $$->header_ = $2;
 733         }
 734         | book_body error {
 735                 $$->paper_ = 0;
 736                 $$->scores_ = SCM_EOL;
 737                 $$->bookparts_ = SCM_EOL;
 738         }
 739         ;
 740
 741 bookpart_block:
 742         BOOKPART '{' bookpart_body '}' {
 743                 $$ = $3;
 744                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 745         }
 746         ;
 747
 748 bookpart_body:
 749         {
 750                 $$ = new Book;
 751                 $$->origin ()->set_spot (@$);
 752                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$->self_scm ());
 753         }
 754         | BOOK_IDENTIFIER {
 755                 $$ = unsmob_book ($1);
 756                 $$->protect ();
 757                 $$->origin ()->set_spot (@$);
 758                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 759         }
 760         | bookpart_body paper_block {
 761                 $$->paper_ = $2;
 762                 $2->unprotect ();
 763         }
 764         | bookpart_body score_block {
 765                 Score *score = $2;
 766                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-score-handler");
 767                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 768                 score->unprotect ();
 769         }
 770         | bookpart_body composite_music {
 771                 Music *music = unsmob_music ($2);
 772                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-music-handler");
 773                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 774         }
 775         | bookpart_body full_markup {
 776                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 777                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 778         }
 779         | bookpart_body full_markup_list {
 780                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 781                 scm_call_2 (proc, $$->self_scm (), $2);
 782         }
 783         | bookpart_body lilypond_header {
 784                 $$->header_ = $2;
 785         }
 786         | bookpart_body error {
 787                 $$->paper_ = 0;
 788                 $$->scores_ = SCM_EOL;
 789         }
 790         ;
 791
 792 score_block:
 793         SCORE '{' score_body '}'        {
 794                 $$ = $3;
 795         }
 796         ;
 797
 798 score_body:
 799         music {
 800                 SCM m = $1;
 801                 SCM scorify = ly_lily_module_constant ("scorify-music");
 802                 SCM score = scm_call_2 (scorify, m, PARSER->self_scm ());
 803
 804                 // pass ownernship to C++ again.
 805                 $$ = unsmob_score (score);
 806                 $$->protect ();
 807                 $$->origin ()->set_spot (@$);
 808         }
 809         | SCORE_IDENTIFIER {
 810                 $$ = unsmob_score ($1);
 811                 $$->protect ();
 812                 $$->origin ()->set_spot (@$);
 813         }
 814         | score_body lilypond_header    {
 815                 $$->set_header ($2);
 816         }
 817         | score_body output_def {
 818                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 819                 {
 820                         PARSER->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 821
 822                 }
 823                 else
 824                 {
 825                         $$->add_output_def ($2);
 826                 }
 827                 $2->unprotect ();
 828         }
 829         | score_body error {
 830                 $$->error_found_ = true;
 831         }
 832         ;
 833
 834
 835 /*
 836         OUTPUT DEF
 837 */
 838
 839 paper_block:
 840         output_def {
 841                 $$ = $1;
 842                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 843                 {
 844                         PARSER->parser_error (@1, _ ("need \\paper for paper block"));
 845                         $1->unprotect ();
 846                         $$ = get_paper (PARSER);
 847                 }
 848         }
 849         ;
 850
 851
 852 output_def:
 853         output_def_body '}' {
 854                 $$ = $1;
 855
 856                 PARSER->lexer_->remove_scope ();
 857                 PARSER->lexer_->pop_state ();
 858         }
 859         ;
 860
 861 output_def_head:
 862         PAPER {
 863                 $$ = get_paper (PARSER);
 864                 $$->input_origin_ = @$;
 865                 PARSER->lexer_->add_scope ($$->scope_);
 866         }
 867         | MIDI    {
 868                 Output_def *p = get_midi (PARSER);
 869                 $$ = p;
 870                 PARSER->lexer_->add_scope (p->scope_);
 871         }
 872         | LAYOUT        {
 873                 Output_def *p = get_layout (PARSER);
 874
 875                 PARSER->lexer_->add_scope (p->scope_);
 876                 $$ = p;
 877         }
 878         ;
 879
 880 output_def_head_with_mode_switch:
 881         output_def_head {
 882                 PARSER->lexer_->push_initial_state ();
 883                 $$ = $1;
 884         }
 885         ;
 886
 887 output_def_body:
 888         output_def_head_with_mode_switch '{' {
 889                 $$ = $1;
 890                 $$->input_origin_.set_spot (@$);
 891         }
 892         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 893                 $1->unprotect ();
 894
 895                 Output_def *o = unsmob_output_def ($3);
 896                 o->input_origin_.set_spot (@$);
 897                 $$ = o;
 898                 $$->protect ();
 899                 PARSER->lexer_->remove_scope ();
 900                 PARSER->lexer_->add_scope (o->scope_);
 901         }
 902         | output_def_body assignment  {
 903
 904         }
 905         | output_def_body context_def_spec_block        {
 906                 assign_context_def ($$, $2);
 907         }
 908         | output_def_body error {
 909
 910         }
 911         ;
 912
 913 tempo_event:
 914         TEMPO steno_duration '=' tempo_range    {
 915                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_BOOL_F, $2, $4);
 916         }
 917         | TEMPO string steno_duration '=' tempo_range   {
 918                 $$ = MAKE_SYNTAX ("tempo", @$, make_simple_markup($2), $3, $5);
 919         }
 920         | TEMPO full_markup steno_duration '=' tempo_range      {
 921                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, $5);
 922         }
 923         | TEMPO string {
 924                 $$ = MAKE_SYNTAX ("tempoText", @$, make_simple_markup($2) );
 925         }
 926         | TEMPO full_markup {
 927                 $$ = MAKE_SYNTAX ("tempoText", @$, $2 );
 928         }
 929         ;
 930
 931 /*
 932 The representation of a  list is the
 933
 934   (LIST . LAST-CONS)
 935
 936  to have efficient append.  */
 937
 938 music_list:
 939         /* empty */ {
 940                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 941         }
 942         | music_list music {
 943                 SCM s = $$;
 944                 SCM c = scm_cons ($2, SCM_EOL);
 945
 946                 if (scm_is_pair (scm_cdr (s)))
 947                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 948                 else
 949                         scm_set_car_x (s, c); /* set first cons */
 950                 scm_set_cdr_x (s, c);  /* remember last cell */
 951         }
 952         | music_list embedded_scm {
 953
 954         }
 955         | music_list error {
 956                 Music *m = MY_MAKE_MUSIC("Music", @$);
 957                 // ugh. code dup
 958                 m->set_property ("error-found", SCM_BOOL_T);
 959                 SCM s = $$;
 960                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 961                 m->unprotect (); /* UGH */
 962
 963                 if (scm_is_pair (scm_cdr (s)))
 964                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 965                 else
 966                         scm_set_car_x (s, c); /* set first cons */
 967                 scm_set_cdr_x (s, c);  /* remember last cell */
 968         }
 969         ;
 970
 971 music:
 972         simple_music
 973         | composite_music
 974         ;
 975
 976 alternative_music:
 977         /* empty */ {
 978                 $$ = SCM_EOL;
 979         }
 980         | ALTERNATIVE '{' music_list '}' {
 981                 $$ = scm_car ($3);
 982         }
 983         ;
 984
 985
 986 repeated_music:
 987         REPEAT simple_string unsigned_number music alternative_music
 988         {
 989                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $5);
 990         }
 991         ;
 992
 993 sequential_music:
 994         SEQUENTIAL '{' music_list '}'           {
 995                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($3));
 996         }
 997         | '{' music_list '}'            {
 998                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($2));
 999         }
1000         ;
1001
1002 simultaneous_music:
1003         SIMULTANEOUS '{' music_list '}'{
1004                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($3));
1005         }
1006         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1007                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($2));
1008         }
1009         ;
1010
1011 simple_music:
1012         event_chord
1013         | MUSIC_IDENTIFIER
1014         | music_property_def
1015         | context_change
1016         ;
1017
1018 context_modification:
1019         WITH { PARSER->lexer_->push_initial_state (); } '{' context_mod_list '}'
1020         {
1021                 PARSER->lexer_->pop_state ();
1022                 $$ = $4;
1023         }
1024         | WITH CONTEXT_MOD_IDENTIFIER
1025         {
1026                 $$ = $2;
1027         }
1028         | CONTEXT_MOD_IDENTIFIER
1029         {
1030                 $$ = $1;
1031         }
1032         ;
1033
1034 optional_context_mod:
1035         /**/ {
1036             $$ = SCM_EOL;
1037         }
1038         | context_modification
1039         {
1040               $$ = $1;
1041         }
1042         ;
1043
1044 context_mod_list:
1045         /**/ {
1046             $$ = Context_mod ().smobbed_copy ();
1047         }
1048         | context_mod_list context_mod  {
1049                  unsmob_context_mod ($1)->add_context_mod ($2);
1050         }
1051         | context_mod_list CONTEXT_MOD_IDENTIFIER {
1052                  Context_mod *md = unsmob_context_mod ($2);
1053                  if (md)
1054                      unsmob_context_mod ($1)->add_context_mods (md->get_mods ());
1055         }
1056         ;
1057
1058 composite_music:
1059         prefix_composite_music { $$ = $1; }
1060         | grouped_music_list { $$ = $1; }
1061         ;
1062
1063 grouped_music_list:
1064         simultaneous_music              { $$ = $1; }
1065         | sequential_music              { $$ = $1; }
1066         ;
1067
1068 function_scm_argument:
1069         embedded_scm
1070         | simple_string
1071         ;
1072
1073 /* An argument list. If a function \foo expects scm scm music, then the lexer expands \foo into the token sequence:
1074  MUSIC_FUNCTION EXPECT_MUSIC EXPECT_SCM EXPECT_SCM EXPECT_NO_MORE_ARGS
1075 and this rule returns the reversed list of arguments. */
1076
1077 function_arglist_music_last:
1078         EXPECT_MUSIC function_arglist music {
1079                 $$ = scm_cons ($3, $2);
1080         }
1081         ;
1082
1083 function_arglist_nonmusic_last:
1084         EXPECT_MARKUP function_arglist full_markup {
1085                 $$ = scm_cons ($3, $2);
1086         }
1087         | EXPECT_MARKUP function_arglist simple_string {
1088                 $$ = scm_cons ($3, $2);
1089         }
1090         | EXPECT_SCM function_arglist function_scm_argument {
1091                 $$ = scm_cons ($3, $2);
1092         }
1093         ;
1094
1095 function_arglist_nonmusic: EXPECT_NO_MORE_ARGS {
1096                 $$ = SCM_EOL;
1097         }
1098         | EXPECT_MARKUP function_arglist_nonmusic full_markup {
1099                 $$ = scm_cons ($3, $2);
1100         }
1101         | EXPECT_MARKUP function_arglist_nonmusic simple_string {
1102                 $$ = scm_cons ($3, $2);
1103         }
1104         | EXPECT_SCM function_arglist_nonmusic function_scm_argument {
1105                 $$ = scm_cons ($3, $2);
1106         }
1107         ;
1108
1109 function_arglist: EXPECT_NO_MORE_ARGS {
1110                 /* This is for 0-ary functions, so they don't need to
1111                    read a lookahead token */
1112                 $$ = SCM_EOL;
1113         }
1114         | function_arglist_music_last
1115         | function_arglist_nonmusic_last
1116         ;
1117
1118 generic_prefix_music_scm:
1119         MUSIC_FUNCTION function_arglist {
1120                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
1121         }
1122         ;
1123
1124
1125 optional_id:
1126         /**/ { $$ = SCM_EOL; }
1127         | '=' simple_string {
1128                 $$ = $2;
1129         }
1130         ;
1131
1132
1133 prefix_composite_music:
1134         generic_prefix_music_scm {
1135                 $$ = run_music_function (PARSER, $1);
1136         }
1137         | CONTEXT simple_string optional_id optional_context_mod music {
1138                 Context_mod *ctxmod = unsmob_context_mod ($4);
1139                 SCM mods = SCM_EOL;
1140                 if (ctxmod)
1141                         mods = ctxmod->get_mods ();
1142                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, mods, SCM_BOOL_F);
1143         }
1144         | NEWCONTEXT simple_string optional_id optional_context_mod music {
1145                 Context_mod *ctxmod = unsmob_context_mod ($4);
1146                 SCM mods = SCM_EOL;
1147                 if (ctxmod)
1148                         mods = ctxmod->get_mods ();
1149                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, mods, SCM_BOOL_T);
1150         }
1151
1152         | TIMES fraction music {
1153                 $$ = MAKE_SYNTAX ("time-scaled-music", @$, $2, $3);
1154         }
1155         | repeated_music                { $$ = $1; }
1156         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords music {
1157                 Pitch from = *unsmob_pitch ($2);
1158                 Pitch to = *unsmob_pitch ($3);
1159                 SCM pitch = pitch_interval (from, to).smobbed_copy ();
1160                 $$ = MAKE_SYNTAX ("transpose-music", @$, pitch, $4);
1161         }
1162         | mode_changing_head grouped_music_list {
1163                 if ($1 == ly_symbol2scm ("chords"))
1164                 {
1165                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
1166                 }
1167                 else
1168                 {
1169                   $$ = $2;
1170                 }
1171                 PARSER->lexer_->pop_state ();
1172         }
1173         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1174                 Context_mod *ctxmod = unsmob_context_mod ($2);
1175                 SCM mods = SCM_EOL;
1176                 if (ctxmod)
1177                         mods = ctxmod->get_mods ();
1178                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, $3, mods, SCM_BOOL_T);
1179                 if ($1 == ly_symbol2scm ("ChordNames"))
1180                 {
1181                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1182                 }
1183                 PARSER->lexer_->pop_state ();
1184         }
1185         | relative_music        { $$ = $1; }
1186         | re_rhythmed_music     { $$ = $1; }
1187         ;
1188
1189 mode_changing_head:
1190         NOTEMODE {
1191                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1192                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1193
1194                 $$ = ly_symbol2scm ("notes");
1195         }
1196         | DRUMMODE
1197                 {
1198                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1199                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1200
1201                 $$ = ly_symbol2scm ("drums");
1202         }
1203         | FIGUREMODE {
1204                 PARSER->lexer_->push_figuredbass_state ();
1205
1206                 $$ = ly_symbol2scm ("figures");
1207         }
1208         | CHORDMODE {
1209                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1210                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1211                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1212                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1213                 $$ = ly_symbol2scm ("chords");
1214
1215         }
1216         | LYRICMODE
1217                 { PARSER->lexer_->push_lyric_state ();
1218                 $$ = ly_symbol2scm ("lyrics");
1219         }
1220         ;
1221
1222 mode_changing_head_with_context:
1223         DRUMS {
1224                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1225                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1226
1227                 $$ = ly_symbol2scm ("DrumStaff");
1228         }
1229         | FIGURES {
1230                 PARSER->lexer_->push_figuredbass_state ();
1231
1232                 $$ = ly_symbol2scm ("FiguredBass");
1233         }
1234         | CHORDS {
1235                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1236                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1237                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1238                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1239                 $$ = ly_symbol2scm ("ChordNames");
1240         }
1241         | LYRICS
1242                 { PARSER->lexer_->push_lyric_state ();
1243                 $$ = ly_symbol2scm ("Lyrics");
1244         }
1245         ;
1246
1247
1248 relative_music:
1249         RELATIVE absolute_pitch music {
1250                 Pitch start = *unsmob_pitch ($2);
1251                 $$ = make_music_relative (start, $3, @$);
1252         }
1253         | RELATIVE composite_music {
1254                 Pitch middle_c (0, 0, 0);
1255                 $$ = make_music_relative (middle_c, $2, @$);
1256         }
1257         ;
1258
1259 new_lyrics:
1260         ADDLYRICS { PARSER->lexer_->push_lyric_state (); }
1261         /*cont */
1262         grouped_music_list {
1263         /* Can also use music at the expensive of two S/Rs similar to
1264            \repeat \alternative */
1265                 PARSER->lexer_->pop_state ();
1266
1267                 $$ = scm_cons ($3, SCM_EOL);
1268         }
1269         | ADDLYRICS {
1270                 PARSER->lexer_->push_lyric_state (); }
1271         MUSIC_IDENTIFIER {
1272                 PARSER->lexer_->pop_state ();
1273                 $$ = scm_cons ($3, SCM_EOL);
1274         }
1275         | new_lyrics ADDLYRICS {
1276                 PARSER->lexer_->push_lyric_state ();
1277         } grouped_music_list {
1278                 PARSER->lexer_->pop_state ();
1279                 $$ = scm_cons ($4, $1);
1280         }
1281         | new_lyrics ADDLYRICS {
1282                 PARSER->lexer_->push_lyric_state ();
1283         } MUSIC_IDENTIFIER {
1284                 PARSER->lexer_->pop_state ();
1285                 $$ = scm_cons ($4, $1);
1286         }
1287         ;
1288
1289 re_rhythmed_music:
1290         grouped_music_list new_lyrics {
1291                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1292         }
1293         | MUSIC_IDENTIFIER new_lyrics {
1294                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1295         }
1296         | LYRICSTO simple_string {
1297                 PARSER->lexer_->push_lyric_state ();
1298         } music {
1299                 PARSER->lexer_->pop_state ();
1300                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
1301         }
1302         ;
1303
1304 context_change:
1305         CHANGE STRING '=' STRING  {
1306                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
1307         }
1308         ;
1309
1310
1311 property_path_revved:
1312         embedded_scm {
1313                 $$ = scm_cons ($1, SCM_EOL);
1314         }
1315         | property_path_revved embedded_scm {
1316                 $$ = scm_cons ($2, $1);
1317         }
1318         ;
1319
1320 property_path:
1321         property_path_revved  {
1322                 $$ = scm_reverse_x ($1, SCM_EOL);
1323         }
1324         ;
1325
1326 property_operation:
1327         STRING '=' scalar {
1328                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1329                         scm_string_to_symbol ($1), $3);
1330         }
1331         | UNSET simple_string {
1332                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1333                         scm_string_to_symbol ($2));
1334         }
1335         | OVERRIDE simple_string property_path '=' scalar {
1336                 $$ = scm_append (scm_list_2 (scm_list_3 (ly_symbol2scm ("push"),
1337                                                         scm_string_to_symbol ($2), $5),
1338                                              $3));
1339         }
1340         | REVERT simple_string embedded_scm {
1341                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1342                         scm_string_to_symbol ($2), $3);
1343         }
1344         ;
1345
1346 context_def_mod:
1347         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1348         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1349
1350         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1351         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1352         | DENIES { $$ = ly_symbol2scm ("denies"); }
1353
1354         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1355         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1356         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1357         | NAME { $$ = ly_symbol2scm ("context-name"); }
1358         ;
1359
1360 context_mod:
1361         property_operation { $$ = $1; }
1362         | context_def_mod STRING {
1363                 $$ = scm_list_2 ($1, $2);
1364         }
1365         | context_def_mod embedded_scm {
1366            if (ly_symbol2scm ("consists") != $1)
1367            {
1368              $$ = SCM_EOL;
1369              PARSER->parser_error (@1, _ ("only \\consists takes non-string argument."));
1370            }
1371            else
1372            {
1373              $$ = scm_list_2 ($1, $2);
1374            }
1375         }
1376         ;
1377
1378 context_prop_spec:
1379         simple_string {
1380                 if (!is_regular_identifier ($1))
1381                 {
1382                         @$.error (_("Grob name should be alphanumeric"));
1383                 }
1384
1385                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1386                         scm_string_to_symbol ($1));
1387         }
1388         | simple_string '.' simple_string {
1389                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1390                         scm_string_to_symbol ($3));
1391         }
1392         ;
1393
1394 simple_music_property_def:
1395         OVERRIDE context_prop_spec property_path '=' scalar {
1396                 $$ = scm_append (scm_list_2 (scm_list_n (scm_car ($2),
1397                                 ly_symbol2scm ("OverrideProperty"),
1398                                 scm_cadr ($2),
1399                                 $5, SCM_UNDEFINED),
1400                                 $3));
1401         }
1402         | REVERT context_prop_spec embedded_scm {
1403                 $$ = scm_list_4 (scm_car ($2),
1404                         ly_symbol2scm ("RevertProperty"),
1405                         scm_cadr ($2),
1406                         $3);
1407         }
1408         | SET context_prop_spec '=' scalar {
1409                 $$ = scm_list_4 (scm_car ($2),
1410                         ly_symbol2scm ("PropertySet"),
1411                         scm_cadr ($2),
1412                         $4);
1413         }
1414         | UNSET context_prop_spec {
1415                 $$ = scm_list_3 (scm_car ($2),
1416                         ly_symbol2scm ("PropertyUnset"),
1417                         scm_cadr ($2));
1418         }
1419         ;
1420
1421 music_property_def:
1422         simple_music_property_def {
1423                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_F, $1)));
1424         }
1425         | ONCE simple_music_property_def {
1426                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_T, $2)));
1427         }
1428         ;
1429
1430 string:
1431         STRING {
1432                 $$ = $1;
1433         }
1434         | STRING_IDENTIFIER {
1435                 $$ = $1;
1436         }
1437         | string '+' string {
1438                 $$ = scm_string_append (scm_list_2 ($1, $3));
1439         }
1440         ;
1441
1442 simple_string: STRING {
1443                 $$ = $1;
1444         }
1445         | LYRICS_STRING {
1446                 $$ = $1;
1447         }
1448         | STRING_IDENTIFIER {
1449                 $$ = $1;
1450         }
1451         ;
1452
1453 scalar: string {
1454                 $$ = $1;
1455         }
1456         | LYRICS_STRING {
1457                 $$ = $1;
1458         }
1459         | bare_number {
1460                 $$ = $1;
1461         }
1462         | embedded_scm {
1463                 $$ = $1;
1464         }
1465         | full_markup {
1466                 $$ = $1;
1467         }
1468         | DIGIT {
1469                 $$ = scm_from_int ($1);
1470         }
1471         ;
1472
1473 event_chord:
1474         /* TODO: Create a special case that avoids the creation of
1475            EventChords around simple_elements that have no post_events?
1476          */
1477         simple_chord_elements post_events       {
1478                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
1479
1480                 Input i;
1481                 /* why is this giving wrong start location? -ns
1482                  * i = @$; */
1483                 i.set_location (@1, @2);
1484                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
1485         }
1486         | CHORD_REPETITION optional_notemode_duration post_events {
1487                 Input i;
1488                 i.set_location (@1, @3);
1489                 $$ = MAKE_SYNTAX ("repetition-chord", i,
1490                                   PARSER->lexer_->chord_repetition_.last_chord_,
1491                                   PARSER->lexer_->chord_repetition_.repetition_function_,
1492                                   $2, scm_reverse_x ($3, SCM_EOL));
1493         }
1494         | MULTI_MEASURE_REST optional_notemode_duration post_events {
1495                 Input i;
1496                 i.set_location (@1, @3);
1497                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2,
1498                                   scm_reverse_x ($3, SCM_EOL));
1499         }
1500         | command_element
1501         /* note chord elements are memorized into
1502            PARSER->lexer_->chord_repetition_ so that the chord repetition
1503            mechanism copy them when a chord repetition symbol is found
1504         */
1505         | note_chord_element    {
1506                 PARSER->lexer_->chord_repetition_.last_chord_ = $$;
1507         }
1508         ;
1509
1510
1511 note_chord_element:
1512         chord_body optional_notemode_duration post_events
1513         {
1514                 Music *m = unsmob_music ($1);
1515                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1516                 SCM es = m->get_property ("elements");
1517                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1518
1519                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1520                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1521                 es = ly_append2 (es, postevs);
1522
1523                 m-> set_property ("elements", es);
1524                 m->set_spot (@$);
1525                 $$ = m->self_scm ();
1526         }
1527         ;
1528
1529 chord_body:
1530         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
1531         {
1532                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
1533         }
1534         ;
1535
1536 chord_body_elements:
1537         /* empty */             { $$ = SCM_EOL; }
1538         | chord_body_elements chord_body_element {
1539                 $$ = scm_cons ($2, $1);
1540         }
1541         ;
1542
1543 chord_body_element:
1544         pitch exclamations questions octave_check post_events
1545         {
1546                 int q = $3;
1547                 int ex = $2;
1548                 SCM check = $4;
1549                 SCM post = $5;
1550
1551                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1552                 n->set_property ("pitch", $1);
1553                 if (q % 2)
1554                         n->set_property ("cautionary", SCM_BOOL_T);
1555                 if (ex % 2 || q % 2)
1556                         n->set_property ("force-accidental", SCM_BOOL_T);
1557
1558                 if (scm_is_pair (post)) {
1559                         SCM arts = scm_reverse_x (post, SCM_EOL);
1560                         n->set_property ("articulations", arts);
1561                 }
1562                 if (scm_is_number (check))
1563                 {
1564                         int q = scm_to_int (check);
1565                         n->set_property ("absolute-octave", scm_from_int (q-1));
1566                 }
1567
1568                 $$ = n->unprotect ();
1569         }
1570         | DRUM_PITCH post_events {
1571                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1572                 n->set_property ("duration", $2);
1573                 n->set_property ("drum-type", $1);
1574
1575                 if (scm_is_pair ($2)) {
1576                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1577                         n->set_property ("articulations", arts);
1578                 }
1579                 $$ = n->unprotect ();
1580         }
1581         | music_function_chord_body {
1582                 $$ = run_music_function (PARSER, $1);
1583         }
1584         ;
1585
1586 music_function_identifier_musicless_prefix: MUSIC_FUNCTION {
1587                 SCM sig = scm_object_property (yylval.scm, ly_symbol2scm ("music-function-signature"));
1588                 if (scm_is_pair (sig) && to_boolean (scm_memq (ly_music_p_proc, scm_cdr (scm_reverse (sig)))))
1589                 {
1590                         PARSER->parser_error (@$, "Music function applied to event may not have a Music argument, except as the last argument.");
1591                 }
1592         }
1593         ;
1594
1595 music_function_chord_body:
1596         /* We could allow chord functions to have multiple music arguments,
1597            but it's more consistent with music_function_event if we
1598            prohibit it here too */
1599         music_function_identifier_musicless_prefix EXPECT_MUSIC function_arglist_nonmusic chord_body_element {
1600                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($3, scm_list_1 ($4)));
1601         }
1602         | music_function_identifier_musicless_prefix function_arglist_nonmusic {
1603                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
1604         }
1605         ;
1606
1607 music_function_event:
1608         /* Post-events can only have the last argument as music, without this
1609            restriction we get a shift/reduce conflict from e.g.
1610            c8-\partcombine c8 -. */
1611         music_function_identifier_musicless_prefix EXPECT_MUSIC function_arglist_nonmusic post_event {
1612                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($3, scm_list_1 ($4)));
1613         }
1614         | music_function_identifier_musicless_prefix function_arglist_nonmusic {
1615                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
1616         }
1617         ;
1618
1619 command_element:
1620         command_event {
1621                 $$ = $1;
1622         }
1623         | SKIP duration_length {
1624                 $$ = MAKE_SYNTAX ("skip-music", @$, $2);
1625         }
1626         | E_BRACKET_OPEN {
1627                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1628                 m->set_property ("span-direction", scm_from_int (START));
1629                 $$ = m->unprotect();
1630         }
1631         | E_BRACKET_CLOSE {
1632                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1633                 m->set_property ("span-direction", scm_from_int (STOP));
1634                 $$ = m->unprotect ();
1635         }
1636         | E_BACKSLASH {
1637                 $$ = MAKE_SYNTAX ("voice-separator", @$, SCM_UNDEFINED);
1638         }
1639         | '|'      {
1640                 SCM pipe = PARSER->lexer_->lookup_identifier ("pipeSymbol");
1641
1642                 Music *m = unsmob_music (pipe);
1643                 if (m)
1644                 {
1645                         m = m->clone ();
1646                         m->set_spot (@$);
1647                         $$ = m->unprotect ();
1648                 }
1649                 else
1650                         $$ = MAKE_SYNTAX ("bar-check", @$, SCM_UNDEFINED);
1651
1652         }
1653         | PARTIAL duration_length       {
1654                 $$ = MAKE_SYNTAX ("partial", @$, $2);
1655         }
1656
1657         | TIME_T fraction  {
1658                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1659
1660                 $$ = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1661         }
1662         | MARK scalar {
1663                 $$ = MAKE_SYNTAX ("make-mark-set", @$, $2);
1664         }
1665         ;
1666
1667 command_event:
1668         E_TILDE {
1669                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent", @$)->unprotect ();
1670         }
1671         | MARK DEFAULT  {
1672                 Music *m = MY_MAKE_MUSIC ("MarkEvent", @$);
1673                 $$ = m->unprotect ();
1674         }
1675         | tempo_event {
1676                 $$ = $1;
1677         }
1678         | KEY DEFAULT {
1679                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1680                 $$ = key->unprotect ();
1681         }
1682         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1683
1684                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1685                 if (scm_ilength ($3) > 0)
1686                 {
1687                         key->set_property ("pitch-alist", $3);
1688                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1689                         key->transpose (* unsmob_pitch ($2));
1690                 } else {
1691                         PARSER->parser_error (@3, _ ("second argument must be pitch list"));
1692                 }
1693
1694                 $$ = key->unprotect ();
1695         }
1696         ;
1697
1698
1699 post_events:
1700         /* empty */ {
1701                 $$ = SCM_EOL;
1702         }
1703         | post_events post_event {
1704                 unsmob_music ($2)->set_spot (@2);
1705                 $$ = scm_cons ($2, $$);
1706         }
1707         ;
1708
1709 post_event:
1710         direction_less_event {
1711                 $$ = $1;
1712         }
1713         | script_dir music_function_event {
1714                 $$ = run_music_function (PARSER, $2);
1715                 if ($1)
1716                 {
1717                         unsmob_music ($$)->set_property ("direction", scm_from_int ($1));
1718                 }
1719         }
1720         | HYPHEN {
1721                 if (!PARSER->lexer_->is_lyric_state ())
1722                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1723                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
1724         }
1725         | EXTENDER {
1726                 if (!PARSER->lexer_->is_lyric_state ())
1727                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1728                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
1729         }
1730         | script_dir direction_reqd_event {
1731                 if ($1)
1732                 {
1733                         Music *m = unsmob_music ($2);
1734                         m->set_property ("direction", scm_from_int ($1));
1735                 }
1736                 $$ = $2;
1737         }
1738         | script_dir direction_less_event {
1739                 if ($1)
1740                 {
1741                         Music *m = unsmob_music ($2);
1742                         m->set_property ("direction", scm_from_int ($1));
1743                 }
1744                 $$ = $2;
1745         }
1746         | string_number_event
1747         ;
1748
1749 string_number_event:
1750         E_UNSIGNED {
1751                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
1752                 s->set_property ("string-number", scm_from_int ($1));
1753                 $$ = s->unprotect ();
1754         }
1755         ;
1756
1757 direction_less_char:
1758         '['  {
1759                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1760         }
1761         | ']'  {
1762                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1763         }
1764         | '~'  {
1765                 $$ = ly_symbol2scm ("tildeSymbol");
1766         }
1767         | '('  {
1768                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1769         }
1770         | ')'  {
1771                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1772         }
1773         | E_EXCLAMATION  {
1774                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1775         }
1776         | E_OPEN  {
1777                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1778         }
1779         | E_CLOSE  {
1780                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1781         }
1782         | E_ANGLE_CLOSE  {
1783                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1784         }
1785         | E_ANGLE_OPEN  {
1786                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1787         }
1788         ;
1789
1790 direction_less_event:
1791         direction_less_char {
1792                 SCM predefd = PARSER->lexer_->lookup_identifier_symbol ($1);
1793                 Music *m = 0;
1794                 if (unsmob_music (predefd))
1795                 {
1796                         m = unsmob_music (predefd)->clone ();
1797                         m->set_spot (@$);
1798                 }
1799                 else
1800                 {
1801                         m = MY_MAKE_MUSIC ("Music", @$);
1802                 }
1803                 $$ = m->unprotect ();
1804         }
1805         | EVENT_IDENTIFIER      {
1806                 $$ = $1;
1807         }
1808         | tremolo_type  {
1809                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
1810                a->set_property ("tremolo-type", scm_from_int ($1));
1811                $$ = a->unprotect ();
1812         }
1813         ;
1814
1815 direction_reqd_event:
1816         gen_text_def {
1817                 $$ = $1;
1818         }
1819         | script_abbreviation {
1820                 SCM s = PARSER->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1821                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
1822                 if (scm_is_string (s))
1823                         a->set_property ("articulation-type", s);
1824                 else PARSER->parser_error (@1, _ ("expecting string as script definition"));
1825                 $$ = a->unprotect ();
1826         }
1827         ;
1828
1829 octave_check:
1830         /**/ { $$ = SCM_EOL; }
1831         | '='  { $$ = scm_from_int (0); }
1832         | '=' sub_quotes { $$ = scm_from_int (-$2); }
1833         | '=' sup_quotes { $$ = scm_from_int ($2); }
1834         ;
1835
1836 sup_quotes:
1837         '\'' {
1838                 $$ = 1;
1839         }
1840         | sup_quotes '\'' {
1841                 $$ ++;
1842         }
1843         ;
1844
1845 sub_quotes:
1846         ',' {
1847                 $$ = 1;
1848         }
1849         | sub_quotes ',' {
1850                 $$++;
1851         }
1852         ;
1853
1854 steno_pitch:
1855         NOTENAME_PITCH  {
1856                 $$ = $1;
1857         }
1858         | NOTENAME_PITCH sup_quotes     {
1859                 Pitch p = *unsmob_pitch ($1);
1860                 p = p.transposed (Pitch ($2,0,0));
1861                 $$ = p.smobbed_copy ();
1862         }
1863         | NOTENAME_PITCH sub_quotes      {
1864                 Pitch p =* unsmob_pitch ($1);
1865                 p = p.transposed (Pitch (-$2,0,0));
1866                 $$ = p.smobbed_copy ();
1867         }
1868         ;
1869
1870 /*
1871 ugh. duplication
1872 */
1873
1874 steno_tonic_pitch:
1875         TONICNAME_PITCH {
1876                 $$ = $1;
1877         }
1878         | TONICNAME_PITCH sup_quotes    {
1879                 Pitch p = *unsmob_pitch ($1);
1880                 p = p.transposed (Pitch ($2,0,0));
1881                 $$ = p.smobbed_copy ();
1882         }
1883         | TONICNAME_PITCH sub_quotes     {
1884                 Pitch p = *unsmob_pitch ($1);
1885
1886                 p = p.transposed (Pitch (-$2,0,0));
1887                 $$ = p.smobbed_copy ();
1888         }
1889         ;
1890
1891 pitch:
1892         steno_pitch {
1893                 $$ = $1;
1894         }
1895         ;
1896
1897 pitch_also_in_chords:
1898         pitch
1899         | steno_tonic_pitch
1900         ;
1901
1902 gen_text_def:
1903         full_markup {
1904                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
1905                 t->set_property ("text", $1);
1906                 $$ = t->unprotect ();
1907         }
1908         | string {
1909                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
1910                 t->set_property ("text",
1911                         make_simple_markup ($1));
1912                 $$ = t->unprotect ();
1913         }
1914         | DIGIT {
1915                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
1916                 t->set_property ("digit", scm_from_int ($1));
1917                 $$ = t->unprotect ();
1918         }
1919         ;
1920
1921 script_abbreviation:
1922         '^'             {
1923                 $$ = scm_from_locale_string ("Hat");
1924         }
1925         | '+'           {
1926                 $$ = scm_from_locale_string ("Plus");
1927         }
1928         | '-'           {
1929                 $$ = scm_from_locale_string ("Dash");
1930         }
1931         | '|'           {
1932                 $$ = scm_from_locale_string ("Bar");
1933         }
1934         | ANGLE_CLOSE   {
1935                 $$ = scm_from_locale_string ("Larger");
1936         }
1937         | '.'           {
1938                 $$ = scm_from_locale_string ("Dot");
1939         }
1940         | '_' {
1941                 $$ = scm_from_locale_string ("Underscore");
1942         }
1943         ;
1944
1945 script_dir:
1946         '_'     { $$ = DOWN; }
1947         | '^'   { $$ = UP; }
1948         | '-'   { $$ = CENTER; }
1949         ;
1950
1951
1952 absolute_pitch:
1953         steno_pitch     {
1954                 $$ = $1;
1955         }
1956         ;
1957
1958 duration_length:
1959         multiplied_duration {
1960                 $$ = $1;
1961         }
1962         ;
1963
1964 optional_notemode_duration:
1965         {
1966                 Duration dd = PARSER->default_duration_;
1967                 $$ = dd.smobbed_copy ();
1968         }
1969         | multiplied_duration   {
1970                 $$ = $1;
1971                 PARSER->default_duration_ = *unsmob_duration ($$);
1972         }
1973         ;
1974
1975 steno_duration:
1976         bare_unsigned dots              {
1977                 int len = 0;
1978                 if (!is_duration ($1))
1979                         PARSER->parser_error (@1, _f ("not a duration: %d", $1));
1980                 else
1981                         len = intlog2 ($1);
1982
1983                 $$ = Duration (len, $2).smobbed_copy ();
1984         }
1985         | DURATION_IDENTIFIER dots      {
1986                 Duration *d = unsmob_duration ($1);
1987                 Duration k (d->duration_log (), d->dot_count () + $2);
1988                 k = k.compressed (d->factor ());
1989                 *d = k;
1990                 $$ = $1;
1991         }
1992         ;
1993
1994 multiplied_duration:
1995         steno_duration {
1996                 $$ = $1;
1997         }
1998         | multiplied_duration '*' bare_unsigned {
1999                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2000         }
2001         | multiplied_duration '*' FRACTION {
2002                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2003
2004                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2005         }
2006         ;
2007
2008 fraction:
2009         FRACTION { $$ = $1; }
2010         | UNSIGNED '/' UNSIGNED {
2011                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2012         }
2013         ;
2014
2015 dots:
2016         /* empty */     {
2017                 $$ = 0;
2018         }
2019         | dots '.' {
2020                 $$ ++;
2021         }
2022         ;
2023
2024 tremolo_type:
2025         ':'     {
2026                 $$ = 0;
2027         }
2028         | ':' bare_unsigned {
2029                 if (!is_duration ($2))
2030                         PARSER->parser_error (@2, _f ("not a duration: %d", $2));
2031                 $$ = $2;
2032         }
2033         ;
2034
2035 bass_number:
2036         DIGIT   {
2037                 $$ = scm_from_int ($1);
2038         }
2039         | UNSIGNED {
2040                 $$ = scm_from_int ($1);
2041         }
2042         | STRING { $$ = $1; }
2043         | full_markup { $$ = $1; }
2044         ;
2045
2046 figured_bass_alteration:
2047         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
2048         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
2049         | '!'   { $$ = scm_from_int (0); }
2050         ;
2051
2052 bass_figure:
2053         FIGURE_SPACE {
2054                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2055                 $$ = bfr->unprotect ();
2056         }
2057         | bass_number  {
2058                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2059                 $$ = bfr->self_scm ();
2060
2061                 if (scm_is_number ($1))
2062                         bfr->set_property ("figure", $1);
2063                 else if (Text_interface::is_markup ($1))
2064                         bfr->set_property ("text", $1);
2065
2066                 bfr->unprotect ();
2067         }
2068         | bass_figure ']' {
2069                 $$ = $1;
2070                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2071         }
2072         | bass_figure figured_bass_alteration {
2073                 Music *m = unsmob_music ($1);
2074                 if (scm_to_double ($2)) {
2075                         SCM salter = m->get_property ("alteration");
2076                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
2077                         m->set_property ("alteration",
2078                                          scm_sum (alter, $2));
2079                 } else {
2080                         m->set_property ("alteration", scm_from_int (0));
2081                 }
2082         }
2083         | bass_figure figured_bass_modification  {
2084                 Music *m = unsmob_music ($1);
2085                 if ($2 == ly_symbol2scm ("plus"))
2086                         {
2087                         m->set_property ("augmented", SCM_BOOL_T);
2088                         }
2089                 else if ($2 == ly_symbol2scm ("slash"))
2090                         {
2091                         m->set_property ("diminished", SCM_BOOL_T);
2092                         }
2093                 else if ($2 == ly_symbol2scm ("exclamation"))
2094                         {
2095                         m->set_property ("no-continuation", SCM_BOOL_T);
2096                         }
2097                 else if ($2 == ly_symbol2scm ("backslash"))
2098                         {
2099                         m->set_property ("augmented-slash", SCM_BOOL_T);
2100                         }
2101         }
2102         ;
2103
2104
2105 figured_bass_modification:
2106         E_PLUS          {
2107                 $$ = ly_symbol2scm ("plus");
2108         }
2109         | E_EXCLAMATION {
2110                 $$ = ly_symbol2scm ("exclamation");
2111         }
2112         | '/'           {
2113                 $$ = ly_symbol2scm ("slash");
2114         }
2115         | E_BACKSLASH {
2116                 $$ = ly_symbol2scm ("backslash");
2117         }
2118         ;
2119
2120 br_bass_figure:
2121         bass_figure {
2122                 $$ = $1;
2123         }
2124         | '[' bass_figure {
2125                 $$ = $2;
2126                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2127         }
2128         ;
2129
2130 figure_list:
2131         /**/            {
2132                 $$ = SCM_EOL;
2133         }
2134         | figure_list br_bass_figure {
2135                 $$ = scm_cons ($2, $1);
2136         }
2137         ;
2138
2139 figure_spec:
2140         FIGURE_OPEN figure_list FIGURE_CLOSE {
2141                 $$ = scm_reverse_x ($2, SCM_EOL);
2142         }
2143         ;
2144
2145
2146 optional_rest:
2147         /**/   { $$ = 0; }
2148         | REST { $$ = 1; }
2149         ;
2150
2151 simple_element:
2152         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2153                 if (!PARSER->lexer_->is_note_state ())
2154                         PARSER->parser_error (@1, _ ("have to be in Note mode for notes"));
2155
2156                 Music *n = 0;
2157                 if ($6)
2158                         n = MY_MAKE_MUSIC ("RestEvent", @$);
2159                 else
2160                         n = MY_MAKE_MUSIC ("NoteEvent", @$);
2161
2162                 n->set_property ("pitch", $1);
2163                 n->set_property ("duration", $5);
2164
2165                 if (scm_is_number ($4))
2166                 {
2167                         int q = scm_to_int ($4);
2168                         n->set_property ("absolute-octave", scm_from_int (q-1));
2169                 }
2170
2171                 if ($3 % 2)
2172                         n->set_property ("cautionary", SCM_BOOL_T);
2173                 if ($2 % 2 || $3 % 2)
2174                         n->set_property ("force-accidental", SCM_BOOL_T);
2175
2176                 $$ = n->unprotect ();
2177         }
2178         | DRUM_PITCH optional_notemode_duration {
2179                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2180                 n->set_property ("duration", $2);
2181                 n->set_property ("drum-type", $1);
2182
2183                 $$ = n->unprotect ();
2184         }
2185         | RESTNAME optional_notemode_duration           {
2186                 Music *ev = 0;
2187                 if (ly_scm2string ($1) == "s") {
2188                         /* Space */
2189                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
2190                   }
2191                 else {
2192                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
2193
2194                     }
2195                 ev->set_property ("duration", $2);
2196                 $$ = ev->unprotect ();
2197         }
2198         | lyric_element optional_notemode_duration      {
2199                 if (!PARSER->lexer_->is_lyric_state ())
2200                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2201
2202                 Music *levent = MY_MAKE_MUSIC ("LyricEvent", @$);
2203                 levent->set_property ("text", $1);
2204                 levent->set_property ("duration",$2);
2205                 $$= levent->unprotect ();
2206         }
2207         ;
2208
2209 simple_chord_elements:
2210         simple_element  {
2211                 $$ = scm_list_1 ($1);
2212         }
2213         | new_chord {
2214                 if (!PARSER->lexer_->is_chord_state ())
2215                         PARSER->parser_error (@1, _ ("have to be in Chord mode for chords"));
2216                 $$ = $1;
2217         }
2218         | figure_spec optional_notemode_duration {
2219                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
2220                 {
2221                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2222                 }
2223                 $$ = $1;
2224         }
2225         ;
2226
2227 lyric_element:
2228         lyric_markup {
2229                 $$ = $1;
2230         }
2231         | LYRICS_STRING {
2232                 $$ = $1;
2233         }
2234         ;
2235
2236 new_chord:
2237         steno_tonic_pitch optional_notemode_duration   {
2238                 $$ = make_chord_elements ($1, $2, SCM_EOL);
2239         }
2240         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2241                 SCM its = scm_reverse_x ($4, SCM_EOL);
2242                 $$ = make_chord_elements ($1, $2, scm_cons ($3, its));
2243         }
2244         ;
2245
2246 chord_items:
2247         /**/ {
2248                 $$ = SCM_EOL;
2249         }
2250         | chord_items chord_item {
2251                 $$ = scm_cons ($2, $$);
2252         }
2253         ;
2254
2255 chord_separator:
2256         CHORD_COLON {
2257                 $$ = ly_symbol2scm ("chord-colon");
2258         }
2259         | CHORD_CARET {
2260                 $$ = ly_symbol2scm ("chord-caret");
2261         }
2262         | CHORD_SLASH steno_tonic_pitch {
2263                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2264         }
2265         | CHORD_BASS steno_tonic_pitch {
2266                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2267         }
2268         ;
2269
2270 chord_item:
2271         chord_separator {
2272                 $$ = $1;
2273         }
2274         | step_numbers {
2275                 $$ = scm_reverse_x ($1, SCM_EOL);
2276         }
2277         | CHORD_MODIFIER  {
2278                 $$ = $1;
2279         }
2280         ;
2281
2282 step_numbers:
2283         step_number { $$ = scm_cons ($1, SCM_EOL); }
2284         | step_numbers '.' step_number {
2285                 $$ = scm_cons ($3, $$);
2286         }
2287         ;
2288
2289 step_number:
2290         bare_unsigned {
2291                 $$ = make_chord_step ($1, 0);
2292         }
2293         | bare_unsigned '+' {
2294                 $$ = make_chord_step ($1, SHARP_ALTERATION);
2295         }
2296         | bare_unsigned CHORD_MINUS {
2297                 $$ = make_chord_step ($1, FLAT_ALTERATION);
2298         }
2299         ;
2300
2301 tempo_range:
2302         bare_unsigned {
2303                 $$ = scm_from_int ($1);
2304         }
2305         | bare_unsigned '~' bare_unsigned {
2306                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2307         }
2308         ;
2309
2310 /*
2311         UTILITIES
2312
2313 TODO: should deprecate in favor of Scheme?
2314
2315  */
2316 number_expression:
2317         number_expression '+' number_term {
2318                 $$ = scm_sum ($1, $3);
2319         }
2320         | number_expression '-' number_term {
2321                 $$ = scm_difference ($1, $3);
2322         }
2323         | number_term
2324         ;
2325
2326 number_term:
2327         number_factor {
2328                 $$ = $1;
2329         }
2330         | number_factor '*' number_factor {
2331                 $$ = scm_product ($1, $3);
2332         }
2333         | number_factor '/' number_factor {
2334                 $$ = scm_divide ($1, $3);
2335         }
2336         ;
2337
2338 number_factor:
2339         '-'  number_factor { /* %prec UNARY_MINUS */
2340                 $$ = scm_difference ($2, SCM_UNDEFINED);
2341         }
2342         | bare_number
2343         ;
2344
2345
2346 bare_number:
2347         UNSIGNED        {
2348                 $$ = scm_from_int ($1);
2349         }
2350         | REAL          {
2351                 $$ = $1;
2352         }
2353         | NUMBER_IDENTIFIER             {
2354                 $$ = $1;
2355         }
2356         | REAL NUMBER_IDENTIFIER        {
2357                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2358         }
2359         | UNSIGNED NUMBER_IDENTIFIER    {
2360                 $$ = scm_from_double ($1 *scm_to_double ($2));
2361         }
2362         ;
2363
2364
2365 bare_unsigned:
2366         UNSIGNED {
2367                         $$ = $1;
2368         }
2369         | DIGIT {
2370                 $$ = $1;
2371         }
2372         ;
2373
2374 unsigned_number:
2375         bare_unsigned  { $$ = scm_from_int ($1); }
2376         | NUMBER_IDENTIFIER {
2377                 $$ = $1;
2378         }
2379         ;
2380
2381 exclamations:
2382                 { $$ = 0; }
2383         | exclamations '!'      { $$ ++; }
2384         ;
2385
2386 questions:
2387                 { $$ = 0; }
2388         | questions '?' { $$ ++; }
2389         ;
2390
2391 /*
2392 This should be done more dynamically if possible.
2393 */
2394
2395 lyric_markup:
2396         LYRIC_MARKUP_IDENTIFIER {
2397                 $$ = $1;
2398         }
2399         | LYRIC_MARKUP
2400                 { PARSER->lexer_->push_markup_state (); }
2401         markup_top {
2402                 $$ = $3;
2403                 PARSER->lexer_->pop_state ();
2404         }
2405         ;
2406
2407 full_markup_list:
2408         MARKUPLINES_IDENTIFIER {
2409                 $$ = $1;
2410         }
2411         | MARKUPLINES
2412                 { PARSER->lexer_->push_markup_state (); }
2413         markup_list {
2414                 $$ = $3;
2415                 PARSER->lexer_->pop_state ();
2416         }
2417         ;
2418
2419 full_markup:
2420         MARKUP_IDENTIFIER {
2421                 $$ = $1;
2422         }
2423         | MARKUP
2424                 { PARSER->lexer_->push_markup_state (); }
2425         markup_top {
2426                 $$ = $3;
2427                 PARSER->lexer_->pop_state ();
2428         }
2429         ;
2430
2431 markup_top:
2432         markup_list {
2433                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2434         }
2435         | markup_head_1_list simple_markup      {
2436                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2437         }
2438         | simple_markup {
2439                 $$ = $1;
2440         }
2441         ;
2442
2443 markup_list:
2444         MARKUPLINES_IDENTIFIER {
2445                 $$ = $1;
2446         }
2447         | markup_composed_list {
2448                 $$ = $1;
2449         }
2450         | markup_braced_list {
2451                 $$ = $1;
2452         }
2453         | markup_command_list {
2454                 $$ = scm_list_1 ($1);
2455         }
2456         ;
2457
2458 markup_composed_list:
2459         markup_head_1_list markup_braced_list {
2460                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2461
2462         }
2463         ;
2464
2465 markup_braced_list:
2466         '{' markup_braced_list_body '}' {
2467                 $$ = scm_reverse_x ($2, SCM_EOL);
2468         }
2469         ;
2470
2471 markup_braced_list_body:
2472         /* empty */     {  $$ = SCM_EOL; }
2473         | markup_braced_list_body markup {
2474                 $$ = scm_cons ($2, $1);
2475         }
2476         | markup_braced_list_body markup_list {
2477                 $$ = scm_reverse_x ($2, $1);
2478         }
2479         ;
2480
2481 markup_command_list:
2482         MARKUP_LIST_FUNCTION markup_command_list_arguments {
2483           $$ = scm_cons ($1, scm_reverse_x($2, SCM_EOL));
2484         }
2485         ;
2486
2487 markup_command_basic_arguments:
2488         EXPECT_MARKUP_LIST markup_command_list_arguments markup_list {
2489           $$ = scm_cons ($3, $2);
2490         }
2491         | EXPECT_SCM markup_command_list_arguments embedded_scm {
2492           $$ = scm_cons ($3, $2);
2493         }
2494         | EXPECT_NO_MORE_ARGS {
2495           $$ = SCM_EOL;
2496         }
2497         ;
2498
2499 markup_command_list_arguments:
2500         markup_command_basic_arguments { $$ = $1; }
2501         | EXPECT_MARKUP markup_command_list_arguments markup {
2502           $$ = scm_cons ($3, $2);
2503         }
2504         ;
2505
2506 markup_head_1_item:
2507         MARKUP_FUNCTION EXPECT_MARKUP markup_command_list_arguments {
2508           $$ = scm_cons ($1, scm_reverse_x ($3, SCM_EOL));
2509         }
2510         ;
2511
2512 markup_head_1_list:
2513         markup_head_1_item      {
2514                 $$ = scm_list_1 ($1);
2515         }
2516         | markup_head_1_list markup_head_1_item {
2517                 $$ = scm_cons ($2, $1);
2518         }
2519         ;
2520
2521 simple_markup:
2522         STRING {
2523                 $$ = make_simple_markup ($1);
2524         }
2525         | MARKUP_IDENTIFIER {
2526                 $$ = $1;
2527         }
2528         | LYRIC_MARKUP_IDENTIFIER {
2529                 $$ = $1;
2530         }
2531         | STRING_IDENTIFIER {
2532                 $$ = $1;
2533         }
2534         | SCORE {
2535                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
2536                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
2537         } '{' score_body '}' {
2538                 Score * sc = $4;
2539                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2540                 sc->unprotect ();
2541                 PARSER->lexer_->pop_state ();
2542         }
2543         | MARKUP_FUNCTION markup_command_basic_arguments {
2544                 $$ = scm_cons ($1, scm_reverse_x ($2, SCM_EOL));
2545         }
2546         ;
2547
2548 markup:
2549         markup_head_1_list simple_markup        {
2550                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2551                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2552         }
2553         | simple_markup {
2554                 $$ = $1;
2555         }
2556         ;
2557
2558 %%
2559
2560 void
2561 Lily_parser::set_yydebug (bool x)
2562 {
2563         yydebug = x;
2564 }
2565
2566 void
2567 Lily_parser::do_yyparse ()
2568 {
2569         yyparse ((void*)this);
2570 }
2571
2572
2573
2574
2575
2576 /*
2577
2578 It is a little strange to have this function in this file, but
2579 otherwise, we have to import music classes into the lexer.
2580
2581 */
2582 int
2583 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2584 {
2585         if (scm_is_string (sid)) {
2586                 *destination = sid;
2587                 return STRING_IDENTIFIER;
2588         } else if (unsmob_book (sid)) {
2589                 Book *book =  unsmob_book (sid)->clone ();
2590                 *destination = book->self_scm ();
2591                 book->unprotect ();
2592
2593                 return BOOK_IDENTIFIER;
2594         } else if (scm_is_number (sid)) {
2595                 *destination = sid;
2596                 return NUMBER_IDENTIFIER;
2597         } else if (unsmob_context_def (sid)) {
2598                 Context_def *def= unsmob_context_def (sid)->clone ();
2599
2600                 *destination = def->self_scm ();
2601                 def->unprotect ();
2602
2603                 return CONTEXT_DEF_IDENTIFIER;
2604         } else if (unsmob_context_mod (sid)) {
2605                 *destination = unsmob_context_mod (sid)->smobbed_copy ();
2606
2607                 return CONTEXT_MOD_IDENTIFIER;
2608         } else if (unsmob_score (sid)) {
2609                 Score *score = new Score (*unsmob_score (sid));
2610                 *destination = score->self_scm ();
2611
2612                 score->unprotect ();
2613                 return SCORE_IDENTIFIER;
2614         } else if (Music *mus = unsmob_music (sid)) {
2615                 mus = mus->clone ();
2616                 *destination = mus->self_scm ();
2617                 unsmob_music (*destination)->
2618                         set_property ("origin", make_input (last_input_));
2619
2620                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2621                         != SCM_BOOL_F;
2622
2623                 mus->unprotect ();
2624                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2625         } else if (unsmob_duration (sid)) {
2626                 *destination = unsmob_duration (sid)->smobbed_copy ();
2627                 return DURATION_IDENTIFIER;
2628         } else if (unsmob_output_def (sid)) {
2629                 Output_def *p = unsmob_output_def (sid);
2630                 p = p->clone ();
2631
2632                 *destination = p->self_scm ();
2633                 p->unprotect ();
2634                 return OUTPUT_DEF_IDENTIFIER;
2635         } else if (Text_interface::is_markup (sid)) {
2636                 *destination = sid;
2637                 if (is_lyric_state ())
2638                         return LYRIC_MARKUP_IDENTIFIER;
2639                 return MARKUP_IDENTIFIER;
2640         } else if (Text_interface::is_markup_list (sid)) {
2641                 *destination = sid;
2642                 return MARKUPLINES_IDENTIFIER;
2643         }
2644
2645         return -1;
2646 }
2647
2648 SCM
2649 get_next_unique_context_id ()
2650 {
2651         return scm_from_locale_string ("$uniqueContextId");
2652 }
2653
2654
2655 SCM
2656 get_next_unique_lyrics_context_id ()
2657 {
2658         static int new_context_count;
2659         char s[128];
2660         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2661         return scm_from_locale_string (s);
2662 }
2663
2664
2665 SCM
2666 run_music_function (Lily_parser *parser, SCM expr)
2667 {
2668         SCM func = scm_car (expr);
2669         Input *loc = unsmob_input (scm_cadr (expr));
2670         SCM args = scm_cddr (expr);
2671         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2672
2673         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2674
2675         if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr (expr), sig, args)))
2676         {
2677                 parser->error_level_ = 1;
2678                 return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("void-music"), scm_list_2 (parser->self_scm (), make_input (*loc)));
2679         }
2680
2681         SCM syntax_args = scm_list_4 (parser->self_scm (), make_input (*loc), func, args);
2682         return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("music-function"), syntax_args);
2683 }
2684
2685 bool
2686 is_regular_identifier (SCM id)
2687 {
2688   string str = ly_scm2string (id);
2689   char const *s = str.c_str ();
2690
2691   bool v = true;
2692 #if 0
2693   isalpha (*s);
2694   s++;
2695 #endif
2696   while (*s && v)
2697    {
2698         v = v && isalnum (*s);
2699         s++;
2700    }
2701   return v;
2702 }
2703
2704 Music *
2705 make_music_with_input (SCM name, Input where)
2706 {
2707        Music *m = make_music_by_name (name);
2708        m->set_spot (where);
2709        return m;
2710 }
2711
2712 SCM
2713 get_first_context_id (SCM type, Music *m)
2714 {
2715         SCM id = m->get_property ("context-id");
2716         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2717             && scm_is_string (m->get_property ("context-id"))
2718             && scm_c_string_length (id) > 0)
2719         {
2720                 return id;
2721         }
2722         return SCM_EOL;
2723 }
2724
2725 SCM
2726 make_simple_markup (SCM a)
2727 {
2728         return a;
2729 }
2730
2731 bool
2732 is_duration (int t)
2733 {
2734   return t && t == 1 << intlog2 (t);
2735 }
2736
2737 void
2738 set_music_properties (Music *p, SCM a)
2739 {
2740   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2741         p->set_property (scm_caar (k), scm_cdar (k));
2742 }
2743
2744
2745 SCM
2746 make_chord_step (int step, Rational alter)
2747 {
2748         if (step == 7)
2749                 alter += FLAT_ALTERATION;
2750
2751         while (step < 0)
2752                 step += 7;
2753         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2754         return m.smobbed_copy ();
2755 }
2756
2757
2758 SCM
2759 make_chord_elements (SCM pitch, SCM dur, SCM modification_list)
2760 {
2761         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
2762         return scm_call_3 (chord_ctor, pitch, dur, modification_list);
2763 }
2764
2765
2766 /* Todo: actually also use apply iso. call too ...  */
2767 bool
2768 ly_input_procedure_p (SCM x)
2769 {
2770         return ly_is_procedure (x)
2771                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2772 }
2773
2774 SCM
2775 make_music_relative (Pitch start, SCM music, Input loc)
2776 {
2777         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic", loc);
2778         relative->set_property ("element", music);
2779
2780         Music *m = unsmob_music (music);
2781         Pitch last = m->to_relative_octave (start);
2782         if (lily_1_8_relative)
2783                 m->set_property ("last-pitch", last.smobbed_copy ());
2784         return relative->unprotect ();
2785 }
2786
2787 int
2788 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2789 {
2790         Lily_parser *pars = (Lily_parser*) v;
2791         Lily_lexer *lex = pars->lexer_;
2792
2793         lex->lexval_ = (void*) s;
2794         lex->lexloc_ = loc;
2795         lex->prepare_for_next_token ();
2796         return lex->yylex ();
2797 }