Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2000.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &isnative &autoscript &filearray &GetPackages
  15             &xargs %dh);
  16
  17 my $max_compat=3;
  18
  19 sub init {
  20         # If DH_OPTIONS is set, prepend it @ARGV.
  21         if (defined($ENV{DH_OPTIONS})) {
  22                 unshift @ARGV,split(/\s+/,$ENV{DH_OPTIONS});
  23         }
  24
  25         # Check to see if an argument on the command line starts with a dash.
  26         # if so, we need to pass this off to the resource intensive
  27         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  28         my $parseopt=undef;
  29         my $arg;
  30         foreach $arg (@ARGV) {
  31                 if ($arg=~m/^-/) {
  32                         $parseopt=1;
  33                         last;
  34                 }
  35         }
  36         if ($parseopt) {
  37                 eval "use Debian::Debhelper::Dh_Getopt";
  38                 error($!) if $@;
  39                 %dh=Debian::Debhelper::Dh_Getopt::parseopts();
  40         }
  41
  42         # Check to see if DH_VERBOSE environment variable was set, if so,
  43         # make sure verbose is on.
  44         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  45                 $dh{VERBOSE}=1;
  46         }
  47
  48         # Check to see if DH_NO_ACT environment variable was set, if so,
  49         # make sure no act mode is on.
  50         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  51                 $dh{NO_ACT}=1;
  52         }
  53
  54         # Get the name of the main binary package (first one listed in
  55         # debian/control).
  56         my @allpackages=GetPackages();
  57         $dh{MAINPACKAGE}=$allpackages[0];
  58
  59         # Check if packages to build have been specified, if not, fall back to
  60         # the default, doing them all.
  61         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  62                 if ($dh{DOINDEP} || $dh{DOARCH} || $dh{DOSAME}) {
  63                         # User specified that all arch (in)dep package be
  64                         # built, and there are none of that type.
  65                         error("I have no package to act on");
  66                 }
  67                 push @{$dh{DOPACKAGES}},@allpackages;
  68         }
  69
  70         # Check to see if -P was specified. If so, we can only act on a single
  71         # package.
  72         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  73                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  74         }
  75
  76         # Figure out which package is the first one we were instructed to build.
  77         # This package gets special treatement: files and directories specified on
  78         # the command line may affect it.
  79         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  80
  81         # Split the U_PARAMS up into an array.
  82         my $u=$dh{U_PARAMS};
  83         undef $dh{U_PARAMS};
  84         if (defined $u) {
  85                 push @{$dh{U_PARAMS}}, split(/\s+/,$u);
  86         }
  87 }
  88
  89 # Escapes out shell metacharacters in a line of shell script.
  90 sub escape_shell {
  91         my $line=shift;
  92         # This list is from _Unix in a Nutshell_. (except '#')
  93         $line=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
  94         return $line;
  95 }
  96
  97 # Run a command, and display the command to stdout if verbose mode is on.
  98 # All commands that modifiy files in $TMP should be ran via this
  99 # function.
 100 #
 101 # Note that this cannot handle complex commands, especially anything
 102 # involving redirection. Use complex_doit instead.
 103 sub doit {
 104         verbose_print(join(" ",map { escape_shell($_) } @_));
 105
 106         if (! $dh{NO_ACT}) {
 107                 system(@_) == 0 || error("command returned error code");
 108         }
 109 }
 110
 111 # Run a command and display the command to stdout if verbose mode is on.
 112 # Use doit() if you can, instead of this function, because this function
 113 # forks a shell. However, this function can handle more complicated stuff
 114 # like redirection.
 115 sub complex_doit {
 116         verbose_print(join(" ",@_));
 117
 118         if (! $dh{NO_ACT}) {
 119                 # The join makes system get a scalar so it forks off a shell.
 120                 system(join(" ",@_)) == 0
 121                         || error("command returned error code");
 122         }
 123 }
 124
 125 # Run a command that may have a huge number of arguments, like xargs does.
 126 # Pass in a reference to an array containing the arguments, and then other
 127 # parameters that are the command and any parameters that should be passed to
 128 # it each time.
 129 sub xargs {
 130         my $args=shift;
 131
 132         # The kernel can accept command lines up to 20k worth of characters.
 133         my $command_max=20000; # LINUX SPECIFIC!!
 134
 135         # Figure out length of static portion of command.
 136         my $static_length=0;
 137         foreach (@_) {
 138                 $static_length+=length($_)+1;
 139         }
 140
 141         my @collect=();
 142         my $length=$static_length;
 143         foreach (@$args) {
 144                 if (length($_) + 1 + $static_length > $command_max) {
 145                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 146                 }
 147                 $length+=length($_) + 1;
 148                 if ($length < $command_max) {
 149                         push @collect, $_;
 150                 }
 151                 else {
 152                         doit(@_,@collect) if $#collect > -1;
 153                         @collect=($_);
 154                         $length=$static_length + length($_) + 1;
 155                 }
 156         }
 157         doit(@_,@collect) if $#collect > -1;
 158 }
 159
 160 # Print something if the verbose flag is on.
 161 sub verbose_print {
 162         my $message=shift;
 163
 164         if ($dh{VERBOSE}) {
 165                 print "\t$message\n";
 166         }
 167 }
 168
 169 # Output an error message and exit.
 170 sub error {
 171         my $message=shift;
 172
 173         warning($message);
 174         exit 1;
 175 }
 176
 177 # Output a warning.
 178 sub warning {
 179         my $message=shift;
 180
 181         print STDERR basename($0).": $message\n";
 182 }
 183
 184 # Returns the basename of the argument passed to it.
 185 sub basename {
 186         my $fn=shift;
 187
 188         $fn=~s:^.*/(.*?)$:$1:;
 189         return $fn;
 190 }
 191
 192 # Returns the directory name of the argument passed to it.
 193 sub dirname {
 194         my $fn=shift;
 195
 196         $fn=~s:^(.*)/.*?$:$1:;
 197         return $fn;
 198 }
 199
 200 # Pass in a number, will return true iff the current compatability level
 201 # is less than or equal to that number.
 202 sub compat {
 203         my $num=shift;
 204
 205         my $c=1;
 206         if (defined $ENV{DH_COMPAT}) {
 207                 $c=$ENV{DH_COMPAT};
 208         }
 209
 210         if ($c > $max_compat) {
 211                 error("Sorry, but $max_compat is the highest compatability level of debhelper currently supported.");
 212         }
 213
 214         return ($c <= $num);
 215 }
 216
 217 # Pass it a name of a binary package, it returns the name of the tmp dir to
 218 # use, for that package.
 219 sub tmpdir {
 220         my $package=shift;
 221
 222         if ($dh{TMPDIR}) {
 223                 return $dh{TMPDIR};
 224         }
 225         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 226                 # This is for back-compatability with the debian/tmp tradition.
 227                 return "debian/tmp";
 228         }
 229         else {
 230                 return "debian/$package";
 231         }
 232 }
 233
 234 # Pass this the name of a binary package, and the name of the file wanted
 235 # for the package, and it will return the actual existing filename to use.
 236 #
 237 # It tries several filenames:
 238 #   * debian/package.filename.buildarch
 239 #   * debian/package.filename
 240 #   * debian/file (if the package is the main package)
 241 sub pkgfile {
 242         my $package=shift;
 243         my $filename=shift;
 244
 245         if (-f "debian/$package.$filename.".buildarch()) {
 246                 return "debian/$package.$filename.".buildarch();
 247         }
 248         elsif (-f "debian/$package.$filename") {
 249                 return "debian/$package.$filename";
 250         }
 251         elsif ($package eq $dh{MAINPACKAGE} && -f "debian/$filename") {
 252                 return "debian/$filename";
 253         }
 254         else {
 255                 return "";
 256         }
 257 }
 258
 259 # Pass it a name of a binary package, it returns the name to prefix to files
 260 # in debian for this package.
 261 sub pkgext {
 262         my $package=shift;
 263
 264         if ($package ne $dh{MAINPACKAGE}) {
 265                 return "$package.";
 266         }
 267         return "";
 268 }
 269
 270 # Returns 1 if the package is a native debian package, null otherwise.
 271 # As a side effect, sets $dh{VERSION} to the version of this package.
 272 {
 273         # Caches return code so it only needs to run dpkg-parsechangelog once.
 274         my %isnative_cache;
 275
 276         sub isnative {
 277                 my $package=shift;
 278
 279                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 280
 281                 # Make sure we look at the correct changelog.
 282                 my $isnative_changelog=pkgfile($package,"changelog");
 283                 if (! $isnative_changelog) {
 284                         $isnative_changelog="debian/changelog";
 285                 }
 286                 # Get the package version.
 287                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 288                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 289                 # Did the changelog parse fail?
 290                 if (! defined $dh{VERSION}) {
 291                         error("changelog parse failure");
 292                 }
 293
 294                 # Is this a native Debian package?
 295                 if ($dh{VERSION}=~m/.*-/) {
 296                         return $isnative_cache{$package}=0;
 297                 }
 298                 else {
 299                         return $isnative_cache{$package}=1;
 300                 }
 301         }
 302 }
 303
 304 # Automatically add a shell script snippet to a debian script.
 305 # Only works if the script has #DEBHELPER# in it.
 306 #
 307 # Parameters:
 308 # 1: package
 309 # 2: script to add to
 310 # 3: filename of snippet
 311 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 312 sub autoscript {
 313         my $package=shift;
 314         my $script=shift;
 315         my $filename=shift;
 316         my $sed=shift || "";
 317
 318         # This is the file we will append to.
 319         my $outfile="debian/".pkgext($package)."$script.debhelper";
 320
 321         # Figure out what shell script snippet to use.
 322         my $infile;
 323         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 324             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 325                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 326         }
 327         else {
 328                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 329                         $infile="/usr/share/debhelper/autoscripts/$filename";
 330                 }
 331                 else {
 332                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 333                 }
 334         }
 335
 336         complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 337         complex_doit("sed \"$sed\" $infile >> $outfile");
 338         complex_doit("echo '# End automatically added section' >> $outfile");
 339 }
 340
 341 # Reads in the specified file, one word at a time, and returns an array of
 342 # the result. If a value is passed in as the second parameter, then glob
 343 # expansion is done in the directory specified by the parameter ("." is
 344 # frequently a good choice).
 345 sub filearray {
 346         my $file=shift;
 347         my $globdir=shift;
 348
 349         my @ret;
 350         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 351         while (<DH_FARRAY_IN>) {
 352                 # Only do glob expansion in v3 mode.
 353                 #
 354                 # The tricky bit is that the glob expansion is done
 355                 # as if we were in the specified directory, so the
 356                 # filenames that come out are relative to it.
 357                 if (defined $globdir && compat(3)) {
 358                         for (map { glob "$globdir/$_" } split) {
 359                                 s#^$globdir/##;
 360                                 push @ret, $_;
 361                                 print "(--$_)\n";
 362                         }
 363                 }
 364                 else {
 365                         push @ret, split;
 366                 }
 367         }
 368         close DH_FARRAY_IN;
 369
 370         return @ret;
 371 }
 372
 373 # Returns the build architecture. (Memoized)
 374 {
 375         my $arch;
 376
 377         sub buildarch {
 378                 return $arch if defined $arch;
 379
 380                 $arch=`dpkg --print-architecture` || error($!);
 381                 chomp $arch;
 382                 return $arch;
 383         }
 384 }
 385
 386 # Returns a list of packages in the control file.
 387 # Must pass "arch" or "indep" or "same" to specify arch-dependant or
 388 # -independant or same arch packages. If nothing is specified, returns all
 389 # packages.
 390 sub GetPackages {
 391         my $type=shift;
 392
 393         $type="" if ! defined $type;
 394
 395         # Look up the build arch if we need to.
 396         my $buildarch='';
 397         if ($type eq 'same') {
 398                 $buildarch=buildarch();
 399         }
 400
 401         my $package="";
 402         my $arch="";
 403         my @list=();
 404         open (CONTROL,"<debian/control") ||
 405                 error("cannot read debian/control: $!\n");
 406         while (<CONTROL>) {
 407                 chomp;
 408                 s/\s+$//;
 409                 if (/^Package:\s*(.*)/) {
 410                         $package=$1;
 411                 }
 412                 if (/^Architecture:\s*(.*)/) {
 413                         $arch=$1;
 414                 }
 415                 if (!$_ or eof) { # end of stanza.
 416                         if ($package &&
 417                             (($type eq 'indep' && $arch eq 'all') ||
 418                              ($type eq 'arch' && $arch ne 'all') ||
 419                              ($type eq 'same' && ($arch eq 'any' || $arch =~ /\b$buildarch\b/)) ||
 420                              ! $type)) {
 421                                 push @list, $package;
 422                                 $package="";
 423                                 $arch="";
 424                         }
 425                 }
 426         }
 427         close CONTROL;
 428
 429         return @list;
 430 }
 431
 432 1