Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2000.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &is_udeb
  17             &udeb_filename);
  18
  19 my $max_compat=4;
  20
  21 sub init {
  22         # If DH_OPTIONS is set, prepend it @ARGV.
  23         if (defined($ENV{DH_OPTIONS})) {
  24                 # Ignore leading/trailing whitespace.
  25                 $ENV{DH_OPTIONS}=~s/^\s+//;
  26                 $ENV{DH_OPTIONS}=~s/\s+$//;
  27                 unshift @ARGV,split(/\s+/,$ENV{DH_OPTIONS});
  28         }
  29
  30         # Check to see if an argument on the command line starts with a dash.
  31         # if so, we need to pass this off to the resource intensive
  32         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  33         my $parseopt=undef;
  34         my $arg;
  35         foreach $arg (@ARGV) {
  36                 if ($arg=~m/^-/) {
  37                         $parseopt=1;
  38                         last;
  39                 }
  40         }
  41         if ($parseopt) {
  42                 eval "use Debian::Debhelper::Dh_Getopt";
  43                 error($!) if $@;
  44                 %dh=Debian::Debhelper::Dh_Getopt::parseopts();
  45         }
  46
  47         # Another way to set excludes.
  48         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  49                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  50         }
  51
  52         # Generate EXCLUDE_FIND.
  53         if ($dh{EXCLUDE}) {
  54                 $dh{EXCLUDE_FIND}='';
  55                 foreach (@{$dh{EXCLUDE}}) {
  56                         my $x=$_;
  57                         $x=escape_shell($x);
  58                         $x=~s/\./\\./g;
  59                         $dh{EXCLUDE_FIND}.="-regex .*$x.* -or ";
  60                 }
  61                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  62         }
  63
  64         # Check to see if DH_VERBOSE environment variable was set, if so,
  65         # make sure verbose is on.
  66         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  67                 $dh{VERBOSE}=1;
  68         }
  69
  70         # Check to see if DH_NO_ACT environment variable was set, if so,
  71         # make sure no act mode is on.
  72         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  73                 $dh{NO_ACT}=1;
  74         }
  75
  76         my @allpackages=getpackages();
  77         # Get the name of the main binary package (first one listed in
  78         # debian/control). Only if the main package was not set on the
  79         # command line.
  80         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  81                 $dh{MAINPACKAGE}=$allpackages[0];
  82         }
  83
  84         # Check if packages to build have been specified, if not, fall back to
  85         # the default, doing them all.
  86         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  87                 if ($dh{DOINDEP} || $dh{DOARCH} || $dh{DOSAME}) {
  88                         error("You asked that all arch in(dep) packages be built, but there are none of that type.");
  89                 }
  90                 push @{$dh{DOPACKAGES}},@allpackages;
  91         }
  92
  93         # Check to see if -P was specified. If so, we can only act on a single
  94         # package.
  95         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  96                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  97         }
  98
  99         # Figure out which package is the first one we were instructed to build.
 100         # This package gets special treatement: files and directories specified on
 101         # the command line may affect it.
 102         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
 103
 104         # If no error handling function was specified, just propigate
 105         # errors out.
 106         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
 107                 $dh{ERROR_HANDLER}='exit $?';
 108         }
 109 }
 110
 111 # Pass it an array containing the arguments of a shell command like would
 112 # be run by exec(). It turns that into a line like you might enter at the
 113 # shell, escaping metacharacters and quoting arguments that contain spaces.
 114 sub escape_shell {
 115         my @args=@_;
 116         my $line="";
 117         my @ret;
 118         foreach my $word (@args) {
 119                 if ($word=~/\s/) {
 120                         # Escape only a few things since it will be quoted.
 121                         # Note we use double quotes because you cannot
 122                         # escape ' in single quotes, while " can be escaped
 123                         # in double.
 124                         # This does make -V"foo bar" turn into "-Vfoo bar",
 125                         # but that will be parsed identically by the shell
 126                         # anyway..
 127                         $word=~s/([\n`\$"\\])/\\$1/g;
 128                         push @ret, "\"$word\"";
 129                 }
 130                 else {
 131                         # This list is from _Unix in a Nutshell_. (except '#')
 132                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 133                         push @ret,$word;
 134                 }
 135         }
 136         return join(' ', @ret);
 137 }
 138
 139 # Run a command, and display the command to stdout if verbose mode is on.
 140 # All commands that modifiy files in $TMP should be ran via this
 141 # function.
 142 #
 143 # Note that this cannot handle complex commands, especially anything
 144 # involving redirection. Use complex_doit instead.
 145 sub doit {
 146         verbose_print(escape_shell(@_));
 147
 148         if (! $dh{NO_ACT}) {
 149                 my $ret=system(@_);
 150                 $ret == 0 || error("command returned error code $ret");
 151         }
 152 }
 153
 154 # Run a command and display the command to stdout if verbose mode is on.
 155 # Use doit() if you can, instead of this function, because this function
 156 # forks a shell. However, this function can handle more complicated stuff
 157 # like redirection.
 158 sub complex_doit {
 159         verbose_print(join(" ",@_));
 160
 161         if (! $dh{NO_ACT}) {
 162                 # The join makes system get a scalar so it forks off a shell.
 163                 system(join(" ",@_)) == 0
 164                         || error("command returned error code");
 165         }
 166 }
 167
 168 # Run a command that may have a huge number of arguments, like xargs does.
 169 # Pass in a reference to an array containing the arguments, and then other
 170 # parameters that are the command and any parameters that should be passed to
 171 # it each time.
 172 sub xargs {
 173         my $args=shift;
 174
 175         # The kernel can accept command lines up to 20k worth of characters.
 176         my $command_max=20000; # LINUX SPECIFIC!!
 177                         # I could use POSIX::ARG_MAX, but that would be slow.
 178
 179         # Figure out length of static portion of command.
 180         my $static_length=0;
 181         foreach (@_) {
 182                 $static_length+=length($_)+1;
 183         }
 184
 185         my @collect=();
 186         my $length=$static_length;
 187         foreach (@$args) {
 188                 if (length($_) + 1 + $static_length > $command_max) {
 189                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 190                 }
 191                 $length+=length($_) + 1;
 192                 if ($length < $command_max) {
 193                         push @collect, $_;
 194                 }
 195                 else {
 196                         doit(@_,@collect) if $#collect > -1;
 197                         @collect=($_);
 198                         $length=$static_length + length($_) + 1;
 199                 }
 200         }
 201         doit(@_,@collect) if $#collect > -1;
 202 }
 203
 204 # Print something if the verbose flag is on.
 205 sub verbose_print {
 206         my $message=shift;
 207
 208         if ($dh{VERBOSE}) {
 209                 print "\t$message\n";
 210         }
 211 }
 212
 213 # Output an error message and exit.
 214 sub error {
 215         my $message=shift;
 216
 217         warning($message);
 218         exit 1;
 219 }
 220
 221 # Output a warning.
 222 sub warning {
 223         my $message=shift;
 224
 225         print STDERR basename($0).": $message\n";
 226 }
 227
 228 # Returns the basename of the argument passed to it.
 229 sub basename {
 230         my $fn=shift;
 231
 232         $fn=~s/\/$//g; # ignore trailing slashes
 233         $fn=~s:^.*/(.*?)$:$1:;
 234         return $fn;
 235 }
 236
 237 # Returns the directory name of the argument passed to it.
 238 sub dirname {
 239         my $fn=shift;
 240
 241         $fn=~s/\/$//g; # ignore trailing slashes
 242         $fn=~s:^(.*)/.*?$:$1:;
 243         return $fn;
 244 }
 245
 246 # Pass in a number, will return true iff the current compatibility level
 247 # is less than or equal to that number.
 248 sub compat {
 249         my $num=shift;
 250
 251         my $c=1;
 252         if (defined $ENV{DH_COMPAT}) {
 253                 $c=$ENV{DH_COMPAT};
 254         }
 255         elsif (-e 'debian/compat') {
 256                 # Try the file..
 257                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 258                 my $l=<COMPAT_IN>;
 259                 if (! defined $l || ! length $l) {
 260                         warning("debian/compat is empty, assuming level $c");
 261                 }
 262                 else {
 263                         chomp $l;
 264                         $c=$l
 265                 }
 266         }
 267
 268         if ($c > $max_compat) {
 269                 error("Sorry, but $max_compat is the highest compatibility level of debhelper currently supported.");
 270         }
 271
 272         return ($c <= $num);
 273 }
 274
 275 # Pass it a name of a binary package, it returns the name of the tmp dir to
 276 # use, for that package.
 277 sub tmpdir {
 278         my $package=shift;
 279
 280         if ($dh{TMPDIR}) {
 281                 return $dh{TMPDIR};
 282         }
 283         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 284                 # This is for back-compatibility with the debian/tmp tradition.
 285                 return "debian/tmp";
 286         }
 287         else {
 288                 return "debian/$package";
 289         }
 290 }
 291
 292 # Pass this the name of a binary package, and the name of the file wanted
 293 # for the package, and it will return the actual existing filename to use.
 294 #
 295 # It tries several filenames:
 296 #   * debian/package.filename.buildarch
 297 #   * debian/package.filename
 298 #   * debian/file (if the package is the main package)
 299 # If --name was specified then tonly the first two are tried, and they must
 300 # have the name after the pacage name:
 301 #   * debian/package.name.filename.buildarch
 302 #   * debian/package.name.filename
 303 sub pkgfile {
 304         my $package=shift;
 305         my $filename=shift;
 306
 307         if (defined $dh{NAME}) {
 308                 $filename="$dh{NAME}.$filename";
 309         }
 310
 311         if (-f "debian/$package.$filename.".buildarch()) {
 312                 return "debian/$package.$filename.".buildarch();
 313         }
 314         elsif (-f "debian/$package.$filename") {
 315                 return "debian/$package.$filename";
 316         }
 317         elsif ($package eq $dh{MAINPACKAGE} && -f "debian/$filename") {
 318                 return "debian/$filename";
 319         }
 320         else {
 321                 return "";
 322         }
 323 }
 324
 325 # Pass it a name of a binary package, it returns the name to prefix to files
 326 # in debian/ for this package.
 327 sub pkgext {
 328         my $package=shift;
 329
 330         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 331                 return "";
 332         }
 333         return "$package.";
 334 }
 335
 336 # Pass it the name of a binary package, it returns the name to install
 337 # files by in eg, etc. Normally this is the same, but --name can override
 338 # it.
 339 sub pkgfilename {
 340         my $package=shift;
 341
 342         if (defined $dh{NAME}) {
 343                 return $dh{NAME};
 344         }
 345         return $package;
 346 }
 347
 348 # Returns 1 if the package is a native debian package, null otherwise.
 349 # As a side effect, sets $dh{VERSION} to the version of this package.
 350 {
 351         # Caches return code so it only needs to run dpkg-parsechangelog once.
 352         my %isnative_cache;
 353
 354         sub isnative {
 355                 my $package=shift;
 356
 357                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 358
 359                 # Make sure we look at the correct changelog.
 360                 my $isnative_changelog=pkgfile($package,"changelog");
 361                 if (! $isnative_changelog) {
 362                         $isnative_changelog="debian/changelog";
 363                 }
 364                 # Get the package version.
 365                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 366                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 367                 # Did the changelog parse fail?
 368                 if (! defined $dh{VERSION}) {
 369                         error("changelog parse failure");
 370                 }
 371
 372                 # Is this a native Debian package?
 373                 if ($dh{VERSION}=~m/.*-/) {
 374                         return $isnative_cache{$package}=0;
 375                 }
 376                 else {
 377                         return $isnative_cache{$package}=1;
 378                 }
 379         }
 380 }
 381
 382 # Automatically add a shell script snippet to a debian script.
 383 # Only works if the script has #DEBHELPER# in it.
 384 #
 385 # Parameters:
 386 # 1: package
 387 # 2: script to add to
 388 # 3: filename of snippet
 389 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 390 sub autoscript {
 391         my $package=shift;
 392         my $script=shift;
 393         my $filename=shift;
 394         my $sed=shift || "";
 395
 396         # This is the file we will append to.
 397         my $outfile="debian/".pkgext($package)."$script.debhelper";
 398
 399         # Figure out what shell script snippet to use.
 400         my $infile;
 401         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 402             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 403                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 404         }
 405         else {
 406                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 407                         $infile="/usr/share/debhelper/autoscripts/$filename";
 408                 }
 409                 else {
 410                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 411                 }
 412         }
 413
 414         complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 415         complex_doit("sed \"$sed\" $infile >> $outfile");
 416         complex_doit("echo '# End automatically added section' >> $outfile");
 417 }
 418
 419 # Removes a whole substvar line.
 420 sub delsubstvar {
 421         my $package=shift;
 422         my $substvar=shift;
 423
 424         my $ext=pkgext($package);
 425         my $substvarfile="debian/${ext}substvars";
 426
 427         if (-e $substvarfile) {
 428                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 429                 doit("mv", "$substvarfile.new","$substvarfile");
 430         }
 431 }
 432
 433 # Adds a dependency on some package to the specified
 434 # substvar in a package's substvar's file.
 435 sub addsubstvar {
 436         my $package=shift;
 437         my $substvar=shift;
 438         my $deppackage=shift;
 439         my $verinfo=shift;
 440         my $remove=shift;
 441
 442         my $ext=pkgext($package);
 443         my $substvarfile="debian/${ext}substvars";
 444         my $str=$deppackage;
 445         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 446
 447         # Figure out what the line will look like, based on what's there
 448         # now, and what we're to add or remove.
 449         my $line="";
 450         if (-e $substvarfile) {
 451                 my %items;
 452                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 453                 while (<SUBSTVARS_IN>) {
 454                         chomp;
 455                         if (/^\Q$substvar\E=(.*)/) {
 456                                 %items = map { $_ => 1} split(", ", $1);
 457
 458                                 last;
 459                         }
 460                 }
 461                 close SUBSTVARS_IN;
 462                 if (! $remove) {
 463                         $items{$str}=1;
 464                 }
 465                 else {
 466                         delete $items{$str};
 467                 }
 468                 $line=join(", ", keys %items);
 469         }
 470         elsif (! $remove) {
 471                 $line=$str;
 472         }
 473
 474         if (length $line) {
 475                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 476                  doit("mv", "$substvarfile.new", $substvarfile);
 477         }
 478         else {
 479                 delsubstvar($package,$substvar);
 480         }
 481 }
 482
 483 # Reads in the specified file, one line at a time. splits on words,
 484 # and returns an array of arrays of the contents.
 485 # If a value is passed in as the second parameter, then glob
 486 # expansion is done in the directory specified by the parameter ("." is
 487 # frequently a good choice).
 488 sub filedoublearray {
 489         my $file=shift;
 490         my $globdir=shift;
 491
 492         my @ret;
 493         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 494         while (<DH_FARRAY_IN>) {
 495                 my @line;
 496                 # Only do glob expansion in v3 mode.
 497                 #
 498                 # The tricky bit is that the glob expansion is done
 499                 # as if we were in the specified directory, so the
 500                 # filenames that come out are relative to it.
 501                 if (defined $globdir && ! compat(2)) {
 502                         for (map { glob "$globdir/$_" } split) {
 503                                 s#^$globdir/##;
 504                                 push @line, $_;
 505                         }
 506                 }
 507                 else {
 508                         @line = split;
 509                 }
 510                 push @ret, [@line];
 511         }
 512         close DH_FARRAY_IN;
 513
 514         return @ret;
 515 }
 516
 517 # Reads in the specified file, one word at a time, and returns an array of
 518 # the result. Can do globbing as does filedoublearray.
 519 sub filearray {
 520         return map { @$_ } filedoublearray(@_);
 521 }
 522
 523 # Passed a filename, returns true if -X says that file should be excluded.
 524 sub excludefile {
 525         my $filename = shift;
 526         foreach my $f (@{$dh{EXCLUDE}}) {
 527                 return 1 if $filename =~ /\Q$f\E/;
 528         }
 529         return 0;
 530 }
 531
 532 # Returns the build architecture. (Memoized)
 533 {
 534         my $arch;
 535
 536         sub buildarch {
 537                 return $arch if defined $arch;
 538
 539                 $arch=`dpkg-architecture -qDEB_HOST_ARCH 2>/dev/null` || error($!);
 540                 chomp $arch;
 541                 return $arch;
 542         }
 543 }
 544
 545 # Returns a list of packages in the control file.
 546 # Must pass "arch" or "indep" or "same" to specify arch-dependant or
 547 # -independant or same arch packages. If nothing is specified, returns all
 548 # packages.
 549 # As a side effect, populates %package_arches and %package_types with the
 550 # types of all packages (not only those returned).
 551 my (%package_types, %package_arches);
 552 sub getpackages {
 553         my $type=shift;
 554
 555         %package_types=();
 556         %package_arches=();
 557
 558         $type="" if ! defined $type;
 559
 560         # Look up the build arch if we need to.
 561         my $buildarch='';
 562         if ($type eq 'same') {
 563                 $buildarch=buildarch();
 564         }
 565
 566         my $package="";
 567         my $arch="";
 568         my $package_type;
 569         my @list=();
 570         my %seen;
 571         open (CONTROL, 'debian/control') ||
 572                 error("cannot read debian/control: $!\n");
 573         while (<CONTROL>) {
 574                 chomp;
 575                 s/\s+$//;
 576                 if (/^Package:\s*(.*)/) {
 577                         $package=$1;
 578                         # Detect duplicate package names in the same control file.
 579                         if (! $seen{$package}) {
 580                                 $seen{$package}=1;
 581                         }
 582                         else {
 583                                 error("debian/control has a duplicate entry for $package");
 584                         }
 585                         $package_type="deb";
 586                 }
 587                 if (/^Architecture:\s*(.*)/) {
 588                         $arch=$1;
 589                 }
 590                 if (/^X[BC]*-Package-Type:\s*(.*)/) {
 591                         $package_type=$1;
 592                 }
 593
 594                 if (!$_ or eof) { # end of stanza.
 595                         if ($package) {
 596                                 $package_types{$package}=$package_type;
 597                                 $package_arches{$package}=$arch;
 598                         }
 599                         if ($package &&
 600                             (($type eq 'indep' && $arch eq 'all') ||
 601                              ($type eq 'arch' && $arch ne 'all') ||
 602                              ($type eq 'same' && ($arch eq 'any' || $arch =~ /\b$buildarch\b/)) ||
 603                              ! $type)) {
 604                                 push @list, $package;
 605                                 $package="";
 606                                 $arch="";
 607                         }
 608                 }
 609         }
 610         close CONTROL;
 611
 612         return @list;
 613 }
 614
 615 sub is_udeb {
 616         my $package=shift;
 617
 618         return $package_types{$package} eq 'udeb';
 619 }
 620
 621 sub udeb_filename {
 622         my $package=shift;
 623
 624         my $filearch=$package_arches{$package} eq 'all' ? "all" : buildarch();
 625         isnative($package); # side effect
 626         return "${package}_$dh{VERSION}_$filearch.udeb";
 627 }
 628
 629 1