Debian/Debhelper/Dh_Getopt.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Debhelper option processing library.
   4 #
   5 # Joey Hess GPL copyright 1998-2002
   6
   7 package Debian::Debhelper::Dh_Getopt;
   8 use strict;
   9
  10 use Debian::Debhelper::Dh_Lib;
  11 use Getopt::Long;
  12
  13 my %exclude_package;
  14
  15 sub showhelp {
  16         my $prog=basename($0);
  17         print "Usage: $prog [options]\n\n";
  18         print "  $prog is a part of debhelper. See debhelper(7)\n";
  19         print "  and $prog(1) for complete usage instructions.\n";
  20         exit(1);
  21 }
  22
  23 # Passed an option name and an option value, adds packages to the list
  24 # of packages. We need this so the list will be built up in the right
  25 # order.
  26 sub AddPackage { my($option,$value)=@_;
  27         if ($option eq 'i' or $option eq 'indep') {
  28                 push @{$dh{DOPACKAGES}}, getpackages('indep');
  29                 $dh{DOINDEP}=1;
  30         }
  31         elsif ($option eq 'a' or $option eq 'arch') {
  32                 push @{$dh{DOPACKAGES}}, getpackages('arch');
  33                 $dh{DOARCH}=1;
  34         }
  35         elsif ($option eq 'p' or $option eq 'package') {
  36                 push @{$dh{DOPACKAGES}}, $value;
  37         }
  38         elsif ($option eq 's' or $option eq 'same-arch') {
  39                 push @{$dh{DOPACKAGES}}, getpackages('same');
  40                 $dh{DOSAME}=1;
  41         }
  42         else {
  43                 error("bad option $option - should never happen!\n");
  44         }
  45 }
  46
  47 # Adds packages to the list of debug packages.
  48 sub AddDebugPackage { my($option,$value)=@_;
  49         push @{$dh{DEBUGPACKAGES}}, $value;
  50 }
  51
  52 # Add a package to a list of packages that should not be acted on.
  53 sub ExcludePackage { my($option,$value)=@_;
  54         $exclude_package{$value}=1;
  55 }
  56
  57 # Add another item to the exclude list.
  58 sub AddExclude { my($option,$value)=@_;
  59         push @{$dh{EXCLUDE}},$value;
  60 }
  61
  62 # Add a file to the ignore list.
  63 sub AddIgnore { my($option,$file)=@_;
  64         $dh{IGNORE}->{$file}=1;
  65 }
  66
  67 # This collects non-options values.
  68 sub NonOption {
  69         push @{$dh{ARGV}}, @_;
  70 }
  71
  72 sub getoptions {
  73         my $array=shift;
  74         my %options=%{shift()} if ref $_[0];
  75
  76         Getopt::Long::GetOptionsFromArray($array,
  77                 "v" => \$dh{VERBOSE},
  78                 "verbose" => \$dh{VERBOSE},
  79
  80                 "no-act" => \$dh{NO_ACT},
  81
  82                 "i" => \&AddPackage,
  83                 "indep" => \&AddPackage,
  84
  85                 "a" => \&AddPackage,
  86                 "arch" => \&AddPackage,
  87
  88                 "p=s" => \&AddPackage,
  89                 "package=s" => \&AddPackage,
  90
  91                 "N=s" => \&ExcludePackage,
  92                 "no-package=s" => \&ExcludePackage,
  93
  94                 "remaining-packages" => \$dh{EXCLUDE_LOGGED},
  95
  96                 "dbg-package=s" => \&AddDebugPackage,
  97
  98                 "s" => \&AddPackage,
  99                 "same-arch" => \&AddPackage,
 100
 101                 "n" => \$dh{NOSCRIPTS},
 102                 "noscripts" => \$dh{NOSCRIPTS},
 103                 "o" => \$dh{ONLYSCRIPTS},
 104                 "onlyscripts" => \$dh{ONLYSCRIPTS},
 105
 106                 "X=s" => \&AddExclude,
 107                 "exclude=s" => \&AddExclude,
 108
 109                 "d" => \$dh{D_FLAG},
 110
 111                 "k" => \$dh{K_FLAG},
 112                 "keep" => \$dh{K_FLAG},
 113
 114                 "P=s" => \$dh{TMPDIR},
 115                 "tmpdir=s" => \$dh{TMPDIR},
 116
 117                 "u=s", => \$dh{U_PARAMS},
 118
 119                 "V:s", => \$dh{V_FLAG},
 120
 121                 "A" => \$dh{PARAMS_ALL},
 122                 "all" => \$dh{PARAMS_ALL},
 123
 124                 "sourcedir=s" => \$dh{SOURCEDIR},
 125
 126                 "destdir=s" => \$dh{DESTDIR},
 127
 128                 "priority=s" => \$dh{PRIORITY},
 129
 130                 "h|help" => \&showhelp,
 131
 132                 "mainpackage=s" => \$dh{MAINPACKAGE},
 133
 134                 "name=s" => \$dh{NAME},
 135
 136                 "error-handler=s" => \$dh{ERROR_HANDLER},
 137
 138                 "ignore=s" => \&AddIgnore,
 139
 140                 %options,
 141
 142                 "<>" => \&NonOption,
 143         )
 144 }
 145
 146 # Parse options and set %dh values.
 147 sub parseopts {
 148         my $options=shift;
 149
 150         my @ARGV_extra;
 151
 152         # DH_INTERNAL_OPTIONS is used to pass additional options from
 153         # dh through an override target to a command.
 154         if (defined $ENV{DH_INTERNAL_OPTIONS}) {
 155                 $ENV{DH_INTERNAL_OPTIONS}=~s/^\s+//;
 156                 $ENV{DH_INTERNAL_OPTIONS}=~s/\s+$//;
 157                 @ARGV_extra=split(/\s+/,$ENV{DH_INTERNAL_OPTIONS});
 158
 159                 # Unknown options will be silently ignored.
 160                 my $oldwarn=$SIG{__WARN__};
 161                 $SIG{__WARN__}=sub {};
 162                 getoptions(\@ARGV_extra, $options);
 163                 $SIG{__WARN__}=$oldwarn;
 164
 165                 # Avoid forcing acting on packages specified in
 166                 # DH_INTERNAL_OPTIONS. This way, -p can be specified
 167                 # at the command line to act on a specific package, and if
 168                 # nothing is specified, the excludes will cause the set of
 169                 # packages DH_INTERNAL_OPTIONS specifies to be acted on.
 170                 if (defined $dh{DOPACKAGES}) {
 171                         foreach my $package (getpackages()) {
 172                                 if (! grep { $_ eq $package } @{$dh{DOPACKAGES}}) {
 173                                         $exclude_package{$package}=1;
 174                                 }
 175                         }
 176                 }
 177                 delete $dh{DOPACKAGES};
 178                 delete $dh{DOINDEP};
 179                 delete $dh{DOARCH};
 180                 delete $dh{DOSAME};
 181         }
 182
 183         # DH_OPTIONS can contain additional options
 184         # to be parsed like @ARGV, but with unknown options
 185         # skipped.
 186         if (defined $ENV{DH_OPTIONS}) {
 187                 $ENV{DH_OPTIONS}=~s/^\s+//;
 188                 $ENV{DH_OPTIONS}=~s/\s+$//;
 189                 @ARGV_extra=split(/\s+/,$ENV{DH_OPTIONS});
 190                 my $ret=getoptions(\@ARGV_extra, $options);
 191                 if (!$ret) {
 192                         warning("warning: ignored unknown options in DH_OPTIONS");
 193                 }
 194         }
 195
 196         my $ret=getoptions(\@ARGV, $options);
 197         if (!$ret) {
 198                 warning("warning: unknown options will be a fatal error in a future debhelper release");
 199                 #error("unknown option; aborting");
 200         }
 201
 202         # Check to see if -V was specified. If so, but no parameters were
 203         # passed, the variable will be defined but empty.
 204         if (defined($dh{V_FLAG})) {
 205                 $dh{V_FLAG_SET}=1;
 206         }
 207
 208         # If we have not been given any packages to act on, assume they
 209         # want us to act on them all. Note we have to do this before excluding
 210         # packages out, below.
 211         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
 212                 if ($dh{DOINDEP} || $dh{DOARCH} || $dh{DOSAME}) {
 213                         # User specified that all arch (in)dep package be
 214                         # built, and there are none of that type.
 215                         warning("You asked that all arch in(dep) packages be built, but there are none of that type.");
 216                         exit(0);
 217                 }
 218                 push @{$dh{DOPACKAGES}},getpackages();
 219         }
 220
 221         # Remove excluded packages from the list of packages to act on.
 222         # Also unique the list, in case some options were specified that
 223         # added a package to it twice.
 224         my @package_list;
 225         my $package;
 226         my %packages_seen;
 227         foreach $package (@{$dh{DOPACKAGES}}) {
 228                 if (defined($dh{EXCLUDE_LOGGED}) &&
 229                     grep { $_ eq basename($0) } load_log($package)) {
 230                         $exclude_package{$package}=1;
 231                 }
 232                 if (! $exclude_package{$package}) {
 233                         if (! exists $packages_seen{$package}) {
 234                                 $packages_seen{$package}=1;
 235                                 push @package_list, $package;
 236                         }
 237                 }
 238         }
 239         @{$dh{DOPACKAGES}}=@package_list;
 240
 241         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
 242                 warning("No packages to build.");
 243                 exit(0);
 244         }
 245
 246         if (defined $dh{U_PARAMS}) {
 247                 # Split the U_PARAMS up into an array.
 248                 my $u=$dh{U_PARAMS};
 249                 undef $dh{U_PARAMS};
 250                 push @{$dh{U_PARAMS}}, split(/\s+/,$u);
 251         }
 252
 253         # Anything left in @ARGV is options that appeared after a --
 254         # These options are added to the U_PARAMS array, while the
 255         # non-option values we collected replace them in @ARGV;
 256         push @{$dh{U_PARAMS}}, @ARGV, @ARGV_extra;
 257         @ARGV=@{$dh{ARGV}} if exists $dh{ARGV};
 258 }
 259
 260 sub import {
 261         # Enable bundling of short command line options.
 262         Getopt::Long::config("bundling");
 263 }
 264
 265 1