dh

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh - debhelper command sequencer
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh> sequence [B<--with> I<addon>] [B<--until> I<cmd>] [B<--before> I<cmd>] [B<--after> I<cmd>] [B<--remaining>] [S<I<debhelper options>>]
  15
  16 =head1 DESCRIPTION
  17
  18 dh runs a sequence of debhelper commands. The supported sequences
  19 correspond to the targets of a debian/rules file: "build", "clean",
  20 "install", "binary-arch", "binary-indep", and "binary".
  21
  22 Commands in the binary-indep sequence are passed the "-i" option to ensure
  23 they only work on binary independent packages, and commands in the
  24 binary-arch sequences are passed the "-a" option to ensure they only work
  25 on architecture dependent packages.
  26
  27 Each debhelper command will record when it's successfully run in
  28 debian/package.debhelper.log. (Which dh_clean deletes.) So dh can tell
  29 which commands have already been run, for which packages, and skip running
  30 those commands again.
  31
  32 Each time dh is run, it examines the log, and finds the last logged command
  33 that is in the specified sequence. It then continues with the next command
  34 in the sequence. The B<--until>, B<--before>, B<--after>, and B<--remaining>
  35 options can override this behavior.
  36
  37 If debian/rules contains a target with a name like "override_I<dh_command>",
  38 then when it gets to that command in the sequence, dh will run that
  39 target from the rules file, rather than running the actual command. The
  40 override target can then run the command with additional options, or run
  41 entirely different commands instead. (Note that to use this feature,
  42 you should Build-Depend on debhelper 7.2 or above.)
  43
  44 =head1 OPTIONS
  45
  46 =over 4
  47
  48 =item B<--with> I<addon>
  49
  50 Add the debhelper commands specified by the given addon to appropriate places
  51 in the sequence of commands that is run. This option can be repeated more
  52 than once, and is used when there is a third-party package that provides
  53 debhelper commands. See "SEQUENCE ADDONS" below for documentation about what
  54 such packages should do to be supported by --with.
  55
  56 =item B<--until> I<cmd>
  57
  58 Run commands in the sequence until and including I<cmd>, then stop.
  59
  60 =item B<--before> I<cmd>
  61
  62 Run commands in the sequence before I<cmd>, then stop.
  63
  64 =item B<--after> I<cmd>
  65
  66 Run commands in the sequence that come after I<cmd>.
  67
  68 =item B<--remaining>
  69
  70 Run all commands in the sequence that have yet to be run.
  71
  72 =back
  73
  74 All other options passed to dh are passed on to each command it runs. This
  75 can be used to set an option like "-v" or "-X" or "-N", as well as for more
  76 specialised options.
  77
  78 =head1 COMMAND SPECIFICATION
  79
  80 I<cmd> can be a full name of a debhelper command, or a substring. It'll first
  81 search for a command in the sequence exactly matching the name, to avoid any
  82 ambiguity. If there are multiple substring matches, the last one in the
  83 sequence will be used.
  84
  85 =head1 SEQUENCE ADDONS
  86
  87 When B<--with> I<addon> is used, dh loads the perl module
  88 Debian::Debhelper::Sequence::I<addon>. Two functions are provided to let
  89 the module add its commands to sequences:
  90
  91 =over 4
  92
  93 =item Debian::Debhelper::Dh_Lib::insert_before(existing_command, new_command)
  94
  95 Insert I<new_command> in sequences before I<existing_command>.
  96
  97 =item Debian::Debhelper::Dh_Lib::insert_after(existing_command, new_command)
  98
  99 Insert I<new_command> in sequences after I<existing_command>.
 100
 101 =item Debian::Debhelper::Dh_Lib::remove_command(existing_command)
 102
 103 Remove I<existing_command> from the list of commands to run.
 104
 105 =back
 106
 107 =cut
 108
 109 sub command_pos {
 110         my $command=shift;
 111         my @sequence=@_;
 112
 113         foreach my $i (0..$#sequence) {
 114                 if ($command eq $sequence[$i]) {
 115                         return $i;
 116                 }
 117         }
 118
 119         my @matches;
 120         foreach my $i (0..$#sequence) {
 121                 if ($sequence[$i] =~ /\Q$command\E/) {
 122                         push @matches, $i;
 123                 }
 124         }
 125         if (! @matches) {
 126                 error "command specification \"$command\" does not match any command in the sequence"
 127         }
 128         else {
 129                 return pop @matches;
 130         }
 131 }
 132
 133 =head1 EXAMPLES
 134
 135 To see what commands are included in a sequence, without actually doing
 136 anything:
 137
 138         dh binary-arch --no-act
 139
 140 This is a very simple rules file, for packages where the default sequences of
 141 commands work with no additional options.
 142
 143         #!/usr/bin/make -f
 144         %:
 145                 dh $@
 146
 147 Often you'll want to pass an option to a specific debhelper command. The
 148 easy way to do with is by adding an override target for that command.
 149
 150         #!/usr/bin/make -f
 151         %:
 152                 dh $@
 153
 154         override_dh_strip:
 155                 dh_strip -Xfoo
 156
 157         override_dh_installdocs:
 158                 dh_installdocs README TODO
 159
 160 Sometimes the automated dh_auto_configure and dh_auto_build can't guess
 161 what to do for a strange package. Here's how to avoid running either
 162 and instead run your own commands.
 163
 164         #!/usr/bin/make -f
 165         %:
 166                 dh $@
 167
 168         override_dh_auto_configure:
 169                 ./mondoconfig
 170
 171         override_dh_auto_build:
 172                 make universe-explode-in-delight
 173
 174 Another common case is wanting to do something manually before or
 175 after a particular debhelper command is run.
 176
 177         #!/usr/bin/make -f
 178         %:
 179                 dh $@
 180
 181         override_dh_fixperms:
 182                 dh_fixperms
 183                 chmod 4755 debian/foo/usr/bin/foo
 184
 185 If the package's source tree might get files with names
 186 like build or clean in it, the rules file would not
 187 run targets with the same names. This issue can be worked
 188 around by passing -B to make.
 189
 190         #!/usr/bin/make -Bf
 191         %:
 192                 dh $@
 193
 194 =cut
 195
 196 # Stash this away before init modifies it.
 197 my @ARGV_orig=@ARGV;
 198
 199 init();
 200 inhibit_log();
 201
 202 # Definitions of sequences.
 203 my %sequences;
 204 $sequences{build} = [qw{
 205         dh_testdir
 206         dh_auto_configure
 207         dh_auto_build
 208         dh_auto_test
 209 }],
 210 $sequences{clean} = [qw{
 211         dh_testdir
 212         dh_auto_clean
 213         dh_clean
 214 }];
 215 $sequences{install} = [@{$sequences{build}}, qw{
 216         dh_testroot
 217         dh_prep
 218         dh_installdirs
 219         dh_auto_install
 220
 221         dh_install
 222         dh_installdocs
 223         dh_installchangelogs
 224         dh_installexamples
 225         dh_installman
 226
 227         dh_installcatalogs
 228         dh_installcron
 229         dh_installdebconf
 230         dh_installcatalogs
 231         dh_installemacsen
 232         dh_installifupdown
 233         dh_installinfo
 234         dh_installinit
 235         dh_installmenu
 236         dh_installmime
 237         dh_installmodules
 238         dh_installlogcheck
 239         dh_installlogrotate
 240         dh_installpam
 241         dh_installppp
 242         dh_installudev
 243         dh_installwm
 244         dh_installxfonts
 245         dh_lintian
 246         dh_desktop
 247         dh_gconf
 248         dh_icons
 249         dh_perl
 250         dh_scrollkeeper
 251         dh_usrlocal
 252
 253         dh_link
 254         dh_compress
 255         dh_fixperms
 256 }];
 257 my @b=qw{
 258         dh_installdeb
 259         dh_gencontrol
 260         dh_md5sums
 261         dh_builddeb
 262 };
 263 $sequences{'binary-indep'} = [@{$sequences{install}}, @b];
 264 $sequences{binary} = [@{$sequences{install}}, qw{
 265         dh_strip
 266         dh_makeshlibs
 267         dh_shlibdeps
 268 }, @b];
 269 $sequences{'binary-arch'} = [@{$sequences{binary}}];
 270
 271 # --with python-support is enabled by default, at least for now
 272 unshift @{$dh{WITH}}, "python-support";
 273
 274 # sequence addon interface
 275 sub _insert {
 276         my $offset=shift;
 277         my $existing=shift;
 278         my $new=shift;
 279         foreach my $sequence (keys %sequences) {
 280                 my @list=@{$sequences{$sequence}};
 281                 next unless grep $existing, @list;
 282                 my @new;
 283                 foreach my $command (@list) {
 284                         if ($command eq $existing) {
 285                                 push @new, $new if $offset < 0;
 286                                 push @new, $command;
 287                                 push @new, $new if $offset > 0;
 288                         }
 289                         else {
 290                                 push @new, $command;
 291                         }
 292                 }
 293                 $sequences{$sequence}=\@new;
 294         }
 295 }
 296 sub insert_before {
 297         _insert(-1, @_);
 298 }
 299 sub insert_after {
 300         _insert(1, @_);
 301 }
 302 sub remove_command {
 303         my $command=shift;
 304         foreach my $sequence (keys %sequences) {
 305                 $sequences{$sequence}=[grep { $_ ne $command } @{$sequences{$sequence}}];
 306         }
 307
 308 }
 309 foreach my $addon (@{$dh{WITH}}) {
 310         my $mod="Debian::Debhelper::Sequence::$addon";
 311         $mod=~s/-/_/g;
 312         eval "use $mod";
 313         if ($@) {
 314                 error("--with $addon not supported or failed to load module $mod");
 315         }
 316 }
 317
 318 # Get the sequence of commands to run.
 319 if (! @ARGV) {
 320         error "specify a sequence to run";
 321 }
 322 my $sequence=shift;
 323 if ($sequence eq 'debian/rules' ||
 324     $sequence =~ /^override_dh_/) {
 325         # make -B causes the rules file to be run as a target
 326         # and support completly empty override targets
 327         exit 0
 328 }
 329 elsif (! exists $sequences{$sequence}) {
 330         error "Unknown sequence $sequence (choose from: ".
 331                 join(" ", sort keys %sequences).")";
 332 }
 333 my @sequence=@{$sequences{$sequence}};
 334
 335 # The list of all packages that can be acted on.
 336 my @packages=@{$dh{DOPACKAGES}};
 337
 338 # Get the options to pass to commands in the sequence.
 339 # Filter out options intended only for this program.
 340 my @options;
 341 if ($sequence eq 'binary-arch') {
 342         push @options, "-a";
 343         # as an optimisation, remove from the list any packages
 344         # that are not arch dependent
 345         my %arch_packages = map { $_ => 1 } getpackages("arch");
 346         @packages = grep { $arch_packages{$_} } @packages;
 347 }
 348 elsif ($sequence eq 'binary-indep') {
 349         push @options, "-i";
 350         # ditto optimisation for arch indep
 351         my %indep_packages = map { $_ => 1 } getpackages("indep");
 352         @packages = grep { $indep_packages{$_} } @packages;
 353 }
 354 while (@ARGV_orig) {
 355         my $opt=shift @ARGV_orig;
 356         next if $opt eq $sequence;
 357         if ($opt =~ /^--?(after|until|before|with)$/) {
 358                 shift @ARGV_orig;
 359                 next;
 360         }
 361         elsif ($opt =~ /^--?(no-act|remaining|(after|until|before|with)=)/) {
 362                 next;
 363         }
 364         push @options, $opt;
 365 }
 366
 367 # Figure out at what point in the sequence to start for each package.
 368 my %logged;
 369 my %startpoint;
 370 foreach my $package (@packages) {
 371         my @log=loadlog($package);
 372         if ($dh{AFTER}) {
 373                 # Run commands in the sequence that come after the
 374                 # specified command.
 375                 $startpoint{$package}=command_pos($dh{AFTER}, @sequence) + 1;
 376                 # Write a dummy log entry indicating that the specified
 377                 # command was, in fact, run. This handles the case where
 378                 # no commands remain to run after it, communicating to
 379                 # future dh instances that the specified command should not
 380                 # be run again.
 381                 writelog($package, $sequence[$startpoint{$package}-1]);
 382         }
 383         elsif ($dh{REMAINING}) {
 384                 # Start at the beginning so all remaining commands will get
 385                 # run.
 386                 $startpoint{$package}=0;
 387         }
 388         else {
 389                 # Find the last logged command that is in the sequence, and
 390                 # continue with the next command after it. If no logged
 391                 # command is in the sequence, we're starting at the beginning..
 392                 $startpoint{$package}=0;
 393 COMMAND:        foreach my $command (reverse @log) {
 394                         foreach my $i (0..$#sequence) {
 395                                 if ($command eq $sequence[$i]) {
 396                                         $startpoint{$package}=$i+1;
 397                                         last COMMAND;
 398                                 }
 399                         }
 400                 }
 401         }
 402 }
 403
 404 # Figure out what point in the sequence to go to.
 405 my $stoppoint=$#sequence;
 406 if ($dh{UNTIL}) {
 407         $stoppoint=command_pos($dh{UNTIL}, @sequence);
 408 }
 409 elsif ($dh{BEFORE}) {
 410         $stoppoint=command_pos($dh{BEFORE}, @sequence) - 1;
 411 }
 412
 413 # Now run the commands in the sequence.
 414 foreach my $i (0..$stoppoint) {
 415         # Figure out which packages need to run this command.
 416         my @exclude;
 417         foreach my $package (@packages) {
 418                 if ($startpoint{$package} > $i ||
 419                     $logged{$package}{$sequence[$i]}) {
 420                         push @exclude, $package;
 421                 }
 422         }
 423
 424         if (@exclude eq @packages) {
 425                 # Command already done for all packages.
 426                 next;
 427         }
 428
 429         run($sequence[$i], \@packages, \@exclude, @options);
 430 }
 431
 432 sub run {
 433         my $command=shift;
 434         my @packages=@{shift()};
 435         my @exclude=@{shift()};
 436         my @options=@_;
 437
 438         # Check for override targets in debian/rules and
 439         # run them instead of running the command directly.
 440         my $override_command;
 441         if (rules_explicit_target("override_".$command)) {
 442                 $override_command=$command;
 443                 # This passes the options through to commands called
 444                 # inside the target.
 445                 $ENV{DH_INTERNAL_OPTIONS}=join(" ", @options);
 446                 $command="debian/rules";
 447                 @options="override_".$override_command;
 448         }
 449         else {
 450                 # If some packages are excluded, add flags
 451                 # to prevent them from being acted on.
 452                 push @options, map { "-N$_" } @exclude;
 453         }
 454
 455         # 3 space indent lines the command being run up under the
 456         # sequence name after "dh ".
 457         print "   ".escape_shell($command, @options)."\n";
 458
 459         if (! $dh{NO_ACT}) {
 460                 my $ret=system($command, @options);
 461                 if ($ret >> 8 != 0) {
 462                         exit $ret >> 8;
 463                 }
 464                 elsif ($ret) {
 465                         exit 1;
 466                 }
 467
 468                 if (defined $override_command) {
 469                         delete $ENV{DH_INTERNAL_OPTIONS};
 470                         # Need to handle logging for overriden commands here,
 471                         # because the actual debhelper command may not have
 472                         # been run by the rules file target.
 473                         my %packages=map { $_ => 1 } @packages;
 474                         map { delete $packages{$_} } @exclude;
 475                         Debian::Debhelper::Dh_Lib::write_log($override_command, keys %packages);
 476                 }
 477         }
 478 }
 479
 480 sub loadlog {
 481         my $package=shift;
 482         my $ext=pkgext($package);
 483
 484         my @log;
 485         open(LOG, "<", "debian/${ext}debhelper.log") || return;
 486         while (<LOG>) {
 487                 chomp;
 488                 push @log, $_;
 489                 $logged{$package}{$_}=1;
 490         }
 491         close LOG;
 492         return @log;
 493 }
 494
 495 sub writelog {
 496         my $package=shift;
 497         my $cmd=shift;
 498         my $ext=pkgext($package);
 499
 500         open(LOG, ">>", "debian/${ext}debhelper.log") || error("failed to write to log");
 501         print LOG $cmd."\n";
 502         close LOG;
 503 }
 504
 505 {
 506 my %targets;
 507 my $rules_parsed;
 508
 509 sub rules_explicit_target {
 510         # Checks if a specified target exists as an explicit target
 511         # in debian/rules.
 512         my $target=shift;
 513
 514         if (! $rules_parsed) {
 515                 my $processing_targets = 0;
 516                 my $not_a_target = 0;
 517                 open(MAKE, "make -Rrnpsf debian/rules debhelper-fail-me 2>/dev/null |");
 518                 while (<MAKE>) {
 519                         if ($processing_targets) {
 520                                 if (/^# Not a target:/) {
 521                                         $not_a_target = 1;
 522                                 }
 523                                 else {
 524                                         if (!$not_a_target && /^([^#:]+)::?/) {
 525                                                 # Target is defined.
 526                                                 # NOTE: if it is a depenency
 527                                                 # of .PHONY it will be
 528                                                 # defined too but that's ok.
 529                                                 $targets{$1} = 1;
 530                                         }
 531                                         # "Not a target:" is always followed by
 532                                         # a target name, so resetting this one
 533                                         # here is safe.
 534                                         $not_a_target = 0;
 535                                 }
 536                         } elsif (/^# Files$/) {
 537                                 $processing_targets = 1;
 538                         }
 539                 }
 540                 close MAKE;
 541                 $rules_parsed = 1;
 542         }
 543
 544         return exists $targets{$target};
 545 }
 546
 547 }
 548
 549 =head1 SEE ALSO
 550
 551 L<debhelper(7)>
 552
 553 This program is a part of debhelper.
 554
 555 =head1 AUTHOR
 556
 557 Joey Hess <joeyh@debian.org>
 558
 559 =cut