1 # This module is part of debbugs, and is released
2 # under the terms of the GPL version 2, or any later
3 # version at your option.
4 # See the file README and COPYING for more information.
6 # [Other people have contributed to this file; their copyrights should
8 # Copyright 2007 by Don Armstrong <don@donarmstrong.com>.
10 package Debbugs::Common;
14 Debbugs::Common -- Common routines for all of Debbugs
18 use Debbugs::Common qw(:url :html);
23 This module is a replacement for the general parts of errorlib.pl.
24 subroutines in errorlib.pl will be gradually phased out and replaced
25 with equivalent (or better) functionality here.
33 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT);
34 use base qw(Exporter);
38 $DEBUG = 0 unless defined $DEBUG;
41 %EXPORT_TAGS = (util => [qw(getbugcomponent getbuglocation getlocationpath get_hashname),
42 qw(appendfile overwritefile buglog getparsedaddrs getmaintainers),
44 qw(getmaintainers_reverse),
46 qw(package_maintainer),
49 misc => [qw(make_list globify_scalar english_join checkpid),
50 qw(cleanup_eval_fail),
53 date => [qw(secs_to_english)],
55 lock => [qw(filelock unfilelock lockpid)],
58 Exporter::export_ok_tags(keys %EXPORT_TAGS);
59 $EXPORT_TAGS{all} = [@EXPORT_OK];
62 #use Debbugs::Config qw(:globals);
67 use Debbugs::Config qw(:config);
70 use Debbugs::MIME qw(decode_rfc1522);
73 use Storable qw(dclone);
75 use Params::Validate qw(validate_with :types);
77 use Fcntl qw(:DEFAULT :flock);
78 use Encode qw(is_utf8 decode_utf8);
80 our $DEBUG_FH = \*STDERR if not defined $DEBUG_FH;
84 The following functions are exported by the C<:util> tag
86 =head2 getbugcomponent
88 my $file = getbugcomponent($bug_number,$extension,$location)
90 Returns the path to the bug file in location C<$location>, bug number
91 C<$bugnumber> and extension C<$extension>
96 my ($bugnum, $ext, $location) = @_;
98 if (not defined $location) {
99 $location = getbuglocation($bugnum, $ext);
100 # Default to non-archived bugs only for now; CGI scripts want
101 # archived bugs but most of the backend scripts don't. For now,
102 # anything that is prepared to accept archived bugs should call
103 # getbuglocation() directly first.
104 return undef if defined $location and
105 ($location ne 'db' and $location ne 'db-h');
107 my $dir = getlocationpath($location);
108 return undef if not defined $dir;
109 if (defined $location and $location eq 'db') {
110 return "$dir/$bugnum.$ext";
112 my $hash = get_hashname($bugnum);
113 return "$dir/$hash/$bugnum.$ext";
117 =head2 getbuglocation
119 getbuglocation($bug_number,$extension)
121 Returns the the location in which a particular bug exists; valid
122 locations returned currently are archive, db-h, or db. If the bug does
123 not exist, returns undef.
128 my ($bugnum, $ext) = @_;
129 my $archdir = get_hashname($bugnum);
130 return 'archive' if -r getlocationpath('archive')."/$archdir/$bugnum.$ext";
131 return 'db-h' if -r getlocationpath('db-h')."/$archdir/$bugnum.$ext";
132 return 'db' if -r getlocationpath('db')."/$bugnum.$ext";
137 =head2 getlocationpath
139 getlocationpath($location)
141 Returns the path to a specific location
145 sub getlocationpath {
147 if (defined $location and $location eq 'archive') {
148 return "$config{spool_dir}/archive";
149 } elsif (defined $location and $location eq 'db') {
150 return "$config{spool_dir}/db";
152 return "$config{spool_dir}/db-h";
161 Returns the hash of the bug which is the location within the archive
166 return "" if ( $_[ 0 ] < 0 );
167 return sprintf "%02d", $_[ 0 ] % 100;
174 Returns the path to the logfile corresponding to the bug.
176 Returns undef if the bug does not exist.
182 my $location = getbuglocation($bugnum, 'log');
183 return getbugcomponent($bugnum, 'log', $location) if ($location);
184 $location = getbuglocation($bugnum, 'log.gz');
185 return getbugcomponent($bugnum, 'log.gz', $location) if ($location);
194 Returns the path to the summary file corresponding to the bug.
196 Returns undef if the bug does not exist.
202 my $location = getbuglocation($bugnum, 'summary');
203 return getbugcomponent($bugnum, 'summary', $location) if ($location);
209 appendfile($file,'data','to','append');
211 Opens a file for appending and writes data to it.
216 my ($file,@data) = @_;
217 my $fh = IO::File->new($file,'a') or
218 die "Unable top open $file for appending: $!";
219 print {$fh} @data or die "Unable to write to $file: $!";
220 close $fh or die "Unable to close $file: $!";
225 ovewritefile($file,'data','to','append');
227 Opens file.new, writes data to it, then moves file.new to file.
232 my ($file,@data) = @_;
233 my $fh = IO::File->new("${file}.new",'w') or
234 die "Unable top open ${file}.new for writing: $!";
235 print {$fh} @data or die "Unable to write to ${file}.new: $!";
236 close $fh or die "Unable to close ${file}.new: $!";
237 rename("${file}.new",$file) or
238 die "Unable to rename ${file}.new to $file: $!";
245 =head2 getparsedaddrs
247 my $address = getparsedaddrs($address);
248 my @address = getparsedaddrs($address);
250 Returns the output from Mail::Address->parse, or the cached output if
251 this address has been parsed before. In SCALAR context returns the
252 first address parsed.
260 return () unless defined $addr;
261 return wantarray?@{$_parsedaddrs{$addr}}:$_parsedaddrs{$addr}[0]
262 if exists $_parsedaddrs{$addr};
264 # don't display the warnings from Mail::Address->parse
265 local $SIG{__WARN__} = sub { };
266 @{$_parsedaddrs{$addr}} = Mail::Address->parse($addr);
268 return wantarray?@{$_parsedaddrs{$addr}}:$_parsedaddrs{$addr}[0];
271 =head2 getmaintainers
273 my $maintainer = getmaintainers()->{debbugs}
275 Returns a hashref of package => maintainer pairs.
279 our $_maintainer = undef;
280 our $_maintainer_rev = undef;
282 return $_maintainer if defined $_maintainer;
283 package_maintainer(rehash => 1);
287 =head2 getmaintainers_reverse
289 my @packages = @{getmaintainers_reverse->{'don@debian.org'}||[]};
291 Returns a hashref of maintainer => [qw(list of packages)] pairs.
295 sub getmaintainers_reverse{
296 return $_maintainer_rev if defined $_maintainer_rev;
297 package_maintainer(rehash => 1);
298 return $_maintainer_rev;
301 =head2 package_maintainer
303 my @s = package_maintainer(source => [qw(foo bar baz)],
304 binary => [qw(bleh blah)],
309 =item source -- scalar or arrayref of source package names to return
310 maintainers for, defaults to the empty arrayref.
312 =item binary -- scalar or arrayref of binary package names to return
313 maintainers for; automatically returns source package maintainer if
314 the package name starts with 'src:', defaults to the empty arrayref.
316 =item reverse -- whether to return the source/binary packages a
317 maintainer maintains instead
319 =item rehash -- whether to reread the maintainer and source maintainer
326 our $_source_maintainer = undef;
327 our $_source_maintainer_rev = undef;
328 sub package_maintainer {
329 my %param = validate_with(params => \@_,
330 spec => {source => {type => SCALAR|ARRAYREF,
333 binary => {type => SCALAR|ARRAYREF,
336 maintainer => {type => SCALAR|ARRAYREF,
339 rehash => {type => BOOLEAN,
342 reverse => {type => BOOLEAN,
347 my @binary = make_list($param{binary});
348 my @source = make_list($param{source});
349 my @maintainers = make_list($param{maintainer});
350 if ((@binary or @source) and @maintainers) {
351 croak "It is nonsensical to pass both maintainers and source or binary";
353 if ($param{rehash}) {
354 $_source_maintainer = undef;
355 $_source_maintainer_rev = undef;
356 $_maintainer = undef;
357 $_maintainer_rev = undef;
359 if (not defined $_source_maintainer or
360 not defined $_source_maintainer_rev) {
361 $_source_maintainer = {};
362 $_source_maintainer_rev = {};
363 for my $fn (@config{('source_maintainer_file',
364 'source_maintainer_file_override',
365 'pseudo_maint_file')}) {
366 next unless defined $fn;
368 warn "Missing source maintainer file '$fn'";
371 __add_to_hash($fn,$_source_maintainer,
372 $_source_maintainer_rev);
375 if (not defined $_maintainer or
376 not defined $_maintainer_rev) {
378 $_maintainer_rev = {};
379 for my $fn (@config{('maintainer_file',
380 'maintainer_file_override',
381 'pseudo_maint_file')}) {
382 next unless defined $fn;
384 warn "Missing maintainer file '$fn'";
387 __add_to_hash($fn,$_maintainer,
392 for my $binary (@binary) {
393 if (not $param{reverse} and $binary =~ /^src:/) {
394 push @source,$binary;
397 push @return,grep {defined $_} make_list($_maintainer->{$binary});
399 for my $source (@source) {
400 $source =~ s/^src://;
401 push @return,grep {defined $_} make_list($_source_maintainer->{$source});
403 for my $maintainer (grep {defined $_} @maintainers) {
404 push @return,grep {defined $_}
405 make_list($_maintainer_rev->{$maintainer});
406 push @return,map {$_ !~ /^src:/?'src:'.$_:$_}
408 make_list($_source_maintainer_rev->{$maintainer});
413 #=head2 __add_to_hash
415 # __add_to_hash($file,$forward_hash,$reverse_hash,'address');
417 # Reads a maintainer/source maintainer/pseudo desc file and adds the
418 # maintainers from it to the forward and reverse hashref; assumes that
419 # the forward is unique; makes no assumptions of the reverse.
424 my ($fn,$forward,$reverse,$type) = @_;
425 if (ref($forward) ne 'HASH') {
426 croak "__add_to_hash must be passed a hashref for the forward";
428 if (defined $reverse and not ref($reverse) eq 'HASH') {
429 croak "if reverse is passed to __add_to_hash, it must be a hashref";
432 my $fh = IO::File->new($fn,'r') or
433 die "Unable to open $fn for reading: $!";
434 binmode($fh,':encoding(UTF-8)');
437 next unless m/^(\S+)\s+(\S.*\S)\s*$/;
438 my ($key,$value)=($1,$2);
440 $forward->{$key}= $value;
441 if (defined $reverse) {
442 if ($type eq 'address') {
443 for my $m (map {lc($_->address)} (getparsedaddrs($value))) {
444 push @{$reverse->{$m}},$key;
448 push @{$reverse->{$value}}, $key;
457 my $pseudopkgdesc = getpseudodesc(...);
459 Returns the entry for a pseudo package from the
460 $config{pseudo_desc_file}. In cases where pseudo_desc_file is not
461 defined, returns an empty arrayref.
463 This function can be used to see if a particular package is a
464 pseudopackage or not.
468 our $_pseudodesc = undef;
470 return $_pseudodesc if defined $_pseudodesc;
472 __add_to_hash($config{pseudo_desc_file},$_pseudodesc) if
473 defined $config{pseudo_desc_file};
479 sort_versions('1.0-2','1.1-2');
481 Sorts versions using AptPkg::Versions::compare if it is available, or
482 Debbugs::Versions::Dpkg::vercmp if it isn't.
488 use Debbugs::Versions::Dpkg;
489 $vercmp=\&Debbugs::Versions::Dpkg::vercmp;
491 # eventually we'll use AptPkg:::Version or similar, but the current
492 # implementation makes this *super* difficult.
495 # use AptPkg::Version;
496 # $vercmp=\&AptPkg::Version::compare;
501 return sort {$vercmp->($a,$b)} @_;
507 my $english = secs_to_english($seconds);
508 my ($days,$english) = secs_to_english($seconds);
510 XXX This should probably be changed to use Date::Calc
517 my $days = int($seconds / 86400);
518 my $years = int($days / 365);
522 push @age, "1 year" if ($years == 1);
523 push @age, "$years years" if ($years > 1);
524 push @age, "1 day" if ($days == 1);
525 push @age, "$days days" if ($days > 1);
526 $result .= join(" and ", @age);
528 return wantarray?(int($seconds/86400),$result):$result;
534 These functions are exported with the :lock tag
539 filelock($lockfile,$locks);
541 FLOCKs the passed file. Use unfilelock to unlock it.
543 Can be passed an optional $locks hashref, which is used to track which
544 files are locked (and how many times they have been locked) to allow
545 for cooperative locking.
554 # NB - NOT COMPATIBLE WITH `with-lock'
555 my ($lockfile,$locks) = @_;
556 if ($lockfile !~ m{^/}) {
557 $lockfile = cwd().'/'.$lockfile;
559 # This is only here to allow for relocking bugs inside of
560 # Debbugs::Control. Nothing else should be using it.
561 if (defined $locks and exists $locks->{locks}{$lockfile} and
562 $locks->{locks}{$lockfile} >= 1) {
563 if (exists $locks->{relockable} and
564 exists $locks->{relockable}{$lockfile}) {
565 $locks->{locks}{$lockfile}++;
566 # indicate that the bug for this lockfile needs to be reread
567 $locks->{relockable}{$lockfile} = 1;
568 push @{$locks->{lockorder}},$lockfile;
573 confess "Locking already locked file: $lockfile\n".Data::Dumper->Dump([$lockfile,$locks],[qw(lockfile locks)]);
577 $count= 10; $errors= '';
580 my $fh2 = IO::File->new($lockfile,'w')
581 or die "Unable to open $lockfile for writing: $!";
582 flock($fh2,LOCK_EX|LOCK_NB)
583 or die "Unable to lock $lockfile $!";
590 push @filelocks, {fh => $fh, file => $lockfile};
591 if (defined $locks) {
592 $locks->{locks}{$lockfile}++;
593 push @{$locks->{lockorder}},$lockfile;
600 croak "failed to get lock on $lockfile -- $errors".
601 (defined $locks?Data::Dumper->Dump([$locks],[qw(locks)]):'');
607 # clean up all outstanding locks at end time
620 Unlocks the file most recently locked.
622 Note that it is not currently possible to unlock a specific file
623 locked with filelock.
629 if (@filelocks == 0) {
630 carp "unfilelock called with no active filelocks!\n";
633 if (defined $locks and ref($locks) ne 'HASH') {
634 croak "hash not passsed to unfilelock";
636 if (defined $locks and exists $locks->{lockorder} and
637 @{$locks->{lockorder}} and
638 exists $locks->{locks}{$locks->{lockorder}[-1]}) {
639 my $lockfile = pop @{$locks->{lockorder}};
640 $locks->{locks}{$lockfile}--;
641 if ($locks->{locks}{$lockfile} > 0) {
644 delete $locks->{locks}{$lockfile};
646 my %fl = %{pop(@filelocks)};
647 flock($fl{fh},LOCK_UN)
648 or warn "Unable to unlock lockfile $fl{file}: $!";
650 or warn "Unable to close lockfile $fl{file}: $!";
652 or warn "Unable to unlink lockfile $fl{file}: $!";
658 lockpid('/path/to/pidfile');
660 Creates a pidfile '/path/to/pidfile' if one doesn't exist or if the
661 pid in the file does not respond to kill 0.
663 Returns 1 on success, false on failure; dies on unusual errors.
670 my $pid = checkpid($pidfile);
671 die "Unable to read pidfile $pidfile: $!" if not defined $pid;
672 return 0 if $pid != 0;
674 die "Unable to unlink stale pidfile $pidfile $!";
676 my $pidfh = IO::File->new($pidfile,O_CREAT|O_EXCL|O_WRONLY) or
677 die "Unable to open $pidfile for writing: $!";
678 print {$pidfh} $$ or die "Unable to write to $pidfile $!";
679 close $pidfh or die "Unable to close $pidfile $!";
685 checkpid('/path/to/pidfile');
687 Checks a pid file and determines if the process listed in the pidfile
688 is still running. Returns the pid if it is, 0 if it isn't running, and
689 undef if the pidfile doesn't exist or cannot be read.
696 my $pidfh = IO::File->new($pidfile, 'r') or
701 ($pid) = $pid =~ /(\d+)/;
702 if (defined $pid and kill(0,$pid)) {
715 These functions are exported with the :quit tag.
721 Exits the program by calling die.
723 Usage of quit is deprecated; just call die instead.
728 print {$DEBUG_FH} "quitting >$_[0]<\n" if $DEBUG;
729 carp "quit() is deprecated; call die directly instead";
735 These functions are exported with the :misc tag
739 LIST = make_list(@_);
741 Turns a scalar or an arrayref into a list; expands a list of arrayrefs
744 That is, make_list([qw(a b c)]); returns qw(a b c); make_list([qw(a
745 b)],[qw(c d)] returns qw(a b c d);
750 return map {(ref($_) eq 'ARRAY')?@{$_}:$_} @_;
756 print english_join(list => \@list);
757 print english_join(\@list);
759 Joins list properly to make an english phrase.
763 =item normal -- how to separate most values; defaults to ', '
765 =item last -- how to separate the last two values; defaults to ', and '
767 =item only_two -- how to separate only two values; defaults to ' and '
769 =item list -- ARRAYREF values to join; if the first argument is an
770 ARRAYREF, it's assumed to be the list of values to join
774 In cases where C<list> is empty, returns ''; when there is only one
775 element, returns that element.
780 if (ref $_[0] eq 'ARRAY') {
781 return english_join(list=>$_[0]);
783 my %param = validate_with(params => \@_,
784 spec => {normal => {type => SCALAR,
787 last => {type => SCALAR,
790 only_two => {type => SCALAR,
793 list => {type => ARRAYREF,
797 my @list = @{$param{list}};
799 return @list?$list[0]:'';
802 return join($param{only_two},@list);
804 my $ret = $param{last} . pop(@list);
805 return join($param{normal},@list) . $ret;
809 =head2 globify_scalar
811 my $handle = globify_scalar(\$foo);
813 if $foo isn't already a glob or a globref, turn it into one using
814 IO::Scalar. Gives a new handle to /dev/null if $foo isn't defined.
816 Will carp if given a scalar which isn't a scalarref or a glob (or
817 globref), and return /dev/null. May return undef if IO::Scalar or
818 IO::File fails. (Check $!)
820 The scalar will fill with octets, not perl's internal encoding, so you
821 must use decode_utf8() after on the scalar, and encode_utf8() on it
822 before. This appears to be a bug in the underlying modules.
829 if (defined $scalar) {
830 if (defined ref($scalar)) {
831 if (ref($scalar) eq 'SCALAR' and
832 not UNIVERSAL::isa($scalar,'GLOB')) {
833 if (is_utf8(${$scalar})) {
834 ${$scalar} = decode_utf8(${$scalar});
835 carp(q(\$scalar must not be in perl's internal encoding));
837 open $handle, '>:scalar:utf8', $scalar;
844 elsif (UNIVERSAL::isa(\$scalar,'GLOB')) {
848 carp "Given a non-scalar reference, non-glob to globify_scalar; returning /dev/null handle";
851 return IO::File->new('/dev/null','>:encoding(UTF-8)');
854 =head2 cleanup_eval_fail()
856 print "Something failed with: ".cleanup_eval_fail($@);
858 Does various bits of cleanup on the failure message from an eval (or
859 any other die message)
861 Takes at most two options; the first is the actual failure message
862 (usually $@ and defaults to $@), the second is the debug level
863 (defaults to $DEBUG).
865 If debug is non-zero, the code at which the failure occured is output.
869 sub cleanup_eval_fail {
870 my ($error,$debug) = @_;
871 if (not defined $error or not @_) {
872 $error = $@ // 'unknown reason';
875 $debug = $DEBUG // 0;
877 $debug = 0 if not defined $debug;
882 # ditch the "at foo/bar/baz.pm line 5"
883 $error =~ s/\sat\s\S+\sline\s\d+//;
884 # ditch croak messages
885 $error =~ s/^\t+.+\n?//g;
886 # ditch trailing multiple periods in case there was a cascade of
888 $error =~ s/\.+$/\./;
894 hash_slice(%hash,qw(key1 key2 key3))
896 For each key, returns matching values and keys of the hash if they exist
901 # NB: We use prototypes here SPECIFICALLY so that we can be passed a
902 # hash without uselessly making a reference to first. DO NOT USE
903 # PROTOTYPES USELESSLY ELSEWHERE.
904 sub hash_slice(\%@) {
905 my ($hashref,@keys) = @_;
906 return map {exists $hashref->{$_}?($_,$hashref->{$_}):()} @keys;