scm/music-functions.scm

   1 ;;;; music-functions.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2006 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7
   8 ;; (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19 (define-safe-public (music-is-of-type? mus type)
  20   "Does @code{mus} belong to the music class @code{type}?"
  21   (memq type (ly:music-property mus 'types)))
  22
  23 ;; TODO move this
  24 (define-public ly:grob-property
  25   (make-procedure-with-setter ly:grob-property
  26                               ly:grob-set-property!))
  27
  28 (define-public ly:prob-property
  29   (make-procedure-with-setter ly:prob-property
  30                               ly:prob-set-property!))
  31
  32 (define-public (music-map function music)
  33   "Apply @var{function} to @var{music} and all of the music it contains.
  34
  35 First it recurses over the children, then the function is applied to MUSIC.
  36 "
  37   (let ((es (ly:music-property music 'elements))
  38         (e (ly:music-property music 'element)))
  39     (set! (ly:music-property music 'elements)
  40           (map (lambda (y) (music-map function y)) es))
  41     (if (ly:music? e)
  42         (set! (ly:music-property music 'element)
  43               (music-map function  e)))
  44     (function music)))
  45
  46 (define-public (music-filter pred? music)
  47   "Filter out music expressions that do not satisfy PRED."
  48
  49   (define (inner-music-filter pred? music)
  50     "Recursive function."
  51     (let* ((es (ly:music-property music 'elements))
  52            (e (ly:music-property music 'element))
  53            (as (ly:music-property music 'articulations))
  54            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  55            (filtered-e (if (ly:music? e)
  56                            (inner-music-filter pred? e)
  57                            e))
  58            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  59       (set! (ly:music-property music 'element) filtered-e)
  60       (set! (ly:music-property music 'elements) filtered-es)
  61       (set! (ly:music-property music 'articulations) filtered-as)
  62       ;; if filtering emptied the expression, we remove it completely.
  63       (if (or (not (pred? music))
  64               (and (eq? filtered-es '()) (not (ly:music? e))
  65                    (or (not (eq? es '()))
  66                        (ly:music? e))))
  67           (set! music '()))
  68       music))
  69
  70   (set! music (inner-music-filter pred? music))
  71   (if (ly:music? music)
  72       music
  73       (make-music 'Music)))       ;must return music.
  74
  75 (define-public (display-music music)
  76   "Display music, not done with music-map for clarity of presentation."
  77   (display music)
  78   (display ": { ")
  79   (let ((es (ly:music-property music 'elements))
  80         (e (ly:music-property music 'element)))
  81     (display (ly:music-mutable-properties music))
  82     (if (pair? es)
  83         (begin (display "\nElements: {\n")
  84                (map display-music es)
  85                (display "}\n")))
  86     (if (ly:music? e)
  87         (begin
  88           (display "\nChild:")
  89           (display-music e))))
  90   (display " }\n")
  91   music)
  92
  93 ;;;
  94 ;;; A scheme music pretty printer
  95 ;;;
  96 (define (markup-expression->make-markup markup-expression)
  97   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
  98 For instance,
  99   \\markup \\bold \\italic hello
 100 ==>
 101   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 102   (define (proc->command-keyword proc)
 103     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 104     (let ((cmd-markup (symbol->string (procedure-name proc))))
 105       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 106                                                                   (string-length "-markup")))))))
 107   (define (transform-arg arg)
 108     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 109            (apply append (map inner-markup->make-markup arg)))
 110           ((and (not (string? arg)) (markup? arg)) ;; a markup
 111            (inner-markup->make-markup arg))
 112           (else                                  ;; scheme arg
 113            arg)))
 114   (define (inner-markup->make-markup mrkup)
 115     (if (string? mrkup)
 116         `(#:simple ,mrkup)
 117         (let ((cmd (proc->command-keyword (car mrkup)))
 118               (args (map transform-arg (cdr mrkup))))
 119           `(,cmd ,@args))))
 120   ;; body:
 121   (if (string? markup-expression)
 122       markup-expression
 123       `(markup ,@(inner-markup->make-markup markup-expression))))
 124
 125 (define-public (music->make-music obj)
 126   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 127 that is, for a music expression, a (make-music ...) form."
 128   (cond (;; markup expression
 129          (markup? obj)
 130          (markup-expression->make-markup obj))
 131         (;; music expression
 132          (ly:music? obj)
 133          `(make-music
 134            ',(ly:music-property obj 'name)
 135            ,@(apply append (map (lambda (prop)
 136                                   `(',(car prop)
 137                                     ,(music->make-music (cdr prop))))
 138                                 (remove (lambda (prop)
 139                                           (eqv? (car prop) 'origin))
 140                                         (ly:music-mutable-properties obj))))))
 141         (;; moment
 142          (ly:moment? obj)
 143          `(ly:make-moment ,(ly:moment-main-numerator obj)
 144                           ,(ly:moment-main-denominator obj)
 145                           ,(ly:moment-grace-numerator obj)
 146                           ,(ly:moment-grace-denominator obj)))
 147         (;; note duration
 148          (ly:duration? obj)
 149          `(ly:make-duration ,(ly:duration-log obj)
 150                             ,(ly:duration-dot-count obj)
 151                             ,(car (ly:duration-factor obj))
 152                             ,(cdr (ly:duration-factor obj))))
 153         (;; note pitch
 154          (ly:pitch? obj)
 155          `(ly:make-pitch ,(ly:pitch-octave obj)
 156                          ,(ly:pitch-notename obj)
 157                          ,(ly:pitch-alteration obj)))
 158         (;; scheme procedure
 159          (procedure? obj)
 160          (or (procedure-name obj) obj))
 161         (;; a symbol (avoid having an unquoted symbol)
 162          (symbol? obj)
 163          `',obj)
 164         (;; an empty list (avoid having an unquoted empty list)
 165          (null? obj)
 166          `'())
 167         (;; a proper list
 168          (list? obj)
 169          `(list ,@(map music->make-music obj)))
 170         (;; a pair
 171          (pair? obj)
 172          `(cons ,(music->make-music (car obj))
 173                 ,(music->make-music (cdr obj))))
 174         (else
 175          obj)))
 176
 177 (use-modules (ice-9 pretty-print))
 178 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 179   "Displays `obj', typically a music expression, in a friendly fashion,
 180 which often can be read back in order to generate an equivalent expression.
 181
 182 Returns `obj'.
 183 "
 184   (pretty-print (music->make-music obj) port)
 185   (newline)
 186   obj)
 187
 188 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 189
 190 (define-public (shift-one-duration-log music shift dot)
 191   "  add SHIFT to duration-log of 'duration in music and optionally
 192   a dot to any note encountered. This scales the music up by a factor
 193   2^shift * (2 - (1/2)^dot)"
 194   (let ((d (ly:music-property music 'duration)))
 195     (if (ly:duration? d)
 196         (let* ((cp (ly:duration-factor d))
 197                (nd (ly:make-duration (+ shift (ly:duration-log d))
 198                                      (+ dot (ly:duration-dot-count d))
 199                                      (car cp)
 200                                      (cdr cp))))
 201           (set! (ly:music-property music 'duration) nd)))
 202     music))
 203
 204 (define-public (shift-duration-log music shift dot)
 205   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 206              music))
 207
 208 (define-public (make-repeat name times main alts)
 209   "create a repeat music expression, with all properties initialized properly"
 210   (let ((talts (if (< times (length alts))
 211                    (begin
 212                      (ly:warning (_ "More alternatives than repeats. Junking excess alternatives"))
 213                      (take alts times))
 214                    alts))
 215         (r (make-repeated-music name)))
 216     (set! (ly:music-property r 'element) main)
 217     (set! (ly:music-property r 'repeat-count) (max times 1))
 218     (set! (ly:music-property r 'elements) talts)
 219     (if (equal? name "tremolo")
 220         (let* ((dot? (zero? (modulo times 3)))
 221                (dots (if dot? 1 0))
 222                (mult (if dot?
 223                          (quotient (* times 2) 3)
 224                          times))
 225                (shift (- (ly:intlog2 mult))))
 226
 227           (if (memq 'sequential-music (ly:music-property main 'types))
 228               ;; \repeat "tremolo" { c4 d4 }
 229               (let ((children (length (ly:music-property main 'elements))))
 230                 (if (not (= children 2))
 231                     (ly:warning (_ "expecting 2 elements for chord tremolo, found ~a") children))
 232                 (ly:music-compress r (ly:make-moment 1 children))
 233                 (shift-duration-log r (1- shift) dots))
 234               ;; \repeat "tremolo" c4
 235               (shift-duration-log r shift dots)))
 236         r)))
 237
 238 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 239 ;; clusters.
 240
 241 (define-public (note-to-cluster music)
 242   "Replace NoteEvents by ClusterNoteEvents."
 243   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 244       (make-music 'ClusterNoteEvent
 245                   'pitch (ly:music-property music 'pitch)
 246                   'duration (ly:music-property music 'duration))
 247       music))
 248
 249 (define-public (notes-to-clusters music)
 250   (music-map note-to-cluster music))
 251
 252 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 253 ;; repeats.
 254
 255 (define-public (unfold-repeats music)
 256   "
 257 This function replaces all repeats  with unfold repeats. "
 258
 259   (let ((es (ly:music-property music 'elements))
 260         (e  (ly:music-property music 'element))
 261         )
 262     (if (memq 'repeated-music (ly:music-property music 'types))
 263         (let*
 264             ((props (ly:music-mutable-properties music))
 265              (old-name (ly:music-property music 'name))
 266              (flattened  (flatten-alist props)))
 267
 268           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 269                                               flattened)))
 270
 271           (if (equal? old-name 'TremoloRepeatedMusic)
 272               (let* ((seq-arg? (memq 'sequential-music
 273                                      (ly:music-property e 'types)))
 274                      (count  (ly:music-property music 'repeat-count))
 275                      (dot-shift (if (= 0 (remainder count 3))
 276                                     -1 0)))
 277
 278                 (if (= 0 -1)
 279                     (set! count (* 2 (quotient count 3))))
 280
 281                 (shift-duration-log music (+ (if seq-arg? 1 0)
 282                                              (ly:intlog2 count)) dot-shift)
 283
 284                 (if seq-arg?
 285                     (ly:music-compress e (ly:make-moment (length (ly:music-property
 286                                                                   e 'elements)) 1)))))))
 287
 288
 289     (if (pair? es)
 290         (set! (ly:music-property music 'elements)
 291               (map unfold-repeats es)))
 292     (if (ly:music? e)
 293         (set! (ly:music-property music 'element)
 294               (unfold-repeats e)))
 295     music))
 296
 297 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 298 ;; property setting music objs.
 299
 300 (define-public (make-grob-property-set grob gprop val)
 301   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 302 i.e.  this is not an override"
 303   (make-music 'OverrideProperty
 304               'symbol grob
 305               'grob-property gprop
 306               'grob-value val
 307               'pop-first #t))
 308
 309 (define-public (make-grob-property-override grob gprop val)
 310   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 311 i.e.  this is not an override"
 312   (make-music 'OverrideProperty
 313               'symbol grob
 314               'grob-property gprop
 315               'grob-value val))
 316
 317 (define-public (make-grob-property-revert grob gprop)
 318   "Revert the grob property GPROP for GROB."
 319   (make-music 'RevertProperty
 320               'symbol grob
 321               'grob-property gprop))
 322
 323 (define direction-polyphonic-grobs
 324   '(Stem Tie Rest Slur PhrasingSlur Script TextScript Dots DotColumn Fingering))
 325
 326 (define-safe-public (make-voice-props-set n)
 327   (make-sequential-music
 328    (append
 329     (map (lambda (x) (make-grob-property-set x 'direction
 330                                              (if (odd? n) -1 1)))
 331          direction-polyphonic-grobs)
 332     (list
 333      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 334      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 335
 336 (define-safe-public (make-voice-props-revert)
 337   (make-sequential-music
 338    (append
 339     (map (lambda (x) (make-grob-property-revert x 'direction))
 340          direction-polyphonic-grobs)
 341     (list (make-grob-property-revert 'NoteColumn 'horizontal-shift))
 342     (list (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 343
 344
 345 (define-safe-public (context-spec-music m context #:optional id)
 346   "Add \\context CONTEXT = ID to M. "
 347   (let ((cm (make-music 'ContextSpeccedMusic
 348                         'element m
 349                         'context-type context)))
 350     (if (string? id)
 351         (set! (ly:music-property cm 'context-id) id))
 352     cm))
 353
 354 (define-public (descend-to-context m context)
 355   "Like context-spec-music, but only descending. "
 356   (let ((cm (context-spec-music m context)))
 357     (ly:music-set-property! cm 'descend-only #t)
 358     cm))
 359
 360 (define-public (make-non-relative-music mus)
 361   (make-music 'UnrelativableMusic
 362               'element mus))
 363
 364 (define-public (make-apply-context func)
 365   (make-music 'ApplyContext
 366               'procedure func))
 367
 368 (define-public (make-sequential-music elts)
 369   (make-music 'SequentialMusic
 370               'elements elts))
 371
 372 (define-public (make-simultaneous-music elts)
 373   (make-music 'SimultaneousMusic
 374               'elements elts))
 375
 376 (define-safe-public (make-event-chord elts)
 377   (make-music 'EventChord
 378               'elements elts))
 379
 380 (define-public (make-skip-music dur)
 381   (make-music 'SkipMusic
 382               'duration dur))
 383
 384 (define-public (make-grace-music music)
 385   (make-music 'GraceMusic
 386               'element music))
 387
 388 ;;;;;;;;;;;;;;;;
 389
 390 ;; mmrest
 391 (define-public (make-multi-measure-rest duration location)
 392   (make-music 'MultiMeasureRestMusic
 393               'origin location
 394               'duration duration))
 395
 396 (define-public (make-property-set sym val)
 397   (make-music 'PropertySet
 398               'symbol sym
 399               'value val))
 400
 401 (define-public (make-property-unset sym)
 402   (make-music 'PropertyUnset
 403               'symbol sym))
 404
 405 (define-public (make-ottava-set octavation)
 406   (let ((m (make-music 'ApplyContext)))
 407     (define (ottava-modify context)
 408       "Either reset middleCPosition to the stored original, or remember
 409 old middleCPosition, add OCTAVATION to middleCPosition, and set
 410 OTTAVATION to `8va', or whatever appropriate."
 411       (if (number? (ly:context-property  context 'middleCPosition))
 412           (begin
 413             (if (number? (ly:context-property context 'originalMiddleCPosition))
 414                 (let ((where (ly:context-property-where-defined context 'middleCPosition)))
 415
 416                   (ly:context-set-property! context 'middleCPosition
 417                                             (ly:context-property context 'originalMiddleCPosition))
 418                   (ly:context-unset-property where 'originalMiddleCPosition)
 419                   (ly:context-unset-property where 'ottavation)))
 420
 421             (let* ((where (ly:context-property-where-defined context 'middleCPosition))
 422                    (c0 (ly:context-property context 'middleCPosition))
 423                    (new-c0 (+ c0 (* -7 octavation)))
 424                    (string (cdr (assoc octavation '((2 . "15ma")
 425                                                     (1 . "8va")
 426                                                     (0 . #f)
 427                                                     (-1 . "8vb")
 428                                                     (-2 . "15mb"))))))
 429               (ly:context-set-property! context 'middleCPosition new-c0)
 430               (ly:context-set-property! context 'originalMiddleCPosition c0)
 431               (ly:context-set-property! context 'ottavation string)))))
 432
 433     (set! (ly:music-property m 'procedure) ottava-modify)
 434     (context-spec-music m 'Staff)))
 435
 436 (define-public (set-octavation ottavation)
 437   (ly:export (make-ottava-set ottavation)))
 438
 439 (define-public (make-time-signature-set num den . rest)
 440   "Set properties for time signature NUM/DEN.  Rest can contain a list
 441 of beat groupings "
 442
 443   (define (standard-beat-grouping num den)
 444
 445     "Some standard subdivisions for time signatures."
 446     (let*
 447         ((key (cons num den))
 448          (entry (assoc key '(((6 . 8) . (3 3))
 449                          ((5 . 8) . (3 2))
 450                          ((9 . 8) . (3 3 3))
 451                          ((12 . 8) . (3 3 3 3))
 452                          ((8 . 8) . (3 3 2))
 453                          ))))
 454
 455       (if entry
 456           (cdr entry)
 457           '())))
 458
 459   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 460          (beat (ly:make-moment 1 den))
 461          (len  (ly:make-moment num den))
 462          (set2 (make-property-set 'beatLength beat))
 463          (set3 (make-property-set 'measureLength len))
 464          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 465                                                     (car rest)
 466                                                     (standard-beat-grouping num den))))
 467          (basic  (list set1 set2 set3 set4)))
 468     (descend-to-context
 469      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 470
 471 (define-public (make-mark-set label)
 472   "Make the music for the \\mark command."
 473   (let* ((set (if (integer? label)
 474                   (context-spec-music (make-property-set 'rehearsalMark label)
 475                                       'Score)
 476                   #f))
 477          (ev (make-music 'MarkEvent))
 478          (ch (make-event-chord (list ev))))
 479     (if set
 480         (make-sequential-music (list set ch))
 481         (begin
 482           (set! (ly:music-property ev 'label) label)
 483           ch))))
 484
 485 (define-public (set-time-signature num den . rest)
 486   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 487
 488 (define-safe-public (make-articulation name)
 489   (make-music 'ArticulationEvent
 490               'articulation-type name))
 491
 492 (define-public (make-lyric-event string duration)
 493   (make-music 'LyricEvent
 494               'duration duration
 495               'text string))
 496
 497 (define-safe-public (make-span-event type spandir)
 498   (make-music type
 499               'span-direction spandir))
 500
 501 (define-public (set-mus-properties! m alist)
 502   "Set all of ALIST as properties of M."
 503   (if (pair? alist)
 504       (begin
 505         (set! (ly:music-property m (caar alist)) (cdar alist))
 506         (set-mus-properties! m (cdr alist)))))
 507
 508 (define-public (music-separator? m)
 509   "Is M a separator?"
 510   (let ((ts (ly:music-property m 'types)))
 511     (memq 'separator ts)))
 512
 513 ;;; splitting chords into voices.
 514 (define (voicify-list lst number)
 515   "Make a list of Musics.
 516
 517    voicify-list :: [ [Music ] ] -> number -> [Music]
 518    LST is a list music-lists.
 519
 520    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 521 "
 522   (if (null? lst)
 523       '()
 524       (cons (context-spec-music
 525              (make-sequential-music
 526               (list (make-voice-props-set number)
 527                     (make-simultaneous-music (car lst))))
 528              'Voice  (number->string (1+ number)))
 529             (voicify-list (cdr lst) (1+ number)))))
 530
 531 (define (voicify-chord ch)
 532   "Split the parts of a chord into different Voices using separator"
 533   (let ((es (ly:music-property ch 'elements)))
 534     (set! (ly:music-property  ch 'elements)
 535           (voicify-list (split-list-by-separator es music-separator?) 0))
 536     ch))
 537
 538 (define-public (voicify-music m)
 539   "Recursively split chords that are separated with \\ "
 540   (if (not (ly:music? m))
 541       (ly:error (_ "music expected: ~S") m))
 542   (let ((es (ly:music-property m 'elements))
 543         (e (ly:music-property m 'element)))
 544
 545     (if (pair? es)
 546         (set! (ly:music-property m 'elements) (map voicify-music es)))
 547     (if (ly:music? e)
 548         (set! (ly:music-property m 'element)  (voicify-music e)))
 549     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 550              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 551         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 552     m))
 553
 554 (define-public (empty-music)
 555   (ly:export (make-music 'Music)))
 556 ;;;
 557
 558                                         ; Make a function that checks score element for being of a specific type.
 559 (define-public (make-type-checker symbol)
 560   (lambda (elt)
 561     ;;(display  symbol)
 562     ;;(eq? #t (ly:grob-property elt symbol))
 563     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 564
 565 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 566   (if (func grob)
 567       (set! (ly:grob-property grob sym) val)))
 568
 569
 570 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 571   "Usage:
 572
 573 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 574
 575 "
 576   (let ((meta (ly:grob-property grob 'meta)))
 577     (if (equal?  (cdr (assoc 'name meta)) grob-name)
 578         (set! (ly:grob-property grob symbol) val))))
 579
 580
 581 ;;
 582 (define-public (smart-bar-check n)
 583   "Make  a bar check that checks for a specific bar number.
 584 "
 585   (let ((m (make-music 'ApplyContext)))
 586     (define (checker tr)
 587       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 588         (if (= bn n)
 589             #t
 590             (ly:error
 591              ;; FIXME: uncomprehensable message
 592              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 593              n bn))))
 594     (set! (ly:music-property m 'procedure) checker)
 595     m))
 596
 597
 598 (define-public (skip->rest mus)
 599
 600   "Replace MUS by RestEvent of the same duration if it is a
 601 SkipEvent. Useful for extracting parts from crowded scores"
 602
 603   (if (equal? (ly:music-property mus 'name) 'SkipEvent)
 604    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 605    mus))
 606
 607
 608 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 609 ;; warn for bare chords at start.
 610
 611 (define (has-request-chord elts)
 612   (reduce (lambda (x y) (or x y)) #f
 613           (map (lambda (x)
 614                  (equal? (ly:music-property x 'name) 'RequestChord))
 615                elts)))
 616
 617 (define-public (ly:music-message music msg)
 618   (let ((ip (ly:music-property music 'origin)))
 619     (if (ly:input-location? ip)
 620         (ly:input-message ip msg)
 621         (ly:warning msg))))
 622
 623 (define (check-start-chords music)
 624   "Check music expression for a Simultaneous_music containing notes\n(ie. Request_chords),
 625 without context specification. Called  from parser."
 626   (let ((es (ly:music-property music 'elements))
 627         (e (ly:music-property music 'element))
 628         (name (ly:music-property music 'name)))
 629     (cond ((equal? name "Context_specced_music") #t)
 630           ((equal? name "Simultaneous_music")
 631            (if (has-request-chord es)
 632                (ly:music-message music "Starting score with a chord.\nInsert an explicit \\context before chord")
 633                (map check-start-chords es)))
 634           ((equal? name "SequentialMusic")
 635            (if (pair? es)
 636                (check-start-chords (car es))))
 637           (else (if (ly:music? e) (check-start-chords e)))))
 638   music)
 639
 640
 641
 642 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 643 ;;
 644 ;; setting stuff for grace context.
 645 ;;
 646
 647 (define (vector-extend v x)
 648   "Make a new vector consisting of V, with X added to the end."
 649   (let* ((n (vector-length v))
 650          (nv (make-vector (+ n 1) '())))
 651     (vector-move-left! v 0 n nv 0)
 652     (vector-set! nv n x)
 653     nv))
 654
 655 (define (vector-map f v)
 656   "Map  F over V. This function returns nothing."
 657   (do ((n (vector-length v))
 658        (i 0 (+ i 1)))
 659       ((>= i n))
 660     (f (vector-ref v i))))
 661
 662 (define (vector-reverse-map f v)
 663   "Map  F over V, N to 0 order. This function returns nothing."
 664   (do ((i (- (vector-length v) 1) (- i 1)))
 665       ((< i 0))
 666     (f (vector-ref v i))))
 667
 668 ;; TODO:  make a remove-grace-property too.
 669 (define-public (add-grace-property context-name grob sym val)
 670   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 671   (define (set-prop context)
 672     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 673            (current (ly:context-property where 'graceSettings))
 674            (new-settings (append current
 675                                  (list (list context-name grob sym val)))))
 676       (ly:context-set-property! where 'graceSettings new-settings)))
 677   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 678
 679
 680
 681 (defmacro-public def-grace-function (start stop)
 682   `(define-music-function (parser location music) (ly:music?)
 683      (make-music 'GraceMusic
 684                  'origin location
 685                  'element (make-music 'SequentialMusic
 686                                       'elements (list (ly:music-deep-copy ,start)
 687                                                       music
 688                                                       (ly:music-deep-copy ,stop))))))
 689
 690 (defmacro-public define-music-function (args signature . body)
 691   "Helper macro for `ly:make-music-function'.
 692 Syntax:
 693   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 694     ...function body...)
 695 "
 696   `(ly:make-music-function (list ,@signature)
 697                            (lambda (,@args)
 698                              ,@body)))
 699
 700
 701 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 702
 703 (define-public (cue-substitute quote-music)
 704   "Must happen after quote-substitute."
 705
 706   (if (vector? (ly:music-property quote-music 'quoted-events))
 707       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 708              (main-voice (if (eq? 1 dir) 1 0))
 709              (cue-voice (if (eq? 1 dir) 0 1))
 710              (main-music (ly:music-property quote-music 'element))
 711              (return-value quote-music))
 712
 713         (if (or (eq? 1 dir) (eq? -1 dir))
 714
 715             ;; if we have stem dirs, change both quoted and main music
 716             ;; to have opposite stems.
 717             (begin
 718               (set! return-value
 719
 720                     ;; cannot context-spec Quote-music, since context
 721                     ;; for the quotes is determined in the iterator.
 722                     (make-sequential-music
 723                      (list
 724                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 725                       quote-music
 726                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 727               (set! main-music
 728                     (make-sequential-music
 729                      (list
 730                       (make-voice-props-set main-voice)
 731                       main-music
 732                       (make-voice-props-revert))))
 733               (set! (ly:music-property quote-music 'element) main-music)))
 734
 735         return-value)
 736       quote-music))
 737
 738 (define-public ((quote-substitute quote-tab) music)
 739   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 740          (quoted-vector (if (string? quoted-name)
 741                             (hash-ref quote-tab quoted-name #f)
 742                             #f)))
 743
 744
 745     (if (string? quoted-name)
 746         (if (vector? quoted-vector)
 747             (begin
 748               (set! (ly:music-property music 'quoted-events) quoted-vector)
 749               (set! (ly:music-property music 'iterator-ctor)
 750                     ly:quote-iterator::constructor))
 751             (ly:warning (_ "cannot find quoted music: `~S'") quoted-name)))
 752     music))
 753
 754
 755 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 756 ;; switch it on here, so parsing and init isn't checked (too slow!)
 757 ;;
 758 ;; automatic music transformations.
 759
 760 (define (switch-on-debugging m)
 761   (if (defined? 'set-debug-cell-accesses!)
 762       (set-debug-cell-accesses! 15000))
 763   m)
 764
 765 (define (music-check-error music)
 766   (define found #f)
 767   (define (signal m)
 768     (if (and (ly:music? m)
 769              (eq? (ly:music-property m 'error-found) #t))
 770         (set! found #t)))
 771
 772   (for-each signal (ly:music-property music 'elements))
 773   (signal (ly:music-property music 'element))
 774
 775   (if found
 776       (set! (ly:music-property music 'error-found) #t))
 777   music)
 778
 779 (define (precompute-music-length music)
 780   (set! (ly:music-property music 'length)
 781         (ly:music-length music))
 782   music)
 783
 784 (define (skip-to-last music parser)
 785
 786   "Replace MUSIC by
 787
 788 << { \\set skipTypesetting = ##t
 789      LENGTHOF(\\showLastLength)
 790      \\set skipTypesetting = ##t  }
 791     MUSIC >>
 792
 793 if appropriate.
 794  "
 795   (let*
 796       ((show-last  (ly:parser-lookup parser 'showLastLength)))
 797
 798     (if (ly:music? show-last)
 799         (let*
 800             ((orig-length (ly:music-length music))
 801              (skip-length (ly:moment-sub orig-length (ly:music-length show-last))))
 802
 803           (make-simultaneous-music
 804            (list
 805             (make-sequential-music
 806              (list
 807               (context-spec-music (make-property-set 'skipTypesetting #t) 'Score)
 808               (make-music 'SkipMusic 'duration
 809                           (ly:make-duration 0 0
 810                                             (ly:moment-main-numerator skip-length)
 811                                             (ly:moment-main-denominator skip-length)))
 812               (context-spec-music (make-property-set 'skipTypesetting #f) 'Score)))
 813             music)))
 814         music)))
 815
 816
 817 (define-public toplevel-music-functions
 818   (list
 819    (lambda (music parser) (voicify-music music))
 820    (lambda (x parser) (music-map music-check-error x))
 821    (lambda (x parser) (music-map precompute-music-length x))
 822    (lambda (music parser)
 823
 824      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 825
 826    ;; switch-on-debugging
 827    (lambda (x parser) (music-map cue-substitute x))
 828
 829    (lambda (x parser)
 830      (skip-to-last x parser)
 831    )))
 832
 833
 834 ;;;;;;;;;;;;;;;;;
 835 ;; lyrics
 836
 837 (define (apply-durations lyric-music durations)
 838   (define (apply-duration music)
 839     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 840              (ly:duration?  (ly:music-property music 'duration)))
 841         (begin
 842           (set! (ly:music-property music 'duration) (car durations))
 843           (set! durations (cdr durations)))))
 844
 845   (music-map apply-duration lyric-music))
 846
 847
 848 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 849 ;; accidentals
 850
 851 (define-public (set-accidentals-properties extra-natural
 852                                            auto-accs auto-cauts
 853                                            context)
 854   (context-spec-music
 855    (make-sequential-music
 856     (append (if (boolean? extra-natural)
 857                 (list (make-property-set 'extraNatural extra-natural))
 858                 '())
 859             (list (make-property-set 'autoAccidentals auto-accs)
 860                   (make-property-set 'autoCautionaries auto-cauts))))
 861    context))
 862
 863 (define-public (set-accidental-style style . rest)
 864   "Set accidental style to STYLE. Optionally takes a context argument,
 865 e.g. 'Staff or 'Voice. The context defaults to Voice, except for piano styles, which
 866 use GrandStaff as a context. "
 867   (let ((context (if (pair? rest)
 868                      (car rest) 'Staff))
 869         (pcontext (if (pair? rest)
 870                       (car rest) 'GrandStaff)))
 871     (ly:export
 872      (cond
 873       ;; accidentals as they were common in the 18th century.
 874       ((equal? style 'default)
 875        (set-accidentals-properties #t '(Staff (same-octave . 0))
 876                                    '() context))
 877       ;; accidentals from one voice do NOT get cancelled in other voices
 878       ((equal? style 'voice)
 879        (set-accidentals-properties #t '(Voice (same-octave . 0))
 880                                    '() context))
 881       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
 882       ;; This includes all the default accidentals, but accidentals also needs cancelling
 883       ;; in other octaves and in the next measure.
 884       ((equal? style 'modern)
 885        (set-accidentals-properties #f '(Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 886                                    '()  context))
 887       ;; the accidentals that Stone adds to the old standard as cautionaries
 888       ((equal? style 'modern-cautionary)
 889        (set-accidentals-properties #f '(Staff (same-octave . 0))
 890                                    '(Staff (any-octave . 0) (same-octave . 1))
 891                                    context))
 892       ;; Multivoice accidentals to be read both by musicians playing one voice
 893       ;; and musicians playing all voices.
 894       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
 895       ((equal? style 'modern-voice)
 896        (set-accidentals-properties  #f
 897                                     '(Voice (same-octave . 0) (any-octave . 0) (same-octave . 1)
 898                                             Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 899                                     '()
 900                                     context))
 901       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
 902       ;; as cautionaries
 903       ((equal? style 'modern-voice-cautionary)
 904        (set-accidentals-properties #f
 905                                    '(Voice (same-octave . 0))
 906                                    '(Voice (any-octave . 0) (same-octave . 1)
 907                                            Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 908                                    context))
 909       ;; stone's suggestions for accidentals on grand staff.
 910       ;; Accidentals are cancelled across the staves in the same grand staff as well
 911       ((equal? style 'piano)
 912        (set-accidentals-properties #f
 913                                    '(Staff (same-octave . 0)
 914                                            (any-octave . 0) (same-octave . 1)
 915                                            GrandStaff (any-octave . 0) (same-octave . 1))
 916                                    '()
 917                                    pcontext))
 918       ((equal? style 'piano-cautionary)
 919        (set-accidentals-properties #f
 920                                    '(Staff (same-octave . 0))
 921                                    '(Staff (any-octave . 0) (same-octave . 1)
 922                                            GrandStaff (any-octave . 0) (same-octave . 1))
 923                                    pcontext))
 924
 925       ;; do not set localKeySignature when a note alterated differently from
 926       ;; localKeySignature is found.
 927       ;; Causes accidentals to be printed at every note instead of
 928       ;; remembered for the duration of a measure.
 929       ;; accidentals not being remembered, causing accidentals always to
 930       ;; be typeset relative to the time signature
 931
 932       ((equal? style 'forget)
 933        (set-accidentals-properties '()
 934                                    '(Staff (same-octave . -1))
 935                                    '() context))
 936       ;; Do not reset the key at the start of a measure.  Accidentals will be
 937       ;; printed only once and are in effect until overridden, possibly many
 938       ;; measures later.
 939       ((equal? style 'no-reset)
 940        (set-accidentals-properties '()
 941                                    '(Staff (same-octave . #t))
 942                                    '()
 943                                    context))
 944       (else
 945        (ly:warning (_ "unknown accidental style: ~S" style))
 946        (make-sequential-music '()))))))
 947
 948 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 949
 950 (define-public (skip-of-length mus)
 951   "Create a skip of exactly the same length as MUS."
 952   (let* ((skip
 953           (make-music
 954            'SkipEvent
 955            'duration (ly:make-duration 0 0))))
 956
 957     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
 958
 959 (define-public (mmrest-of-length mus)
 960   "Create a mmrest of exactly the same length as MUS."
 961
 962   (let* ((skip
 963           (make-multi-measure-rest
 964            (ly:make-duration 0 0) '())))
 965     (ly:music-compress skip (ly:music-length mus))
 966     skip))
 967
 968 (define-public (pitch-of-note event-chord)
 969
 970   (let*
 971       ((evs (filter (lambda (x) (memq 'note-event (ly:music-property x 'types)))
 972                     (ly:music-property event-chord 'elements))))
 973
 974     (if (pair? evs)
 975         (ly:music-property (car evs) 'pitch)
 976         #f)))
 977