lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for mudela
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2000 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 #include <iostream.h>
  13 #include "lily-guile.hh"
  14 #include "translation-property.hh"
  15 #include "lookup.hh"
  16 #include "misc.hh"
  17 #include "my-lily-lexer.hh"
  18 #include "paper-def.hh"
  19 #include "midi-def.hh"
  20 #include "main.hh"
  21 #include "file-path.hh"
  22 #include "debug.hh"
  23 #include "dimensions.hh"
  24 #include "identifier.hh"
  25 #include "command-request.hh"
  26 #include "musical-request.hh"
  27 #include "my-lily-parser.hh"
  28 #include "context-specced-music.hh"
  29 #include "translator-group.hh"
  30 #include "score.hh"
  31 #include "music-list.hh"
  32 #include "change-translator.hh"
  33 #include "file-results.hh"
  34 #include "input.hh"
  35 #include "scope.hh"
  36 #include "relative-music.hh"
  37 #include "lyric-combine-music.hh"
  38 #include "transposed-music.hh"
  39 #include "time-scaled-music.hh"
  40 #include "repeated-music.hh"
  41 #include "mudela-version.hh"
  42 #include "grace-music.hh"
  43 #include "auto-change-music.hh"
  44 #include "part-combine-music.hh"
  45 #include "output-property.hh"
  46
  47 bool
  48 is_duration_b (int t)
  49 {
  50   return t && t == 1 << intlog2(t);
  51 }
  52
  53
  54 // mmm JUNKME ?
  55 Mudela_version oldest_version ("1.3.59");
  56
  57 void
  58 print_mudela_versions (ostream &os)
  59 {
  60   os << _f ("Oldest supported input version: %s", oldest_version.str ())
  61     << endl;
  62 }
  63
  64
  65 // needed for bison.simple's malloc() and free()
  66 #include <malloc.h>
  67
  68 #ifndef NDEBUG
  69 #define YYDEBUG 1
  70 #endif
  71
  72 #define YYERROR_VERBOSE 1
  73
  74 #define YYPARSE_PARAM my_lily_parser_l
  75 #define YYLEX_PARAM my_lily_parser_l
  76 #define THIS ((My_lily_parser *) my_lily_parser_l)
  77
  78 #define yyerror THIS->parser_error
  79 #define ARRAY_SIZE(a,s)   if (a.size () != s) THIS->parser_error (_f ("Expecting %d arguments", s))
  80
  81 %}
  82
  83
  84 %union {
  85     Array<Musical_pitch> *pitch_arr;
  86     Link_array<Request> *reqvec;
  87     Duration *duration;
  88     Identifier *id;
  89     String * string;
  90     Music *music;
  91     Score *score;
  92     Scope *scope;
  93     Interval *interval;
  94     Musical_req* musreq;
  95     Music_output_def * outputdef;
  96     Musical_pitch * pitch;
  97     Midi_def* midi;
  98     Moment *moment;
  99     Real real;
 100     Request * request;
 101
 102     /* We use SCMs to do strings, because it saves us the trouble of
 103 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 104 of the parse stack onto the heap. */
 105
 106     SCM scm;
 107
 108     Tempo_req *tempo;
 109     Translator_group* trans;
 110     int i;
 111 }
 112 %{
 113
 114 int
 115 yylex (YYSTYPE *s,  void * v_l)
 116 {
 117         My_lily_parser   *pars_l = (My_lily_parser*) v_l;
 118         My_lily_lexer * lex_l = pars_l->lexer_p_;
 119
 120         lex_l->lexval_l = (void*) s;
 121         return lex_l->yylex ();
 122 }
 123
 124
 125 %}
 126
 127 %pure_parser
 128
 129 /* tokens which are not keywords */
 130 %token AUTOCHANGE
 131 %token TEXTSCRIPT
 132 %token ACCEPTS
 133 %token ALTERNATIVE
 134 %token BAR
 135 %token BREATHE
 136 %token CHORDMODIFIERS
 137 %token CHORDS
 138 %token CHAR_T
 139 %token CLEF
 140 %token CM_T
 141 %token CONSISTS
 142 %token SEQUENTIAL
 143 %token SIMULTANEOUS
 144 %token CONSISTSEND
 145 %token DENIES
 146 %token DURATION
 147 %token EXTENDER
 148 %token FONT
 149 %token GRACE
 150 %token HEADER
 151 %token HYPHEN
 152 %token IN_T
 153 %token INVALID
 154 %token KEY
 155 %token LYRICS
 156 %token MARK
 157 %token MEASURES
 158 %token MIDI
 159 %token MM_T
 160 %token MUSICAL_PITCH
 161 %token NAME
 162 %token NOTENAMES
 163 %token NOTES
 164 %token PAPER
 165 %token PARTIAL
 166 %token PENALTY
 167 %token PROPERTY
 168 %token PUSHPROPERTY POPPROPERTY
 169 %token PT_T
 170 %token RELATIVE
 171 %token REMOVE
 172 %token REPEAT
 173 %token ADDLYRICS
 174 %token PARTCOMBINE
 175 %token SCM_T
 176 %token SCORE
 177 %token SCRIPT
 178 %token SKIP
 179 %token SPANREQUEST
 180 %token COMMANDSPANREQUEST
 181 %token TEMPO
 182 %token OUTPUTPROPERTY
 183 %token TIME_T
 184 %token TIMES
 185 %token TRANSLATOR
 186 %token TRANSPOSE
 187 %token TYPE
 188 %token CONTEXT
 189
 190 /* escaped */
 191 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER
 192 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET
 193
 194 %type <i>       exclamations questions
 195 %token <i>      DIGIT
 196 %token <pitch>  NOTENAME_PITCH
 197 %token <pitch>  TONICNAME_PITCH
 198 %token <pitch>  CHORDMODIFIER_PITCH
 199 %token <id>     DURATION_IDENTIFIER
 200 %token <id>     IDENTIFIER
 201 %token <id>     TRANS_IDENTIFIER
 202
 203 %token <id>     SCORE_IDENTIFIER
 204 %token <id>     MUSIC_OUTPUT_DEF_IDENTIFIER
 205
 206 %token <scm>    NUMBER_IDENTIFIER
 207 %token <scm>    REQUEST_IDENTIFIER
 208 %token <scm>    MUSIC_IDENTIFIER
 209 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 210 %token <scm>    DURATION RESTNAME
 211 %token <scm>    STRING
 212 %token <scm>    SCM_T
 213 %token <i>      UNSIGNED
 214 %token <real>   REAL
 215
 216 %type <outputdef> output_def
 217 %type <scope>   mudela_header mudela_header_body
 218 %type <request> open_request_parens close_request_parens open_request close_request
 219 %type <request> request_with_dir request_that_take_dir verbose_request
 220 %type <i>       sub_quotes sup_quotes
 221 %type <music>   simple_element  request_chord command_element Simple_music  Composite_music
 222 %type <music>   Alternative_music Repeated_music
 223 %type <i>       tremolo_type
 224 %type <i>       bare_int  bare_unsigned
 225 %type <i>       script_dir
 226
 227 %type <scm>     identifier_init
 228
 229 %type <duration> steno_duration optional_notemode_duration
 230 %type <duration> entered_notemode_duration explicit_duration
 231
 232 %type <reqvec>  pre_requests post_requests
 233 %type <request> gen_text_def
 234 %type <pitch>   steno_musical_pitch musical_pitch absolute_musical_pitch
 235 %type <pitch>   steno_tonic_pitch
 236
 237 %type <pitch_arr>       chord_additions chord_subtractions chord_notes chord_step
 238 %type <music>   chord
 239 %type <pitch>   chord_note chord_inversion chord_bass
 240 %type <duration>        duration_length
 241
 242 %type <scm>  embedded_scm scalar
 243 %type <music>   Music Sequential_music Simultaneous_music Music_sequence
 244 %type <music>   relative_music re_rhythmed_music part_combined_music
 245 %type <music>   property_def translator_change
 246 %type <scm> Music_list
 247 %type <outputdef>  music_output_def_body
 248 %type <request> shorthand_command_req
 249 %type <request> post_request
 250 %type <request> command_req verbose_command_req
 251 %type <request> extender_req
 252 %type <request> hyphen_req
 253 %type <scm>     string bare_number number_expression
 254 %type <score>   score_block score_body
 255
 256 %type <trans>   translator_spec_block translator_spec_body
 257 %type <tempo>   tempo_request
 258 %type <scm> notenames_body notenames_block chordmodifiers_block
 259 %type <scm>     script_abbreviation
 260
 261
 262
 263 %left '-' '+'
 264 %left '*' '/'
 265 %left UNARY_MINUS
 266
 267 %%
 268
 269 mudela: /* empty */
 270         | mudela toplevel_expression {}
 271         | mudela assignment  { }
 272         | mudela error
 273         | mudela INVALID        {
 274                 THIS->error_level_i_  =1;
 275         }
 276         ;
 277
 278 toplevel_expression:
 279         notenames_block                 {
 280                 THIS->lexer_p_->pitchname_tab_ =  $1;
 281         }
 282         | chordmodifiers_block                  {
 283                 THIS->lexer_p_->chordmodifier_tab_  = $1;
 284         }
 285         | mudela_header {
 286                 delete header_global_p;
 287                 header_global_p = $1;
 288         }
 289         | score_block {
 290                 score_global_array.push ($1);
 291         }
 292         | output_def {
 293                 Identifier * id = new
 294                         Music_output_def_identifier ($1, MUSIC_OUTPUT_DEF_IDENTIFIER);
 295                 if (dynamic_cast<Paper_def*> ($1))
 296                         THIS->lexer_p_->set_identifier ("$defaultpaper", id->self_scm ());
 297                 else if (dynamic_cast<Midi_def*> ($1))
 298                         THIS->lexer_p_->set_identifier ("$defaultmidi", id->self_scm ());
 299         }
 300         | embedded_scm {
 301                 // junk value
 302         }
 303         ;
 304
 305 embedded_scm:
 306         SCM_T
 307         | SCM_IDENTIFIER
 308         ;
 309
 310
 311 chordmodifiers_block:
 312         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 313         ;
 314
 315
 316 notenames_block:
 317         NOTENAMES notenames_body   {  $$ = $2; }
 318         ;
 319
 320
 321
 322 notenames_body:
 323         embedded_scm    {
 324           int i = scm_ilength ($1);
 325
 326           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 327           for (SCM s = $1; s != SCM_EOL; s = gh_cdr (s)) {
 328                 SCM pt = gh_cdar (s);
 329                 if (scm_ilength (pt) != 3)
 330                         THIS->parser_error ("Need three args");
 331                 scm_hashq_set_x (tab, gh_caar(s), pt);
 332           }
 333
 334           $$ = tab;
 335         }
 336         ;
 337
 338 mudela_header_body:
 339         {
 340                 $$ = new Scope;
 341                 THIS->lexer_p_-> scope_l_arr_.push ($$);
 342         }
 343         | mudela_header_body assignment semicolon {
 344
 345         }
 346         ;
 347
 348 mudela_header:
 349         HEADER '{' mudela_header_body '}'       {
 350                 $$ = $3;
 351                 THIS->lexer_p_-> scope_l_arr_.pop ();
 352         }
 353         ;
 354
 355
 356 /*
 357         DECLARATIONS
 358 */
 359 assignment:
 360         STRING {
 361                 THIS->remember_spot ();
 362         }
 363         /* cont */ '=' identifier_init  {
 364                 THIS->lexer_p_->set_identifier (ly_scm2string ($1), $4);
 365
 366 /*
 367  TODO: devise standard for protection in parser.
 368                 if (SCM_NIMP($4))
 369                         scm_unprotect_object ($4);
 370
 371   The parser stack lives on the C-stack, which means that
 372 all objects can be unprotected as soon as they're here.
 373
 374 */
 375                 Identifier * id =unsmob_identifier ($4);
 376                 Input spot = THIS->pop_spot ();
 377                 if (id) id->set_spot (spot);
 378         }
 379         ;
 380
 381
 382
 383 identifier_init:
 384         score_block {
 385                 $$ = (new Score_identifier ($1, SCORE_IDENTIFIER))->self_scm();
 386         }
 387         | output_def {
 388                 $$ = (new Music_output_def_identifier ($1, MUSIC_OUTPUT_DEF_IDENTIFIER))->self_scm();
 389         }
 390         | translator_spec_block {
 391                 $$ = (new Translator_group_identifier ($1, TRANS_IDENTIFIER))->self_scm();
 392         }
 393         | Music  {
 394                 $$ = $1->self_scm ();
 395         }
 396         | post_request {
 397                 $$ = $1->self_scm ();
 398         }
 399         | explicit_duration {
 400                 $$ = (new Duration_identifier ($1, DURATION_IDENTIFIER))->self_scm ();
 401         }
 402         | number_expression {
 403                 $$ = $1;
 404         }
 405         | string {
 406                 $$ = $1;
 407         }
 408         | embedded_scm  {
 409                 $$ = $1;
 410         }
 411         ;
 412
 413 translator_spec_block:
 414         TRANSLATOR '{' translator_spec_body '}'
 415                 {
 416                 $$ = $3;
 417         }
 418         ;
 419
 420 translator_spec_body:
 421         TRANS_IDENTIFIER        {
 422                 $$ = $1->access_content_Translator_group (true);
 423                 $$-> set_spot (THIS->here_input ());
 424         }
 425         | TYPE STRING semicolon {
 426                 Translator* t = get_translator_l (ly_scm2string ($2));
 427                 Translator_group * tg = dynamic_cast<Translator_group*> (t);
 428
 429                 if (!tg)
 430                         THIS->parser_error (_("Need a translator group for a context"));
 431
 432                 tg = dynamic_cast<Translator_group*> (t->clone ());
 433                 tg->set_spot (THIS->here_input ());
 434                 $$ = tg;
 435         }
 436         | translator_spec_body STRING '=' embedded_scm                  {
 437                 Translator_group* tg = $$;
 438                 tg->set_property (ly_scm2string ($2), $4);
 439         }
 440         | translator_spec_body STRING '=' identifier_init semicolon     {
 441                 SCM v = gh_int2scm (0);
 442                 if (gh_string_p ($4) || gh_number_p ($4) || gh_boolean_p ($4))
 443                         v = $4;
 444                 else
 445                         THIS->parser_error (_("Wrong type for property value"));
 446
 447                 /* ugh*/
 448                 Translator_group* tg = dynamic_cast<Translator_group*> ($$);
 449
 450                 tg->set_property (ly_scm2string ($2), v);
 451         }
 452         | translator_spec_body NAME STRING semicolon {
 453                 $$->type_str_ = ly_scm2string ($3);
 454         }
 455         | translator_spec_body CONSISTS STRING semicolon {
 456                 dynamic_cast<Translator_group*> ($$)-> set_element (ly_scm2string ($3), true);
 457         }
 458         | translator_spec_body CONSISTSEND STRING semicolon {
 459                 dynamic_cast<Translator_group*> ($$)-> set_element (ly_scm2string ($3), true);
 460         }
 461         | translator_spec_body ACCEPTS STRING semicolon {
 462                 dynamic_cast<Translator_group*> ($$)-> set_acceptor (ly_scm2string ($3), true);
 463         }
 464         | translator_spec_body DENIES STRING semicolon {
 465                 dynamic_cast<Translator_group*> ($$)-> set_acceptor (ly_scm2string ($3), false);
 466         }
 467         | translator_spec_body REMOVE STRING semicolon {
 468                 dynamic_cast<Translator_group*> ($$)-> set_element (ly_scm2string ($3), false);
 469         }
 470         ;
 471
 472 /*
 473         SCORE
 474 */
 475 score_block:
 476         SCORE {
 477         }
 478         /*cont*/ '{' score_body '}'     {
 479                 $$ = $4;
 480                 if (!$$->def_p_arr_.size ())
 481                 {
 482                   Identifier *id =
 483                         unsmob_identifier (THIS->lexer_p_->lookup_identifier ("$defaultpaper"));
 484                   $$->add_output (id ? id->access_content_Music_output_def (true) : new Paper_def );
 485                 }
 486         }
 487         ;
 488
 489 score_body:
 490         Music   {
 491                 $$ = new Score;
 492
 493                 $$->set_spot (THIS->here_input ());
 494                 SCM m = $1->self_scm ();
 495 //              scm_unprotect_object (m);
 496                 $$->music_ = m;
 497         }
 498         | SCORE_IDENTIFIER {
 499                 $$ = $1->access_content_Score (true);
 500         }
 501         | score_body mudela_header      {
 502                 $$->header_p_ = $2;
 503         }
 504         | score_body output_def {
 505                 $$->add_output ($2);
 506         }
 507         | score_body error {
 508
 509         }
 510         ;
 511
 512
 513 /*
 514         MIDI
 515 */
 516 output_def:
 517         music_output_def_body '}' {
 518                 $$ = $1;
 519                 THIS-> lexer_p_-> scope_l_arr_.pop();
 520         }
 521         ;
 522
 523 music_output_def_body:
 524         MIDI '{'    {
 525          Identifier *id = unsmob_identifier (THIS->lexer_p_->lookup_identifier ("$defaultmidi"));
 526
 527
 528          Midi_def* p =0;
 529         if (id)
 530                 p = dynamic_cast<Midi_def*> (id->access_content_Music_output_def (true));
 531         else
 532                 p = new Midi_def;
 533
 534          $$ = p;
 535          THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 536         }
 537         | PAPER '{'     {
 538                   Identifier *id = unsmob_identifier (THIS->lexer_p_->lookup_identifier ("$defaultpaper"));
 539                   Paper_def *p = 0;
 540                 if (id)
 541                         p = dynamic_cast<Paper_def*> (id->access_content_Music_output_def (true));
 542                 else
 543                         p = new Paper_def;
 544                 THIS-> lexer_p_-> scope_l_arr_.push (p->scope_p_);
 545                 $$ = p;
 546         }
 547         | PAPER '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 548                 Music_output_def *p = $3->access_content_Music_output_def (true);
 549                 THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 550                 $$ = p;
 551         }
 552         | MIDI '{' MUSIC_OUTPUT_DEF_IDENTIFIER  {
 553                 Music_output_def *p = $3->access_content_Music_output_def (true);
 554                 THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 555                 $$ = p;
 556         }
 557         | music_output_def_body assignment semicolon {
 558
 559         }
 560         | music_output_def_body translator_spec_block   {
 561                 $$-> assign_translator ($2);
 562         }
 563         | music_output_def_body tempo_request semicolon {
 564                 /*
 565                         junk this ? there already is tempo stuff in
 566                         music.
 567                 */
 568                 dynamic_cast<Midi_def*> ($$)->set_tempo ($2->dur_.length_mom (), $2->metronome_i_);
 569         }
 570         | music_output_def_body bare_int '=' FONT STRING                { // ugh, what a syntax
 571                 SCM sl = Lookup::make_lookup();
 572                 Lookup * l =unsmob_lookup (sl);
 573                 l->font_name_ = ly_scm2string ($5);
 574                 dynamic_cast<Paper_def*> ($$)->set_lookup ($2, sl);
 575         }
 576         | music_output_def_body error {
 577
 578         }
 579         ;
 580
 581 tempo_request:
 582         TEMPO steno_duration '=' bare_unsigned  {
 583                 $$ = new Tempo_req;
 584                 $$->dur_ = *$2;
 585                 delete $2;
 586                 $$-> metronome_i_ = $4;
 587         }
 588         ;
 589
 590 Music_list: /* empty */ {
 591                 $$ = gh_cons (SCM_EOL, SCM_EOL);
 592         }
 593         | Music_list Music {
 594                 SCM s = $$;
 595                 SCM c = gh_cons ($2->self_scm (), SCM_EOL);
 596 //              scm_unprotect_object ($2->self_scm ()); /* UGH */
 597
 598
 599                 if (gh_pair_p (gh_cdr (s)))
 600                         gh_set_cdr_x (gh_cdr (s), c); /* append */
 601                 else
 602                         gh_set_car_x (s, c); /* set first cons */
 603                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 604         }
 605         | Music_list error {
 606         }
 607         ;
 608
 609
 610 Music:
 611         Simple_music
 612         | Composite_music
 613         ;
 614
 615 Alternative_music:
 616         /* empty */ {
 617                 $$ = 0;
 618         }
 619         | ALTERNATIVE Music_sequence {
 620                 $$ = $2;
 621                 $2->set_spot (THIS->here_input ());
 622         }
 623         ;
 624
 625
 626
 627
 628 Repeated_music:
 629         REPEAT STRING bare_unsigned Music Alternative_music
 630         {
 631                 Music_sequence* m = dynamic_cast <Music_sequence*> ($5);
 632                 if (m && $3 < m->length_i ())
 633                         $5->origin ()->warning (_ ("More alternatives than repeats.  Junking excess alternatives."));
 634
 635                 Repeated_music * r = new Repeated_music ($4, $3 >? 1, m);
 636                 $$ = r;
 637                 r->type_ = ly_scm2string ($2);
 638                 r->fold_b_ = (r->type_ == "fold");
 639                 r->volta_fold_b_ =  (r->type_ == "volta");
 640                 r->set_spot (*$4->origin ());
 641         }
 642         ;
 643
 644 Music_sequence: '{' Music_list '}'      {
 645                 $$ = new Music_sequence (gh_car ($2));
 646         }
 647         ;
 648
 649 Sequential_music:
 650         SEQUENTIAL '{' Music_list '}'           {
 651                 $$ = new Sequential_music (gh_car ($3));
 652         }
 653         | '{' Music_list '}'            {
 654                 $$ = new Sequential_music (gh_car ($2));
 655         }
 656         ;
 657
 658 Simultaneous_music:
 659         SIMULTANEOUS '{' Music_list '}'{
 660                 $$ = new Simultaneous_music (gh_car ($3));
 661         }
 662         | '<' Music_list '>'    {
 663                 $$ = new Simultaneous_music (gh_car ($2));
 664         }
 665         ;
 666
 667 Simple_music:
 668         request_chord           { $$ = $1; }
 669         | OUTPUTPROPERTY embedded_scm embedded_scm '=' embedded_scm     {
 670                 SCM pred = $2;
 671                 if (!gh_symbol_p ($3))
 672                 {
 673                         THIS->parser_error (_("Second argument must be a symbol"));
 674                 }
 675                 /*hould check # args */
 676                 if (!gh_procedure_p (pred))
 677                 {
 678                         THIS->parser_error (_("First argument must be a procedure taking 1 argument"));
 679                 }
 680
 681                 $$ = new Output_property (pred,$3, $5);
 682         }
 683         | MUSIC_IDENTIFIER { $$ = unsmob_music ($1)->clone (); }
 684         | property_def
 685         | PUSHPROPERTY embedded_scm embedded_scm embedded_scm {
 686                 $$ = new Push_translation_property;
 687                 $$->set_mus_property ("symbols", $2);
 688                 $$->set_mus_property ("element-property", $3);
 689                 $$->set_mus_property ("element-value", $4);
 690         }
 691         | POPPROPERTY  embedded_scm embedded_scm {
 692                 $$ = new Pop_translation_property;
 693                 $$->set_mus_property ("symbols", $2);
 694                 $$->set_mus_property ("element-property", $3);
 695         }
 696         | translator_change
 697         | Simple_music '*' bare_unsigned '/' bare_unsigned      {
 698                 $$ = $1;
 699                 $$->compress (Moment($3, $5 ));
 700         }
 701         | Simple_music '*' bare_unsigned                 {
 702                 $$ = $1;
 703                 $$->compress (Moment ($3, 1));
 704         }
 705         ;
 706
 707
 708 Composite_music:
 709         CONTEXT STRING Music    {
 710                 Context_specced_music *csm =  new Context_specced_music ($3);
 711
 712                 csm->translator_type_str_ = ly_scm2string ($2);
 713                 csm->translator_id_str_ = "";
 714
 715
 716                 $$ = csm;
 717         }
 718         | AUTOCHANGE STRING Music       {
 719                 Auto_change_music * chm = new Auto_change_music (ly_scm2string ($2), $3);
 720
 721                 $$ = chm;
 722                 chm->set_spot (*$3->origin ());
 723         }
 724         | GRACE Music {
 725                 $$ = new Grace_music ($2);
 726         }
 727         | CONTEXT STRING '=' STRING Music {
 728                 Context_specced_music *csm =  new Context_specced_music ($5);
 729
 730                 csm->translator_type_str_ = ly_scm2string ($2);
 731                 csm->translator_id_str_ = ly_scm2string ($4);
 732
 733                 $$ = csm;
 734         }
 735         | TIMES {
 736                 THIS->remember_spot ();
 737         }
 738         /* CONTINUED */
 739                 bare_unsigned '/' bare_unsigned Music
 740
 741         {
 742                 $$ = new Time_scaled_music ($3, $5, $6);
 743                 $$->set_spot (THIS->pop_spot ());
 744         }
 745         | Repeated_music                { $$ = $1; }
 746         | Simultaneous_music            { $$ = $1; }
 747         | Sequential_music              { $$ = $1; }
 748         | TRANSPOSE musical_pitch Music {
 749                 $$ = new Transposed_music ($3, *$2);
 750                 delete $2; // ugh
 751         }
 752         | TRANSPOSE steno_tonic_pitch Music {
 753                 $$ = new Transposed_music ($3, *$2);
 754                 delete $2; // ugh
 755         }
 756         | NOTES
 757                 { THIS->lexer_p_->push_note_state (); }
 758         Music
 759                 { $$ = $3;
 760                   THIS->lexer_p_->pop_state ();
 761                 }
 762         | CHORDS
 763                 { THIS->lexer_p_->push_chord_state (); }
 764         Music
 765                 {
 766                   $$ = $3;
 767                   THIS->lexer_p_->pop_state ();
 768         }
 769         | LYRICS
 770                 { THIS->lexer_p_->push_lyric_state (); }
 771         Music
 772                 {
 773                   $$ = $3;
 774                   THIS->lexer_p_->pop_state ();
 775         }
 776         | relative_music        { $$ = $1; }
 777         | re_rhythmed_music     { $$ = $1; }
 778         | part_combined_music   { $$ = $1; }
 779         ;
 780
 781 relative_music:
 782         RELATIVE absolute_musical_pitch Music {
 783                 $$ = new Relative_octave_music ($3, *$2);
 784                 delete $2; // ugh
 785         }
 786         ;
 787
 788 re_rhythmed_music:
 789         ADDLYRICS Music Music {
 790                 Lyric_combine_music * l = new Lyric_combine_music ($2, $3);
 791                 $$ = l;
 792         }
 793         ;
 794
 795 part_combined_music:
 796         PARTCOMBINE STRING Music Music {
 797                 Part_combine_music * p = new Part_combine_music (ly_scm2string ($2), $3, $4);
 798                 $$ = p;
 799         }
 800         ;
 801
 802 translator_change:
 803         TRANSLATOR STRING '=' STRING  {
 804                 Change_translator * t = new Change_translator;
 805                 t-> change_to_type_str_ = ly_scm2string ($2);
 806                 t-> change_to_id_str_ = ly_scm2string ($4);
 807
 808                 $$ = t;
 809                 $$->set_spot (THIS->here_input ());
 810         }
 811         ;
 812
 813 property_def:
 814         PROPERTY STRING '.' STRING '='  scalar {
 815                 Translation_property *t = new Translation_property;
 816
 817                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
 818                 t->set_mus_property ("value", $6);
 819
 820                 Context_specced_music *csm = new Context_specced_music (t);
 821                 $$ = csm;
 822                 $$->set_spot (THIS->here_input ());
 823
 824                 csm-> translator_type_str_ = ly_scm2string ($2);
 825         }
 826         ;
 827
 828 scalar:
 829         string          { $$ = $1; }
 830         | bare_int      { $$ = gh_int2scm ($1); }
 831         | embedded_scm  { $$ = $1; }
 832         ;
 833
 834
 835 request_chord:
 836         pre_requests simple_element post_requests       {
 837                 Music_sequence *l = dynamic_cast<Music_sequence*>($2);
 838                 if (l) {
 839                         for (int i=0; i < $1->size(); i++)
 840                                 l->append_music ($1->elem(i));
 841                         for (int i=0; i < $3->size(); i++)
 842                                 l->append_music ($3->elem(i));
 843                         }
 844                 else
 845                         programming_error ("Need Sequence to add music to");
 846                 $$ = $2;
 847
 848         }
 849         | command_element
 850         ;
 851
 852 command_element:
 853         command_req {
 854                 $$ = new Request_chord (gh_cons ($1->self_scm (), SCM_EOL));
 855                 $$-> set_spot (THIS->here_input ());
 856                 $1-> set_spot (THIS->here_input ());
 857         }
 858         | PARTIAL duration_length ';'   {
 859                 Translation_property * p = new Translation_property;
 860                 p->set_mus_property ("symbol", ly_symbol2scm ( "measurePosition"));
 861                 Moment m = - $2->length_mom ();
 862                 p->set_mus_property ("value", m.make_scm());
 863                 delete $2; // ugh
 864                 Context_specced_music * sp = new Context_specced_music (p);
 865                 $$ =sp ;
 866                 sp-> translator_type_str_ = "Score";
 867         }
 868         ;
 869
 870 command_req:
 871         shorthand_command_req
 872         | verbose_command_req semicolon { $$ = $1; }
 873         ;
 874
 875 shorthand_command_req:
 876         extender_req {
 877                 $$ = $1;
 878         }
 879         | hyphen_req {
 880                 $$ = $1;
 881         }
 882         | '|'                           {
 883                 $$ = new Barcheck_req;
 884         }
 885         | '~'   {
 886                 $$ = new Tie_req;
 887         }
 888         | '['           {
 889                 Span_req*b= new Span_req;
 890                 b->span_dir_ = START;
 891                 b->span_type_str_ = "beam";
 892                 $$ =b;
 893         }
 894         | ']'           {
 895              Span_req*b= new Span_req;
 896              b->span_dir_ = STOP;
 897              b->span_type_str_ = "beam";
 898              $$ = b;
 899         }
 900         | BREATHE {
 901                 $$ = new Breathing_sign_req;
 902         }
 903         ;
 904
 905
 906 verbose_command_req:
 907
 908         BAR STRING                      {
 909                 $$ = new Bar_req (ly_scm2string ($2));
 910         }
 911         | COMMANDSPANREQUEST bare_int STRING {
 912                 Span_req * sp_p = new Span_req;
 913                 sp_p-> span_dir_  = Direction($2);
 914                 sp_p->span_type_str_ = ly_scm2string ($3);
 915                 sp_p->set_spot (THIS->here_input ());
 916                 $$ = sp_p;
 917         }
 918         | MARK  {
 919                 Mark_req * m = new Mark_req;
 920                 $$ = m;
 921         }
 922         | MARK STRING {
 923                 Mark_req *m = new Mark_req;
 924                 m->set_mus_property ("label", $2);
 925                 $$ = m;
 926
 927         }
 928         | MARK bare_unsigned {
 929                 Mark_req *m = new Mark_req;
 930                 m->set_mus_property ("label",  gh_int2scm ($2));
 931                 $$ = m;
 932         }
 933
 934         | TIME_T bare_unsigned '/' bare_unsigned        {
 935                 Time_signature_change_req *m = new Time_signature_change_req;
 936                 m->beats_i_ = $2;
 937                 m->one_beat_i_=$4;
 938                 $$ = m;
 939         }
 940         | PENALTY bare_int      {
 941                 Break_req * b = new Break_req;
 942                 b->penalty_f_ = $2 / 100.0;
 943                 b->set_spot (THIS->here_input ());
 944                 $$ = b;
 945         }
 946         | SKIP duration_length {
 947                 Skip_req * skip_p = new Skip_req;
 948                 skip_p->duration_ = *$2;
 949                 delete $2; // ugh
 950                 $$ = skip_p;
 951         }
 952         | tempo_request {
 953                 $$ = $1;
 954         }
 955         | CLEF STRING {
 956                 $$ = new Clef_change_req (ly_scm2string ($2));
 957
 958         }
 959         | KEY {
 960                 Key_change_req *key_p= new Key_change_req;
 961                 $$ = key_p;
 962         }
 963         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
 964                 Key_change_req *key_p= new Key_change_req;
 965
 966                 key_p->set_mus_property ("pitch-alist", $3);
 967                 ((Music* )key_p)->transpose (* $2);
 968                 $$ = key_p;
 969         }
 970         ;
 971
 972 post_requests:
 973         {
 974                 $$ = new Link_array<Request>;
 975         }
 976         | post_requests post_request {
 977                 $2->set_spot (THIS->here_input ());
 978                 $$->push ($2);
 979         }
 980         ;
 981
 982 post_request:
 983         verbose_request
 984         | request_with_dir
 985         | close_request
 986         ;
 987
 988
 989 request_that_take_dir:
 990         gen_text_def
 991         | verbose_request
 992         | script_abbreviation {
 993                 SCM s = THIS->lexer_p_->lookup_identifier ("dash-" + ly_scm2string ($1));
 994                 Articulation_req *a = new Articulation_req;
 995                 if (gh_string_p (s))
 996                         a->articulation_str_ = ly_scm2string (s);
 997                 else THIS->parser_error (_ ("Expecting string as script definition"));
 998                 $$ = a;
 999         }
1000         ;
1001
1002 request_with_dir:
1003         script_dir request_that_take_dir        {
1004                 if (Script_req * gs = dynamic_cast<Script_req*> ($2))
1005                         gs->dir_ = Direction ($1);
1006                 else if ($1)
1007                         $2->origin ()->warning (_ ("Can't specify direction for this request"));
1008                 $$ = $2;
1009         }
1010         ;
1011
1012 verbose_request:
1013         REQUEST_IDENTIFIER      {
1014                 $$ = dynamic_cast<Request*> (unsmob_music ($1)->clone ());
1015                 $$->set_spot (THIS->here_input ());
1016         }
1017         | TEXTSCRIPT STRING STRING      {
1018                 Text_script_req *ts_p = new Text_script_req;
1019                 ts_p-> text_str_ = ly_scm2string ($2);
1020                 ts_p-> style_str_ = ly_scm2string ($3);
1021                 ts_p->set_spot (THIS->here_input ());
1022
1023                 $$ = ts_p;
1024         }
1025         | SPANREQUEST bare_int STRING {
1026                 Span_req * sp_p = new Span_req;
1027                 sp_p->span_dir_  = Direction($2);
1028                 sp_p->span_type_str_ = ly_scm2string ($3);
1029                 sp_p->set_spot (THIS->here_input ());
1030                 $$ = sp_p;
1031         }
1032         | tremolo_type  {
1033                 Tremolo_req* a = new Tremolo_req;
1034                 a->set_spot (THIS->here_input ());
1035                 a->type_i_ = $1;
1036                 $$ = a;
1037         }
1038         | SCRIPT STRING         {
1039                 Articulation_req * a = new Articulation_req;
1040                 a->articulation_str_ = ly_scm2string ($2);
1041                 a->set_spot (THIS->here_input ());
1042                 $$ = a;
1043         }
1044         ;
1045
1046 sup_quotes:
1047         '\'' {
1048                 $$ = 1;
1049         }
1050         | sup_quotes '\'' {
1051                 $$ ++;
1052         }
1053         ;
1054
1055 sub_quotes:
1056         ',' {
1057                 $$ = 1;
1058         }
1059         | sub_quotes ',' {
1060                 $$ ++ ;
1061         }
1062         ;
1063
1064 steno_musical_pitch:
1065         NOTENAME_PITCH  {
1066                 $$ = $1;
1067         }
1068         | NOTENAME_PITCH sup_quotes     {
1069                 $$ = $1;
1070                 $$->octave_i_ +=  $2;
1071         }
1072         | NOTENAME_PITCH sub_quotes      {
1073                 $$ = $1;
1074                 $$->octave_i_ += - $2;
1075         }
1076         ;
1077
1078 steno_tonic_pitch:
1079         TONICNAME_PITCH {
1080                 $$ = $1;
1081         }
1082         | TONICNAME_PITCH sup_quotes    {
1083                 $$ = $1;
1084                 $$->octave_i_ +=  $2;
1085         }
1086         | TONICNAME_PITCH sub_quotes     {
1087                 $$ = $1;
1088                 $$->octave_i_ += - $2;
1089         }
1090         ;
1091
1092 musical_pitch:
1093         steno_musical_pitch {
1094                 $$ = $1;
1095         }
1096         | MUSICAL_PITCH embedded_scm {
1097                 int sz = scm_ilength ($2);
1098                 if (sz != 3) {
1099                         THIS->parser_error (_f ("Expecting %d arguments", 3));
1100                         $2 = gh_list (gh_int2scm (0), gh_int2scm (0), gh_int2scm (0), SCM_UNDEFINED);
1101                 }
1102                 $$ = new Musical_pitch ($2);
1103         }
1104         ;
1105
1106 explicit_duration:
1107         DURATION embedded_scm   {
1108                 $$ = new Duration;
1109                 if (scm_ilength ($2) == 2)
1110                         {
1111                         $$-> durlog_i_ = gh_scm2int (gh_car($2));
1112                         $$-> dots_i_ = gh_scm2int (gh_cadr($2));
1113                         }
1114                 else
1115                         THIS->parser_error (_("Must have 2 arguments for duration"));
1116         }
1117         ;
1118
1119 extender_req:
1120         EXTENDER {
1121                 if (!THIS->lexer_p_->lyric_state_b ())
1122                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1123                 $$ = new Extender_req;
1124         }
1125         ;
1126
1127 hyphen_req:
1128         HYPHEN {
1129                 if (!THIS->lexer_p_->lyric_state_b ())
1130                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1131                 $$ = new Hyphen_req;
1132         }
1133         ;
1134
1135 close_request:
1136         close_request_parens {
1137                 $$ = $1;
1138                 dynamic_cast<Span_req*> ($$)->span_dir_ = START;
1139         }
1140
1141 close_request_parens:
1142         '('     {
1143                 Span_req* s= new Span_req;
1144                 $$ = s;
1145                 s->span_type_str_ = "slur";
1146         }
1147         | E_SMALLER {
1148                 Span_req*s =new Span_req;
1149                 $$ = s;
1150                 s->span_type_str_ = "crescendo";
1151         }
1152         | E_BIGGER {
1153                 Span_req*s =new Span_req;
1154                 $$ = s;
1155                 s->span_type_str_ = "decrescendo";
1156         }
1157         ;
1158
1159
1160 open_request:
1161         open_request_parens {
1162                 $$ = $1;
1163                 dynamic_cast<Span_req*> ($$)->span_dir_ = STOP;
1164         }
1165         ;
1166
1167 open_request_parens:
1168         E_EXCLAMATION   {
1169                 Span_req *s =  new Span_req;
1170                 s->span_type_str_ = "crescendo";
1171                 $$ = s;
1172         }
1173         | ')'   {
1174                 Span_req* s= new Span_req;
1175                 $$ = s;
1176                 s->span_type_str_ = "slur";
1177         }
1178         ;
1179
1180 gen_text_def:
1181         string {
1182                 Text_script_req *t  = new Text_script_req;
1183                 $$ = t;
1184                 t->text_str_ = ly_scm2string ($1);
1185
1186                 $$->set_spot (THIS->here_input ());
1187         }
1188         | DIGIT {
1189                 Text_script_req* t  = new Text_script_req;
1190                 $$ = t;
1191                 t->text_str_ = to_str ($1);
1192                 t->style_str_ = "finger";
1193                 $$->set_spot (THIS->here_input ());
1194         }
1195         ;
1196
1197 script_abbreviation:
1198         '^'             {
1199                 $$ = gh_str02scm  ("hat");
1200         }
1201         | '+'           {
1202                 $$ = gh_str02scm("plus");
1203         }
1204         | '-'           {
1205                 $$ = gh_str02scm ("dash");
1206         }
1207         | '|'           {
1208                 $$ = gh_str02scm ("bar");
1209         }
1210         | '>'           {
1211                 $$ = gh_str02scm ("larger");
1212         }
1213         | '.'           {
1214                 $$ = gh_str02scm ("dot");
1215         }
1216         ;
1217
1218
1219 script_dir:
1220         '_'     { $$ = DOWN; }
1221         | '^'   { $$ = UP; }
1222         | '-'   { $$ = CENTER; }
1223         ;
1224
1225 pre_requests:
1226         {
1227                 $$ = new Link_array<Request>;
1228         }
1229         | pre_requests open_request {
1230                 $$->push ($2);
1231         }
1232         ;
1233
1234 absolute_musical_pitch:
1235         steno_musical_pitch     {
1236                 $$ = $1;
1237         }
1238         ;
1239
1240 duration_length:
1241         steno_duration {
1242                 $$ = $1;
1243         }
1244         | duration_length '*' bare_unsigned {
1245                 $$->tuplet_iso_i_ *= $3;
1246         }
1247         | duration_length '/' bare_unsigned {
1248                 $$->tuplet_type_i_ *= $3;
1249         }
1250         ;
1251
1252 entered_notemode_duration:
1253         steno_duration  {
1254                 THIS->set_last_duration ($1);
1255         }
1256         ;
1257
1258 optional_notemode_duration:
1259         {
1260                 $$ = new Duration (THIS->default_duration_);
1261         }
1262         | entered_notemode_duration {
1263                 $$ = $1;
1264         }
1265         ;
1266
1267 steno_duration:
1268         bare_unsigned           {
1269                 $$ = new Duration;
1270                 if (!is_duration_b ($1))
1271                         THIS->parser_error (_f ("not a duration: %d", $1));
1272                 else {
1273                         $$->durlog_i_ = intlog2 ($1);
1274                      }
1275         }
1276         | DURATION_IDENTIFIER   {
1277                 $$ = $1->access_content_Duration (true);
1278         }
1279         | steno_duration '.'    {
1280                 $$->dots_i_ ++;
1281         }
1282         ;
1283
1284
1285 tremolo_type:
1286         ':'     {
1287                 $$ =0;
1288         }
1289         | ':' bare_unsigned {
1290                 if (!is_duration_b ($2))
1291                         THIS->parser_error (_f ("not a duration: %d", $2));
1292                 $$ = $2;
1293         }
1294         ;
1295
1296
1297 simple_element:
1298         musical_pitch exclamations questions optional_notemode_duration {
1299                 if (!THIS->lexer_p_->note_state_b ())
1300                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1301
1302
1303                 Note_req *n = new Note_req;
1304
1305                 n->pitch_ = *$1;
1306                 n->duration_ = *$4;
1307
1308                 n->cautionary_b_ = $3 % 2;
1309                 n->forceacc_b_ = $2 % 2 || n->cautionary_b_;
1310
1311
1312                 Simultaneous_music*v = new Request_chord (gh_list (n->self_scm (), SCM_UNDEFINED));
1313                 v->set_spot ($1->spot ());
1314                 n->set_spot ($1->spot ());
1315                 $$ = v;
1316
1317                 delete $1;
1318                 delete $4;
1319         }
1320         | RESTNAME optional_notemode_duration           {
1321
1322                 SCM e = SCM_UNDEFINED;
1323                   if (ly_scm2string ($1) =="s")
1324                     { /* Space */
1325                       Skip_req * skip_p = new Skip_req;
1326                       skip_p->duration_ = *$2;
1327
1328                       skip_p->set_spot (THIS->here_input());
1329                         e = skip_p->self_scm ();
1330                     }
1331                   else
1332                     {
1333                       Rest_req * rest_req_p = new Rest_req;
1334                       rest_req_p->duration_ = *$2;
1335                       rest_req_p->set_spot (THIS->here_input());
1336                         e = rest_req_p->self_scm ();
1337                     }
1338                   Simultaneous_music* velt_p = new Request_chord (gh_list (e,SCM_UNDEFINED));
1339                   velt_p->set_spot (THIS->here_input());
1340
1341                   delete $2; // ugh
1342                   $$ = velt_p;
1343         }
1344         | MEASURES optional_notemode_duration   {
1345                 Skip_req * sk = new Skip_req;
1346                 sk->duration_ = *$2;
1347
1348
1349                 Span_req *sp1 = new Span_req;
1350                 Span_req *sp2 = new Span_req;
1351                 sp1-> span_dir_ = START;
1352                 sp2-> span_dir_ = STOP;
1353                 sp1->span_type_str_ = sp2->span_type_str_ = "rest";
1354
1355                 Request_chord * rqc1 = new Request_chord (gh_list (sp1->self_scm (), SCM_UNDEFINED));
1356                 Request_chord * rqc2 = new Request_chord (gh_list (sk->self_scm (), SCM_UNDEFINED));;
1357                 Request_chord * rqc3 = new Request_chord(gh_list (sp2->self_scm (), SCM_UNDEFINED));;
1358
1359                 SCM ms = gh_list (rqc1->self_scm (), rqc2->self_scm (), rqc3->self_scm (), SCM_UNDEFINED);
1360
1361                 $$ = new Sequential_music (ms);
1362         }
1363         | STRING optional_notemode_duration     {
1364                 if (!THIS->lexer_p_->lyric_state_b ())
1365                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1366                 Lyric_req* lreq_p = new Lyric_req;
1367                 lreq_p ->text_str_ = ly_scm2string ($1);
1368                 lreq_p->duration_ = *$2;
1369                 lreq_p->set_spot (THIS->here_input());
1370                 Simultaneous_music* velt_p = new Request_chord (gh_list (lreq_p->self_scm (), SCM_UNDEFINED));
1371
1372                 delete  $2; // ugh
1373                 $$= velt_p;
1374
1375         }
1376         | chord {
1377                 if (!THIS->lexer_p_->chord_state_b ())
1378                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
1379                 $$ = $1;
1380         }
1381         ;
1382
1383
1384 chord:
1385         steno_tonic_pitch optional_notemode_duration chord_additions chord_subtractions chord_inversion chord_bass {
1386                 $$ = THIS->get_chord (*$1, $3, $4, $5, $6, *$2);
1387         };
1388
1389 chord_additions:
1390         {
1391                 $$ = new Array<Musical_pitch>;
1392         }
1393         | CHORD_COLON chord_notes {
1394                 $$ = $2;
1395         }
1396         ;
1397
1398 chord_notes:
1399         chord_step {
1400                 $$ = $1
1401         }
1402         | chord_notes '.' chord_step {
1403                 $$ = $1;
1404                 $$->concat (*$3);
1405         }
1406         ;
1407
1408 chord_subtractions:
1409         {
1410                 $$ = new Array<Musical_pitch>;
1411         }
1412         | CHORD_CARET chord_notes {
1413                 $$ = $2;
1414         }
1415         ;
1416
1417
1418 chord_inversion:
1419         {
1420                 $$ = 0;
1421         }
1422         | '/' steno_tonic_pitch {
1423                 $$ = $2;
1424                 $$->set_spot (THIS->here_input ());
1425         }
1426         ;
1427
1428 chord_bass:
1429         {
1430                 $$ = 0;
1431         }
1432         | CHORD_BASS steno_tonic_pitch {
1433                 $$ = $2;
1434                 $$->set_spot (THIS->here_input ());
1435         }
1436         ;
1437
1438 chord_step:
1439         chord_note {
1440                 $$ = new Array<Musical_pitch>;
1441                 $$->push (*$1);
1442         }
1443         | CHORDMODIFIER_PITCH {
1444                 $$ = new Array<Musical_pitch>;
1445                 $$->push (*$1);
1446         }
1447         | CHORDMODIFIER_PITCH chord_note { /* Ugh. */
1448                 $$ = new Array<Musical_pitch>;
1449                 $$->push (*$1);
1450                 $$->push (*$2);
1451         }
1452         ;
1453
1454 chord_note:
1455         bare_unsigned {
1456                 $$ = new Musical_pitch;
1457                 $$->notename_i_ = ($1 - 1) % 7;
1458                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1459                 $$->accidental_i_ = 0;
1460         }
1461         | bare_unsigned '+' {
1462                 $$ = new Musical_pitch;
1463                 $$->notename_i_ = ($1 - 1) % 7;
1464                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1465                 $$->accidental_i_ = 1;
1466         }
1467         | bare_unsigned CHORD_MINUS {
1468                 $$ = new Musical_pitch;
1469                 $$->notename_i_ = ($1 - 1) % 7;
1470                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1471                 $$->accidental_i_ = -1;
1472         }
1473         ;
1474
1475 /*
1476         UTILITIES
1477  */
1478 number_expression:
1479         bare_number {
1480                 $$ = $1;
1481         }
1482         | '-'  number_expression %prec UNARY_MINUS {
1483                 $$ = scm_difference ($2, SCM_UNDEFINED);
1484         }
1485         | number_expression '*' number_expression {
1486                 $$ = scm_product ($1, $3);
1487         }
1488         | number_expression '/' number_expression {
1489                 $$ = scm_divide ($1, $3);
1490         }
1491         | number_expression '+' number_expression {
1492                 $$ = scm_sum ($1, $3);
1493         }
1494         | number_expression '-' number_expression {
1495                 $$ = scm_difference ($1, $3);
1496         }
1497         | '(' number_expression ')'     {
1498                 $$ = $2;
1499         }
1500         ;
1501
1502 bare_number:
1503         UNSIGNED        {
1504                 $$ = gh_int2scm ($1);
1505         }
1506         | DIGIT         {
1507                 $$ = gh_int2scm ($1);
1508         }
1509         | REAL          {
1510                 $$ = gh_double2scm ($1);
1511         }
1512         | NUMBER_IDENTIFIER             {
1513                 $$ = $1;
1514         }
1515         | REAL CM_T     {
1516                 $$ = gh_double2scm ($1 CM);
1517         }
1518         | REAL PT_T     {
1519                 $$ = gh_double2scm ($1 PT);
1520         }
1521         | REAL IN_T     {
1522                 $$ = gh_double2scm ($1 INCH);
1523         }
1524         | REAL MM_T     {
1525                 $$ = gh_double2scm ($1 MM);
1526         }
1527         | REAL CHAR_T   {
1528                 $$ = gh_double2scm ($1 CHAR);
1529         }
1530         ;
1531
1532
1533 bare_unsigned:
1534         bare_number {
1535                 if (scm_integer_p ($1) == SCM_BOOL_T) {
1536                         $$ = gh_scm2int ($1);
1537
1538                 } else {
1539                         THIS->parser_error (_("need integer number arg"));
1540                         $$ = 0;
1541                 }
1542                 if ($$ < 0) {
1543                         THIS->parser_error (_("Must be positive integer"));
1544                         $$ = -$$;
1545                         }
1546
1547         }
1548         ;
1549 bare_int:
1550         bare_number {
1551                 if (scm_integer_p ($1) == SCM_BOOL_T)
1552                 {
1553                         int k = gh_scm2int ($1);
1554                         $$ = k;
1555                 } else
1556                 {
1557                         THIS->parser_error (_("need integer number arg"));
1558                         $$ = 0;
1559                 }
1560         }
1561         | '-' bare_int {
1562                 $$ = -$2;
1563         }
1564         ;
1565
1566
1567 string:
1568         STRING          {
1569                 $$ = $1;
1570         }
1571         | STRING_IDENTIFIER     {
1572                 $$ = $1;
1573         }
1574         | string '+' string {
1575                 $$ = scm_string_append (scm_listify ($1, $3, SCM_UNDEFINED));
1576         }
1577         ;
1578
1579
1580 exclamations:
1581                 { $$ = 0; }
1582         | exclamations '!'      { $$ ++; }
1583         ;
1584
1585 questions:
1586                 { $$ = 0; }
1587         | questions '?' { $$ ++; }
1588         ;
1589
1590
1591 semicolon:
1592         ';'
1593         ;
1594
1595 %%
1596
1597 void
1598 My_lily_parser::set_yydebug (bool b)
1599 {
1600 #ifdef YYDEBUG
1601         yydebug = b;
1602 #endif
1603 }
1604 void
1605 My_lily_parser::do_yyparse ()
1606 {
1607         yyparse ((void*)this);
1608 }
1609
1610