stepmake/aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4 AC_DEFUN(AC_STEPMAKE_COMPILE, [
   5     # -O is necessary to get inlining
   6     OPTIMIZE=""
   7     CXXFLAGS=${CXXFLAGS:-""}
   8     CFLAGS=${CFLAGS:-""}
   9     checking_b=yes
  10     optimise_b=no
  11     profile_b=no
  12     debug_b=yes
  13
  14     AC_ARG_ENABLE(checking,
  15     [  enable-checking         set runtime checks (assert calls). Default: on],
  16     [checking_b=$enableval] )
  17
  18     # actually, the default is: tja='-O' to get inlining...
  19     # off=''  --jcn
  20
  21     #actually, that sucks.
  22     #  tja looks like a typo.  Default is optimisation off. --hwn
  23
  24     AC_ARG_ENABLE(optimise,
  25     [  enable-optimise         use maximal speed optimisations. Default: off],
  26     [optimise_b=$enableval])
  27
  28     AC_ARG_ENABLE(profiling,
  29     [  enable-profiling        compile with gprof support. Default: off],
  30     [profile_b=$enableval])
  31
  32     AC_ARG_ENABLE(debugging,
  33     [  enable-debugging        set debug info. Default: on],
  34     [debug_b=$enableval])
  35
  36     AC_ARG_ENABLE(mingw-prefix,
  37     [  enable-mingw-prefix=DIR set the mingw32 directory (standalone windows32 exes)],
  38     [MINGWPREFIX=$enableval],
  39     [MINGWPREFIX=no])
  40
  41     if test "$printing_b" = no; then
  42         # ugh
  43         AC_DEFINE(NPRINT)
  44         DEFINES="$DEFINES -DNPRINT"
  45     fi
  46
  47     if test "$checking_b" = no; then
  48         # ugh
  49         AC_DEFINE(NDEBUG)
  50         DEFINES="$DEFINES -DNDEBUG"
  51     fi
  52
  53     if test "$optimise_b" = yes; then
  54         OPTIMIZE="-O2 -finline-functions"
  55     fi
  56
  57     if test "$optimise_b" = no; then
  58         OPTIMIZE=""
  59     fi
  60
  61     if test $profile_b = yes; then
  62         EXTRA_LIBES="-pg"
  63         OPTIMIZE="$OPTIMIZE -pg"
  64     fi
  65
  66     if test $debug_b = yes; then
  67         OPTIMIZE="$OPTIMIZE -g"
  68     fi
  69
  70     # however, C++ support in mingw32 v 0.1.4 is still flaky
  71     if test x$MINGWPREFIX != xno; then
  72         ICFLAGS="-I$MINGWPREFIX/include"
  73         ILDFLAGS="-$MINGWPREFIX/lib"
  74     fi
  75
  76     AC_PROG_CC
  77     LD='$(CC)'
  78     AC_SUBST(LD)
  79
  80     CPPFLAGS=${CPPFLAGS:-""}
  81     AC_SUBST(CPPFLAGS)
  82     AC_SUBST(LDFLAGS)
  83     AC_SUBST(ICFLAGS)
  84     AC_SUBST(ILDFLAGS)
  85     AC_SUBST(DEFINES)
  86     AC_SUBST(EXTRA_LIBES)
  87 ])
  88
  89 AC_DEFUN(AC_STEPMAKE_CXX, [
  90     AC_LANG_CPLUSPLUS
  91     AC_PROG_CXX
  92
  93     AC_CHECK_HEADER(FlexLexer.h, true,
  94         AC_STEPMAKE_WARN(can"\'"t find flex header. Please install Flex headers correctly))
  95
  96     CPPFLAGS="$CPPFLAGS $DEFINES"
  97     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
  98     LDFLAGS=$EXTRA_LIBES
  99
 100     AC_SUBST(CXXFLAGS)
 101     AC_SUBST(CXX)
 102     LD='$(CXX)'
 103     AC_SUBST(LD)
 104 ])
 105
 106 AC_DEFUN(AC_STEPMAKE_CXXTEMPLATE, [
 107     AC_CACHE_CHECK([whether explicit instantiation is needed],
 108         lily_cv_need_explicit_instantiation,
 109         AC_TRY_LINK([
 110     template <class T> struct foo { static int baz; };
 111     template <class T> int foo<T>::baz = 1;
 112     ], [ return foo<int>::baz; ],
 113             lily_cv_need_explicit_instantiation=no,
 114             lily_cv_need_explicit_instantiation=yes))
 115     if test x"$lily_cv_need_explicit_instantiation"x = x"yes"x; then
 116         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 117     fi
 118 ])
 119
 120 AC_DEFUN(AC_STEPMAKE_DATADIR, [
 121     if test "$datadir" = "\${prefix}/share"; then
 122             datadir='${prefix}/share/'$package
 123     fi
 124     DIR_DATADIR=${datadir}
 125     presome=${prefix}
 126     if test "$prefix" = "NONE"; then
 127             presome=${ac_default_prefix}
 128     fi
 129     DIR_DATADIR=`echo ${DIR_DATADIR} | sed "s!\\\${prefix}!$presome!"`
 130     AC_SUBST(datadir)
 131     AC_SUBST(DIR_DATADIR)
 132     AC_DEFINE_UNQUOTED(DIR_DATADIR, "${DIR_DATADIR}")
 133 ])
 134
 135 AC_DEFUN(AC_STEPMAKE_END, [
 136     AC_OUTPUT($CONFIGFILE.make:config.make.in)
 137
 138     rm -f GNUmakefile
 139     cp make/toplevel.make.in ./GNUmakefile
 140     chmod 444 GNUmakefile
 141 ])
 142
 143 AC_DEFUN(AC_STEPMAKE_GXX, [
 144     # ugh autoconf
 145     changequote(<<, >>)dnl
 146     if $CXX --version | grep '2\.[78]' > /dev/null ||
 147         $CXX --version | grep 'egcs' > /dev/null
 148     changequote([, ])dnl
 149     then
 150             true
 151     else
 152             AC_STEPMAKE_WARN(can\'t find g++ 2.7, 2.8 or egcs)
 153     fi
 154 ])
 155
 156 AC_DEFUN(AC_STEPMAKE_GUILE, [
 157     # on some systems, -lguile succeeds for guile-1.3
 158     # others need readline, dl (or even more)
 159     # urg, must check for different functions in libguile
 160     # to force new check iso reading from cache
 161     AC_CHECK_LIB(guile, scm_shell, \
 162       LIBS="-lguile $LIBS"; AC_DEFINE(HAVE_LIBGUILE), \
 163       AC_CHECK_LIB(readline, readline) \
 164       AC_CHECK_LIB(dl, dlopen) \
 165       AC_CHECK_LIB(socket, socket)\
 166       AC_CHECK_LIB(termcap,tgetent)\
 167       AC_CHECK_LIB(m, fabs)\
 168       AC_CHECK_LIB(guile, scm_boot_guile)\
 169     )
 170     if test "$ac_cv_lib_guile_scm_shell" != yes -a \
 171       "$ac_cv_lib_guile_scm_boot_guile" != yes ; then
 172             AC_STEPMAKE_WARN(You should install guile 1.3 or newer)
 173     fi
 174 ])
 175
 176 AC_DEFUN(AC_STEPMAKE_INIT, [
 177
 178     . $srcdir/VERSION
 179     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 180     if test x$MY_PATCH_LEVEL != x; then
 181         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 182     fi
 183
 184     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 185     changequote(<<, >>)dnl
 186     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 187     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 188     changequote([, ])dnl
 189
 190     # No versioning on directory names of sub-packages
 191     # urg, urg
 192     stepmake=${datadir}/stepmake
 193     presome=${prefix}
 194     if test "$prefix" = "NONE"; then
 195             presome=${ac_default_prefix}
 196     fi
 197     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 198
 199     if test "x$PACKAGE" = "xSTEPMAKE"; then
 200         echo Stepmake package!
 201         (cd stepmake; rm -f stepmake; ln -s ../stepmake .)
 202         (cd stepmake; rm -f bin; ln -s ../bin .)
 203         AC_CONFIG_AUX_DIR(bin)
 204         stepmake=stepmake
 205     else
 206         echo Package: $PACKAGE
 207         # Check for installed stepmake
 208         if test -d $stepmake; then
 209             echo Using installed stepmake: $stepmake
 210         else
 211             stepmake='$(depth)'/stepmake
 212             echo Using local stepmake: $datadir/stepmake not found
 213         fi
 214         AC_CONFIG_AUX_DIR(\
 215           $HOME/usr/local/share/stepmake/bin\
 216           $HOME/usr/local/lib/stepmake/bin\
 217           $HOME/usr/share/stepmake/bin\
 218           $HOME/usr/lib/stepmake/bin\
 219           /usr/local/share/stepmake/bin\
 220           /usr/local/lib/stepmake/bin\
 221           /usr/share/stepmake/bin\
 222           /usr/lib/stepmake/bin\
 223           stepmake/bin\
 224         )
 225     fi
 226
 227     AC_SUBST(stepmake)
 228     AC_SUBST(package)
 229     AC_SUBST(PACKAGE)
 230     AC_SUBST(PACKAGE_NAME)
 231     AC_DEFINE_UNQUOTED(PACKAGE, "${PACKAGE_NAME}")
 232     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, "${FULL_VERSION}")
 233
 234     package_depth=`dirname $cache_file`
 235     AC_SUBST(package_depth)
 236
 237     AUTOGENERATE="This file was automatically generated by configure"
 238     AC_SUBST(AUTOGENERATE)
 239     absolute_builddir="`pwd`"
 240     AC_SUBST(absolute_builddir)
 241
 242     STATE_VECTOR=`ls make/STATE-VECTOR 2>/dev/null`
 243     if test "x$STATE_VECTOR" != "x"; then
 244         STATE_VECTOR="\$(depth)/$STATE_VECTOR"
 245     fi
 246     AC_SUBST(STATE_VECTOR)
 247
 248     CONFIGSUFFIX=
 249     AC_ARG_ENABLE(config,
 250     [  enable-config=FILE      put configure settings in config-FILE.make],
 251     [CONFIGSUFFIX=$enableval])
 252
 253     if test "$CONFIGSUFFIX" != "" ; then
 254         CONFIGFILE=config-$CONFIGSUFFIX
 255     else
 256         CONFIGFILE=config
 257     fi
 258     AC_SUBST(CONFIGSUFFIX)
 259
 260     AC_CANONICAL_HOST
 261     AC_CHECK_PROGS(MAKE, make, error)
 262     AC_CHECK_PROGS(FIND, find, error)
 263
 264
 265 dnl system supplied INSTALL is unsafe; use our own install.
 266 dnl    AC_PROG_INSTALL
 267 dnl    if test "$INSTALL" = "bin/install-sh"; then
 268 dnl     export INSTALL="\$\(depth\)/bin/install-sh"
 269 dnl    fi
 270
 271     AC_CHECK_PROGS(TAR, tar, error)
 272     AC_CHECK_PROGS(BASH, bash, /bin/sh)
 273
 274     AC_PATH_PROG(PYTHON, ${PYTHON:-python}, -echo no python)
 275     AC_SUBST(PYTHON)
 276
 277
 278     AC_CHECK_SEARCH_RESULT($MAKE, GNU make,  You should install GNU make)
 279     if test $MAKE != "error" ; then
 280         $MAKE -v| grep GNU > /dev/null
 281         if test "$?" = 1
 282         then
 283                 AC_STEPMAKE_WARN(Please install *GNU* make)
 284         fi
 285     fi
 286
 287     AC_CHECK_SEARCH_RESULT($PYTHON, python, You should install Python)
 288
 289     if test "x$OSTYPE" = "xcygwin32" || test "x$OSTYPE" = "xWindows_NT"; then
 290         LN=cp # hard link does not work under cygnus-nt
 291         LN_S=cp # symbolic link does not work for native nt
 292         ZIP="zip -r -9" #
 293         DOTEXE=.exe
 294        DIRSEP='\\'
 295         PATHSEP=';'
 296        INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
 297     else
 298         DIRSEP='/'
 299         PATHSEP=':'
 300         LN=ln
 301         LN_S='ln -s'
 302         ZIP="zip -r -9"
 303         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-sh -c"
 304     fi
 305     AC_SUBST(DOTEXE)
 306     AC_SUBST(ZIP)
 307     AC_SUBST(LN)
 308     AC_SUBST(LN_S)
 309     AC_SUBST(INSTALL)
 310     AC_DEFINE_UNQUOTED(DIRSEP, '${DIRSEP}')
 311     AC_DEFINE_UNQUOTED(PATHSEP, '${PATHSEP}')
 312     AC_SUBST(PATHSEP)
 313     AC_SUBST(DIRSEP)
 314
 315
 316     AC_STEPMAKE_DATADIR
 317 ])
 318
 319 AC_DEFUN(AC_STEPMAKE_LEXYACC, [
 320     # ugh, automake: we want (and check for) bison
 321     AC_PROG_YACC
 322     # ugh, automake: we want (and check for) flex
 323     # AC_PROG_LEX
 324     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 325
 326     # AC_DECL_YYTEXT
 327     # ugh, ugh
 328     ac_cv_prog_lex_root=lex.yy
 329
 330     AC_CHECK_PROGS(BISON, bison, error)
 331     AC_CHECK_PROGS(FLEX, flex, error)
 332     AC_CHECK_SEARCH_RESULT($BISON, bison,  Please install Bison, 1.25 or newer)
 333     AC_CHECK_SEARCH_RESULT($FLEX,  flex, Please install Flex, 2.5 or newer)
 334
 335     if test $BISON != "error"; then
 336         bison_version=`$BISON --version| sed 's/^.*version 1.//g' `
 337         if test $bison_version -lt 25; then
 338             AC_STEPMAKE_WARN(Your bison is a bit old (1.$bison_version). You might have to install 1.25)
 339         fi
 340     fi
 341
 342     AC_SUBST(BISON)
 343     AC_SUBST(FLEX)
 344 ])
 345
 346 AC_DEFUN(AC_STEPMAKE_LIB, [
 347     AC_CHECK_PROGS(AR, ar, error)
 348     AC_PROG_RANLIB
 349
 350     AC_SUBST(AR)
 351     AC_SUBST(RANLIB)
 352 ])
 353
 354 AC_DEFUN(AC_STEPMAKE_LIBTOOL, [
 355     # libtool.info ...
 356     # **Never** try to set library version numbers so that they correspond
 357     # to the release number of your package.  This is an abuse that only
 358     # fosters misunderstanding of the purpose of library versions.
 359
 360     REVISION=$PATCH_LEVEL
 361     # CURRENT=$MINOR_VERSION
 362     CURRENT=`expr $MINOR_VERSION + 1`
 363     # AGE=$(expr $MAJOR_VERSION + 1)
 364     AGE=$MAJOR_VERSION
 365     AC_SUBST(CURRENT)
 366     AC_SUBST(REVISION)
 367     AC_SUBST(AGE)
 368 ])
 369
 370 AC_DEFUN(AC_STEPMAKE_LOCALE, [
 371     lang=English
 372     ALL_LINGUAS="en nl"
 373
 374     # with/enable ??
 375     AC_ARG_WITH(localedir,
 376     [  with-localedir=LOCALE   use LOCALE as locale dir. Default: PREFIX/share/locale ],
 377     localedir=$with_localedir,
 378     localedir='${prefix}/share/locale')
 379
 380     AC_ARG_WITH(lang,
 381     [  with-lang=LANG          use LANG as language to emit messages],
 382     language=$with_lang,
 383     language=English)
 384
 385     AC_MSG_CHECKING(language)
 386     case "$language" in
 387       En* | en* | Am* | am* | US* | us*)
 388             lang=English;;
 389       NL | nl | Du* | du* | Ned* | ned*)
 390             lang=Dutch;;
 391       "")
 392             lang=English;;
 393       *)
 394             lang=unknown;;
 395     esac
 396     AC_MSG_RESULT($lang)
 397
 398     if test "$lang" = "unknown" ; then
 399         AC_STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 400     fi
 401
 402 ])
 403
 404 AC_DEFUN(AC_STEPMAKE_GETTEXT, [
 405     DIR_LOCALEDIR=${localedir}
 406     presome=${prefix}
 407     if test "$prefix" = "NONE"; then
 408             presome=${ac_default_prefix}
 409     fi
 410     DIR_LOCALEDIR=`echo ${DIR_LOCALEDIR} | sed "s!\\\${prefix}!$presome!"`
 411     AC_SUBST(localedir)
 412     AC_SUBST(DIR_LOCALEDIR)
 413     AC_DEFINE_UNQUOTED(DIR_LOCALEDIR, "${DIR_LOCALEDIR}")
 414
 415     AC_CHECK_LIB(intl, gettext)
 416     AC_CHECK_FUNCS(gettext)
 417 ])
 418
 419 AC_DEFUN(AC_STEPMAKE_MAN, [
 420     AC_CHECK_PROGS(TROFF, troff, -echo no troff)
 421 ])
 422
 423 AC_DEFUN(AC_STEPMAKE_MSGFMT, [
 424     # AC_CHECK_PROGS(MSGFMT, msgfmt, -echo no msgfmt)
 425     AC_CHECK_PROGS(MSGFMT, msgfmt, \$(SHELL) \$(step-bindir)/fake-msgfmt.sh )
 426     AC_MSG_CHECKING(whether msgfmt accepts -o)
 427     msgfmt_output="`msgfmt -o bla 2>&1 | grep usage`"
 428     if test "$msgfmt_output" = ""; then
 429         AC_MSG_RESULT(yes)
 430     else
 431         # urg
 432         MSGFMT="\$(SHELL) \$(step-bindir)/fake-msgfmt.sh"
 433         AC_MSG_RESULT(no)
 434         AC_STEPMAKE_WARN(please install msgfmt from GNU gettext)
 435     fi
 436     if test ! -n "$MSGFMT"; then
 437         AC_STEPMAKE_WARN(please install msgfmt from GNU gettext)
 438     fi
 439 ])
 440
 441 AC_DEFUN(AC_STEPMAKE_TEXMF_DIRS, [
 442     AC_ARG_ENABLE(tex-prefix,
 443     [  enable-tex-prefix=DIR   set the tex-directory to find TeX subdirectories. (default: PREFIX)],
 444     [TEXPREFIX=$enableval],
 445     [TEXPREFIX=auto] )
 446
 447     AC_ARG_ENABLE(tex-dir,
 448     [  enable-tex-dir=DIR      set the directory to put $PACKAGE_NAME TeX files in. ],
 449     [TEXDIR=$enableval],
 450     [TEXDIR=auto] )
 451
 452     AC_ARG_ENABLE(mf-dir,
 453     [  enable-mf-dir=DIR       set the directory to put $PACKAGE_NAME MetaFont files in. ],
 454     [MFDIR=$enableval],
 455     [MFDIR=auto])
 456
 457     if test "x$TEXPREFIX" = xauto ; then
 458         AC_TEX_PREFIX(TEXPREFIX)
 459     else
 460      find_texprefix=$TEXPREFIX
 461     fi
 462
 463     if test "x$MFDIR" = xauto; then
 464         AC_MF_SUBDIR(MFDIR)
 465     fi
 466
 467     if test "x$TEXDIR" = xauto ; then
 468         AC_TEX_SUBDIR(TEXDIR)
 469     fi
 470     AC_SUBST(TEXPREFIX)
 471     AC_SUBST(TEXDIR)
 472     AC_SUBST(MFDIR)
 473 ])
 474
 475 AC_DEFUN(AC_STEPMAKE_TEXMF, [
 476     # urg, never know what names these teTeX guys will think up
 477     AC_CHECK_PROGS(METAFONT, mf, no)
 478     if test "x$METAFONT" = "xno"; then
 479         AC_CHECK_PROGS(MFONT, mfont, -echo no mf or mfont)
 480         METAFONT=$MFONT
 481     fi
 482
 483     AC_CHECK_PROGS(METAPOST, mp, no)
 484     if test "x$METAPOST" = "xno"; then
 485         AC_CHECK_PROGS(MPOST, mpost, -echo no mp or mpost)
 486         METAPOST=$MPOST
 487     fi
 488
 489     AC_SUBST(METAFONT)
 490     AC_SUBST(METAPOST)
 491 ])
 492
 493 AC_DEFUN(AC_STEPMAKE_WARN, [
 494     AC_MSG_WARN($1)
 495     warn_b=yes
 496 ])
 497
 498 AC_DEFUN(AC_STEPMAKE_YODL, [
 499     if test "x$YODL" = "x"; then
 500         AC_CHECK_PROGS(STRIPROFF, striproff, -echo no striproff)
 501         AC_CHECK_PROGS(YODL, yodl, -echo no yodl)
 502         AC_CHECK_PROGS(YODL2HTML, yodl2html, -echo no yodl)
 503         AC_CHECK_PROGS(YODL2LATEX, yodl2latex, )
 504         AC_CHECK_PROGS(YODL2MAN, yodl2man, -echo no yodl)
 505         AC_CHECK_PROGS(YODL2MSLESS, yodl2msless, -echo no yodl)
 506         AC_CHECK_PROGS(YODL2TEXINFO, yodl2texinfo, -echo no yodl)
 507         AC_CHECK_PROGS(YODL2TXT, yodl2txt, -echo no yodl)
 508         YODL2LESS_DIR='$(bindir)/'
 509     else
 510         AC_SUBST(STRIPROFF)
 511         AC_SUBST(YODL)
 512         AC_SUBST(YODL2HTML)
 513         AC_SUBST(YODL2LATEX)
 514         AC_SUBST(YODL2LESS_DIR)
 515         AC_SUBST(YODL2MAN)
 516         AC_SUBST(YODL2MSLESS)
 517         AC_SUBST(YODL2TEXINFO)
 518         AC_SUBST(YODL2TXT)
 519         export STRIPROFF YODL YODL2HTML YODL2LATEX YODL2MAN YODL2MSLESS YODL2TEXINFO YODL2TXT
 520     fi
 521     if test "x$YODL" = "-echo no yodl"; then
 522         AC_STEPMAKE_WARN(Did not find YODL (Yodl is Yet Oneother Document Language, see http://www.cs.uu.nl/~hanwen/yodl))
 523     fi
 524 ])
 525
 526 dnl should cache result.
 527 dnl should  look in $prefix first.
 528 dnl should probably assume TDS
 529
 530 AC_DEFUN(AC_TEX_PREFIX, [
 531
 532
 533     AC_MSG_CHECKING(TeX/MF root dir directory)
 534
 535     find_root_prefix="$prefix"
 536
 537
 538     test "x$find_root_prefix" = xNONE && find_root_prefix="$ac_default_prefix"
 539     find_texpostfix="";
 540     for postfix in "/lib/tex/" "/lib/texmf" "/lib" "/tex" "/texmf"; do
 541         find_texprefix="$find_root_prefix$postfix"
 542         if test -d $find_texprefix; then
 543             find_texpostfix=$postfix
 544             break;
 545         fi
 546     done
 547
 548     if test "x$find_texpostfix" = x; then
 549         find_texpostfix='/lib/texmf/tex'
 550         AC_STEPMAKE_WARN(Cannot determine the TeX-directory. Please use --enable-tex-prefix)
 551     fi
 552
 553     find_texprefix="$find_root_prefix/$find_texpostfix"
 554
 555     # only assign if variablename not empty
 556     if test x != "x[$]$1"; then
 557         $1='${prefix}'/"$find_texpostfix"
 558     fi
 559     AC_MSG_RESULT($find_texprefix)
 560
 561 ])
 562
 563
 564 # find a directory inside a prefix,
 565 # $1 the prefix (expanded version)
 566 # $2 variable to assign
 567 # $3 the directory name
 568 # $4 description
 569 AC_DEFUN(AC_FIND_DIR_IN_PREFIX, [
 570
 571     AC_MSG_CHECKING($4 directory)
 572     find_dirdir=`(cd $1;
 573       $FIND ./ -type d -a -name $3 -print |sort|head -1|sed 's#^\./##')`
 574
 575
 576     if test "x$find_dirdir" = x; then
 577        find_dirdir="/$3";
 578        AC_STEPMAKE_WARN(Cannot determine $4 subdirectory. Please set from command-line)
 579         true
 580     fi
 581     $2=$find_dirdir
 582     AC_MSG_RESULT($1/$find_dirdir)
 583 ])
 584
 585 # ugh.  this is hopeless
 586 AC_DEFUN(AC_KPSE_TEX_DIR, [
 587         kpse_paths=`(kpsepath -n latex tex; kpsepath -n tex tex) | sed 's/:/ /g' | tr ' ' '\012' |sort | uniq -d`
 588         kpse_syspaths=`echo $kpse_paths | grep '!'| sed 's/!//g'`
 589         echo $kpse_paths
 590         if test -w "$kpse_syspaths";
 591         then
 592                 dir=`echo $kpse_syspaths | head -1`
 593         else
 594                 dir=`echo $kpse_paths | grep -v '!'| head -1`
 595         fi
 596         if test "$prefix" = "NONE"; then
 597                 local_prefix=$ac_default_prefix
 598                 local_prefix_quote='${prefix}'
 599
 600         else
 601                 local_prefix=$prefix
 602                 local_prefix_quote=$prefix
 603         fi
 604         echo $local_prefix_quote = $local_prefix
 605         echo $dir
 606         echo $dir  | sed 's!'$local_prefix'!\$local_prefix_quote!g'
 607 ])
 608
 609 AC_DEFUN(AC_TEX_SUBDIR, [
 610 dnl    AC_REQUIRE([AC_TEX_PREFIX])
 611     AC_FIND_DIR_IN_PREFIX($find_texprefix, $1, tex,TeX input)
 612     $1="$TEXPREFIX/$$1"
 613 ])
 614
 615 AC_DEFUN(AC_MF_SUBDIR, [
 616 dnl     AC_REQUIRE([AC_TEX_PREFIX])
 617     AC_FIND_DIR_IN_PREFIX($find_texprefix, $1, source, MF input)
 618     $1="$TEXPREFIX/$$1"
 619 ])
 620
 621 AC_DEFUN(AC_CHECK_SEARCH_RESULT, [
 622         result="`echo \"$1\" | grep echo`"
 623         if test "x$1" = "xerror" -o "x$result" != "x"; then
 624                 AC_STEPMAKE_WARN(can\'t find $2. $3)
 625         fi
 626 ])
 627
 628
 629 # Configure paths for GTK+
 630 # Owen Taylor     97-11-3
 631
 632 dnl AM_PATH_GTK([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 633 dnl Test for GTK, and define GTK_CFLAGS and GTK_LIBS
 634 dnl
 635 AC_DEFUN(AM_PATH_GTK,
 636 [dnl
 637 dnl Get the cflags and libraries from the gtk-config script
 638 dnl
 639   AC_PATH_PROG(GTK_CONFIG, gtk-config, no)
 640   min_gtk_version=ifelse([$1], ,1.1.1,$1)
 641   AC_MSG_CHECKING(for GTK - version >= $min_gtk_version)
 642   no_gtk=""
 643   if test "$GTK_CONFIG" != "no" ; then
 644     GTK_CFLAGS=`$GTK_CONFIG --cflags`
 645     GTK_LIBS=`$GTK_CONFIG --libs`
 646     ac_save_CFLAGS="$CFLAGS"
 647     ac_save_LIBS="$LIBS"
 648     ac_save_CXXFLAGS="$CXXFLAGS"
 649     CFLAGS="$CFLAGS $GTK_CFLAGS"
 650     CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
 651     LIBS="$LIBS $GTK_LIBS"
 652 dnl
 653 dnl Now check if the installed GTK is sufficiently new. (Also sanity
 654 dnl checks the results of gtk-config to some extent
 655 dnl
 656     AC_TRY_RUN([
 657 #include <gtk/gtk.h>
 658 #include <stdio.h>
 659
 660 int
 661 main ()
 662 {
 663   int major, minor, micro;
 664
 665   if (sscanf("$min_gtk_version", "%d.%d.%d", &major, &minor, &micro) != 3) {
 666      printf("%s, bad version string\n", "$min_gtk_version");
 667      exit(1);
 668    }
 669
 670    return !((gtk_major_version > major) ||
 671             ((gtk_major_version == major) && (gtk_minor_version > minor)) ||
 672             ((gtk_major_version == major) && (gtk_minor_version == minor) && (gtk_micro_version >= micro)));
 673 }
 674 ],, no_gtk=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 675      CFLAGS="$ac_save_CFLAGS"
 676      CXXFLAGS="$ac_save_CXXFLAGS"
 677      LIBS="$ac_save_LIBS"
 678   else
 679      no_gtk=yes
 680   fi
 681   if test "x$no_gtk" = x ; then
 682      AC_MSG_RESULT(yes)
 683      ifelse([$2], , :, [$2])
 684   else
 685      AC_MSG_RESULT(no)
 686      GTK_CFLAGS=""
 687      GTK_LIBS=""
 688      ifelse([$3], , :, [$3])
 689   fi
 690   CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
 691   AC_SUBST(CXXFLAGS)
 692   AC_SUBST(GTK_CFLAGS)
 693   AC_SUBST(GTK_LIBS)
 694 ])
 695
 696
 697 # Configure paths for GTK--
 698 # Erik Andersen 30 May 1998
 699 # Modified by Tero Pulkkinen (added the compiler checks... I hope they work..)
 700
 701 dnl Test for GTK__, and define GTK___CFLAGS and GTK___LIBS
 702 dnl   to be used as follows:
 703 dnl AM_PATH_GTKMM([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 704 dnl
 705
 706 dnl Get the cflags and libraries from the gtkmm-config script
 707 dnl
 708 AC_ARG_WITH(gtkmm-prefix,[  --with-gtkmm-prefix=PREFIX
 709                           Prefix where GTK-- is installed (optional)],
 710             gtkmm_config_prefix="$withval", gtkmm_config_prefix="")
 711 AC_ARG_WITH(gtkmm-exec-prefix,[  --with-gtkmm-exec-prefix=PREFIX
 712                           Exec prefix where GTK-- is installed (optional)],
 713             gtkmm_config_exec_prefix="$withval", gtkmm_config_exec_prefix="")
 714 AC_ARG_ENABLE(gtkmmtest, [  --disable-gtkmmtest     Do not try to compile and run a test GTK-- program],
 715                     , enable_gtkmmtest=yes)
 716
 717   if test x$gtkmm_config_exec_prefix != x ; then
 718      gtkmm_config_args="$gtkmm_config_args --exec-prefix=$gtkmm_config_exec_prefix"
 719      if test x${GTKMM_CONFIG+set} != xset ; then
 720         GTKMM_CONFIG=$gtkmm_config_exec_prefix/bin/gtkmm-config
 721      fi
 722   fi
 723   if test x$gtkmm_config_prefix != x ; then
 724      gtkmm_config_args="$gtkmm_config_args --prefix=$gtkmm_config_prefix"
 725      if test x${GTKMM_CONFIG+set} != xset ; then
 726         GTKMM_CONFIG=$gtkmm_config_prefix/bin/gtkmm-config
 727      fi
 728   fi
 729
 730
 731 AC_DEFUN(AM_PATH_GTKMM,
 732 [dnl
 733
 734 dnl
 735 dnl Check check if the installed GTK-- is sufficiently new.
 736 dnl
 737   AC_PATH_PROG(GTKMM_CONFIG, gtkmm-config, no)
 738   min_gtkmm_version=ifelse([$1], ,0.9.14,$1)
 739
 740   AC_MSG_CHECKING(for GTK-- - version >= $min_gtkmm_version)
 741   no_gtkmm=""
 742   if test "$GTKMM_CONFIG" = "no" ; then
 743     no_gtkmm=yes
 744   else
 745     AC_LANG_SAVE
 746     AC_LANG_CPLUSPLUS
 747
 748     GTK___CFLAGS=`$GTKMM_CONFIG $gtkmm_config_args --cflags`
 749     GTK___LIBS=`$GTKMM_CONFIG $gtkmm_config_args --libs`
 750     gtkmm_config_major_version=`$GTKMM_CONFIG $gtkmm_config_args --version | \
 751            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
 752     gtkmm_config_minor_version=`$GTKMM_CONFIG $gtkmm_config_args --version | \
 753            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
 754     gtkmm_config_micro_version=`$GTKMM_CONFIG $gtkmm_config_args --version | \
 755            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
 756     if test "x$enable_gtkmmtest" = "xyes" ; then
 757       ac_save_CXXFLAGS="$CXXFLAGS"
 758       ac_save_LIBS="$LIBS"
 759       CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 760       LIBS="$LIBS $GTK___LIBS"
 761 dnl
 762 dnl Now check if the installed GTK-- is sufficiently new. (Also sanity
 763 dnl checks the results of gtkmm-config to some extent
 764 dnl
 765       rm -f conf.gtkmmtest
 766       AC_TRY_RUN([
 767 #include <gtk--.h>
 768 #include <stdio.h>
 769 #include <stdlib.h>
 770
 771 int
 772 main ()
 773 {
 774   int major, minor, micro;
 775   char *tmp_version;
 776
 777   system ("touch conf.gtkmmtest");
 778
 779   /* HP/UX 0 (%@#!) writes to sscanf strings */
 780   tmp_version = g_strdup("$min_gtkmm_version");
 781   if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) != 3) {
 782      printf("%s, bad version string\n", "$min_gtkmm_version");
 783      exit(1);
 784    }
 785
 786   if ((gtkmm_major_version != $gtkmm_config_major_version) ||
 787       (gtkmm_minor_version != $gtkmm_config_minor_version) ||
 788       (gtkmm_micro_version != $gtkmm_config_micro_version))
 789     {
 790       printf("\n*** 'gtkmm-config --version' returned %d.%d.%d, but GTK-- (%d.%d.%d)\n",
 791              $gtkmm_config_major_version, $gtkmm_config_minor_version, $gtkmm_config_micro_version,
 792              gtkmm_major_version, gtkmm_minor_version, gtkmm_micro_version);
 793       printf ("*** was found! If gtkmm-config was correct, then it is best\n");
 794       printf ("*** to remove the old version of GTK--. You may also be able to fix the error\n");
 795       printf("*** by modifying your LD_LIBRARY_PATH enviroment variable, or by editing\n");
 796       printf("*** /etc/ld.so.conf. Make sure you have run ldconfig if that is\n");
 797       printf("*** required on your system.\n");
 798       printf("*** If gtkmm-config was wrong, set the environment variable GTKMM_CONFIG\n");
 799       printf("*** to point to the correct copy of gtkmm-config, and remove the file config.cache\n");
 800       printf("*** before re-running configure\n");
 801     }
 802 /* GTK-- does not have the GTKMM_*_VERSION constants */
 803 /*
 804   else if ((gtkmm_major_version != GTKMM_MAJOR_VERSION) ||
 805            (gtkmm_minor_version != GTKMM_MINOR_VERSION) ||
 806            (gtkmm_micro_version != GTKMM_MICRO_VERSION))
 807     {
 808       printf("*** GTK-- header files (version %d.%d.%d) do not match\n",
 809              GTKMM_MAJOR_VERSION, GTKMM_MINOR_VERSION, GTKMM_MICRO_VERSION);
 810       printf("*** library (version %d.%d.%d)\n",
 811              gtkmm_major_version, gtkmm_minor_version, gtkmm_micro_version);
 812     }
 813 */
 814   else
 815     {
 816       if ((gtkmm_major_version > major) ||
 817         ((gtkmm_major_version == major) && (gtkmm_minor_version > minor)) ||
 818         ((gtkmm_major_version == major) && (gtkmm_minor_version == minor) && (gtkmm_micro_version >= micro)))
 819       {
 820         return 0;
 821        }
 822      else
 823       {
 824         printf("\n*** An old version of GTK-- (%d.%d.%d) was found.\n",
 825                gtkmm_major_version, gtkmm_minor_version, gtkmm_micro_version);
 826         printf("*** You need a version of GTK-- newer than %d.%d.%d. The latest version of\n",
 827                major, minor, micro);
 828         printf("*** GTK-- is always available from ftp://ftp.gtk.org.\n");
 829         printf("***\n");
 830         printf("*** If you have already installed a sufficiently new version, this error\n");
 831         printf("*** probably means that the wrong copy of the gtkmm-config shell script is\n");
 832         printf("*** being found. The easiest way to fix this is to remove the old version\n");
 833         printf("*** of GTK--, but you can also set the GTKMM_CONFIG environment to point to the\n");
 834         printf("*** correct copy of gtkmm-config. (In this case, you will have to\n");
 835         printf("*** modify your LD_LIBRARY_PATH enviroment variable, or edit /etc/ld.so.conf\n");
 836         printf("*** so that the correct libraries are found at run-time))\n");
 837       }
 838     }
 839   return 1;
 840 }
 841 ],, no_gtkmm=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 842        CXXFLAGS="$ac_save_CXXFLAGS"
 843        LIBS="$ac_save_LIBS"
 844      fi
 845   fi
 846   if test "x$no_gtkmm" = x ; then
 847      AC_MSG_RESULT(yes)
 848      ifelse([$2], , :, [$2])
 849   else
 850      AC_MSG_RESULT(no)
 851      if test "$GTKMM_CONFIG" = "no" ; then
 852        echo "*** The gtkmm-config script installed by GTK-- could not be found"
 853        echo "*** If GTK-- was installed in PREFIX, make sure PREFIX/bin is in"
 854        echo "*** your path, or set the GTK_CONFIG environment variable to the"
 855        echo "*** full path to gtk-config."
 856        echo "*** The gtkmm-config script was not available in GTK-- versions"
 857        echo "*** prior to 0.9.12. Perhaps you need to update your installed"
 858        echo "*** version to 0.9.12 or newer"
 859      else
 860        if test -f conf.gtkmmtest ; then
 861         :
 862        else
 863           echo "*** Could not run GTK-- test program, checking why..."
 864           CXXFLAGS="$CFLAGS $GTKMM_CXXFLAGS"
 865           LIBS="$LIBS $GTK___LIBS"
 866           AC_TRY_LINK([
 867 #include <gtk--.h>
 868 #include <stdio.h>
 869 ],      [ return ((gtkmm_major_version) || (gtkmm_minor_version) || (gtkmm_micro_version)); ],
 870         [ echo "*** The test program compiled, but did not run. This usually means"
 871           echo "*** that the run-time linker is not finding GTK-- or finding the wrong"
 872           echo "*** version of GTK--. If it is not finding GTK--, you'll need to set your"
 873           echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
 874           echo "*** to the installed location  Also, make sure you have run ldconfig if that"
 875           echo "*** is required on your system"
 876           echo "***"
 877           echo "*** If you have an old version installed, it is best to remove it, although"
 878           echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH" ],
 879         [ echo "*** The test program failed to compile or link. See the file config.log for the"
 880           echo "*** exact error that occured. This usually means GTK-- was incorrectly installed"
 881           echo "*** or that you have moved GTK-- since it was installed. In the latter case, you"
 882           echo "*** may want to edit the gtkmm-config script: $GTKMM_CONFIG" ])
 883           CXXFLAGS="$ac_save_CXXFLAGS"
 884           LIBS="$ac_save_LIBS"
 885        fi
 886      fi
 887      GTK___CFLAGS=""
 888      GTK__LIBS=""
 889      ifelse([$3], , :, [$3])
 890      AC_LANG_RESTORE
 891   fi
 892   AC_SUBST(GTK___CFLAGS)
 893   AC_SUBST(GTK___LIBS)
 894   rm -f conf.gtkmmtest
 895 ])
 896
 897 # Configure paths for GTK--DRAW
 898 # Derek Quinn Wyatt   98-08-21  (adapted from Jan Nieuwenhuizen's code)
 899
 900 dnl AM_PATH_GTK__DRAW([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 901 dnl Test for GTK--DRAW, and define GTK___CFLAGS and GTK___LIBS
 902 dnl
 903 AC_DEFUN(AM_PATH_GTK__DRAW,
 904 [dnl
 905 dnl Get the cflags and libraries from the gtk__-config script
 906 dnl
 907   AC_PATH_PROG(GTKMM_CONFIG, gtkmm-config, no)
 908   min_gtk___version=ifelse([$1], ,0.0.5,$1)
 909   AC_MSG_CHECKING(for GTK--DRAW - version >= $min_gtk___version)
 910   no_gtk__=""
 911   if test "$GTKMM_CONFIG" != "no" ; then
 912     GTK___CFLAGS=`$GTKMM_CONFIG --cflags`
 913     GTK___LIBS=`$GTKMM_CONFIG --libs`
 914     GTK___DLIBS="$GTK___LIBS -lgtkmmdraw"
 915     GTK___LIBS="$GTK___DLIBS"
 916     ac_save_CFLAGS="$CFLAGS"
 917     ac_save_LIBS="$LIBS"
 918     ac_save_CXXFLAGS="$CXXFLAGS"
 919     CFLAGS="$CFLAGS $GTK___CFLAGS"
 920     CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 921     LIBS="$LIBS $GTK___LIBS"
 922 dnl
 923 dnl Now check if the installed GTK__ is sufficiently new. (Also sanity
 924 dnl checks the results of gtk__-config to some extent
 925 dnl
 926     AC_TRY_RUN([
 927 #include <gtk--.h>
 928 #include <stdio.h>
 929
 930 int
 931 main ()
 932 {
 933   // urg
 934   return 0;
 935 }
 936 ],, no_gtk__=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 937      CFLAGS="$ac_save_CFLAGS"
 938      CXXFLAGS="$ac_save_CXXFLAGS"
 939      LIBS="$ac_save_LIBS"
 940   else
 941      no_gtk__=yes
 942   fi
 943   if test "x$no_gtk__" = x ; then
 944      AC_MSG_RESULT(yes)
 945      ifelse([$2], , :, [$2])
 946   else
 947      AC_MSG_RESULT(no)
 948      GTK___CFLAGS=""
 949      GTK___LIBS=""
 950      ifelse([$3], , :, [$3])
 951   fi
 952   CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 953   AC_SUBST(CXXFLAGS)
 954   AC_SUBST(GTK___CFLAGS)
 955   AC_SUBST(GTK___LIBS)
 956 ])
 957