dh_makeshlibs

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_makeshlibs - automatically create shlibs file and call dpkg-gensymbols
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh_makeshlibs> [S<I<debhelper options>>] [B<-m>I<major>] [B<-V>I<[dependencies]>] [B<-n>] [B<-X>I<item>] [S<B<--> I<params>>]
  15
  16 =head1 DESCRIPTION
  17
  18 dh_makeshlibs is a debhelper program that automatically scans for shared
  19 libraries, and generates a shlibs file for the libraries it finds.
  20
  21 It also adds a call to ldconfig in the postinst and postrm scripts (in
  22 V3 mode and above only) to any packages in which it finds shared libraries.
  23
  24 =head1 FILES
  25
  26 =over 4
  27
  28 =item debian/I<package>.symbols
  29
  30 =item debian/I<package>.symbols.I<arch>
  31
  32 These symbols files, if present, are passed to L<dpkg-gensymbols(1)> to
  33 be processed and installed. Use the I<arch> specific names if you need
  34 to provide different symbols files for different architectures.
  35
  36 =back
  37
  38 =head1 OPTIONS
  39
  40 =over 4
  41
  42 =item B<-m>I<major>, B<--major=>I<major>
  43
  44 Instead of trying to guess the major number of the library with objdump,
  45 use the major number specified after the -m parameter. This is much less
  46 useful than it used to be, back in the bad old days when this program
  47 looked at library filenames rather than using objdump.
  48
  49 =item B<-V>, B<-V>I<dependencies>
  50
  51 =item B<--version-info>, B<--version-info=>I<dependencies>
  52
  53 By default, the shlibs file generated by this program does not make packages
  54 depend on any particular version of the package containing the shared
  55 library. It may be necessary for you to add some version dependancy
  56 information to the shlibs file. If -V is specified with no dependency
  57 information, the current upstream version of the package is plugged into a
  58 dependency that looks like "packagename (>= packageversion)". Note that in
  59 debhelper compatibility levels before v4, the debian part of the package
  60 version number is also included. If -V is specified with parameters, the
  61 parameters can be used to specify the exact dependency information needed
  62 (be sure to include the package name).
  63
  64 Beware of using -V without any parameters; this is a conservative setting
  65 that always ensures that other packages' shared library dependencies are at
  66 least as tight as they need to be (unless your library is prone to changing
  67 ABI without updating the upstream version number), so that if the
  68 maintainer screws up then they won't break. The flip side is that packages
  69 might end up with dependencies that are too tight and so find it harder to
  70 be upgraded.
  71
  72 =item B<-n>, B<--noscripts>
  73
  74 Do not modify postinst/postrm scripts.
  75
  76 =item B<-X>I<item>, B<--exclude=>I<item>
  77
  78 Exclude files that contain "item" anywhere in their filename or directory
  79 from being treated as shared libraries.
  80
  81 =item B<--add-udeb=>I<udeb>
  82
  83 Create an additional line for udebs in the shlibs file and use "udeb" as the
  84 package name for udebs to depend on instead of the regular library package.
  85
  86 =item B<--> I<params>
  87
  88 Pass "params" to L<dpkg-gensymbols(1)>.
  89
  90 =back
  91
  92 =head1 EXAMPLES
  93
  94 =over 4
  95
  96 =item dh_makeshlibs
  97
  98 Assuming this is a package named libfoobar1, generates a shlibs file that
  99 looks something like:
 100  libfoobar 1 libfoobar1
 101
 102 =item dh_makeshlibs -V
 103
 104 Assuming the current version of the package is 1.1-3, generates a shlibs
 105 file that looks something like:
 106  libfoobar 1 libfoobar1 (>= 1.1)
 107
 108 =item dh_makeshlibs -V 'libfoobar1 (>= 1.0)'
 109
 110 Generates a shlibs file that looks something like:
 111   libfoobar 1 libfoobar1 (>= 1.0)
 112
 113 =back
 114
 115 =cut
 116
 117 init(options => {
 118         "m=s", => \$dh{M_PARAMS},
 119         "major=s" => \$dh{M_PARAMS},
 120         "version-info:s" => \$dh{V_FLAG},
 121         "add-udeb=s" => \$dh{SHLIBS_UDEB},
 122 });
 123
 124 foreach my $package (@{$dh{DOPACKAGES}}) {
 125         next if is_udeb($package);
 126
 127         my $tmp=tmpdir($package);
 128
 129         my %seen;
 130         my $need_ldconfig = 0;
 131
 132         doit("rm", "-f", "$tmp/DEBIAN/shlibs");
 133
 134         # So, we look for files or links to existing files with names that
 135         # match "*.so*". Matching *.so.* is not good enough because of
 136         # broken crap like db3. And we only look at real files not
 137         # symlinks, so we don't accidentually add shlibs data to -dev
 138         # packages. This may have a few false positives, which is ok,
 139         # because only if we can get a library name and a major number from
 140         # objdump is anything actually added.
 141         my $exclude='';
 142         my (@udeb_lines, @lib_files);
 143         if (defined($dh{EXCLUDE_FIND}) && $dh{EXCLUDE_FIND} ne '') {
 144                 $exclude="! \\( $dh{EXCLUDE_FIND} \\) ";
 145         }
 146         open (FIND, "find $tmp -type f \\( -name '*.so' -or -name '*.so.*' \\) $exclude |");
 147         while (<FIND>) {
 148                 my ($library, $major);
 149                 push @lib_files, $_;
 150                 my $objdump=`objdump -p $_`;
 151                 if ($objdump=~m/\s+SONAME\s+(.+)\.so\.(.+)/) {
 152                         # proper soname format
 153                         $library=$1;
 154                         $major=$2;
 155                 }
 156                 elsif ($objdump=~m/\s+SONAME\s+(.+)-(.+)\.so/) {
 157                         # idiotic crap soname format
 158                         $library=$1;
 159                         $major=$2;
 160                 }
 161
 162                 if (defined($dh{M_PARAMS}) && $dh{M_PARAMS} ne '') {
 163                         $major=$dh{M_PARAMS};
 164                 }
 165
 166                 if (! -d "$tmp/DEBIAN") {
 167                         doit("install","-d","$tmp/DEBIAN");
 168                 }
 169                 my $deps=$package;
 170                 if ($dh{V_FLAG_SET}) {
 171                         if ($dh{V_FLAG} ne '') {
 172                                 $deps=$dh{V_FLAG};
 173                         }
 174                         else {
 175                                 # Call isnative becuase it sets $dh{VERSION}
 176                                 # as a side effect.
 177                                 isnative($package);
 178                                 my $version = $dh{VERSION};
 179                                 # Old compatibility levels include the
 180                                 # debian revision, while new do not.
 181                                 if (! compat(3)) {
 182                                         # Remove debian version, if any.
 183                                         $version =~ s/-[^-]+$//;
 184                                 }
 185                                 $deps="$package (>= $version)";
 186                         }
 187                 }
 188                 if (defined($library) && defined($major) && defined($deps) &&
 189                     $library ne '' && $major ne '' && $deps ne '') {
 190                         $need_ldconfig=1;
 191                         # Prevent duplicate lines from entering the file.
 192                         my $line="$library $major $deps";
 193                         if (! $seen{$line}) {
 194                                 $seen{$line}=1;
 195                                 complex_doit("echo '$line' >>$tmp/DEBIAN/shlibs");
 196                                 if (defined($dh{SHLIBS_UDEB}) && $dh{SHLIBS_UDEB} ne '') {
 197                                         my $udeb_deps = $deps;
 198                                         $udeb_deps =~ s/\Q$package\E/$dh{SHLIBS_UDEB}/e;
 199                                         $line="udeb: "."$library $major $udeb_deps";
 200                                         push @udeb_lines, $line;
 201                                 }
 202                         }
 203                 }
 204         }
 205         close FIND;
 206
 207         # Write udeb: lines last.
 208         foreach (@udeb_lines) {
 209                 complex_doit("echo '$_' >>$tmp/DEBIAN/shlibs");
 210         }
 211
 212         # New as of dh_v3.
 213         if (! compat(2) && ! $dh{NOSCRIPTS} && $need_ldconfig) {
 214                 autoscript($package,"postinst","postinst-makeshlibs");
 215                 autoscript($package,"postrm","postrm-makeshlibs");
 216         }
 217
 218         if (-e "$tmp/DEBIAN/shlibs") {
 219                 doit("chmod",644,"$tmp/DEBIAN/shlibs");
 220                 doit("chown","0:0","$tmp/DEBIAN/shlibs");
 221         }
 222
 223         # dpkg-gensymbols files
 224         my $symbols=pkgfile($package, "symbols");
 225         if (-e $symbols) {
 226                 # -I is used rather than using dpkg-gensymbols
 227                 # own search for symbols files, since that search
 228                 # is not 100% compatible with debhelper. (For example,
 229                 # this supports --ignore being used.)
 230                 doit("dpkg-gensymbols", "-p$package", "-I$symbols",
 231                         "-P$tmp", (map { "-e$_" } @lib_files),
 232                         @{$dh{U_PARAMS}});
 233                 if (-s "$tmp/DEBIAN/symbols" == 0) {
 234                         doit("rm", "-f", "$tmp/DEBIAN/symbols");
 235                 }
 236         }
 237 }
 238
 239 =head1 SEE ALSO
 240
 241 L<debhelper(7)>
 242
 243 This program is a part of debhelper.
 244
 245 =head1 AUTHOR
 246
 247 Joey Hess <joeyh@debian.org>
 248
 249 =cut