Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2000.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &is_udeb
  17             &udeb_filename);
  18
  19 my $max_compat=4;
  20
  21 sub init {
  22         # If DH_OPTIONS is set, prepend it @ARGV.
  23         if (defined($ENV{DH_OPTIONS})) {
  24                 # Ignore leading/trailing whitespace.
  25                 $ENV{DH_OPTIONS}=~s/^\s+//;
  26                 $ENV{DH_OPTIONS}=~s/\s+$//;
  27                 unshift @ARGV,split(/\s+/,$ENV{DH_OPTIONS});
  28         }
  29
  30         # Check to see if an argument on the command line starts with a dash.
  31         # if so, we need to pass this off to the resource intensive
  32         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  33         my $parseopt=undef;
  34         my $arg;
  35         foreach $arg (@ARGV) {
  36                 if ($arg=~m/^-/) {
  37                         $parseopt=1;
  38                         last;
  39                 }
  40         }
  41         if ($parseopt) {
  42                 eval "use Debian::Debhelper::Dh_Getopt";
  43                 error($!) if $@;
  44                 %dh=Debian::Debhelper::Dh_Getopt::parseopts();
  45         }
  46
  47         # Another way to set excludes.
  48         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  49                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  50         }
  51
  52         # Generate EXCLUDE_FIND.
  53         if ($dh{EXCLUDE}) {
  54                 $dh{EXCLUDE_FIND}='';
  55                 foreach (@{$dh{EXCLUDE}}) {
  56                         my $x=$_;
  57                         $x=escape_shell($x);
  58                         $x=~s/\./\\./g;
  59                         $dh{EXCLUDE_FIND}.="-regex .*$x.* -or ";
  60                 }
  61                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  62         }
  63
  64         # Check to see if DH_VERBOSE environment variable was set, if so,
  65         # make sure verbose is on.
  66         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  67                 $dh{VERBOSE}=1;
  68         }
  69
  70         # Check to see if DH_NO_ACT environment variable was set, if so,
  71         # make sure no act mode is on.
  72         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  73                 $dh{NO_ACT}=1;
  74         }
  75
  76         my @allpackages=getpackages();
  77         # Get the name of the main binary package (first one listed in
  78         # debian/control). Only if the main package was not set on the
  79         # command line.
  80         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  81                 $dh{MAINPACKAGE}=$allpackages[0];
  82         }
  83
  84         # Check if packages to build have been specified, if not, fall back to
  85         # the default, doing them all.
  86         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  87                 if ($dh{DOINDEP} || $dh{DOARCH} || $dh{DOSAME}) {
  88                         error("You asked that all arch in(dep) packages be built, but there are none of that type.");
  89                 }
  90                 push @{$dh{DOPACKAGES}},@allpackages;
  91         }
  92
  93         # Check to see if -P was specified. If so, we can only act on a single
  94         # package.
  95         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  96                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  97         }
  98
  99         # Figure out which package is the first one we were instructed to build.
 100         # This package gets special treatement: files and directories specified on
 101         # the command line may affect it.
 102         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
 103 }
 104
 105 # Pass it an array containing the arguments of a shell command like would
 106 # be run by exec(). It turns that into a line like you might enter at the
 107 # shell, escaping metacharacters and quoting arguments that contain spaces.
 108 sub escape_shell {
 109         my @args=@_;
 110         my $line="";
 111         my @ret;
 112         foreach my $word (@args) {
 113                 if ($word=~/\s/) {
 114                         # Escape only a few things since it will be quoted.
 115                         # Note we use double quotes because you cannot
 116                         # escape ' in single quotes, while " can be escaped
 117                         # in double.
 118                         # This does make -V"foo bar" turn into "-Vfoo bar",
 119                         # but that will be parsed identically by the shell
 120                         # anyway..
 121                         $word=~s/([\n`\$"\\])/\\$1/g;
 122                         push @ret, "\"$word\"";
 123                 }
 124                 else {
 125                         # This list is from _Unix in a Nutshell_. (except '#')
 126                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 127                         push @ret,$word;
 128                 }
 129         }
 130         return join(' ', @ret);
 131 }
 132
 133 # Run a command, and display the command to stdout if verbose mode is on.
 134 # All commands that modifiy files in $TMP should be ran via this
 135 # function.
 136 #
 137 # Note that this cannot handle complex commands, especially anything
 138 # involving redirection. Use complex_doit instead.
 139 sub doit {
 140         verbose_print(escape_shell(@_));
 141
 142         if (! $dh{NO_ACT}) {
 143                 my $ret=system(@_);
 144                 $ret == 0 || error("command returned error code $ret");
 145         }
 146 }
 147
 148 # Run a command and display the command to stdout if verbose mode is on.
 149 # Use doit() if you can, instead of this function, because this function
 150 # forks a shell. However, this function can handle more complicated stuff
 151 # like redirection.
 152 sub complex_doit {
 153         verbose_print(join(" ",@_));
 154
 155         if (! $dh{NO_ACT}) {
 156                 # The join makes system get a scalar so it forks off a shell.
 157                 system(join(" ",@_)) == 0
 158                         || error("command returned error code");
 159         }
 160 }
 161
 162 # Run a command that may have a huge number of arguments, like xargs does.
 163 # Pass in a reference to an array containing the arguments, and then other
 164 # parameters that are the command and any parameters that should be passed to
 165 # it each time.
 166 sub xargs {
 167         my $args=shift;
 168
 169         # The kernel can accept command lines up to 20k worth of characters.
 170         my $command_max=20000; # LINUX SPECIFIC!!
 171                         # I could use POSIX::ARG_MAX, but that would be slow.
 172
 173         # Figure out length of static portion of command.
 174         my $static_length=0;
 175         foreach (@_) {
 176                 $static_length+=length($_)+1;
 177         }
 178
 179         my @collect=();
 180         my $length=$static_length;
 181         foreach (@$args) {
 182                 if (length($_) + 1 + $static_length > $command_max) {
 183                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 184                 }
 185                 $length+=length($_) + 1;
 186                 if ($length < $command_max) {
 187                         push @collect, $_;
 188                 }
 189                 else {
 190                         doit(@_,@collect) if $#collect > -1;
 191                         @collect=($_);
 192                         $length=$static_length + length($_) + 1;
 193                 }
 194         }
 195         doit(@_,@collect) if $#collect > -1;
 196 }
 197
 198 # Print something if the verbose flag is on.
 199 sub verbose_print {
 200         my $message=shift;
 201
 202         if ($dh{VERBOSE}) {
 203                 print "\t$message\n";
 204         }
 205 }
 206
 207 # Output an error message and exit.
 208 sub error {
 209         my $message=shift;
 210
 211         warning($message);
 212         exit 1;
 213 }
 214
 215 # Output a warning.
 216 sub warning {
 217         my $message=shift;
 218
 219         print STDERR basename($0).": $message\n";
 220 }
 221
 222 # Returns the basename of the argument passed to it.
 223 sub basename {
 224         my $fn=shift;
 225
 226         $fn=~s/\/$//g; # ignore trailing slashes
 227         $fn=~s:^.*/(.*?)$:$1:;
 228         return $fn;
 229 }
 230
 231 # Returns the directory name of the argument passed to it.
 232 sub dirname {
 233         my $fn=shift;
 234
 235         $fn=~s/\/$//g; # ignore trailing slashes
 236         $fn=~s:^(.*)/.*?$:$1:;
 237         return $fn;
 238 }
 239
 240 # Pass in a number, will return true iff the current compatibility level
 241 # is less than or equal to that number.
 242 sub compat {
 243         my $num=shift;
 244
 245         my $c=1;
 246         if (defined $ENV{DH_COMPAT}) {
 247                 $c=$ENV{DH_COMPAT};
 248         }
 249         elsif (-e 'debian/compat') {
 250                 # Try the file..
 251                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 252                 $c=<COMPAT_IN>;
 253                 chomp $c;
 254         }
 255
 256         if ($c > $max_compat) {
 257                 error("Sorry, but $max_compat is the highest compatibility level of debhelper currently supported.");
 258         }
 259
 260         return ($c <= $num);
 261 }
 262
 263 # Pass it a name of a binary package, it returns the name of the tmp dir to
 264 # use, for that package.
 265 sub tmpdir {
 266         my $package=shift;
 267
 268         if ($dh{TMPDIR}) {
 269                 return $dh{TMPDIR};
 270         }
 271         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 272                 # This is for back-compatibility with the debian/tmp tradition.
 273                 return "debian/tmp";
 274         }
 275         else {
 276                 return "debian/$package";
 277         }
 278 }
 279
 280 # Pass this the name of a binary package, and the name of the file wanted
 281 # for the package, and it will return the actual existing filename to use.
 282 #
 283 # It tries several filenames:
 284 #   * debian/package.filename.buildarch
 285 #   * debian/package.filename
 286 #   * debian/file (if the package is the main package)
 287 # If --name was specified then tonly the first two are tried, and they must
 288 # have the name after the pacage name:
 289 #   * debian/package.name.filename.buildarch
 290 #   * debian/package.name.filename
 291 sub pkgfile {
 292         my $package=shift;
 293         my $filename=shift;
 294
 295         if (defined $dh{NAME}) {
 296                 $filename="$dh{NAME}.$filename";
 297         }
 298
 299         if (-f "debian/$package.$filename.".buildarch()) {
 300                 return "debian/$package.$filename.".buildarch();
 301         }
 302         elsif (-f "debian/$package.$filename") {
 303                 return "debian/$package.$filename";
 304         }
 305         elsif ($package eq $dh{MAINPACKAGE} && -f "debian/$filename") {
 306                 return "debian/$filename";
 307         }
 308         else {
 309                 return "";
 310         }
 311 }
 312
 313 # Pass it a name of a binary package, it returns the name to prefix to files
 314 # in debian/ for this package.
 315 sub pkgext {
 316         my $package=shift;
 317
 318         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 319                 return "";
 320         }
 321         return "$package.";
 322 }
 323
 324 # Pass it the name of a binary package, it returns the name to install
 325 # files by in eg, etc. Normally this is the same, but --name can override
 326 # it.
 327 sub pkgfilename {
 328         my $package=shift;
 329
 330         if (defined $dh{NAME}) {
 331                 return $dh{NAME};
 332         }
 333         return $package;
 334 }
 335
 336 # Returns 1 if the package is a native debian package, null otherwise.
 337 # As a side effect, sets $dh{VERSION} to the version of this package.
 338 {
 339         # Caches return code so it only needs to run dpkg-parsechangelog once.
 340         my %isnative_cache;
 341
 342         sub isnative {
 343                 my $package=shift;
 344
 345                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 346
 347                 # Make sure we look at the correct changelog.
 348                 my $isnative_changelog=pkgfile($package,"changelog");
 349                 if (! $isnative_changelog) {
 350                         $isnative_changelog="debian/changelog";
 351                 }
 352                 # Get the package version.
 353                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 354                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 355                 # Did the changelog parse fail?
 356                 if (! defined $dh{VERSION}) {
 357                         error("changelog parse failure");
 358                 }
 359
 360                 # Is this a native Debian package?
 361                 if ($dh{VERSION}=~m/.*-/) {
 362                         return $isnative_cache{$package}=0;
 363                 }
 364                 else {
 365                         return $isnative_cache{$package}=1;
 366                 }
 367         }
 368 }
 369
 370 # Automatically add a shell script snippet to a debian script.
 371 # Only works if the script has #DEBHELPER# in it.
 372 #
 373 # Parameters:
 374 # 1: package
 375 # 2: script to add to
 376 # 3: filename of snippet
 377 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 378 sub autoscript {
 379         my $package=shift;
 380         my $script=shift;
 381         my $filename=shift;
 382         my $sed=shift || "";
 383
 384         # This is the file we will append to.
 385         my $outfile="debian/".pkgext($package)."$script.debhelper";
 386
 387         # Figure out what shell script snippet to use.
 388         my $infile;
 389         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 390             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 391                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 392         }
 393         else {
 394                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 395                         $infile="/usr/share/debhelper/autoscripts/$filename";
 396                 }
 397                 else {
 398                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 399                 }
 400         }
 401
 402         complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 403         complex_doit("sed \"$sed\" $infile >> $outfile");
 404         complex_doit("echo '# End automatically added section' >> $outfile");
 405 }
 406
 407 # Removes a whole substvar line.
 408 sub delsubstvar {
 409         my $package=shift;
 410         my $substvar=shift;
 411
 412         my $ext=pkgext($package);
 413         my $substvarfile="debian/${ext}substvars";
 414
 415         if (-e $substvarfile) {
 416                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 417                 doit("mv", "$substvarfile.new","$substvarfile");
 418         }
 419 }
 420
 421 # Adds a dependency on some package to the specified
 422 # substvar in a package's substvar's file.
 423 sub addsubstvar {
 424         my $package=shift;
 425         my $substvar=shift;
 426         my $deppackage=shift;
 427         my $verinfo=shift;
 428         my $remove=shift;
 429
 430         my $ext=pkgext($package);
 431         my $substvarfile="debian/${ext}substvars";
 432         my $str=$deppackage;
 433         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 434
 435         # Figure out what the line will look like, based on what's there
 436         # now, and what we're to add or remove.
 437         my $line="";
 438         if (-e $substvarfile) {
 439                 my %items;
 440                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 441                 while (<SUBSTVARS_IN>) {
 442                         chomp;
 443                         if (/^\Q$substvar\E=(.*)/) {
 444                                 %items = map { $_ => 1} split(", ", $1);
 445
 446                                 last;
 447                         }
 448                 }
 449                 close SUBSTVARS_IN;
 450                 if (! $remove) {
 451                         $items{$str}=1;
 452                 }
 453                 else {
 454                         delete $items{$str};
 455                 }
 456                 $line=join(", ", keys %items);
 457         }
 458         elsif (! $remove) {
 459                 $line=$str;
 460         }
 461
 462         if (length $line) {
 463                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 464                  doit("mv", "$substvarfile.new", $substvarfile);
 465         }
 466         else {
 467                 delsubstvar($package,$substvar);
 468         }
 469 }
 470
 471 # Reads in the specified file, one line at a time. splits on words,
 472 # and returns an array of arrays of the contents.
 473 # If a value is passed in as the second parameter, then glob
 474 # expansion is done in the directory specified by the parameter ("." is
 475 # frequently a good choice).
 476 sub filedoublearray {
 477         my $file=shift;
 478         my $globdir=shift;
 479
 480         my @ret;
 481         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 482         while (<DH_FARRAY_IN>) {
 483                 my @line;
 484                 # Only do glob expansion in v3 mode.
 485                 #
 486                 # The tricky bit is that the glob expansion is done
 487                 # as if we were in the specified directory, so the
 488                 # filenames that come out are relative to it.
 489                 if (defined $globdir && ! compat(2)) {
 490                         for (map { glob "$globdir/$_" } split) {
 491                                 s#^$globdir/##;
 492                                 push @line, $_;
 493                         }
 494                 }
 495                 else {
 496                         @line = split;
 497                 }
 498                 push @ret, [@line];
 499         }
 500         close DH_FARRAY_IN;
 501
 502         return @ret;
 503 }
 504
 505 # Reads in the specified file, one word at a time, and returns an array of
 506 # the result. Can do globbing as does filedoublearray.
 507 sub filearray {
 508         return map { @$_ } filedoublearray(@_);
 509 }
 510
 511 # Passed a filename, returns true if -X says that file should be excluded.
 512 sub excludefile {
 513         my $filename = shift;
 514         foreach my $f (@{$dh{EXCLUDE}}) {
 515                 return 1 if $filename =~ /\Q$f\E/;
 516         }
 517         return 0;
 518 }
 519
 520 # Returns the build architecture. (Memoized)
 521 {
 522         my $arch;
 523
 524         sub buildarch {
 525                 return $arch if defined $arch;
 526
 527                 $arch=`dpkg-architecture -qDEB_HOST_ARCH 2>/dev/null` || error($!);
 528                 chomp $arch;
 529                 return $arch;
 530         }
 531 }
 532
 533 # Returns a list of packages in the control file.
 534 # Must pass "arch" or "indep" or "same" to specify arch-dependant or
 535 # -independant or same arch packages. If nothing is specified, returns all
 536 # packages.
 537 # As a side effect, populates %package_arches and %package_types with the
 538 # types of all packages (not only those returned).
 539 my (%package_types, %package_arches);
 540 sub getpackages {
 541         my $type=shift;
 542
 543         %package_types=();
 544         %package_arches=();
 545
 546         $type="" if ! defined $type;
 547
 548         # Look up the build arch if we need to.
 549         my $buildarch='';
 550         if ($type eq 'same') {
 551                 $buildarch=buildarch();
 552         }
 553
 554         my $package="";
 555         my $arch="";
 556         my $package_type;
 557         my @list=();
 558         my %seen;
 559         open (CONTROL, 'debian/control') ||
 560                 error("cannot read debian/control: $!\n");
 561         while (<CONTROL>) {
 562                 chomp;
 563                 s/\s+$//;
 564                 if (/^Package:\s*(.*)/) {
 565                         $package=$1;
 566                         # Detect duplicate package names in the same control file.
 567                         if (! $seen{$package}) {
 568                                 $seen{$package}=1;
 569                         }
 570                         else {
 571                                 error("debian/control has a duplicate entry for $package");
 572                         }
 573                         $package_type="deb";
 574                 }
 575                 if (/^Architecture:\s*(.*)/) {
 576                         $arch=$1;
 577                 }
 578                 if (/^X[BC]*-Package-Type:\s*(.*)/) {
 579                         $package_type=$1;
 580                 }
 581
 582                 if (!$_ or eof) { # end of stanza.
 583                         if ($package) {
 584                                 $package_types{$package}=$package_type;
 585                                 $package_arches{$package}=$arch;
 586                         }
 587                         if ($package &&
 588                             (($type eq 'indep' && $arch eq 'all') ||
 589                              ($type eq 'arch' && $arch ne 'all') ||
 590                              ($type eq 'same' && ($arch eq 'any' || $arch =~ /\b$buildarch\b/)) ||
 591                              ! $type)) {
 592                                 push @list, $package;
 593                                 $package="";
 594                                 $arch="";
 595                         }
 596                 }
 597         }
 598         close CONTROL;
 599
 600         return @list;
 601 }
 602
 603 sub is_udeb {
 604         my $package=shift;
 605
 606         return $package_types{$package} eq 'udeb';
 607 }
 608
 609 sub udeb_filename {
 610         my $package=shift;
 611
 612         my $filearch=$package_arches{$package} eq 'all' ? "all" : buildarch();
 613         isnative($package); # side effect
 614         return "${package}_$dh{VERSION}_$filearch.udeb";
 615 }
 616
 617 1