Debian/Debhelper/Dh_Getopt.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Debhelper option processing library.
   4 #
   5 # Joey Hess GPL copyright 1998-2002
   6
   7 package Debian::Debhelper::Dh_Getopt;
   8 use strict;
   9
  10 use Debian::Debhelper::Dh_Lib;
  11 use Getopt::Long;
  12
  13 my %exclude_package;
  14
  15 sub showhelp {
  16         my $prog=basename($0);
  17         print "Usage: $prog [options]\n\n";
  18         print "  $prog is a part of debhelper. See debhelper(7)\n";
  19         print "  and $prog(1) for complete usage instructions.\n";
  20         exit(1);
  21 }
  22
  23 # Passed an option name and an option value, adds packages to the list
  24 # of packages. We need this so the list will be built up in the right
  25 # order.
  26 sub AddPackage { my($option,$value)=@_;
  27         if ($option eq 'i' or $option eq 'indep') {
  28                 push @{$dh{DOPACKAGES}}, getpackages('indep');
  29                 $dh{DOINDEP}=1;
  30         }
  31         elsif ($option eq 'a' or $option eq 'arch' or
  32                $option eq 's' or $option eq 'same-arch') {
  33                 push @{$dh{DOPACKAGES}}, getpackages('arch');
  34                 $dh{DOARCH}=1;
  35         }
  36         elsif ($option eq 'p' or $option eq 'package') {
  37                 push @{$dh{DOPACKAGES}}, $value;
  38         }
  39         else {
  40                 error("bad option $option - should never happen!\n");
  41         }
  42 }
  43
  44 # Adds packages to the list of debug packages.
  45 sub AddDebugPackage { my($option,$value)=@_;
  46         push @{$dh{DEBUGPACKAGES}}, $value;
  47 }
  48
  49 # Add a package to a list of packages that should not be acted on.
  50 sub ExcludePackage { my($option,$value)=@_;
  51         $exclude_package{$value}=1;
  52 }
  53
  54 # Add another item to the exclude list.
  55 sub AddExclude { my($option,$value)=@_;
  56         push @{$dh{EXCLUDE}},$value;
  57 }
  58
  59 # Add a file to the ignore list.
  60 sub AddIgnore { my($option,$file)=@_;
  61         $dh{IGNORE}->{$file}=1;
  62 }
  63
  64 # This collects non-options values.
  65 sub NonOption {
  66         push @{$dh{ARGV}}, @_;
  67 }
  68
  69 sub getoptions {
  70         my $array=shift;
  71         my %params=@_;
  72
  73         my @test;
  74         my %options=(
  75                 "v" => \$dh{VERBOSE},
  76                 "verbose" => \$dh{VERBOSE},
  77
  78                 "no-act" => \$dh{NO_ACT},
  79
  80                 "i" => \&AddPackage,
  81                 "indep" => \&AddPackage,
  82
  83                 "a" => \&AddPackage,
  84                 "arch" => \&AddPackage,
  85
  86                 "p=s" => \&AddPackage,
  87                 "package=s" => \&AddPackage,
  88
  89                 "N=s" => \&ExcludePackage,
  90                 "no-package=s" => \&ExcludePackage,
  91
  92                 "remaining-packages" => \$dh{EXCLUDE_LOGGED},
  93
  94                 "dbg-package=s" => \&AddDebugPackage,
  95
  96                 "s" => \&AddPackage,
  97                 "same-arch" => \&AddPackage,
  98
  99                 "n" => \$dh{NOSCRIPTS},
 100                 "noscripts" => \$dh{NOSCRIPTS},
 101                 "o" => \$dh{ONLYSCRIPTS},
 102                 "onlyscripts" => \$dh{ONLYSCRIPTS},
 103
 104                 "X=s" => \&AddExclude,
 105                 "exclude=s" => \&AddExclude,
 106
 107                 "d" => \$dh{D_FLAG},
 108
 109                 "k" => \$dh{K_FLAG},
 110                 "keep" => \$dh{K_FLAG},
 111
 112                 "P=s" => \$dh{TMPDIR},
 113                 "tmpdir=s" => \$dh{TMPDIR},
 114
 115                 "u=s", => \$dh{U_PARAMS},
 116
 117                 "V:s", => \$dh{V_FLAG},
 118
 119                 "A" => \$dh{PARAMS_ALL},
 120                 "all" => \$dh{PARAMS_ALL},
 121
 122                 "priority=s" => \$dh{PRIORITY},
 123
 124                 "h|help" => \&showhelp,
 125
 126                 "mainpackage=s" => \$dh{MAINPACKAGE},
 127
 128                 "name=s" => \$dh{NAME},
 129
 130                 "error-handler=s" => \$dh{ERROR_HANDLER},
 131
 132                 "ignore=s" => \&AddIgnore,
 133
 134                 "O=s" => sub { push @test, $_[1] },
 135
 136                 (ref $params{options} ? %{$params{options}} : ()) ,
 137
 138                 "<>" => \&NonOption,
 139         );
 140
 141         if ($params{test}) {
 142                 foreach my $key (keys %options) {
 143                         $options{$key}=sub {};
 144                 }
 145         }
 146
 147         my $oldwarn;
 148         if ($params{test}) {
 149                 $oldwarn=$SIG{__WARN__};
 150                 $SIG{__WARN__}=sub {};
 151         }
 152         my $ret=Getopt::Long::GetOptionsFromArray($array, %options);
 153         if ($oldwarn) {
 154                 $SIG{__WARN__}=$oldwarn;
 155         }
 156
 157         foreach my $opt (@test) {
 158                 # Try to parse an option, but ignore it
 159                 # if it is not known.
 160                 if (getoptions([$opt], %params, test => 1)) {
 161                         getoptions([$opt], %params);
 162                 }
 163         }
 164
 165         return $ret;
 166 }
 167
 168 sub split_options_string {
 169         my $str=shift;
 170         $str=~s/^\s+//;
 171         return split(/\s+/,$str);
 172 }
 173
 174 # Parse options and set %dh values.
 175 sub parseopts {
 176         my %params=@_;
 177
 178         my @ARGV_extra;
 179
 180         # DH_INTERNAL_OPTIONS is used to pass additional options from
 181         # dh through an override target to a command.
 182         if (defined $ENV{DH_INTERNAL_OPTIONS}) {
 183                 @ARGV_extra=split(/\x1e/, $ENV{DH_INTERNAL_OPTIONS});
 184                 getoptions(\@ARGV_extra, %params);
 185
 186                 # Avoid forcing acting on packages specified in
 187                 # DH_INTERNAL_OPTIONS. This way, -p can be specified
 188                 # at the command line to act on a specific package, but when
 189                 # nothing is specified, the excludes will cause the set of
 190                 # packages DH_INTERNAL_OPTIONS specifies to be acted on.
 191                 if (defined $dh{DOPACKAGES}) {
 192                         foreach my $package (getpackages()) {
 193                                 if (! grep { $_ eq $package } @{$dh{DOPACKAGES}}) {
 194                                         $exclude_package{$package}=1;
 195                                 }
 196                         }
 197                 }
 198                 delete $dh{DOPACKAGES};
 199                 delete $dh{DOINDEP};
 200                 delete $dh{DOARCH};
 201         }
 202
 203         # DH_OPTIONS can contain additional options to be parsed like @ARGV
 204         if (defined $ENV{DH_OPTIONS}) {
 205                 @ARGV_extra=split_options_string($ENV{DH_OPTIONS});
 206                 my $ret=getoptions(\@ARGV_extra, %params);
 207                 if (!$ret) {
 208                         warning("warning: ignored unknown options in DH_OPTIONS");
 209                 }
 210         }
 211
 212         my $ret=getoptions(\@ARGV, %params);
 213         if (!$ret) {
 214                 warning("warning: unknown options will be a fatal error in a future debhelper release");
 215                 #error("unknown option; aborting");
 216         }
 217
 218         # Check to see if -V was specified. If so, but no parameters were
 219         # passed, the variable will be defined but empty.
 220         if (defined($dh{V_FLAG})) {
 221                 $dh{V_FLAG_SET}=1;
 222         }
 223
 224         # If we have not been given any packages to act on, assume they
 225         # want us to act on them all. Note we have to do this before excluding
 226         # packages out, below.
 227         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
 228                 if ($dh{DOINDEP} || $dh{DOARCH}) {
 229                         # User specified that all arch (in)dep package be
 230                         # built, and there are none of that type.
 231                         warning("You asked that all arch in(dep) packages be built, but there are none of that type.");
 232                         exit(0);
 233                 }
 234                 push @{$dh{DOPACKAGES}},getpackages();
 235         }
 236
 237         # Remove excluded packages from the list of packages to act on.
 238         # Also unique the list, in case some options were specified that
 239         # added a package to it twice.
 240         my @package_list;
 241         my $package;
 242         my %packages_seen;
 243         foreach $package (@{$dh{DOPACKAGES}}) {
 244                 if (defined($dh{EXCLUDE_LOGGED}) &&
 245                     grep { $_ eq basename($0) } load_log($package)) {
 246                         $exclude_package{$package}=1;
 247                 }
 248                 if (! $exclude_package{$package}) {
 249                         if (! exists $packages_seen{$package}) {
 250                                 $packages_seen{$package}=1;
 251                                 push @package_list, $package;
 252                         }
 253                 }
 254         }
 255         @{$dh{DOPACKAGES}}=@package_list;
 256
 257         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
 258                 warning("No packages to build.");
 259                 exit(0);
 260         }
 261
 262         if (defined $dh{U_PARAMS}) {
 263                 # Split the U_PARAMS up into an array.
 264                 my $u=$dh{U_PARAMS};
 265                 undef $dh{U_PARAMS};
 266                 push @{$dh{U_PARAMS}}, split(/\s+/,$u);
 267         }
 268
 269         # Anything left in @ARGV is options that appeared after a --
 270         # These options are added to the U_PARAMS array, while the
 271         # non-option values we collected replace them in @ARGV;
 272         push @{$dh{U_PARAMS}}, @ARGV, @ARGV_extra;
 273         @ARGV=@{$dh{ARGV}} if exists $dh{ARGV};
 274 }
 275
 276 sub import {
 277         # Enable bundling of short command line options.
 278         Getopt::Long::config("bundling");
 279 }
 280
 281 1