dh_strip

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_strip - strip executables, shared libraries, and some static libraries
   6
   7 =cut
   8
   9 use strict;
  10 use File::Find;
  11 use Debian::Debhelper::Dh_Lib;
  12
  13 =head1 SYNOPSIS
  14
  15 B<dh_strip> [S<I<debhelper options>>] [B<-X>I<item>] [--dbg-package=package] [--keep-debug]
  16
  17 =head1 DESCRIPTION
  18
  19 dh_strip is a debhelper program that is responsible for stripping
  20 executables, shared libraries, and static libraries that are not used for
  21 debugging.
  22
  23 This program examines your package build directories and works out what
  24 to strip on its own. It uses L<file(1)> and file permissions and filenames
  25 to figure out what files are shared libraries (*.so), executable binaries,
  26 and static (lib*.a) and debugging libraries (lib*_g.a, debug/*.so), and
  27 strips each as much as is possible. (Which is not at all for debugging
  28 libraries.) In general it seems to make very good guesses, and will do the
  29 right thing in almost all cases.
  30
  31 Since it is very hard to automatically guess if a file is a
  32 module, and hard to determine how to strip a module, dh_strip does not
  33 currently deal with stripping binary modules such as .o files.
  34
  35 =head1 OPTIONS
  36
  37 =over 4
  38
  39 =item B<-X>I<item>, B<--exclude=>I<item>
  40
  41 Exclude files that contain "item" anywhere in their filename from being
  42 stripped. You may use this option multiple times to build up a list of
  43 things to exclude.
  44
  45 =item B<--dbg-package=>I<package>
  46
  47 Causes dh_strip to save debug symbols stripped from the packages it acts on
  48 as independent files in the package build directory of the specified debugging
  49 package.
  50
  51 For example, if your packages are libfoo and foo and you want to include a
  52 foo-dbg package with debugging symbols, use dh_strip --dbg-package=foo-dbg.
  53
  54 Note that this option behaves significantly different in debhelper
  55 compatibility levels 4 and below. Instead of specifying the name of a debug
  56 package to put symbols in, it specifies a package (or packages) which
  57 should have separated debug symbols, and the separated symbols are placed
  58 in packages with "-dbg" added to their name.
  59
  60 =item B<-k>, B<--keep-debug>
  61
  62 Debug symbols will be retained, but split into an independent
  63 file in usr/lib/debug/ in the package build directory. --dbg-package
  64 is easier to use than this option, but this option is more flexible.
  65
  66 =back
  67
  68 =head1 NOTES
  69
  70 If the DEB_BUILD_OPTIONS environment variable contains "nostrip", nothing
  71 will be stripped, in accordance with Debian policy (section 10.1
  72 "Binaries").
  73
  74 =head1 CONFORMS TO
  75
  76 Debian policy, version 3.0.1
  77
  78 =cut
  79
  80 init(options => {
  81         "keep-debug" => \$dh{K_FLAG},
  82 });
  83
  84 # This variable can be used to turn off stripping (see Policy).
  85 if (defined $ENV{DEB_BUILD_OPTIONS} && $ENV{DEB_BUILD_OPTIONS} =~ /nostrip/) {
  86         exit;
  87 }
  88
  89 # I could just use `file $_[0]`, but this is safer
  90 sub get_file_type {
  91         my $file=shift;
  92         open (FILE, '-|') # handle all filenames safely
  93                 || exec('file', $file)
  94                 || die "can't exec file: $!";
  95         my $type=<FILE>;
  96         close FILE;
  97         return $type;
  98 }
  99
 100 # Check if a file is an elf binary, shared library, or static library,
 101 # for use by File::Find. It'll fill the following 3 arrays with anything
 102 # it finds:
 103 my (@shared_libs, @executables, @static_libs);
 104 sub testfile {
 105         return if -l $_ or -d $_; # Skip directories and symlinks always.
 106
 107         # See if we were asked to exclude this file.
 108         # Note that we have to test on the full filename, including directory.
 109         my $fn="$File::Find::dir/$_";
 110         foreach my $f (@{$dh{EXCLUDE}}) {
 111                 return if ($fn=~m/\Q$f\E/);
 112         }
 113
 114         # Is it a debug library in a debug subdir?
 115         return if $fn=~m/debug\/.*\.so/;
 116
 117         # Does its filename look like a shared library?
 118         # (*.cmxs are OCaml native code shared libraries)
 119         if (m/.*\.(so.*?|cmxs$)/) {
 120                 # Ok, do the expensive test.
 121                 my $type=get_file_type($_);
 122                 if ($type=~m/.*ELF.*shared.*/) {
 123                         push @shared_libs, $fn;
 124                         return;
 125                 }
 126         }
 127
 128         # Is it executable? -x isn't good enough, so we need to use stat.
 129         my (undef,undef,$mode,undef)=stat(_);
 130         if ($mode & 0111) {
 131                 # Ok, expensive test.
 132                 my $type=get_file_type($_);
 133                 if ($type=~m/.*ELF.*(executable|shared).*/) {
 134                         push @executables, $fn;
 135                         return;
 136                 }
 137         }
 138
 139         # Is it a static library, and not a debug library?
 140         if (m/lib.*\.a$/ && ! m/.*_g\.a$/) {
 141                 # Is it a binary file, or something else (maybe a liner
 142                 # script on Hurd, for example? I don't use file, because
 143                 # file returns a variety of things on static libraries.
 144                 if (-B $_) {
 145                         push @static_libs, $fn;
 146                         return;
 147                 }
 148         }
 149 }
 150
 151 sub make_debug {
 152         my $file=shift;
 153         my $tmp=shift;
 154         my $desttmp=shift;
 155
 156         # Don't try to copy debug symbols out if the file is already
 157         # stripped.
 158         return unless get_file_type($file) =~ /not stripped/;
 159
 160         my ($base_file)=$file=~/^\Q$tmp\E(.*)/;
 161         my $debug_path=$desttmp."/usr/lib/debug/".$base_file;
 162         my $debug_dir=dirname($debug_path);
 163         if (! -d $debug_dir) {
 164                 doit("install", "-d", $debug_dir);
 165         }
 166         doit("objcopy", "--only-keep-debug", $file, $debug_path);
 167         # No reason for this to be executable.
 168         doit("chmod", 644, $debug_path);
 169         return $debug_path;
 170 }
 171
 172 sub attach_debug {
 173         my $file=shift;
 174         my $debug_path=shift;
 175         doit("objcopy", "--add-gnu-debuglink", $debug_path, $file);
 176 }
 177
 178 foreach my $package (@{$dh{DOPACKAGES}}) {
 179         my $tmp=tmpdir($package);
 180
 181         # Support for keeping the debugging symbols in a detached file.
 182         my $keep_debug=$dh{K_FLAG};
 183         my $debugtmp=$tmp;
 184         if (! compat(4)) {
 185                 if (ref $dh{DEBUGPACKAGES}) {
 186                         $keep_debug=1;
 187                         # Note that it's only an array for the v4 stuff;
 188                         # for v5 only one value is used.
 189                         my $debugpackage=@{$dh{DEBUGPACKAGES}}[0];
 190                         if (! grep { $_ eq $debugpackage } getpackages()) {
 191                                 error("debug package $debugpackage is not listed in the control file");
 192                         }
 193                         $debugtmp=tmpdir($debugpackage);
 194                 }
 195         }
 196         else {
 197                 if (ref $dh{DEBUGPACKAGES} && grep { $_ eq $package } @{$dh{DEBUGPACKAGES}}) {
 198                         $keep_debug=1;
 199                         $debugtmp=tmpdir($package."-dbg");
 200                 }
 201         }
 202
 203         @shared_libs=@executables=@static_libs=();
 204         find(\&testfile,$tmp);
 205
 206         foreach (@shared_libs) {
 207                 my $debug_path = make_debug($_, $tmp, $debugtmp) if $keep_debug;
 208                 # Note that all calls to strip on shared libs
 209                 # *must* inclde the --strip-unneeded.
 210                 doit("strip","--remove-section=.comment",
 211                         "--remove-section=.note","--strip-unneeded",$_);
 212                 attach_debug($_, $debug_path) if defined $debug_path;
 213         }
 214
 215         foreach (@executables) {
 216                 my $debug_path = make_debug($_, $tmp, $debugtmp) if $keep_debug;
 217                 doit("strip","--remove-section=.comment",
 218                         "--remove-section=.note",$_);
 219                 attach_debug($_, $debug_path) if defined $debug_path;
 220         }
 221
 222         foreach (@static_libs) {
 223                 doit("strip","--strip-debug",$_);
 224         }
 225 }
 226
 227 =head1 SEE ALSO
 228
 229 L<debhelper(7)>
 230
 231 This program is a part of debhelper.
 232
 233 =head1 AUTHOR
 234
 235 Joey Hess <joeyh@debian.org>
 236
 237 =cut