dh

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh - debhelper command sequencer
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh> sequence [B<--with> I<addon>] [B<--until> I<cmd>] [B<--before> I<cmd>] [B<--after> I<cmd>] [B<--remaining>] [S<I<debhelper options>>]
  15
  16 =head1 DESCRIPTION
  17
  18 dh runs a sequence of debhelper commands. The supported sequences
  19 correspond to the targets of a debian/rules file: "build", "clean",
  20 "install", "binary-arch", "binary-indep", and "binary".
  21
  22 Commands in the binary-indep sequence are passed the "-i" option to ensure
  23 they only work on binary independent packages, and commands in the
  24 binary-arch sequences are passed the "-a" option to ensure they only work
  25 on architecture dependent packages.
  26
  27 Each debhelper command will record when it's successfully run in
  28 debian/package.debhelper.log. (Which dh_clean deletes.) So dh can tell
  29 which commands have already been run, for which packages, and skip running
  30 those commands again.
  31
  32 Each time dh is run, it examines the log, and finds the last logged command
  33 that is in the specified sequence. It then continues with the next command
  34 in the sequence. The B<--until>, B<--before>, B<--after>, and B<--remaining>
  35 options can override this behavior.
  36
  37 If debian/rules contains a target with a name like "override_I<dh_command>",
  38 then when it gets to that command in the sequence, dh will run that
  39 target from the rules file, rather than running the actual command. The
  40 override target can then run the command with additional options, or run
  41 entirely different commands instead. (Note that to use this feature,
  42 you should Build-Depend on debhelper 7.0.50 or above.)
  43
  44 =head1 OPTIONS
  45
  46 =over 4
  47
  48 =item B<--with> I<addon>
  49
  50 Add the debhelper commands specified by the given addon to appropriate places
  51 in the sequence of commands that is run. This option can be repeated more
  52 than once, and is used when there is a third-party package that provides
  53 debhelper commands. See "SEQUENCE ADDONS" below for documentation about what
  54 such packages should do to be supported by --with.
  55
  56 =item B<--until> I<cmd>
  57
  58 Run commands in the sequence until and including I<cmd>, then stop.
  59
  60 =item B<--before> I<cmd>
  61
  62 Run commands in the sequence before I<cmd>, then stop.
  63
  64 =item B<--after> I<cmd>
  65
  66 Run commands in the sequence that come after I<cmd>.
  67
  68 =item B<--remaining>
  69
  70 Run all commands in the sequence that have yet to be run.
  71
  72 =back
  73
  74 All other options passed to dh are passed on to each command it runs. This
  75 can be used to set an option like "-v" or "-X" or "-N", as well as for more
  76 specialised options.
  77
  78 =head1 COMMAND SPECIFICATION
  79
  80 I<cmd> can be a full name of a debhelper command, or a substring. It'll first
  81 search for a command in the sequence exactly matching the name, to avoid any
  82 ambiguity. If there are multiple substring matches, the last one in the
  83 sequence will be used.
  84
  85 =head1 SEQUENCE ADDONS
  86
  87 When B<--with> I<addon> is used, dh loads the perl module
  88 Debian::Debhelper::Sequence::I<addon>. Two functions are provided to let
  89 the module add its commands to sequences:
  90
  91 =over 4
  92
  93 =item Debian::Debhelper::Dh_Lib::insert_before(existing_command, new_command)
  94
  95 Insert I<new_command> in sequences before I<existing_command>.
  96
  97 =item Debian::Debhelper::Dh_Lib::insert_after(existing_command, new_command)
  98
  99 Insert I<new_command> in sequences after I<existing_command>.
 100
 101 =item Debian::Debhelper::Dh_Lib::remove_command(existing_command)
 102
 103 Remove I<existing_command> from the list of commands to run.
 104
 105 =back
 106
 107 =cut
 108
 109 sub command_pos {
 110         my $command=shift;
 111         my @sequence=@_;
 112
 113         foreach my $i (0..$#sequence) {
 114                 if ($command eq $sequence[$i]) {
 115                         return $i;
 116                 }
 117         }
 118
 119         my @matches;
 120         foreach my $i (0..$#sequence) {
 121                 if ($sequence[$i] =~ /\Q$command\E/) {
 122                         push @matches, $i;
 123                 }
 124         }
 125         if (! @matches) {
 126                 error "command specification \"$command\" does not match any command in the sequence"
 127         }
 128         else {
 129                 return pop @matches;
 130         }
 131 }
 132
 133 =head1 EXAMPLES
 134
 135 To see what commands are included in a sequence, without actually doing
 136 anything:
 137
 138         dh binary-arch --no-act
 139
 140 This is a very simple rules file, for packages where the default sequences of
 141 commands work with no additional options.
 142
 143         #!/usr/bin/make -f
 144         %:
 145                 dh $@
 146
 147 Often you'll want to pass an option to a specific debhelper command. The
 148 easy way to do with is by adding an override target for that command.
 149
 150         #!/usr/bin/make -f
 151         %:
 152                 dh $@
 153
 154         override_dh_strip:
 155                 dh_strip -Xfoo
 156
 157         override_dh_installdocs:
 158                 dh_installdocs README TODO
 159
 160 Sometimes the automated dh_auto_configure and dh_auto_build can't guess
 161 what to do for a strange package. Here's how to avoid running either
 162 and instead run your own commands.
 163
 164         #!/usr/bin/make -f
 165         %:
 166                 dh $@
 167
 168         override_dh_auto_configure:
 169                 ./mondoconfig
 170
 171         override_dh_auto_build:
 172                 make universe-explode-in-delight
 173
 174 Another common case is wanting to do something manually before or
 175 after a particular debhelper command is run.
 176
 177         #!/usr/bin/make -f
 178         %:
 179                 dh $@
 180
 181         override_dh_fixperms:
 182                 dh_fixperms
 183                 chmod 4755 debian/foo/usr/bin/foo
 184
 185 If your package is a python package, dh will use dh_pysupport by
 186 default. This is how to use dh_pycentral instead.
 187
 188         #!/usr/bin/make -f
 189         %:
 190                 dh --with python-central $@
 191
 192 =cut
 193
 194 # Stash this away before init modifies it.
 195 my @ARGV_orig=@ARGV;
 196
 197 init(options => {
 198         "until=s" => \$dh{UNTIL},
 199         "after=s" => \$dh{AFTER},
 200         "before=s" => \$dh{BEFORE},
 201         "remaining" => \$dh{REMAINING},
 202         "with=s" => sub {
 203                 my ($option,$value)=@_;
 204                 push @{$dh{WITH}},$value;
 205         },
 206 });
 207 inhibit_log();
 208
 209 # Definitions of sequences.
 210 my %sequences;
 211 $sequences{build} = [qw{
 212         dh_testdir
 213         dh_auto_configure
 214         dh_auto_build
 215         dh_auto_test
 216 }],
 217 $sequences{clean} = [qw{
 218         dh_testdir
 219         dh_auto_clean
 220         dh_clean
 221 }];
 222 $sequences{install} = [@{$sequences{build}}, qw{
 223         dh_testroot
 224         dh_prep
 225         dh_installdirs
 226         dh_auto_install
 227
 228         dh_install
 229         dh_installdocs
 230         dh_installchangelogs
 231         dh_installexamples
 232         dh_installman
 233
 234         dh_installcatalogs
 235         dh_installcron
 236         dh_installdebconf
 237         dh_installcatalogs
 238         dh_installemacsen
 239         dh_installifupdown
 240         dh_installinfo
 241         dh_installinit
 242         dh_installmenu
 243         dh_installmime
 244         dh_installmodules
 245         dh_installlogcheck
 246         dh_installlogrotate
 247         dh_installpam
 248         dh_installppp
 249         dh_installudev
 250         dh_installwm
 251         dh_installxfonts
 252         dh_bugfiles
 253         dh_lintian
 254         dh_desktop
 255         dh_gconf
 256         dh_icons
 257         dh_perl
 258         dh_scrollkeeper
 259         dh_usrlocal
 260
 261         dh_link
 262         dh_compress
 263         dh_fixperms
 264 }];
 265 my @b=qw{
 266         dh_installdeb
 267         dh_gencontrol
 268         dh_md5sums
 269         dh_builddeb
 270 };
 271 $sequences{'binary-indep'} = [@{$sequences{install}}, @b];
 272 $sequences{binary} = [@{$sequences{install}}, qw{
 273         dh_strip
 274         dh_makeshlibs
 275         dh_shlibdeps
 276 }, @b];
 277 $sequences{'binary-arch'} = [@{$sequences{binary}}];
 278
 279 # --with python-support is enabled by default, at least for now
 280 unshift @{$dh{WITH}}, "python-support";
 281
 282 # sequence addon interface
 283 sub _insert {
 284         my $offset=shift;
 285         my $existing=shift;
 286         my $new=shift;
 287         foreach my $sequence (keys %sequences) {
 288                 my @list=@{$sequences{$sequence}};
 289                 next unless grep $existing, @list;
 290                 my @new;
 291                 foreach my $command (@list) {
 292                         if ($command eq $existing) {
 293                                 push @new, $new if $offset < 0;
 294                                 push @new, $command;
 295                                 push @new, $new if $offset > 0;
 296                         }
 297                         else {
 298                                 push @new, $command;
 299                         }
 300                 }
 301                 $sequences{$sequence}=\@new;
 302         }
 303 }
 304 sub insert_before {
 305         _insert(-1, @_);
 306 }
 307 sub insert_after {
 308         _insert(1, @_);
 309 }
 310 sub remove_command {
 311         my $command=shift;
 312         foreach my $sequence (keys %sequences) {
 313                 $sequences{$sequence}=[grep { $_ ne $command } @{$sequences{$sequence}}];
 314         }
 315
 316 }
 317 foreach my $addon (@{$dh{WITH}}) {
 318         my $mod="Debian::Debhelper::Sequence::$addon";
 319         $mod=~s/-/_/g;
 320         eval "use $mod";
 321         if ($@) {
 322                 error("--with $addon not supported or failed to load module $mod");
 323         }
 324 }
 325
 326 # Get the sequence of commands to run.
 327 if (! @ARGV) {
 328         error "specify a sequence to run";
 329 }
 330 my $sequence=shift;
 331 if ($sequence eq 'debian/rules' ||
 332     $sequence =~ /^override_dh_/) {
 333         # make -B causes the rules file to be run as a target
 334         # and support completly empty override targets
 335         exit 0
 336 }
 337 elsif (! exists $sequences{$sequence}) {
 338         error "Unknown sequence $sequence (choose from: ".
 339                 join(" ", sort keys %sequences).")";
 340 }
 341 my @sequence=@{$sequences{$sequence}};
 342
 343 # The list of all packages that can be acted on.
 344 my @packages=@{$dh{DOPACKAGES}};
 345
 346 # Get the options to pass to commands in the sequence.
 347 # Filter out options intended only for this program.
 348 my @options;
 349 if ($sequence eq 'binary-arch') {
 350         push @options, "-a";
 351         # as an optimisation, remove from the list any packages
 352         # that are not arch dependent
 353         my %arch_packages = map { $_ => 1 } getpackages("arch");
 354         @packages = grep { $arch_packages{$_} } @packages;
 355 }
 356 elsif ($sequence eq 'binary-indep') {
 357         push @options, "-i";
 358         # ditto optimisation for arch indep
 359         my %indep_packages = map { $_ => 1 } getpackages("indep");
 360         @packages = grep { $indep_packages{$_} } @packages;
 361 }
 362 while (@ARGV_orig) {
 363         my $opt=shift @ARGV_orig;
 364         next if $opt eq $sequence;
 365         if ($opt =~ /^--?(after|until|before|with)$/) {
 366                 shift @ARGV_orig;
 367                 next;
 368         }
 369         elsif ($opt =~ /^--?(no-act|remaining|(after|until|before|with)=)/) {
 370                 next;
 371         }
 372         push @options, $opt;
 373 }
 374
 375 # Figure out at what point in the sequence to start for each package.
 376 my %logged;
 377 my %startpoint;
 378 foreach my $package (@packages) {
 379         my @log=load_log($package, \%logged);
 380         if ($dh{AFTER}) {
 381                 # Run commands in the sequence that come after the
 382                 # specified command.
 383                 $startpoint{$package}=command_pos($dh{AFTER}, @sequence) + 1;
 384                 # Write a dummy log entry indicating that the specified
 385                 # command was, in fact, run. This handles the case where
 386                 # no commands remain to run after it, communicating to
 387                 # future dh instances that the specified command should not
 388                 # be run again.
 389                 write_log($sequence[$startpoint{$package}-1], $package);
 390         }
 391         elsif ($dh{REMAINING}) {
 392                 # Start at the beginning so all remaining commands will get
 393                 # run.
 394                 $startpoint{$package}=0;
 395         }
 396         else {
 397                 # Find the last logged command that is in the sequence, and
 398                 # continue with the next command after it. If no logged
 399                 # command is in the sequence, we're starting at the beginning..
 400                 $startpoint{$package}=0;
 401 COMMAND:        foreach my $command (reverse @log) {
 402                         foreach my $i (0..$#sequence) {
 403                                 if ($command eq $sequence[$i]) {
 404                                         $startpoint{$package}=$i+1;
 405                                         last COMMAND;
 406                                 }
 407                         }
 408                 }
 409         }
 410 }
 411
 412 # Figure out what point in the sequence to go to.
 413 my $stoppoint=$#sequence;
 414 if ($dh{UNTIL}) {
 415         $stoppoint=command_pos($dh{UNTIL}, @sequence);
 416 }
 417 elsif ($dh{BEFORE}) {
 418         $stoppoint=command_pos($dh{BEFORE}, @sequence) - 1;
 419 }
 420
 421 # Now run the commands in the sequence.
 422 foreach my $i (0..$stoppoint) {
 423         # Figure out which packages need to run this command.
 424         my @exclude;
 425         foreach my $package (@packages) {
 426                 if ($startpoint{$package} > $i ||
 427                     $logged{$package}{$sequence[$i]}) {
 428                         push @exclude, $package;
 429                 }
 430         }
 431
 432         if (@exclude eq @packages) {
 433                 # Command already done for all packages.
 434                 next;
 435         }
 436
 437         run($sequence[$i], \@packages, \@exclude, @options);
 438 }
 439
 440 sub run {
 441         my $command=shift;
 442         my @packages=@{shift()};
 443         my @exclude=@{shift()};
 444         my @options=@_;
 445
 446         # If some packages are excluded, add flags
 447         # to prevent them from being acted on.
 448         push @options, map { "-N$_" } @exclude;
 449
 450         # Check for override targets in debian/rules and
 451         # run them instead of running the command directly.
 452         my $override_command;
 453         if (rules_explicit_target("override_".$command)) {
 454                 $override_command=$command;
 455                 # This passes the options through to commands called
 456                 # inside the target.
 457                 $ENV{DH_INTERNAL_OPTIONS}=join(" ", @options);
 458                 $command="debian/rules";
 459                 @options="override_".$override_command;
 460         }
 461
 462         # 3 space indent lines the command being run up under the
 463         # sequence name after "dh ".
 464         print "   ".escape_shell($command, @options)."\n";
 465
 466         if (! $dh{NO_ACT}) {
 467                 my $ret=system($command, @options);
 468                 if ($ret >> 8 != 0) {
 469                         exit $ret >> 8;
 470                 }
 471                 elsif ($ret) {
 472                         exit 1;
 473                 }
 474
 475                 if (defined $override_command) {
 476                         delete $ENV{DH_INTERNAL_OPTIONS};
 477                         # Need to handle logging for overriden commands here,
 478                         # because the actual debhelper command may not have
 479                         # been run by the rules file target.
 480                         my %packages=map { $_ => 1 } @packages;
 481                         map { delete $packages{$_} } @exclude;
 482                         write_log($override_command, keys %packages);
 483                 }
 484         }
 485 }
 486
 487 {
 488 my %targets;
 489 my $rules_parsed;
 490
 491 sub rules_explicit_target {
 492         # Checks if a specified target exists as an explicit target
 493         # in debian/rules.
 494         my $target=shift;
 495
 496         if (! $rules_parsed) {
 497                 my $processing_targets = 0;
 498                 my $not_a_target = 0;
 499                 open(MAKE, "LC_ALL=C make -Rrnpsf debian/rules debhelper-fail-me 2>/dev/null |");
 500                 while (<MAKE>) {
 501                         if ($processing_targets) {
 502                                 if (/^# Not a target:/) {
 503                                         $not_a_target = 1;
 504                                 }
 505                                 else {
 506                                         if (!$not_a_target && /^([^#:]+)::?/) {
 507                                                 # Target is defined.
 508                                                 # NOTE: if it is a depenency
 509                                                 # of .PHONY it will be
 510                                                 # defined too but that's ok.
 511                                                 $targets{$1} = 1;
 512                                         }
 513                                         # "Not a target:" is always followed by
 514                                         # a target name, so resetting this one
 515                                         # here is safe.
 516                                         $not_a_target = 0;
 517                                 }
 518                         } elsif (/^# Files$/) {
 519                                 $processing_targets = 1;
 520                         }
 521                 }
 522                 close MAKE;
 523                 $rules_parsed = 1;
 524         }
 525
 526         return exists $targets{$target};
 527 }
 528
 529 }
 530
 531 =head1 SEE ALSO
 532
 533 L<debhelper(7)>
 534
 535 This program is a part of debhelper.
 536
 537 =head1 AUTHOR
 538
 539 Joey Hess <joeyh@debian.org>
 540
 541 =cut