lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for mudela
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2000 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 #include <iostream.h>
  13 #include "translator-def.hh"
  14 #include "lily-guile.hh"
  15 #include "translation-property.hh"
  16 #include "lookup.hh"
  17 #include "misc.hh"
  18 #include "my-lily-lexer.hh"
  19 #include "paper-def.hh"
  20 #include "midi-def.hh"
  21 #include "main.hh"
  22 #include "file-path.hh"
  23 #include "debug.hh"
  24 #include "dimensions.hh"
  25 #include "identifier.hh"
  26 #include "command-request.hh"
  27 #include "musical-request.hh"
  28 #include "my-lily-parser.hh"
  29 #include "context-specced-music.hh"
  30 #include "score.hh"
  31 #include "music-list.hh"
  32 #include "change-translator.hh"
  33 #include "file-results.hh"
  34 #include "input.hh"
  35 #include "scope.hh"
  36 #include "relative-music.hh"
  37 #include "lyric-combine-music.hh"
  38 #include "transposed-music.hh"
  39 #include "time-scaled-music.hh"
  40 #include "repeated-music.hh"
  41 #include "mudela-version.hh"
  42 #include "grace-music.hh"
  43 #include "auto-change-music.hh"
  44 #include "part-combine-music.hh"
  45 #include "output-property.hh"
  46 #include "chord.hh"
  47
  48 bool
  49 is_duration_b (int t)
  50 {
  51   return t && t == 1 << intlog2(t);
  52 }
  53
  54
  55 // mmm JUNKME ?
  56 Mudela_version oldest_version ("1.3.59");
  57
  58 void
  59 print_mudela_versions (ostream &os)
  60 {
  61   os << _f ("Oldest supported input version: %s", oldest_version.str ())
  62     << endl;
  63 }
  64
  65
  66 // needed for bison.simple's malloc() and free()
  67 #include <malloc.h>
  68
  69 #ifndef NDEBUG
  70 #define YYDEBUG 1
  71 #endif
  72
  73 #define YYERROR_VERBOSE 1
  74
  75 #define YYPARSE_PARAM my_lily_parser_l
  76 #define YYLEX_PARAM my_lily_parser_l
  77 #define THIS ((My_lily_parser *) my_lily_parser_l)
  78
  79 #define yyerror THIS->parser_error
  80 #define ARRAY_SIZE(a,s)   if (a.size () != s) THIS->parser_error (_f ("Expecting %d arguments", s))
  81
  82 %}
  83
  84
  85 %union {
  86     Array<Musical_pitch> *pitch_arr;
  87     Link_array<Request> *reqvec;
  88     Duration *duration;
  89     Identifier *id;
  90     String * string;
  91     Music *music;
  92     Score *score;
  93     Scope *scope;
  94
  95     Musical_req* musreq;
  96     Music_output_def * outputdef;
  97     Musical_pitch * pitch;
  98     Midi_def* midi;
  99     Real real;
 100     Request * request;
 101
 102     /* We use SCMs to do strings, because it saves us the trouble of
 103 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 104 of the parse stack onto the heap. */
 105
 106     SCM scm;
 107
 108     Tempo_req *tempo;
 109     int i;
 110 }
 111 %{
 112
 113 int
 114 yylex (YYSTYPE *s,  void * v_l)
 115 {
 116         My_lily_parser   *pars_l = (My_lily_parser*) v_l;
 117         My_lily_lexer * lex_l = pars_l->lexer_p_;
 118
 119         lex_l->lexval_l = (void*) s;
 120         return lex_l->yylex ();
 121 }
 122
 123
 124 %}
 125
 126 %pure_parser
 127
 128 /* tokens which are not keywords */
 129 %token AUTOCHANGE
 130 %token TEXTSCRIPT
 131 %token ACCEPTS
 132 %token ALTERNATIVE
 133 %token BAR
 134 %token BREATHE
 135 %token CHORDMODIFIERS
 136 %token CHORDS
 137 %token CHAR_T
 138 %token CLEF
 139 %token CM_T
 140 %token CONSISTS
 141 %token SEQUENTIAL
 142 %token SIMULTANEOUS
 143 %token CONSISTSEND
 144 %token DENIES
 145 %token DURATION
 146 %token EXTENDER
 147 %token FONT
 148 %token GRACE
 149 %token HEADER
 150 %token HYPHEN
 151 %token IN_T
 152 %token INVALID
 153 %token KEY
 154 %token LYRICS
 155 %token MARK
 156 %token MEASURES
 157 %token MIDI
 158 %token MM_T
 159 %token MUSICAL_PITCH
 160 %token NAME
 161 %token NOTENAMES
 162 %token NOTES
 163 %token PAPER
 164 %token PARTIAL
 165 %token PENALTY
 166 %token PROPERTY
 167 %token PUSH POP
 168 %token PT_T
 169 %token RELATIVE
 170 %token REMOVE
 171 %token REPEAT
 172 %token ADDLYRICS
 173 %token PARTCOMBINE
 174 %token SCM_T
 175 %token SCORE
 176 %token SCRIPT
 177 %token SKIP
 178 %token SPANREQUEST
 179 %token COMMANDSPANREQUEST
 180 %token TEMPO
 181 %token OUTPUTPROPERTY
 182 %token TIME_T
 183 %token TIMES
 184 %token TRANSLATOR
 185 %token TRANSPOSE
 186 %token TYPE
 187 %token CONTEXT
 188
 189 /* escaped */
 190 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER
 191 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET
 192
 193 %type <i>       exclamations questions
 194 %token <i>      DIGIT
 195 %token <pitch>  NOTENAME_PITCH
 196 %token <pitch>  TONICNAME_PITCH
 197 %token <pitch>  CHORDMODIFIER_PITCH
 198 %token <id>     DURATION_IDENTIFIER
 199 %token <id>     IDENTIFIER
 200
 201
 202 %token <id>     SCORE_IDENTIFIER
 203 %token <id>     MUSIC_OUTPUT_DEF_IDENTIFIER
 204
 205 %token <scm>    NUMBER_IDENTIFIER
 206 %token <scm>    REQUEST_IDENTIFIER
 207 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 208 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 209 %token <scm>    DURATION RESTNAME
 210 %token <scm>    STRING
 211 %token <scm>    SCM_T
 212 %token <i>      UNSIGNED
 213 %token <real>   REAL
 214
 215 %type <outputdef> output_def
 216 %type <scope>   mudela_header mudela_header_body
 217 %type <request> open_request_parens close_request_parens open_request close_request
 218 %type <request> request_with_dir request_that_take_dir verbose_request
 219 %type <i>       sub_quotes sup_quotes
 220 %type <music>   simple_element  request_chord command_element Simple_music  Composite_music
 221 %type <music>   Alternative_music Repeated_music
 222 %type <i>       tremolo_type
 223 %type <i>       bare_int  bare_unsigned
 224 %type <i>       script_dir
 225
 226 %type <scm>     identifier_init
 227
 228 %type <duration> steno_duration optional_notemode_duration
 229 %type <duration> entered_notemode_duration explicit_duration
 230
 231 %type <reqvec>  pre_requests post_requests
 232 %type <request> gen_text_def
 233 %type <pitch>   steno_musical_pitch musical_pitch absolute_musical_pitch
 234 %type <pitch>   steno_tonic_pitch
 235
 236 %type <pitch_arr>       chord_additions chord_subtractions chord_notes chord_step
 237 %type <music>   chord
 238 %type <pitch>   chord_note chord_inversion chord_bass
 239 %type <duration>        duration_length
 240
 241 %type <scm>  embedded_scm scalar
 242 %type <music>   Music Sequential_music Simultaneous_music Music_sequence
 243 %type <music>   relative_music re_rhythmed_music part_combined_music
 244 %type <music>   property_def translator_change
 245 %type <scm> Music_list
 246 %type <outputdef>  music_output_def_body
 247 %type <request> shorthand_command_req
 248 %type <request> post_request
 249 %type <request> command_req verbose_command_req
 250 %type <request> extender_req
 251 %type <request> hyphen_req
 252 %type <scm>     string bare_number number_expression
 253 %type <score>   score_block score_body
 254
 255 %type <scm>     translator_spec_block translator_spec_body
 256 %type <tempo>   tempo_request
 257 %type <scm> notenames_body notenames_block chordmodifiers_block
 258 %type <scm>     script_abbreviation
 259
 260
 261
 262 %left '-' '+'
 263 %left '*' '/'
 264 %left UNARY_MINUS
 265
 266 %%
 267
 268 mudela: /* empty */
 269         | mudela toplevel_expression {}
 270         | mudela assignment  { }
 271         | mudela error {
 272                 THIS->error_level_i_  = 1;
 273                 //THIS->parser_error (_ ("ly invalid"));
 274         }
 275         | mudela INVALID        {
 276                 THIS->error_level_i_  = 1;
 277                 //THIS->parser_error (_ ("ly invalid"));
 278         }
 279         ;
 280
 281 toplevel_expression:
 282         notenames_block                 {
 283                 THIS->lexer_p_->pitchname_tab_ =  $1;
 284         }
 285         | chordmodifiers_block                  {
 286                 THIS->lexer_p_->chordmodifier_tab_  = $1;
 287         }
 288         | mudela_header {
 289                 delete header_global_p;
 290                 header_global_p = $1;
 291         }
 292         | score_block {
 293                 score_global_array.push ($1);
 294         }
 295         | output_def {
 296                 Identifier * id = new
 297                         Music_output_def_identifier ($1, MUSIC_OUTPUT_DEF_IDENTIFIER);
 298                 if (dynamic_cast<Paper_def*> ($1))
 299                         THIS->lexer_p_->set_identifier ("$defaultpaper", id->self_scm ());
 300                 else if (dynamic_cast<Midi_def*> ($1))
 301                         THIS->lexer_p_->set_identifier ("$defaultmidi", id->self_scm ());
 302         }
 303         | embedded_scm {
 304                 // junk value
 305         }
 306         ;
 307
 308 embedded_scm:
 309         SCM_T
 310         | SCM_IDENTIFIER
 311         ;
 312
 313
 314 chordmodifiers_block:
 315         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 316         ;
 317
 318
 319 notenames_block:
 320         NOTENAMES notenames_body   {  $$ = $2; }
 321         ;
 322
 323
 324
 325 notenames_body:
 326         embedded_scm    {
 327           int i = scm_ilength ($1);
 328
 329           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 330           for (SCM s = $1; s != SCM_EOL; s = gh_cdr (s)) {
 331                 SCM pt = gh_cdar (s);
 332                 if (scm_ilength (pt) != 3)
 333                         THIS->parser_error ("Need three args");
 334                 scm_hashq_set_x (tab, gh_caar(s), pt);
 335           }
 336
 337           $$ = tab;
 338         }
 339         ;
 340
 341 mudela_header_body:
 342         {
 343                 $$ = new Scope;
 344                 THIS->lexer_p_-> scope_l_arr_.push ($$);
 345         }
 346         | mudela_header_body assignment semicolon {
 347
 348         }
 349         ;
 350
 351 mudela_header:
 352         HEADER '{' mudela_header_body '}'       {
 353                 $$ = $3;
 354                 THIS->lexer_p_-> scope_l_arr_.pop ();
 355         }
 356         ;
 357
 358
 359 /*
 360         DECLARATIONS
 361 */
 362 assignment:
 363         STRING {
 364                 THIS->remember_spot ();
 365         }
 366         /* cont */ '=' identifier_init  {
 367                 THIS->lexer_p_->set_identifier (ly_scm2string ($1), $4);
 368
 369 /*
 370  TODO: devise standard for protection in parser.
 371
 372   The parser stack lives on the C-stack, which means that
 373 all objects can be unprotected as soon as they're here.
 374
 375 */
 376                 Identifier * id =unsmob_identifier ($4);
 377                 Input spot = THIS->pop_spot ();
 378                 if (id) id->set_spot (spot);
 379         }
 380         ;
 381
 382
 383
 384 identifier_init:
 385         score_block {
 386                 $$ = (new Score_identifier ($1, SCORE_IDENTIFIER))->self_scm();
 387         }
 388         | output_def {
 389                 $$ = (new Music_output_def_identifier ($1, MUSIC_OUTPUT_DEF_IDENTIFIER))->self_scm();
 390         }
 391         | translator_spec_block {
 392                 $$ = $1;
 393         }
 394         | Music  {
 395                 $$ = $1->self_scm ();
 396                 scm_unprotect_object ($$);
 397         }
 398         | post_request {
 399                 $$ = $1->self_scm ();
 400                 scm_unprotect_object ($$);
 401         }
 402         | explicit_duration {
 403                 $$ = (new Duration_identifier ($1, DURATION_IDENTIFIER))->self_scm ();
 404         }
 405         | number_expression {
 406                 $$ = $1;
 407         }
 408         | string {
 409                 $$ = $1;
 410         }
 411         | embedded_scm  {
 412                 $$ = $1;
 413         }
 414         ;
 415
 416 translator_spec_block:
 417         TRANSLATOR '{' translator_spec_body '}'
 418                 {
 419                 $$ = $3;
 420         }
 421         ;
 422
 423 translator_spec_body:
 424         TRANSLATOR_IDENTIFIER   {
 425                 $$ = unsmob_translator_def ($1)->clone_scm ();
 426                 unsmob_translator_def ($$)-> set_spot (THIS->here_input ());
 427         }
 428         | TYPE STRING semicolon {
 429                 $$ = Translator_def::make_scm ();
 430                 Translator_def*td =  unsmob_translator_def ($$);
 431                 td->translator_group_type_ = $2;
 432                 td->set_spot (THIS->here_input ());
 433         }
 434         | translator_spec_body STRING '=' embedded_scm                  {
 435                 unsmob_translator_def ($$)->add_property_assign ($2, $4);
 436         }
 437         | translator_spec_body STRING PUSH embedded_scm '=' embedded_scm {
 438                 unsmob_translator_def ($$)
 439                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 440         }
 441         | translator_spec_body STRING POP embedded_scm  {
 442           unsmob_translator_def($$)->add_pop_property (
 443                 scm_string_to_symbol ($2), $4);
 444         }
 445         | translator_spec_body STRING '=' identifier_init semicolon     {
 446                 SCM v = gh_int2scm (0);
 447                 if (gh_string_p ($4) || gh_number_p ($4) || gh_boolean_p ($4))
 448                         v = $4;
 449                 else
 450                         THIS->parser_error (_("Wrong type for property value"));
 451
 452                 /* ugh*/
 453                 unsmob_translator_def($$)->add_property_assign ($2, v);
 454         }
 455         | translator_spec_body NAME STRING semicolon {
 456                 unsmob_translator_def ($$)->type_name_ = $3;
 457         }
 458         | translator_spec_body CONSISTS STRING semicolon {
 459                 unsmob_translator_def ($$)->add_element ($3);
 460         }
 461         | translator_spec_body CONSISTSEND STRING semicolon {
 462                 unsmob_translator_def ($$)->add_last_element ( $3);
 463         }
 464         | translator_spec_body ACCEPTS STRING semicolon {
 465                 unsmob_translator_def ($$)->set_acceptor ($3,true);
 466         }
 467         | translator_spec_body DENIES STRING semicolon {
 468                 unsmob_translator_def ($$)->set_acceptor ($3,false);
 469         }
 470         | translator_spec_body REMOVE STRING semicolon {
 471                 unsmob_translator_def ($$)->remove_element ($3);
 472         }
 473         ;
 474
 475 /*
 476         SCORE
 477 */
 478 score_block:
 479         SCORE {
 480                 THIS->remember_spot ();
 481         }
 482         /*cont*/ '{' score_body '}'     {
 483                 THIS->pop_spot ();
 484                 $$ = $4;
 485                 if (!$$->def_p_arr_.size ())
 486                 {
 487                   Identifier *id =
 488                         unsmob_identifier (THIS->lexer_p_->lookup_identifier ("$defaultpaper"));
 489                   $$->add_output (id ? id->access_content_Music_output_def (true) : new Paper_def );
 490                 }
 491         }
 492 /*
 493         | SCORE '{' score_body error {
 494                 $$ = $3
 495                 $$->set_spot (THIS->here_input ());
 496                 // THIS->here_input ().error ("SCORE INVALID");
 497                 $$->error ("SCORE INVALID");
 498                 THIS->parser_error (_f ("SCORE ERROR"));
 499         }
 500 */
 501         ;
 502
 503 score_body:
 504         Music   {
 505                 $$ = new Score;
 506
 507                 $$->set_spot (THIS->here_input ());
 508                 SCM m = $1->self_scm ();
 509                 scm_unprotect_object (m);
 510                 $$->music_ = m;
 511         }
 512         | SCORE_IDENTIFIER {
 513                 $$ = $1->access_content_Score (true);
 514         }
 515         | score_body mudela_header      {
 516                 $$->header_p_ = $2;
 517         }
 518         | score_body output_def {
 519                 $$->add_output ($2);
 520         }
 521         | score_body error {
 522
 523         }
 524         ;
 525
 526
 527 /*
 528         MIDI
 529 */
 530 output_def:
 531         music_output_def_body '}' {
 532                 $$ = $1;
 533                 THIS-> lexer_p_-> scope_l_arr_.pop();
 534         }
 535         ;
 536
 537 music_output_def_body:
 538         MIDI '{'    {
 539          Identifier *id = unsmob_identifier (THIS->lexer_p_->lookup_identifier ("$defaultmidi"));
 540
 541
 542          Midi_def* p =0;
 543         if (id)
 544                 p = dynamic_cast<Midi_def*> (id->access_content_Music_output_def (true));
 545         else
 546                 p = new Midi_def;
 547
 548          $$ = p;
 549          THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 550         }
 551         | PAPER '{'     {
 552                   Identifier *id = unsmob_identifier (THIS->lexer_p_->lookup_identifier ("$defaultpaper"));
 553                   Paper_def *p = 0;
 554                 if (id)
 555                         p = dynamic_cast<Paper_def*> (id->access_content_Music_output_def (true));
 556                 else
 557                         p = new Paper_def;
 558                 THIS-> lexer_p_-> scope_l_arr_.push (p->scope_p_);
 559                 $$ = p;
 560         }
 561         | PAPER '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 562                 Music_output_def *p = $3->access_content_Music_output_def (true);
 563                 THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 564                 $$ = p;
 565         }
 566         | MIDI '{' MUSIC_OUTPUT_DEF_IDENTIFIER  {
 567                 Music_output_def *p = $3->access_content_Music_output_def (true);
 568                 THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 569                 $$ = p;
 570         }
 571         | music_output_def_body assignment semicolon {
 572
 573         }
 574         | music_output_def_body translator_spec_block   {
 575                 $$->assign_translator ($2);
 576         }
 577         | music_output_def_body tempo_request semicolon {
 578                 /*
 579                         junk this ? there already is tempo stuff in
 580                         music.
 581                 */
 582                 dynamic_cast<Midi_def*> ($$)->set_tempo ($2->dur_.length_mom (), $2->metronome_i_);
 583         }
 584         | music_output_def_body bare_int '=' FONT STRING                { // ugh, what a syntax
 585                 SCM sl = Lookup::make_lookup();
 586                 Lookup * l =unsmob_lookup (sl);
 587                 l->font_name_ = ly_scm2string ($5);
 588                 dynamic_cast<Paper_def*> ($$)->set_lookup ($2, sl);
 589         }
 590         | music_output_def_body error {
 591
 592         }
 593         ;
 594
 595 tempo_request:
 596         TEMPO steno_duration '=' bare_unsigned  {
 597                 $$ = new Tempo_req;
 598                 $$->dur_ = *$2;
 599                 delete $2;
 600                 $$-> metronome_i_ = $4;
 601         }
 602         ;
 603
 604 Music_list: /* empty */ {
 605                 $$ = gh_cons (SCM_EOL, SCM_EOL);
 606         }
 607         | Music_list Music {
 608                 SCM s = $$;
 609                 SCM c = gh_cons ($2->self_scm (), SCM_EOL);
 610                 scm_unprotect_object ($2->self_scm ()); /* UGH */
 611
 612
 613                 if (gh_pair_p (gh_cdr (s)))
 614                         gh_set_cdr_x (gh_cdr (s), c); /* append */
 615                 else
 616                         gh_set_car_x (s, c); /* set first cons */
 617                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 618         }
 619         | Music_list error {
 620         }
 621         ;
 622
 623
 624 Music:
 625         Simple_music
 626         | Composite_music
 627         ;
 628
 629 Alternative_music:
 630         /* empty */ {
 631                 $$ = 0;
 632         }
 633         | ALTERNATIVE Music_sequence {
 634                 $$ = $2;
 635                 $2->set_spot (THIS->here_input ());
 636         }
 637         ;
 638
 639
 640
 641
 642 Repeated_music:
 643         REPEAT STRING bare_unsigned Music Alternative_music
 644         {
 645                 Music_sequence* m = dynamic_cast <Music_sequence*> ($5);
 646                 if (m && $3 < m->length_i ())
 647                         $5->origin ()->warning (_ ("More alternatives than repeats.  Junking excess alternatives."));
 648
 649                 Repeated_music * r = new Repeated_music ($4, $3 >? 1, m);
 650                 $$ = r;
 651                 r->type_ = ly_scm2string ($2);
 652                 r->fold_b_ = (r->type_ == "fold");
 653                 r->volta_fold_b_ =  (r->type_ == "volta");
 654                 r->set_spot (*$4->origin ());
 655         }
 656         ;
 657
 658 Music_sequence: '{' Music_list '}'      {
 659                 $$ = new Music_sequence (gh_car ($2));
 660         }
 661         ;
 662
 663 Sequential_music:
 664         SEQUENTIAL '{' Music_list '}'           {
 665                 $$ = new Sequential_music (gh_car ($3));
 666         }
 667         | '{' Music_list '}'            {
 668                 $$ = new Sequential_music (gh_car ($2));
 669         }
 670         ;
 671
 672 Simultaneous_music:
 673         SIMULTANEOUS '{' Music_list '}'{
 674                 $$ = new Simultaneous_music (gh_car ($3));
 675         }
 676         | '<' Music_list '>'    {
 677                 $$ = new Simultaneous_music (gh_car ($2));
 678         }
 679         ;
 680
 681 Simple_music:
 682         request_chord           { $$ = $1; }
 683         | OUTPUTPROPERTY embedded_scm embedded_scm '=' embedded_scm     {
 684                 SCM pred = $2;
 685                 if (!gh_symbol_p ($3))
 686                 {
 687                         THIS->parser_error (_("Second argument must be a symbol"));
 688                 }
 689                 /*hould check # args */
 690                 if (!gh_procedure_p (pred))
 691                 {
 692                         THIS->parser_error (_("First argument must be a procedure taking 1 argument"));
 693                 }
 694
 695                 $$ = new Output_property (pred,$3, $5);
 696         }
 697         | MUSIC_IDENTIFIER { $$ = unsmob_music ($1)->clone (); }
 698         | property_def
 699         | translator_change
 700         | Simple_music '*' bare_unsigned '/' bare_unsigned      {
 701                 $$ = $1;
 702                 $$->compress (Moment($3, $5 ));
 703         }
 704         | Simple_music '*' bare_unsigned                 {
 705                 $$ = $1;
 706                 $$->compress (Moment ($3, 1));
 707         }
 708         ;
 709
 710
 711 Composite_music:
 712         CONTEXT STRING Music    {
 713                 Context_specced_music *csm =  new Context_specced_music ($3);
 714
 715                 csm->translator_type_str_ = ly_scm2string ($2);
 716                 csm->translator_id_str_ = "";
 717
 718
 719                 $$ = csm;
 720         }
 721         | AUTOCHANGE STRING Music       {
 722                 Auto_change_music * chm = new Auto_change_music (ly_scm2string ($2), $3);
 723
 724                 $$ = chm;
 725                 chm->set_spot (*$3->origin ());
 726         }
 727         | GRACE Music {
 728                 $$ = new Grace_music ($2);
 729         }
 730         | CONTEXT STRING '=' STRING Music {
 731                 Context_specced_music *csm =  new Context_specced_music ($5);
 732
 733                 csm->translator_type_str_ = ly_scm2string ($2);
 734                 csm->translator_id_str_ = ly_scm2string ($4);
 735
 736                 $$ = csm;
 737         }
 738         | TIMES {
 739                 THIS->remember_spot ();
 740         }
 741         /* CONTINUED */
 742                 bare_unsigned '/' bare_unsigned Music
 743
 744         {
 745                 $$ = new Time_scaled_music ($3, $5, $6);
 746                 $$->set_spot (THIS->pop_spot ());
 747         }
 748         | Repeated_music                { $$ = $1; }
 749         | Simultaneous_music            { $$ = $1; }
 750         | Sequential_music              { $$ = $1; }
 751         | TRANSPOSE musical_pitch Music {
 752                 $$ = new Transposed_music ($3, *$2);
 753                 delete $2; // ugh
 754         }
 755         | TRANSPOSE steno_tonic_pitch Music {
 756                 $$ = new Transposed_music ($3, *$2);
 757                 delete $2; // ugh
 758         }
 759         | NOTES
 760                 { THIS->lexer_p_->push_note_state (); }
 761         Music
 762                 { $$ = $3;
 763                   THIS->lexer_p_->pop_state ();
 764                 }
 765         | CHORDS
 766                 { THIS->lexer_p_->push_chord_state (); }
 767         Music
 768                 {
 769                   $$ = $3;
 770                   THIS->lexer_p_->pop_state ();
 771         }
 772         | LYRICS
 773                 { THIS->lexer_p_->push_lyric_state (); }
 774         Music
 775                 {
 776                   $$ = $3;
 777                   THIS->lexer_p_->pop_state ();
 778         }
 779         | relative_music        { $$ = $1; }
 780         | re_rhythmed_music     { $$ = $1; }
 781         | part_combined_music   { $$ = $1; }
 782         ;
 783
 784 relative_music:
 785         RELATIVE absolute_musical_pitch Music {
 786                 $$ = new Relative_octave_music ($3, *$2);
 787                 delete $2; // ugh
 788         }
 789         ;
 790
 791 re_rhythmed_music:
 792         ADDLYRICS Music Music {
 793                 Lyric_combine_music * l = new Lyric_combine_music ($2, $3);
 794                 $$ = l;
 795         }
 796         ;
 797
 798 part_combined_music:
 799         PARTCOMBINE STRING Music Music {
 800                 Part_combine_music * p = new Part_combine_music (ly_scm2string ($2), $3, $4);
 801                 $$ = p;
 802         }
 803         ;
 804
 805 translator_change:
 806         TRANSLATOR STRING '=' STRING  {
 807                 Change_translator * t = new Change_translator;
 808                 t-> change_to_type_str_ = ly_scm2string ($2);
 809                 t-> change_to_id_str_ = ly_scm2string ($4);
 810
 811                 $$ = t;
 812                 $$->set_spot (THIS->here_input ());
 813         }
 814         ;
 815
 816 property_def:
 817         PROPERTY STRING '.' STRING '='  scalar {
 818                 Translation_property *t = new Translation_property;
 819
 820                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
 821                 t->set_mus_property ("value", $6);
 822
 823                 Context_specced_music *csm = new Context_specced_music (t);
 824                 $$ = csm;
 825                 $$->set_spot (THIS->here_input ());
 826
 827                 csm-> translator_type_str_ = ly_scm2string ($2);
 828         }
 829         | PROPERTY STRING '.' STRING PUSH embedded_scm '=' embedded_scm {
 830                 Push_translation_property *t = new Push_translation_property;
 831
 832                 t->set_mus_property ("symbols", scm_string_to_symbol ($4));
 833                 t->set_mus_property ("element-property", $6);
 834                 t->set_mus_property ("element-value", $8);
 835                 Context_specced_music *csm = new Context_specced_music (t);
 836                 $$ = csm;
 837                 $$->set_spot (THIS->here_input ());
 838
 839                 csm-> translator_type_str_ = ly_scm2string ($2);
 840         }
 841         | PROPERTY STRING '.' STRING POP embedded_scm {
 842                 Pop_translation_property *t = new Pop_translation_property;
 843
 844                 t->set_mus_property ("symbols", scm_string_to_symbol ($4));
 845                 t->set_mus_property ("element-property", $6);
 846
 847                 Context_specced_music *csm = new Context_specced_music (t);
 848                 $$ = csm;
 849                 $$->set_spot (THIS->here_input ());
 850
 851                 csm-> translator_type_str_ = ly_scm2string ($2);
 852         }
 853         ;
 854
 855 scalar:
 856         string          { $$ = $1; }
 857         | bare_int      { $$ = gh_int2scm ($1); }
 858         | embedded_scm  { $$ = $1; }
 859         ;
 860
 861
 862 request_chord:
 863         pre_requests simple_element post_requests       {
 864                 Music_sequence *l = dynamic_cast<Music_sequence*>($2);
 865                 if (l) {
 866                         for (int i=0; i < $1->size(); i++)
 867                                 l->append_music ($1->elem(i));
 868                         for (int i=0; i < $3->size(); i++)
 869                                 l->append_music ($3->elem(i));
 870                         }
 871                 else
 872                         programming_error ("Need Sequence to add music to");
 873                 $$ = $2;
 874
 875         }
 876         | command_element
 877         ;
 878
 879 command_element:
 880         command_req {
 881                 $$ = new Request_chord (gh_cons ($1->self_scm (), SCM_EOL));
 882                 $$-> set_spot (THIS->here_input ());
 883                 $1-> set_spot (THIS->here_input ());
 884         }
 885         | PARTIAL duration_length ';'   {
 886                 Translation_property * p = new Translation_property;
 887                 p->set_mus_property ("symbol", ly_symbol2scm ( "measurePosition"));
 888                 Moment m = - $2->length_mom ();
 889                 p->set_mus_property ("value", m.make_scm());
 890                 delete $2; // ugh
 891                 Context_specced_music * sp = new Context_specced_music (p);
 892                 $$ =sp ;
 893                 sp-> translator_type_str_ = "Score";
 894         }
 895         ;
 896
 897 command_req:
 898         shorthand_command_req
 899         | verbose_command_req semicolon { $$ = $1; }
 900         ;
 901
 902 shorthand_command_req:
 903         extender_req {
 904                 $$ = $1;
 905         }
 906         | hyphen_req {
 907                 $$ = $1;
 908         }
 909         | '|'                           {
 910                 $$ = new Barcheck_req;
 911         }
 912         | '~'   {
 913                 $$ = new Tie_req;
 914         }
 915         | '['           {
 916                 Span_req*b= new Span_req;
 917                 b->span_dir_ = START;
 918                 b->span_type_str_ = "beam";
 919                 $$ =b;
 920         }
 921         | ']'           {
 922              Span_req*b= new Span_req;
 923              b->span_dir_ = STOP;
 924              b->span_type_str_ = "beam";
 925              $$ = b;
 926         }
 927         | BREATHE {
 928                 $$ = new Breathing_sign_req;
 929         }
 930         ;
 931
 932
 933 verbose_command_req:
 934
 935         BAR STRING                      {
 936                 $$ = new Bar_req (ly_scm2string ($2));
 937         }
 938         | COMMANDSPANREQUEST bare_int STRING {
 939                 Span_req * sp_p = new Span_req;
 940                 sp_p-> span_dir_  = Direction($2);
 941                 sp_p->span_type_str_ = ly_scm2string ($3);
 942                 sp_p->set_spot (THIS->here_input ());
 943                 $$ = sp_p;
 944         }
 945         | MARK  {
 946                 Mark_req * m = new Mark_req;
 947                 $$ = m;
 948         }
 949         | MARK STRING {
 950                 Mark_req *m = new Mark_req;
 951                 m->set_mus_property ("label", $2);
 952                 $$ = m;
 953
 954         }
 955         | MARK bare_unsigned {
 956                 Mark_req *m = new Mark_req;
 957                 m->set_mus_property ("label",  gh_int2scm ($2));
 958                 $$ = m;
 959         }
 960
 961         | TIME_T bare_unsigned '/' bare_unsigned        {
 962                 Time_signature_change_req *m = new Time_signature_change_req;
 963                 m->beats_i_ = $2;
 964                 m->one_beat_i_=$4;
 965                 $$ = m;
 966         }
 967         | PENALTY bare_int      {
 968                 Break_req * b = new Break_req;
 969                 b->penalty_f_ = $2 / 100.0;
 970                 b->set_spot (THIS->here_input ());
 971                 $$ = b;
 972         }
 973         | SKIP duration_length {
 974                 Skip_req * skip_p = new Skip_req;
 975                 skip_p->duration_ = *$2;
 976                 delete $2; // ugh
 977                 $$ = skip_p;
 978         }
 979         | tempo_request {
 980                 $$ = $1;
 981         }
 982         | CLEF STRING {
 983                 $$ = new Clef_change_req (ly_scm2string ($2));
 984
 985         }
 986         | KEY {
 987                 Key_change_req *key_p= new Key_change_req;
 988                 $$ = key_p;
 989         }
 990         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
 991                 Key_change_req *key_p= new Key_change_req;
 992
 993                 key_p->set_mus_property ("pitch-alist", $3);
 994                 ((Music* )key_p)->transpose (* $2);
 995                 $$ = key_p;
 996         }
 997         ;
 998
 999 post_requests:
1000         {
1001                 $$ = new Link_array<Request>;
1002         }
1003         | post_requests post_request {
1004                 $2->set_spot (THIS->here_input ());
1005                 $$->push ($2);
1006         }
1007         ;
1008
1009 post_request:
1010         verbose_request
1011         | request_with_dir
1012         | close_request
1013         ;
1014
1015
1016 request_that_take_dir:
1017         gen_text_def
1018         | verbose_request
1019         | script_abbreviation {
1020                 SCM s = THIS->lexer_p_->lookup_identifier ("dash-" + ly_scm2string ($1));
1021                 Articulation_req *a = new Articulation_req;
1022                 if (gh_string_p (s))
1023                         a->articulation_str_ = ly_scm2string (s);
1024                 else THIS->parser_error (_ ("Expecting string as script definition"));
1025                 $$ = a;
1026         }
1027         ;
1028
1029 request_with_dir:
1030         script_dir request_that_take_dir        {
1031                 if (Script_req * gs = dynamic_cast<Script_req*> ($2))
1032                         gs->dir_ = Direction ($1);
1033                 else if ($1)
1034                         $2->origin ()->warning (_ ("Can't specify direction for this request"));
1035                 $$ = $2;
1036         }
1037         ;
1038
1039 verbose_request:
1040         REQUEST_IDENTIFIER      {
1041                 $$ = dynamic_cast<Request*> (unsmob_music ($1)->clone ());
1042                 $$->set_spot (THIS->here_input ());
1043         }
1044         | TEXTSCRIPT STRING STRING      {
1045                 Text_script_req *ts_p = new Text_script_req;
1046                 ts_p-> text_str_ = ly_scm2string ($2);
1047                 ts_p-> style_str_ = ly_scm2string ($3);
1048                 ts_p->set_spot (THIS->here_input ());
1049
1050                 $$ = ts_p;
1051         }
1052         | SPANREQUEST bare_int STRING {
1053                 Span_req * sp_p = new Span_req;
1054                 sp_p->span_dir_  = Direction($2);
1055                 sp_p->span_type_str_ = ly_scm2string ($3);
1056                 sp_p->set_spot (THIS->here_input ());
1057                 $$ = sp_p;
1058         }
1059         | tremolo_type  {
1060                 Tremolo_req* a = new Tremolo_req;
1061                 a->set_spot (THIS->here_input ());
1062                 a->type_i_ = $1;
1063                 $$ = a;
1064         }
1065         | SCRIPT STRING         {
1066                 Articulation_req * a = new Articulation_req;
1067                 a->articulation_str_ = ly_scm2string ($2);
1068                 a->set_spot (THIS->here_input ());
1069                 $$ = a;
1070         }
1071         ;
1072
1073 sup_quotes:
1074         '\'' {
1075                 $$ = 1;
1076         }
1077         | sup_quotes '\'' {
1078                 $$ ++;
1079         }
1080         ;
1081
1082 sub_quotes:
1083         ',' {
1084                 $$ = 1;
1085         }
1086         | sub_quotes ',' {
1087                 $$ ++ ;
1088         }
1089         ;
1090
1091 steno_musical_pitch:
1092         NOTENAME_PITCH  {
1093                 $$ = $1;
1094         }
1095         | NOTENAME_PITCH sup_quotes     {
1096                 $$ = $1;
1097                 $$->octave_i_ +=  $2;
1098         }
1099         | NOTENAME_PITCH sub_quotes      {
1100                 $$ = $1;
1101                 $$->octave_i_ += - $2;
1102         }
1103         ;
1104
1105 steno_tonic_pitch:
1106         TONICNAME_PITCH {
1107                 $$ = $1;
1108         }
1109         | TONICNAME_PITCH sup_quotes    {
1110                 $$ = $1;
1111                 $$->octave_i_ +=  $2;
1112         }
1113         | TONICNAME_PITCH sub_quotes     {
1114                 $$ = $1;
1115                 $$->octave_i_ += - $2;
1116         }
1117         ;
1118
1119 musical_pitch:
1120         steno_musical_pitch {
1121                 $$ = $1;
1122         }
1123         | MUSICAL_PITCH embedded_scm {
1124                 int sz = scm_ilength ($2);
1125                 if (sz != 3) {
1126                         THIS->parser_error (_f ("Expecting %d arguments", 3));
1127                         $2 = gh_list (gh_int2scm (0), gh_int2scm (0), gh_int2scm (0), SCM_UNDEFINED);
1128                 }
1129                 $$ = new Musical_pitch ($2);
1130         }
1131         ;
1132
1133 explicit_duration:
1134         DURATION embedded_scm   {
1135                 $$ = new Duration;
1136                 if (scm_ilength ($2) == 2)
1137                         {
1138                         $$-> durlog_i_ = gh_scm2int (gh_car($2));
1139                         $$-> dots_i_ = gh_scm2int (gh_cadr($2));
1140                         }
1141                 else
1142                         THIS->parser_error (_("Must have 2 arguments for duration"));
1143         }
1144         ;
1145
1146 extender_req:
1147         EXTENDER {
1148                 if (!THIS->lexer_p_->lyric_state_b ())
1149                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1150                 $$ = new Extender_req;
1151         }
1152         ;
1153
1154 hyphen_req:
1155         HYPHEN {
1156                 if (!THIS->lexer_p_->lyric_state_b ())
1157                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1158                 $$ = new Hyphen_req;
1159         }
1160         ;
1161
1162 close_request:
1163         close_request_parens {
1164                 $$ = $1;
1165                 dynamic_cast<Span_req*> ($$)->span_dir_ = START;
1166         }
1167
1168 close_request_parens:
1169         '('     {
1170                 Span_req* s= new Span_req;
1171                 $$ = s;
1172                 s->span_type_str_ = "slur";
1173         }
1174         | E_SMALLER {
1175                 Span_req*s =new Span_req;
1176                 $$ = s;
1177                 s->span_type_str_ = "crescendo";
1178         }
1179         | E_BIGGER {
1180                 Span_req*s =new Span_req;
1181                 $$ = s;
1182                 s->span_type_str_ = "decrescendo";
1183         }
1184         ;
1185
1186
1187 open_request:
1188         open_request_parens {
1189                 $$ = $1;
1190                 dynamic_cast<Span_req*> ($$)->span_dir_ = STOP;
1191         }
1192         ;
1193
1194 open_request_parens:
1195         E_EXCLAMATION   {
1196                 Span_req *s =  new Span_req;
1197                 s->span_type_str_ = "crescendo";
1198                 $$ = s;
1199         }
1200         | ')'   {
1201                 Span_req* s= new Span_req;
1202                 $$ = s;
1203                 s->span_type_str_ = "slur";
1204         }
1205         ;
1206
1207 gen_text_def:
1208         string {
1209                 Text_script_req *t  = new Text_script_req;
1210                 $$ = t;
1211                 t->text_str_ = ly_scm2string ($1);
1212
1213                 $$->set_spot (THIS->here_input ());
1214         }
1215         | DIGIT {
1216                 Text_script_req* t  = new Text_script_req;
1217                 $$ = t;
1218                 t->text_str_ = to_str ($1);
1219                 t->style_str_ = "finger";
1220                 $$->set_spot (THIS->here_input ());
1221         }
1222         ;
1223
1224 script_abbreviation:
1225         '^'             {
1226                 $$ = gh_str02scm  ("hat");
1227         }
1228         | '+'           {
1229                 $$ = gh_str02scm("plus");
1230         }
1231         | '-'           {
1232                 $$ = gh_str02scm ("dash");
1233         }
1234         | '|'           {
1235                 $$ = gh_str02scm ("bar");
1236         }
1237         | '>'           {
1238                 $$ = gh_str02scm ("larger");
1239         }
1240         | '.'           {
1241                 $$ = gh_str02scm ("dot");
1242         }
1243         ;
1244
1245
1246 script_dir:
1247         '_'     { $$ = DOWN; }
1248         | '^'   { $$ = UP; }
1249         | '-'   { $$ = CENTER; }
1250         ;
1251
1252 pre_requests:
1253         {
1254                 $$ = new Link_array<Request>;
1255         }
1256         | pre_requests open_request {
1257                 $$->push ($2);
1258         }
1259         ;
1260
1261 absolute_musical_pitch:
1262         steno_musical_pitch     {
1263                 $$ = $1;
1264         }
1265         ;
1266
1267 duration_length:
1268         steno_duration {
1269                 $$ = $1;
1270         }
1271         | duration_length '*' bare_unsigned {
1272                 $$->tuplet_iso_i_ *= $3;
1273         }
1274         | duration_length '/' bare_unsigned {
1275                 $$->tuplet_type_i_ *= $3;
1276         }
1277         ;
1278
1279 entered_notemode_duration:
1280         steno_duration  {
1281                 THIS->set_last_duration ($1);
1282         }
1283         ;
1284
1285 optional_notemode_duration:
1286         {
1287                 $$ = new Duration (THIS->default_duration_);
1288         }
1289         | entered_notemode_duration {
1290                 $$ = $1;
1291         }
1292         ;
1293
1294 steno_duration:
1295         bare_unsigned           {
1296                 $$ = new Duration;
1297                 if (!is_duration_b ($1))
1298                         THIS->parser_error (_f ("not a duration: %d", $1));
1299                 else {
1300                         $$->durlog_i_ = intlog2 ($1);
1301                      }
1302         }
1303         | DURATION_IDENTIFIER   {
1304                 $$ = $1->access_content_Duration (true);
1305         }
1306         | steno_duration '.'    {
1307                 $$->dots_i_ ++;
1308         }
1309         ;
1310
1311
1312 tremolo_type:
1313         ':'     {
1314                 $$ =0;
1315         }
1316         | ':' bare_unsigned {
1317                 if (!is_duration_b ($2))
1318                         THIS->parser_error (_f ("not a duration: %d", $2));
1319                 $$ = $2;
1320         }
1321         ;
1322
1323
1324 simple_element:
1325         musical_pitch exclamations questions optional_notemode_duration {
1326                 if (!THIS->lexer_p_->note_state_b ())
1327                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1328
1329
1330                 Note_req *n = new Note_req;
1331
1332                 n->pitch_ = *$1;
1333                 n->duration_ = *$4;
1334
1335                 n->cautionary_b_ = $3 % 2;
1336                 n->forceacc_b_ = $2 % 2 || n->cautionary_b_;
1337
1338
1339                 Simultaneous_music*v = new Request_chord (gh_list (n->self_scm (), SCM_UNDEFINED));
1340                 v->set_spot ($1->spot ());
1341                 n->set_spot ($1->spot ());
1342                 $$ = v;
1343
1344                 delete $1;
1345                 delete $4;
1346         }
1347         | RESTNAME optional_notemode_duration           {
1348
1349                 SCM e = SCM_UNDEFINED;
1350                   if (ly_scm2string ($1) =="s")
1351                     { /* Space */
1352                       Skip_req * skip_p = new Skip_req;
1353                       skip_p->duration_ = *$2;
1354
1355                       skip_p->set_spot (THIS->here_input());
1356                         e = skip_p->self_scm ();
1357                     }
1358                   else
1359                     {
1360                       Rest_req * rest_req_p = new Rest_req;
1361                       rest_req_p->duration_ = *$2;
1362                       rest_req_p->set_spot (THIS->here_input());
1363                         e = rest_req_p->self_scm ();
1364                     }
1365                   Simultaneous_music* velt_p = new Request_chord (gh_list (e,SCM_UNDEFINED));
1366                   velt_p->set_spot (THIS->here_input());
1367
1368                   delete $2; // ugh
1369                   $$ = velt_p;
1370         }
1371         | MEASURES optional_notemode_duration   {
1372                 Skip_req * sk = new Skip_req;
1373                 sk->duration_ = *$2;
1374
1375
1376                 Span_req *sp1 = new Span_req;
1377                 Span_req *sp2 = new Span_req;
1378                 sp1-> span_dir_ = START;
1379                 sp2-> span_dir_ = STOP;
1380                 sp1->span_type_str_ = sp2->span_type_str_ = "rest";
1381
1382                 Request_chord * rqc1 = new Request_chord (gh_list (sp1->self_scm (), SCM_UNDEFINED));
1383                 Request_chord * rqc2 = new Request_chord (gh_list (sk->self_scm (), SCM_UNDEFINED));;
1384                 Request_chord * rqc3 = new Request_chord(gh_list (sp2->self_scm (), SCM_UNDEFINED));;
1385
1386                 SCM ms = gh_list (rqc1->self_scm (), rqc2->self_scm (), rqc3->self_scm (), SCM_UNDEFINED);
1387
1388                 $$ = new Sequential_music (ms);
1389         }
1390         | STRING {
1391                 THIS->remember_spot ();
1392         }
1393         /* cont */
1394         optional_notemode_duration      {
1395                 if (!THIS->lexer_p_->lyric_state_b ()) {
1396                         THIS->pop_spot ().error (_ ("Have to be in Lyric mode for lyrics"));
1397                         THIS->error_level_i_  = 1;
1398                         THIS->parser_error (_ ("Giving up"));
1399                 }
1400                 else
1401                         THIS->pop_spot ();
1402                 Lyric_req* lreq_p = new Lyric_req;
1403                 lreq_p ->text_str_ = ly_scm2string ($1);
1404                 lreq_p->duration_ = *$3;
1405                 lreq_p->set_spot (THIS->here_input());
1406                 Simultaneous_music* velt_p = new Request_chord (gh_list (lreq_p->self_scm (), SCM_UNDEFINED));
1407
1408                 delete  $3; // ugh
1409                 $$= velt_p;
1410
1411         }
1412         | chord {
1413                 if (!THIS->lexer_p_->chord_state_b ())
1414                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
1415                 $$ = $1;
1416         }
1417         ;
1418
1419
1420 chord:
1421         steno_tonic_pitch optional_notemode_duration chord_additions chord_subtractions chord_inversion chord_bass {
1422                 $$ = get_chord (*$1, $3, $4, $5, $6, *$2);
1423                 $$->set_spot (THIS->here_input ());
1424         };
1425
1426 chord_additions:
1427         {
1428                 $$ = new Array<Musical_pitch>;
1429         }
1430         | CHORD_COLON chord_notes {
1431                 $$ = $2;
1432         }
1433         ;
1434
1435 chord_notes:
1436         chord_step {
1437                 $$ = $1
1438         }
1439         | chord_notes '.' chord_step {
1440                 $$ = $1;
1441                 $$->concat (*$3);
1442         }
1443         ;
1444
1445 chord_subtractions:
1446         {
1447                 $$ = new Array<Musical_pitch>;
1448         }
1449         | CHORD_CARET chord_notes {
1450                 $$ = $2;
1451         }
1452         ;
1453
1454
1455 chord_inversion:
1456         {
1457                 $$ = 0;
1458         }
1459         | '/' steno_tonic_pitch {
1460                 $$ = $2;
1461                 $$->set_spot (THIS->here_input ());
1462         }
1463         ;
1464
1465 chord_bass:
1466         {
1467                 $$ = 0;
1468         }
1469         | CHORD_BASS steno_tonic_pitch {
1470                 $$ = $2;
1471                 $$->set_spot (THIS->here_input ());
1472         }
1473         ;
1474
1475 chord_step:
1476         chord_note {
1477                 $$ = new Array<Musical_pitch>;
1478                 $$->push (*$1);
1479         }
1480         | CHORDMODIFIER_PITCH {
1481                 $$ = new Array<Musical_pitch>;
1482                 $$->push (*$1);
1483         }
1484         | CHORDMODIFIER_PITCH chord_note { /* Ugh. */
1485                 $$ = new Array<Musical_pitch>;
1486                 $$->push (*$1);
1487                 $$->push (*$2);
1488         }
1489         ;
1490
1491 chord_note:
1492         bare_unsigned {
1493                 $$ = new Musical_pitch;
1494                 $$->notename_i_ = ($1 - 1) % 7;
1495                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1496                 $$->accidental_i_ = 0;
1497         }
1498         | bare_unsigned '+' {
1499                 $$ = new Musical_pitch;
1500                 $$->notename_i_ = ($1 - 1) % 7;
1501                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1502                 $$->accidental_i_ = 1;
1503         }
1504         | bare_unsigned CHORD_MINUS {
1505                 $$ = new Musical_pitch;
1506                 $$->notename_i_ = ($1 - 1) % 7;
1507                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1508                 $$->accidental_i_ = -1;
1509         }
1510         ;
1511
1512 /*
1513         UTILITIES
1514  */
1515 number_expression:
1516         bare_number {
1517                 $$ = $1;
1518         }
1519         | '-'  number_expression %prec UNARY_MINUS {
1520                 $$ = scm_difference ($2, SCM_UNDEFINED);
1521         }
1522         | number_expression '*' number_expression {
1523                 $$ = scm_product ($1, $3);
1524         }
1525         | number_expression '/' number_expression {
1526                 $$ = scm_divide ($1, $3);
1527         }
1528         | number_expression '+' number_expression {
1529                 $$ = scm_sum ($1, $3);
1530         }
1531         | number_expression '-' number_expression {
1532                 $$ = scm_difference ($1, $3);
1533         }
1534         | '(' number_expression ')'     {
1535                 $$ = $2;
1536         }
1537         ;
1538
1539 bare_number:
1540         UNSIGNED        {
1541                 $$ = gh_int2scm ($1);
1542         }
1543         | DIGIT         {
1544                 $$ = gh_int2scm ($1);
1545         }
1546         | REAL          {
1547                 $$ = gh_double2scm ($1);
1548         }
1549         | NUMBER_IDENTIFIER             {
1550                 $$ = $1;
1551         }
1552         | REAL CM_T     {
1553                 $$ = gh_double2scm ($1 CM);
1554         }
1555         | REAL PT_T     {
1556                 $$ = gh_double2scm ($1 PT);
1557         }
1558         | REAL IN_T     {
1559                 $$ = gh_double2scm ($1 INCH);
1560         }
1561         | REAL MM_T     {
1562                 $$ = gh_double2scm ($1 MM);
1563         }
1564         | REAL CHAR_T   {
1565                 $$ = gh_double2scm ($1 CHAR);
1566         }
1567         ;
1568
1569
1570 bare_unsigned:
1571         bare_number {
1572                 if (scm_integer_p ($1) == SCM_BOOL_T) {
1573                         $$ = gh_scm2int ($1);
1574
1575                 } else {
1576                         THIS->parser_error (_("need integer number arg"));
1577                         $$ = 0;
1578                 }
1579                 if ($$ < 0) {
1580                         THIS->parser_error (_("Must be positive integer"));
1581                         $$ = -$$;
1582                         }
1583
1584         }
1585         ;
1586 bare_int:
1587         bare_number {
1588                 if (scm_integer_p ($1) == SCM_BOOL_T)
1589                 {
1590                         int k = gh_scm2int ($1);
1591                         $$ = k;
1592                 } else
1593                 {
1594                         THIS->parser_error (_("need integer number arg"));
1595                         $$ = 0;
1596                 }
1597         }
1598         | '-' bare_int {
1599                 $$ = -$2;
1600         }
1601         ;
1602
1603
1604 string:
1605         STRING          {
1606                 $$ = $1;
1607         }
1608         | STRING_IDENTIFIER     {
1609                 $$ = $1;
1610         }
1611         | string '+' string {
1612                 $$ = scm_string_append (scm_listify ($1, $3, SCM_UNDEFINED));
1613         }
1614         ;
1615
1616
1617 exclamations:
1618                 { $$ = 0; }
1619         | exclamations '!'      { $$ ++; }
1620         ;
1621
1622 questions:
1623                 { $$ = 0; }
1624         | questions '?' { $$ ++; }
1625         ;
1626
1627
1628 semicolon:
1629         ';'
1630         ;
1631
1632 %%
1633
1634 void
1635 My_lily_parser::set_yydebug (bool b)
1636 {
1637 #ifdef YYDEBUG
1638         yydebug = b;
1639 #endif
1640 }
1641 void
1642 My_lily_parser::do_yyparse ()
1643 {
1644         yyparse ((void*)this);
1645 }
1646
1647