dh

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh - debhelper command sequencer
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh> sequence [B<--with> I<addon>] [B<--until> I<cmd>] [B<--before> I<cmd>] [B<--after> I<cmd>] [B<--remaining>] [S<I<debhelper options>>]
  15
  16 =head1 DESCRIPTION
  17
  18 dh runs a sequence of debhelper commands. The supported sequences
  19 correspond to the targets of a debian/rules file: "build", "clean",
  20 "install", "binary-arch", "binary-indep", and "binary".
  21
  22 Commands in the binary-indep sequence are passed the "-i" option to ensure
  23 they only work on binary independent packages, and commands in the
  24 binary-arch sequences are passed the "-a" option to ensure they only work
  25 on architecture dependent packages.
  26
  27 Each debhelper command will record when it's successfully run in
  28 debian/package.debhelper.log. (Which dh_clean deletes.) So dh can tell
  29 which commands have already been run, for which packages, and skip running
  30 those commands again.
  31
  32 Each time dh is run, it examines the log, and finds the last logged command
  33 that is in the specified sequence. It then continues with the next command
  34 in the sequence. The B<--until>, B<--before>, B<--after>, and B<--remaining>
  35 options can override this behavior.
  36
  37 If debian/rules contains a target with a name like "override_I<dh_command>",
  38 then when it gets to that command in the sequence, dh will run that
  39 target from the rules file, rather than running the actual command. The
  40 override target can then run the command with additional options, or run
  41 entirely different commands instead. (Note that to use this feature,
  42 you should Build-Depend on debhelper 7.2 or above.)
  43
  44 =head1 OPTIONS
  45
  46 =over 4
  47
  48 =item B<--with> I<addon>
  49
  50 Add the debhelper commands specified by the given addon to appropriate places
  51 in the sequence of commands that is run. This option can be repeated more
  52 than once, and is used when there is a third-party package that provides
  53 debhelper commands. See "SEQUENCE ADDONS" below for documentation about what
  54 such packages should do to be supported by --with.
  55
  56 =item B<--until> I<cmd>
  57
  58 Run commands in the sequence until and including I<cmd>, then stop.
  59
  60 =item B<--before> I<cmd>
  61
  62 Run commands in the sequence before I<cmd>, then stop.
  63
  64 =item B<--after> I<cmd>
  65
  66 Run commands in the sequence that come after I<cmd>.
  67
  68 =item B<--remaining>
  69
  70 Run all commands in the sequence that have yet to be run.
  71
  72 =back
  73
  74 All other options passed to dh are passed on to each command it runs. This
  75 can be used to set an option like "-v" or "-X" or "-N", as well as for more
  76 specialised options.
  77
  78 =head1 COMMAND SPECIFICATION
  79
  80 I<cmd> can be a full name of a debhelper command, or a substring. It'll first
  81 search for a command in the sequence exactly matching the name, to avoid any
  82 ambiguity. If there are multiple substring matches, the last one in the
  83 sequence will be used.
  84
  85 =head1 SEQUENCE ADDONS
  86
  87 When B<--with> I<addon> is used, dh loads the perl module
  88 Debian::Debhelper::Sequence::I<addon>. Two functions are provided to let
  89 the module add its commands to sequences:
  90
  91 =over 4
  92
  93 =item Debian::Debhelper::Dh_Lib::insert_before(existing_command, new_command)
  94
  95 Insert I<new_command> in sequences before I<existing_command>.
  96
  97 =item Debian::Debhelper::Dh_Lib::insert_after(existing_command, new_command)
  98
  99 Insert I<new_command> in sequences after I<existing_command>.
 100
 101 =item Debian::Debhelper::Dh_Lib::remove_command(existing_command)
 102
 103 Remove I<existing_command> from the list of commands to run.
 104
 105 =back
 106
 107 =cut
 108
 109 sub command_pos {
 110         my $command=shift;
 111         my @sequence=@_;
 112
 113         foreach my $i (0..$#sequence) {
 114                 if ($command eq $sequence[$i]) {
 115                         return $i;
 116                 }
 117         }
 118
 119         my @matches;
 120         foreach my $i (0..$#sequence) {
 121                 if ($sequence[$i] =~ /\Q$command\E/) {
 122                         push @matches, $i;
 123                 }
 124         }
 125         if (! @matches) {
 126                 error "command specification \"$command\" does not match any command in the sequence"
 127         }
 128         else {
 129                 return pop @matches;
 130         }
 131 }
 132
 133 =head1 EXAMPLES
 134
 135 To see what commands are included in a sequence, without actually doing
 136 anything:
 137
 138         dh binary-arch --no-act
 139
 140 This is a very simple rules file, for packages where the default sequences of
 141 commands work with no additional options.
 142
 143         #!/usr/bin/make -f
 144         %:
 145                 dh $@
 146
 147 Often you'll want to pass an option to a specific debhelper command. The
 148 easy way to do with is by adding an override target for that command.
 149
 150         #!/usr/bin/make -f
 151         %:
 152                 dh $@
 153
 154         override_dh_strip:
 155                 dh_strip -Xfoo
 156
 157         override_dh_installdocs:
 158                 dh_installdocs README TODO
 159
 160 Sometimes the automated dh_auto_configure and dh_auto_build can't guess
 161 what to do for a strange package. Here's how to avoid running either
 162 and instead run your own commands.
 163
 164         #!/usr/bin/make -f
 165         %:
 166                 dh $@
 167
 168         override_dh_auto_configure:
 169                 ./mondoconfig
 170
 171         override_dh_auto_build:
 172                 make universe-explode-in-delight
 173
 174 Another common case is wanting to do something manually before or
 175 after a particular debhelper command is run.
 176
 177         #!/usr/bin/make -f
 178         %:
 179                 dh $@
 180
 181         override_dh_fixperms:
 182                 dh_fixperms
 183                 chmod 4755 debian/foo/usr/bin/foo
 184
 185 =cut
 186
 187 # Stash this away before init modifies it.
 188 my @ARGV_orig=@ARGV;
 189
 190 init(options => {
 191         "until=s" => \$dh{UNTIL},
 192         "after=s" => \$dh{AFTER},
 193         "before=s" => \$dh{BEFORE},
 194         "remaining" => \$dh{REMAINING},
 195         "with=s" => sub {
 196                 my ($option,$value)=@_;
 197                 push @{$dh{WITH}},$value;
 198         },
 199 });
 200 inhibit_log();
 201
 202 # Definitions of sequences.
 203 my %sequences;
 204 $sequences{build} = [qw{
 205         dh_testdir
 206         dh_auto_configure
 207         dh_auto_build
 208         dh_auto_test
 209 }],
 210 $sequences{clean} = [qw{
 211         dh_testdir
 212         dh_auto_clean
 213         dh_clean
 214 }];
 215 $sequences{install} = [@{$sequences{build}}, qw{
 216         dh_testroot
 217         dh_prep
 218         dh_installdirs
 219         dh_auto_install
 220
 221         dh_install
 222         dh_installdocs
 223         dh_installchangelogs
 224         dh_installexamples
 225         dh_installman
 226
 227         dh_installcatalogs
 228         dh_installcron
 229         dh_installdebconf
 230         dh_installcatalogs
 231         dh_installemacsen
 232         dh_installifupdown
 233         dh_installinfo
 234         dh_installinit
 235         dh_installmenu
 236         dh_installmime
 237         dh_installmodules
 238         dh_installlogcheck
 239         dh_installlogrotate
 240         dh_installpam
 241         dh_installppp
 242         dh_installudev
 243         dh_installwm
 244         dh_installxfonts
 245         dh_lintian
 246         dh_desktop
 247         dh_gconf
 248         dh_icons
 249         dh_perl
 250         dh_scrollkeeper
 251         dh_usrlocal
 252
 253         dh_link
 254         dh_compress
 255         dh_fixperms
 256 }];
 257 my @b=qw{
 258         dh_installdeb
 259         dh_gencontrol
 260         dh_md5sums
 261         dh_builddeb
 262 };
 263 $sequences{'binary-indep'} = [@{$sequences{install}}, @b];
 264 $sequences{binary} = [@{$sequences{install}}, qw{
 265         dh_strip
 266         dh_makeshlibs
 267         dh_shlibdeps
 268 }, @b];
 269 $sequences{'binary-arch'} = [@{$sequences{binary}}];
 270
 271 # --with python-support is enabled by default, at least for now
 272 unshift @{$dh{WITH}}, "python-support";
 273
 274 # sequence addon interface
 275 sub _insert {
 276         my $offset=shift;
 277         my $existing=shift;
 278         my $new=shift;
 279         foreach my $sequence (keys %sequences) {
 280                 my @list=@{$sequences{$sequence}};
 281                 next unless grep $existing, @list;
 282                 my @new;
 283                 foreach my $command (@list) {
 284                         if ($command eq $existing) {
 285                                 push @new, $new if $offset < 0;
 286                                 push @new, $command;
 287                                 push @new, $new if $offset > 0;
 288                         }
 289                         else {
 290                                 push @new, $command;
 291                         }
 292                 }
 293                 $sequences{$sequence}=\@new;
 294         }
 295 }
 296 sub insert_before {
 297         _insert(-1, @_);
 298 }
 299 sub insert_after {
 300         _insert(1, @_);
 301 }
 302 sub remove_command {
 303         my $command=shift;
 304         foreach my $sequence (keys %sequences) {
 305                 $sequences{$sequence}=[grep { $_ ne $command } @{$sequences{$sequence}}];
 306         }
 307
 308 }
 309 foreach my $addon (@{$dh{WITH}}) {
 310         my $mod="Debian::Debhelper::Sequence::$addon";
 311         $mod=~s/-/_/g;
 312         eval "use $mod";
 313         if ($@) {
 314                 error("--with $addon not supported or failed to load module $mod");
 315         }
 316 }
 317
 318 # Get the sequence of commands to run.
 319 if (! @ARGV) {
 320         error "specify a sequence to run";
 321 }
 322 my $sequence=shift;
 323 if (! exists $sequences{$sequence}) {
 324         error "Unknown sequence $sequence (choose from: ".
 325                 join(" ", sort keys %sequences).")";
 326 }
 327 my @sequence=@{$sequences{$sequence}};
 328
 329 # The list of all packages that can be acted on.
 330 my @packages=@{$dh{DOPACKAGES}};
 331
 332 # Get the options to pass to commands in the sequence.
 333 # Filter out options intended only for this program.
 334 my @options;
 335 if ($sequence eq 'binary-arch') {
 336         push @options, "-a";
 337         # as an optimisation, remove from the list any packages
 338         # that are not arch dependent
 339         my %arch_packages = map { $_ => 1 } getpackages("arch");
 340         @packages = grep { $arch_packages{$_} } @packages;
 341 }
 342 elsif ($sequence eq 'binary-indep') {
 343         push @options, "-i";
 344         # ditto optimisation for arch indep
 345         my %indep_packages = map { $_ => 1 } getpackages("indep");
 346         @packages = grep { $indep_packages{$_} } @packages;
 347 }
 348 while (@ARGV_orig) {
 349         my $opt=shift @ARGV_orig;
 350         next if $opt eq $sequence;
 351         if ($opt =~ /^--?(after|until|before|with)$/) {
 352                 shift @ARGV_orig;
 353                 next;
 354         }
 355         elsif ($opt =~ /^--?(no-act|remaining|(after|until|before|with)=)/) {
 356                 next;
 357         }
 358         push @options, $opt;
 359 }
 360
 361 # Figure out at what point in the sequence to start for each package.
 362 my %logged;
 363 my %startpoint;
 364 foreach my $package (@packages) {
 365         my @log=loadlog($package);
 366         if ($dh{AFTER}) {
 367                 # Run commands in the sequence that come after the
 368                 # specified command.
 369                 $startpoint{$package}=command_pos($dh{AFTER}, @sequence) + 1;
 370                 # Write a dummy log entry indicating that the specified
 371                 # command was, in fact, run. This handles the case where
 372                 # no commands remain to run after it, communicating to
 373                 # future dh instances that the specified command should not
 374                 # be run again.
 375                 writelog($package, $sequence[$startpoint{$package}-1]);
 376         }
 377         elsif ($dh{REMAINING}) {
 378                 # Start at the beginning so all remaining commands will get
 379                 # run.
 380                 $startpoint{$package}=0;
 381         }
 382         else {
 383                 # Find the last logged command that is in the sequence, and
 384                 # continue with the next command after it. If no logged
 385                 # command is in the sequence, we're starting at the beginning..
 386                 $startpoint{$package}=0;
 387 COMMAND:        foreach my $command (reverse @log) {
 388                         foreach my $i (0..$#sequence) {
 389                                 if ($command eq $sequence[$i]) {
 390                                         $startpoint{$package}=$i+1;
 391                                         last COMMAND;
 392                                 }
 393                         }
 394                 }
 395         }
 396 }
 397
 398 # Figure out what point in the sequence to go to.
 399 my $stoppoint=$#sequence;
 400 if ($dh{UNTIL}) {
 401         $stoppoint=command_pos($dh{UNTIL}, @sequence);
 402 }
 403 elsif ($dh{BEFORE}) {
 404         $stoppoint=command_pos($dh{BEFORE}, @sequence) - 1;
 405 }
 406
 407 # Now run the commands in the sequence.
 408 foreach my $i (0..$stoppoint) {
 409         # Figure out which packages need to run this command.
 410         my @exclude;
 411         foreach my $package (@packages) {
 412                 if ($startpoint{$package} > $i ||
 413                     $logged{$package}{$sequence[$i]}) {
 414                         push @exclude, $package;
 415                 }
 416         }
 417
 418         if (@exclude eq @packages) {
 419                 # Command already done for all packages.
 420                 next;
 421         }
 422
 423         run($sequence[$i], \@packages, \@exclude, @options);
 424 }
 425
 426 sub run {
 427         my $command=shift;
 428         my @packages=@{shift()};
 429         my @exclude=@{shift()};
 430         my @options=@_;
 431
 432         # Check for override targets in debian/rules and
 433         # run them instead of running the command directly.
 434         my $override_command;
 435         if (rules_explicit_target("override_".$command)) {
 436                 $override_command=$command;
 437                 # This passes the options through to commands called
 438                 # inside the target.
 439                 $ENV{DH_INTERNAL_OPTIONS}=join(" ", @options);
 440                 $command="debian/rules";
 441                 @options="override_".$override_command;
 442         }
 443         else {
 444                 # If some packages are excluded, add flags
 445                 # to prevent them from being acted on.
 446                 push @options, map { "-N$_" } @exclude;
 447         }
 448
 449         # 3 space indent lines the command being run up under the
 450         # sequence name after "dh ".
 451         print "   ".escape_shell($command, @options)."\n";
 452
 453         if (! $dh{NO_ACT}) {
 454                 my $ret=system($command, @options);
 455                 if ($ret >> 8 != 0) {
 456                         exit $ret >> 8;
 457                 }
 458                 elsif ($ret) {
 459                         exit 1;
 460                 }
 461
 462                 if (defined $override_command) {
 463                         delete $ENV{DH_INTERNAL_OPTIONS};
 464                         # Need to handle logging for overriden commands here,
 465                         # because the actual debhelper command may not have
 466                         # been run by the rules file target.
 467                         my %packages=map { $_ => 1 } @packages;
 468                         map { delete $packages{$_} } @exclude;
 469                         Debian::Debhelper::Dh_Lib::write_log($override_command, keys %packages);
 470                 }
 471         }
 472 }
 473
 474 sub loadlog {
 475         my $package=shift;
 476         my $ext=pkgext($package);
 477
 478         my @log;
 479         open(LOG, "<", "debian/${ext}debhelper.log") || return;
 480         while (<LOG>) {
 481                 chomp;
 482                 push @log, $_;
 483                 $logged{$package}{$_}=1;
 484         }
 485         close LOG;
 486         return @log;
 487 }
 488
 489 sub writelog {
 490         my $package=shift;
 491         my $cmd=shift;
 492         my $ext=pkgext($package);
 493
 494         open(LOG, ">>", "debian/${ext}debhelper.log") || error("failed to write to log");
 495         print LOG $cmd."\n";
 496         close LOG;
 497 }
 498
 499 {
 500 my %targets;
 501 my $rules_parsed;
 502
 503 sub rules_explicit_target {
 504         # Checks if a specified target exists as an explicit target
 505         # in debian/rules.
 506         my $target=shift;
 507
 508         if (! $rules_parsed) {
 509                 my $processing_targets = 0;
 510                 my $not_a_target = 0;
 511                 open(MAKE, "make -Rrnpsf debian/rules debhelper-fail-me 2>/dev/null |");
 512                 while (<MAKE>) {
 513                         if ($processing_targets) {
 514                                 if (/^# Not a target:/) {
 515                                         $not_a_target = 1;
 516                                 }
 517                                 else {
 518                                         if (!$not_a_target && /^([^#:]+)::?/) {
 519                                                 # Target is defined.
 520                                                 # NOTE: if it is a depenency
 521                                                 # of .PHONY it will be
 522                                                 # defined too but that's ok.
 523                                                 $targets{$1} = 1;
 524                                         }
 525                                         # "Not a target:" is always followed by
 526                                         # a target name, so resetting this one
 527                                         # here is safe.
 528                                         $not_a_target = 0;
 529                                 }
 530                         } elsif (/^# Files$/) {
 531                                 $processing_targets = 1;
 532                         }
 533                 }
 534                 close MAKE;
 535                 $rules_parsed = 1;
 536         }
 537
 538         return exists $targets{$target};
 539 }
 540
 541 }
 542
 543 =head1 SEE ALSO
 544
 545 L<debhelper(7)>
 546
 547 This program is a part of debhelper.
 548
 549 =head1 AUTHOR
 550
 551 Joey Hess <joeyh@debian.org>
 552
 553 =cut