Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2000.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &isnative &autoscript &filearray &GetPackages
  15             &basename &xargs %dh &compat);
  16
  17 my $max_compat=3;
  18
  19 sub init {
  20         # If DH_OPTIONS is set, prepend it @ARGV.
  21         if (defined($ENV{DH_OPTIONS})) {
  22                 unshift @ARGV,split(/\s+/,$ENV{DH_OPTIONS});
  23         }
  24
  25         # Check to see if an argument on the command line starts with a dash.
  26         # if so, we need to pass this off to the resource intensive
  27         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  28         my $parseopt=undef;
  29         my $arg;
  30         foreach $arg (@ARGV) {
  31                 if ($arg=~m/^-/) {
  32                         $parseopt=1;
  33                         last;
  34                 }
  35         }
  36         if ($parseopt) {
  37                 eval "use Debian::Debhelper::Dh_Getopt";
  38                 error($!) if $@;
  39                 %dh=Debian::Debhelper::Dh_Getopt::parseopts();
  40         }
  41
  42         # Check to see if DH_VERBOSE environment variable was set, if so,
  43         # make sure verbose is on.
  44         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  45                 $dh{VERBOSE}=1;
  46         }
  47
  48         # Check to see if DH_NO_ACT environment variable was set, if so,
  49         # make sure no act mode is on.
  50         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  51                 $dh{NO_ACT}=1;
  52         }
  53
  54         # Get the name of the main binary package (first one listed in
  55         # debian/control).
  56         my @allpackages=GetPackages();
  57         $dh{MAINPACKAGE}=$allpackages[0];
  58
  59         # Check if packages to build have been specified, if not, fall back to
  60         # the default, doing them all.
  61         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  62                 if ($dh{DOINDEP} || $dh{DOARCH} || $dh{DOSAME}) {
  63                         error("You asked that all arch in(dep) packages be built, but there are none of that type.");
  64                 }
  65                 push @{$dh{DOPACKAGES}},@allpackages;
  66         }
  67
  68         # Check to see if -P was specified. If so, we can only act on a single
  69         # package.
  70         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  71                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  72         }
  73
  74         # Figure out which package is the first one we were instructed to build.
  75         # This package gets special treatement: files and directories specified on
  76         # the command line may affect it.
  77         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  78 }
  79
  80 # Pass it an array containing the arguments of a shell command like would
  81 # be run by exec(). It turns that into a line like you might enter at the
  82 # shell, escaping metacharacters and quoting qrguments that contain spaces.
  83 sub escape_shell {
  84         my @args=@_;
  85         my $line="";
  86         my @ret;
  87         foreach my $word (@args) {
  88                 if ($word=~/\s/) {
  89                         # Escape only a few things since it will be quoted.
  90                         # Note we use double quotes because you cannot
  91                         # escape ' in qingle quotes, while " can be escaped
  92                         # in double.
  93                         # This does make -V"foo bar" turn into "-Vfoo bar",
  94                         # but that will be parsed identically by the shell
  95                         # anyway..
  96                         $word=~s/([\n`\$"\\])/\$1/g;
  97                         push @ret, "\"$word\"";
  98                 }
  99                 else {
 100                         # This list is from _Unix in a Nutshell_. (except '#')
 101                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 102                         push @ret,$word;
 103                 }
 104         }
 105         return join(' ', @ret);
 106 }
 107
 108 # Run a command, and display the command to stdout if verbose mode is on.
 109 # All commands that modifiy files in $TMP should be ran via this
 110 # function.
 111 #
 112 # Note that this cannot handle complex commands, especially anything
 113 # involving redirection. Use complex_doit instead.
 114 sub doit {
 115         verbose_print(escape_shell(@_));
 116
 117         if (! $dh{NO_ACT}) {
 118                 system(@_) == 0 || error("command returned error code");
 119         }
 120 }
 121
 122 # Run a command and display the command to stdout if verbose mode is on.
 123 # Use doit() if you can, instead of this function, because this function
 124 # forks a shell. However, this function can handle more complicated stuff
 125 # like redirection.
 126 sub complex_doit {
 127         verbose_print(join(" ",@_));
 128
 129         if (! $dh{NO_ACT}) {
 130                 # The join makes system get a scalar so it forks off a shell.
 131                 system(join(" ",@_)) == 0
 132                         || error("command returned error code");
 133         }
 134 }
 135
 136 # Run a command that may have a huge number of arguments, like xargs does.
 137 # Pass in a reference to an array containing the arguments, and then other
 138 # parameters that are the command and any parameters that should be passed to
 139 # it each time.
 140 sub xargs {
 141         my $args=shift;
 142
 143         # The kernel can accept command lines up to 20k worth of characters.
 144         my $command_max=20000; # LINUX SPECIFIC!!
 145                         # I could use POSIX::ARG_MAX, but that would be slow.
 146
 147         # Figure out length of static portion of command.
 148         my $static_length=0;
 149         foreach (@_) {
 150                 $static_length+=length($_)+1;
 151         }
 152
 153         my @collect=();
 154         my $length=$static_length;
 155         foreach (@$args) {
 156                 if (length($_) + 1 + $static_length > $command_max) {
 157                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 158                 }
 159                 $length+=length($_) + 1;
 160                 if ($length < $command_max) {
 161                         push @collect, $_;
 162                 }
 163                 else {
 164                         doit(@_,@collect) if $#collect > -1;
 165                         @collect=($_);
 166                         $length=$static_length + length($_) + 1;
 167                 }
 168         }
 169         doit(@_,@collect) if $#collect > -1;
 170 }
 171
 172 # Print something if the verbose flag is on.
 173 sub verbose_print {
 174         my $message=shift;
 175
 176         if ($dh{VERBOSE}) {
 177                 print "\t$message\n";
 178         }
 179 }
 180
 181 # Output an error message and exit.
 182 sub error {
 183         my $message=shift;
 184
 185         warning($message);
 186         exit 1;
 187 }
 188
 189 # Output a warning.
 190 sub warning {
 191         my $message=shift;
 192
 193         print STDERR basename($0).": $message\n";
 194 }
 195
 196 # Returns the basename of the argument passed to it.
 197 sub basename {
 198         my $fn=shift;
 199
 200         $fn=~s:^.*/(.*?)$:$1:;
 201         return $fn;
 202 }
 203
 204 # Returns the directory name of the argument passed to it.
 205 sub dirname {
 206         my $fn=shift;
 207
 208         $fn=~s:^(.*)/.*?$:$1:;
 209         return $fn;
 210 }
 211
 212 # Pass in a number, will return true iff the current compatibility level
 213 # is less than or equal to that number.
 214 sub compat {
 215         my $num=shift;
 216
 217         my $c=1;
 218         if (defined $ENV{DH_COMPAT}) {
 219                 $c=$ENV{DH_COMPAT};
 220         }
 221
 222         if ($c > $max_compat) {
 223                 error("Sorry, but $max_compat is the highest compatibility level of debhelper currently supported.");
 224         }
 225
 226         return ($c <= $num);
 227 }
 228
 229 # Pass it a name of a binary package, it returns the name of the tmp dir to
 230 # use, for that package.
 231 sub tmpdir {
 232         my $package=shift;
 233
 234         if ($dh{TMPDIR}) {
 235                 return $dh{TMPDIR};
 236         }
 237         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 238                 # This is for back-compatibility with the debian/tmp tradition.
 239                 return "debian/tmp";
 240         }
 241         else {
 242                 return "debian/$package";
 243         }
 244 }
 245
 246 # Pass this the name of a binary package, and the name of the file wanted
 247 # for the package, and it will return the actual existing filename to use.
 248 #
 249 # It tries several filenames:
 250 #   * debian/package.filename.buildarch
 251 #   * debian/package.filename
 252 #   * debian/file (if the package is the main package)
 253 sub pkgfile {
 254         my $package=shift;
 255         my $filename=shift;
 256
 257         if (-f "debian/$package.$filename.".buildarch()) {
 258                 return "debian/$package.$filename.".buildarch();
 259         }
 260         elsif (-f "debian/$package.$filename") {
 261                 return "debian/$package.$filename";
 262         }
 263         elsif ($package eq $dh{MAINPACKAGE} && -f "debian/$filename") {
 264                 return "debian/$filename";
 265         }
 266         else {
 267                 return "";
 268         }
 269 }
 270
 271 # Pass it a name of a binary package, it returns the name to prefix to files
 272 # in debian for this package.
 273 sub pkgext {
 274         my $package=shift;
 275
 276         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 277                 return "";
 278         }
 279         return "$package.";
 280 }
 281
 282 # Returns 1 if the package is a native debian package, null otherwise.
 283 # As a side effect, sets $dh{VERSION} to the version of this package.
 284 {
 285         # Caches return code so it only needs to run dpkg-parsechangelog once.
 286         my %isnative_cache;
 287
 288         sub isnative {
 289                 my $package=shift;
 290
 291                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 292
 293                 # Make sure we look at the correct changelog.
 294                 my $isnative_changelog=pkgfile($package,"changelog");
 295                 if (! $isnative_changelog) {
 296                         $isnative_changelog="debian/changelog";
 297                 }
 298                 # Get the package version.
 299                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 300                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 301                 # Did the changelog parse fail?
 302                 if (! defined $dh{VERSION}) {
 303                         error("changelog parse failure");
 304                 }
 305
 306                 # Is this a native Debian package?
 307                 if ($dh{VERSION}=~m/.*-/) {
 308                         return $isnative_cache{$package}=0;
 309                 }
 310                 else {
 311                         return $isnative_cache{$package}=1;
 312                 }
 313         }
 314 }
 315
 316 # Automatically add a shell script snippet to a debian script.
 317 # Only works if the script has #DEBHELPER# in it.
 318 #
 319 # Parameters:
 320 # 1: package
 321 # 2: script to add to
 322 # 3: filename of snippet
 323 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 324 sub autoscript {
 325         my $package=shift;
 326         my $script=shift;
 327         my $filename=shift;
 328         my $sed=shift || "";
 329
 330         # This is the file we will append to.
 331         my $outfile="debian/".pkgext($package)."$script.debhelper";
 332
 333         # Figure out what shell script snippet to use.
 334         my $infile;
 335         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 336             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 337                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 338         }
 339         else {
 340                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 341                         $infile="/usr/share/debhelper/autoscripts/$filename";
 342                 }
 343                 else {
 344                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 345                 }
 346         }
 347
 348         complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 349         complex_doit("sed \"$sed\" $infile >> $outfile");
 350         complex_doit("echo '# End automatically added section' >> $outfile");
 351 }
 352
 353 # Reads in the specified file, one word at a time, and returns an array of
 354 # the result. If a value is passed in as the second parameter, then glob
 355 # expansion is done in the directory specified by the parameter ("." is
 356 # frequently a good choice).
 357 sub filearray {
 358         my $file=shift;
 359         my $globdir=shift;
 360
 361         my @ret;
 362         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 363         while (<DH_FARRAY_IN>) {
 364                 # Only do glob expansion in v3 mode.
 365                 #
 366                 # The tricky bit is that the glob expansion is done
 367                 # as if we were in the specified directory, so the
 368                 # filenames that come out are relative to it.
 369                 if (defined $globdir && ! compat(2)) {
 370                         for (map { glob "$globdir/$_" } split) {
 371                                 s#^$globdir/##;
 372                                 push @ret, $_;
 373                         }
 374                 }
 375                 else {
 376                         push @ret, split;
 377                 }
 378         }
 379         close DH_FARRAY_IN;
 380
 381         return @ret;
 382 }
 383
 384 # Returns the build architecture. (Memoized)
 385 {
 386         my $arch;
 387
 388         sub buildarch {
 389                 return $arch if defined $arch;
 390
 391                 $arch=`dpkg --print-architecture` || error($!);
 392                 chomp $arch;
 393                 return $arch;
 394         }
 395 }
 396
 397 # Returns a list of packages in the control file.
 398 # Must pass "arch" or "indep" or "same" to specify arch-dependant or
 399 # -independant or same arch packages. If nothing is specified, returns all
 400 # packages.
 401 sub GetPackages {
 402         my $type=shift;
 403
 404         $type="" if ! defined $type;
 405
 406         # Look up the build arch if we need to.
 407         my $buildarch='';
 408         if ($type eq 'same') {
 409                 $buildarch=buildarch();
 410         }
 411
 412         my $package="";
 413         my $arch="";
 414         my @list=();
 415         my %seen;
 416         open (CONTROL, 'debian/control') ||
 417                 error("cannot read debian/control: $!\n");
 418         while (<CONTROL>) {
 419                 chomp;
 420                 s/\s+$//;
 421                 if (/^Package:\s*(.*)/) {
 422                         $package=$1;
 423                         # Detect duplicate package names in the same control file.
 424                         if (! $seen{$package}) {
 425                                 $seen{$package}=1;
 426                         }
 427                         else {
 428                                 error("debian/control has a duplicate entry for $package");
 429                         }
 430                 }
 431                 if (/^Architecture:\s*(.*)/) {
 432                         $arch=$1;
 433                 }
 434
 435                 if (!$_ or eof) { # end of stanza.
 436                         if ($package &&
 437                             (($type eq 'indep' && $arch eq 'all') ||
 438                              ($type eq 'arch' && $arch ne 'all') ||
 439                              ($type eq 'same' && ($arch eq 'any' || $arch =~ /\b$buildarch\b/)) ||
 440                              ! $type)) {
 441                                 push @list, $package;
 442                                 $package="";
 443                                 $arch="";
 444                         }
 445                 }
 446         }
 447         close CONTROL;
 448
 449         return @list;
 450 }
 451
 452 1