Lib/mk20dx256vlh7.bootloader.ld

   1 /* Teensyduino Core Library
   2  * http://www.pjrc.com/teensy/
   3  * Copyright (c) 2013 PJRC.COM, LLC.
   4  * Modifications by Jacob Alexander 2014-2015 for use with McHCK and Kiibohd-dfu
   5  *
   6  * Permission is hereby granted, free of charge, to any person obtaining
   7  * a copy of this software and associated documentation files (the
   8  * "Software"), to deal in the Software without restriction, including
   9  * without limitation the rights to use, copy, modify, merge, publish,
  10  * distribute, sublicense, and/or sell copies of the Software, and to
  11  * permit persons to whom the Software is furnished to do so, subject to
  12  * the following conditions:
  13  *
  14  * 1. The above copyright notice and this permission notice shall be
  15  * included in all copies or substantial portions of the Software.
  16  *
  17  * 2. If the Software is incorporated into a build system that allows
  18  * selection among a list of target devices, then similar target
  19  * devices manufactured by PJRC.COM must be included in the list of
  20  * target devices and selectable in the same manner.
  21  *
  22  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  23  * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  24  * MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  25  * NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS
  26  * BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN
  27  * ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  28  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  29  * SOFTWARE.
  30  */
  31
  32 MEMORY
  33 {
  34         FLASH (rx)     : ORIGIN = 0x0, LENGTH = 256K
  35         FLASH_APP (rx) : ORIGIN = 8K, LENGTH = 256K-8K
  36         FLASH_END (r)  : ORIGIN = 256K, LENGTH = 32
  37         RAM  (rwx)     : ORIGIN = 0x20000000 - 64K / 2, LENGTH = 64K
  38 }
  39
  40 /* Starting Address of the application ROM */
  41 _app_rom = ORIGIN( FLASH_APP );
  42 _app_rom_end = ORIGIN( FLASH_END );
  43
  44 FlexRAM = 0x14000000;
  45 FTFL = 0x40020000;
  46 SCB = 0xe000ed00;
  47 USB0 = 0x40072000;
  48 SIM = 0x40047000;
  49
  50 /* Section Definitions */
  51 SECTIONS
  52 {
  53         .text :
  54         {
  55                 . = 0; KEEP(* (.vectors)) /* MUST BE AT 0 */
  56                 *(.startup*)
  57                 . = 0x400; KEEP(* (.flashconfig)) /* MUST BE AT 0x400 */
  58                 *(.rodata*)
  59                 *(.text*)
  60                 . = ALIGN(4);
  61                 KEEP(*(.init))
  62         } > FLASH
  63
  64         .ARM.exidx :
  65         {
  66                 __exidx_start = .;
  67                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  68                 __exidx_end = .;
  69         } > FLASH
  70         _etext = .;
  71
  72         .usbdescriptortable (NOLOAD) : {
  73                 . = ALIGN(512);
  74                 *(.usbdescriptortable*)
  75         } > RAM
  76
  77         .dmabuffers (NOLOAD) : {
  78                 . = ALIGN(4);
  79                 *(.dmabuffers*)
  80         } > RAM
  81
  82         .usbbuffers (NOLOAD) : {
  83                 . = ALIGN(4);
  84                 *(.usbbuffers*)
  85         } > RAM
  86
  87         .data : AT (_etext) {
  88                 . = ALIGN(4);
  89                 _sdata = .;
  90                 *(SORT_BY_ALIGNMENT(.ramtext.*) SORT_BY_ALIGNMENT(.data*))
  91                 *(.data*)
  92                 . = ALIGN(4);
  93                 _edata = .;
  94         } > RAM
  95
  96         .noinit (NOLOAD) : {
  97                 *(.noinit*)
  98         } > RAM
  99
 100         .bss : {
 101                 . = ALIGN(4);
 102                 _sbss = .;
 103                 *(.bss*)
 104                 *(COMMON)
 105                 . = ALIGN(4);
 106                 _ebss = .;
 107                 __bss_end = .;
 108         } > RAM
 109
 110         _estack = ORIGIN(RAM) + LENGTH(RAM);
 111 }
 112