mf/feta-macros.mf

   1 %
   2 % debugging
   3 %
   4 def test_grid =
   5 if test>1:
   6         proofrulethickness 1pt#;
   7         makegrid(0pt,0pt for i:=-5pt step 1pt until 5pt: ,i endfor)
   8                 (0pt,0pt for i:=-5pt step 1pt until 5pt: ,i endfor);
   9         proofrulethickness .1pt#;
  10         makegrid(0pt,0pt for i:=-4.8pt step .2pt until 4.8pt: ,i endfor)
  11                 (0pt,0pt for i:=-4.8pt step .2pt until 4.8pt: ,i endfor);
  12 fi
  13         enddef;
  14
  15 def treq =
  16         tracingequations := tracingonline := 1;
  17 enddef;
  18
  19
  20 def draw_staff(expr first, last, offset)=
  21         pickup pencircle scaled stafflinethickness;
  22         for i:= first step 1 until last:
  23                 draw (- staff_space, (i + offset) * staff_space) .. (4 staff_space,( i+ offset)* staff_space);
  24         endfor
  25         enddef;
  26
  27
  28 %
  29 % Transforms
  30 %
  31
  32 def scaledabout(expr point, scale) =
  33         shifted -point scaled scale shifted point
  34 enddef;
  35
  36
  37 %
  38 % make a local (restored after endgroup) copy of t_var
  39 %
  40 def local_copy(text type, t_var)=
  41         save copy_temp;
  42         type copy_temp;
  43         copy_temp := t_var;
  44         save t_var;
  45         type t_var;
  46         t_var := copy_temp;
  47 enddef;
  48
  49
  50 %
  51 % Urgh! Want to do parametric types
  52 %
  53
  54 def del_picture_stack=
  55         save save_picture_stack, picture_stack_idx;
  56 enddef;
  57
  58 % better versions of Taupin/Egler savepic cmds
  59 %
  60 %
  61 def make_picture_stack =
  62         % override previous stack.
  63         del_picture_stack;
  64         picture save_picture_stack[];
  65         numeric picture_stack_idx;
  66         picture_stack_idx := 0;
  67         def push_picture(expr p) =
  68                 save_picture_stack[picture_stack_idx] := p ;
  69                 picture_stack_idx := picture_stack_idx + 1;
  70         enddef;
  71         def pop_picture =  save_picture_stack[decr picture_stack_idx] enddef;
  72         def top_picture = save_picture_stack[picture_stack_idx] enddef;
  73 enddef;
  74
  75
  76 % save/restore pens
  77 % why can't I delete individual pens?
  78 def make_pen_stack =
  79         del_pen_stack;
  80         pen save_pen_stack[];
  81         numeric pen_stack_idx;
  82         pen_stack_idx := 0;
  83         def push_pen(expr p) =
  84                 save_pen_stack[pen_stack_idx] := p ;
  85                 pen_stack_idx := pen_stack_idx +1;
  86         enddef;
  87         def pop_pen =  save_pen_stack[decr pen_stack_idx] enddef;
  88         def top_pen = save_pen_stack[pen_stack_idx] enddef;
  89 enddef;
  90 def del_pen_stack=
  91         save save_pen_stack, pen_stack_idx;
  92 enddef;
  93
  94 %
  95 % drawing
  96 %
  97
  98 def soft_penstroke text t =
  99         forsuffixes e = l,r: path_.e:=t; endfor
 100         if cycle path_.l:
 101           cyclestroke_
 102         else:
 103           fill path_.l .. tension1.5 .. reverse path_.r .. tension1.5 .. cycle
 104         fi
 105 enddef;
 106
 107
 108 %
 109 % make a round path segment going from P to Q. 2*A is the angle that the
 110 % path should take.
 111 %
 112
 113 def simple_serif(expr p,q, a)=
 114         p{dir(angle(q-p) -a)} .. q{ - dir(angle(p -q) + a)}
 115 enddef;
 116 %
 117
 118 % a: x diameter
 119 % b: y diameter
 120 % err_x: drift of y axis at top
 121 % err_y: drift of x axis at right
 122 def distorted_ellipse(expr a,b,err_y,err_x,super) =
 123         superellipse((a,err_x),(-err_y,b),(-a,-err_x),(err_y,-b),super);
 124         enddef;
 125
 126
 127
 128 def draw_rounded_block (expr bottom_left, top_right, roundness) =
 129        save round;
 130        round = floor min(roundness,xpart (top_right-bottom_left),
 131                                    ypart (top_right-bottom_left));
 132
 133
 134        pickup pencircle scaled round;
 135
 136         begingroup;
 137         save x,y;
 138        z2+(round/2,round/2) = top_right;
 139        z4-(round/2,round/2) = bottom_left;
 140         y3 = y2;
 141         y4 = y1;
 142         x2 = x1;
 143         x4 = x3;
 144        fill bot z1 .. rt z1 --- rt z2 .. top z2 ---
 145             top z3 .. lft z3 --- lft z4 .. bot z4 --- cycle;
 146         endgroup;
 147         enddef;
 148
 149
 150
 151  def draw_block (expr bottom_left, top_right) =
 152        draw_rounded_block (bottom_left, top_right, blot_diameter);
 153        enddef;
 154
 155  def draw_gridline (expr bottom_left,top_right,thickness) =
 156        draw_rounded_block (bottom_left-(thickness/2,thickness/2),
 157                            top_right+(thickness/2,thickness/2),
 158                            thickness);
 159        enddef;
 160
 161
 162 def draw_brush(expr a,w,b,v) =
 163         save x,y;
 164         z1=a; z2=b;
 165         penpos3(w,angle(z2-z1)+90);
 166         penpos4(w,angle(z2-z1));
 167         penpos5(v,angle(z1-z2)+90);
 168         penpos6(v,angle(z1-z2));
 169         z3 = z4 = z1;
 170         z5 = z6 = z2;
 171
 172         fill z3r{z3r-z5l}..z4l..{z5r-z3l}z3l..z5r{z5r-z3l}..z6l..{z3r-z5l}z5l..cycle;
 173 enddef;
 174
 175
 176
 177 %
 178 % make a superellipsoid segment going from FROM to TO, with SUPERNESS.
 179 % Take superness = sqrt(2)/2 to get a circle segment
 180 %
 181 % see Knuth, p. 267 and p.126
 182 def super_curvelet(expr from, to, superness, dir) =
 183         if dir = 1:
 184          (superness [xpart to, xpart from], superness [ypart from,ypart to]){to - from}
 185         else:
 186          (superness [xpart from, xpart to], superness [ypart  to,ypart from]){to - from}
 187         fi
 188 enddef;
 189
 190
 191 %
 192 % alpha = start direction.
 193 % beta = which side to turn to.
 194 % flare = diameter of the bulb
 195 % line = diameter of line attachment
 196 % direction = is ink on left or right side (1 or -1)
 197 %
 198 def flare_path(expr pos,alpha,beta,line,flare, direction) =
 199         begingroup;
 200         clearxy;
 201         penpos1(line,180+beta+alpha);
 202         z1r=pos;
 203         penpos2(flare,180+beta+alpha);
 204         z2=z3;
 205         penpos3(flare,0+alpha);
 206         z3l=z1r+(1/2+0.43)*flare*dir(alpha+beta);
 207         save taille;
 208         taille = 0.0;
 209         z4=z2r-  line * dir(alpha);
 210         penlabels(1,2,3,4);
 211         pickup pencircle;
 212         save t; t=0.833;
 213         save p;
 214         path p;
 215         p:=z1r{dir(alpha)}..z3r{dir(180+alpha-beta)}..z2l{dir(alpha+180)}
 216                 ..z3l{dir(180+alpha+beta)}..tension t
 217                 ..z4{dir(180+alpha+beta)}..z1l{dir(alpha+180)};
 218
 219         if direction = 1:
 220                 p
 221         else:
 222                 reverse p
 223         fi
 224         endgroup
 225         enddef;
 226
 227 def flare_path_t(expr pos,alpha,beta,line, flare, bulb, direction) =
 228         begingroup;
 229         clearxy;
 230         penpos1(line, 180+beta+alpha);
 231         z1r=pos;
 232         penpos2(bulb, 180+beta+alpha);
 233         z2=z3;
 234         penpos3(bulb, 0+alpha);
 235         save taille,roundness;
 236
 237         taille = -0.5;
 238         roundness = 0.5;
 239         z3r = z1  + flare * (dir (alpha) + dir (alpha +beta));
 240         z4=  z2r - taille * line * dir(alpha)
 241                 + roundness * line *dir (alpha - beta)
 242                 ;
 243
 244         penlabels(1,2,3,4);
 245         pickup pencircle;
 246         save t; t=0.833;
 247         save p;
 248         path p;
 249         p:=z1r{dir(alpha)}..z3r{dir(180+alpha-beta)}..z2l{dir(alpha+180)}
 250                 ..z3l{dir(180+alpha+beta)}..tension t
 251                 ..z4{dir(180+alpha+beta)}
 252                 ..z1l{dir(alpha+180)};
 253
 254         if direction = 1:
 255                 p
 256         else:
 257                 reverse p
 258         fi
 259         endgroup
 260         enddef;
 261
 262
 263 def brush(expr a,w,b,v) =
 264         begingroup;
 265         draw_brush(a,w,b,v);
 266         penlabels(3,4,5,6);
 267         endgroup;
 268 enddef;
 269
 270 %
 271 % Draw a (rest) crook, starting at thickness STEM in point A,
 272 % ending a ball W to the left, diameter BALLDIAM
 273 % ypart of the center of the ball is BALLDIAM/4 lower than ypart A
 274 %
 275 def balled_crook(expr a, w, balldiam, stem) =
 276 begingroup;
 277         save x,y;
 278         penpos1(balldiam/2,-90);
 279         penpos2(balldiam/2,0);
 280         penpos3(balldiam/2,90);
 281         penpos4(balldiam/2,180);
 282         x4r=xpart a-w; y3r=ypart a+balldiam/4;
 283         x1l=x2l=x3l=x4l;
 284         y1l=y2l=y3l=y4l;
 285         penpos5(stem,250);
 286         x5=x4r+9/8balldiam; y5r=y1r;
 287         penpos6(stem,260);
 288         x6l=xpart a; y6l=ypart a;
 289         penstroke z1e..z2e..z3e..z4e..z1e..z5e{right}..z6e;
 290         penlabels(1,2,3,4,5,6);
 291 endgroup;
 292 enddef;
 293
 294
 295 def y_mirror_char =
 296         currentpicture := currentpicture yscaled -1;
 297         set_char_box(charbp, charwd, charht, chardp);
 298 enddef;
 299
 300
 301 def xy_mirror_char =
 302         currentpicture := currentpicture scaled -1;
 303         set_char_box(charwd, charbp, charht, chardp);
 304 enddef;
 305
 306
 307 %
 308 % center_factor: typically .5, the larger, the larger the radius of the bulb
 309 % radius factor: how much the bulb curves inward
 310 %
 311 def draw_bulb(expr turndir, zl, zr, bulb_rad, radius_factor)=
 312         begingroup;
 313         clearxy;
 314         save rad, ang;
 315
 316         ang = angle(zr-zl);
 317
 318         % don't get near infinity
 319         %z0 = zr + bulb_rad * (zl-zr)/length(zr -zl);
 320         z0 = zr + bulb_rad /length(zr -zl) * (zl-zr);
 321
 322         rad =  bulb_rad;
 323
 324         z1 = z0 + radius_factor* rad * dir(ang + turndir* 100);
 325         z2 = z0 + rad * dir(ang  + turndir*300);
 326         labels(0,1,2);
 327         fill zr{dir (ang + turndir* 90)} .. z1 .. z2 -- cycle;
 328
 329         endgroup
 330 enddef;