scm/framework-ps.scm

   1 ;;;; framework-ps.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c)  2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6
   7 (define-module (scm framework-ps))
   8
   9 (use-modules (ice-9 regex)
  10              (ice-9 string-fun)
  11              (ice-9 format)
  12              (guile)
  13              (srfi srfi-1)
  14              (srfi srfi-13)
  15              (lily))
  16
  17 (define mm-to-bigpoint
  18   (/ 72 25.4))
  19
  20 (define-public (ps-font-command font . override-coding)
  21   (let* ((name (ly:font-filename font))
  22          (magnify (ly:font-magnification font))
  23          (coding-alist (ly:font-encoding-alist font))
  24          (input-encoding (assoc-get 'input-name coding-alist))
  25          (font-encoding (assoc-get 'output-name coding-alist))
  26          (coding-command (if (null? override-coding)
  27                              (if (equal? input-encoding font-encoding)
  28                                  #f font-encoding)
  29                              (car override-coding))))
  30
  31     (string-append
  32      "magfont" (string-encode-integer (hashq  name 1000000))
  33      "m" (string-encode-integer (inexact->exact (round (* 1000 magnify))))
  34      (if (not coding-command) "" (string-append "e" coding-command)))))
  35
  36 (define (tex-font? fontname)
  37   (or
  38    (equal? (substring fontname 0 2) "cm")
  39    (equal? (substring fontname 0 2) "ec")))
  40
  41 (define (load-fonts bookpaper)
  42   (let* ((fonts (ly:bookpaper-fonts bookpaper))
  43          (font-names (uniq-list (sort (map ly:font-filename fonts) string<?)))
  44          (pfas (map
  45                 (lambda (x)
  46
  47                 (let*
  48                     ((aname (string-append x ".pfa"))
  49                      (apath (ly:kpathsea-expand-path aname))
  50
  51                      (bpath (if (not apath)
  52                                 (ly:kpathsea-expand-path (string-append x ".pfb"))
  53                                 #f)))
  54
  55
  56                   (cond
  57                    (apath (ly:gulp-file apath))
  58                    (bpath (ly:pfb->pfa bpath))
  59                    (else
  60                     (ly:warn "Can't find PFA font ~S" x)
  61                     ""))))
  62                 (filter string? font-names))))
  63
  64     (string-join pfas "\n")))
  65
  66 (define (define-fonts bookpaper)
  67
  68   (define font-list (ly:bookpaper-fonts bookpaper))
  69   (define (define-font command fontname scaling)
  70     (string-append
  71      "/" command " { /" fontname " findfont "
  72      (ly:number->string scaling) " output-scale div scalefont } bind def\n"))
  73
  74   (define (reencode-font plain encoding command)
  75     (let ((coding-vector (get-coding-command encoding)))
  76       (string-append
  77        plain " " coding-vector " /" command " reencode-font\n"
  78        "/" command "{ /" command " findfont 1 scalefont } bind def\n")))
  79
  80   (define (guess-ps-fontname basename)
  81
  82     "We do not have the FontName, try to guess is from basename."
  83     (cond
  84      (#t basename)
  85      ((tex-font? basename)
  86       ;; FIXME: we need proper Fontmap for the bluesky CM*, EC* fonts.
  87       ;; Only the fonts that we trace in mf/ are in our own FontMap.
  88       (string-append basename ".pfb"))
  89      (else (string-append basename ".pfa"))))
  90
  91   (define (font-load-command font)
  92     (let* ((specced-font-name (ly:font-name font))
  93            (fontname (if specced-font-name
  94                          specced-font-name
  95                          (guess-ps-fontname (ly:font-filename font))))
  96
  97            (coding-alist (ly:font-encoding-alist font))
  98            (input-encoding (assoc-get 'input-name coding-alist))
  99            (font-encoding (assoc-get 'output-name coding-alist))
 100            (command (ps-font-command font))
 101            ;; FIXME -- see (ps-font-command )
 102            (plain (ps-font-command font #f))
 103            (designsize (ly:font-design-size font))
 104            (magnification (* (ly:font-magnification font)))
 105            (ops (ly:output-def-lookup bookpaper 'outputscale))
 106            (scaling (* ops magnification designsize)))
 107
 108       (string-append
 109        (define-font plain fontname scaling)
 110        (if (or (equal? input-encoding font-encoding)
 111                ;; guh
 112                (equal? font-encoding "fetaBraces")
 113                (equal? font-encoding "fetaNumber")
 114                (equal? font-encoding "fetaMusic")
 115                (equal? font-encoding "parmesanMusic"))
 116                ""
 117            (reencode-font plain input-encoding command)))))
 118
 119   (define (font-load-encoding encoding)
 120     (let ((filename (get-coding-filename encoding)))
 121       (ly:gulp-file (ly:kpathsea-expand-path filename))))
 122
 123   (let* ((encoding-list (map (lambda (x)
 124                                (assoc-get 'input-name
 125                                           (ly:font-encoding-alist x)))
 126                              font-list))
 127          (encodings (uniq-list (sort-list (filter string? encoding-list)
 128                                           string<?))))
 129
 130     (string-append
 131      (apply string-append (map font-load-encoding encodings))
 132      (apply string-append
 133             (map (lambda (x) (font-load-command x)) font-list)))))
 134
 135 ;; FIXME: duplicated in other output backends
 136 ;; FIXME: silly interface name
 137 (define (output-variables paper)
 138   ;; FIXME: duplicates output-paper's scope-entry->string, mostly
 139   (define (value->string  val)
 140     (cond
 141      ((string? val) (string-append "(" val ")"))
 142      ((symbol? val) (symbol->string val))
 143      ((number? val) (number->string val))
 144      (else "")))
 145
 146   (define (output-entry ps-key ly-key)
 147     (string-append
 148      "/" ps-key " "
 149      (value->string (ly:output-def-lookup paper ly-key)) " def \n"))
 150
 151   (string-append
 152    "/lily-output-units " (number->string mm-to-bigpoint) "  def  %% milimeter \n"
 153    (output-entry "staff-line-thickness" 'linethickness)
 154    (output-entry "line-width" 'linewidth)
 155    (output-entry "paper-size" 'papersize)
 156    (output-entry "staff-height" 'staffheight)   ;junkme.
 157    "/output-scale "
 158    (number->string (ly:output-def-lookup paper 'outputscale))
 159    " lily-output-units mul def \n"))
 160
 161 (define (dump-page outputter page page-number page-count)
 162   (ly:outputter-dump-string outputter
 163    (string-append
 164     "%%Page: "
 165     (number->string page-number) " " (number->string page-count) "\n"
 166     "0 0 start-system { "
 167     "set-ps-scale-to-lily-scale "
 168     "\n"))
 169   (ly:outputter-dump-stencil outputter page)
 170   (ly:outputter-dump-string outputter "} stop-system \nshowpage\n"))
 171
 172 (define (eps-header bookpaper bbox)
 173   (string-append "%!PS-Adobe-2.0 EPSF-2.0\n"
 174                  "%%Creator: creator time-stamp\n"
 175                  "%%BoundingBox: " (string-join (map number->string  bbox) " ") "\n"
 176                  "%%EndComments\n"))
 177
 178 (define (page-header bookpaper page-count)
 179   (string-append "%!PS-Adobe-3.0\n"
 180                  "%%Creator: creator time-stamp\n"
 181                  "%%Pages: " (number->string page-count) "\n"
 182                  "%%PageOrder: Ascend\n"
 183                  "%%DocumentPaperSizes: " (ly:output-def-lookup bookpaper 'papersize) "\n"))
 184
 185 (define (preamble bookpaper)
 186   (list
 187    (output-variables bookpaper)
 188    (ly:gulp-file "music-drawing-routines.ps")
 189    (ly:gulp-file "lilyponddefs.ps")
 190    (load-fonts bookpaper)
 191    (define-fonts bookpaper)))
 192
 193 (define-public (output-framework outputter book scopes fields basename)
 194   (let* ((bookpaper (ly:paper-book-book-paper book))
 195          (pages (ly:paper-book-pages book))
 196          (page-number 0)
 197          (page-count (length pages)))
 198   (for-each
 199    (lambda (x)
 200      (ly:outputter-dump-string outputter x))
 201    (cons
 202     (page-header bookpaper page-count)
 203     (preamble bookpaper)))
 204
 205   (for-each
 206    (lambda (page)
 207      (set! page-number (1+ page-number))
 208      (dump-page outputter page page-number page-count))
 209    pages)
 210   (ly:outputter-dump-string outputter "%%Trailer\n%%EOF\n")))
 211
 212 (define-public (output-preview-framework outputter book scopes fields basename)
 213   (let* ((bookpaper (ly:paper-book-book-paper book))
 214          (systems (ly:paper-book-lines book))
 215          (scale  (ly:output-def-lookup bookpaper 'outputscale ))
 216          (titles (take-while ly:paper-system-title? systems))
 217          (non-title (find (lambda (x) (not (ly:paper-system-title? x))) systems))
 218          (dump-me
 219           (stack-stencils Y DOWN 0.0
 220                           (map ly:paper-system-stencil
 221                                (append titles (list non-title)))))
 222          (xext (ly:stencil-extent dump-me X))
 223          (yext (ly:stencil-extent dump-me Y))
 224          )
 225
 226   (for-each
 227    (lambda (x)
 228      (ly:outputter-dump-string outputter x))
 229    (cons
 230     (eps-header bookpaper
 231                 (map
 232                  (lambda (x)
 233                    (inexact->exact
 234                     (round (* x scale mm-to-bigpoint))))
 235                  (list (car xext) (car yext)
 236                        (cdr xext) (cdr yext))))
 237     (preamble bookpaper)))
 238
 239
 240   (ly:outputter-dump-string outputter
 241                             (string-append "0 0 start-system { "
 242                                            "set-ps-scale-to-lily-scale "
 243                                            "\n"))
 244   (ly:outputter-dump-stencil outputter dump-me)
 245   (ly:outputter-dump-string outputter "} stop-system\n%%Trailer\n%%EOF\n")))
 246
 247 (define-public (convert-to-pdf book name)
 248   (let*
 249       ((defs (ly:paper-book-book-paper book))
 250        (size (ly:output-def-lookup defs 'papersize)))
 251
 252     (postscript->pdf (if (string? size) size "a4")
 253                      name)))
 254
 255 (define-public (convert-to-png book name)
 256   (let*
 257       ((defs (ly:paper-book-book-paper book))
 258        (resolution (ly:output-def-lookup defs 'pngresolution)))
 259
 260     (postscript->png (if (number? resolution) resolution 90)
 261                      name)))
 262
 263 (define-public (convert-to-dvi book name)
 264   (ly:warn "Can not generate DVI via the postscript back-end"))
 265
 266 (define-public (convert-to-tex book name)
 267   (ly:warn "Can not generate TeX via the postscript back-end"))
 268
 269 (define-public (convert-to-ps book name)
 270   #t)
 271