Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2000.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &is_udeb
  17             &udeb_filename);
  18
  19 my $max_compat=4;
  20
  21 sub init {
  22         # If DH_OPTIONS is set, prepend it @ARGV.
  23         if (defined($ENV{DH_OPTIONS})) {
  24                 # Ignore leading/trailing whitespace.
  25                 $ENV{DH_OPTIONS}=~s/^\s+//;
  26                 $ENV{DH_OPTIONS}=~s/\s+$//;
  27                 unshift @ARGV,split(/\s+/,$ENV{DH_OPTIONS});
  28         }
  29
  30         # Check to see if an argument on the command line starts with a dash.
  31         # if so, we need to pass this off to the resource intensive
  32         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  33         my $parseopt=undef;
  34         my $arg;
  35         foreach $arg (@ARGV) {
  36                 if ($arg=~m/^-/) {
  37                         $parseopt=1;
  38                         last;
  39                 }
  40         }
  41         if ($parseopt) {
  42                 eval "use Debian::Debhelper::Dh_Getopt";
  43                 error($!) if $@;
  44                 %dh=Debian::Debhelper::Dh_Getopt::parseopts();
  45         }
  46
  47         # Another way to set excludes.
  48         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  49                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  50         }
  51
  52         # Generate EXCLUDE_FIND.
  53         if ($dh{EXCLUDE}) {
  54                 $dh{EXCLUDE_FIND}='';
  55                 foreach (@{$dh{EXCLUDE}}) {
  56                         my $x=$_;
  57                         $x=escape_shell($x);
  58                         $x=~s/\./\\./g;
  59                         $dh{EXCLUDE_FIND}.="-regex .*$x.* -or ";
  60                 }
  61                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  62         }
  63
  64         # Check to see if DH_VERBOSE environment variable was set, if so,
  65         # make sure verbose is on.
  66         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  67                 $dh{VERBOSE}=1;
  68         }
  69
  70         # Check to see if DH_NO_ACT environment variable was set, if so,
  71         # make sure no act mode is on.
  72         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  73                 $dh{NO_ACT}=1;
  74         }
  75
  76         my @allpackages=getpackages();
  77         # Get the name of the main binary package (first one listed in
  78         # debian/control). Only if the main package was not set on the
  79         # command line.
  80         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  81                 $dh{MAINPACKAGE}=$allpackages[0];
  82         }
  83
  84         # Check if packages to build have been specified, if not, fall back to
  85         # the default, doing them all.
  86         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  87                 if ($dh{DOINDEP} || $dh{DOARCH} || $dh{DOSAME}) {
  88                         error("You asked that all arch in(dep) packages be built, but there are none of that type.");
  89                 }
  90                 push @{$dh{DOPACKAGES}},@allpackages;
  91         }
  92
  93         # Check to see if -P was specified. If so, we can only act on a single
  94         # package.
  95         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  96                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  97         }
  98
  99         # Figure out which package is the first one we were instructed to build.
 100         # This package gets special treatement: files and directories specified on
 101         # the command line may affect it.
 102         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
 103
 104         # If no error handling function was specified, just propigate
 105         # errors out.
 106         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
 107                 $dh{ERROR_HANDLER}='exit $?';
 108         }
 109 }
 110
 111 # Pass it an array containing the arguments of a shell command like would
 112 # be run by exec(). It turns that into a line like you might enter at the
 113 # shell, escaping metacharacters and quoting arguments that contain spaces.
 114 sub escape_shell {
 115         my @args=@_;
 116         my $line="";
 117         my @ret;
 118         foreach my $word (@args) {
 119                 if ($word=~/\s/) {
 120                         # Escape only a few things since it will be quoted.
 121                         # Note we use double quotes because you cannot
 122                         # escape ' in single quotes, while " can be escaped
 123                         # in double.
 124                         # This does make -V"foo bar" turn into "-Vfoo bar",
 125                         # but that will be parsed identically by the shell
 126                         # anyway..
 127                         $word=~s/([\n`\$"\\])/\\$1/g;
 128                         push @ret, "\"$word\"";
 129                 }
 130                 else {
 131                         # This list is from _Unix in a Nutshell_. (except '#')
 132                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 133                         push @ret,$word;
 134                 }
 135         }
 136         return join(' ', @ret);
 137 }
 138
 139 # Run a command, and display the command to stdout if verbose mode is on.
 140 # All commands that modifiy files in $TMP should be ran via this
 141 # function.
 142 #
 143 # Note that this cannot handle complex commands, especially anything
 144 # involving redirection. Use complex_doit instead.
 145 sub doit {
 146         verbose_print(escape_shell(@_));
 147
 148         if (! $dh{NO_ACT}) {
 149                 my $ret=system(@_);
 150                 $ret == 0 || error("command returned error code $ret");
 151         }
 152 }
 153
 154 # Run a command and display the command to stdout if verbose mode is on.
 155 # Use doit() if you can, instead of this function, because this function
 156 # forks a shell. However, this function can handle more complicated stuff
 157 # like redirection.
 158 sub complex_doit {
 159         verbose_print(join(" ",@_));
 160
 161         if (! $dh{NO_ACT}) {
 162                 # The join makes system get a scalar so it forks off a shell.
 163                 system(join(" ",@_)) == 0
 164                         || error("command returned error code");
 165         }
 166 }
 167
 168 # Run a command that may have a huge number of arguments, like xargs does.
 169 # Pass in a reference to an array containing the arguments, and then other
 170 # parameters that are the command and any parameters that should be passed to
 171 # it each time.
 172 sub xargs {
 173         my $args=shift;
 174
 175         # The kernel can accept command lines up to 20k worth of characters.
 176         my $command_max=20000; # LINUX SPECIFIC!!
 177                         # I could use POSIX::ARG_MAX, but that would be slow.
 178
 179         # Figure out length of static portion of command.
 180         my $static_length=0;
 181         foreach (@_) {
 182                 $static_length+=length($_)+1;
 183         }
 184
 185         my @collect=();
 186         my $length=$static_length;
 187         foreach (@$args) {
 188                 if (length($_) + 1 + $static_length > $command_max) {
 189                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 190                 }
 191                 $length+=length($_) + 1;
 192                 if ($length < $command_max) {
 193                         push @collect, $_;
 194                 }
 195                 else {
 196                         doit(@_,@collect) if $#collect > -1;
 197                         @collect=($_);
 198                         $length=$static_length + length($_) + 1;
 199                 }
 200         }
 201         doit(@_,@collect) if $#collect > -1;
 202 }
 203
 204 # Print something if the verbose flag is on.
 205 sub verbose_print {
 206         my $message=shift;
 207
 208         if ($dh{VERBOSE}) {
 209                 print "\t$message\n";
 210         }
 211 }
 212
 213 # Output an error message and exit.
 214 sub error {
 215         my $message=shift;
 216
 217         warning($message);
 218         exit 1;
 219 }
 220
 221 # Output a warning.
 222 sub warning {
 223         my $message=shift;
 224
 225         print STDERR basename($0).": $message\n";
 226 }
 227
 228 # Returns the basename of the argument passed to it.
 229 sub basename {
 230         my $fn=shift;
 231
 232         $fn=~s/\/$//g; # ignore trailing slashes
 233         $fn=~s:^.*/(.*?)$:$1:;
 234         return $fn;
 235 }
 236
 237 # Returns the directory name of the argument passed to it.
 238 sub dirname {
 239         my $fn=shift;
 240
 241         $fn=~s/\/$//g; # ignore trailing slashes
 242         $fn=~s:^(.*)/.*?$:$1:;
 243         return $fn;
 244 }
 245
 246 # Pass in a number, will return true iff the current compatibility level
 247 # is less than or equal to that number.
 248 sub compat {
 249         my $num=shift;
 250
 251         my $c=1;
 252         if (defined $ENV{DH_COMPAT}) {
 253                 $c=$ENV{DH_COMPAT};
 254         }
 255         elsif (-e 'debian/compat') {
 256                 # Try the file..
 257                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 258                 $c=<COMPAT_IN>;
 259                 chomp $c;
 260         }
 261
 262         if ($c > $max_compat) {
 263                 error("Sorry, but $max_compat is the highest compatibility level of debhelper currently supported.");
 264         }
 265
 266         return ($c <= $num);
 267 }
 268
 269 # Pass it a name of a binary package, it returns the name of the tmp dir to
 270 # use, for that package.
 271 sub tmpdir {
 272         my $package=shift;
 273
 274         if ($dh{TMPDIR}) {
 275                 return $dh{TMPDIR};
 276         }
 277         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 278                 # This is for back-compatibility with the debian/tmp tradition.
 279                 return "debian/tmp";
 280         }
 281         else {
 282                 return "debian/$package";
 283         }
 284 }
 285
 286 # Pass this the name of a binary package, and the name of the file wanted
 287 # for the package, and it will return the actual existing filename to use.
 288 #
 289 # It tries several filenames:
 290 #   * debian/package.filename.buildarch
 291 #   * debian/package.filename
 292 #   * debian/file (if the package is the main package)
 293 # If --name was specified then tonly the first two are tried, and they must
 294 # have the name after the pacage name:
 295 #   * debian/package.name.filename.buildarch
 296 #   * debian/package.name.filename
 297 sub pkgfile {
 298         my $package=shift;
 299         my $filename=shift;
 300
 301         if (defined $dh{NAME}) {
 302                 $filename="$dh{NAME}.$filename";
 303         }
 304
 305         if (-f "debian/$package.$filename.".buildarch()) {
 306                 return "debian/$package.$filename.".buildarch();
 307         }
 308         elsif (-f "debian/$package.$filename") {
 309                 return "debian/$package.$filename";
 310         }
 311         elsif ($package eq $dh{MAINPACKAGE} && -f "debian/$filename") {
 312                 return "debian/$filename";
 313         }
 314         else {
 315                 return "";
 316         }
 317 }
 318
 319 # Pass it a name of a binary package, it returns the name to prefix to files
 320 # in debian/ for this package.
 321 sub pkgext {
 322         my $package=shift;
 323
 324         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 325                 return "";
 326         }
 327         return "$package.";
 328 }
 329
 330 # Pass it the name of a binary package, it returns the name to install
 331 # files by in eg, etc. Normally this is the same, but --name can override
 332 # it.
 333 sub pkgfilename {
 334         my $package=shift;
 335
 336         if (defined $dh{NAME}) {
 337                 return $dh{NAME};
 338         }
 339         return $package;
 340 }
 341
 342 # Returns 1 if the package is a native debian package, null otherwise.
 343 # As a side effect, sets $dh{VERSION} to the version of this package.
 344 {
 345         # Caches return code so it only needs to run dpkg-parsechangelog once.
 346         my %isnative_cache;
 347
 348         sub isnative {
 349                 my $package=shift;
 350
 351                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 352
 353                 # Make sure we look at the correct changelog.
 354                 my $isnative_changelog=pkgfile($package,"changelog");
 355                 if (! $isnative_changelog) {
 356                         $isnative_changelog="debian/changelog";
 357                 }
 358                 # Get the package version.
 359                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 360                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 361                 # Did the changelog parse fail?
 362                 if (! defined $dh{VERSION}) {
 363                         error("changelog parse failure");
 364                 }
 365
 366                 # Is this a native Debian package?
 367                 if ($dh{VERSION}=~m/.*-/) {
 368                         return $isnative_cache{$package}=0;
 369                 }
 370                 else {
 371                         return $isnative_cache{$package}=1;
 372                 }
 373         }
 374 }
 375
 376 # Automatically add a shell script snippet to a debian script.
 377 # Only works if the script has #DEBHELPER# in it.
 378 #
 379 # Parameters:
 380 # 1: package
 381 # 2: script to add to
 382 # 3: filename of snippet
 383 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 384 sub autoscript {
 385         my $package=shift;
 386         my $script=shift;
 387         my $filename=shift;
 388         my $sed=shift || "";
 389
 390         # This is the file we will append to.
 391         my $outfile="debian/".pkgext($package)."$script.debhelper";
 392
 393         # Figure out what shell script snippet to use.
 394         my $infile;
 395         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 396             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 397                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 398         }
 399         else {
 400                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 401                         $infile="/usr/share/debhelper/autoscripts/$filename";
 402                 }
 403                 else {
 404                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 405                 }
 406         }
 407
 408         complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 409         complex_doit("sed \"$sed\" $infile >> $outfile");
 410         complex_doit("echo '# End automatically added section' >> $outfile");
 411 }
 412
 413 # Removes a whole substvar line.
 414 sub delsubstvar {
 415         my $package=shift;
 416         my $substvar=shift;
 417
 418         my $ext=pkgext($package);
 419         my $substvarfile="debian/${ext}substvars";
 420
 421         if (-e $substvarfile) {
 422                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 423                 doit("mv", "$substvarfile.new","$substvarfile");
 424         }
 425 }
 426
 427 # Adds a dependency on some package to the specified
 428 # substvar in a package's substvar's file.
 429 sub addsubstvar {
 430         my $package=shift;
 431         my $substvar=shift;
 432         my $deppackage=shift;
 433         my $verinfo=shift;
 434         my $remove=shift;
 435
 436         my $ext=pkgext($package);
 437         my $substvarfile="debian/${ext}substvars";
 438         my $str=$deppackage;
 439         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 440
 441         # Figure out what the line will look like, based on what's there
 442         # now, and what we're to add or remove.
 443         my $line="";
 444         if (-e $substvarfile) {
 445                 my %items;
 446                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 447                 while (<SUBSTVARS_IN>) {
 448                         chomp;
 449                         if (/^\Q$substvar\E=(.*)/) {
 450                                 %items = map { $_ => 1} split(", ", $1);
 451
 452                                 last;
 453                         }
 454                 }
 455                 close SUBSTVARS_IN;
 456                 if (! $remove) {
 457                         $items{$str}=1;
 458                 }
 459                 else {
 460                         delete $items{$str};
 461                 }
 462                 $line=join(", ", keys %items);
 463         }
 464         elsif (! $remove) {
 465                 $line=$str;
 466         }
 467
 468         if (length $line) {
 469                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 470                  doit("mv", "$substvarfile.new", $substvarfile);
 471         }
 472         else {
 473                 delsubstvar($package,$substvar);
 474         }
 475 }
 476
 477 # Reads in the specified file, one line at a time. splits on words,
 478 # and returns an array of arrays of the contents.
 479 # If a value is passed in as the second parameter, then glob
 480 # expansion is done in the directory specified by the parameter ("." is
 481 # frequently a good choice).
 482 sub filedoublearray {
 483         my $file=shift;
 484         my $globdir=shift;
 485
 486         my @ret;
 487         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 488         while (<DH_FARRAY_IN>) {
 489                 my @line;
 490                 # Only do glob expansion in v3 mode.
 491                 #
 492                 # The tricky bit is that the glob expansion is done
 493                 # as if we were in the specified directory, so the
 494                 # filenames that come out are relative to it.
 495                 if (defined $globdir && ! compat(2)) {
 496                         for (map { glob "$globdir/$_" } split) {
 497                                 s#^$globdir/##;
 498                                 push @line, $_;
 499                         }
 500                 }
 501                 else {
 502                         @line = split;
 503                 }
 504                 push @ret, [@line];
 505         }
 506         close DH_FARRAY_IN;
 507
 508         return @ret;
 509 }
 510
 511 # Reads in the specified file, one word at a time, and returns an array of
 512 # the result. Can do globbing as does filedoublearray.
 513 sub filearray {
 514         return map { @$_ } filedoublearray(@_);
 515 }
 516
 517 # Passed a filename, returns true if -X says that file should be excluded.
 518 sub excludefile {
 519         my $filename = shift;
 520         foreach my $f (@{$dh{EXCLUDE}}) {
 521                 return 1 if $filename =~ /\Q$f\E/;
 522         }
 523         return 0;
 524 }
 525
 526 # Returns the build architecture. (Memoized)
 527 {
 528         my $arch;
 529
 530         sub buildarch {
 531                 return $arch if defined $arch;
 532
 533                 $arch=`dpkg-architecture -qDEB_HOST_ARCH 2>/dev/null` || error($!);
 534                 chomp $arch;
 535                 return $arch;
 536         }
 537 }
 538
 539 # Returns a list of packages in the control file.
 540 # Must pass "arch" or "indep" or "same" to specify arch-dependant or
 541 # -independant or same arch packages. If nothing is specified, returns all
 542 # packages.
 543 # As a side effect, populates %package_arches and %package_types with the
 544 # types of all packages (not only those returned).
 545 my (%package_types, %package_arches);
 546 sub getpackages {
 547         my $type=shift;
 548
 549         %package_types=();
 550         %package_arches=();
 551
 552         $type="" if ! defined $type;
 553
 554         # Look up the build arch if we need to.
 555         my $buildarch='';
 556         if ($type eq 'same') {
 557                 $buildarch=buildarch();
 558         }
 559
 560         my $package="";
 561         my $arch="";
 562         my $package_type;
 563         my @list=();
 564         my %seen;
 565         open (CONTROL, 'debian/control') ||
 566                 error("cannot read debian/control: $!\n");
 567         while (<CONTROL>) {
 568                 chomp;
 569                 s/\s+$//;
 570                 if (/^Package:\s*(.*)/) {
 571                         $package=$1;
 572                         # Detect duplicate package names in the same control file.
 573                         if (! $seen{$package}) {
 574                                 $seen{$package}=1;
 575                         }
 576                         else {
 577                                 error("debian/control has a duplicate entry for $package");
 578                         }
 579                         $package_type="deb";
 580                 }
 581                 if (/^Architecture:\s*(.*)/) {
 582                         $arch=$1;
 583                 }
 584                 if (/^X[BC]*-Package-Type:\s*(.*)/) {
 585                         $package_type=$1;
 586                 }
 587
 588                 if (!$_ or eof) { # end of stanza.
 589                         if ($package) {
 590                                 $package_types{$package}=$package_type;
 591                                 $package_arches{$package}=$arch;
 592                         }
 593                         if ($package &&
 594                             (($type eq 'indep' && $arch eq 'all') ||
 595                              ($type eq 'arch' && $arch ne 'all') ||
 596                              ($type eq 'same' && ($arch eq 'any' || $arch =~ /\b$buildarch\b/)) ||
 597                              ! $type)) {
 598                                 push @list, $package;
 599                                 $package="";
 600                                 $arch="";
 601                         }
 602                 }
 603         }
 604         close CONTROL;
 605
 606         return @list;
 607 }
 608
 609 sub is_udeb {
 610         my $package=shift;
 611
 612         return $package_types{$package} eq 'udeb';
 613 }
 614
 615 sub udeb_filename {
 616         my $package=shift;
 617
 618         my $filearch=$package_arches{$package} eq 'all' ? "all" : buildarch();
 619         isnative($package); # side effect
 620         return "${package}_$dh{VERSION}_$filearch.udeb";
 621 }
 622
 623 1