Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2000.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &isnative &autoscript &filearray &filedoublearray
  15             &GetPackages &basename &dirname &xargs %dh &compat &addsubstvar
  16             &delsubstvar &excludefile);
  17
  18 my $max_compat=4;
  19
  20 sub init {
  21         # If DH_OPTIONS is set, prepend it @ARGV.
  22         if (defined($ENV{DH_OPTIONS})) {
  23                 # Ignore leading/trailing whitespace.
  24                 $ENV{DH_OPTIONS}=~s/^\s+//;
  25                 $ENV{DH_OPTIONS}=~s/\s+$//;
  26                 unshift @ARGV,split(/\s+/,$ENV{DH_OPTIONS});
  27         }
  28
  29         # Check to see if an argument on the command line starts with a dash.
  30         # if so, we need to pass this off to the resource intensive
  31         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  32         my $parseopt=undef;
  33         my $arg;
  34         foreach $arg (@ARGV) {
  35                 if ($arg=~m/^-/) {
  36                         $parseopt=1;
  37                         last;
  38                 }
  39         }
  40         if ($parseopt) {
  41                 eval "use Debian::Debhelper::Dh_Getopt";
  42                 error($!) if $@;
  43                 %dh=Debian::Debhelper::Dh_Getopt::parseopts();
  44         }
  45
  46         # Another way to set excludes.
  47         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  48                 push @{$dh{EXCLUDE}}, $ENV{DH_ALWAYS_EXCLUDE};
  49         }
  50
  51         # Generate EXCLUDE_FIND.
  52         if ($dh{EXCLUDE}) {
  53                 $dh{EXCLUDE_FIND}='';
  54                 foreach (@{$dh{EXCLUDE}}) {
  55                         my $x=$_;
  56                         $x=escape_shell($x);
  57                         $x=~s/\./\\\\./g;
  58                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  59                 }
  60                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  61         }
  62
  63         # Check to see if DH_VERBOSE environment variable was set, if so,
  64         # make sure verbose is on.
  65         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  66                 $dh{VERBOSE}=1;
  67         }
  68
  69         # Check to see if DH_NO_ACT environment variable was set, if so,
  70         # make sure no act mode is on.
  71         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  72                 $dh{NO_ACT}=1;
  73         }
  74
  75         my @allpackages=GetPackages();
  76         # Get the name of the main binary package (first one listed in
  77         # debian/control). Only if the main package was not set on the
  78         # command line.
  79         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  80                 $dh{MAINPACKAGE}=$allpackages[0];
  81         }
  82
  83         # Check if packages to build have been specified, if not, fall back to
  84         # the default, doing them all.
  85         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  86                 if ($dh{DOINDEP} || $dh{DOARCH} || $dh{DOSAME}) {
  87                         error("You asked that all arch in(dep) packages be built, but there are none of that type.");
  88                 }
  89                 push @{$dh{DOPACKAGES}},@allpackages;
  90         }
  91
  92         # Check to see if -P was specified. If so, we can only act on a single
  93         # package.
  94         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  95                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  96         }
  97
  98         # Figure out which package is the first one we were instructed to build.
  99         # This package gets special treatement: files and directories specified on
 100         # the command line may affect it.
 101         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
 102 }
 103
 104 # Pass it an array containing the arguments of a shell command like would
 105 # be run by exec(). It turns that into a line like you might enter at the
 106 # shell, escaping metacharacters and quoting arguments that contain spaces.
 107 sub escape_shell {
 108         my @args=@_;
 109         my $line="";
 110         my @ret;
 111         foreach my $word (@args) {
 112                 if ($word=~/\s/) {
 113                         # Escape only a few things since it will be quoted.
 114                         # Note we use double quotes because you cannot
 115                         # escape ' in single quotes, while " can be escaped
 116                         # in double.
 117                         # This does make -V"foo bar" turn into "-Vfoo bar",
 118                         # but that will be parsed identically by the shell
 119                         # anyway..
 120                         $word=~s/([\n`\$"\\])/\$1/g;
 121                         push @ret, "\"$word\"";
 122                 }
 123                 else {
 124                         # This list is from _Unix in a Nutshell_. (except '#')
 125                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 126                         push @ret,$word;
 127                 }
 128         }
 129         return join(' ', @ret);
 130 }
 131
 132 # Run a command, and display the command to stdout if verbose mode is on.
 133 # All commands that modifiy files in $TMP should be ran via this
 134 # function.
 135 #
 136 # Note that this cannot handle complex commands, especially anything
 137 # involving redirection. Use complex_doit instead.
 138 sub doit {
 139         verbose_print(escape_shell(@_));
 140
 141         if (! $dh{NO_ACT}) {
 142                 system(@_) == 0 || error("command returned error code");
 143         }
 144 }
 145
 146 # Run a command and display the command to stdout if verbose mode is on.
 147 # Use doit() if you can, instead of this function, because this function
 148 # forks a shell. However, this function can handle more complicated stuff
 149 # like redirection.
 150 sub complex_doit {
 151         verbose_print(join(" ",@_));
 152
 153         if (! $dh{NO_ACT}) {
 154                 # The join makes system get a scalar so it forks off a shell.
 155                 system(join(" ",@_)) == 0
 156                         || error("command returned error code");
 157         }
 158 }
 159
 160 # Run a command that may have a huge number of arguments, like xargs does.
 161 # Pass in a reference to an array containing the arguments, and then other
 162 # parameters that are the command and any parameters that should be passed to
 163 # it each time.
 164 sub xargs {
 165         my $args=shift;
 166
 167         # The kernel can accept command lines up to 20k worth of characters.
 168         my $command_max=20000; # LINUX SPECIFIC!!
 169                         # I could use POSIX::ARG_MAX, but that would be slow.
 170
 171         # Figure out length of static portion of command.
 172         my $static_length=0;
 173         foreach (@_) {
 174                 $static_length+=length($_)+1;
 175         }
 176
 177         my @collect=();
 178         my $length=$static_length;
 179         foreach (@$args) {
 180                 if (length($_) + 1 + $static_length > $command_max) {
 181                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 182                 }
 183                 $length+=length($_) + 1;
 184                 if ($length < $command_max) {
 185                         push @collect, $_;
 186                 }
 187                 else {
 188                         doit(@_,@collect) if $#collect > -1;
 189                         @collect=($_);
 190                         $length=$static_length + length($_) + 1;
 191                 }
 192         }
 193         doit(@_,@collect) if $#collect > -1;
 194 }
 195
 196 # Print something if the verbose flag is on.
 197 sub verbose_print {
 198         my $message=shift;
 199
 200         if ($dh{VERBOSE}) {
 201                 print "\t$message\n";
 202         }
 203 }
 204
 205 # Output an error message and exit.
 206 sub error {
 207         my $message=shift;
 208
 209         warning($message);
 210         exit 1;
 211 }
 212
 213 # Output a warning.
 214 sub warning {
 215         my $message=shift;
 216
 217         print STDERR basename($0).": $message\n";
 218 }
 219
 220 # Returns the basename of the argument passed to it.
 221 sub basename {
 222         my $fn=shift;
 223
 224         $fn=~s/\/$//g; # ignore trailing slashes
 225         $fn=~s:^.*/(.*?)$:$1:;
 226         return $fn;
 227 }
 228
 229 # Returns the directory name of the argument passed to it.
 230 sub dirname {
 231         my $fn=shift;
 232
 233         $fn=~s/\/$//g; # ignore trailing slashes
 234         $fn=~s:^(.*)/.*?$:$1:;
 235         return $fn;
 236 }
 237
 238 # Pass in a number, will return true iff the current compatibility level
 239 # is less than or equal to that number.
 240 sub compat {
 241         my $num=shift;
 242
 243         my $c=1;
 244         if (defined $ENV{DH_COMPAT}) {
 245                 $c=$ENV{DH_COMPAT};
 246         }
 247         elsif (-e 'debian/compat') {
 248                 # Try the file..
 249                 open (COMPAT_IN, "debian/compat") || die "debian/compat: $!";
 250                 $c=<COMPAT_IN>;
 251                 chomp $c;
 252         }
 253
 254         if ($c > $max_compat) {
 255                 error("Sorry, but $max_compat is the highest compatibility level of debhelper currently supported.");
 256         }
 257
 258         return ($c <= $num);
 259 }
 260
 261 # Pass it a name of a binary package, it returns the name of the tmp dir to
 262 # use, for that package.
 263 sub tmpdir {
 264         my $package=shift;
 265
 266         if ($dh{TMPDIR}) {
 267                 return $dh{TMPDIR};
 268         }
 269         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 270                 # This is for back-compatibility with the debian/tmp tradition.
 271                 return "debian/tmp";
 272         }
 273         else {
 274                 return "debian/$package";
 275         }
 276 }
 277
 278 # Pass this the name of a binary package, and the name of the file wanted
 279 # for the package, and it will return the actual existing filename to use.
 280 #
 281 # It tries several filenames:
 282 #   * debian/package.filename.buildarch
 283 #   * debian/package.filename
 284 #   * debian/file (if the package is the main package)
 285 sub pkgfile {
 286         my $package=shift;
 287         my $filename=shift;
 288
 289         if (-f "debian/$package.$filename.".buildarch()) {
 290                 return "debian/$package.$filename.".buildarch();
 291         }
 292         elsif (-f "debian/$package.$filename") {
 293                 return "debian/$package.$filename";
 294         }
 295         elsif ($package eq $dh{MAINPACKAGE} && -f "debian/$filename") {
 296                 return "debian/$filename";
 297         }
 298         else {
 299                 return "";
 300         }
 301 }
 302
 303 # Pass it a name of a binary package, it returns the name to prefix to files
 304 # in debian for this package.
 305 sub pkgext {
 306         my $package=shift;
 307
 308         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 309                 return "";
 310         }
 311         return "$package.";
 312 }
 313
 314 # Returns 1 if the package is a native debian package, null otherwise.
 315 # As a side effect, sets $dh{VERSION} to the version of this package.
 316 {
 317         # Caches return code so it only needs to run dpkg-parsechangelog once.
 318         my %isnative_cache;
 319
 320         sub isnative {
 321                 my $package=shift;
 322
 323                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 324
 325                 # Make sure we look at the correct changelog.
 326                 my $isnative_changelog=pkgfile($package,"changelog");
 327                 if (! $isnative_changelog) {
 328                         $isnative_changelog="debian/changelog";
 329                 }
 330                 # Get the package version.
 331                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 332                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 333                 # Did the changelog parse fail?
 334                 if (! defined $dh{VERSION}) {
 335                         error("changelog parse failure");
 336                 }
 337
 338                 # Is this a native Debian package?
 339                 if ($dh{VERSION}=~m/.*-/) {
 340                         return $isnative_cache{$package}=0;
 341                 }
 342                 else {
 343                         return $isnative_cache{$package}=1;
 344                 }
 345         }
 346 }
 347
 348 # Automatically add a shell script snippet to a debian script.
 349 # Only works if the script has #DEBHELPER# in it.
 350 #
 351 # Parameters:
 352 # 1: package
 353 # 2: script to add to
 354 # 3: filename of snippet
 355 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 356 sub autoscript {
 357         my $package=shift;
 358         my $script=shift;
 359         my $filename=shift;
 360         my $sed=shift || "";
 361
 362         # This is the file we will append to.
 363         my $outfile="debian/".pkgext($package)."$script.debhelper";
 364
 365         # Figure out what shell script snippet to use.
 366         my $infile;
 367         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 368             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 369                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 370         }
 371         else {
 372                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 373                         $infile="/usr/share/debhelper/autoscripts/$filename";
 374                 }
 375                 else {
 376                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 377                 }
 378         }
 379
 380         complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 381         complex_doit("sed \"$sed\" $infile >> $outfile");
 382         complex_doit("echo '# End automatically added section' >> $outfile");
 383 }
 384
 385 # Removes a whole substvar line.
 386 sub delsubstvar {
 387         my $package=shift;
 388         my $substvar=shift;
 389
 390         my $ext=pkgext($package);
 391         my $substvarfile="debian/${ext}substvars";
 392
 393         if (-e $substvarfile) {
 394                 complex_doit("grep -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 395                 doit("mv", "$substvarfile.new","$substvarfile");
 396         }
 397 }
 398
 399 # Adds a dependency on some package to the specified
 400 # substvar in a package's substvar's file.
 401 sub addsubstvar {
 402         my $package=shift;
 403         my $substvar=shift;
 404         my $deppackage=shift;
 405         my $verinfo=shift;
 406         my $remove=shift;
 407
 408         my $ext=pkgext($package);
 409         my $substvarfile="debian/${ext}substvars";
 410         my $str=$deppackage;
 411         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 412
 413         # Figure out what the line will look like, based on what's there
 414         # now, and what we're to add or remove.
 415         my $line="";
 416         if (-e $substvarfile) {
 417                 my %items;
 418                 open(SUBSTVARS_IN, "$substvarfile") || die "read $substvarfile: $!";
 419                 while (<SUBSTVARS_IN>) {
 420                         chomp;
 421                         if (/^\Q$substvar\E=(.*)/) {
 422                                 %items = map { $_ => 1} split(", ", $1);
 423
 424                                 last;
 425                         }
 426                 }
 427                 close SUBSTVARS_IN;
 428                 if (! $remove) {
 429                         $items{$str}=1;
 430                 }
 431                 else {
 432                         delete $items{$str};
 433                 }
 434                 $line=join(", ", keys %items);
 435         }
 436         elsif (! $remove) {
 437                 $line=$str;
 438         }
 439
 440         if (length $line) {
 441                  complex_doit("echo '${substvar}=$line' >> $substvarfile");
 442         }
 443 }
 444
 445 # Reads in the specified file, one line at a time. splits on words,
 446 # and returns an array of arrays of the contents.
 447 # If a value is passed in as the second parameter, then glob
 448 # expansion is done in the directory specified by the parameter ("." is
 449 # frequently a good choice).
 450 sub filedoublearray {
 451         my $file=shift;
 452         my $globdir=shift;
 453
 454         my @ret;
 455         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 456         while (<DH_FARRAY_IN>) {
 457                 my @line;
 458                 # Only do glob expansion in v3 mode.
 459                 #
 460                 # The tricky bit is that the glob expansion is done
 461                 # as if we were in the specified directory, so the
 462                 # filenames that come out are relative to it.
 463                 if (defined $globdir && ! compat(2)) {
 464                         for (map { glob "$globdir/$_" } split) {
 465                                 s#^$globdir/##;
 466                                 push @line, $_;
 467                         }
 468                 }
 469                 else {
 470                         @line = split;
 471                 }
 472                 push @ret, [@line];
 473         }
 474         close DH_FARRAY_IN;
 475
 476         return @ret;
 477 }
 478
 479 # Reads in the specified file, one word at a time, and returns an array of
 480 # the result. Can do globbing as does filedoublearray.
 481 sub filearray {
 482         return map { @$_ } filedoublearray(@_);
 483 }
 484
 485 # Passed a filename, returns true if -X says that file should be excluded.
 486 sub excludefile {
 487         my $filename = shift;
 488         foreach my $f (@{$dh{EXCLUDE}}) {
 489                 return 1 if $filename =~ /\Q$f\E/;
 490         }
 491         return 0;
 492 }
 493
 494 # Returns the build architecture. (Memoized)
 495 {
 496         my $arch;
 497
 498         sub buildarch {
 499                 return $arch if defined $arch;
 500
 501                 $arch=`dpkg --print-architecture` || error($!);
 502                 chomp $arch;
 503                 return $arch;
 504         }
 505 }
 506
 507 # Returns a list of packages in the control file.
 508 # Must pass "arch" or "indep" or "same" to specify arch-dependant or
 509 # -independant or same arch packages. If nothing is specified, returns all
 510 # packages.
 511 sub GetPackages {
 512         my $type=shift;
 513
 514         $type="" if ! defined $type;
 515
 516         # Look up the build arch if we need to.
 517         my $buildarch='';
 518         if ($type eq 'same') {
 519                 $buildarch=buildarch();
 520         }
 521
 522         my $package="";
 523         my $arch="";
 524         my @list=();
 525         my %seen;
 526         open (CONTROL, 'debian/control') ||
 527                 error("cannot read debian/control: $!\n");
 528         while (<CONTROL>) {
 529                 chomp;
 530                 s/\s+$//;
 531                 if (/^Package:\s*(.*)/) {
 532                         $package=$1;
 533                         # Detect duplicate package names in the same control file.
 534                         if (! $seen{$package}) {
 535                                 $seen{$package}=1;
 536                         }
 537                         else {
 538                                 error("debian/control has a duplicate entry for $package");
 539                         }
 540                 }
 541                 if (/^Architecture:\s*(.*)/) {
 542                         $arch=$1;
 543                 }
 544
 545                 if (!$_ or eof) { # end of stanza.
 546                         if ($package &&
 547                             (($type eq 'indep' && $arch eq 'all') ||
 548                              ($type eq 'arch' && $arch ne 'all') ||
 549                              ($type eq 'same' && ($arch eq 'any' || $arch =~ /\b$buildarch\b/)) ||
 550                              ! $type)) {
 551                                 push @list, $package;
 552                                 $package="";
 553                                 $arch="";
 554                         }
 555                 }
 556         }
 557         close CONTROL;
 558
 559         return @list;
 560 }
 561
 562 1