Debian/Debhelper/Dh_Getopt.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Debhelper option processing library.
   4 #
   5 # Joey Hess GPL copyright 1998-2002
   6
   7 package Debian::Debhelper::Dh_Getopt;
   8 use strict;
   9
  10 use Debian::Debhelper::Dh_Lib;
  11 use Getopt::Long;
  12
  13 my %exclude_package;
  14
  15 sub showhelp {
  16         my $prog=basename($0);
  17         print "Usage: $prog [options]\n\n";
  18         print "  $prog is a part of debhelper. See debhelper(7)\n";
  19         print "  and $prog(1) for complete usage instructions.\n";
  20         exit(1);
  21 }
  22
  23 # Passed an option name and an option value, adds packages to the list
  24 # of packages. We need this so the list will be built up in the right
  25 # order.
  26 sub AddPackage { my($option,$value)=@_;
  27         if ($option eq 'i' or $option eq 'indep') {
  28                 push @{$dh{DOPACKAGES}}, getpackages('indep');
  29                 $dh{DOINDEP}=1;
  30         }
  31         elsif ($option eq 'a' or $option eq 'arch') {
  32                 push @{$dh{DOPACKAGES}}, getpackages('arch');
  33                 $dh{DOARCH}=1;
  34         }
  35         elsif ($option eq 'p' or $option eq 'package') {
  36                 push @{$dh{DOPACKAGES}}, $value;
  37         }
  38         elsif ($option eq 's' or $option eq 'same-arch') {
  39                 push @{$dh{DOPACKAGES}}, getpackages('same');
  40                 $dh{DOSAME}=1;
  41         }
  42         else {
  43                 error("bad option $option - should never happen!\n");
  44         }
  45 }
  46
  47 # Adds packages to the list of debug packages.
  48 sub AddDebugPackage { my($option,$value)=@_;
  49         push @{$dh{DEBUGPACKAGES}}, $value;
  50 }
  51
  52 # Add a package to a list of packages that should not be acted on.
  53 sub ExcludePackage { my($option,$value)=@_;
  54         $exclude_package{$value}=1;
  55 }
  56
  57 # Add another item to the exclude list.
  58 sub AddExclude { my($option,$value)=@_;
  59         push @{$dh{EXCLUDE}},$value;
  60 }
  61
  62 # Add a file to the ignore list.
  63 sub AddIgnore { my($option,$file)=@_;
  64         $dh{IGNORE}->{$file}=1;
  65 }
  66
  67 # This collects non-options values.
  68 sub NonOption {
  69         push @{$dh{ARGV}}, @_;
  70 }
  71
  72 sub getoptions {
  73         my $array=shift;
  74         my %options=%{shift()} if ref $_[0];
  75
  76         Getopt::Long::GetOptionsFromArray($array,
  77                 "v" => \$dh{VERBOSE},
  78                 "verbose" => \$dh{VERBOSE},
  79
  80                 "no-act" => \$dh{NO_ACT},
  81
  82                 "i" => \&AddPackage,
  83                 "indep" => \&AddPackage,
  84
  85                 "a" => \&AddPackage,
  86                 "arch" => \&AddPackage,
  87
  88                 "p=s" => \&AddPackage,
  89                 "package=s" => \&AddPackage,
  90
  91                 "N=s" => \&ExcludePackage,
  92                 "no-package=s" => \&ExcludePackage,
  93
  94                 "remaining-packages" => \$dh{EXCLUDE_LOGGED},
  95
  96                 "dbg-package=s" => \&AddDebugPackage,
  97
  98                 "s" => \&AddPackage,
  99                 "same-arch" => \&AddPackage,
 100
 101                 "n" => \$dh{NOSCRIPTS},
 102                 "noscripts" => \$dh{NOSCRIPTS},
 103                 "o" => \$dh{ONLYSCRIPTS},
 104                 "onlyscripts" => \$dh{ONLYSCRIPTS},
 105
 106                 "X=s" => \&AddExclude,
 107                 "exclude=s" => \&AddExclude,
 108
 109                 "d" => \$dh{D_FLAG},
 110
 111                 "k" => \$dh{K_FLAG},
 112                 "keep" => \$dh{K_FLAG},
 113
 114                 "P=s" => \$dh{TMPDIR},
 115                 "tmpdir=s" => \$dh{TMPDIR},
 116
 117                 "u=s", => \$dh{U_PARAMS},
 118
 119                 "V:s", => \$dh{V_FLAG},
 120
 121                 "A" => \$dh{PARAMS_ALL},
 122                 "all" => \$dh{PARAMS_ALL},
 123
 124                 "sourcedir=s" => \$dh{SOURCEDIR},
 125
 126                 "destdir=s" => \$dh{DESTDIR},
 127
 128                 "priority=s" => \$dh{PRIORITY},
 129
 130                 "h|help" => \&showhelp,
 131
 132                 "mainpackage=s" => \$dh{MAINPACKAGE},
 133
 134                 "name=s" => \$dh{NAME},
 135
 136                 "error-handler=s" => \$dh{ERROR_HANDLER},
 137
 138                 "ignore=s" => \&AddIgnore,
 139
 140                 %options,
 141
 142                 "<>" => \&NonOption,
 143         )
 144 }
 145
 146 sub split_options_string {
 147         my $str=shift;
 148         $str=~s/^\s+//;
 149         return split(/\s+/,$str);
 150 }
 151
 152 # Parse options and set %dh values.
 153 sub parseopts {
 154         my $options=shift;
 155
 156         my @ARGV_extra;
 157
 158         # DH_INTERNAL_OPTIONS is used to pass additional options from
 159         # dh through an override target to a command.
 160         if (defined $ENV{DH_INTERNAL_OPTIONS}) {
 161                 @ARGV_extra=split_options_string($ENV{DH_INTERNAL_OPTIONS});
 162                 # Unknown options will be silently ignored.
 163                 my $oldwarn=$SIG{__WARN__};
 164                 $SIG{__WARN__}=sub {};
 165                 getoptions(\@ARGV_extra, $options);
 166                 $SIG{__WARN__}=$oldwarn;
 167
 168                 # Avoid forcing acting on packages specified in
 169                 # DH_INTERNAL_OPTIONS. This way, -p can be specified
 170                 # at the command line to act on a specific package, and if
 171                 # nothing is specified, the excludes will cause the set of
 172                 # packages DH_INTERNAL_OPTIONS specifies to be acted on.
 173                 if (defined $dh{DOPACKAGES}) {
 174                         foreach my $package (getpackages()) {
 175                                 if (! grep { $_ eq $package } @{$dh{DOPACKAGES}}) {
 176                                         $exclude_package{$package}=1;
 177                                 }
 178                         }
 179                 }
 180                 delete $dh{DOPACKAGES};
 181                 delete $dh{DOINDEP};
 182                 delete $dh{DOARCH};
 183                 delete $dh{DOSAME};
 184         }
 185
 186         # DH_OPTIONS can contain additional options
 187         # to be parsed like @ARGV, but with unknown options
 188         # skipped.
 189         if (defined $ENV{DH_OPTIONS}) {
 190                 @ARGV_extra=split_options_string($ENV{DH_OPTIONS});
 191                 my $ret=getoptions(\@ARGV_extra, $options);
 192                 if (!$ret) {
 193                         warning("warning: ignored unknown options in DH_OPTIONS");
 194                 }
 195         }
 196
 197         my $ret=getoptions(\@ARGV, $options);
 198         if (!$ret) {
 199                 warning("warning: unknown options will be a fatal error in a future debhelper release");
 200                 #error("unknown option; aborting");
 201         }
 202
 203         # Check to see if -V was specified. If so, but no parameters were
 204         # passed, the variable will be defined but empty.
 205         if (defined($dh{V_FLAG})) {
 206                 $dh{V_FLAG_SET}=1;
 207         }
 208
 209         # If we have not been given any packages to act on, assume they
 210         # want us to act on them all. Note we have to do this before excluding
 211         # packages out, below.
 212         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
 213                 if ($dh{DOINDEP} || $dh{DOARCH} || $dh{DOSAME}) {
 214                         # User specified that all arch (in)dep package be
 215                         # built, and there are none of that type.
 216                         warning("You asked that all arch in(dep) packages be built, but there are none of that type.");
 217                         exit(0);
 218                 }
 219                 push @{$dh{DOPACKAGES}},getpackages();
 220         }
 221
 222         # Remove excluded packages from the list of packages to act on.
 223         # Also unique the list, in case some options were specified that
 224         # added a package to it twice.
 225         my @package_list;
 226         my $package;
 227         my %packages_seen;
 228         foreach $package (@{$dh{DOPACKAGES}}) {
 229                 if (defined($dh{EXCLUDE_LOGGED}) &&
 230                     grep { $_ eq basename($0) } load_log($package)) {
 231                         $exclude_package{$package}=1;
 232                 }
 233                 if (! $exclude_package{$package}) {
 234                         if (! exists $packages_seen{$package}) {
 235                                 $packages_seen{$package}=1;
 236                                 push @package_list, $package;
 237                         }
 238                 }
 239         }
 240         @{$dh{DOPACKAGES}}=@package_list;
 241
 242         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
 243                 warning("No packages to build.");
 244                 exit(0);
 245         }
 246
 247         if (defined $dh{U_PARAMS}) {
 248                 # Split the U_PARAMS up into an array.
 249                 my $u=$dh{U_PARAMS};
 250                 undef $dh{U_PARAMS};
 251                 push @{$dh{U_PARAMS}}, split(/\s+/,$u);
 252         }
 253
 254         # Anything left in @ARGV is options that appeared after a --
 255         # These options are added to the U_PARAMS array, while the
 256         # non-option values we collected replace them in @ARGV;
 257         push @{$dh{U_PARAMS}}, @ARGV, @ARGV_extra;
 258         @ARGV=@{$dh{ARGV}} if exists $dh{ARGV};
 259 }
 260
 261 sub import {
 262         # Enable bundling of short command line options.
 263         Getopt::Long::config("bundling");
 264 }
 265
 266 1