scm/music-functions.scm

   1 ;;;; music-functions.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2009 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7
   8 ;; (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19 (define-safe-public (music-is-of-type? mus type)
  20   "Does @code{mus} belong to the music class @code{type}?"
  21   (memq type (ly:music-property mus 'types)))
  22
  23 ;; TODO move this
  24 (define-public ly:grob-property
  25   (make-procedure-with-setter ly:grob-property
  26                               ly:grob-set-property!))
  27
  28 (define-public ly:prob-property
  29   (make-procedure-with-setter ly:prob-property
  30                               ly:prob-set-property!))
  31
  32 (define-public (music-map function music)
  33   "Apply @var{function} to @var{music} and all of the music it contains.
  34
  35 First it recurses over the children, then the function is applied to MUSIC.
  36 "
  37   (let ((es (ly:music-property music 'elements))
  38         (e (ly:music-property music 'element)))
  39     (set! (ly:music-property music 'elements)
  40           (map (lambda (y) (music-map function y)) es))
  41     (if (ly:music? e)
  42         (set! (ly:music-property music 'element)
  43               (music-map function  e)))
  44     (function music)))
  45
  46 (define-public (music-filter pred? music)
  47   "Filter out music expressions that do not satisfy PRED."
  48
  49   (define (inner-music-filter pred? music)
  50     "Recursive function."
  51     (let* ((es (ly:music-property music 'elements))
  52            (e (ly:music-property music 'element))
  53            (as (ly:music-property music 'articulations))
  54            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  55            (filtered-e (if (ly:music? e)
  56                            (inner-music-filter pred? e)
  57                            e))
  58            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  59       (set! (ly:music-property music 'element) filtered-e)
  60       (set! (ly:music-property music 'elements) filtered-es)
  61       (set! (ly:music-property music 'articulations) filtered-as)
  62       ;; if filtering emptied the expression, we remove it completely.
  63       (if (or (not (pred? music))
  64               (and (eq? filtered-es '()) (not (ly:music? e))
  65                    (or (not (eq? es '()))
  66                        (ly:music? e))))
  67           (set! music '()))
  68       music))
  69
  70   (set! music (inner-music-filter pred? music))
  71   (if (ly:music? music)
  72       music
  73       (make-music 'Music)))       ;must return music.
  74
  75 (define-public (display-music music)
  76   "Display music, not done with music-map for clarity of presentation."
  77
  78   (display music)
  79   (display ": { ")
  80   (let ((es (ly:music-property music 'elements))
  81         (e (ly:music-property music 'element)))
  82     (display (ly:music-mutable-properties music))
  83     (if (pair? es)
  84         (begin (display "\nElements: {\n")
  85                (map display-music es)
  86                (display "}\n")))
  87     (if (ly:music? e)
  88         (begin
  89           (display "\nChild:")
  90           (display-music e))))
  91   (display " }\n")
  92   music)
  93
  94 ;;;
  95 ;;; A scheme music pretty printer
  96 ;;;
  97 (define (markup-expression->make-markup markup-expression)
  98   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
  99 For instance,
 100   \\markup \\bold \\italic hello
 101 ==>
 102   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 103   (define (proc->command-keyword proc)
 104     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 105     (let ((cmd-markup (symbol->string (procedure-name proc))))
 106       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 107                                                                   (string-length "-markup")))))))
 108   (define (transform-arg arg)
 109     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 110            (apply append (map inner-markup->make-markup arg)))
 111           ((and (not (string? arg)) (markup? arg)) ;; a markup
 112            (inner-markup->make-markup arg))
 113           (else                                  ;; scheme arg
 114            arg)))
 115   (define (inner-markup->make-markup mrkup)
 116     (if (string? mrkup)
 117         `(#:simple ,mrkup)
 118         (let ((cmd (proc->command-keyword (car mrkup)))
 119               (args (map transform-arg (cdr mrkup))))
 120           `(,cmd ,@args))))
 121   ;; body:
 122   (if (string? markup-expression)
 123       markup-expression
 124       `(markup ,@(inner-markup->make-markup markup-expression))))
 125
 126 (define-public (music->make-music obj)
 127   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 128 that is, for a music expression, a (make-music ...) form."
 129   (cond (;; markup expression
 130          (markup? obj)
 131          (markup-expression->make-markup obj))
 132         (;; music expression
 133          (ly:music? obj)
 134          `(make-music
 135            ',(ly:music-property obj 'name)
 136            ,@(apply append (map (lambda (prop)
 137                                   `(',(car prop)
 138                                     ,(music->make-music (cdr prop))))
 139                                 (remove (lambda (prop)
 140                                           (eqv? (car prop) 'origin))
 141                                         (ly:music-mutable-properties obj))))))
 142         (;; moment
 143          (ly:moment? obj)
 144          `(ly:make-moment ,(ly:moment-main-numerator obj)
 145                           ,(ly:moment-main-denominator obj)
 146                           ,(ly:moment-grace-numerator obj)
 147                           ,(ly:moment-grace-denominator obj)))
 148         (;; note duration
 149          (ly:duration? obj)
 150          `(ly:make-duration ,(ly:duration-log obj)
 151                             ,(ly:duration-dot-count obj)
 152                             ,(car (ly:duration-factor obj))
 153                             ,(cdr (ly:duration-factor obj))))
 154         (;; note pitch
 155          (ly:pitch? obj)
 156          `(ly:make-pitch ,(ly:pitch-octave obj)
 157                          ,(ly:pitch-notename obj)
 158                          ,(ly:pitch-alteration obj)))
 159         (;; scheme procedure
 160          (procedure? obj)
 161          (or (procedure-name obj) obj))
 162         (;; a symbol (avoid having an unquoted symbol)
 163          (symbol? obj)
 164          `',obj)
 165         (;; an empty list (avoid having an unquoted empty list)
 166          (null? obj)
 167          `'())
 168         (;; a proper list
 169          (list? obj)
 170          `(list ,@(map music->make-music obj)))
 171         (;; a pair
 172          (pair? obj)
 173          `(cons ,(music->make-music (car obj))
 174                 ,(music->make-music (cdr obj))))
 175         (else
 176          obj)))
 177
 178 (use-modules (ice-9 pretty-print))
 179 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 180   "Displays `obj', typically a music expression, in a friendly fashion,
 181 which often can be read back in order to generate an equivalent expression.
 182
 183 Returns `obj'.
 184 "
 185   (pretty-print (music->make-music obj) port)
 186   (newline)
 187   obj)
 188
 189 ;;;
 190 ;;; Scheme music expression --> Lily-syntax-using string translator
 191 ;;;
 192 (use-modules (srfi srfi-39)
 193              (scm display-lily))
 194
 195 (define*-public (display-lily-music expr parser #:key force-duration)
 196   "Display the music expression using LilyPond syntax"
 197   (memoize-clef-names supported-clefs)
 198   (parameterize ((*indent* 0)
 199                  (*previous-duration* (ly:make-duration 2))
 200                  (*force-duration* force-duration))
 201     (display (music->lily-string expr parser))
 202     (newline)))
 203
 204 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 205
 206 (define-public (shift-one-duration-log music shift dot)
 207   "  add SHIFT to duration-log of 'duration in music and optionally
 208   a dot to any note encountered. This scales the music up by a factor
 209   2^shift * (2 - (1/2)^dot)"
 210   (let ((d (ly:music-property music 'duration)))
 211     (if (ly:duration? d)
 212         (let* ((cp (ly:duration-factor d))
 213                (nd (ly:make-duration (+ shift (ly:duration-log d))
 214                                      (+ dot (ly:duration-dot-count d))
 215                                      (car cp)
 216                                      (cdr cp))))
 217           (set! (ly:music-property music 'duration) nd)))
 218     music))
 219
 220 (define-public (shift-duration-log music shift dot)
 221   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 222              music))
 223
 224 (define-public (make-repeat name times main alts)
 225   "create a repeat music expression, with all properties initialized properly"
 226   (define (first-note-duration music)
 227     "Finds the duration of the first NoteEvent by searching depth-first
 228 through MUSIC."
 229     (if (memq 'note-event (ly:music-property music 'types))
 230         (ly:music-property music 'duration)
 231         (let loop ((elts (if (ly:music? (ly:music-property music 'element))
 232                              (list (ly:music-property music 'element))
 233                              (ly:music-property music 'elements))))
 234           (and (pair? elts)
 235                (let ((dur (first-note-duration (car elts))))
 236                  (if (ly:duration? dur)
 237                      dur
 238                      (loop (cdr elts))))))))
 239
 240   (let ((talts (if (< times (length alts))
 241                    (begin
 242                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 243                      (take alts times))
 244                    alts))
 245         (r (make-repeated-music name)))
 246     (set! (ly:music-property r 'element) main)
 247     (set! (ly:music-property r 'repeat-count) (max times 1))
 248     (set! (ly:music-property r 'elements) talts)
 249     (if (equal? name "tremolo")
 250         (let* ((dots (1- (logcount times)))
 251                (mult (/ (* times (ash 1 dots)) (1- (ash 2 dots))))
 252                (shift (- (ly:intlog2 (floor mult))))
 253                (note-duration (first-note-duration r))
 254                (duration-log (if (ly:duration? note-duration)
 255                                  (ly:duration-log note-duration)
 256                                  1))
 257                (tremolo-type (ash 1 duration-log)))
 258           (set! (ly:music-property r 'tremolo-type) tremolo-type)
 259           (if (not (integer?  mult))
 260               (ly:warning (_ "invalid tremolo repeat count: ~a") times))
 261           (if (memq 'sequential-music (ly:music-property main 'types))
 262               ;; \repeat "tremolo" { c4 d4 }
 263               (let ((children (length (ly:music-property main 'elements))))
 264
 265                 ;; fixme: should be more generic.
 266                 (if (and (not (= children 2))
 267                          (not (= children 1)))
 268                     (ly:warning (_ "expecting 2 elements for chord tremolo, found ~a") children))
 269                 (ly:music-compress r (ly:make-moment 1 children))
 270                 (shift-duration-log r
 271                                     (if (= children 2)  (1- shift) shift)
 272                                     dots))
 273               ;; \repeat "tremolo" c4
 274               (shift-duration-log r shift dots)))
 275         r)))
 276
 277 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 278 ;; clusters.
 279
 280 (define-public (note-to-cluster music)
 281   "Replace NoteEvents by ClusterNoteEvents."
 282   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 283       (make-music 'ClusterNoteEvent
 284                   'pitch (ly:music-property music 'pitch)
 285                   'duration (ly:music-property music 'duration))
 286       music))
 287
 288 (define-public (notes-to-clusters music)
 289   (music-map note-to-cluster music))
 290
 291 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 292 ;; repeats.
 293
 294 (define-public (unfold-repeats music)
 295   "
 296 This function replaces all repeats  with unfold repeats. "
 297
 298   (let ((es (ly:music-property music 'elements))
 299         (e  (ly:music-property music 'element))
 300         )
 301     (if (memq 'repeated-music (ly:music-property music 'types))
 302         (let*
 303             ((props (ly:music-mutable-properties music))
 304              (old-name (ly:music-property music 'name))
 305              (flattened  (flatten-alist props)))
 306
 307           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 308                                               flattened)))
 309
 310           (if (equal? old-name 'TremoloRepeatedMusic)
 311               (let* ((seq-arg? (memq 'sequential-music
 312                                      (ly:music-property e 'types)))
 313                      (count  (ly:music-property music 'repeat-count))
 314                      (dot-shift (if (= 0 (remainder count 3))
 315                                     -1 0)))
 316
 317                 (if (= 0 -1)
 318                     (set! count (* 2 (quotient count 3))))
 319
 320                 (shift-duration-log music (+ (if seq-arg? 1 0)
 321                                              (ly:intlog2 count)) dot-shift)
 322
 323                 (if seq-arg?
 324                     (ly:music-compress e (ly:make-moment (length (ly:music-property
 325                                                                   e 'elements)) 1)))))))
 326
 327
 328     (if (pair? es)
 329         (set! (ly:music-property music 'elements)
 330               (map unfold-repeats es)))
 331     (if (ly:music? e)
 332         (set! (ly:music-property music 'element)
 333               (unfold-repeats e)))
 334     music))
 335
 336 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 337 ;; property setting music objs.
 338
 339 (define-public (make-grob-property-set grob gprop val)
 340   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 341 i.e.  this is not an override"
 342   (make-music 'OverrideProperty
 343               'symbol grob
 344               'grob-property gprop
 345               'grob-value val
 346               'pop-first #t))
 347
 348 (define-public (make-grob-property-override grob gprop val)
 349   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 350 i.e.  this is not an override"
 351   (make-music 'OverrideProperty
 352               'symbol grob
 353               'grob-property gprop
 354               'grob-value val))
 355
 356 (define-public (make-grob-property-revert grob gprop)
 357   "Revert the grob property GPROP for GROB."
 358   (make-music 'RevertProperty
 359               'symbol grob
 360               'grob-property gprop))
 361
 362 (define direction-polyphonic-grobs
 363   '(DotColumn
 364     Dots
 365     Fingering
 366     LaissezVibrerTie
 367     PhrasingSlur
 368     RepeatTie
 369     Rest
 370     Script
 371     Slur
 372     Stem
 373     TextScript
 374     Tie))
 375
 376 (define-safe-public (make-voice-props-set n)
 377   (make-sequential-music
 378    (append
 379     (map (lambda (x) (make-grob-property-set x 'direction
 380                                              (if (odd? n) -1 1)))
 381          direction-polyphonic-grobs)
 382     (list
 383      (make-property-set 'graceSettings
 384                         ;; TODO: take this from voicedGraceSettings or similar.
 385                         '((Voice Stem font-size -3)
 386                           (Voice NoteHead font-size -3)
 387                           (Voice Dots font-size -3)
 388                           (Voice Stem length-fraction 0.8)
 389                           (Voice Stem no-stem-extend #t)
 390                           (Voice Beam thickness 0.384)
 391                           (Voice Beam length-fraction 0.8)
 392                           (Voice Accidental font-size -4)))
 393
 394      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 395      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 396
 397 (define-safe-public (make-voice-props-revert)
 398   (make-sequential-music
 399    (append
 400     (map (lambda (x) (make-grob-property-revert x 'direction))
 401          direction-polyphonic-grobs)
 402     (list (make-property-unset 'graceSettings)
 403           (make-grob-property-revert 'NoteColumn 'horizontal-shift)
 404           (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 405
 406
 407 (define-safe-public (context-spec-music m context #:optional id)
 408   "Add \\context CONTEXT = ID to M. "
 409   (let ((cm (make-music 'ContextSpeccedMusic
 410                         'element m
 411                         'context-type context)))
 412     (if (string? id)
 413         (set! (ly:music-property cm 'context-id) id))
 414     cm))
 415
 416 (define-public (descend-to-context m context)
 417   "Like context-spec-music, but only descending. "
 418   (let ((cm (context-spec-music m context)))
 419     (ly:music-set-property! cm 'descend-only #t)
 420     cm))
 421
 422 (define-public (make-non-relative-music mus)
 423   (make-music 'UnrelativableMusic
 424               'element mus))
 425
 426 (define-public (make-apply-context func)
 427   (make-music 'ApplyContext
 428               'procedure func))
 429
 430 (define-public (make-sequential-music elts)
 431   (make-music 'SequentialMusic
 432               'elements elts))
 433
 434 (define-public (make-simultaneous-music elts)
 435   (make-music 'SimultaneousMusic
 436               'elements elts))
 437
 438 (define-safe-public (make-event-chord elts)
 439   (make-music 'EventChord
 440               'elements elts))
 441
 442 (define-public (make-skip-music dur)
 443   (make-music 'SkipMusic
 444               'duration dur))
 445
 446 (define-public (make-grace-music music)
 447   (make-music 'GraceMusic
 448               'element music))
 449
 450 ;;;;;;;;;;;;;;;;
 451
 452 ;; mmrest
 453 (define-public (make-multi-measure-rest duration location)
 454   (make-music 'MultiMeasureRestMusic
 455               'origin location
 456               'duration duration))
 457
 458 (define-public (make-property-set sym val)
 459   (make-music 'PropertySet
 460               'symbol sym
 461               'value val))
 462
 463 (define-public (make-property-unset sym)
 464   (make-music 'PropertyUnset
 465               'symbol sym))
 466
 467 (define-public (make-ottava-set octavation)
 468   (let ((m (make-music 'ApplyContext)))
 469     (define (ottava-modify context)
 470       "Either reset middleCPosition to the stored original, or remember
 471 old middleCPosition, add OCTAVATION to middleCPosition, and set
 472 OTTAVATION to `8va', or whatever appropriate."
 473       (if (number? (ly:context-property  context 'middleCOffset))
 474           (let ((where (ly:context-property-where-defined context 'middleCOffset)))
 475             (ly:context-unset-property where 'middleCOffset)
 476             (ly:context-unset-property where 'ottavation)))
 477
 478       (let* ((offset (* -7 octavation))
 479              (string (cdr (assoc octavation '((2 . "15ma")
 480                                               (1 . "8va")
 481                                               (0 . #f)
 482                                               (-1 . "8vb")
 483                                               (-2 . "15mb"))))))
 484         (ly:context-set-property! context 'middleCOffset offset)
 485         (ly:context-set-property! context 'ottavation string)
 486         (ly:set-middle-C! context)))
 487     (set! (ly:music-property m 'procedure) ottava-modify)
 488     (context-spec-music m 'Staff)))
 489
 490 (define-public (set-octavation ottavation)
 491   (ly:export (make-ottava-set ottavation)))
 492
 493 (define-public (make-time-signature-set num den . rest)
 494   "Set properties for time signature NUM/DEN.  Rest can contain a list
 495 of beat groupings "
 496
 497   (define (standard-beat-grouping num den)
 498
 499     "Some standard subdivisions for time signatures."
 500     (let*
 501         ((key (cons num den))
 502          (entry (assoc key '(((6 . 8) . (3 3))
 503                          ((5 . 8) . (3 2))
 504                          ((9 . 8) . (3 3 3))
 505                          ((12 . 8) . (3 3 3 3))
 506                          ((8 . 8) . (3 3 2))
 507                          ))))
 508
 509       (if entry
 510           (cdr entry)
 511           '())))
 512
 513   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 514          (beat (ly:make-moment 1 den))
 515          (len  (ly:make-moment num den))
 516          (set2 (make-property-set 'beatLength beat))
 517          (set3 (make-property-set 'measureLength len))
 518          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 519                                                     (car rest)
 520                                                     (standard-beat-grouping num den))))
 521          (basic  (list set1 set2 set3 set4)))
 522     (descend-to-context
 523      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 524
 525 (define-public (make-mark-set label)
 526   "Make the music for the \\mark command."
 527   (let* ((set (if (integer? label)
 528                   (context-spec-music (make-property-set 'rehearsalMark label)
 529                                       'Score)
 530                   #f))
 531          (ev (make-music 'MarkEvent))
 532          (ch (make-event-chord (list ev))))
 533     (if set
 534         (make-sequential-music (list set ch))
 535         (begin
 536           (set! (ly:music-property ev 'label) label)
 537           ch))))
 538
 539 (define-public (set-time-signature num den . rest)
 540   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 541
 542 (define-safe-public (make-articulation name)
 543   (make-music 'ArticulationEvent
 544               'articulation-type name))
 545
 546 (define-public (make-lyric-event string duration)
 547   (make-music 'LyricEvent
 548               'duration duration
 549               'text string))
 550
 551 (define-safe-public (make-span-event type span-dir)
 552   (make-music type
 553               'span-direction span-dir))
 554
 555 (define-public (set-mus-properties! m alist)
 556   "Set all of ALIST as properties of M."
 557   (if (pair? alist)
 558       (begin
 559         (set! (ly:music-property m (caar alist)) (cdar alist))
 560         (set-mus-properties! m (cdr alist)))))
 561
 562 (define-public (music-separator? m)
 563   "Is M a separator?"
 564   (let ((ts (ly:music-property m 'types)))
 565     (memq 'separator ts)))
 566
 567 ;;; splitting chords into voices.
 568 (define (voicify-list lst number)
 569   "Make a list of Musics.
 570
 571    voicify-list :: [ [Music ] ] -> number -> [Music]
 572    LST is a list music-lists.
 573
 574    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 575 "
 576   (if (null? lst)
 577       '()
 578       (cons (context-spec-music
 579              (make-sequential-music
 580               (list (make-voice-props-set number)
 581                     (make-simultaneous-music (car lst))))
 582              'Voice  (number->string (1+ number)))
 583             (voicify-list (cdr lst) (1+ number)))))
 584
 585 (define (voicify-chord ch)
 586   "Split the parts of a chord into different Voices using separator"
 587   (let ((es (ly:music-property ch 'elements)))
 588     (set! (ly:music-property  ch 'elements)
 589           (voicify-list (split-list-by-separator es music-separator?) 0))
 590     ch))
 591
 592 (define-public (voicify-music m)
 593   "Recursively split chords that are separated with \\ "
 594   (if (not (ly:music? m))
 595       (ly:error (_ "music expected: ~S") m))
 596   (let ((es (ly:music-property m 'elements))
 597         (e (ly:music-property m 'element)))
 598
 599     (if (pair? es)
 600         (set! (ly:music-property m 'elements) (map voicify-music es)))
 601     (if (ly:music? e)
 602         (set! (ly:music-property m 'element)  (voicify-music e)))
 603     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 604              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 605         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 606     m))
 607
 608 (define-public (empty-music)
 609   (ly:export (make-music 'Music)))
 610
 611 ;; Make a function that checks score element for being of a specific type.
 612 (define-public (make-type-checker symbol)
 613   (lambda (elt)
 614     ;;(display  symbol)
 615     ;;(eq? #t (ly:grob-property elt symbol))
 616     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 617
 618 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 619   (if (func grob)
 620       (set! (ly:grob-property grob sym) val)))
 621
 622
 623 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 624   "Usage:
 625
 626 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 627
 628 "
 629   (let ((meta (ly:grob-property grob 'meta)))
 630     (if (equal?  (cdr (assoc 'name meta)) grob-name)
 631         (set! (ly:grob-property grob symbol) val))))
 632
 633
 634 ;;
 635 (define-public (smart-bar-check n)
 636   "Make  a bar check that checks for a specific bar number.
 637 "
 638   (let ((m (make-music 'ApplyContext)))
 639     (define (checker tr)
 640       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 641         (if (= bn n)
 642             #t
 643             (ly:error
 644              ;; FIXME: uncomprehensable message
 645              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 646              n bn))))
 647     (set! (ly:music-property m 'procedure) checker)
 648     m))
 649
 650
 651 (define-public (skip->rest mus)
 652
 653   "Replace MUS by RestEvent of the same duration if it is a
 654 SkipEvent. Useful for extracting parts from crowded scores"
 655
 656   (if  (memq (ly:music-property mus 'name) '(SkipEvent SkipMusic))
 657    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 658    mus))
 659
 660
 661 (define-public (music-has-type music type)
 662   (memq type (ly:music-property music 'types)))
 663
 664 (define-public (music-clone music)
 665   (define (alist->args alist acc)
 666     (if (null? alist)
 667         acc
 668         (alist->args (cdr alist)
 669                      (cons (caar alist) (cons (cdar alist) acc)))))
 670
 671   (apply
 672    make-music
 673    (ly:music-property music 'name)
 674    (alist->args (ly:music-mutable-properties music) '())))
 675
 676 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 677 ;; warn for bare chords at start.
 678
 679
 680 (define-public (ly:music-message music msg)
 681   (let ((ip (ly:music-property music 'origin)))
 682     (if (ly:input-location? ip)
 683         (ly:input-message ip msg)
 684         (ly:warning msg))))
 685
 686 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 687 ;;
 688 ;; setting stuff for grace context.
 689 ;;
 690
 691 (define (vector-extend v x)
 692   "Make a new vector consisting of V, with X added to the end."
 693   (let* ((n (vector-length v))
 694          (nv (make-vector (+ n 1) '())))
 695     (vector-move-left! v 0 n nv 0)
 696     (vector-set! nv n x)
 697     nv))
 698
 699 (define (vector-map f v)
 700   "Map  F over V. This function returns nothing."
 701   (do ((n (vector-length v))
 702        (i 0 (+ i 1)))
 703       ((>= i n))
 704     (f (vector-ref v i))))
 705
 706 (define (vector-reverse-map f v)
 707   "Map  F over V, N to 0 order. This function returns nothing."
 708   (do ((i (- (vector-length v) 1) (- i 1)))
 709       ((< i 0))
 710     (f (vector-ref v i))))
 711
 712 (define-public (add-grace-property context-name grob sym val)
 713   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 714   (define (set-prop context)
 715     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 716            (current (ly:context-property where 'graceSettings))
 717            (new-settings (append current
 718                                  (list (list context-name grob sym val)))))
 719       (ly:context-set-property! where 'graceSettings new-settings)))
 720   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 721
 722 (define-public (remove-grace-property context-name grob sym)
 723   "Remove all SYM for GROB in CONTEXT-NAME. "
 724   (define (sym-grob-context? property sym grob context-name)
 725     (and (eq? (car property) context-name)
 726          (eq? (cadr property) grob)
 727          (eq? (caddr property) sym)))
 728   (define (delete-prop context)
 729     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 730            (current (ly:context-property where 'graceSettings))
 731            (prop-settings (filter
 732                             (lambda(x) (sym-grob-context? x sym grob context-name))
 733                             current))
 734            (new-settings current))
 735       (for-each (lambda(x)
 736                  (set! new-settings (delete x new-settings)))
 737                prop-settings)
 738       (ly:context-set-property! where 'graceSettings new-settings)))
 739   (ly:export (context-spec-music (make-apply-context delete-prop) 'Voice)))
 740
 741
 742
 743 (defmacro-public def-grace-function (start stop . docstring)
 744   "Helper macro for defining grace music"
 745   `(define-music-function (parser location music) (ly:music?)
 746      ,@docstring
 747      (make-music 'GraceMusic
 748                  'origin location
 749                  'element (make-music 'SequentialMusic
 750                                       'elements (list (ly:music-deep-copy ,start)
 751                                                       music
 752                                                       (ly:music-deep-copy ,stop))))))
 753
 754 (defmacro-public define-music-function (args signature . body)
 755   "Helper macro for `ly:make-music-function'.
 756 Syntax:
 757   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 758     ...function body...)
 759 "
 760 (if (and (pair? body) (pair? (car body)) (eqv? '_i (caar body)))
 761       ;; When the music function definition contains a i10n doc string,
 762       ;; (_i "doc string"), keep the literal string only
 763       (let ((docstring (cadar body))
 764             (body (cdr body)))
 765         `(ly:make-music-function (list ,@signature)
 766                                  (lambda (,@args)
 767                                    ,docstring
 768                                    ,@body)))
 769       `(ly:make-music-function (list ,@signature)
 770                                (lambda (,@args)
 771                                  ,@body))))
 772
 773
 774 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 775
 776 (define-public (cue-substitute quote-music)
 777   "Must happen after quote-substitute."
 778
 779   (if (vector? (ly:music-property quote-music 'quoted-events))
 780       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 781              (main-voice (if (eq? 1 dir) 1 0))
 782              (cue-voice (if (eq? 1 dir) 0 1))
 783              (main-music (ly:music-property quote-music 'element))
 784              (return-value quote-music))
 785
 786         (if (or (eq? 1 dir) (eq? -1 dir))
 787
 788             ;; if we have stem dirs, change both quoted and main music
 789             ;; to have opposite stems.
 790             (begin
 791               (set! return-value
 792
 793                     ;; cannot context-spec Quote-music, since context
 794                     ;; for the quotes is determined in the iterator.
 795                     (make-sequential-music
 796                      (list
 797                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 798                       quote-music
 799                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 800               (set! main-music
 801                     (make-sequential-music
 802                      (list
 803                       (make-voice-props-set main-voice)
 804                       main-music
 805                       (make-voice-props-revert))))
 806               (set! (ly:music-property quote-music 'element) main-music)))
 807
 808         return-value)
 809       quote-music))
 810
 811 (define-public ((quote-substitute quote-tab) music)
 812   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 813          (quoted-vector (if (string? quoted-name)
 814                             (hash-ref quote-tab quoted-name #f)
 815                             #f)))
 816
 817
 818     (if (string? quoted-name)
 819         (if (vector? quoted-vector)
 820             (begin
 821               (set! (ly:music-property music 'quoted-events) quoted-vector)
 822               (set! (ly:music-property music 'iterator-ctor)
 823                     ly:quote-iterator::constructor))
 824             (ly:warning (_ "cannot find quoted music: `~S'") quoted-name)))
 825     music))
 826
 827
 828 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 829 ;; switch it on here, so parsing and init isn't checked (too slow!)
 830 ;;
 831 ;; automatic music transformations.
 832
 833 (define (switch-on-debugging m)
 834   (if (defined? 'set-debug-cell-accesses!)
 835       (set-debug-cell-accesses! 15000))
 836   m)
 837
 838 (define (music-check-error music)
 839   (define found #f)
 840   (define (signal m)
 841     (if (and (ly:music? m)
 842              (eq? (ly:music-property m 'error-found) #t))
 843         (set! found #t)))
 844
 845   (for-each signal (ly:music-property music 'elements))
 846   (signal (ly:music-property music 'element))
 847
 848   (if found
 849       (set! (ly:music-property music 'error-found) #t))
 850   music)
 851
 852 (define (precompute-music-length music)
 853   (set! (ly:music-property music 'length)
 854         (ly:music-length music))
 855   music)
 856
 857 (define-public (make-duration-of-length moment)
 858  "Make duration of the given MOMENT length."
 859  (ly:make-duration 0 0
 860   (ly:moment-main-numerator moment)
 861   (ly:moment-main-denominator moment)))
 862
 863 (define (skip-this moment)
 864  "set skipTypesetting, make SkipMusic of the given MOMENT length,
 865  and then unset skipTypesetting."
 866  (make-sequential-music
 867   (list
 868    (context-spec-music (make-property-set 'skipTypesetting #t)
 869     'Score)
 870    (make-music 'SkipMusic 'duration
 871     (make-duration-of-length moment))
 872    (context-spec-music (make-property-set 'skipTypesetting #f)
 873     'Score))))
 874
 875 (define (unskip-this moment)
 876  "unset skipTypesetting, make SkipMusic of the given MOMENT length,
 877  and then set skipTypesetting."
 878  (make-sequential-music
 879   (list
 880    (context-spec-music (make-property-set 'skipTypesetting #f)
 881     'Score)
 882    (make-music 'SkipMusic 'duration
 883     (make-duration-of-length moment))
 884    (context-spec-music (make-property-set 'skipTypesetting #t)
 885     'Score))))
 886
 887 (define (skip-as-needed music parser)
 888  "Replace MUSIC by
 889  << {  \\set skipTypesetting = ##f
 890  LENGTHOF(\\showFirstLength)
 891  \\set skipTypesetting = ##t
 892  LENGTHOF(\\showLastLength) }
 893  MUSIC >>
 894  if appropriate.
 895
 896  When only showFirstLength is set,
 897  the 'length property of the music is
 898  overridden to speed up compiling."
 899  (let*
 900   ((show-last (ly:parser-lookup parser 'showLastLength))
 901    (show-first (ly:parser-lookup parser 'showFirstLength)))
 902   (cond
 903
 904    ;; both properties may be set.
 905    ((and (ly:music? show-first) (ly:music? show-last))
 906     (let*
 907      ((orig-length (ly:music-length music))
 908       (skip-length (ly:moment-sub orig-length (ly:music-length show-last)))
 909       (begin-length (ly:music-length show-first)))
 910      (make-simultaneous-music
 911       (list
 912        (make-sequential-music
 913         (list
 914          (skip-this skip-length)
 915          ;; let's draw a separator between the beginning and the end
 916          (context-spec-music (make-property-set 'whichBar "||")
 917           'Timing)))
 918        (unskip-this begin-length)
 919        music))))
 920
 921    ;; we may only want to print the last length
 922    ((ly:music? show-last)
 923     (let*
 924      ((orig-length (ly:music-length music))
 925       (skip-length (ly:moment-sub orig-length (ly:music-length show-last))))
 926      (make-simultaneous-music
 927       (list
 928        (skip-this skip-length)
 929        music))))
 930
 931    ;; we may only want to print the beginning; in this case
 932    ;; only the first length will be processed (much faster).
 933    ((ly:music? show-first)
 934     (let*
 935      ((orig-length (ly:music-length music))
 936       (begin-length (ly:music-length show-first)))
 937      ;; the first length must not exceed the original length.
 938      (if (ly:moment<? begin-length orig-length)
 939       (set! (ly:music-property music 'length)
 940        (ly:music-length show-first)))
 941      music))
 942
 943    (else music))))
 944
 945
 946 (define-public toplevel-music-functions
 947   (list
 948    (lambda (music parser) (voicify-music music))
 949    (lambda (x parser) (music-map music-check-error x))
 950    (lambda (x parser) (music-map precompute-music-length x))
 951    (lambda (music parser)
 952
 953      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 954
 955    ;; switch-on-debugging
 956    (lambda (x parser) (music-map cue-substitute x))
 957
 958    (lambda (x parser)
 959      (skip-as-needed x parser)
 960    )))
 961
 962 ;;;;;;;;;;
 963 ;;; general purpose music functions
 964
 965 (define (shift-octave pitch octave-shift)
 966   (_i "Add @var{octave-shift} to the octave of @var{pitch}.")
 967   (ly:make-pitch
 968      (+ (ly:pitch-octave pitch) octave-shift)
 969      (ly:pitch-notename pitch)
 970      (ly:pitch-alteration pitch)))
 971
 972
 973 ;;;;;;;;;;;;;;;;;
 974 ;; lyrics
 975
 976 (define (apply-durations lyric-music durations)
 977   (define (apply-duration music)
 978     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 979              (ly:duration?  (ly:music-property music 'duration)))
 980         (begin
 981           (set! (ly:music-property music 'duration) (car durations))
 982           (set! durations (cdr durations)))))
 983
 984   (music-map apply-duration lyric-music))
 985
 986
 987 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 988 ;; accidentals
 989
 990 (define (recent-enough? bar-number alteration-def laziness)
 991   (if (or (number? alteration-def)
 992           (equal? laziness #t))
 993       #t
 994       (<= bar-number (+ (cadr alteration-def) laziness))))
 995
 996 (define (is-tied? alteration-def)
 997   (let* ((def (if (pair? alteration-def)
 998                  (car alteration-def)
 999                  alteration-def)))
1000
1001     (if (equal? def 'tied) #t #f)))
1002
1003 (define (extract-alteration alteration-def)
1004   (cond ((number? alteration-def)
1005          alteration-def)
1006         ((pair? alteration-def)
1007          (car alteration-def))
1008         (else 0)))
1009
1010 (define (check-pitch-against-signature context pitch barnum laziness octaveness)
1011   "Checks the need for an accidental and a @q{restore} accidental against
1012 @code{localKeySignature}. The @var{laziness} is the number of measures
1013 for which reminder accidentals are used (i.e., if @var{laziness} is zero,
1014 only cancel accidentals in the same measure; if @var{laziness} is three,
1015 we cancel accidentals up to three measures after they first appear.
1016 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1017 specifies whether accidentals should be canceled in different octaves."
1018   (let* ((ignore-octave (cond ((equal? octaveness 'any-octave) #t)
1019                               ((equal? octaveness 'same-octave) #f)
1020                               (else
1021                                (ly:warning (_ "Unknown octaveness type: ~S ") octaveness)
1022                                (ly:warning (_ "Defaulting to 'any-octave."))
1023                                #t)))
1024          (key-sig (ly:context-property context 'keySignature))
1025          (local-key-sig (ly:context-property context 'localKeySignature))
1026          (notename (ly:pitch-notename pitch))
1027          (octave (ly:pitch-octave pitch))
1028          (pitch-handle (cons octave notename))
1029          (need-restore #f)
1030          (need-accidental #f)
1031          (previous-alteration #f)
1032          (from-other-octaves #f)
1033          (from-same-octave (ly:assoc-get pitch-handle local-key-sig))
1034          (from-key-sig (ly:assoc-get notename local-key-sig)))
1035
1036     ;; If no key signature match is found from localKeySignature, we may have a custom
1037     ;; type with octave-specific entries of the form ((octave . pitch) alteration)
1038     ;; instead of (pitch . alteration).  Since this type cannot coexist with entries in
1039     ;; localKeySignature, try extracting from keySignature instead.
1040     (if (equal? from-key-sig #f)
1041         (set! from-key-sig (ly:assoc-get pitch-handle key-sig)))
1042
1043     ;; loop through localKeySignature to search for a notename match from other octaves
1044     (let loop ((l local-key-sig))
1045       (if (pair? l)
1046           (let ((entry (car l)))
1047             (if (and (pair? (car entry))
1048                      (= (cdar entry) notename))
1049                 (set! from-other-octaves (cdr entry))
1050                 (loop (cdr l))))))
1051
1052     ;; find previous alteration-def for comparison with pitch
1053     (cond
1054      ;; from same octave?
1055      ((and (eq? ignore-octave #f)
1056            (not (equal? from-same-octave #f))
1057            (recent-enough? barnum from-same-octave laziness))
1058       (set! previous-alteration from-same-octave))
1059
1060      ;; from any octave?
1061      ((and (eq? ignore-octave #t)
1062            (not (equal? from-other-octaves #f))
1063            (recent-enough? barnum from-other-octaves laziness))
1064       (set! previous-alteration from-other-octaves))
1065
1066      ;; not recent enough, extract from key signature/local key signature
1067      ((not (equal? from-key-sig #f))
1068       (set! previous-alteration from-key-sig)))
1069
1070     (if (is-tied? previous-alteration)
1071         (set! need-accidental #t)
1072
1073         (let* ((prev-alt (extract-alteration previous-alteration))
1074                (this-alt (ly:pitch-alteration pitch)))
1075
1076           (if (not (= this-alt prev-alt))
1077               (begin
1078                 (set! need-accidental #t)
1079                 (if (and (not (= this-alt 0))
1080                          (or (< (abs this-alt) (abs prev-alt))
1081                              (< (* prev-alt this-alt) 0)))
1082                     (set! need-restore #t))))))
1083
1084     (cons need-restore need-accidental)))
1085
1086 (define-public ((make-accidental-rule octaveness laziness) context pitch barnum measurepos)
1087   "Creates an accidental rule that makes its decision based on the octave of the note
1088   and a laziness value.
1089   octaveness is either 'same-octave or 'any-octave and defines whether the rule should
1090   respond to accidental changes in other octaves than the current. 'same-octave is the
1091   normal way to typeset accidentals - an accidental is made if the alteration is different
1092   from the last active pitch in the same octave. 'any-octave looks at the last active pitch
1093   in any octave.
1094   laziness states over how many bars an accidental should be remembered.
1095   0 is default - accidental lasts over 0 bar lines, that is, to the end of current measure.
1096   A positive integer means that the accidental lasts over that many bar lines.
1097   -1 is 'forget immediately', that is, only look at key signature.
1098   #t is forever."
1099   (check-pitch-against-signature context pitch barnum laziness octaveness))
1100
1101 (define (key-entry-notename entry)
1102   "Return the pitch of an entry in localKeySignature. The entry is either of the form
1103   '(notename . alter) or '((octave . notename) . (alter barnum . measurepos))."
1104   (if (number? (car entry))
1105       (car entry)
1106       (cdar entry)))
1107
1108 (define (key-entry-octave entry)
1109   "Return the octave of an entry in localKeySignature (or #f if the entry does not have
1110   an octave)."
1111   (and (pair? (car entry)) (caar entry)))
1112
1113 (define (key-entry-bar-number entry)
1114   "Return the bar number of an entry in localKeySignature (or #f if the entry does not
1115   have a bar number)."
1116   (and (pair? (car entry)) (caddr entry)))
1117
1118 (define (key-entry-measure-position entry)
1119   "Return the measure position of an entry in localKeySignature (or #f if the entry does
1120   not have a measure position)."
1121   (and (pair? (car entry)) (cdddr entry)))
1122
1123 (define (key-entry-alteration entry)
1124   "Return the alteration of an entry in localKeySignature."
1125   (if (number? (car entry))
1126       (cdr entry)
1127       (cadr entry)))
1128
1129 (define-public (find-pitch-entry keysig pitch accept-global accept-local)
1130   "Return the first entry in keysig that matches the pitch.
1131   accept-global states whether key signature entries should be included.
1132   accept-local states whether local accidentals should be included.
1133   if no matching entry is found, #f is returned."
1134   (if (pair? keysig)
1135       (let* ((entry (car keysig))
1136              (entryoct (key-entry-octave entry))
1137              (entrynn (key-entry-notename entry))
1138              (oct (ly:pitch-octave pitch))
1139              (nn (ly:pitch-notename pitch)))
1140         (if (and (equal? nn entrynn)
1141                  (or (and accept-global (equal? #f entryoct))
1142                      (and accept-local (equal? oct entryoct))))
1143             entry
1144             (find-pitch-entry (cdr keysig) pitch accept-global accept-local)))
1145       #f))
1146
1147 (define-public (neo-modern-accidental-rule context pitch barnum measurepos)
1148   "an accidental rule that typesets an accidental if it differs from the key signature
1149    AND does not directly follow a note on the same staff-line.
1150    This rule should not be used alone because it does neither look at bar lines
1151    nor different accidentals at the same notename"
1152   (let* ((keysig (ly:context-property context 'localKeySignature))
1153          (entry (find-pitch-entry keysig pitch #t #t)))
1154     (if (equal? #f entry)
1155         (cons #f #f)
1156         (let* ((global-entry (find-pitch-entry keysig pitch #t #f))
1157                (key-acc (if (equal? global-entry #f)
1158                             0
1159                             (key-entry-alteration global-entry)))
1160                (acc (ly:pitch-alteration pitch))
1161                (entrymp (key-entry-measure-position entry))
1162                (entrybn (key-entry-bar-number entry)))
1163           (cons #f (not (or (equal? acc key-acc)
1164                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1165
1166 (define-public (teaching-accidental-rule context pitch barnum measurepos)
1167   "an accidental rule that typesets a cautionary accidental
1168   if it is included in the key signature AND does not directly follow
1169   a note on the same staff-line."
1170   (let* ((keysig (ly:context-property context 'localKeySignature))
1171          (entry (find-pitch-entry keysig pitch #t #t)))
1172     (if (equal? #f entry)
1173         (cons #f #f)
1174         (let* ((global-entry (find-pitch-entry keysig pitch #f #f))
1175                (key-acc (if (equal? global-entry #f)
1176                             0
1177                             (key-entry-alteration global-entry)))
1178                (acc (ly:pitch-alteration pitch))
1179                (entrymp (key-entry-measure-position entry))
1180                (entrybn (key-entry-bar-number entry)))
1181           (cons #f (not (or (equal? acc key-acc)
1182                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1183
1184 (define-public (set-accidentals-properties extra-natural
1185                                            auto-accs auto-cauts
1186                                            context)
1187   (context-spec-music
1188    (make-sequential-music
1189     (append (if (boolean? extra-natural)
1190                 (list (make-property-set 'extraNatural extra-natural))
1191                 '())
1192             (list (make-property-set 'autoAccidentals auto-accs)
1193                   (make-property-set 'autoCautionaries auto-cauts))))
1194    context))
1195
1196 (define-public (set-accidental-style style . rest)
1197   "Set accidental style to STYLE. Optionally takes a context argument,
1198 e.g. 'Staff or 'Voice. The context defaults to Staff, except for piano styles, which
1199 use GrandStaff as a context. "
1200   (let ((context (if (pair? rest)
1201                      (car rest) 'Staff))
1202         (pcontext (if (pair? rest)
1203                       (car rest) 'GrandStaff)))
1204     (ly:export
1205      (cond
1206       ;; accidentals as they were common in the 18th century.
1207       ((equal? style 'default)
1208        (set-accidentals-properties #t
1209                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1210                                    '()
1211                                    context))
1212       ;; accidentals from one voice do NOT get cancelled in other voices
1213       ((equal? style 'voice)
1214        (set-accidentals-properties #t
1215                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1216                                    '()
1217                                    context))
1218       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
1219       ;; This includes all the default accidentals, but accidentals also needs cancelling
1220       ;; in other octaves and in the next measure.
1221       ((equal? style 'modern)
1222        (set-accidentals-properties #f
1223                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1224                                            ,(make-accidental-rule 'any-octave 0)
1225                                            ,(make-accidental-rule 'same-octave 1))
1226                                    '()
1227                                    context))
1228       ;; the accidentals that Stone adds to the old standard as cautionaries
1229       ((equal? style 'modern-cautionary)
1230        (set-accidentals-properties #f
1231                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1232                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1233                                            ,(make-accidental-rule 'same-octave 1))
1234                                    context))
1235       ;; same as modern, but accidentals different from the key signature are always
1236       ;; typeset - unless they directly follow a note of the same pitch.
1237       ((equal? style 'neo-modern)
1238        (set-accidentals-properties #f
1239                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1240                                            ,(make-accidental-rule 'any-octave 0)
1241                                            ,(make-accidental-rule 'same-octave 1)
1242                                            ,neo-modern-accidental-rule)
1243                                    '()
1244                                    context))
1245       ((equal? style 'neo-modern-cautionary)
1246        (set-accidentals-properties #f
1247                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1248                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1249                                            ,(make-accidental-rule 'same-octave 1)
1250                                            ,neo-modern-accidental-rule)
1251                                    context))
1252       ;; Accidentals as they were common in dodecaphonic music with no tonality.
1253       ;; Each note gets one accidental.
1254       ((equal? style 'dodecaphonic)
1255        (set-accidentals-properties #f
1256                                    `(Staff ,(lambda (c p bn mp) '(#f . #t)))
1257                                    '()
1258                                    context))
1259       ;; Multivoice accidentals to be read both by musicians playing one voice
1260       ;; and musicians playing all voices.
1261       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
1262       ((equal? style 'modern-voice)
1263        (set-accidentals-properties  #f
1264                                     `(Voice ,(make-accidental-rule 'same-octave 0)
1265                                             ,(make-accidental-rule 'any-octave 0)
1266                                             ,(make-accidental-rule 'same-octave 1)
1267                                       Staff ,(make-accidental-rule 'same-octave 0)
1268                                             ,(make-accidental-rule 'any-octave 0)
1269                                             ,(make-accidental-rule 'same-octave 1))
1270                                     '()
1271                                     context))
1272       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
1273       ;; as cautionaries
1274       ((equal? style 'modern-voice-cautionary)
1275        (set-accidentals-properties #f
1276                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1277                                    `(Voice ,(make-accidental-rule 'any-octave 0)
1278                                            ,(make-accidental-rule 'same-octave 1)
1279                                      Staff ,(make-accidental-rule 'same-octave 0)
1280                                            ,(make-accidental-rule 'any-octave 0)
1281                                            ,(make-accidental-rule 'same-octave 1))
1282                                    context))
1283       ;; stone's suggestions for accidentals on grand staff.
1284       ;; Accidentals are cancelled across the staves in the same grand staff as well
1285       ((equal? style 'piano)
1286        (set-accidentals-properties #f
1287                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1288                                            ,(make-accidental-rule 'any-octave 0)
1289                                            ,(make-accidental-rule 'same-octave 1)
1290                                      GrandStaff
1291                                            ,(make-accidental-rule 'any-octave 0)
1292                                            ,(make-accidental-rule 'same-octave 1))
1293                                    '()
1294                                    pcontext))
1295       ((equal? style 'piano-cautionary)
1296        (set-accidentals-properties #f
1297                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1298                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1299                                            ,(make-accidental-rule 'same-octave 1)
1300                                      GrandStaff
1301                                            ,(make-accidental-rule 'any-octave 0)
1302                                            ,(make-accidental-rule 'same-octave 1))
1303                                    pcontext))
1304
1305       ;; same as modern, but cautionary accidentals are printed for all sharp or flat
1306       ;; tones specified by the key signature.
1307        ((equal? style 'teaching)
1308        (set-accidentals-properties #f
1309                                     `(Staff ,(make-accidental-rule 'same-octave 0))
1310                                     `(Staff ,(make-accidental-rule 'same-octave 1)
1311                                            ,teaching-accidental-rule)
1312                                    context))
1313
1314       ;; do not set localKeySignature when a note alterated differently from
1315       ;; localKeySignature is found.
1316       ;; Causes accidentals to be printed at every note instead of
1317       ;; remembered for the duration of a measure.
1318       ;; accidentals not being remembered, causing accidentals always to
1319       ;; be typeset relative to the time signature
1320       ((equal? style 'forget)
1321        (set-accidentals-properties '()
1322                                    `(Staff ,(make-accidental-rule 'same-octave -1))
1323                                    '()
1324                                    context))
1325       ;; Do not reset the key at the start of a measure.  Accidentals will be
1326       ;; printed only once and are in effect until overridden, possibly many
1327       ;; measures later.
1328       ((equal? style 'no-reset)
1329        (set-accidentals-properties '()
1330                                    `(Staff ,(make-accidental-rule 'same-octave #t))
1331                                    '()
1332                                    context))
1333       (else
1334        (ly:warning (_ "unknown accidental style: ~S") style)
1335        (make-sequential-music '()))))))
1336
1337 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1338
1339 (define-public (skip-of-length mus)
1340   "Create a skip of exactly the same length as MUS."
1341   (let* ((skip
1342           (make-music
1343            'SkipEvent
1344            'duration (ly:make-duration 0 0))))
1345
1346     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
1347
1348 (define-public (mmrest-of-length mus)
1349   "Create a mmrest of exactly the same length as MUS."
1350
1351   (let* ((skip
1352           (make-multi-measure-rest
1353            (ly:make-duration 0 0) '())))
1354     (ly:music-compress skip (ly:music-length mus))
1355     skip))
1356
1357 (define-public (pitch-of-note event-chord)
1358
1359   (let*
1360       ((evs (filter (lambda (x) (memq 'note-event (ly:music-property x 'types)))
1361                     (ly:music-property event-chord 'elements))))
1362
1363     (if (pair? evs)
1364         (ly:music-property (car evs) 'pitch)
1365         #f)))
1366
1367 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1368
1369 (define-public (extract-named-music music music-name)
1370 "Return a flat list of all music named @code{music-name}
1371 from @code{music}."
1372    (let ((extracted-list
1373           (if (ly:music? music)
1374               (if (eq? (ly:music-property music 'name) music-name)
1375                   (list music)
1376                   (let ((elt (ly:music-property music 'element))
1377                         (elts (ly:music-property music 'elements)))
1378                     (if (ly:music? elt)
1379                         (extract-named-music elt music-name)
1380                         (if (null? elts)
1381                             '()
1382                             (map (lambda(x)
1383                                     (extract-named-music x music-name ))
1384                              elts)))))
1385               '())))
1386      (flatten-list extracted-list)))
1387
1388 (define-public (event-chord-notes event-chord)
1389 "Return a list of all notes from @{event-chord}."
1390   (filter
1391     (lambda (m) (eq? 'NoteEvent (ly:music-property m 'name)))
1392     (ly:music-property event-chord 'elements)))
1393
1394 (define-public (event-chord-pitches event-chord)
1395 "Return a list of all pitches from @{event-chord}."
1396   (map (lambda (x) (ly:music-property x 'pitch))
1397        (event-chord-notes event-chord)))