lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for mudela
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 #include <iostream.h>
  13 #include "lily-guile.hh"
  14 #include "notename-table.hh"
  15 #include "scalar.hh"
  16 #include "translation-property.hh"
  17 #include "lookup.hh"
  18 #include "misc.hh"
  19 #include "my-lily-lexer.hh"
  20 #include "paper-def.hh"
  21 #include "midi-def.hh"
  22 #include "main.hh"
  23 #include "file-path.hh"
  24 #include "keyword.hh"
  25 #include "debug.hh"
  26 #include "parseconstruct.hh"
  27 #include "dimensions.hh"
  28 #include "identifier.hh"
  29 #include "command-request.hh"
  30 #include "musical-request.hh"
  31 #include "my-lily-parser.hh"
  32
  33 #include "translator-group.hh"
  34 #include "score.hh"
  35 #include "music-list.hh"
  36 #include "duration-convert.hh"
  37 #include "change-translator.hh"
  38 #include "file-results.hh"
  39 #include "mudela-version.hh"
  40 #include "scope.hh"
  41 #include "relative-music.hh"
  42 #include "transposed-music.hh"
  43 #include "compressed-music.hh"
  44 #include "repeated-music.hh"
  45
  46 // mmm
  47 Mudela_version oldest_version ("1.0.14");
  48 Mudela_version version ("1.0.15");
  49
  50
  51 // needed for bison.simple's malloc() and free()
  52 #include <malloc.h>
  53
  54 struct Assignment {
  55         String *name_p_;
  56         Identifier *id_p_;
  57         ~Assignment () {
  58                 delete name_p_;
  59                 delete id_p_;
  60         }
  61         Assignment () {
  62                 name_p_ = 0;
  63                 id_p_ =0;
  64         }
  65         Assignment (Assignment const&s)
  66         {
  67                 name_p_ = new String (*s.name_p_);
  68                 id_p_ = s.id_p_->clone ();
  69         }
  70 };
  71
  72 Paper_def* current_paper = 0;
  73
  74 #ifndef NDEBUG
  75 #define YYDEBUG 1
  76 #endif
  77
  78 #define YYERROR_VERBOSE 1
  79
  80 #define YYPARSE_PARAM my_lily_parser_l
  81 #define YYLEX_PARAM my_lily_parser_l
  82 #define THIS ((My_lily_parser *) my_lily_parser_l)
  83
  84 #define yyerror THIS->parser_error
  85 #define ARRAY_SIZE(a,s)   if (a.size () != s) THIS->parser_error (_f("expecting %d arguments", s))
  86
  87 %}
  88
  89
  90 %union {
  91     Array<Interval>* intarr;
  92     Array<Musical_pitch> *pitch_arr;
  93     Link_array<Request> *reqvec;
  94     Array<String> * strvec;
  95     Array<int> *intvec;
  96     Notename_table *chordmodifiertab;
  97     Duration *duration;
  98     Identifier *id;
  99     Music *music;
 100     Music_list *music_list;
 101     Score *score;
 102     Scope *scope;
 103     Interval *interval;
 104     Musical_req* musreq;
 105     Music_output_def * outputdef;
 106     Musical_pitch * pitch;
 107     Midi_def* midi;
 108     Moment *moment;
 109     Notename_table *notenametab;
 110     Paper_def *paper;
 111     Real real;
 112     Request * request;
 113     Scalar *scalar;
 114
 115     String *string;
 116     Tempo_req *tempo;
 117     Translator* trans;
 118     char c;
 119     int i;
 120     int ii[10];
 121 }
 122 %{
 123
 124 int
 125 yylex (YYSTYPE *s,  void * v_l)
 126 {
 127         My_lily_parser   *pars_l = (My_lily_parser*) v_l;
 128         My_lily_lexer * lex_l = pars_l->lexer_p_;
 129
 130         lex_l->lexval_l = (void*) s;
 131         return lex_l->yylex ();
 132 }
 133
 134
 135 %}
 136
 137 %pure_parser
 138
 139 /* tokens which are not keywords */
 140
 141 %token ABSDYNAMIC
 142 %token ACCEPTS
 143 %token ALTERNATIVE
 144 %token BAR
 145 %token CADENZA
 146 %token CHORDMODIFIERS
 147 %token CHORDS
 148 %token CLEF
 149 %token CM_T
 150 %token CONSISTS
 151 %token DURATION
 152 %token EXTENDER
 153 %token FONT
 154 %token GROUPING
 155 %token HEADER
 156 %token IN_T
 157 %token KEY
 158 %token KEYSIGNATURE
 159 %token LYRICS
 160 %token MARK
 161 %token MEASURES
 162 %token MIDI
 163 %token MM_T
 164 %token MUSICAL_PITCH
 165 %token NAME
 166 %token NOTENAMES
 167 %token NOTES
 168 %token PAPER
 169 %token PARTIAL
 170 %token PENALTY
 171 %token PROPERTY
 172 %token PT_T
 173 %token RELATIVE
 174 %token REMOVE
 175 %token REPEAT
 176 %token SCM_T
 177 %token SCMFILE
 178 %token SCORE
 179 %token SCRIPT
 180 %token SHAPE
 181 %token SKIP
 182 %token SPANDYNAMIC
 183 %token TEMPO
 184 %token TIME_T
 185 %token TIMES
 186 %token TRANSLATOR
 187 %token TRANSPOSE
 188 %token TYPE
 189 %token VERSION
 190
 191 /* escaped */
 192 %token E_EXCLAMATION E_SMALLER E_BIGGER E_CHAR
 193
 194 %type <i>       dots exclamations questions
 195 %token <i>      DIGIT
 196 %token <pitch>  NOTENAME_PITCH
 197 %token <pitch>  TONICNAME_PITCH
 198 %token <pitch>  CHORDMODIFIER_PITCH
 199 %token <id>     DURATION_IDENTIFIER
 200 %token <id>     IDENTIFIER
 201 %token <id>     NOTENAME_TABLE_IDENTIFIER
 202 %token <id>     MUSIC_IDENTIFIER
 203 %token <id>     REQUEST_IDENTIFIER
 204 %token <id>     REAL_IDENTIFIER
 205 %token <id>     STRING_IDENTIFIER
 206 %token <id>     TRANS_IDENTIFIER
 207 %token <id>     INT_IDENTIFIER
 208 %token <id>     SCORE_IDENTIFIER
 209 %token <id>     MIDI_IDENTIFIER
 210 %token <id>     PAPER_IDENTIFIER
 211 %token <real>   REAL
 212 %token <string> DURATION RESTNAME
 213 %token <string> STRING
 214 %token <i>      UNSIGNED
 215
 216
 217 %type <outputdef> output_def
 218 %type <scope>   mudela_header mudela_header_body
 219 %type <request> open_request_parens close_request_parens open_request close_request
 220 %type <request> request_with_dir request_that_take_dir verbose_request
 221 %type <i>       sub_quotes sup_quotes
 222 %type <music>   simple_element  request_chord command_element Simple_music  Composite_music
 223 %type <music>   Alternative_music Repeated_music
 224 %type <i>       abbrev_type
 225 %type <i>       int unsigned
 226 %type <i>       script_dir
 227 %type <i>       optional_modality
 228 %type <id>      identifier_init
 229 %type <duration> steno_duration notemode_duration
 230 %type <duration> entered_notemode_duration explicit_duration
 231 %type <intvec>  intastint_list int_list
 232 %type <reqvec>  pre_requests post_requests
 233 %type <request> gen_text_def
 234 %type <pitch>   explicit_musical_pitch steno_musical_pitch musical_pitch absolute_musical_pitch
 235 %type <pitch>   steno_tonic_pitch
 236
 237 %type <pitch_arr>       pitch_list
 238 %type <music>   chord notemode_chord
 239 %type <pitch_arr>       chord_additions chord_subtractions chord_notes
 240 %type <pitch>   chord_addsub chord_note chord_inversion notemode_chord_inversion
 241 %type <midi>    midi_block midi_body
 242 %type <duration>        duration_length
 243
 244 %type <scalar>  scalar
 245 %type <music>   Music  relative_music Sequential_music Simultaneous_music
 246 %type <music>   property_def translator_change
 247 %type <music_list> Music_list
 248 %type <paper>   paper_block paper_def_body
 249 %type <real>    real_expression real real_with_dimension
 250 %type <request> abbrev_command_req
 251 %type <request> post_request
 252 %type <request> command_req verbose_command_req
 253 %type <request> extender_req
 254 %type <string>  string
 255 %type <score>   score_block score_body
 256 %type <intarr>  shape_array
 257
 258 %type <string>  script_abbreviation
 259 %type <trans>   translator_spec_block translator_spec_body
 260 %type <tempo>   tempo_request
 261 %type <notenametab> notenames_body notenames_block chordmodifiers_block
 262
 263
 264
 265
 266 %left '-' '+'
 267 %left '*' '/'
 268 %left UNARY_MINUS
 269
 270 %%
 271
 272 mudela: /* empty */
 273         | mudela toplevel_expression {}
 274         | mudela assignment { }
 275         | mudela error
 276         | mudela check_version { }
 277         ;
 278
 279 toplevel_expression:
 280         notenames_block                 {
 281                 THIS->lexer_p_->set_notename_table ($1);
 282         }
 283         | chordmodifiers_block                  {
 284                 THIS->lexer_p_->set_chordmodifier_table ($1);
 285         }
 286         | mudela_header {
 287                 delete header_global_p;
 288                 header_global_p = $1;
 289         }
 290         | score_block {
 291                 score_global_array.push ($1);
 292         }
 293         | paper_block {
 294                 Identifier * id = new
 295                         Paper_def_identifier ($1, PAPER_IDENTIFIER);
 296                 THIS->lexer_p_->set_identifier ("$defaultpaper", id)
 297         }
 298         | midi_block {
 299                 Identifier * id = new
 300                         Midi_def_identifier ($1, MIDI_IDENTIFIER);
 301                 THIS->lexer_p_->set_identifier ("$defaultmidi", id)
 302         }
 303         | embedded_scm {
 304         }
 305         ;
 306
 307 embedded_scm:
 308         SCMFILE STRING semicolon {
 309                 read_lily_scm_file (*$2);
 310                 delete $2;
 311         }
 312         | SCM_T STRING semicolon {
 313                 gh_eval_str ($2->ch_l ());
 314                 delete $2;
 315         };
 316
 317 check_version:
 318         VERSION STRING semicolon                {
 319                 Mudela_version ver (*$2);
 320                 if (!((ver >= oldest_version) && (ver <= version))) {
 321                         if (THIS->ignore_version_b_) {
 322                                 THIS->here_input ().error (_f ("incorrect mudela version: %s (%s, %s)", ver.str (), oldest_version.str (), version.str ()));
 323                         } else {
 324                                 THIS->fatal_error_i_ = 1;
 325                                 THIS->parser_error (_f ("incorrect mudela version: %s (%s, %s)", ver.str (), oldest_version.str (), version.str ()));
 326                         }
 327                 }
 328         }
 329         ;
 330
 331
 332 chordmodifiers_block:
 333         CHORDMODIFIERS '{' notenames_body '}'  {  $$ = $3; }
 334         ;
 335
 336
 337 notenames_block:
 338         NOTENAMES '{' notenames_body '}'  {  $$ = $3; }
 339         ;
 340
 341
 342
 343 notenames_body:
 344         /**/    {
 345                 $$ = new Notename_table;
 346         }
 347         | NOTENAME_TABLE_IDENTIFIER     {
 348                 $$ = $1-> access_content_Notename_table(true);
 349         }
 350         | notenames_body STRING '=' explicit_musical_pitch {
 351                 (*$$)[*$2] = *$4;
 352
 353                 delete $4;
 354                 delete $2;
 355         }
 356         ;
 357
 358 mudela_header_body:
 359         {
 360                 $$ = new Scope;
 361                 THIS->lexer_p_-> scope_l_arr_.push ($$);
 362         }
 363         | mudela_header_body assignment semicolon {
 364
 365         }
 366         ;
 367
 368 mudela_header:
 369         HEADER '{' mudela_header_body '}'       {
 370                 $$ = $3;
 371                 THIS->lexer_p_-> scope_l_arr_.pop ();
 372         }
 373         ;
 374
 375
 376 /*
 377         DECLARATIONS
 378 */
 379 assignment:
 380         STRING {
 381                 THIS->remember_spot ();
 382         }
 383         /* cont */ '=' identifier_init  {
 384             THIS->lexer_p_->set_identifier (*$1, $4);
 385             $4->init_b_ = THIS->init_parse_b_;
 386             $4->set_spot (THIS->pop_spot ());
 387         }
 388         ;
 389
 390
 391
 392 identifier_init:
 393         score_block {
 394                 $$ = new Score_identifier ($1, SCORE_IDENTIFIER);
 395
 396         }
 397         | chordmodifiers_block {
 398                 $$ = new Notename_table_identifier ($1, NOTENAME_TABLE_IDENTIFIER);
 399         }
 400         | notenames_block {
 401                 $$ = new Notename_table_identifier ($1, NOTENAME_TABLE_IDENTIFIER);
 402         }
 403         | paper_block {
 404                 $$ = new Paper_def_identifier ($1, PAPER_IDENTIFIER);
 405         }
 406         | midi_block {
 407                 $$ = new Midi_def_identifier ($1, MIDI_IDENTIFIER);
 408
 409         }
 410         | translator_spec_block {
 411                 $$ = new Translator_identifier ($1, TRANS_IDENTIFIER);
 412         }
 413         | Music  {
 414                 $$ = new Music_identifier ($1, MUSIC_IDENTIFIER);
 415         }
 416
 417         | post_request {
 418                 $$ = new Request_identifier ($1, REQUEST_IDENTIFIER);
 419         }
 420         | explicit_duration {
 421                 $$ = new Duration_identifier ($1, DURATION_IDENTIFIER);
 422         }
 423         | real {
 424                 $$ = new Real_identifier (new Real ($1), REAL_IDENTIFIER);
 425         }
 426         | string {
 427                 $$ = new String_identifier ($1, STRING_IDENTIFIER);
 428         }
 429         | int   {
 430                 $$ = new int_identifier (new int ($1), INT_IDENTIFIER);
 431         }
 432         ;
 433
 434 translator_spec_block:
 435         TRANSLATOR '{' translator_spec_body '}'
 436                 {
 437                 $$ = $3;
 438         }
 439         ;
 440
 441 translator_spec_body:
 442         TRANS_IDENTIFIER        {
 443                 $$ = $1->access_content_Translator (true);
 444                 $$-> set_spot (THIS->here_input ());
 445         }
 446         | TYPE STRING semicolon {
 447                 Translator* t = get_translator_l (*$2);
 448                 Translator_group * tg = dynamic_cast<Translator_group*> (t);
 449
 450                 if (!tg)
 451                         THIS->parser_error (_("Need a translator group for a context"));
 452
 453                 t = t->clone ();
 454                 t->set_spot (THIS->here_input ());
 455                 $$ = t;
 456                 delete $2;
 457         }
 458         | translator_spec_body STRING '=' identifier_init semicolon     {
 459                 Identifier* id = $4;
 460                 String_identifier *s = dynamic_cast<String_identifier*> (id);
 461                 Real_identifier *r= dynamic_cast<Real_identifier*>(id);
 462                 int_identifier *i = dynamic_cast<int_identifier*> (id);
 463
 464                 String str;
 465                 if (s) str = *s->access_content_String (false);
 466                 if (i) str = to_str (*i->access_content_int (false));
 467                 if (r) str = to_str (*r->access_content_Real (false));
 468                 if (!s && !i && !r)
 469                         THIS->parser_error (_("Wrong type for property value"));
 470
 471                 delete $4;
 472                 /* ugh*/
 473                 Translator_group * tr = dynamic_cast<Translator_group*>($$);
 474                 tr->set_property (*$2, str);
 475         }
 476         | translator_spec_body NAME STRING semicolon {
 477                 $$->type_str_ = *$3;
 478                 delete $3;
 479         }
 480         | translator_spec_body CONSISTS STRING semicolon {
 481                 dynamic_cast<Translator_group*> ($$)-> set_element (*$3, true);
 482                 delete $3;
 483         }
 484         | translator_spec_body ACCEPTS STRING semicolon {
 485                 dynamic_cast<Translator_group*> ($$)-> set_acceptor (*$3, true);
 486                 delete $3;
 487         }
 488         | translator_spec_body REMOVE STRING semicolon {
 489                 dynamic_cast<Translator_group*> ($$)-> set_element (*$3, false);
 490                 delete $3;
 491         }
 492         ;
 493
 494 /*
 495         SCORE
 496 */
 497 score_block:
 498         SCORE { THIS->remember_spot ();
 499         }
 500         /*cont*/ '{' score_body '}'     {
 501                 $$ = $4;
 502                 $$->set_spot (THIS->pop_spot ());
 503                 if (!$$->def_p_arr_.size ())
 504                         $$->add_output (THIS->default_paper_p ());
 505
 506         }
 507         ;
 508
 509 score_body:             {
 510                 $$ = new Score;
 511         }
 512         | SCORE_IDENTIFIER {
 513                 $$ = $1->access_content_Score (true);
 514         }
 515         | score_body mudela_header      {
 516                 $$->header_p_ = $2;
 517         }
 518         | score_body Music      {
 519                 if ($$->music_p_)
 520                         $2->warning (_ ("More than one music block"));
 521                 $$->music_p_ = $2;
 522         }
 523         | score_body output_def {
 524                 $$->add_output ($2);
 525         }
 526         | score_body error {
 527
 528         }
 529         ;
 530
 531 output_def:
 532         paper_block {
 533                 $$ = $1;
 534         }
 535         |  midi_block           {
 536                 $$= $1;
 537         }
 538         ;
 539
 540 intastint_list:
 541         /* */   { $$ =new Array<int>; }
 542         | intastint_list int '*' int    {
 543                 $$->push ($2); $$->push ($4);
 544         }
 545         | intastint_list int    {
 546                 $$->push ($2); $$->push (1);
 547         }
 548         ;
 549
 550
 551 /*
 552         PAPER
 553 */
 554 paper_block:
 555         PAPER '{' paper_def_body '}'    {
 556                 $$ = $3;
 557                 THIS-> lexer_p_->scope_l_arr_.pop ();
 558         }
 559         ;
 560
 561
 562 optional_dot:
 563         /* empty */
 564         | '.'
 565         ;
 566
 567 paper_def_body:
 568         /* empty */                     {
 569                 Paper_def *p = THIS->default_paper_p ();
 570                 THIS-> lexer_p_-> scope_l_arr_.push (p->scope_p_);
 571                 $$ = p;
 572         }
 573         | PAPER_IDENTIFIER      {
 574                 Paper_def *p = $1->access_content_Paper_def (true);
 575                 THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 576                 $$ = p;
 577         }
 578         | paper_def_body int '=' FONT STRING            { // ugh, what a syntax
 579                 Lookup * l = new Lookup;
 580                 l->font_name_ = *$5;
 581                 delete $5;
 582                 $$->set_lookup ($2, l);
 583         }
 584         | paper_def_body assignment semicolon {
 585
 586         }
 587         | paper_def_body translator_spec_block {
 588                 $$->assign_translator ($2);
 589         }
 590         | paper_def_body SHAPE '=' shape_array semicolon {
 591                 $$->shape_int_a_ = *$4;
 592                 delete $4;
 593         }
 594         | paper_def_body error {
 595
 596         }
 597         ;
 598
 599
 600 real:
 601         real_expression         { $$ = $1; }
 602         ;
 603
 604
 605 real_with_dimension:
 606         REAL CM_T       {
 607                 $$ = $1 CM;
 608         }
 609         | REAL PT_T     {
 610                 $$ = $1 PT;
 611         }
 612         | REAL IN_T     {
 613                 $$ = $1 INCH;
 614         }
 615         | REAL MM_T     {
 616                 $$ = $1 MM;
 617         }
 618         ;
 619
 620 real_expression:
 621         REAL            {
 622                 $$ = $1;
 623         }
 624         | real_with_dimension
 625         | REAL_IDENTIFIER               {
 626                 $$= *$1->access_content_Real (false);
 627         }
 628         | '-'  real_expression %prec UNARY_MINUS {
 629                 $$ = -$2;
 630         }
 631         | real_expression '*' real_expression {
 632                 $$ = $1 * $3;
 633         }
 634         | real_expression '/' real_expression {
 635                 $$ = $1 / $3;
 636         }
 637         | real_expression '+' real_expression {
 638                 $$ = $1  + $3;
 639         }
 640         | real_expression '-' real_expression {
 641                 $$ = $1 - $3;
 642         }
 643         | '(' real_expression ')'       {
 644                 $$ = $2;
 645         }
 646         ;
 647
 648
 649 shape_array:
 650         /* empty */ {
 651                 $$ = new Array<Interval>;
 652         }
 653         | shape_array real real {
 654                 $$->push(Interval($2, $2 + $3));
 655         };
 656
 657 /*
 658         MIDI
 659 */
 660 midi_block:
 661         MIDI
 662
 663         '{' midi_body '}'       { $$ = $3; }
 664         ;
 665
 666 midi_body: /* empty */          {
 667                 $$ = THIS->default_midi_p ();
 668         }
 669         | MIDI_IDENTIFIER       {
 670                 $$ = $1-> access_content_Midi_def (true);
 671         }
 672         | midi_body translator_spec_block       {
 673                 $$-> assign_translator ($2);
 674         }
 675         | midi_body tempo_request semicolon {
 676                 $$->set_tempo ($2->dur_.length_mom (), $2->metronome_i_);
 677                 delete $2;
 678         }
 679         | midi_body error {
 680
 681         }
 682         ;
 683
 684 tempo_request:
 685         TEMPO steno_duration '=' unsigned       {
 686                 $$ = new Tempo_req;
 687                 $$->dur_ = *$2;
 688                 delete $2;
 689                 $$-> metronome_i_ = $4;
 690         }
 691         ;
 692
 693 Music_list: /* empty */ {
 694                 $$ = new Music_list;
 695         }
 696         | Music_list Music {
 697                 $$->add_music ($2);
 698         }
 699         | Music_list error {
 700         }
 701         ;
 702
 703
 704 Music:
 705         Simple_music
 706         | Composite_music
 707         ;
 708
 709 Alternative_music:
 710         ALTERNATIVE Simultaneous_music {
 711                 $$ = $2;
 712         }
 713         | ALTERNATIVE Sequential_music {
 714                 $$ = $2;
 715         }
 716         ;
 717
 718 Repeated_music: REPEAT unsigned Music Alternative_music {
 719                 Music_sequence* m = dynamic_cast <Music_sequence*> ($4);
 720                 assert (m);
 721                 $$ = new Repeated_music ($3, $2 >? 1, m);
 722         }
 723         ;
 724
 725 Sequential_music: '{' Music_list '}'            {
 726                 $$ = new Sequential_music ($2);
 727         }
 728         ;
 729
 730 Simultaneous_music: '<' Music_list '>'  {
 731                 $$ = new Simultaneous_music ($2);
 732         }
 733         ;
 734
 735 Simple_music:
 736         request_chord           { $$ = $1; }
 737         | MUSIC_IDENTIFIER { $$ = $1->access_content_Music (true); }
 738         | property_def
 739         | translator_change
 740         | Simple_music '*' unsigned '/' unsigned        {
 741                 /* urg */
 742                 $$ = new Compressed_music ($3, $5, $1);
 743         }
 744         | Simple_music '*' unsigned              {
 745                 $$ = new Compressed_music ($3, 1, $1);
 746         }
 747         ;
 748
 749
 750 Composite_music:
 751         TYPE STRING Music       {
 752                 $$ = $3;
 753                 $$->translator_type_str_ = *$2;
 754                 delete $2;
 755         }
 756         | TYPE STRING '=' STRING Music {
 757                 $$ = $5;
 758                 $$->translator_type_str_ = *$2;
 759                 $$->translator_id_str_ = *$4;
 760                 delete $2;
 761                 delete $4;
 762         }
 763         | TIMES {
 764                 THIS->remember_spot ();
 765         }
 766         /* CONTINUED */
 767                 unsigned '/' unsigned Music
 768
 769         {
 770                 $$ = new Compressed_music ($3, $5, $6);
 771                 $$->set_spot (THIS->pop_spot ());
 772         }
 773         | Repeated_music                { $$ = $1; }
 774         | Simultaneous_music            { $$ = $1; }
 775         | Sequential_music              { $$ = $1; }
 776         | TRANSPOSE musical_pitch Music {
 777                 $$ = new Transposed_music ($3, *$2);
 778                 delete $2;
 779         }
 780         | TRANSPOSE steno_tonic_pitch Music {
 781                 $$ = new Transposed_music ($3, *$2);
 782                 delete $2;
 783         }
 784         | NOTES
 785                 { THIS->lexer_p_->push_note_state (); }
 786         Music
 787                 { $$ = $3;
 788                   THIS->lexer_p_->pop_state ();
 789                 }
 790         | CHORDS
 791                 { THIS->lexer_p_->push_chord_state (); }
 792         Music
 793                 {
 794                   $$ = $3;
 795                   THIS->lexer_p_->pop_state ();
 796         }
 797         | LYRICS
 798                 { THIS->lexer_p_->push_lyric_state (); }
 799         Music
 800                 {
 801                   $$ = $3;
 802                   THIS->lexer_p_->pop_state ();
 803         }
 804         | relative_music        { $$ = $1; }
 805         ;
 806
 807 relative_music:
 808         RELATIVE absolute_musical_pitch Music {
 809                 $$ = new Relative_octave_music ($3, *$2);
 810                 delete $2;
 811         }
 812         ;
 813
 814 translator_change:
 815         TRANSLATOR STRING '=' STRING  {
 816                 Change_translator * t = new Change_translator;
 817                 t-> change_to_type_str_ = *$2;
 818                 t-> change_to_id_str_ = *$4;
 819
 820                 $$ = t;
 821                 $$->set_spot (THIS->here_input ());
 822                 delete $2;
 823                 delete $4;
 824         }
 825         ;
 826
 827 property_def:
 828         PROPERTY STRING '.' STRING '=' scalar   {
 829                 Translation_property *t = new Translation_property;
 830                 t-> translator_type_str_ = *$2;
 831                 t-> var_str_ = *$4;
 832                 t-> value_ = *$6;
 833                 $$ = t;
 834                 $$->set_spot (THIS->here_input ());
 835                 delete $2;
 836                 delete $4;
 837                 delete $6;
 838         }
 839         ;
 840
 841 scalar:
 842         STRING          { $$ = new Scalar (*$1); delete $1; }
 843         | int           { $$ = new Scalar ($1); }
 844         ;
 845
 846
 847 request_chord:
 848         pre_requests simple_element post_requests       {
 849                 Music_sequence *l = dynamic_cast<Music_sequence*>($2);
 850                 for (int i=0; i < $1->size(); i++)
 851                         l->add_music ($1->elem(i));
 852                 for (int i=0; i < $3->size(); i++)
 853                         l->add_music ($3->elem(i));
 854                 $$ = $2;
 855
 856         }
 857         | command_element
 858         ;
 859
 860 command_element:
 861         command_req {
 862                 $$ = new Request_chord;
 863                 $$-> set_spot (THIS->here_input ());
 864                 $1-> set_spot (THIS->here_input ());
 865                 ((Simultaneous_music*)$$) ->add_music ($1);//ugh
 866         }
 867         ;
 868
 869 command_req:
 870         abbrev_command_req
 871         | verbose_command_req semicolon { $$ = $1; }
 872         ;
 873
 874 abbrev_command_req:
 875         extender_req {
 876                 $$ = $1;
 877         }
 878         | '|'                           {
 879                 $$ = new Barcheck_req;
 880         }
 881         | '~'   {
 882                 $$ = new Tie_req;
 883         }
 884         | '['           {
 885                 Beam_req*b= new Beam_req;
 886                 b->spantype_ = START;
 887                 $$ =b;
 888         }
 889         | ']'           {
 890                 Beam_req*b= new Beam_req;
 891                 b->spantype_ = STOP;
 892                 $$ = b;
 893         }
 894         ;
 895
 896
 897 verbose_command_req:
 898         BAR STRING                      {
 899                 $$ = new Bar_req (*$2);
 900                 delete $2;
 901         }
 902         | MARK STRING {
 903                 $$ = new Mark_req (*$2);
 904                 delete $2;
 905         }
 906         | MARK unsigned {
 907                 $$ = new Mark_req (to_str ($2));
 908         }
 909         | TIME_T unsigned '/' unsigned  {
 910                 Time_signature_change_req *m = new Time_signature_change_req;
 911                 m->beats_i_ = $2;
 912                 m->one_beat_i_=$4;
 913                 $$ = m;
 914         }
 915         | PENALTY int   {
 916                 Break_req * b = new Break_req;
 917                 b->penalty_i_ = $2;
 918                 b-> set_spot (THIS->here_input ());
 919                 $$ = b;
 920         }
 921         | SKIP duration_length {
 922                 Skip_req * skip_p = new Skip_req;
 923                 skip_p->duration_ = *$2;
 924                 delete $2;
 925                 $$ = skip_p;
 926         }
 927         | tempo_request {
 928                 $$ = $1;
 929         }
 930         | CADENZA unsigned      {
 931                 $$ = new Cadenza_req ($2);
 932         }
 933         | PARTIAL duration_length       {
 934                 $$ = new Partial_measure_req ($2->length_mom ());
 935                 delete $2;
 936         }
 937         | CLEF STRING {
 938                 $$ = new Clef_change_req (*$2);
 939                 delete $2;
 940         }
 941         | KEY NOTENAME_PITCH optional_modality  {
 942                 Key_change_req *key_p= new Key_change_req;
 943                 key_p->pitch_arr_.push(*$2);
 944                 key_p->ordinary_key_b_ = true;
 945                 key_p->modality_i_ = $3;
 946                 $$ = key_p;
 947                 delete $2;
 948         }
 949         | KEYSIGNATURE pitch_list {
 950                 Key_change_req *key_p= new Key_change_req;
 951                 key_p->pitch_arr_ = *$2;
 952                 key_p->ordinary_key_b_ = false;
 953                 $$ = key_p;
 954                 delete $2;
 955         }
 956         | GROUPING intastint_list  {
 957                   Measure_grouping_req * mr_p = new Measure_grouping_req;
 958                   for (int i=0; i < $2->size();)
 959                     {
 960                       mr_p->elt_length_arr_.push (Moment (1, $2->elem(i++)));
 961                       mr_p->beat_i_arr_.push ($2->elem(i++));
 962                     }
 963
 964
 965                 $$ = mr_p;
 966                 delete $2;
 967         }
 968         ;
 969
 970 post_requests:
 971         {
 972                 $$ = new Link_array<Request>;
 973         }
 974         | post_requests post_request {
 975                 $2->set_spot (THIS->here_input ());
 976                 $$->push ($2);
 977         }
 978         ;
 979
 980 post_request:
 981         verbose_request
 982         | request_with_dir
 983         | close_request
 984         ;
 985
 986
 987 request_that_take_dir:
 988         gen_text_def
 989         | verbose_request
 990         | script_abbreviation {
 991                 Identifier*i = THIS->lexer_p_->lookup_identifier ("dash-" + *$1);
 992                 Articulation_req *a = new Articulation_req;
 993                 a->articulation_str_ = *i->access_content_String (false);
 994                 delete $1;
 995                 $$ = a;
 996         }
 997         ;
 998
 999 request_with_dir:
1000         script_dir request_that_take_dir        {
1001                 if (G_script_req * gs = dynamic_cast<G_script_req*> ($2))
1002                         gs->dir_ = $1;
1003                 else if ($1)
1004                         $2->warning ("Can't specify direction for this request");
1005                 $$ = $2;
1006         }
1007         ;
1008
1009 verbose_request:
1010         REQUEST_IDENTIFIER      {
1011                 $$ = (Request*)$1->access_content_Request (true);
1012                 $$->set_spot (THIS->here_input ());
1013         }
1014         | ABSDYNAMIC '{' STRING '}'     {
1015                 Absolute_dynamic_req *ad_p = new Absolute_dynamic_req;
1016                 ad_p ->loudness_str_ = *$3;
1017                 ad_p->set_spot (THIS->here_input ());
1018                 delete $3;
1019                 $$ =ad_p;
1020         }
1021         | SPANDYNAMIC '{' int int '}' {
1022                 Span_dynamic_req * sp_p = new Span_dynamic_req;
1023                 sp_p-> dynamic_dir_  = Direction($3);
1024                 sp_p->spantype_ = Direction($4);
1025                 sp_p->set_spot (THIS->here_input ());
1026                 $$ = sp_p;
1027         }
1028         | abbrev_type   {
1029                 Abbreviation_req* a = new Abbreviation_req;
1030                 a->set_spot (THIS->here_input ());
1031                 a->type_i_ = $1;
1032                 $$ = a;
1033         }
1034         | SCRIPT STRING         {
1035                 Articulation_req * a = new Articulation_req;
1036                 a->articulation_str_ = *$2;
1037                 a->set_spot (THIS->here_input ());
1038                 $$ = a;
1039                 delete $2;
1040         }
1041         ;
1042
1043 optional_modality:
1044         /* empty */     {
1045                 $$ = 0;
1046         }
1047         | int   {
1048                 $$ = $1;
1049         }
1050         ;
1051
1052 sup_quotes:
1053         '\'' {
1054                 $$ = 1;
1055         }
1056         | sup_quotes '\'' {
1057                 $$ ++;
1058         }
1059         ;
1060
1061 sub_quotes:
1062         ',' {
1063                 $$ = 1;
1064         }
1065         | sub_quotes ',' {
1066                 $$ ++ ;
1067         }
1068         ;
1069
1070 steno_musical_pitch:
1071         NOTENAME_PITCH  {
1072                 $$ = $1;
1073         }
1074         | NOTENAME_PITCH sup_quotes     {
1075                 $$ = $1;
1076                 $$->octave_i_ +=  $2;
1077         }
1078         | NOTENAME_PITCH sub_quotes      {
1079                 $$ = $1;
1080                 $$->octave_i_ += - $2;
1081         }
1082         ;
1083
1084 steno_tonic_pitch:
1085         TONICNAME_PITCH {
1086                 $$ = $1;
1087         }
1088         | TONICNAME_PITCH sup_quotes    {
1089                 $$ = $1;
1090                 $$->octave_i_ +=  $2;
1091         }
1092         | TONICNAME_PITCH sub_quotes     {
1093                 $$ = $1;
1094                 $$->octave_i_ += - $2;
1095         }
1096         ;
1097
1098 explicit_musical_pitch:
1099         MUSICAL_PITCH '{' int_list '}'  {/* ugh */
1100                 Array<int> &a = *$3;
1101                 ARRAY_SIZE(a,3);
1102                 $$ = new Musical_pitch;
1103                 $$->octave_i_ = a[0];
1104                 $$->notename_i_ = a[1];
1105                 $$->accidental_i_ = a[2];
1106                 delete &a;
1107         }
1108         ;
1109
1110 musical_pitch:
1111         steno_musical_pitch
1112         | explicit_musical_pitch
1113         ;
1114
1115 explicit_duration:
1116         DURATION '{' int_list '}'       {
1117                 $$ = new Duration;
1118                 Array<int> &a = *$3;
1119                 ARRAY_SIZE(a,2);
1120
1121                 $$-> durlog_i_ = a[0];
1122                 $$-> dots_i_ = a[1];
1123
1124                 delete &a;
1125         }
1126         ;
1127
1128 extender_req:
1129         EXTENDER {
1130                 if (!THIS->lexer_p_->lyric_state_b ())
1131                         THIS->parser_error (_ ("have to be in Lyric mode for lyrics"));
1132                 $$ = new Extender_req;
1133         }
1134         ;
1135
1136 close_request:
1137         close_request_parens {
1138                 $$ = $1;
1139                 dynamic_cast<Span_req*> ($$)->spantype_ = START;
1140         }
1141
1142 close_request_parens:
1143         '('     {
1144                 $$= new Slur_req;
1145         }
1146         | E_SMALLER {
1147                 Span_dynamic_req*s =new Span_dynamic_req;
1148                 $$ = s;
1149                 s->dynamic_dir_ = UP;
1150         }
1151         | E_BIGGER {
1152                 Span_dynamic_req*s =new Span_dynamic_req;
1153                 $$ = s;
1154                 s->dynamic_dir_ = DOWN;
1155         }
1156         ;
1157
1158
1159 open_request:
1160         open_request_parens {
1161                 $$ = $1;
1162                 dynamic_cast<Span_req*> ($$)->spantype_ = STOP;
1163         }
1164         ;
1165
1166 open_request_parens:
1167         E_EXCLAMATION   {
1168                 Span_dynamic_req *s =  new Span_dynamic_req;
1169                 s->dynamic_dir_ = SMALLER;
1170                 $$ = s;
1171
1172         }
1173         | ')'   {
1174                 $$= new Slur_req
1175         }
1176         ;
1177
1178 gen_text_def:
1179         string {
1180                 Text_script_req *t  = new Text_script_req;
1181                 $$ = t;
1182                 t->text_str_ = *$1;
1183                 delete $1;
1184                 $$->set_spot (THIS->here_input ());
1185         }
1186         | DIGIT {
1187                 Text_script_req* t  = new Text_script_req;
1188                 $$ = t;
1189                 t->text_str_ = to_str ($1);
1190                 t->style_str_ = "finger";
1191                 $$->set_spot (THIS->here_input ());
1192         }
1193         ;
1194
1195 script_abbreviation:
1196         '^'             {
1197                 $$ = new String ("hat");
1198         }
1199         | '+'           {
1200                 $$ = new String ("plus");
1201         }
1202         | '-'           {
1203                 $$ = new String ("dash");
1204         }
1205         | '|'           {
1206                 $$ = new String ("bar");
1207         }
1208         | '>'           {
1209                 $$ = new String ("larger");
1210         }
1211         | '.'           {
1212                 $$ = new String ("dot");
1213         }
1214         ;
1215
1216
1217 script_dir:
1218         '_'     { $$ = DOWN; }
1219         | '^'   { $$ = UP; }
1220         | '-'   { $$ = CENTER; }
1221         ;
1222
1223 pre_requests:
1224         {
1225                 $$ = new Link_array<Request>;
1226         }
1227         | pre_requests open_request {
1228                 $$->push ($2);
1229         }
1230         ;
1231
1232 absolute_musical_pitch:
1233         steno_musical_pitch     {
1234                 $$ = $1;
1235         }
1236         ;
1237
1238 duration_length:
1239         steno_duration {
1240                 $$ = $1;
1241         }
1242         | duration_length '*' unsigned {
1243                 $$->plet_.iso_i_ *= $3;
1244         }
1245         | duration_length '/' unsigned {
1246                 $$->plet_.type_i_ *= $3;
1247         }
1248         ;
1249
1250 entered_notemode_duration:
1251         dots            {
1252                 $$ = new Duration (THIS->default_duration_);
1253                 if ($1)
1254                         $$->dots_i_  = $1;
1255         }
1256         | steno_duration        {
1257                 THIS->set_last_duration ($1);
1258         }
1259         ;
1260
1261 notemode_duration:
1262         entered_notemode_duration {
1263                 $$ = $1;
1264         }
1265         ;
1266
1267 steno_duration:
1268         unsigned                {
1269                 $$ = new Duration;
1270                 if (!Duration::duration_type_b ($1))
1271                         THIS->parser_error (_f ("not a duration: %d", $1));
1272                 else {
1273                         $$->durlog_i_ = Duration_convert::i2_type ($1);
1274                      }
1275         }
1276         | DURATION_IDENTIFIER   {
1277                 $$ = $1->access_content_Duration (true);
1278         }
1279         | steno_duration '.'    {
1280                 $$->dots_i_ ++;
1281         }
1282         ;
1283
1284
1285 abbrev_type:
1286         ':'     {
1287                 $$ =0;
1288         }
1289         | ':' unsigned {
1290                 if (!Duration::duration_type_b ($2))
1291                         THIS->parser_error (_f ("not a duration: %d", $2));
1292                 else if ($2 < 8)
1293                         THIS->parser_error (_ ("can't abbreviate"));
1294                 $$ = $2;
1295         }
1296         ;
1297
1298
1299 simple_element:
1300         musical_pitch exclamations questions notemode_duration  {
1301                 if (!THIS->lexer_p_->note_state_b ())
1302                         THIS->parser_error (_ ("have to be in Note mode for notes"));
1303
1304
1305                 Note_req *n = new Note_req;
1306
1307                 n->pitch_ = *$1;
1308                 delete $1;
1309                 n->duration_ = *$4;
1310                 delete $4;
1311                 n->forceacc_b_ = $2 % 2;
1312                 n->cautionary_b_ = $3 % 2;
1313
1314                 Simultaneous_music*v = new Request_chord;
1315                 v->set_spot (THIS->here_input ());
1316                 n->set_spot (THIS->here_input ());
1317
1318                 v->add_music (n);
1319
1320                 $$ = v;
1321         }
1322         | RESTNAME notemode_duration            {
1323                 $$ = THIS->get_rest_element (*$1, $2);
1324                 delete $1;  // delete notename
1325         }
1326         | MEASURES notemode_duration    {
1327                 Multi_measure_rest_req* m = new Multi_measure_rest_req;
1328                 m->duration_ = *$2;
1329                 delete $2;
1330
1331                 Simultaneous_music*velt_p = new Request_chord;
1332                 velt_p->set_spot (THIS->here_input ());
1333                 velt_p->add_music (m);
1334                 $$ = velt_p;
1335         }
1336         | STRING notemode_duration                      {
1337                 if (!THIS->lexer_p_->lyric_state_b ())
1338                         THIS->parser_error (_ ("have to be in Lyric mode for lyrics"));
1339                 $$ = THIS->get_word_element (*$1, $2);
1340                 delete $1;
1341         }
1342         | chord {
1343                 if (!THIS->lexer_p_->chord_state_b ())
1344                         THIS->parser_error (_ ("have to be in Chord mode for chords"));
1345                 $$ = $1;
1346         }
1347         | '@' notemode_chord '@' {
1348                 if (!THIS->lexer_p_->note_state_b ())
1349                         THIS->parser_error (_ ("have to be in Note mode for @chords"));
1350                 $$ = $2;
1351         }
1352         ;
1353
1354 chord:
1355         steno_tonic_pitch notemode_duration chord_additions chord_subtractions chord_inversion {
1356                 $$ = THIS->get_chord (*$1, $3, $4, $5, *$2);
1357         };
1358
1359 notemode_chord:
1360         steno_musical_pitch notemode_duration chord_additions chord_subtractions notemode_chord_inversion {
1361                 $$ = THIS->get_chord (*$1, $3, $4, $5, *$2);
1362         };
1363
1364
1365 chord_additions:
1366         {
1367                 $$ = new Array<Musical_pitch>;
1368         }
1369         | '-' chord_notes {
1370                 $$ = $2;
1371         }
1372         ;
1373
1374 chord_notes:
1375         {
1376                 $$ = new Array<Musical_pitch>;
1377         }
1378         | chord_notes chord_addsub {
1379                 $$ = $1;
1380                 $$->push (*$2);
1381         }
1382         ;
1383
1384 chord_subtractions:
1385         {
1386                 $$ = new Array<Musical_pitch>;
1387         }
1388         | '^' chord_notes {
1389                 $$ = $2;
1390         }
1391         ;
1392
1393
1394 /*
1395         forevery : X : optional_X sucks. Devise  a solution.
1396 */
1397
1398
1399 chord_addsub:
1400         chord_note optional_dot
1401         | CHORDMODIFIER_PITCH optional_dot
1402         ;
1403
1404 chord_inversion:
1405         {
1406                 $$ = 0;
1407         }
1408         | '/' steno_tonic_pitch {
1409                 $$ = $2
1410         }
1411         ;
1412
1413 notemode_chord_inversion:
1414         {
1415                 $$ = 0;
1416         }
1417         | '/' steno_musical_pitch {
1418                 $$ = $2
1419         }
1420         ;
1421
1422 chord_note:
1423         unsigned {
1424                 $$ = new Musical_pitch;
1425                 $$->notename_i_ = ($1 - 1) % 7;
1426                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1427                 $$->accidental_i_ = 0;
1428         }
1429         | unsigned '+' {
1430                 $$ = new Musical_pitch;
1431                 $$->notename_i_ = ($1 - 1) % 7;
1432                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1433                 $$->accidental_i_ = 1;
1434         }
1435         | unsigned '-' {
1436                 $$ = new Musical_pitch;
1437                 $$->notename_i_ = ($1 - 1) % 7;
1438                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1439                 $$->accidental_i_ = -1;
1440         }
1441         ;
1442
1443 /*
1444         UTILITIES
1445  */
1446 pitch_list:                     {
1447                 $$ = new Array<Musical_pitch>;
1448         }
1449         | pitch_list musical_pitch      {
1450                 $$->push (*$2);
1451                 delete $2;
1452         }
1453         ;
1454
1455
1456 int_list:
1457         /**/                    {
1458                 $$ = new Array<int>
1459         }
1460         | int_list int          {
1461                 $$->push ($2);
1462         }
1463         ;
1464
1465 unsigned:
1466         UNSIGNED        {
1467                 $$ = $1;
1468         }
1469         | DIGIT {
1470                 $$ = $1;
1471         };
1472
1473 int:
1474         unsigned {
1475                 $$ = $1;
1476         }
1477         | '-' unsigned {
1478                 $$ = -$2;
1479         }
1480         | INT_IDENTIFIER        {
1481                 $$ = *$1->access_content_int (false);
1482         }
1483         ;
1484
1485
1486 string:
1487         STRING          {
1488                 $$ = $1;
1489         }
1490         | STRING_IDENTIFIER     {
1491                 $$ = $1->access_content_String (true);
1492         }
1493         | string '+' string {
1494                 *$$ += *$3;
1495                 delete $3;
1496         }
1497         ;
1498
1499
1500
1501
1502 dots:
1503                         { $$ = 0; }
1504         | dots '.'      { $$ ++; }
1505         ;
1506
1507
1508
1509 exclamations:
1510                 { $$ = 0; }
1511         | exclamations '!'      { $$ ++; }
1512         ;
1513
1514 questions:
1515                 { $$ = 0; }
1516         | questions '?' { $$ ++; }
1517         ;
1518
1519
1520 semicolon:
1521         ';'
1522         ;
1523 %%
1524
1525 void
1526 My_lily_parser::set_yydebug (bool b)
1527 {
1528 #ifdef YYDEBUG
1529         yydebug = b;
1530 #endif
1531 }
1532 void
1533 My_lily_parser::do_yyparse ()
1534 {
1535         yyparse ((void*)this);
1536 }
1537
1538