dh

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh - debhelper command sequencer
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh> sequence [B<--with> I<addon>] [B<--until> I<cmd>] [B<--before> I<cmd>] [B<--after> I<cmd>] [B<--remaining>] [S<I<debhelper options>>]
  15
  16 =head1 DESCRIPTION
  17
  18 dh runs a sequence of debhelper commands. The supported sequences
  19 correspond to the targets of a debian/rules file: "build", "clean",
  20 "install", "binary-arch", "binary-indep", and "binary".
  21
  22 Commands in the binary-indep sequence are passed the "-i" option to ensure
  23 they only work on binary independent packages, and commands in the
  24 binary-arch sequences are passed the "-a" option to ensure they only work
  25 on architecture dependent packages.
  26
  27 Each debhelper command will record when it's successfully run in
  28 debian/package.debhelper.log. (Which dh_clean deletes.) So dh can tell
  29 which commands have already been run, for which packages, and skip running
  30 those commands again.
  31
  32 Each time dh is run, it examines the log, and finds the last logged command
  33 that is in the specified sequence. It then continues with the next command
  34 in the sequence. The B<--until>, B<--before>, B<--after>, and B<--remaining>
  35 options can override this behavior.
  36
  37 If debian/rules contains a target with a name like "override_I<dh_command>",
  38 then when it gets to that command in the sequence, dh will run that
  39 target from the rules file, rather than running the actual command. The
  40 override target can then run the command with additional options, or run
  41 entirely different commands instead. (Note that to use this feature,
  42 you should Build-Depend on debhelper 7.2 or above.)
  43
  44 =head1 OPTIONS
  45
  46 =over 4
  47
  48 =item B<--with> I<addon>
  49
  50 Add the debhelper commands specified by the given addon to appropriate places
  51 in the sequence of commands that is run. This option can be repeated more
  52 than once, and is used when there is a third-party package that provides
  53 debhelper commands. See "SEQUENCE ADDONS" below for documentation about what
  54 such packages should do to be supported by --with.
  55
  56 =item B<--until> I<cmd>
  57
  58 Run commands in the sequence until and including I<cmd>, then stop.
  59
  60 =item B<--before> I<cmd>
  61
  62 Run commands in the sequence before I<cmd>, then stop.
  63
  64 =item B<--after> I<cmd>
  65
  66 Run commands in the sequence that come after I<cmd>.
  67
  68 =item B<--remaining>
  69
  70 Run all commands in the sequence that have yet to be run.
  71
  72 =back
  73
  74 All other options passed to dh are passed on to each command it runs. This
  75 can be used to set an option like "-v" or "-X" or "-N", as well as for more
  76 specialised options.
  77
  78 =head1 COMMAND SPECIFICATION
  79
  80 I<cmd> can be a full name of a debhelper command, or a substring. It'll first
  81 search for a command in the sequence exactly matching the name, to avoid any
  82 ambiguity. If there are multiple substring matches, the last one in the
  83 sequence will be used.
  84
  85 =head1 SEQUENCE ADDONS
  86
  87 When B<--with> I<addon> is used, dh loads the perl module
  88 Debian::Debhelper::Sequence::I<addon>. Two functions are provided to let
  89 the module add its commands to sequences:
  90
  91 =over 4
  92
  93 =item Debian::Debhelper::Dh_Lib::insert_before(existing_command, new_command)
  94
  95 Insert I<new_command> in sequences before I<existing_command>.
  96
  97 =item Debian::Debhelper::Dh_Lib::insert_after(existing_command, new_command)
  98
  99 Insert I<new_command> in sequences after I<existing_command>.
 100
 101 =item Debian::Debhelper::Dh_Lib::remove_command(existing_command)
 102
 103 Remove I<existing_command> from the list of commands to run.
 104
 105 =back
 106
 107 =cut
 108
 109 sub command_pos {
 110         my $command=shift;
 111         my @sequence=@_;
 112
 113         foreach my $i (0..$#sequence) {
 114                 if ($command eq $sequence[$i]) {
 115                         return $i;
 116                 }
 117         }
 118
 119         my @matches;
 120         foreach my $i (0..$#sequence) {
 121                 if ($sequence[$i] =~ /\Q$command\E/) {
 122                         push @matches, $i;
 123                 }
 124         }
 125         if (! @matches) {
 126                 error "command specification \"$command\" does not match any command in the sequence"
 127         }
 128         else {
 129                 return pop @matches;
 130         }
 131 }
 132
 133 =head1 EXAMPLES
 134
 135 To see what commands are included in a sequence, without actually doing
 136 anything:
 137
 138         dh binary-arch --no-act
 139
 140 This is a very simple rules file, for packages where the default sequences of
 141 commands work with no additional options.
 142
 143         #!/usr/bin/make -f
 144         %:
 145                 dh $@
 146
 147 Often you'll want to pass an option to a specific debhelper command. The
 148 easy way to do with is by adding an override target for that command.
 149
 150         #!/usr/bin/make -f
 151         %:
 152                 dh $@
 153
 154         override_dh_strip:
 155                 dh_strip -Xfoo
 156
 157         override_dh_installdocs:
 158                 dh_installdocs README TODO
 159
 160 Sometimes the automated dh_auto_configure and dh_auto_build can't guess
 161 what to do for a strange package. Here's how to avoid running either
 162 and instead run your own commands.
 163
 164         #!/usr/bin/make -f
 165         %:
 166                 dh $@
 167
 168         override_dh_auto_configure:
 169                 ./mondoconfig
 170
 171         override_dh_auto_build:
 172                 make universe-explode-in-delight
 173
 174 Another common case is wanting to do something manually before or
 175 after a particular debhelper command is run.
 176
 177         #!/usr/bin/make -f
 178         %:
 179                 dh $@
 180
 181         override_dh_fixperms:
 182                 dh_fixperms
 183                 chmod 4755 debian/foo/usr/bin/foo
 184
 185 =cut
 186
 187 # Stash this away before init modifies it.
 188 my @ARGV_orig=@ARGV;
 189
 190 init();
 191 inhibit_log();
 192
 193 # Definitions of sequences.
 194 my %sequences;
 195 $sequences{build} = [qw{
 196         dh_testdir
 197         dh_auto_configure
 198         dh_auto_build
 199         dh_auto_test
 200 }],
 201 $sequences{clean} = [qw{
 202         dh_testdir
 203         dh_auto_clean
 204         dh_clean
 205 }];
 206 $sequences{install} = [@{$sequences{build}}, qw{
 207         dh_testroot
 208         dh_prep
 209         dh_installdirs
 210         dh_auto_install
 211
 212         dh_install
 213         dh_installdocs
 214         dh_installchangelogs
 215         dh_installexamples
 216         dh_installman
 217
 218         dh_installcatalogs
 219         dh_installcron
 220         dh_installdebconf
 221         dh_installcatalogs
 222         dh_installemacsen
 223         dh_installifupdown
 224         dh_installinfo
 225         dh_installinit
 226         dh_installmenu
 227         dh_installmime
 228         dh_installmodules
 229         dh_installlogcheck
 230         dh_installlogrotate
 231         dh_installpam
 232         dh_installppp
 233         dh_installudev
 234         dh_installwm
 235         dh_installxfonts
 236         dh_lintian
 237         dh_desktop
 238         dh_gconf
 239         dh_icons
 240         dh_perl
 241         dh_scrollkeeper
 242         dh_usrlocal
 243
 244         dh_link
 245         dh_compress
 246         dh_fixperms
 247 }];
 248 my @b=qw{
 249         dh_installdeb
 250         dh_gencontrol
 251         dh_md5sums
 252         dh_builddeb
 253 };
 254 $sequences{'binary-indep'} = [@{$sequences{install}}, @b];
 255 $sequences{binary} = [@{$sequences{install}}, qw{
 256         dh_strip
 257         dh_makeshlibs
 258         dh_shlibdeps
 259 }, @b];
 260 $sequences{'binary-arch'} = [@{$sequences{binary}}];
 261
 262 # --with python-support is enabled by default, at least for now
 263 unshift @{$dh{WITH}}, "python-support";
 264
 265 # sequence addon interface
 266 sub _insert {
 267         my $offset=shift;
 268         my $existing=shift;
 269         my $new=shift;
 270         foreach my $sequence (keys %sequences) {
 271                 my @list=@{$sequences{$sequence}};
 272                 next unless grep $existing, @list;
 273                 my @new;
 274                 foreach my $command (@list) {
 275                         if ($command eq $existing) {
 276                                 push @new, $new if $offset < 0;
 277                                 push @new, $command;
 278                                 push @new, $new if $offset > 0;
 279                         }
 280                         else {
 281                                 push @new, $command;
 282                         }
 283                 }
 284                 $sequences{$sequence}=\@new;
 285         }
 286 }
 287 sub insert_before {
 288         _insert(-1, @_);
 289 }
 290 sub insert_after {
 291         _insert(1, @_);
 292 }
 293 sub remove_command {
 294         my $command=shift;
 295         foreach my $sequence (keys %sequences) {
 296                 $sequences{$sequence}=[grep { $_ ne $command } @{$sequences{$sequence}}];
 297         }
 298
 299 }
 300 foreach my $addon (@{$dh{WITH}}) {
 301         my $mod="Debian::Debhelper::Sequence::$addon";
 302         $mod=~s/-/_/g;
 303         eval "use $mod";
 304         if ($@) {
 305                 error("--with $addon not supported or failed to load module $mod");
 306         }
 307 }
 308
 309 # Get the sequence of commands to run.
 310 if (! @ARGV) {
 311         error "specify a sequence to run";
 312 }
 313 my $sequence=shift;
 314 if ($sequence eq 'debian/rules') {
 315         # make -B causes the rules file to be run as a target
 316         exit 0
 317 }
 318 elsif (! exists $sequences{$sequence}) {
 319         error "Unknown sequence $sequence (choose from: ".
 320                 join(" ", sort keys %sequences).")";
 321 }
 322 my @sequence=@{$sequences{$sequence}};
 323
 324 # The list of all packages that can be acted on.
 325 my @packages=@{$dh{DOPACKAGES}};
 326
 327 # Get the options to pass to commands in the sequence.
 328 # Filter out options intended only for this program.
 329 my @options;
 330 if ($sequence eq 'binary-arch') {
 331         push @options, "-a";
 332         # as an optimisation, remove from the list any packages
 333         # that are not arch dependent
 334         my %arch_packages = map { $_ => 1 } getpackages("arch");
 335         @packages = grep { $arch_packages{$_} } @packages;
 336 }
 337 elsif ($sequence eq 'binary-indep') {
 338         push @options, "-i";
 339         # ditto optimisation for arch indep
 340         my %indep_packages = map { $_ => 1 } getpackages("indep");
 341         @packages = grep { $indep_packages{$_} } @packages;
 342 }
 343 while (@ARGV_orig) {
 344         my $opt=shift @ARGV_orig;
 345         next if $opt eq $sequence;
 346         if ($opt =~ /^--?(after|until|before|with)$/) {
 347                 shift @ARGV_orig;
 348                 next;
 349         }
 350         elsif ($opt =~ /^--?(no-act|remaining|(after|until|before|with)=)/) {
 351                 next;
 352         }
 353         push @options, $opt;
 354 }
 355
 356 # Figure out at what point in the sequence to start for each package.
 357 my %logged;
 358 my %startpoint;
 359 foreach my $package (@packages) {
 360         my @log=loadlog($package);
 361         if ($dh{AFTER}) {
 362                 # Run commands in the sequence that come after the
 363                 # specified command.
 364                 $startpoint{$package}=command_pos($dh{AFTER}, @sequence) + 1;
 365                 # Write a dummy log entry indicating that the specified
 366                 # command was, in fact, run. This handles the case where
 367                 # no commands remain to run after it, communicating to
 368                 # future dh instances that the specified command should not
 369                 # be run again.
 370                 writelog($package, $sequence[$startpoint{$package}-1]);
 371         }
 372         elsif ($dh{REMAINING}) {
 373                 # Start at the beginning so all remaining commands will get
 374                 # run.
 375                 $startpoint{$package}=0;
 376         }
 377         else {
 378                 # Find the last logged command that is in the sequence, and
 379                 # continue with the next command after it. If no logged
 380                 # command is in the sequence, we're starting at the beginning..
 381                 $startpoint{$package}=0;
 382 COMMAND:        foreach my $command (reverse @log) {
 383                         foreach my $i (0..$#sequence) {
 384                                 if ($command eq $sequence[$i]) {
 385                                         $startpoint{$package}=$i+1;
 386                                         last COMMAND;
 387                                 }
 388                         }
 389                 }
 390         }
 391 }
 392
 393 # Figure out what point in the sequence to go to.
 394 my $stoppoint=$#sequence;
 395 if ($dh{UNTIL}) {
 396         $stoppoint=command_pos($dh{UNTIL}, @sequence);
 397 }
 398 elsif ($dh{BEFORE}) {
 399         $stoppoint=command_pos($dh{BEFORE}, @sequence) - 1;
 400 }
 401
 402 # Now run the commands in the sequence.
 403 foreach my $i (0..$stoppoint) {
 404         # Figure out which packages need to run this command.
 405         my @exclude;
 406         foreach my $package (@packages) {
 407                 if ($startpoint{$package} > $i ||
 408                     $logged{$package}{$sequence[$i]}) {
 409                         push @exclude, $package;
 410                 }
 411         }
 412
 413         if (@exclude eq @packages) {
 414                 # Command already done for all packages.
 415                 next;
 416         }
 417
 418         run($sequence[$i], \@packages, \@exclude, @options);
 419 }
 420
 421 sub run {
 422         my $command=shift;
 423         my @packages=@{shift()};
 424         my @exclude=@{shift()};
 425         my @options=@_;
 426
 427         # Check for override targets in debian/rules and
 428         # run them instead of running the command directly.
 429         my $override_command;
 430         if (rules_explicit_target("override_".$command)) {
 431                 $override_command=$command;
 432                 # This passes the options through to commands called
 433                 # inside the target.
 434                 $ENV{DH_INTERNAL_OPTIONS}=join(" ", @options);
 435                 $command="debian/rules";
 436                 @options="override_".$override_command;
 437         }
 438         else {
 439                 # If some packages are excluded, add flags
 440                 # to prevent them from being acted on.
 441                 push @options, map { "-N$_" } @exclude;
 442         }
 443
 444         # 3 space indent lines the command being run up under the
 445         # sequence name after "dh ".
 446         print "   ".escape_shell($command, @options)."\n";
 447
 448         if (! $dh{NO_ACT}) {
 449                 my $ret=system($command, @options);
 450                 if ($ret >> 8 != 0) {
 451                         exit $ret >> 8;
 452                 }
 453                 elsif ($ret) {
 454                         exit 1;
 455                 }
 456
 457                 if (defined $override_command) {
 458                         delete $ENV{DH_INTERNAL_OPTIONS};
 459                         # Need to handle logging for overriden commands here,
 460                         # because the actual debhelper command may not have
 461                         # been run by the rules file target.
 462                         my %packages=map { $_ => 1 } @packages;
 463                         map { delete $packages{$_} } @exclude;
 464                         Debian::Debhelper::Dh_Lib::write_log($override_command, keys %packages);
 465                 }
 466         }
 467 }
 468
 469 sub loadlog {
 470         my $package=shift;
 471         my $ext=pkgext($package);
 472
 473         my @log;
 474         open(LOG, "<", "debian/${ext}debhelper.log") || return;
 475         while (<LOG>) {
 476                 chomp;
 477                 push @log, $_;
 478                 $logged{$package}{$_}=1;
 479         }
 480         close LOG;
 481         return @log;
 482 }
 483
 484 sub writelog {
 485         my $package=shift;
 486         my $cmd=shift;
 487         my $ext=pkgext($package);
 488
 489         open(LOG, ">>", "debian/${ext}debhelper.log") || error("failed to write to log");
 490         print LOG $cmd."\n";
 491         close LOG;
 492 }
 493
 494 {
 495 my %targets;
 496 my $rules_parsed;
 497
 498 sub rules_explicit_target {
 499         # Checks if a specified target exists as an explicit target
 500         # in debian/rules.
 501         my $target=shift;
 502
 503         if (! $rules_parsed) {
 504                 my $processing_targets = 0;
 505                 my $not_a_target = 0;
 506                 open(MAKE, "make -Rrnpsf debian/rules debhelper-fail-me 2>/dev/null |");
 507                 while (<MAKE>) {
 508                         if ($processing_targets) {
 509                                 if (/^# Not a target:/) {
 510                                         $not_a_target = 1;
 511                                 }
 512                                 else {
 513                                         if (!$not_a_target && /^([^#:]+)::?/) {
 514                                                 # Target is defined.
 515                                                 # NOTE: if it is a depenency
 516                                                 # of .PHONY it will be
 517                                                 # defined too but that's ok.
 518                                                 $targets{$1} = 1;
 519                                         }
 520                                         # "Not a target:" is always followed by
 521                                         # a target name, so resetting this one
 522                                         # here is safe.
 523                                         $not_a_target = 0;
 524                                 }
 525                         } elsif (/^# Files$/) {
 526                                 $processing_targets = 1;
 527                         }
 528                 }
 529                 close MAKE;
 530                 $rules_parsed = 1;
 531         }
 532
 533         return exists $targets{$target};
 534 }
 535
 536 }
 537
 538 =head1 SEE ALSO
 539
 540 L<debhelper(7)>
 541
 542 This program is a part of debhelper.
 543
 544 =head1 AUTHOR
 545
 546 Joey Hess <joeyh@debian.org>
 547
 548 =cut