lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for mudela
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 #include <iostream.h>
  13 #include "lily-guile.hh"
  14 #include "notename-table.hh"
  15 #include "scalar.hh"
  16 #include "translation-property.hh"
  17 #include "script-def.hh"
  18 #include "symtable.hh"
  19 #include "lookup.hh"
  20 #include "misc.hh"
  21 #include "my-lily-lexer.hh"
  22 #include "paper-def.hh"
  23 #include "midi-def.hh"
  24 #include "main.hh"
  25 #include "file-path.hh"
  26 #include "keyword.hh"
  27 #include "debug.hh"
  28 #include "parseconstruct.hh"
  29 #include "dimensions.hh"
  30 #include "identifier.hh"
  31 #include "command-request.hh"
  32 #include "musical-request.hh"
  33 #include "my-lily-parser.hh"
  34 #include "text-def.hh"
  35 #include "translator-group.hh"
  36 #include "score.hh"
  37 #include "music-list.hh"
  38 #include "duration-convert.hh"
  39 #include "change-translator.hh"
  40 #include "file-results.hh"
  41 #include "mudela-version.hh"
  42 #include "scope.hh"
  43 #include "relative-music.hh"
  44 #include "transposed-music.hh"
  45 #include "compressed-music.hh"
  46 #include "repeated-music.hh"
  47
  48 // mmm
  49 Mudela_version oldest_version ("1.0.7");
  50 Mudela_version version ("1.0.10");
  51
  52
  53 // needed for bison.simple's malloc() and free()
  54 #include <malloc.h>
  55
  56 int const GUESS_PLET = 5;
  57 int guess_plet_a[GUESS_PLET] =
  58 {
  59   1,
  60   3,
  61   2,
  62   3,
  63   4
  64 };
  65
  66 struct Assignment {
  67         String *name_p_;
  68         Identifier *id_p_;
  69         ~Assignment () {
  70                 delete name_p_;
  71                 delete id_p_;
  72         }
  73         Assignment () {
  74                 name_p_ = 0;
  75                 id_p_ =0;
  76         }
  77         Assignment (Assignment const&s)
  78         {
  79                 name_p_ = new String (*s.name_p_);
  80                 id_p_ = s.id_p_->clone ();
  81         }
  82 };
  83
  84 Paper_def* current_paper = 0;
  85
  86 #ifndef NDEBUG
  87 #define YYDEBUG 1
  88 #endif
  89
  90 #define YYERROR_VERBOSE 1
  91
  92 #define YYPARSE_PARAM my_lily_parser_l
  93 #define YYLEX_PARAM my_lily_parser_l
  94 #define THIS ((My_lily_parser *) my_lily_parser_l)
  95
  96 #define yyerror THIS->parser_error
  97 #define ARRAY_SIZE(a,s)   if (a.size () != s) THIS->parser_error (_f("expecting %d arguments", s))
  98
  99 %}
 100
 101
 102 %union {
 103     Array<Interval>* intarr;
 104     Array<Musical_pitch> *pitch_arr;
 105     Array<String> * strvec;
 106     Array<int> *intvec;
 107     Box *box;
 108     Simultaneous_music *chord;
 109     Duration *duration;
 110     Identifier *id;
 111     Translator* trans;
 112     Music *music;
 113     Music_list *music_list;
 114     Score *score;
 115     Scope *scope;
 116     Interval *interval;
 117     Musical_req* musreq;
 118     Music_output_def * outputdef;
 119     Musical_pitch * pitch;
 120     Midi_def* midi;
 121     Moment *moment;
 122     Note_req *notereq;
 123     Notename_table *notenametab;
 124     Paper_def *paper;
 125     Real real;
 126     Request * request;
 127     General_script_def * script;
 128     Scalar *scalar;
 129     String *string;
 130     Atom * symbol;
 131     Symtable * symtable;
 132     Symtables* symtables;
 133     Text_def * textdef;
 134     Tempo_req *tempo;
 135     char c;
 136     const char *consstr;
 137     int i;
 138     int pair[2];
 139     int ii[10];
 140 }
 141 %{
 142
 143 int
 144 yylex (YYSTYPE *s,  void * v_l)
 145 {
 146         My_lily_parser   *pars_l = (My_lily_parser*) v_l;
 147         My_lily_lexer * lex_l = pars_l->lexer_p_;
 148
 149         lex_l->lexval_l = (void*) s;
 150         return lex_l->yylex ();
 151 }
 152
 153
 154 %}
 155
 156 %pure_parser
 157
 158 /* tokens which are not keywords */
 159
 160 %token ABSDYNAMIC
 161 %token ACCEPTS
 162 %token ALTERNATIVE
 163 %token BAR
 164 %token BEAMPLET
 165 %token CADENZA
 166 %token CLEF
 167 %token CM_T
 168 %token CONSISTS
 169 %token DURATION
 170 %token END
 171 %token EXTENDER
 172 %token FONT
 173 %token GROUPING
 174 %token HEADER
 175 %token IN_T
 176 %token KEY
 177 %token KEYSIGNATURE
 178 %token LYRICS
 179 %token MAEBTELP
 180 %token MARK
 181 %token MEASURES
 182 %token MIDI
 183 %token MM_T
 184 %token MUSIC
 185 %token MUSICAL_PITCH
 186 %token NAME
 187 %token NOTENAMES
 188 %token NOTES
 189 %token OCTAVE
 190 %token OUTPUT
 191 %token PAPER
 192 %token PARTIAL
 193 %token PENALTY
 194 %token PLET
 195 %token PROPERTY
 196 %token PT_T
 197 %token RELATIVE
 198 %token REMOVE
 199 %token REPEAT
 200 %token SCM_T
 201 %token SCMFILE
 202 %token SCORE
 203 %token SCRIPT
 204 %token SHAPE
 205 %token SKIP
 206 %token SPANDYNAMIC
 207 %token SYMBOLTABLES
 208 %token TABLE
 209 %token TELP
 210 %token TEMPO
 211 %token TIME_T
 212 %token TIMES
 213 %token TRANSLATOR
 214 %token TRANSPOSE
 215 %token TYPE
 216 %token VERSION
 217
 218 /* escaped */
 219 %token E_EXCLAMATION E_SMALLER E_BIGGER E_CHAR
 220
 221 %type <i>       dots
 222 %token <i>      DIGIT
 223 %token <pitch>  NOTENAME_PITCH
 224 %token <id>     DURATION_IDENTIFIER
 225 %token <id>     IDENTIFIER
 226 %token <id>     NOTENAME_TABLE_IDENTIFIER
 227 %token <id>     MUSIC_IDENTIFIER
 228 %token <id>     POST_REQUEST_IDENTIFIER
 229 %token <id>     SCRIPT_IDENTIFIER
 230 %token <id>     COMMAND_IDENTIFIER
 231 %token <id>     REAL_IDENTIFIER
 232 %token <id>     STRING_IDENTIFIER
 233 %token <id>     TRANS_IDENTIFIER
 234 %token <id>     INT_IDENTIFIER
 235 %token <id>     SCORE_IDENTIFIER
 236 %token <id>     MIDI_IDENTIFIER
 237 %token <id>     PAPER_IDENTIFIER
 238 %token <id>     REQUEST_IDENTIFIER
 239 %token <real>   REAL
 240 %token <string> DURATION RESTNAME
 241 %token <string> STRING
 242 %token <i>      UNSIGNED
 243
 244
 245 %type <outputdef> output_def
 246 %type <scope>   mudela_header mudela_header_body
 247 %type <box>     box
 248 %type <i>       open_request_parens close_request_parens
 249 %type <i>       open_abbrev_parens
 250 %type <i>       open_plet_parens close_plet_parens
 251 %type <i>       sub_quotes sup_quotes
 252 %type <music>   simple_element  request_chord command_element Simple_music  Composite_music
 253 %type <music>   Alternative_music Repeated_music
 254 %type <i>       abbrev_type
 255 %type <i>       int unsigned
 256 %type <i>       script_dir
 257 %type <i>       optional_modality
 258 %type <id>      identifier_init simple_identifier_init block_identifier
 259 %type <duration> steno_duration notemode_duration
 260 %type <duration> entered_notemode_duration explicit_duration
 261 %type <interval>        dinterval
 262 %type <intvec>  intastint_list int_list
 263 %type <symtables>       symtables symtables_body
 264
 265 %type <pitch>   explicit_musical_pitch steno_musical_pitch musical_pitch absolute_musical_pitch
 266 %type <notereq> steno_notepitch
 267 %type <pitch_arr>       pitch_list
 268 %type <midi>    midi_block midi_body
 269 %type <duration>        duration_length
 270
 271 %type <scalar>  scalar
 272 %type <music>   Music  relative_music Sequential_music Simultaneous_music
 273 %type <music>   property_def translator_change
 274 %type <music_list> Music_list
 275 %type <paper>   paper_block paper_def_body
 276 %type <real>    real_expression real dimension
 277 %type <request> abbrev_command_req
 278 %type <request> post_request structured_post_request
 279 %type <pair>    plet_fraction
 280 %type <request> command_req verbose_command_req
 281 %type <request> script_req  dynamic_req extender_req
 282 %type <string>  string
 283 %type <score>   score_block score_body
 284 %type <intarr>  shape_array
 285 %type <script>  script_definition script_body mudela_script gen_script_def
 286 %type <textdef> text_def finger
 287 %type <string>  script_abbreviation
 288 %type <symbol>  symboldef
 289 %type <symtable>        symtable symtable_body
 290 %type <trans>   translator_spec translator_spec_body
 291 %type <tempo>   tempo_request
 292 %type <notenametab> notenames_body notenames_block
 293 %expect 3
 294
 295
 296 %left '-' '+'
 297 %left '*' '/'
 298 %left UNARY_MINUS
 299
 300 %%
 301
 302 mudela: /* empty */
 303         | mudela toplevel_expression {}
 304         | mudela assignment { }
 305         | mudela error
 306         | mudela check_version { }
 307         ;
 308
 309 toplevel_expression:
 310         notenames_block                 {
 311                 THIS->lexer_p_->set_notename_table ($1);
 312         }
 313         | mudela_header {
 314                 delete header_global_p;
 315                 header_global_p = $1;
 316         }
 317         | score_block {
 318                 score_global_array.push ($1);
 319         }
 320         | paper_block {
 321                 Identifier * id = new
 322                         Paper_def_identifier ($1, PAPER_IDENTIFIER);
 323                 THIS->lexer_p_->set_identifier ("$defaultpaper", id)
 324         }
 325         | midi_block {
 326                 Identifier * id = new
 327                         Midi_def_identifier ($1, MIDI_IDENTIFIER);
 328                 THIS->lexer_p_->set_identifier ("$defaultmidi", id)
 329         }
 330         | embedded_scm {
 331         }
 332         ;
 333
 334 embedded_scm:
 335         SCMFILE STRING ';' {
 336                 read_lily_scm_file (*$2);
 337                 delete $2;
 338         }
 339         | SCM_T STRING ';' {
 340                 gh_eval_str ($2->ch_l ());
 341                 delete $2;
 342         };
 343
 344 check_version:
 345         VERSION STRING ';'              {
 346                 Mudela_version ver (*$2);
 347                 if (!((ver >= oldest_version) && (ver <= version))) {
 348                         if (THIS->ignore_version_b_) {
 349                                 THIS->here_input ().error (_f ("incorrect mudela version: %s (%s, %s)", ver.str (), oldest_version.str (), version.str ()));
 350                         } else {
 351                                 THIS->fatal_error_i_ = 1;
 352                                 THIS->parser_error (_f ("incorrect mudela version: %s (%s, %s)", ver.str (), oldest_version.str (), version.str ()));
 353                         }
 354                 }
 355         }
 356         ;
 357
 358
 359 notenames_block:
 360         NOTENAMES '{' notenames_body '}'  {  $$ = $3; }
 361         ;
 362
 363
 364
 365 notenames_body:
 366         /**/    {
 367                 $$ = new Notename_table;
 368         }
 369         | NOTENAME_TABLE_IDENTIFIER     {
 370                 $$ = $1-> access_content_Notename_table(true);
 371         }
 372         | notenames_body STRING '=' explicit_musical_pitch {
 373                 (*$$)[*$2] = *$4;
 374
 375                 delete $4;
 376                 delete $2;
 377         }
 378         ;
 379
 380 mudela_header_body:
 381         {
 382                 $$ = new Scope;
 383                 THIS->lexer_p_-> scope_l_arr_.push ($$);
 384         }
 385         | mudela_header_body assignment ';' {
 386
 387         }
 388         ;
 389
 390 mudela_header:
 391         HEADER '{' mudela_header_body '}'       {
 392                 $$ = $3;
 393                 THIS->lexer_p_-> scope_l_arr_.pop ();
 394         }
 395         ;
 396
 397
 398 /*
 399         DECLARATIONS
 400 */
 401 assignment:
 402         STRING {
 403                 THIS->remember_spot ();
 404         }
 405         /* cont */ '=' identifier_init  {
 406             THIS->lexer_p_->set_identifier (*$1, $4);
 407             $4->init_b_ = THIS->init_parse_b_;
 408             $4->set_spot (THIS->pop_spot ());
 409         }
 410         ;
 411
 412
 413 simple_identifier_init: identifier_init
 414         ;
 415
 416 identifier_init:
 417         block_identifier
 418         ;
 419
 420 block_identifier:
 421         score_block {
 422                 $$ = new Score_identifier ($1, SCORE_IDENTIFIER);
 423
 424         }
 425         | notenames_block {
 426                 $$ = new Notename_table_identifier ($1, NOTENAME_TABLE_IDENTIFIER);
 427         }
 428         | paper_block {
 429                 $$ = new Paper_def_identifier ($1, PAPER_IDENTIFIER);
 430         }
 431         | midi_block {
 432                 $$ = new Midi_def_identifier ($1, MIDI_IDENTIFIER);
 433
 434         }
 435         | symtables {
 436                 $$ = new Symtables_identifier ($1, IDENTIFIER);
 437         }
 438         | translator_spec {
 439                 $$ = new Translator_identifier ($1, TRANS_IDENTIFIER);
 440         }
 441         | Music  {
 442                 $$ = new Music_identifier ($1, MUSIC_IDENTIFIER);
 443         }
 444
 445         | post_request {
 446                 $$ = new Request_identifier ($1, POST_REQUEST_IDENTIFIER);
 447         }
 448         | explicit_duration {
 449                 $$ = new Duration_identifier ($1, DURATION_IDENTIFIER);
 450         }
 451         | real {
 452                 $$ = new Real_identifier (new Real ($1), REAL_IDENTIFIER);
 453         }
 454         | string {
 455                 $$ = new String_identifier ($1, STRING_IDENTIFIER);
 456         }
 457         | int   {
 458                 $$ = new int_identifier (new int ($1), INT_IDENTIFIER);
 459         }
 460         | script_definition {
 461                 $$ = new General_script_def_identifier ($1, SCRIPT_IDENTIFIER);
 462
 463         }
 464         ;
 465
 466 translator_spec:
 467         TRANSLATOR '{' translator_spec_body '}'
 468                 { $$ = $3; }
 469         ;
 470
 471 translator_spec_body:
 472         TRANS_IDENTIFIER        {
 473                 $$ = $1->access_content_Translator (true);
 474                 $$-> set_spot (THIS->here_input ());
 475         }
 476         | TYPE STRING ';'       {
 477                 Translator* t = get_translator_l (*$2);
 478                 Translator_group * tg = dynamic_cast<Translator_group*> (t);
 479
 480                 if (!tg)
 481                         THIS->parser_error (_("Need a translator group for a context"));
 482
 483                 t = t->clone ();
 484                 t->set_spot (THIS->here_input ());
 485                 $$ = t;
 486                 delete $2;
 487         }
 488         | translator_spec_body STRING '=' simple_identifier_init ';'    {
 489                 Identifier* id = $4;
 490                 String_identifier *s = dynamic_cast<String_identifier*> (id);
 491                 Real_identifier *r= dynamic_cast<Real_identifier*>(id);
 492                 int_identifier *i = dynamic_cast<int_identifier*> (id);
 493
 494                 String str;
 495                 if (s) str = *s->access_content_String (false);
 496                 if (i) str = to_str (*i->access_content_int (false));
 497                 if (r) str = to_str (*r->access_content_Real (false));
 498                 if (!s && !i && !r)
 499                         THIS->parser_error (_("Wrong type for property value"));
 500
 501                 delete $4;
 502                 $$->set_property (*$2, str);
 503         }
 504         | translator_spec_body NAME STRING ';' {
 505                 $$->type_str_ = *$3;
 506                 delete $3;
 507         }
 508         | translator_spec_body CONSISTS STRING ';' {
 509                 dynamic_cast<Translator_group*> ($$)-> set_element (*$3, true);
 510                 delete $3;
 511         }
 512         | translator_spec_body ACCEPTS STRING ';' {
 513                 dynamic_cast<Translator_group*> ($$)-> set_acceptor (*$3, true);
 514                 delete $3;
 515         }
 516         | translator_spec_body REMOVE STRING ';' {
 517                 dynamic_cast<Translator_group*> ($$)-> set_element (*$3, false);
 518                 delete $3;
 519         }
 520         ;
 521
 522 /*
 523         SCORE
 524 */
 525 score_block:
 526         SCORE { THIS->remember_spot ();
 527                 THIS->error_level_i_ =0;
 528         }
 529         /*cont*/ '{' score_body '}'     {
 530                 $$ = $4;
 531                 $$->set_spot (THIS->pop_spot ());
 532                 if (!$$->def_p_arr_.size ())
 533                         $$->add_output (THIS->default_paper_p ());
 534
 535                 /* handle error levels. */
 536                 $$->errorlevel_i_ = THIS->error_level_i_;
 537                 THIS->error_level_i_ = 0;
 538         }
 539         ;
 540
 541 score_body:             {
 542                 $$ = new Score;
 543         }
 544         | SCORE_IDENTIFIER {
 545                 $$ = $1->access_content_Score (true);
 546         }
 547         | score_body mudela_header      {
 548                 $$->header_p_ = $2;
 549         }
 550         | score_body Music      {
 551                 if ($$->music_p_)
 552                         $2->warning (_ ("More than one music block"));
 553                 $$->music_p_ = $2;
 554         }
 555         | score_body output_def {
 556                 $$->add_output ($2);
 557         }
 558         | score_body error {
 559
 560         }
 561         ;
 562
 563 output_def:
 564         paper_block {
 565                 $$ = $1;
 566         }
 567         |  midi_block           {
 568                 $$= $1;
 569         }
 570         ;
 571
 572 intastint_list:
 573         /* */   { $$ =new Array<int>; }
 574         | intastint_list int '*' int    {
 575                 $$->push ($2); $$->push ($4);
 576         }
 577         | intastint_list int    {
 578                 $$->push ($2); $$->push (1);
 579         }
 580         ;
 581
 582
 583 /*
 584         PAPER
 585 */
 586 paper_block:
 587         PAPER '{' paper_def_body '}'    {
 588                 $$ = $3;
 589                 THIS-> lexer_p_->scope_l_arr_.pop ();
 590         }
 591         ;
 592
 593 optional_semicolon:
 594         /* empty */
 595         | ';'
 596         ;
 597
 598 paper_def_body:
 599         /* empty */                     {
 600                 Paper_def *p = THIS->default_paper_p ();
 601                 THIS-> lexer_p_-> scope_l_arr_.push (p->scope_p_);
 602                 $$ = p;
 603         }
 604         | PAPER_IDENTIFIER optional_semicolon   {
 605                 Paper_def *p = $1->access_content_Paper_def (true);
 606                 THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 607                 $$ = p;
 608         }
 609         | paper_def_body int '=' symtables              { // ugh, what a syntax
 610                 Lookup * l = new Lookup (*$4);
 611                 $$->set_lookup ($2, l);
 612         }
 613         | paper_def_body assignment ';' {
 614
 615         }
 616         | paper_def_body translator_spec {
 617                 $$->assign_translator ($2);
 618         }
 619         | paper_def_body SHAPE '=' shape_array ';' {
 620                 $$->shape_int_a_ = *$4;
 621                 delete $4;
 622         }
 623         | paper_def_body error {
 624
 625         }
 626         ;
 627
 628
 629 real:
 630         real_expression         { $$ = $1; }
 631         ;
 632
 633
 634 dimension:
 635         REAL CM_T       {
 636                 $$ = $1 CM;
 637         }
 638         | REAL PT_T     {
 639                 $$ = $1 PT;
 640         }
 641         | REAL IN_T     {
 642                 $$ = $1 INCH;
 643         }
 644         | REAL MM_T     {
 645                 $$ = $1 MM;
 646         }
 647         ;
 648
 649 real_expression:
 650         REAL            {
 651                 $$ = $1;
 652         }
 653         | dimension
 654         | REAL_IDENTIFIER               {
 655                 $$= *$1->access_content_Real (false);
 656         }
 657         | '-'  real_expression %prec UNARY_MINUS {
 658                 $$ = -$2;
 659         }
 660         | real_expression '*' real_expression {
 661                 $$ = $1 * $3;
 662         }
 663         | real_expression '/' real_expression {
 664                 $$ = $1 / $3;
 665         }
 666         | real_expression '+' real_expression {
 667                 $$ = $1  + $3;
 668         }
 669         | real_expression '-' real_expression {
 670                 $$ = $1 - $3;
 671         }
 672         | '(' real_expression ')'       {
 673                 $$ = $2;
 674         }
 675         ;
 676
 677
 678 shape_array:
 679         /* empty */ {
 680                 $$ = new Array<Interval>;
 681         }
 682         | shape_array real real {
 683                 $$->push(Interval($2, $2 + $3));
 684         };
 685
 686 /*
 687         MIDI
 688 */
 689 midi_block:
 690         MIDI
 691
 692         '{' midi_body '}'       { $$ = $3; }
 693         ;
 694
 695 midi_body: /* empty */          {
 696                 $$ = THIS->default_midi_p ();
 697         }
 698         | MIDI_IDENTIFIER       {
 699                 $$ = $1-> access_content_Midi_def (true);
 700         }
 701         | midi_body translator_spec     {
 702                 $$-> assign_translator ($2);
 703         }
 704         | midi_body tempo_request ';' {
 705                 $$->set_tempo ($2->dur_.length (), $2->metronome_i_);
 706                 delete $2;
 707         }
 708         | midi_body error {
 709
 710         }
 711         ;
 712
 713 tempo_request:
 714         TEMPO entered_notemode_duration '=' unsigned    {
 715                 $$ = new Tempo_req;
 716                 $$->dur_ = *$2;
 717                 delete $2;
 718                 $$-> metronome_i_ = $4;
 719         }
 720         ;
 721
 722 Music_list: /* empty */ {
 723                 $$ = new Music_list;
 724         }
 725         | Music_list Music {
 726                 $$->add_music ($2);
 727         }
 728         | Music_list error {
 729         }
 730         ;
 731
 732
 733 Music:
 734         Simple_music
 735         | Composite_music
 736         ;
 737
 738 Alternative_music: {
 739                 Music_list* m = new Music_list;
 740                 $$ = new Sequential_music (m);
 741         }
 742         | ALTERNATIVE '{' Music_list '}'                {
 743                 $$ = new Sequential_music ($3);
 744         }
 745         ;
 746
 747 Repeated_music: REPEAT unsigned '{' Music '}' Alternative_music {
 748                 // s/r conflicts -> '{' '}'
 749                 Sequential_music* s = (Sequential_music*)$6;
 750                 $$ = new Repeated_music ($4, $2, s);
 751         }
 752         ;
 753
 754 Sequential_music: '{' Music_list '}'            {
 755                 $$ = new Sequential_music ($2);
 756         }
 757         ;
 758
 759 Simultaneous_music: '<' Music_list '>'  {
 760                 $$ = new Simultaneous_music ($2);
 761         }
 762         ;
 763
 764 Simple_music:
 765         request_chord           { $$ = $1; }
 766         | MUSIC_IDENTIFIER { $$ = $1->access_content_Music (true); }
 767         | property_def
 768         | translator_change
 769         ;
 770
 771
 772 Composite_music:
 773         TYPE STRING Music       {
 774                 $$ = $3;
 775                 $$->translator_type_str_ = *$2;
 776                 delete $2;
 777         }
 778         | TYPE STRING '=' STRING Music {
 779                 $$ = $5;
 780                 $$->translator_type_str_ = *$2;
 781                 $$->translator_id_str_ = *$4;
 782                 delete $2;
 783                 delete $4;
 784         }
 785         | TIMES {
 786                 THIS->remember_spot ();
 787         }
 788         /* CONTINUED */
 789                 int '/' int Music
 790
 791         {
 792                 $$ = new Compressed_music ($3, $5, $6);
 793                 $$->set_spot (THIS->pop_spot ());
 794         }
 795         | Repeated_music                { $$ = $1; }
 796         | Simultaneous_music            { $$ = $1; }
 797         | Sequential_music              { $$ = $1; }
 798         | TRANSPOSE musical_pitch Music {
 799                 $$ = new Transposed_music ($3, *$2);
 800                 delete $2;
 801         }
 802         | NOTES
 803                 { THIS->lexer_p_->push_note_state (); }
 804         Music
 805                 { $$ = $3;
 806                   THIS->lexer_p_->pop_state ();
 807                 }
 808
 809         | LYRICS
 810                 { THIS->lexer_p_->push_lyric_state (); }
 811         Music
 812                 {
 813                   $$ = $3;
 814                   THIS->lexer_p_->pop_state ();
 815         }
 816         | relative_music        { $$ = $1; }
 817         ;
 818
 819 relative_music:
 820         RELATIVE absolute_musical_pitch Music {
 821                 $$ = new Relative_octave_music ($3, *$2);
 822                 delete $2;
 823         }
 824         ;
 825
 826 translator_change:
 827         TRANSLATOR STRING '=' STRING  {
 828                 Change_translator * t = new Change_translator;
 829                 t-> change_to_type_str_ = *$2;
 830                 t-> change_to_id_str_ = *$4;
 831
 832                 $$ = t;
 833                 $$->set_spot (THIS->here_input ());
 834                 delete $2;
 835                 delete $4;
 836         }
 837         ;
 838
 839 property_def:
 840         PROPERTY STRING '.' STRING '=' scalar   {
 841                 Translation_property *t = new Translation_property;
 842                 t-> translator_type_str_ = *$2;
 843                 t-> var_str_ = *$4;
 844                 t-> value_ = *$6;
 845                 $$ = t;
 846                 $$->set_spot (THIS->here_input ());
 847                 delete $2;
 848                 delete $4;
 849                 delete $6;
 850         }
 851         ;
 852
 853 scalar:
 854         STRING          { $$ = new Scalar (*$1); delete $1; }
 855         | int           { $$ = new Scalar ($1); }
 856         ;
 857
 858
 859 request_chord:
 860         pre_requests simple_element post_requests       {
 861                 THIS->add_requests ((Simultaneous_music*)$2);//ugh
 862                 $$ = $2;
 863         }
 864         | command_element
 865         ;
 866
 867 command_element:
 868         command_req {
 869                 $$ = new Request_chord;
 870                 $$-> set_spot (THIS->here_input ());
 871                 $1-> set_spot (THIS->here_input ());
 872                 ((Simultaneous_music*)$$) ->add_music ($1);//ugh
 873         }
 874         ;
 875
 876 command_req:
 877         abbrev_command_req
 878         | verbose_command_req ';'       { $$ = $1; }
 879         ;
 880
 881 abbrev_command_req:
 882         '|'                             {
 883                 $$ = new Barcheck_req;
 884         }
 885         | COMMAND_IDENTIFIER    {
 886                 $$ = $1->access_content_Request (true);
 887         }
 888 /*
 889         | '['           {
 890                 $$ = new Beam_req;
 891                 $$->spantype = Span_req::START;
 892         }
 893         | ']'           {
 894                 $$ = new Beam_req;
 895                 $$->spantype = Span_req::STOP;
 896         }
 897 */
 898         ;
 899
 900
 901 verbose_command_req:
 902         BAR STRING                      {
 903                 $$ = new Bar_req (*$2);
 904                 delete $2;
 905         }
 906         | MARK STRING {
 907                 $$ = new Mark_req (*$2);
 908                 delete $2;
 909         }
 910         | MARK unsigned {
 911                 $$ = new Mark_req (to_str ($2));
 912         }
 913         | TIME_T unsigned '/' unsigned  {
 914                 Time_signature_change_req *m = new Time_signature_change_req;
 915                 m->beats_i_ = $2;
 916                 m->one_beat_i_=$4;
 917                 $$ = m;
 918         }
 919         | PENALTY '=' int       {
 920                 Break_req * b = new Break_req;
 921                 b->penalty_i_ = $3;
 922                 b-> set_spot (THIS->here_input ());
 923                 $$ = b;
 924         }
 925         | SKIP duration_length {
 926                 Skip_req * skip_p = new Skip_req;
 927                 skip_p->duration_ = *$2;
 928                 delete $2;
 929                 $$ = skip_p;
 930         }
 931         | tempo_request {
 932                 $$ = $1;
 933         }
 934         | CADENZA unsigned      {
 935                 $$ = new Cadenza_req ($2);
 936         }
 937         | PARTIAL duration_length       {
 938                 $$ = new Partial_measure_req ($2->length ());
 939                 delete $2;
 940         }
 941         | CLEF STRING {
 942                 $$ = new Clef_change_req (*$2);
 943                 delete $2;
 944         }
 945         | KEY NOTENAME_PITCH optional_modality  {
 946                 Key_change_req *key_p= new Key_change_req;
 947                 key_p->pitch_arr_.push(*$2);
 948                 key_p->ordinary_key_b_ = true;
 949                 key_p->modality_i_ = $3;
 950                 $$ = key_p;
 951                 delete $2;
 952         }
 953         | KEYSIGNATURE pitch_list       {
 954                 Key_change_req *key_p= new Key_change_req;
 955                 key_p->pitch_arr_ = *$2;
 956                 key_p->ordinary_key_b_ = false;
 957                 $$ = key_p;
 958                 delete $2;
 959         }
 960         | GROUPING intastint_list {
 961                 $$ = get_grouping_req (*$2); delete $2;
 962         }
 963         ;
 964
 965 post_requests:
 966         {
 967                 /* something silly happened.  Junk this stuff*/
 968                 if (!THIS->post_reqs.empty ())
 969                 {
 970                         warning ("Junking post-requests");
 971                         THIS->post_reqs.clear ();
 972                 }
 973         }
 974         | post_requests structured_post_request {
 975                 $2->set_spot (THIS->here_input ());
 976                 THIS->post_reqs.push ($2);
 977         }
 978         | post_requests close_request_parens    {
 979                 Array<Request*>& r = *THIS->get_parens_request ($2);
 980                 for (int i = 0; i < r.size (); i++ )
 981                         r[i]->set_spot (THIS->here_input ());
 982                 THIS->post_reqs.concat (r);
 983                 delete &r;
 984         }
 985         ;
 986
 987 structured_post_request:
 988         script_req
 989         | post_request
 990         ;
 991
 992 post_request:
 993         POST_REQUEST_IDENTIFIER {
 994                 $$ = (Request*)$1->access_content_Request (true);
 995         }
 996         | dynamic_req {
 997                 $$ = $1;
 998         }
 999         | abbrev_type   {
1000                 Abbreviation_req* a = new Abbreviation_req;
1001                 a->type_i_ = $1;
1002                 $$ = a;
1003         }
1004         | extender_req {
1005                 $$ = $1;
1006         }
1007         ;
1008
1009 optional_modality:
1010         /* empty */     {
1011                 $$ = 0;
1012         }
1013         | int   {
1014                 $$ = $1;
1015         }
1016         ;
1017
1018 sup_quotes:
1019         '\'' {
1020                 $$ = 1;
1021         }
1022         | sup_quotes '\'' {
1023                 $$ ++;
1024         }
1025         ;
1026 sub_quotes:
1027         ',' {
1028                 $$ = 1;
1029         }
1030         | sub_quotes ',' {
1031                 $$ ++ ;
1032         }
1033         ;
1034
1035 steno_musical_pitch:
1036         NOTENAME_PITCH  {
1037                 $$ = $1;
1038         }
1039         | NOTENAME_PITCH sup_quotes     {
1040                 $$ = $1;
1041                 $$->octave_i_ +=  $2;
1042         }
1043         | NOTENAME_PITCH sub_quotes      {
1044                 $$ = $1;
1045                 $$->octave_i_ += - $2;
1046         }
1047         ;
1048
1049 explicit_musical_pitch:
1050         MUSICAL_PITCH '{' int_list '}'  {/* ugh */
1051                 Array<int> &a = *$3;
1052                 ARRAY_SIZE(a,3);
1053                 $$ = new Musical_pitch;
1054                 $$->octave_i_ = a[0];
1055                 $$->notename_i_ = a[1];
1056                 $$->accidental_i_ = a[2];
1057                 delete &a;
1058         }
1059         ;
1060
1061 musical_pitch:
1062         steno_musical_pitch
1063         | explicit_musical_pitch
1064         ;
1065
1066 steno_notepitch:
1067         musical_pitch   {
1068                 $$ = new Note_req;
1069
1070                 $$->pitch_ = *$1;
1071                 delete $1;
1072         }
1073         | steno_notepitch  '!'          {
1074                 $$->forceacc_b_ = ! $$->forceacc_b_;
1075         }
1076         | steno_notepitch  '?'          {
1077                 $$->forceacc_b_ = ! $$->forceacc_b_;
1078                 $$->cautionary_b_ = ! $$->cautionary_b_;
1079         }
1080         ;
1081
1082
1083 explicit_duration:
1084         DURATION '{' int_list '}'       {
1085                 $$ = new Duration;
1086                 Array<int> &a = *$3;
1087                 ARRAY_SIZE(a,2);
1088
1089                 $$-> durlog_i_ = a[0];
1090                 $$-> dots_i_ = a[1];
1091
1092                 delete &a;
1093         }
1094         ;
1095
1096 extender_req:
1097         EXTENDER {
1098                 if (!THIS->lexer_p_->lyric_state_b ())
1099                         THIS->parser_error (_ ("have to be in Lyric mode for lyrics"));
1100                 Extender_req * e_p = new Extender_req;
1101                 e_p->spantype = Span_req::START;
1102                 $$ = e_p;
1103                 THIS->extender_req = e_p;
1104         };
1105
1106 dynamic_req:
1107         ABSDYNAMIC '{' unsigned '}'     {
1108                 Absolute_dynamic_req *ad_p = new Absolute_dynamic_req;
1109                 ad_p ->loudness_ = (Dynamic_req::Loudness)$3;
1110                 $$ =ad_p;
1111         }
1112         | SPANDYNAMIC '{' int int '}' {
1113                 Span_dynamic_req * sp_p = new Span_dynamic_req;
1114                 sp_p->spantype = (Span_req::Spantype)$4;
1115                 sp_p-> dynamic_dir_  = (Direction)$3;
1116                 $$ = sp_p;
1117         }
1118         ;
1119
1120 plet_fraction:
1121         unsigned '/' unsigned {
1122                 $$[0] = $1;
1123                 $$[1] = $3;
1124         }
1125         |
1126         '/' unsigned {
1127                 int num = $2 >? 1;
1128                 $$[0] = guess_plet_a[(num <? GUESS_PLET) - 1];
1129                 $$[1] = num;
1130         }
1131         ;
1132
1133 close_plet_parens:
1134         ']' plet_fraction {
1135                 $$ = MAEBTELP;
1136                 THIS->plet_.type_i_ = $2[1];
1137                 THIS->plet_.iso_i_ = $2[0];
1138                 THIS->default_duration_.plet_ = THIS->plet_;
1139         }
1140         | TELP {
1141                 $$ = TELP;
1142                 THIS->plet_.type_i_ = 1;
1143                 THIS->plet_.iso_i_ = 1;
1144                 THIS->default_duration_.plet_ = THIS->plet_;
1145         }
1146         | TELP plet_fraction {
1147                 $$ = TELP;
1148                 THIS->plet_.type_i_ = $2[1];
1149                 THIS->plet_.iso_i_ = $2[0];
1150                 THIS->default_duration_.plet_ = THIS->plet_;
1151         }
1152         ;
1153
1154 close_request_parens:
1155         '~'     {
1156                 $$ = '~';
1157         }
1158         | '('   {
1159                 $$='(';
1160         }
1161         | ']'   {
1162                 $$ = ']';
1163         }
1164         | E_SMALLER {
1165                 $$ = '<';
1166         }
1167         | E_BIGGER {
1168                 $$ = '>';
1169         }
1170         | close_plet_parens
1171         ;
1172
1173 open_abbrev_parens:
1174         '[' ':' unsigned {
1175                 $$ = '[';
1176                 if (!Duration::duration_type_b ($3))
1177                         THIS->parser_error (_f ("not a duration: %d", $3));
1178                 else if ($3 < 8)
1179                         THIS->parser_error (_ ("can't abbreviate"));
1180                 else
1181                         THIS->set_abbrev_beam ($3);
1182         }
1183         ;
1184
1185 open_plet_parens:
1186         '[' plet_fraction {
1187                 $$ = BEAMPLET;
1188                 THIS->plet_.type_i_ = $2[1];
1189                 THIS->plet_.iso_i_ = $2[0];
1190                 THIS->default_duration_.plet_ = THIS->plet_;
1191         }
1192         | PLET plet_fraction {
1193                 $$ = PLET;
1194                 THIS->plet_.type_i_ = $2[1];
1195                 THIS->plet_.iso_i_ = $2[0];
1196                 THIS->default_duration_.plet_ = THIS->plet_;
1197         }
1198         ;
1199
1200 open_request_parens:
1201         E_EXCLAMATION   {
1202                 $$ = '!';
1203         }
1204         | ')'   {
1205                 $$=')';
1206         }
1207         | '['   {
1208                 $$='[';
1209         }
1210         | open_abbrev_parens
1211         | open_plet_parens
1212         ;
1213
1214
1215
1216 script_definition:
1217         SCRIPT '{' script_body '}'      { $$ = $3; }
1218         ;
1219
1220 script_body:
1221         STRING int int int int int              {
1222                 Script_def *s = new Script_def;
1223                 s->set_from_input (*$1,$2, $3,$4,$5, $6);
1224                 $$  = s;
1225                 delete $1;
1226         }
1227         ;
1228
1229 script_req:
1230         script_dir gen_script_def       {
1231                 Musical_script_req *m = new Musical_script_req;
1232                 $$ = m;
1233                 m->scriptdef_p_ = $2;
1234                 m->set_spot (THIS->here_input ());
1235                 if (!m->dir_)
1236                   m->dir_  = (Direction)$1;
1237         }
1238         ;
1239
1240 gen_script_def:
1241         text_def        {
1242                 $$ = $1;
1243                 ((Text_def*) $$)->align_dir_ = LEFT; /* UGH */
1244         }
1245         | mudela_script {
1246                 $$ = $1;
1247                 $$-> set_spot (THIS->here_input ());
1248         }
1249         | finger {
1250                 $$ = $1;
1251                 ((Text_def*)$$)->align_dir_ = RIGHT; /* UGH */
1252         }
1253         ;
1254
1255 text_def:
1256         string {
1257                 Text_def *t  = new Text_def;
1258                 $$ = t;
1259                 t->text_str_ = *$1;
1260                 delete $1;
1261                 $$->set_spot (THIS->here_input ());
1262         }
1263         ;
1264
1265 finger:
1266          DIGIT {
1267                 Text_def* t  = new Text_def;
1268                 $$ = t;
1269                 t->text_str_ = to_str ($1);
1270                 t->style_str_ = "finger";
1271                 $$->set_spot (THIS->here_input ());
1272         }
1273         ;
1274
1275 script_abbreviation:
1276         '^'             { $$ = get_scriptdef ('^'); }
1277         | '+'           { $$ = get_scriptdef ('+'); }
1278         | '-'           { $$ = get_scriptdef ('-'); }
1279         | '|'           { $$ = get_scriptdef ('|'); }
1280         | 'o'           { $$ = get_scriptdef ('o'); }
1281         | '>'           { $$ = get_scriptdef ('>'); }
1282         | '.'           {
1283                 $$ = get_scriptdef ('.');
1284         }
1285         ;
1286
1287 mudela_script:
1288         SCRIPT_IDENTIFIER               { $$ = $1->access_content_General_script_def (true); }
1289         | script_definition             { $$ = $1; }
1290         | script_abbreviation           {
1291                 $$ = THIS->lexer_p_->lookup_identifier (*$1)->access_content_General_script_def (true);
1292                 delete $1;
1293         }
1294         ;
1295
1296 script_dir:
1297         '_'     { $$ = -1; }
1298         | '^'   { $$ = 1; }
1299         | '-'   { $$ = 0; }
1300         ;
1301
1302 pre_requests:
1303         {
1304                 if (THIS->extender_req)
1305                   {
1306                     Extender_req * e_p = new Extender_req;
1307                     e_p->spantype = Span_req::STOP;
1308                     THIS->pre_reqs.push (e_p);
1309                     THIS->extender_req = 0;
1310                   }
1311
1312         }
1313         | pre_requests open_request_parens {
1314
1315                 Array<Request*>& r = *THIS->get_parens_request ($2);
1316                 for (int i = 0; i < r.size (); i++ )
1317                         r[i]->set_spot (THIS->here_input ());
1318                 THIS->pre_reqs.concat (r);
1319                 delete &r;
1320         }
1321         ;
1322
1323 absolute_musical_pitch:
1324         steno_musical_pitch     {
1325                 $$ = $1;
1326         }
1327         ;
1328
1329 duration_length:
1330         steno_duration {
1331                 $$ = $1;
1332         }
1333         ;
1334
1335 dots:
1336         '.'             { $$ = 1; }
1337         | dots '.'      { $$ ++; }
1338         ;
1339
1340 entered_notemode_duration:
1341         /* */           {
1342                 $$ = new Duration (THIS->default_duration_);
1343         }
1344         | dots          {
1345                 $$ = new Duration (THIS->default_duration_);
1346                 $$->dots_i_  = $1;
1347         }
1348         | steno_duration        {
1349                 THIS->set_last_duration ($1);
1350         }
1351         ;
1352
1353 notemode_duration:
1354         entered_notemode_duration {
1355                 $$ = $1;
1356         }
1357         ;
1358
1359 steno_duration:
1360         unsigned                {
1361                 $$ = new Duration;
1362                 if (!Duration::duration_type_b ($1))
1363                         THIS->parser_error (_f ("not a duration: %d", $1));
1364                 else {
1365                         $$->durlog_i_ = Duration_convert::i2_type ($1);
1366                         $$->set_plet (THIS->plet_.iso_i_, THIS->plet_.type_i_);
1367                      }
1368         }
1369         | DURATION_IDENTIFIER   {
1370                 $$ = $1->access_content_Duration (true);
1371         }
1372         | steno_duration '.'    {
1373                 $$->dots_i_ ++;
1374         }
1375         | steno_duration '*' unsigned  {
1376                 $$->plet_.iso_i_ *= $3;
1377         }
1378         | steno_duration '/' unsigned {
1379                 $$->plet_.type_i_ *= $3;
1380         }
1381         ;
1382
1383
1384 abbrev_type:
1385         ':'     {
1386                 $$ =0;
1387         }
1388         | ':' unsigned {
1389                 if (!Duration::duration_type_b ($2))
1390                         THIS->parser_error (_f ("not a duration: %d", $2));
1391                 else if ($2 < 8)
1392                         THIS->parser_error (_ ("can't abbreviate"));
1393                 $$ = $2;
1394         }
1395         ;
1396
1397
1398
1399 simple_element:
1400         steno_notepitch notemode_duration  {
1401                 if (!THIS->lexer_p_->note_state_b ())
1402                         THIS->parser_error (_ ("have to be in Note mode for notes"));
1403                 $1->duration_ = *$2;
1404                 $$ = THIS->get_note_element ($1, $2);
1405         }
1406         | RESTNAME notemode_duration            {
1407                 $$ = THIS->get_rest_element (*$1, $2);
1408                 delete $1;  // delete notename
1409         }
1410         | MEASURES notemode_duration    {
1411                 Multi_measure_rest_req* m = new Multi_measure_rest_req;
1412                 m->duration_ = *$2;
1413                 delete $2;
1414
1415                 Simultaneous_music*velt_p = new Request_chord;
1416                 velt_p->set_spot (THIS->here_input ());
1417                 velt_p->add_music (m);
1418                 $$ = velt_p;
1419         }
1420         | STRING notemode_duration                      {
1421                 if (!THIS->lexer_p_->lyric_state_b ())
1422                         THIS->parser_error (_ ("have to be in Lyric mode for lyrics"));
1423                 $$ = THIS->get_word_element (*$1, $2);
1424                 delete $1;
1425         }
1426         ;
1427
1428
1429 /*
1430         UTILITIES
1431  */
1432 pitch_list:                     {
1433                 $$ = new Array<Musical_pitch>;
1434         }
1435         | pitch_list musical_pitch      {
1436                 $$->push (*$2);
1437                 delete $2;
1438         }
1439         ;
1440
1441
1442 int_list:
1443         /**/                    {
1444                 $$ = new Array<int>
1445         }
1446         | int_list int          {
1447                 $$->push ($2);
1448         }
1449         ;
1450
1451 unsigned:
1452         UNSIGNED        {
1453                 $$ = $1;
1454         }
1455         | DIGIT {
1456                 $$ = $1;
1457         };
1458
1459 int:
1460         unsigned {
1461                 $$ = $1;
1462         }
1463         | '-' unsigned {
1464                 $$ = -$2;
1465         }
1466         | INT_IDENTIFIER        {
1467                 $$ = *$1->access_content_int (false);
1468         }
1469         ;
1470
1471
1472 string:
1473         STRING          {
1474                 $$ = $1;
1475         }
1476         | STRING_IDENTIFIER     {
1477                 $$ = $1->access_content_String (true);
1478         }
1479         | string '+' string {
1480                 *$$ += *$3;
1481                 delete $3;
1482         }
1483         ;
1484
1485
1486
1487 /*
1488         symbol tables
1489 */
1490 symtables:
1491         SYMBOLTABLES '{' symtables_body '}'     { $$ = $3; }
1492         ;
1493
1494 symtables_body:
1495                         {
1496                 $$ = new Symtables;
1497         }
1498         | IDENTIFIER            {
1499                 $$ = $1->access_content_Symtables (true);
1500         }
1501         | symtables_body FONT STRING            {
1502                 $$->font_ = *$3;
1503                 $$->font_path_ = global_path.find (*$3);
1504                 if  (!$$->font_path_.length_i ())
1505                         THIS->here_input ().error (_f("can't open file: `%s'", $3->ch_C()));
1506
1507                 delete $3;
1508         }
1509         | symtables_body STRING '=' symtable            {
1510                 $$->add (*$2, $4);
1511                 delete $2;
1512         }
1513         ;
1514
1515 symtable:
1516         TABLE '{' symtable_body '}' { $$ = $3; }
1517         ;
1518
1519 symtable_body:
1520                                 { $$ = new Symtable; }
1521         | symtable_body STRING  symboldef {
1522                 $$->elem (*$2) = *$3;
1523                 delete $2;
1524                 delete $3;
1525         }
1526         ;
1527
1528 symboldef:
1529         STRING unsigned box             {
1530                 // ignore #args
1531                 $$ = new Atom (*$1, *$3);
1532                 delete $1;
1533                 delete $3;
1534         }
1535         | STRING unsigned {
1536                 Box b (Interval (0,0), Interval (0,0));
1537                 // ignore #args
1538                 $$ = new Atom (*$1, b);
1539                 delete $1;
1540         }
1541         ;
1542
1543 box:
1544         dinterval dinterval     {
1545                 $$ = new Box (*$1, *$2);
1546                 delete $1;
1547                 delete $2;
1548         }
1549         ;
1550
1551 dinterval: real real            {
1552                 $$ = new Interval ($1, $2);
1553         }
1554         ;
1555
1556 %%
1557
1558 void
1559 My_lily_parser::set_yydebug (bool b)
1560 {
1561 #ifdef YYDEBUG
1562         yydebug = b;
1563 #endif
1564 }
1565 void
1566 My_lily_parser::do_yyparse ()
1567 {
1568         yyparse ((void*)this);
1569 }
1570
1571