scm/lily.scm

   1 ;;;; lily.scm -- toplevel Scheme stuff
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2007 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;; Han-Wen Nienhuys <hanwen@xs4all.nl>
   7
   8 ;; Internationalisation: (_i "to be translated") gets an entry in the
   9 ;; POT file (gettext ) must be invoked explicitely to do the actual
  10 ;; "translation".
  11 ;;(define-macro (_i x) x)
  12 ;;(define-macro-public _i (x) x)
  13 ;;(define-public-macro _i (x) x)
  14 ;; Abbrv-PWR!
  15 (defmacro-public _i (x) x)
  16
  17 (read-enable 'positions)
  18 (debug-enable 'debug)
  19
  20 (define scheme-options-definitions
  21   `(
  22
  23     ;; NAMING: either
  24
  25     ;; - [subject-]object-object-verb +"ing"
  26     ;; - [subject-]-verb-object-object
  27
  28     (anti-alias-factor 1 "render at higher resolution and scale down result\nto prevent jaggies in PNG")
  29     (backend ps "which backend to use by default; Options: eps, ps [default], scm, svg, tex, texstr)")
  30     (check-internal-types #f "check every property assignment for types")
  31     (clip-systems #f "Generate cut-out snippets of a score")
  32     (datadir #f "LilyPond prefix for data files (Readonly).")
  33     (debug-gc #f "dump memory debugging statistics")
  34     (debug-gc-assert-parsed-dead #f "for memory debugging:
  35 ensure that all refs to parsed objects are dead.  This is an internal option, and is switched on automatically for -ddebug-gc.")
  36     (debug-lexer #f "debug the flex lexer")
  37     (debug-page-breaking-scoring #f "dump scores for many different page breaking configurations")
  38     (debug-parser #f "debug the bison parser")
  39     (debug-property-callbacks #f "debug cyclic callback chains")
  40     (debug-skylines #f "debug skylines")
  41     (delete-intermediate-files #f
  42                                "delete unusable PostScript files")
  43     (dump-profile #f "dump memory and time information for each file")
  44     (dump-cpu-profile #f "dump timing information (system-dependent)")
  45     (dump-signatures #f "dump output signatures of each system.  Used for regression testing.")
  46
  47     (eps-box-padding #f "Pad EPS bounding box left edge.  Guarantee alignment between systems in LaTeX.")
  48     (gs-load-fonts #f
  49                    "load fonts via Ghostscript.")
  50     (gs-load-lily-fonts #f
  51                         "load only lilypond fonts via Ghostscript.")
  52     (gui #f "running from gui; redirect stderr to log file")
  53     (help #f "show this help.")
  54     (include-book-title-preview #t "include book-titles in preview images.")
  55     (include-eps-fonts #t "Include fonts in separate-system EPS files.")
  56     (job-count #f "Process in parallel")
  57     (log-file #f "redirect output to log FILE.log")
  58
  59     (old-relative #f
  60                   "relative for simultaneous music works
  61 similar to chord syntax")
  62     (point-and-click #t "use point & click")
  63     (paper-size "a4" "the default paper size")
  64     (pixmap-format "png16m" "GS format to use for pixel images")
  65     (preview #f "make a incipit image. ")
  66     (print-pages #t "print pages normally. ")
  67     (protected-scheme-parsing #t "continue when finding errors in inline
  68 scheme are caught in the parser. If off, halt
  69 on errors, and print a stack trace.")
  70     (profile-property-accesses #f "keep statistics of get_property() calls.")
  71
  72     (resolution 101 "resolution for generating PNG bitmaps")
  73     (read-file-list #f "Read files to be processed from command line arguments")
  74
  75     (safe #f "Run safely")
  76     (strict-infinity-checking #f "If yes, crash on encountering Inf/NaN.")
  77     (strip-output-dir #t "If yes, strip directories from input files.")
  78     (separate-log-files #f "Output to FILE.log per file.")
  79     (trace-memory-frequency #f "Record Scheme cell usage this many times per second, and dump to file.")
  80     (trace-scheme-coverage #f "Record coverage of Scheme files")
  81     (ttf-verbosity 0
  82                    "how much verbosity for TTF font embedding?")
  83     (show-available-fonts #f
  84                           "List font names available.")
  85     (verbose ,(ly:command-line-verbose?) "value for the --verbose flag")
  86     ))
  87
  88 ;; need to do this in the beginning. Other parts of the
  89 ;; Scheme init depend on these options.
  90 ;;
  91 (for-each
  92  (lambda (x)
  93    (ly:add-option (car x) (cadr x) (caddr x)))
  94  scheme-options-definitions)
  95
  96 (for-each
  97  (lambda (x)
  98    (ly:set-option (car x) (cdr x)))
  99  (eval-string (ly:command-line-options)))
 100
 101 (debug-set! stack 0)
 102
 103 (if (defined? 'set-debug-cell-accesses!)
 104     (set-debug-cell-accesses! #f))
 105
 106                                         ;(set-debug-cell-accesses! 1000)
 107
 108 (use-modules (ice-9 regex)
 109              (ice-9 safe)
 110              (ice-9 format)
 111              (ice-9 rdelim)
 112              (ice-9 optargs)
 113              (oop goops)
 114              (srfi srfi-1)
 115              (srfi srfi-13)
 116              (srfi srfi-14)
 117              (scm clip-region)
 118              (scm memory-trace)
 119              (scm coverage)
 120              )
 121 (define-public fancy-format format)
 122 (define-public (ergonomic-simple-format dest . rest)
 123   "Like ice-9 format, but without the memory consumption."
 124
 125   (if (string? dest)
 126       (apply simple-format (cons #f (cons dest rest)))
 127       (apply simple-format (cons dest rest))))
 128
 129 (define format ergonomic-simple-format)
 130
 131 ;; my display
 132 (define-public (myd k v) (display k) (display ": ") (display v) (display ", ")
 133   v)
 134
 135 (define-public (print . args)
 136   (apply format (cons (current-output-port) args)))
 137
 138
 139 ;;; General settings
 140 ;;; debugging evaluator is slower.  This should
 141 ;;; have a more sensible default.
 142
 143 (if (or (ly:get-option 'verbose)
 144         (ly:get-option 'trace-memory-frequency)
 145         (ly:get-option 'trace-scheme-coverage)
 146         )
 147     (begin
 148       (ly:set-option 'protected-scheme-parsing #f)
 149       (debug-enable 'debug)
 150       (debug-enable 'backtrace)
 151       (read-enable 'positions)))
 152
 153
 154 (if (ly:get-option 'trace-scheme-coverage)
 155     (coverage:enable))
 156
 157 (define-public tex-backend?
 158   (member (ly:get-option 'backend) '(texstr tex)))
 159
 160 (define-public parser #f)
 161
 162
 163 ;; TeX C++ code actually hooks into TEX_STRING_HASHLIMIT
 164 (define-public TEX_STRING_HASHLIMIT 10000000)
 165
 166
 167
 168 ;; gettext wrapper for guile < 1.7.2
 169 (if (defined? 'gettext)
 170     (define-public _ gettext)
 171     (define-public _ ly:gettext))
 172
 173 (define-public (ly:load x)
 174   (let* ((file-name (%search-load-path x)))
 175     (if (ly:get-option 'verbose)
 176         (ly:progress "[~A" file-name))
 177     (if (not file-name)
 178         (ly:error (_ "cannot find: ~A") x))
 179     (primitive-load file-name)
 180     (if (ly:get-option 'verbose)
 181         (ly:progress "]"))))
 182
 183 ;; Cygwin
 184 ;; #(CYGWIN_NT-5.1 Hostname 1.5.12(0.116/4/2) 2004-11-10 08:34 i686)
 185 ;;
 186 ;; Debian
 187 ;; #(Linux hostname 2.4.27-1-686 #1 Fri Sep 3 06:28:00 UTC 2004 i686)
 188 ;;
 189 ;; Mingw
 190 ;; #(Windows XP HOSTNAME build 2600 5.01 Service Pack 1 i686)
 191 ;;
 192
 193 ;; ugh, code dup.
 194 (define-public PLATFORM
 195   (string->symbol
 196    (string-downcase
 197     (car (string-tokenize (vector-ref (uname) 0) char-set:letter)))))
 198
 199 (define-public DOS
 200   (let ((platform (string-tokenize
 201                    (vector-ref (uname) 0) char-set:letter+digit)))
 202     (if (null? (cdr platform)) #f
 203         (member (string-downcase (cadr platform)) '("95" "98" "me")))))
 204
 205 (case PLATFORM
 206   ((windows)
 207    (define native-getcwd getcwd)
 208    (define (slashify x)
 209      (if (string-index x #\\)
 210          x
 211          (string-regexp-substitute
 212           "//*" "/"
 213           (string-regexp-substitute "\\\\" "/" x))))
 214    ;; FIXME: this prints a warning.
 215    (define-public (ly-getcwd)
 216      (slashify (native-getcwd))))
 217   (else (define-public ly-getcwd getcwd)))
 218
 219 (define-public (is-absolute? file-name)
 220   (let ((file-name-length (string-length file-name)))
 221     (if (= file-name-length 0)
 222         #f
 223         (or (eq? (string-ref file-name 0) #\/)
 224             (and (eq? PLATFORM 'windows)
 225                  (> file-name-length 2)
 226                  (eq? (string-ref file-name 1) #\:)
 227                  (eq? (string-ref file-name 2) #\/))))))
 228
 229 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 230
 231 (define (type-check-list location signature arguments)
 232   "Typecheck a list of arguments against a list of type
 233 predicates. Print a message at LOCATION if any predicate failed."
 234
 235   (define (recursion-helper signature arguments count)
 236     (define (helper pred? arg count)
 237       (if (not (pred? arg))
 238
 239           (begin
 240             (ly:input-message
 241              location
 242              (format
 243               #f (_ "wrong type for argument ~a.  Expecting ~a, found ~s")
 244               count (type-name pred?) arg))
 245             #f)
 246           #t))
 247
 248     (if (null? signature)
 249         #t
 250         (and (helper (car signature) (car arguments) count)
 251              (recursion-helper (cdr signature) (cdr arguments) (1+ count)))))
 252
 253   (recursion-helper signature arguments 1))
 254
 255 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 256 ;;  output
 257
 258
 259 ;;(define-public (output-framework) (write "hello\n"))
 260
 261 (define output-tex-module
 262   (make-module 1021 (list (resolve-interface '(scm output-tex)))))
 263 (define output-ps-module
 264   (make-module 1021 (list (resolve-interface '(scm output-ps)))))
 265
 266 (define-public (ps-output-expression expr port)
 267   (display (eval expr output-ps-module) port))
 268
 269 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 270 ;; Safe definitions utility
 271 (define safe-objects (list))
 272
 273 (define-macro (define-safe-public arglist . body)
 274   "Define a variable, export it, and mark it as safe, ie usable in LilyPond safe mode.
 275 The syntax is the same as `define*-public'."
 276   (define (get-symbol arg)
 277     (if (pair? arg)
 278         (get-symbol (car arg))
 279         arg))
 280   (let ((safe-symbol (get-symbol arglist)))
 281     `(begin
 282        (define*-public ,arglist
 283          ,@body)
 284        (set! safe-objects (cons (cons ',safe-symbol ,safe-symbol)
 285                                 safe-objects))
 286        ,safe-symbol)))
 287
 288 (define-safe-public (lilypond-version)
 289   (string-join
 290    (map (lambda (x) (if (symbol? x)
 291                         (symbol->string x)
 292                         (number->string x)))
 293         (ly:version))
 294    "."))
 295
 296 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 297 ;; init pitch system
 298
 299 (ly:set-default-scale (ly:make-scale #(0 1 2 5/2 7/2 9/2 11/2)))
 300
 301
 302
 303 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 304 ;; other files.
 305
 306
 307 (define
 308   init-scheme-files
 309   '("lily-library.scm"
 310             "file-cache.scm"
 311             "define-event-classes.scm"
 312             "define-music-types.scm"
 313             "output-lib.scm"
 314             "c++.scm"
 315             "chord-ignatzek-names.scm"
 316             "chord-entry.scm"
 317             "chord-generic-names.scm"
 318             "stencil.scm"
 319             "markup.scm"
 320             "music-functions.scm"
 321             "part-combiner.scm"
 322             "autochange.scm"
 323             "define-music-properties.scm"
 324             "auto-beam.scm"
 325             "chord-name.scm"
 326
 327             "parser-ly-from-scheme.scm"
 328             "ly-syntax-constructors.scm"
 329
 330             "define-context-properties.scm"
 331             "translation-functions.scm"
 332             "script.scm"
 333             "midi.scm"
 334             "layout-beam.scm"
 335             "parser-clef.scm"
 336             "layout-slur.scm"
 337             "font.scm"
 338             "encoding.scm"
 339
 340             "fret-diagrams.scm"
 341             "predefined-fretboards.scm"
 342             "define-markup-commands.scm"
 343             "define-grob-properties.scm"
 344             "define-grobs.scm"
 345             "define-grob-interfaces.scm"
 346             "define-stencil-commands.scm"
 347             "titling.scm"
 348
 349             "paper.scm"
 350             "backend-library.scm"
 351             "x11-color.scm"
 352
 353             ;; must be after everything has been defined
 354             "safe-lily.scm"))
 355
 356
 357 (for-each ly:load init-scheme-files)
 358
 359
 360 (set! type-p-name-alist
 361       `(
 362         (,boolean-or-symbol? . "boolean or symbol")
 363         (,boolean? . "boolean")
 364         (,char? . "char")
 365         (,grob-list? . "list of grobs")
 366         (,hash-table? . "hash table")
 367         (,input-port? . "input port")
 368         (,integer? . "integer")
 369         (,list? . "list")
 370         (,ly:context? . "context")
 371         (,ly:dimension? . "dimension, in staff space")
 372         (,ly:dir? . "direction")
 373         (,ly:duration? . "duration")
 374         (,ly:grob? . "layout object")
 375         (,ly:input-location? . "input location")
 376         (,ly:moment? . "moment")
 377         (,ly:music? . "music")
 378         (,ly:pitch? . "pitch")
 379         (,ly:translator? . "translator")
 380         (,ly:font-metric? . "font metric")
 381         (,ly:simple-closure? . "simple closure")
 382         (,markup-list? . "list of markups")
 383         (,markup? . "markup")
 384         (,ly:music-list? . "list of music")
 385         (,number-or-grob? . "number or grob")
 386         (,number-or-string? . "number or string")
 387         (,number-pair? . "pair of numbers")
 388         (,number? . "number")
 389         (,output-port? . "output port")
 390         (,pair? . "pair")
 391         (,procedure? . "procedure")
 392         (,rhythmic-location? . "rhythmic location")
 393         (,scheme? . "any type")
 394         (,string? . "string")
 395         (,symbol? . "symbol")
 396         (,vector? . "vector")))
 397
 398 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 399 ;; timing
 400
 401 (define (profile-measurements)
 402   (let* ((t (times))
 403          (stats (gc-stats)))
 404
 405     (list
 406      (- (+ (tms:cutime t)
 407            (tms:utime t))
 408         (ly:assoc-get 'gc-time-taken stats))
 409
 410      (ly:assoc-get 'total-cells-allocated  stats 0)
 411      )))
 412
 413 (define (dump-profile base last this)
 414   (let*
 415       ((outname (format "~a.profile" (dir-basename base ".ly")))
 416        (diff (map (lambda (y) (apply - y)) (zip this last))))
 417
 418     (ly:progress "\nWriting timing to ~a..." outname)
 419     (format (open-file outname "w")
 420             "time: ~a\ncells: ~a\n"
 421             (if (ly:get-option 'dump-cpu-profile)
 422                 (car diff)
 423                 0)
 424             (cadr diff)
 425             )))
 426
 427
 428 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 429 ;; debug mem leaks
 430
 431 (define gc-dumping #f)
 432 (define gc-protect-stat-count 0)
 433
 434 (define-public (dump-live-object-stats outfile)
 435   (for-each
 436    (lambda (x)
 437      (format outfile "~a: ~a\n" (car x) (cdr x)))
 438    (sort (gc-live-object-stats)
 439          (lambda (x y)
 440            (string<? (car x) (car y))))))
 441
 442 (define-public (dump-gc-protects)
 443   (set! gc-protect-stat-count (1+ gc-protect-stat-count))
 444   (let* ((protects (sort
 445                     (hash-table->alist (ly:protects))
 446                     (lambda (a b)
 447                       (< (object-address (car a))
 448                          (object-address (car b))))))
 449
 450          (out-file-name (string-append
 451                          "gcstat-" (number->string gc-protect-stat-count)
 452                          ".scm"))
 453          (outfile    (open-file  out-file-name  "w")))
 454
 455     (set! gc-dumping #t)
 456     (display (format "Dumping GC statistics ~a...\n" out-file-name))
 457     (display
 458      (map (lambda (y)
 459             (let ((x (car y))
 460                   (c (cdr y)))
 461               (display
 462                (format "~a (~a) = ~a\n" (object-address x) c x)
 463                outfile)))
 464           (filter
 465            (lambda (x)
 466              (not (symbol? (car x))))
 467            protects))
 468      outfile)
 469
 470     (format outfile "\nprotected symbols: ~a\n"
 471             (apply + (map (lambda (obj-count) (if (symbol? (car obj-count))
 472                                                   (cdr obj-count)
 473                                                   0))
 474                              protects)))
 475
 476     ;; (display (ly:smob-protects))
 477     (newline outfile)
 478     (if (defined? 'gc-live-object-stats)
 479         (let* ((stats #f))
 480           (display "Live object statistics: GC'ing\n")
 481           (ly:reset-all-fonts)
 482           (gc)
 483           (gc)
 484           (display "Asserting dead objects\n")
 485           (ly:set-option 'debug-gc-assert-parsed-dead #t)
 486           (gc)
 487           (ly:set-option 'debug-gc-assert-parsed-dead #f)
 488
 489           (set! stats (gc-live-object-stats))
 490           (display "Dumping live object statistics.\n")
 491           (dump-live-object-stats outfile)))
 492
 493     (newline outfile)
 494     (let*
 495         ((stats (gc-stats)))
 496
 497       (for-each
 498        (lambda (sym)
 499          (display
 500           (format "~a ~a ~a\n"
 501                   gc-protect-stat-count
 502                   sym
 503                   (let ((sym-stat (assoc sym stats)))
 504                     (if sym-stat
 505                         (cdr sym-stat)
 506                         "?")))
 507           outfile))
 508        '(protected-objects bytes-malloced cell-heap-size
 509
 510                            )))
 511
 512     (set! gc-dumping #f)
 513     (close-port outfile)
 514
 515     ))
 516
 517
 518 (define (check-memory)
 519   "read /proc/self to check up on memory use."
 520   (define (gulp-file name)
 521     (let* ((file (open-input-file name))
 522            (text (read-delimited "" file)))
 523       (close file)
 524       text))
 525   (let*
 526       ((stat (gulp-file "/proc/self/status"))
 527        (lines (string-split stat #\newline))
 528        (interesting (filter identity
 529                             (map
 530                              (lambda (l)
 531                                (string-match "^VmData:[ \t]*([0-9]*) kB" l))
 532                              lines)))
 533        (mem (string->number (match:substring (car interesting) 1)))
 534        )
 535
 536
 537     (display (format  "VMDATA: ~a\n" mem))
 538     (display (gc-stats))
 539     (if (> mem 100000)
 540         (begin
 541           (dump-gc-protects)
 542           (raise 1)))
 543
 544     ))
 545
 546 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 547
 548
 549 (define (multi-fork count)
 550   "Split this process in COUNT helpers. Returns either a list of pids,
 551 or the number of the process."
 552   (define (helper count acc)
 553     (if (> count 0)
 554       (let*
 555           ((pid  (primitive-fork)))
 556         (if (= pid 0)
 557             (1- count)
 558             (helper (1- count) (cons pid acc))))
 559       acc))
 560   (helper count '()))
 561
 562
 563 (define-public (lilypond-main files)
 564   "Entry point for LilyPond."
 565
 566   (eval-string (ly:command-line-code))
 567
 568   (if (ly:get-option 'help)
 569       (begin
 570         (ly:option-usage)
 571         (exit 0)))
 572
 573   (if (ly:get-option 'show-available-fonts)
 574       (begin
 575         (ly:font-config-display-fonts)
 576         (exit 0)
 577         ))
 578
 579
 580   (if (ly:get-option 'gui)
 581       (gui-main files))
 582
 583   (if (null? files)
 584       (begin
 585         (ly:usage)
 586         (exit 2)))
 587
 588   (if (ly:get-option 'read-file-list)
 589       (set! files
 590             (filter (lambda (s)
 591                       (> (string-length s) 0))
 592                     (apply append
 593                            (map (lambda (f) (string-split (ly:gulp-file f) #\nl))
 594                                 files)))
 595             ))
 596
 597   (if (and (number? (ly:get-option 'job-count))
 598            (>= (length files) (ly:get-option 'job-count)))
 599       (let*
 600           ((count (ly:get-option 'job-count))
 601            (split-todo (split-list files count))
 602            (joblist (multi-fork count))
 603            (errors '()))
 604
 605         (if (not (string-or-symbol? (ly:get-option 'log-file)))
 606             (ly:set-option 'log-file "lilypond-multi-run"))
 607
 608         (if (number? joblist)
 609             (begin
 610               (ly:set-option
 611                'log-file (format "~a-~a"
 612                                  (ly:get-option 'log-file) joblist))
 613               (set! files (vector-ref split-todo joblist)))
 614
 615             (begin
 616               (ly:progress "\nForking into jobs:  ~a\n" joblist)
 617               (for-each
 618                (lambda (pid)
 619                  (let* ((stat (cdr (waitpid pid))))
 620
 621                    (if (not (= stat 0))
 622                        (set! errors
 623                              (acons (list-element-index joblist pid)
 624                                     stat errors)))))
 625                joblist)
 626
 627               (for-each
 628                (lambda (x)
 629                  (let* ((job (car x))
 630                         (state (cdr x))
 631                         (logfile (format "~a-~a.log"
 632                                           (ly:get-option 'log-file) job))
 633                         (log (ly:gulp-file logfile))
 634                         (len (string-length log))
 635                         (tail (substring  log (max 0 (- len 1024)))))
 636
 637                    (if (status:term-sig state)
 638                        (ly:message
 639                         "\n\n~a\n"
 640                         (format (_ "job ~a terminated with signal: ~a")
 641                                 job (status:term-sig state)))
 642                        (ly:message
 643                         (_ "logfile ~a (exit ~a):\n~a")
 644                         logfile (status:exit-val state) tail))))
 645
 646                errors)
 647
 648               (if (pair? errors)
 649                   (ly:error "Children ~a exited with errors." (map car errors)))
 650
 651               ;; must overwrite individual entries
 652               (if (ly:get-option 'dump-profile)
 653                   (dump-profile "lily-run-total" '(0 0) (profile-measurements)))
 654
 655             (exit (if (null? errors) 0 1))))))
 656
 657   (if (string-or-symbol? (ly:get-option 'log-file))
 658       (ly:stderr-redirect (format "~a.log" (ly:get-option 'log-file)) "w"))
 659
 660   (let ((failed (lilypond-all files)))
 661     (if (ly:get-option 'trace-scheme-coverage)
 662         (begin
 663           (coverage:show-all (lambda (f) (string-contains f "lilypond"))
 664                              )))
 665
 666     (if (pair? failed)
 667         (begin
 668           (ly:error (_ "failed files: ~S") (string-join failed))
 669           (exit 1))
 670         (begin
 671           ;; HACK: be sure to exit with single newline
 672           (ly:message "")
 673           (exit 0)))))
 674
 675 (define-public (lilypond-all files)
 676   (let* ((failed '())
 677          (separate-logs (ly:get-option 'separate-log-files))
 678          (ping-log
 679           (if separate-logs
 680               (open-file (if (string-or-symbol? (ly:get-option 'log-file))
 681                              (format "~a.log" (ly:get-option 'log-file))
 682                              "/dev/tty") "a") #f))
 683          (do-measurements (ly:get-option 'dump-profile))
 684          (handler (lambda (key failed-file)
 685                     (set! failed (append (list failed-file) failed)))))
 686
 687     (gc)
 688     (for-each
 689      (lambda (x)
 690        (let*
 691            ((start-measurements (if do-measurements
 692                                     (profile-measurements)
 693                                     #f))
 694             (base (dir-basename x ".ly"))
 695             (all-settings (ly:all-options)))
 696
 697          (if separate-logs
 698              (ly:stderr-redirect (format "~a.log" base) "w"))
 699          (if ping-log
 700              (format ping-log "Procesing ~a\n" base))
 701
 702          (if (ly:get-option 'trace-memory-frequency)
 703              (mtrace:start-trace  (ly:get-option 'trace-memory-frequency)))
 704
 705          (lilypond-file handler x)
 706          (if start-measurements
 707              (dump-profile x start-measurements (profile-measurements)))
 708
 709          (if (ly:get-option 'trace-memory-frequency)
 710              (begin
 711                (mtrace:stop-trace)
 712                (mtrace:dump-results base)))
 713
 714          (for-each
 715           (lambda (s)
 716             (ly:set-option (car s) (cdr s)))
 717           all-settings)
 718
 719          (ly:clear-anonymous-modules)
 720          (ly:set-option 'debug-gc-assert-parsed-dead #t)
 721          (gc)
 722          (ly:set-option 'debug-gc-assert-parsed-dead #f)
 723
 724
 725          (if (ly:get-option 'debug-gc)
 726              (dump-gc-protects)
 727              (if (= (random 40) 1)
 728                  (ly:reset-all-fonts)))))
 729
 730      files)
 731
 732     ;; we want the failed-files notice in the aggregrate logfile.
 733     (if ping-log
 734         (format ping-log "Failed files: ~a\n" failed))
 735
 736     (if (ly:get-option 'dump-profile)
 737         (dump-profile "lily-run-total" '(0 0) (profile-measurements)))
 738
 739     failed))
 740
 741 (define (lilypond-file handler file-name)
 742   (catch 'ly-file-failed
 743          (lambda () (ly:parse-file file-name))
 744          (lambda (x . args) (handler x file-name))))
 745
 746 (use-modules (scm editor))
 747
 748 (define-public (gui-main files)
 749   (if (null? files)
 750       (gui-no-files-handler))
 751
 752   (if (not (string? (ly:get-option 'log-file)))
 753       (let* ((base (dir-basename (car files) ".ly"))
 754              (log-name (string-append base ".log")))
 755         (if (not (ly:get-option 'gui))
 756             (ly:message (_ "Redirecting output to ~a...") log-name))
 757         (ly:stderr-redirect log-name "w")
 758         (ly:message "# -*-compilation-*-"))
 759
 760     (let ((failed (lilypond-all files)))
 761       (if (pair? failed)
 762           (begin
 763             ;; ugh
 764             (ly:stderr-redirect "foo" "r")
 765             (system (get-editor-command log-name 0 0 0))
 766             (ly:error (_ "failed files: ~S") (string-join failed))
 767             ;; not reached?
 768             (exit 1))
 769           (exit 0)))))
 770
 771 (define (gui-no-files-handler)
 772   (let* ((ly (string-append (ly:effective-prefix) "/ly/"))
 773          ;; FIXME: soft-code, localize
 774          (welcome-ly (string-append ly "Welcome_to_LilyPond.ly"))
 775          (cmd (get-editor-command welcome-ly 0 0 0)))
 776     (ly:message (_ "Invoking `~a'...") cmd)
 777     (system cmd)
 778     (exit 1)))