dh

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh - debhelper command sequencer
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh> sequence [B<--with> I<addon>] [B<--until> I<cmd>] [B<--before> I<cmd>] [B<--after> I<cmd>] [B<--remaining>] [S<I<debhelper options>>]
  15
  16 =head1 DESCRIPTION
  17
  18 dh runs a sequence of debhelper commands. The supported sequences
  19 correspond to the targets of a debian/rules file: "build", "clean",
  20 "install", "binary-arch", "binary-indep", and "binary".
  21
  22 Commands in the binary-indep sequence are passed the "-i" option to ensure
  23 they only work on binary independent packages, and commands in the
  24 binary-arch sequences are passed the "-a" option to ensure they only work
  25 on architecture dependent packages.
  26
  27 Each debhelper command will record when it's successfully run in
  28 debian/package.debhelper.log. (Which dh_clean deletes.) So dh can tell
  29 which commands have already been run, for which packages, and skip running
  30 those commands again.
  31
  32 Each time dh is run, it examines the log, and finds the last logged command
  33 that is in the specified sequence. It then continues with the next command
  34 in the sequence. The B<--until>, B<--before>, B<--after>, and B<--remaining>
  35 options can override this behavior.
  36
  37 If debian/rules contains a target with a name like "override_I<dh_command>",
  38 then when it gets to that command in the sequence, dh will run that
  39 target from the rules file, rather than running the actual command. The
  40 override target can then run the command with additional options, or run
  41 entirely different commands instead. (Note that to use this feature,
  42 you should Build-Depend on debhelper 7.2 or above.)
  43
  44 =head1 OPTIONS
  45
  46 =over 4
  47
  48 =item B<--with> I<addon>
  49
  50 Add the debhelper commands specified by the given addon to appropriate places
  51 in the sequence of commands that is run. This option can be repeated more
  52 than once, and is used when there is a third-party package that provides
  53 debhelper commands. See "SEQUENCE ADDONS" below for documentation about what
  54 such packages should do to be supported by --with.
  55
  56 =item B<--until> I<cmd>
  57
  58 Run commands in the sequence until and including I<cmd>, then stop.
  59
  60 =item B<--before> I<cmd>
  61
  62 Run commands in the sequence before I<cmd>, then stop.
  63
  64 =item B<--after> I<cmd>
  65
  66 Run commands in the sequence that come after I<cmd>.
  67
  68 =item B<--remaining>
  69
  70 Run all commands in the sequence that have yet to be run.
  71
  72 =back
  73
  74 All other options passed to dh are passed on to each command it runs. This
  75 can be used to set an option like "-v" or "-X" or "-N", as well as for more
  76 specialised options.
  77
  78 =head1 COMMAND SPECIFICATION
  79
  80 I<cmd> can be a full name of a debhelper command, or a substring. It'll first
  81 search for a command in the sequence exactly matching the name, to avoid any
  82 ambiguity. If there are multiple substring matches, the last one in the
  83 sequence will be used.
  84
  85 =head1 SEQUENCE ADDONS
  86
  87 When B<--with> I<addon> is used, dh loads the perl module
  88 Debian::Debhelper::Sequence::I<addon>. Two functions are provided to let
  89 the module add its commands to sequences:
  90
  91 =over 4
  92
  93 =item Debian::Debhelper::Dh_Lib::insert_before(existing_command, new_command)
  94
  95 Insert I<new_command> in sequences before I<existing_command>.
  96
  97 =item Debian::Debhelper::Dh_Lib::insert_after(existing_command, new_command)
  98
  99 Insert I<new_command> in sequences after I<existing_command>.
 100
 101 =item Debian::Debhelper::Dh_Lib::remove_command(existing_command)
 102
 103 Remove I<existing_command> from the list of commands to run.
 104
 105 =back
 106
 107 =cut
 108
 109 sub command_pos {
 110         my $command=shift;
 111         my @sequence=@_;
 112
 113         foreach my $i (0..$#sequence) {
 114                 if ($command eq $sequence[$i]) {
 115                         return $i;
 116                 }
 117         }
 118
 119         my @matches;
 120         foreach my $i (0..$#sequence) {
 121                 if ($sequence[$i] =~ /\Q$command\E/) {
 122                         push @matches, $i;
 123                 }
 124         }
 125         if (! @matches) {
 126                 error "command specification \"$command\" does not match any command in the sequence"
 127         }
 128         else {
 129                 return pop @matches;
 130         }
 131 }
 132
 133 =head1 EXAMPLES
 134
 135 To see what commands are included in a sequence, without actually doing
 136 anything:
 137
 138         dh binary-arch --no-act
 139
 140 This is a very simple rules file, for packages where the default sequences of
 141 commands work with no additional options.
 142
 143         #!/usr/bin/make -Bf
 144         %:
 145                 dh $@
 146
 147 Often you'll want to pass an option to a specific debhelper command. The
 148 easy way to do with is by adding an override target for that command.
 149
 150         #!/usr/bin/make -Bf
 151         %:
 152                 dh $@
 153
 154         override_dh_strip:
 155                 dh_strip -Xfoo
 156
 157         override_dh_installdocs:
 158                 dh_installdocs README TODO
 159
 160 Sometimes the automated dh_auto_configure and dh_auto_build can't guess
 161 what to do for a strange package. Here's how to avoid running either
 162 and instead run your own commands.
 163
 164         #!/usr/bin/make -Bf
 165         %:
 166                 dh $@
 167
 168         override_dh_auto_configure:
 169                 ./mondoconfig
 170
 171         override_dh_auto_build:
 172                 make universe-explode-in-delight
 173
 174 Another common case is wanting to do something manually before or
 175 after a particular debhelper command is run.
 176
 177         #!/usr/bin/make -Bf
 178         %:
 179                 dh $@
 180
 181         override_dh_fixperms:
 182                 dh_fixperms
 183                 chmod 4755 debian/foo/usr/bin/foo
 184
 185 If your package is a python package, dh will use dh_pysupport by
 186 default. This is how to use dh_pycentral instead.
 187
 188         #!/usr/bin/make -Bf
 189         %:
 190                 dh --with python-central
 191
 192 =cut
 193
 194 # Stash this away before init modifies it.
 195 my @ARGV_orig=@ARGV;
 196
 197 init();
 198 inhibit_log();
 199
 200 # Definitions of sequences.
 201 my %sequences;
 202 $sequences{build} = [qw{
 203         dh_testdir
 204         dh_auto_configure
 205         dh_auto_build
 206         dh_auto_test
 207 }],
 208 $sequences{clean} = [qw{
 209         dh_testdir
 210         dh_auto_clean
 211         dh_clean
 212 }];
 213 $sequences{install} = [@{$sequences{build}}, qw{
 214         dh_testroot
 215         dh_prep
 216         dh_installdirs
 217         dh_auto_install
 218
 219         dh_install
 220         dh_installdocs
 221         dh_installchangelogs
 222         dh_installexamples
 223         dh_installman
 224
 225         dh_installcatalogs
 226         dh_installcron
 227         dh_installdebconf
 228         dh_installcatalogs
 229         dh_installemacsen
 230         dh_installifupdown
 231         dh_installinfo
 232         dh_installinit
 233         dh_installmenu
 234         dh_installmime
 235         dh_installmodules
 236         dh_installlogcheck
 237         dh_installlogrotate
 238         dh_installpam
 239         dh_installppp
 240         dh_installudev
 241         dh_installwm
 242         dh_installxfonts
 243         dh_lintian
 244         dh_desktop
 245         dh_gconf
 246         dh_icons
 247         dh_perl
 248         dh_scrollkeeper
 249         dh_usrlocal
 250
 251         dh_link
 252         dh_compress
 253         dh_fixperms
 254 }];
 255 my @b=qw{
 256         dh_installdeb
 257         dh_gencontrol
 258         dh_md5sums
 259         dh_builddeb
 260 };
 261 $sequences{'binary-indep'} = [@{$sequences{install}}, @b];
 262 $sequences{binary} = [@{$sequences{install}}, qw{
 263         dh_strip
 264         dh_makeshlibs
 265         dh_shlibdeps
 266 }, @b];
 267 $sequences{'binary-arch'} = [@{$sequences{binary}}];
 268
 269 # --with python-support is enabled by default, at least for now
 270 unshift @{$dh{WITH}}, "python-support";
 271
 272 # sequence addon interface
 273 sub _insert {
 274         my $offset=shift;
 275         my $existing=shift;
 276         my $new=shift;
 277         foreach my $sequence (keys %sequences) {
 278                 my @list=@{$sequences{$sequence}};
 279                 next unless grep $existing, @list;
 280                 my @new;
 281                 foreach my $command (@list) {
 282                         if ($command eq $existing) {
 283                                 push @new, $new if $offset < 0;
 284                                 push @new, $command;
 285                                 push @new, $new if $offset > 0;
 286                         }
 287                         else {
 288                                 push @new, $command;
 289                         }
 290                 }
 291                 $sequences{$sequence}=\@new;
 292         }
 293 }
 294 sub insert_before {
 295         _insert(-1, @_);
 296 }
 297 sub insert_after {
 298         _insert(1, @_);
 299 }
 300 sub remove_command {
 301         my $command=shift;
 302         foreach my $sequence (keys %sequences) {
 303                 $sequences{$sequence}=[grep { $_ ne $command } @{$sequences{$sequence}}];
 304         }
 305
 306 }
 307 foreach my $addon (@{$dh{WITH}}) {
 308         my $mod="Debian::Debhelper::Sequence::$addon";
 309         $mod=~s/-/_/g;
 310         eval "use $mod";
 311         if ($@) {
 312                 error("--with $addon not supported or failed to load module $mod");
 313         }
 314 }
 315
 316 # Get the sequence of commands to run.
 317 if (! @ARGV) {
 318         error "specify a sequence to run";
 319 }
 320 my $sequence=shift;
 321 if ($sequence eq 'debian/rules' ||
 322     $sequence =~ /^override_dh_/) {
 323         # make -B causes the rules file to be run as a target
 324         # and support completly empty override targets
 325         exit 0
 326 }
 327 elsif (! exists $sequences{$sequence}) {
 328         error "Unknown sequence $sequence (choose from: ".
 329                 join(" ", sort keys %sequences).")";
 330 }
 331 my @sequence=@{$sequences{$sequence}};
 332
 333 # The list of all packages that can be acted on.
 334 my @packages=@{$dh{DOPACKAGES}};
 335
 336 # Get the options to pass to commands in the sequence.
 337 # Filter out options intended only for this program.
 338 my @options;
 339 if ($sequence eq 'binary-arch') {
 340         push @options, "-a";
 341         # as an optimisation, remove from the list any packages
 342         # that are not arch dependent
 343         my %arch_packages = map { $_ => 1 } getpackages("arch");
 344         @packages = grep { $arch_packages{$_} } @packages;
 345 }
 346 elsif ($sequence eq 'binary-indep') {
 347         push @options, "-i";
 348         # ditto optimisation for arch indep
 349         my %indep_packages = map { $_ => 1 } getpackages("indep");
 350         @packages = grep { $indep_packages{$_} } @packages;
 351 }
 352 while (@ARGV_orig) {
 353         my $opt=shift @ARGV_orig;
 354         next if $opt eq $sequence;
 355         if ($opt =~ /^--?(after|until|before|with)$/) {
 356                 shift @ARGV_orig;
 357                 next;
 358         }
 359         elsif ($opt =~ /^--?(no-act|remaining|(after|until|before|with)=)/) {
 360                 next;
 361         }
 362         push @options, $opt;
 363 }
 364
 365 # Figure out at what point in the sequence to start for each package.
 366 my %logged;
 367 my %startpoint;
 368 foreach my $package (@packages) {
 369         my @log=loadlog($package);
 370         if ($dh{AFTER}) {
 371                 # Run commands in the sequence that come after the
 372                 # specified command.
 373                 $startpoint{$package}=command_pos($dh{AFTER}, @sequence) + 1;
 374                 # Write a dummy log entry indicating that the specified
 375                 # command was, in fact, run. This handles the case where
 376                 # no commands remain to run after it, communicating to
 377                 # future dh instances that the specified command should not
 378                 # be run again.
 379                 writelog($sequence[$startpoint{$package}-1], $package);
 380         }
 381         elsif ($dh{REMAINING}) {
 382                 # Start at the beginning so all remaining commands will get
 383                 # run.
 384                 $startpoint{$package}=0;
 385         }
 386         else {
 387                 # Find the last logged command that is in the sequence, and
 388                 # continue with the next command after it. If no logged
 389                 # command is in the sequence, we're starting at the beginning..
 390                 $startpoint{$package}=0;
 391 COMMAND:        foreach my $command (reverse @log) {
 392                         foreach my $i (0..$#sequence) {
 393                                 if ($command eq $sequence[$i]) {
 394                                         $startpoint{$package}=$i+1;
 395                                         last COMMAND;
 396                                 }
 397                         }
 398                 }
 399         }
 400 }
 401
 402 # Figure out what point in the sequence to go to.
 403 my $stoppoint=$#sequence;
 404 if ($dh{UNTIL}) {
 405         $stoppoint=command_pos($dh{UNTIL}, @sequence);
 406 }
 407 elsif ($dh{BEFORE}) {
 408         $stoppoint=command_pos($dh{BEFORE}, @sequence) - 1;
 409 }
 410
 411 # Now run the commands in the sequence.
 412 foreach my $i (0..$stoppoint) {
 413         # Figure out which packages need to run this command.
 414         my @exclude;
 415         foreach my $package (@packages) {
 416                 if ($startpoint{$package} > $i ||
 417                     $logged{$package}{$sequence[$i]}) {
 418                         push @exclude, $package;
 419                 }
 420         }
 421
 422         if (@exclude eq @packages) {
 423                 # Command already done for all packages.
 424                 next;
 425         }
 426
 427         run($sequence[$i], \@packages, \@exclude, @options);
 428 }
 429
 430 sub run {
 431         my $command=shift;
 432         my @packages=@{shift()};
 433         my @exclude=@{shift()};
 434         my @options=@_;
 435
 436         # Check for override targets in debian/rules and
 437         # run them instead of running the command directly.
 438         my $override_command;
 439         if (rules_explicit_target("override_".$command)) {
 440                 $override_command=$command;
 441                 # This passes the options through to commands called
 442                 # inside the target.
 443                 $ENV{DH_INTERNAL_OPTIONS}=join(" ", @options);
 444                 $command="debian/rules";
 445                 @options="override_".$override_command;
 446         }
 447         else {
 448                 # If some packages are excluded, add flags
 449                 # to prevent them from being acted on.
 450                 push @options, map { "-N$_" } @exclude;
 451         }
 452
 453         # 3 space indent lines the command being run up under the
 454         # sequence name after "dh ".
 455         print "   ".escape_shell($command, @options)."\n";
 456
 457         if (! $dh{NO_ACT}) {
 458                 my $ret=system($command, @options);
 459                 if ($ret >> 8 != 0) {
 460                         exit $ret >> 8;
 461                 }
 462                 elsif ($ret) {
 463                         exit 1;
 464                 }
 465
 466                 if (defined $override_command) {
 467                         delete $ENV{DH_INTERNAL_OPTIONS};
 468                         # Need to handle logging for overriden commands here,
 469                         # because the actual debhelper command may not have
 470                         # been run by the rules file target.
 471                         my %packages=map { $_ => 1 } @packages;
 472                         map { delete $packages{$_} } @exclude;
 473                         writelog($override_command, keys %packages);
 474                 }
 475         }
 476 }
 477
 478 sub loadlog {
 479         my $package=shift;
 480         my $ext=pkgext($package);
 481
 482         my @log;
 483         open(LOG, "<", "debian/${ext}debhelper.log") || return;
 484         while (<LOG>) {
 485                 chomp;
 486                 push @log, $_;
 487                 $logged{$package}{$_}=1;
 488         }
 489         close LOG;
 490         return @log;
 491 }
 492
 493 sub writelog {
 494         Debian::Debhelper::Dh_Lib::write_log(@_);
 495 }
 496
 497 {
 498 my %targets;
 499 my $rules_parsed;
 500
 501 sub rules_explicit_target {
 502         # Checks if a specified target exists as an explicit target
 503         # in debian/rules.
 504         my $target=shift;
 505
 506         if (! $rules_parsed) {
 507                 my $processing_targets = 0;
 508                 my $not_a_target = 0;
 509                 open(MAKE, "make -Rrnpsf debian/rules debhelper-fail-me 2>/dev/null |");
 510                 while (<MAKE>) {
 511                         if ($processing_targets) {
 512                                 if (/^# Not a target:/) {
 513                                         $not_a_target = 1;
 514                                 }
 515                                 else {
 516                                         if (!$not_a_target && /^([^#:]+)::?/) {
 517                                                 # Target is defined.
 518                                                 # NOTE: if it is a depenency
 519                                                 # of .PHONY it will be
 520                                                 # defined too but that's ok.
 521                                                 $targets{$1} = 1;
 522                                         }
 523                                         # "Not a target:" is always followed by
 524                                         # a target name, so resetting this one
 525                                         # here is safe.
 526                                         $not_a_target = 0;
 527                                 }
 528                         } elsif (/^# Files$/) {
 529                                 $processing_targets = 1;
 530                         }
 531                 }
 532                 close MAKE;
 533                 $rules_parsed = 1;
 534         }
 535
 536         return exists $targets{$target};
 537 }
 538
 539 }
 540
 541 =head1 SEE ALSO
 542
 543 L<debhelper(7)>
 544
 545 This program is a part of debhelper.
 546
 547 =head1 AUTHOR
 548
 549 Joey Hess <joeyh@debian.org>
 550
 551 =cut