Lib/CMake/build.cmake

   1 ###| CMAKE Kiibohd Controller Source Configurator |###
   2 #
   3 # Written by Jacob Alexander in 2011-2014 for the Kiibohd Controller
   4 #
   5 # Released into the Public Domain
   6 #
   7 ###
   8
   9
  10 ###
  11 # Disable -Wl,-search_paths_first for OSX (not supported by avr-gcc or arm-none-eabi-gcc)
  12 #
  13
  14 if ( APPLE )
  15         string ( REPLACE "-Wl,-search_paths_first" "" CMAKE_C_LINK_FLAGS ${CMAKE_C_LINK_FLAGS} )
  16         string ( REPLACE "-Wl,-search_paths_first" "" CMAKE_CXX_LINK_FLAGS ${CMAKE_CXX_LINK_FLAGS} )
  17 endif ()
  18
  19
  20
  21 ###
  22 # Build Targets
  23 #
  24
  25 #| Create the .ELF file
  26 set( TARGET_ELF ${TARGET}.elf )
  27 add_executable( ${TARGET_ELF} ${SRCS} generatedKeymap.h )
  28
  29
  30 #| .ELF Properties
  31 set_target_properties( ${TARGET_ELF} PROPERTIES
  32         LINK_FLAGS ${LINKER_FLAGS}
  33         SUFFIX ""                               # XXX Force Windows to keep the .exe off
  34 )
  35
  36 #| llvm-clang does not have an objcopy equivalent
  37 if ( "${COMPILER}" MATCHES "clang" )
  38         if ( "${COMPILER_FAMILY}" MATCHES "arm" )
  39                 set ( OBJ_COPY arm-none-eabi-objcopy )
  40         elseif ( "${COMPILER_FAMILY}" MATCHES "arm" )
  41                 set ( OBJ_COPY avr-objcopy )
  42         endif ()
  43 else ()
  44         set ( OBJ_COPY ${CMAKE_OBJCOPY} )
  45 endif ()
  46
  47
  48 #| Convert the .ELF into a .bin to load onto the McHCK
  49 if ( DEFINED DFU )
  50         set( TARGET_BIN ${TARGET}.dfu.bin )
  51         add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
  52                 COMMAND ${OBJ_COPY} ${BIN_FLAGS} ${TARGET_ELF} ${TARGET_BIN}
  53                 COMMENT "Creating dfu binary file:      ${TARGET_BIN}"
  54         )
  55 endif ()
  56
  57
  58 #| Convert the .ELF into a .HEX to load onto the Teensy
  59 if ( DEFINED TEENSY )
  60         set( TARGET_HEX ${TARGET}.teensy.hex )
  61         add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
  62                 COMMAND ${OBJ_COPY} ${HEX_FLAGS} ${TARGET_ELF} ${TARGET_HEX}
  63                 COMMENT "Creating iHex file to load:    ${TARGET_HEX}"
  64         )
  65 endif()
  66
  67
  68 #| Generate the Extended .LSS
  69 set( TARGET_LSS ${TARGET}.lss )
  70 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
  71         COMMAND ${CMAKE_OBJDUMP} ${LSS_FLAGS} ${TARGET_ELF} > ${TARGET_LSS}
  72         COMMENT "Creating Extended Listing:     ${TARGET_LSS}"
  73 )
  74
  75
  76 #| Generate the Symbol Table .SYM
  77 set( TARGET_SYM ${TARGET}.sym )
  78 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
  79         COMMAND ${CMAKE_NM} -n ${TARGET_ELF} > ${TARGET_SYM}
  80         COMMENT "Creating Symbol Table:         ${TARGET_SYM}"
  81 )
  82
  83
  84 #| Compiler Selection Record
  85 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
  86         COMMAND ${CMAKE_SOURCE_DIR}/Lib/CMake/writer compiler ${COMPILER_FAMILY}
  87 )
  88
  89
  90
  91 ###
  92 # Size Information
  93 #
  94
  95 #| After Changes Size Information
  96 add_custom_target( SizeAfter ALL
  97         COMMAND ${CMAKE_SOURCE_DIR}/Lib/CMake/sizeCalculator ${CMAKE_SIZE} ram   ${TARGET_ELF} ${SIZE_RAM}   " SRAM"
  98         COMMAND ${CMAKE_SOURCE_DIR}/Lib/CMake/sizeCalculator ${CMAKE_SIZE} flash ${TARGET_ELF} ${SIZE_FLASH} "Flash"
  99         DEPENDS ${TARGET_ELF}
 100         COMMENT "Chip usage for ${CHIP}"
 101 )
 102
 103
 104
 105 ###
 106 # Setup Loader Script and Program
 107 #
 108
 109 #| First check for DFU based controllers
 110 if( DEFINED DFU )
 111         configure_file( LoadFile/load.dfu load NEWLINE_STYLE UNIX )
 112
 113 #| Next check for Teensy based
 114 elseif ( DEFINED TEENSY )
 115         # Provides the user with the correct teensy-loader-cli command for the built .HEX file
 116         # Windows
 117         if( CMAKE_SYSTEM_NAME MATCHES "Windows" )
 118                 configure_file( LoadFile/winload.teensy load NEWLINE_STYLE UNIX )
 119         # Default
 120         else()
 121                 configure_file( LoadFile/load.teensy load NEWLINE_STYLE UNIX )
 122         endif()
 123 endif()
 124