Debian/Debhelper/Buildsystem.pm

   1 # Defines debhelper buildsystem class interface and implementation
   2 # of common functionality.
   3 #
   4 # Copyright: © 2008-2009 Modestas Vainius
   5 # License: GPL-2+
   6
   7 package Debian::Debhelper::Buildsystem;
   8
   9 use strict;
  10 use warnings;
  11 use Cwd;
  12 use File::Spec;
  13 use Debian::Debhelper::Dh_Lib;
  14
  15 # Cache DEB_BUILD_GNU_TYPE value. Performance hit of multiple
  16 # invocations is noticable when listing buildsystems.
  17 our $DEB_BUILD_GNU_TYPE = dpkg_architecture_value("DEB_BUILD_GNU_TYPE");
  18
  19 # Build system name. Defaults to the last component of the class
  20 # name. Do not override this method unless you know what you are
  21 # doing.
  22 sub NAME {
  23         my $this=shift;
  24         my $class = ref($this) || $this;
  25         if ($class =~ m/^.+::([^:]+)$/) {
  26                 return $1;
  27         }
  28         else {
  29                 error("ınvalid buildsystem class name: $class");
  30         }
  31 }
  32
  33 # Description of the build system to be shown to the users.
  34 sub DESCRIPTION {
  35         error("class lacking a DESCRIPTION");
  36 }
  37
  38 # Default build directory. Can be overriden in the derived
  39 # class if really needed.
  40 sub DEFAULT_BUILD_DIRECTORY {
  41         "obj-" . $DEB_BUILD_GNU_TYPE;
  42 }
  43
  44 # Constructs a new build system object. Named parameters:
  45 # - builddir -     specifies build directory to use. If not specified,
  46 #                  in-source build will be performed. If undef or empty,
  47 #                  DEFAULT_BUILD_DIRECTORY will be used.
  48 # - build_action - set this parameter to the name of the build action
  49 #                  if you want the object to determine its is_buidable
  50 #                  status automatically (with check_auto_buildable()).
  51 #                  Do not pass this parameter if is_buildable flag should
  52 #                  be forced to true or set this parameter to undef if
  53 #                  is_buildable flag should be false.
  54 # Derived class can override the constructor to initialize common object
  55 # parameters and execute commands to configure build environment if
  56 # is_buildable flag is set on the object.
  57 sub new {
  58         my ($class, %opts)=@_;
  59
  60         my $this = bless({ builddir => undef, is_buildable => 1 }, $class);
  61         if (exists $opts{builddir}) {
  62                 if ($opts{builddir}) {
  63                         $this->{builddir} = $opts{builddir};
  64                 }
  65                 else {
  66                         $this->{builddir} = $this->DEFAULT_BUILD_DIRECTORY();
  67                 }
  68         }
  69         if (exists $opts{build_action}) {
  70                 if (defined $opts{build_action}) {
  71                         $this->{is_buildable} = $this->check_auto_buildable($opts{build_action});
  72                 }
  73                 else {
  74                         $this->{is_buildable} = 0;
  75                 }
  76         }
  77         return $this;
  78 }
  79
  80 # Test is_buildable flag of the object.
  81 sub is_buildable {
  82         my $this=shift;
  83         return $this->{is_buildable};
  84 }
  85
  86 # This instance method is called to check if the build system is capable
  87 # to auto build a source package. Additional argument $action describes
  88 # which operation the caller is going to perform (either configure,
  89 # build, test, install or clean). You must override this method for the
  90 # build system module to be ever picked up automatically. This method is
  91 # used in conjuction with @Dh_Buildsystems::BUILDSYSTEMS.
  92 #
  93 # This method is supposed to be called with source root directory being
  94 # working directory. Use $this->get_buildpath($path) method to get full
  95 # path to the files in the build directory.
  96 sub check_auto_buildable {
  97         my $this=shift;
  98         my ($action) = @_;
  99         return 0;
 100 }
 101
 102 # Derived class can call this method in its constructor
 103 # to enforce in-source building even if the user requested otherwise.
 104 sub enforce_in_source_building {
 105         my $this=shift;
 106         if ($this->{builddir}) {
 107                 # Do not emit warning unless the object is buildable.
 108                 if ($this->is_buildable()) {
 109                         warning("warning: " . $this->NAME() .
 110                             " does not support building outside-source. In-source build enforced.");
 111                 }
 112                 $this->{builddir} = undef;
 113         }
 114 }
 115
 116 # Derived class can call this method in its constructor to enforce
 117 # outside-source building even if the user didn't request it.
 118 sub enforce_outside_source_building {
 119         my ($this, $builddir) = @_;
 120         if (!defined $this->{builddir}) {
 121                 $this->{builddir} = ($builddir && $builddir ne ".") ? $builddir : $this->DEFAULT_BUILD_DIRECTORY();
 122         }
 123 }
 124
 125 # Get path to the specified build directory
 126 sub get_builddir {
 127         my $this=shift;
 128         return $this->{builddir};
 129 }
 130
 131 # Construct absolute path to the file from the given path that is relative
 132 # to the build directory.
 133 sub get_buildpath {
 134         my ($this, $path) = @_;
 135         if ($this->get_builddir()) {
 136                 return File::Spec->catfile($this->get_builddir(), $path);
 137         }
 138         else {
 139                 return File::Spec->catfile('.', $path);
 140         }
 141 }
 142
 143 # When given a relative path in the source tree, converts it
 144 # to the path that is relative to the build directory.
 145 # If $path is not given, returns relative path to the root of the
 146 # source tree from the build directory.
 147 sub get_rel2builddir_path {
 148         my $this=shift;
 149         my $path=shift;
 150
 151         if (defined $path) {
 152                 $path = File::Spec->catfile(Cwd::getcwd(), $path);
 153         }
 154         else {
 155                 $path = Cwd::getcwd();
 156         }
 157         if ($this->get_builddir()) {
 158                 return File::Spec->abs2rel($path, Cwd::abs_path($this->get_builddir()));
 159         }
 160         return $path;
 161 }
 162
 163 # Creates a build directory.
 164 sub mkdir_builddir {
 165         my $this=shift;
 166         if ($this->get_builddir()) {
 167                 doit("mkdir", "-p", $this->get_builddir());
 168         }
 169 }
 170
 171 sub _cd {
 172         my ($this, $dir)=@_;
 173         if (! $dh{NO_ACT}) {
 174                 verbose_print("cd $dir");
 175                 chdir $dir or error("error: unable to chdir to $dir");
 176         }
 177 }
 178
 179 # Changes working directory the build directory (if needed), calls doit(@_)
 180 # and changes working directory back to the source directory.
 181 sub doit_in_builddir {
 182         my $this=shift;
 183         if ($this->get_builddir()) {
 184                 my $builddir = $this->get_builddir();
 185                 my $sourcedir = $this->get_rel2builddir_path();
 186                 $this->_cd($builddir);
 187                 doit(@_);
 188                 $this->_cd($sourcedir);
 189         }
 190         else {
 191                 doit(@_);
 192         }
 193         return 1;
 194 }
 195
 196 # In case of outside-source tree building, whole build directory
 197 # gets wiped (if it exists) and 1 is returned. Otherwise, nothing
 198 # is done and 0 is returned.
 199 sub clean_builddir {
 200         my $this=shift;
 201         if ($this->get_builddir()) {
 202                 if (-d $this->get_builddir()) {
 203                         doit("rm", "-rf", $this->get_builddir());
 204                 }
 205                 return 1;
 206         }
 207         return 0;
 208 }
 209
 210
 211 # Instance method that is called before performing any action (see below).
 212 # Action name is passed as an argument. Derived classes overriding this
 213 # method should also call SUPER implementation of it.
 214 sub pre_action {
 215         my $this=shift;
 216         my ($action)=@_;
 217 }
 218
 219 # Instance method that is called after performing any action (see below).
 220 # Action name is passed as an argument. Derived classes overriding this
 221 # method should also call SUPER implementation of it.
 222 sub post_action {
 223         my $this=shift;
 224         my ($action)=@_;
 225 }
 226
 227 # The instance methods below provide support for configuring,
 228 # building, testing, install and cleaning source packages.
 229 # In case of failure, the method may just error() out.
 230 #
 231 # These methods should be overriden by derived classes to
 232 # implement buildsystem specific actions needed to build the
 233 # source. Arbitary number of custom action arguments might be
 234 # passed. Default implementations do nothing.
 235 sub configure {
 236         my $this=shift;
 237 }
 238
 239 sub build {
 240         my $this=shift;
 241 }
 242
 243 sub test {
 244         my $this=shift;
 245 }
 246
 247 # destdir parameter specifies where to install files.
 248 sub install {
 249         my $this=shift;
 250         my $destdir=shift;
 251 }
 252
 253 sub clean {
 254         my $this=shift;
 255 }
 256
 257 1;