scm/music-functions.scm

   1 ;;;; music-functions.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2007 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7
   8 ;; (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19 (define-safe-public (music-is-of-type? mus type)
  20   "Does @code{mus} belong to the music class @code{type}?"
  21   (memq type (ly:music-property mus 'types)))
  22
  23 ;; TODO move this
  24 (define-public ly:grob-property
  25   (make-procedure-with-setter ly:grob-property
  26                               ly:grob-set-property!))
  27
  28 (define-public ly:prob-property
  29   (make-procedure-with-setter ly:prob-property
  30                               ly:prob-set-property!))
  31
  32 (define-public (music-map function music)
  33   "Apply @var{function} to @var{music} and all of the music it contains.
  34
  35 First it recurses over the children, then the function is applied to MUSIC.
  36 "
  37   (let ((es (ly:music-property music 'elements))
  38         (e (ly:music-property music 'element)))
  39     (set! (ly:music-property music 'elements)
  40           (map (lambda (y) (music-map function y)) es))
  41     (if (ly:music? e)
  42         (set! (ly:music-property music 'element)
  43               (music-map function  e)))
  44     (function music)))
  45
  46 (define-public (music-filter pred? music)
  47   "Filter out music expressions that do not satisfy PRED."
  48
  49   (define (inner-music-filter pred? music)
  50     "Recursive function."
  51     (let* ((es (ly:music-property music 'elements))
  52            (e (ly:music-property music 'element))
  53            (as (ly:music-property music 'articulations))
  54            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  55            (filtered-e (if (ly:music? e)
  56                            (inner-music-filter pred? e)
  57                            e))
  58            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  59       (set! (ly:music-property music 'element) filtered-e)
  60       (set! (ly:music-property music 'elements) filtered-es)
  61       (set! (ly:music-property music 'articulations) filtered-as)
  62       ;; if filtering emptied the expression, we remove it completely.
  63       (if (or (not (pred? music))
  64               (and (eq? filtered-es '()) (not (ly:music? e))
  65                    (or (not (eq? es '()))
  66                        (ly:music? e))))
  67           (set! music '()))
  68       music))
  69
  70   (set! music (inner-music-filter pred? music))
  71   (if (ly:music? music)
  72       music
  73       (make-music 'Music)))       ;must return music.
  74
  75 (define-public (display-music music)
  76   "Display music, not done with music-map for clarity of presentation."
  77   (display music)
  78   (display ": { ")
  79   (let ((es (ly:music-property music 'elements))
  80         (e (ly:music-property music 'element)))
  81     (display (ly:music-mutable-properties music))
  82     (if (pair? es)
  83         (begin (display "\nElements: {\n")
  84                (map display-music es)
  85                (display "}\n")))
  86     (if (ly:music? e)
  87         (begin
  88           (display "\nChild:")
  89           (display-music e))))
  90   (display " }\n")
  91   music)
  92
  93 ;;;
  94 ;;; A scheme music pretty printer
  95 ;;;
  96 (define (markup-expression->make-markup markup-expression)
  97   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
  98 For instance,
  99   \\markup \\bold \\italic hello
 100 ==>
 101   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 102   (define (proc->command-keyword proc)
 103     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 104     (let ((cmd-markup (symbol->string (procedure-name proc))))
 105       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 106                                                                   (string-length "-markup")))))))
 107   (define (transform-arg arg)
 108     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 109            (apply append (map inner-markup->make-markup arg)))
 110           ((and (not (string? arg)) (markup? arg)) ;; a markup
 111            (inner-markup->make-markup arg))
 112           (else                                  ;; scheme arg
 113            arg)))
 114   (define (inner-markup->make-markup mrkup)
 115     (if (string? mrkup)
 116         `(#:simple ,mrkup)
 117         (let ((cmd (proc->command-keyword (car mrkup)))
 118               (args (map transform-arg (cdr mrkup))))
 119           `(,cmd ,@args))))
 120   ;; body:
 121   (if (string? markup-expression)
 122       markup-expression
 123       `(markup ,@(inner-markup->make-markup markup-expression))))
 124
 125 (define-public (music->make-music obj)
 126   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 127 that is, for a music expression, a (make-music ...) form."
 128   (cond (;; markup expression
 129          (markup? obj)
 130          (markup-expression->make-markup obj))
 131         (;; music expression
 132          (ly:music? obj)
 133          `(make-music
 134            ',(ly:music-property obj 'name)
 135            ,@(apply append (map (lambda (prop)
 136                                   `(',(car prop)
 137                                     ,(music->make-music (cdr prop))))
 138                                 (remove (lambda (prop)
 139                                           (eqv? (car prop) 'origin))
 140                                         (ly:music-mutable-properties obj))))))
 141         (;; moment
 142          (ly:moment? obj)
 143          `(ly:make-moment ,(ly:moment-main-numerator obj)
 144                           ,(ly:moment-main-denominator obj)
 145                           ,(ly:moment-grace-numerator obj)
 146                           ,(ly:moment-grace-denominator obj)))
 147         (;; note duration
 148          (ly:duration? obj)
 149          `(ly:make-duration ,(ly:duration-log obj)
 150                             ,(ly:duration-dot-count obj)
 151                             ,(car (ly:duration-factor obj))
 152                             ,(cdr (ly:duration-factor obj))))
 153         (;; note pitch
 154          (ly:pitch? obj)
 155          `(ly:make-pitch ,(ly:pitch-octave obj)
 156                          ,(ly:pitch-notename obj)
 157                          ,(ly:pitch-alteration obj)))
 158         (;; scheme procedure
 159          (procedure? obj)
 160          (or (procedure-name obj) obj))
 161         (;; a symbol (avoid having an unquoted symbol)
 162          (symbol? obj)
 163          `',obj)
 164         (;; an empty list (avoid having an unquoted empty list)
 165          (null? obj)
 166          `'())
 167         (;; a proper list
 168          (list? obj)
 169          `(list ,@(map music->make-music obj)))
 170         (;; a pair
 171          (pair? obj)
 172          `(cons ,(music->make-music (car obj))
 173                 ,(music->make-music (cdr obj))))
 174         (else
 175          obj)))
 176
 177 (use-modules (ice-9 pretty-print))
 178 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 179   "Displays `obj', typically a music expression, in a friendly fashion,
 180 which often can be read back in order to generate an equivalent expression.
 181
 182 Returns `obj'.
 183 "
 184   (pretty-print (music->make-music obj) port)
 185   (newline)
 186   obj)
 187
 188 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 189
 190 (define-public (shift-one-duration-log music shift dot)
 191   "  add SHIFT to duration-log of 'duration in music and optionally
 192   a dot to any note encountered. This scales the music up by a factor
 193   2^shift * (2 - (1/2)^dot)"
 194   (let ((d (ly:music-property music 'duration)))
 195     (if (ly:duration? d)
 196         (let* ((cp (ly:duration-factor d))
 197                (nd (ly:make-duration (+ shift (ly:duration-log d))
 198                                      (+ dot (ly:duration-dot-count d))
 199                                      (car cp)
 200                                      (cdr cp))))
 201           (set! (ly:music-property music 'duration) nd)))
 202     music))
 203
 204 (define-public (shift-duration-log music shift dot)
 205   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 206              music))
 207
 208 (define-public (make-repeat name times main alts)
 209   "create a repeat music expression, with all properties initialized properly"
 210   (let ((talts (if (< times (length alts))
 211                    (begin
 212                      (ly:warning (_ "More alternatives than repeats. Junking excess alternatives"))
 213                      (take alts times))
 214                    alts))
 215         (r (make-repeated-music name)))
 216     (set! (ly:music-property r 'element) main)
 217     (set! (ly:music-property r 'repeat-count) (max times 1))
 218     (set! (ly:music-property r 'elements) talts)
 219     (if (equal? name "tremolo")
 220         (let* ((dots (1- (logcount times)))
 221                (mult (/ (* times (ash 1 dots)) (1- (ash 2 dots))))
 222                (shift (- (ly:intlog2 (floor mult)))))
 223           (if (not (integer?  mult))
 224               (ly:warning (_ "illegal tremolo repeat count: ~a") times))
 225           (if (memq 'sequential-music (ly:music-property main 'types))
 226               ;; \repeat "tremolo" { c4 d4 }
 227               (let ((children (length (ly:music-property main 'elements))))
 228                 (if (not (= children 2))
 229                     (ly:warning (_ "expecting 2 elements for chord tremolo, found ~a") children))
 230                 (ly:music-compress r (ly:make-moment 1 children))
 231                 (shift-duration-log r (1- shift) dots))
 232               ;; \repeat "tremolo" c4
 233               (shift-duration-log r shift dots)))
 234         r)))
 235
 236 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 237 ;; clusters.
 238
 239 (define-public (note-to-cluster music)
 240   "Replace NoteEvents by ClusterNoteEvents."
 241   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 242       (make-music 'ClusterNoteEvent
 243                   'pitch (ly:music-property music 'pitch)
 244                   'duration (ly:music-property music 'duration))
 245       music))
 246
 247 (define-public (notes-to-clusters music)
 248   (music-map note-to-cluster music))
 249
 250 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 251 ;; repeats.
 252
 253 (define-public (unfold-repeats music)
 254   "
 255 This function replaces all repeats  with unfold repeats. "
 256
 257   (let ((es (ly:music-property music 'elements))
 258         (e  (ly:music-property music 'element))
 259         )
 260     (if (memq 'repeated-music (ly:music-property music 'types))
 261         (let*
 262             ((props (ly:music-mutable-properties music))
 263              (old-name (ly:music-property music 'name))
 264              (flattened  (flatten-alist props)))
 265
 266           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 267                                               flattened)))
 268
 269           (if (equal? old-name 'TremoloRepeatedMusic)
 270               (let* ((seq-arg? (memq 'sequential-music
 271                                      (ly:music-property e 'types)))
 272                      (count  (ly:music-property music 'repeat-count))
 273                      (dot-shift (if (= 0 (remainder count 3))
 274                                     -1 0)))
 275
 276                 (if (= 0 -1)
 277                     (set! count (* 2 (quotient count 3))))
 278
 279                 (shift-duration-log music (+ (if seq-arg? 1 0)
 280                                              (ly:intlog2 count)) dot-shift)
 281
 282                 (if seq-arg?
 283                     (ly:music-compress e (ly:make-moment (length (ly:music-property
 284                                                                   e 'elements)) 1)))))))
 285
 286
 287     (if (pair? es)
 288         (set! (ly:music-property music 'elements)
 289               (map unfold-repeats es)))
 290     (if (ly:music? e)
 291         (set! (ly:music-property music 'element)
 292               (unfold-repeats e)))
 293     music))
 294
 295 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 296 ;; property setting music objs.
 297
 298 (define-public (make-grob-property-set grob gprop val)
 299   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 300 i.e.  this is not an override"
 301   (make-music 'OverrideProperty
 302               'symbol grob
 303               'grob-property gprop
 304               'grob-value val
 305               'pop-first #t))
 306
 307 (define-public (make-grob-property-override grob gprop val)
 308   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 309 i.e.  this is not an override"
 310   (make-music 'OverrideProperty
 311               'symbol grob
 312               'grob-property gprop
 313               'grob-value val))
 314
 315 (define-public (make-grob-property-revert grob gprop)
 316   "Revert the grob property GPROP for GROB."
 317   (make-music 'RevertProperty
 318               'symbol grob
 319               'grob-property gprop))
 320
 321 (define direction-polyphonic-grobs
 322   '(Stem Tie Rest Slur PhrasingSlur Script TextScript Dots DotColumn Fingering))
 323
 324 (define-safe-public (make-voice-props-set n)
 325   (make-sequential-music
 326    (append
 327     (map (lambda (x) (make-grob-property-set x 'direction
 328                                              (if (odd? n) -1 1)))
 329          direction-polyphonic-grobs)
 330     (list
 331      (make-property-set 'graceSettings
 332                         ;; TODO: take this from voicedGraceSettings or similar.
 333                         '((Voice Stem font-size -3)
 334                           (Voice NoteHead font-size -3)
 335                           (Voice Dots font-size -3)
 336                           (Voice Stem length-fraction 0.8)
 337                           (Voice Stem no-stem-extend #t)
 338                           (Voice Beam thickness 0.384)
 339                           (Voice Beam length-fraction 0.8)
 340                           (Voice Accidental font-size -4)))
 341
 342      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 343      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 344
 345 (define-safe-public (make-voice-props-revert)
 346   (make-sequential-music
 347    (append
 348     (map (lambda (x) (make-grob-property-revert x 'direction))
 349          direction-polyphonic-grobs)
 350     (list (make-property-unset 'graceSettings)
 351           (make-grob-property-revert 'NoteColumn 'horizontal-shift)
 352           (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 353
 354
 355 (define-safe-public (context-spec-music m context #:optional id)
 356   "Add \\context CONTEXT = ID to M. "
 357   (let ((cm (make-music 'ContextSpeccedMusic
 358                         'element m
 359                         'context-type context)))
 360     (if (string? id)
 361         (set! (ly:music-property cm 'context-id) id))
 362     cm))
 363
 364 (define-public (descend-to-context m context)
 365   "Like context-spec-music, but only descending. "
 366   (let ((cm (context-spec-music m context)))
 367     (ly:music-set-property! cm 'descend-only #t)
 368     cm))
 369
 370 (define-public (make-non-relative-music mus)
 371   (make-music 'UnrelativableMusic
 372               'element mus))
 373
 374 (define-public (make-apply-context func)
 375   (make-music 'ApplyContext
 376               'procedure func))
 377
 378 (define-public (make-sequential-music elts)
 379   (make-music 'SequentialMusic
 380               'elements elts))
 381
 382 (define-public (make-simultaneous-music elts)
 383   (make-music 'SimultaneousMusic
 384               'elements elts))
 385
 386 (define-safe-public (make-event-chord elts)
 387   (make-music 'EventChord
 388               'elements elts))
 389
 390 (define-public (make-skip-music dur)
 391   (make-music 'SkipMusic
 392               'duration dur))
 393
 394 (define-public (make-grace-music music)
 395   (make-music 'GraceMusic
 396               'element music))
 397
 398 ;;;;;;;;;;;;;;;;
 399
 400 ;; mmrest
 401 (define-public (make-multi-measure-rest duration location)
 402   (make-music 'MultiMeasureRestMusic
 403               'origin location
 404               'duration duration))
 405
 406 (define-public (make-property-set sym val)
 407   (make-music 'PropertySet
 408               'symbol sym
 409               'value val))
 410
 411 (define-public (make-property-unset sym)
 412   (make-music 'PropertyUnset
 413               'symbol sym))
 414
 415 (define-public (make-ottava-set octavation)
 416   (let ((m (make-music 'ApplyContext)))
 417     (define (ottava-modify context)
 418       "Either reset middleCPosition to the stored original, or remember
 419 old middleCPosition, add OCTAVATION to middleCPosition, and set
 420 OTTAVATION to `8va', or whatever appropriate."
 421       (if (number? (ly:context-property  context 'middleCPosition))
 422           (begin
 423             (if (number? (ly:context-property context 'originalMiddleCPosition))
 424                 (let ((where (ly:context-property-where-defined context 'middleCPosition)))
 425
 426                   (ly:context-set-property! context 'middleCPosition
 427                                             (ly:context-property context 'originalMiddleCPosition))
 428                   (ly:context-unset-property where 'originalMiddleCPosition)
 429                   (ly:context-unset-property where 'ottavation)))
 430
 431             (let* ((where (ly:context-property-where-defined context 'middleCPosition))
 432                    (c0 (ly:context-property context 'middleCPosition))
 433                    (new-c0 (+ c0 (* -7 octavation)))
 434                    (string (cdr (assoc octavation '((2 . "15ma")
 435                                                     (1 . "8va")
 436                                                     (0 . #f)
 437                                                     (-1 . "8vb")
 438                                                     (-2 . "15mb"))))))
 439               (ly:context-set-property! context 'middleCPosition new-c0)
 440               (ly:context-set-property! context 'originalMiddleCPosition c0)
 441               (ly:context-set-property! context 'ottavation string)))))
 442
 443     (set! (ly:music-property m 'procedure) ottava-modify)
 444     (context-spec-music m 'Staff)))
 445
 446 (define-public (set-octavation ottavation)
 447   (ly:export (make-ottava-set ottavation)))
 448
 449 (define-public (make-time-signature-set num den . rest)
 450   "Set properties for time signature NUM/DEN.  Rest can contain a list
 451 of beat groupings "
 452
 453   (define (standard-beat-grouping num den)
 454
 455     "Some standard subdivisions for time signatures."
 456     (let*
 457         ((key (cons num den))
 458          (entry (assoc key '(((6 . 8) . (3 3))
 459                          ((5 . 8) . (3 2))
 460                          ((9 . 8) . (3 3 3))
 461                          ((12 . 8) . (3 3 3 3))
 462                          ((8 . 8) . (3 3 2))
 463                          ))))
 464
 465       (if entry
 466           (cdr entry)
 467           '())))
 468
 469   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 470          (beat (ly:make-moment 1 den))
 471          (len  (ly:make-moment num den))
 472          (set2 (make-property-set 'beatLength beat))
 473          (set3 (make-property-set 'measureLength len))
 474          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 475                                                     (car rest)
 476                                                     (standard-beat-grouping num den))))
 477          (basic  (list set1 set2 set3 set4)))
 478     (descend-to-context
 479      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 480
 481 (define-public (make-mark-set label)
 482   "Make the music for the \\mark command."
 483   (let* ((set (if (integer? label)
 484                   (context-spec-music (make-property-set 'rehearsalMark label)
 485                                       'Score)
 486                   #f))
 487          (ev (make-music 'MarkEvent))
 488          (ch (make-event-chord (list ev))))
 489     (if set
 490         (make-sequential-music (list set ch))
 491         (begin
 492           (set! (ly:music-property ev 'label) label)
 493           ch))))
 494
 495 (define-public (set-time-signature num den . rest)
 496   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 497
 498 (define-safe-public (make-articulation name)
 499   (make-music 'ArticulationEvent
 500               'articulation-type name))
 501
 502 (define-public (make-lyric-event string duration)
 503   (make-music 'LyricEvent
 504               'duration duration
 505               'text string))
 506
 507 (define-safe-public (make-span-event type spandir)
 508   (make-music type
 509               'span-direction spandir))
 510
 511 (define-public (set-mus-properties! m alist)
 512   "Set all of ALIST as properties of M."
 513   (if (pair? alist)
 514       (begin
 515         (set! (ly:music-property m (caar alist)) (cdar alist))
 516         (set-mus-properties! m (cdr alist)))))
 517
 518 (define-public (music-separator? m)
 519   "Is M a separator?"
 520   (let ((ts (ly:music-property m 'types)))
 521     (memq 'separator ts)))
 522
 523 ;;; splitting chords into voices.
 524 (define (voicify-list lst number)
 525   "Make a list of Musics.
 526
 527    voicify-list :: [ [Music ] ] -> number -> [Music]
 528    LST is a list music-lists.
 529
 530    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 531 "
 532   (if (null? lst)
 533       '()
 534       (cons (context-spec-music
 535              (make-sequential-music
 536               (list (make-voice-props-set number)
 537                     (make-simultaneous-music (car lst))))
 538              'Voice  (number->string (1+ number)))
 539             (voicify-list (cdr lst) (1+ number)))))
 540
 541 (define (voicify-chord ch)
 542   "Split the parts of a chord into different Voices using separator"
 543   (let ((es (ly:music-property ch 'elements)))
 544     (set! (ly:music-property  ch 'elements)
 545           (voicify-list (split-list-by-separator es music-separator?) 0))
 546     ch))
 547
 548 (define-public (voicify-music m)
 549   "Recursively split chords that are separated with \\ "
 550   (if (not (ly:music? m))
 551       (ly:error (_ "music expected: ~S") m))
 552   (let ((es (ly:music-property m 'elements))
 553         (e (ly:music-property m 'element)))
 554
 555     (if (pair? es)
 556         (set! (ly:music-property m 'elements) (map voicify-music es)))
 557     (if (ly:music? e)
 558         (set! (ly:music-property m 'element)  (voicify-music e)))
 559     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 560              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 561         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 562     m))
 563
 564 (define-public (empty-music)
 565   (ly:export (make-music 'Music)))
 566 ;;;
 567
 568                                         ; Make a function that checks score element for being of a specific type.
 569 (define-public (make-type-checker symbol)
 570   (lambda (elt)
 571     ;;(display  symbol)
 572     ;;(eq? #t (ly:grob-property elt symbol))
 573     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 574
 575 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 576   (if (func grob)
 577       (set! (ly:grob-property grob sym) val)))
 578
 579
 580 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 581   "Usage:
 582
 583 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 584
 585 "
 586   (let ((meta (ly:grob-property grob 'meta)))
 587     (if (equal?  (cdr (assoc 'name meta)) grob-name)
 588         (set! (ly:grob-property grob symbol) val))))
 589
 590
 591 ;;
 592 (define-public (smart-bar-check n)
 593   "Make  a bar check that checks for a specific bar number.
 594 "
 595   (let ((m (make-music 'ApplyContext)))
 596     (define (checker tr)
 597       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 598         (if (= bn n)
 599             #t
 600             (ly:error
 601              ;; FIXME: uncomprehensable message
 602              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 603              n bn))))
 604     (set! (ly:music-property m 'procedure) checker)
 605     m))
 606
 607
 608 (define-public (skip->rest mus)
 609
 610   "Replace MUS by RestEvent of the same duration if it is a
 611 SkipEvent. Useful for extracting parts from crowded scores"
 612
 613   (if (equal? (ly:music-property mus 'name) 'SkipEvent)
 614    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 615    mus))
 616
 617
 618 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 619 ;; warn for bare chords at start.
 620
 621 (define (has-request-chord elts)
 622   (reduce (lambda (x y) (or x y)) #f
 623           (map (lambda (x)
 624                  (equal? (ly:music-property x 'name) 'RequestChord))
 625                elts)))
 626
 627 (define-public (ly:music-message music msg)
 628   (let ((ip (ly:music-property music 'origin)))
 629     (if (ly:input-location? ip)
 630         (ly:input-message ip msg)
 631         (ly:warning msg))))
 632
 633 (define (check-start-chords music)
 634   "Check music expression for a Simultaneous_music containing notes\n(ie. Request_chords),
 635 without context specification. Called  from parser."
 636   (let ((es (ly:music-property music 'elements))
 637         (e (ly:music-property music 'element))
 638         (name (ly:music-property music 'name)))
 639     (cond ((equal? name "Context_specced_music") #t)
 640           ((equal? name "Simultaneous_music")
 641            (if (has-request-chord es)
 642                (ly:music-message music "Starting score with a chord.\nInsert an explicit \\context before chord")
 643                (map check-start-chords es)))
 644           ((equal? name "SequentialMusic")
 645            (if (pair? es)
 646                (check-start-chords (car es))))
 647           (else (if (ly:music? e) (check-start-chords e)))))
 648   music)
 649
 650
 651
 652 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 653 ;;
 654 ;; setting stuff for grace context.
 655 ;;
 656
 657 (define (vector-extend v x)
 658   "Make a new vector consisting of V, with X added to the end."
 659   (let* ((n (vector-length v))
 660          (nv (make-vector (+ n 1) '())))
 661     (vector-move-left! v 0 n nv 0)
 662     (vector-set! nv n x)
 663     nv))
 664
 665 (define (vector-map f v)
 666   "Map  F over V. This function returns nothing."
 667   (do ((n (vector-length v))
 668        (i 0 (+ i 1)))
 669       ((>= i n))
 670     (f (vector-ref v i))))
 671
 672 (define (vector-reverse-map f v)
 673   "Map  F over V, N to 0 order. This function returns nothing."
 674   (do ((i (- (vector-length v) 1) (- i 1)))
 675       ((< i 0))
 676     (f (vector-ref v i))))
 677
 678 ;; TODO:  make a remove-grace-property too.
 679 (define-public (add-grace-property context-name grob sym val)
 680   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 681   (define (set-prop context)
 682     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 683            (current (ly:context-property where 'graceSettings))
 684            (new-settings (append current
 685                                  (list (list context-name grob sym val)))))
 686       (ly:context-set-property! where 'graceSettings new-settings)))
 687   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 688
 689
 690
 691 (defmacro-public def-grace-function (start stop)
 692   `(define-music-function (parser location music) (ly:music?)
 693      (make-music 'GraceMusic
 694                  'origin location
 695                  'element (make-music 'SequentialMusic
 696                                       'elements (list (ly:music-deep-copy ,start)
 697                                                       music
 698                                                       (ly:music-deep-copy ,stop))))))
 699
 700 (defmacro-public define-music-function (args signature . body)
 701   "Helper macro for `ly:make-music-function'.
 702 Syntax:
 703   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 704     ...function body...)
 705 "
 706   `(ly:make-music-function (list ,@signature)
 707                            (lambda (,@args)
 708                              ,@body)))
 709
 710
 711 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 712
 713 (define-public (cue-substitute quote-music)
 714   "Must happen after quote-substitute."
 715
 716   (if (vector? (ly:music-property quote-music 'quoted-events))
 717       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 718              (main-voice (if (eq? 1 dir) 1 0))
 719              (cue-voice (if (eq? 1 dir) 0 1))
 720              (main-music (ly:music-property quote-music 'element))
 721              (return-value quote-music))
 722
 723         (if (or (eq? 1 dir) (eq? -1 dir))
 724
 725             ;; if we have stem dirs, change both quoted and main music
 726             ;; to have opposite stems.
 727             (begin
 728               (set! return-value
 729
 730                     ;; cannot context-spec Quote-music, since context
 731                     ;; for the quotes is determined in the iterator.
 732                     (make-sequential-music
 733                      (list
 734                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 735                       quote-music
 736                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 737               (set! main-music
 738                     (make-sequential-music
 739                      (list
 740                       (make-voice-props-set main-voice)
 741                       main-music
 742                       (make-voice-props-revert))))
 743               (set! (ly:music-property quote-music 'element) main-music)))
 744
 745         return-value)
 746       quote-music))
 747
 748 (define-public ((quote-substitute quote-tab) music)
 749   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 750          (quoted-vector (if (string? quoted-name)
 751                             (hash-ref quote-tab quoted-name #f)
 752                             #f)))
 753
 754
 755     (if (string? quoted-name)
 756         (if (vector? quoted-vector)
 757             (begin
 758               (set! (ly:music-property music 'quoted-events) quoted-vector)
 759               (set! (ly:music-property music 'iterator-ctor)
 760                     ly:quote-iterator::constructor))
 761             (ly:warning (_ "cannot find quoted music: `~S'") quoted-name)))
 762     music))
 763
 764
 765 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 766 ;; switch it on here, so parsing and init isn't checked (too slow!)
 767 ;;
 768 ;; automatic music transformations.
 769
 770 (define (switch-on-debugging m)
 771   (if (defined? 'set-debug-cell-accesses!)
 772       (set-debug-cell-accesses! 15000))
 773   m)
 774
 775 (define (music-check-error music)
 776   (define found #f)
 777   (define (signal m)
 778     (if (and (ly:music? m)
 779              (eq? (ly:music-property m 'error-found) #t))
 780         (set! found #t)))
 781
 782   (for-each signal (ly:music-property music 'elements))
 783   (signal (ly:music-property music 'element))
 784
 785   (if found
 786       (set! (ly:music-property music 'error-found) #t))
 787   music)
 788
 789 (define (precompute-music-length music)
 790   (set! (ly:music-property music 'length)
 791         (ly:music-length music))
 792   music)
 793
 794 (define (skip-to-last music parser)
 795
 796   "Replace MUSIC by
 797
 798 << { \\set skipTypesetting = ##t
 799      LENGTHOF(\\showLastLength)
 800      \\set skipTypesetting = ##t  }
 801     MUSIC >>
 802
 803 if appropriate.
 804  "
 805   (let*
 806       ((show-last  (ly:parser-lookup parser 'showLastLength)))
 807
 808     (if (ly:music? show-last)
 809         (let*
 810             ((orig-length (ly:music-length music))
 811              (skip-length (ly:moment-sub orig-length (ly:music-length show-last))))
 812
 813           (make-simultaneous-music
 814            (list
 815             (make-sequential-music
 816              (list
 817               (context-spec-music (make-property-set 'skipTypesetting #t) 'Score)
 818               (make-music 'SkipMusic 'duration
 819                           (ly:make-duration 0 0
 820                                             (ly:moment-main-numerator skip-length)
 821                                             (ly:moment-main-denominator skip-length)))
 822               (context-spec-music (make-property-set 'skipTypesetting #f) 'Score)))
 823             music)))
 824         music)))
 825
 826
 827 (define-public toplevel-music-functions
 828   (list
 829    (lambda (music parser) (voicify-music music))
 830    (lambda (x parser) (music-map music-check-error x))
 831    (lambda (x parser) (music-map precompute-music-length x))
 832    (lambda (music parser)
 833
 834      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 835
 836    ;; switch-on-debugging
 837    (lambda (x parser) (music-map cue-substitute x))
 838
 839    (lambda (x parser)
 840      (skip-to-last x parser)
 841    )))
 842
 843
 844 ;;;;;;;;;;;;;;;;;
 845 ;; lyrics
 846
 847 (define (apply-durations lyric-music durations)
 848   (define (apply-duration music)
 849     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 850              (ly:duration?  (ly:music-property music 'duration)))
 851         (begin
 852           (set! (ly:music-property music 'duration) (car durations))
 853           (set! durations (cdr durations)))))
 854
 855   (music-map apply-duration lyric-music))
 856
 857
 858 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 859 ;; accidentals
 860
 861 (define-public (set-accidentals-properties extra-natural
 862                                            auto-accs auto-cauts
 863                                            context)
 864   (context-spec-music
 865    (make-sequential-music
 866     (append (if (boolean? extra-natural)
 867                 (list (make-property-set 'extraNatural extra-natural))
 868                 '())
 869             (list (make-property-set 'autoAccidentals auto-accs)
 870                   (make-property-set 'autoCautionaries auto-cauts))))
 871    context))
 872
 873 (define-public (set-accidental-style style . rest)
 874   "Set accidental style to STYLE. Optionally takes a context argument,
 875 e.g. 'Staff or 'Voice. The context defaults to Voice, except for piano styles, which
 876 use GrandStaff as a context. "
 877   (let ((context (if (pair? rest)
 878                      (car rest) 'Staff))
 879         (pcontext (if (pair? rest)
 880                       (car rest) 'GrandStaff)))
 881     (ly:export
 882      (cond
 883       ;; accidentals as they were common in the 18th century.
 884       ((equal? style 'default)
 885        (set-accidentals-properties #t '(Staff (same-octave . 0))
 886                                    '() context))
 887       ;; accidentals from one voice do NOT get cancelled in other voices
 888       ((equal? style 'voice)
 889        (set-accidentals-properties #t '(Voice (same-octave . 0))
 890                                    '() context))
 891       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
 892       ;; This includes all the default accidentals, but accidentals also needs cancelling
 893       ;; in other octaves and in the next measure.
 894       ((equal? style 'modern)
 895        (set-accidentals-properties #f '(Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 896                                    '()  context))
 897       ;; the accidentals that Stone adds to the old standard as cautionaries
 898       ((equal? style 'modern-cautionary)
 899        (set-accidentals-properties #f '(Staff (same-octave . 0))
 900                                    '(Staff (any-octave . 0) (same-octave . 1))
 901                                    context))
 902       ;; Multivoice accidentals to be read both by musicians playing one voice
 903       ;; and musicians playing all voices.
 904       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
 905       ((equal? style 'modern-voice)
 906        (set-accidentals-properties  #f
 907                                     '(Voice (same-octave . 0) (any-octave . 0) (same-octave . 1)
 908                                             Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 909                                     '()
 910                                     context))
 911       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
 912       ;; as cautionaries
 913       ((equal? style 'modern-voice-cautionary)
 914        (set-accidentals-properties #f
 915                                    '(Voice (same-octave . 0))
 916                                    '(Voice (any-octave . 0) (same-octave . 1)
 917                                            Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 918                                    context))
 919       ;; stone's suggestions for accidentals on grand staff.
 920       ;; Accidentals are cancelled across the staves in the same grand staff as well
 921       ((equal? style 'piano)
 922        (set-accidentals-properties #f
 923                                    '(Staff (same-octave . 0)
 924                                            (any-octave . 0) (same-octave . 1)
 925                                            GrandStaff (any-octave . 0) (same-octave . 1))
 926                                    '()
 927                                    pcontext))
 928       ((equal? style 'piano-cautionary)
 929        (set-accidentals-properties #f
 930                                    '(Staff (same-octave . 0))
 931                                    '(Staff (any-octave . 0) (same-octave . 1)
 932                                            GrandStaff (any-octave . 0) (same-octave . 1))
 933                                    pcontext))
 934
 935       ;; do not set localKeySignature when a note alterated differently from
 936       ;; localKeySignature is found.
 937       ;; Causes accidentals to be printed at every note instead of
 938       ;; remembered for the duration of a measure.
 939       ;; accidentals not being remembered, causing accidentals always to
 940       ;; be typeset relative to the time signature
 941
 942       ((equal? style 'forget)
 943        (set-accidentals-properties '()
 944                                    '(Staff (same-octave . -1))
 945                                    '() context))
 946       ;; Do not reset the key at the start of a measure.  Accidentals will be
 947       ;; printed only once and are in effect until overridden, possibly many
 948       ;; measures later.
 949       ((equal? style 'no-reset)
 950        (set-accidentals-properties '()
 951                                    '(Staff (same-octave . #t))
 952                                    '()
 953                                    context))
 954       (else
 955        (ly:warning (_ "unknown accidental style: ~S" style))
 956        (make-sequential-music '()))))))
 957
 958 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 959
 960 (define-public (skip-of-length mus)
 961   "Create a skip of exactly the same length as MUS."
 962   (let* ((skip
 963           (make-music
 964            'SkipEvent
 965            'duration (ly:make-duration 0 0))))
 966
 967     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
 968
 969 (define-public (mmrest-of-length mus)
 970   "Create a mmrest of exactly the same length as MUS."
 971
 972   (let* ((skip
 973           (make-multi-measure-rest
 974            (ly:make-duration 0 0) '())))
 975     (ly:music-compress skip (ly:music-length mus))
 976     skip))
 977
 978 (define-public (pitch-of-note event-chord)
 979
 980   (let*
 981       ((evs (filter (lambda (x) (memq 'note-event (ly:music-property x 'types)))
 982                     (ly:music-property event-chord 'elements))))
 983
 984     (if (pair? evs)
 985         (ly:music-property (car evs) 'pitch)
 986         #f)))
 987