lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for mudela
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 #include <iostream.h>
  13 #include "lily-guile.hh"
  14 #include "notename-table.hh"
  15 #include "scalar.hh"
  16 #include "translation-property.hh"
  17 #include "script-def.hh"
  18 #include "lookup.hh"
  19 #include "misc.hh"
  20 #include "my-lily-lexer.hh"
  21 #include "paper-def.hh"
  22 #include "midi-def.hh"
  23 #include "main.hh"
  24 #include "file-path.hh"
  25 #include "keyword.hh"
  26 #include "debug.hh"
  27 #include "parseconstruct.hh"
  28 #include "dimensions.hh"
  29 #include "identifier.hh"
  30 #include "command-request.hh"
  31 #include "musical-request.hh"
  32 #include "my-lily-parser.hh"
  33 #include "text-def.hh"
  34 #include "translator-group.hh"
  35 #include "score.hh"
  36 #include "music-list.hh"
  37 #include "duration-convert.hh"
  38 #include "change-translator.hh"
  39 #include "file-results.hh"
  40 #include "mudela-version.hh"
  41 #include "scope.hh"
  42 #include "relative-music.hh"
  43 #include "transposed-music.hh"
  44 #include "compressed-music.hh"
  45 #include "repeated-music.hh"
  46
  47 // mmm
  48 Mudela_version oldest_version ("1.0.14");
  49 Mudela_version version ("1.0.15");
  50
  51
  52 // needed for bison.simple's malloc() and free()
  53 #include <malloc.h>
  54
  55 struct Assignment {
  56         String *name_p_;
  57         Identifier *id_p_;
  58         ~Assignment () {
  59                 delete name_p_;
  60                 delete id_p_;
  61         }
  62         Assignment () {
  63                 name_p_ = 0;
  64                 id_p_ =0;
  65         }
  66         Assignment (Assignment const&s)
  67         {
  68                 name_p_ = new String (*s.name_p_);
  69                 id_p_ = s.id_p_->clone ();
  70         }
  71 };
  72
  73 Paper_def* current_paper = 0;
  74
  75 #ifndef NDEBUG
  76 #define YYDEBUG 1
  77 #endif
  78
  79 #define YYERROR_VERBOSE 1
  80
  81 #define YYPARSE_PARAM my_lily_parser_l
  82 #define YYLEX_PARAM my_lily_parser_l
  83 #define THIS ((My_lily_parser *) my_lily_parser_l)
  84
  85 #define yyerror THIS->parser_error
  86 #define ARRAY_SIZE(a,s)   if (a.size () != s) THIS->parser_error (_f("expecting %d arguments", s))
  87
  88 %}
  89
  90
  91 %union {
  92     Array<Interval>* intarr;
  93     Array<Musical_pitch> *pitch_arr;
  94     Link_array<Request> *reqvec;
  95     Array<String> * strvec;
  96     Array<int> *intvec;
  97     Notename_table *chordmodifiertab;
  98     Duration *duration;
  99     General_script_def * script;
 100     Identifier *id;
 101     Music *music;
 102     Music_list *music_list;
 103     Score *score;
 104     Scope *scope;
 105     Interval *interval;
 106     Musical_req* musreq;
 107     Music_output_def * outputdef;
 108     Musical_pitch * pitch;
 109     Midi_def* midi;
 110     Moment *moment;
 111     Note_req *notereq;
 112     Notename_table *notenametab;
 113     Paper_def *paper;
 114     Real real;
 115     Request * request;
 116     Scalar *scalar;
 117     Simultaneous_music *chord;
 118     String *string;
 119     Tempo_req *tempo;
 120     Text_def * textdef;
 121     Translator* trans;
 122     char c;
 123     const char *consstr;
 124     int i;
 125     int ii[10];
 126 }
 127 %{
 128
 129 int
 130 yylex (YYSTYPE *s,  void * v_l)
 131 {
 132         My_lily_parser   *pars_l = (My_lily_parser*) v_l;
 133         My_lily_lexer * lex_l = pars_l->lexer_p_;
 134
 135         lex_l->lexval_l = (void*) s;
 136         return lex_l->yylex ();
 137 }
 138
 139
 140 %}
 141
 142 %pure_parser
 143
 144 /* tokens which are not keywords */
 145
 146 %token ABSDYNAMIC
 147 %token ACCEPTS
 148 %token ALTERNATIVE
 149 %token BAR
 150 %token CADENZA
 151 %token CHORDMODIFIERS
 152 %token CHORDS
 153 %token CLEF
 154 %token CM_T
 155 %token CONSISTS
 156 %token DURATION
 157 %token EXTENDER
 158 %token FONT
 159 %token GROUPING
 160 %token HEADER
 161 %token IN_T
 162 %token KEY
 163 %token KEYSIGNATURE
 164 %token LYRICS
 165 %token MARK
 166 %token MEASURES
 167 %token MIDI
 168 %token MM_T
 169 %token MUSICAL_PITCH
 170 %token NAME
 171 %token NOTENAMES
 172 %token NOTES
 173 %token PAPER
 174 %token PARTIAL
 175 %token PENALTY
 176 %token PROPERTY
 177 %token PT_T
 178 %token RELATIVE
 179 %token REMOVE
 180 %token REPEAT
 181 %token SCM_T
 182 %token SCMFILE
 183 %token SCORE
 184 %token SCRIPT
 185 %token SHAPE
 186 %token SKIP
 187 %token SPANDYNAMIC
 188 %token TEMPO
 189 %token TIME_T
 190 %token TIMES
 191 %token TRANSLATOR
 192 %token TRANSPOSE
 193 %token TYPE
 194 %token VERSION
 195
 196 /* escaped */
 197 %token E_EXCLAMATION E_SMALLER E_BIGGER E_CHAR
 198
 199 %type <i>       dots
 200 %token <i>      DIGIT
 201 %token <pitch>  NOTENAME_PITCH
 202 %token <pitch>  TONICNAME_PITCH
 203 %token <pitch>  CHORDMODIFIER_PITCH
 204 %token <id>     DURATION_IDENTIFIER
 205 %token <id>     IDENTIFIER
 206 %token <id>     NOTENAME_TABLE_IDENTIFIER
 207 %token <id>     MUSIC_IDENTIFIER
 208 %token <id>     POST_REQUEST_IDENTIFIER
 209 %token <id>     SCRIPT_IDENTIFIER
 210 %token <id>     COMMAND_IDENTIFIER
 211 %token <id>     REAL_IDENTIFIER
 212 %token <id>     STRING_IDENTIFIER
 213 %token <id>     TRANS_IDENTIFIER
 214 %token <id>     INT_IDENTIFIER
 215 %token <id>     SCORE_IDENTIFIER
 216 %token <id>     MIDI_IDENTIFIER
 217 %token <id>     PAPER_IDENTIFIER
 218 %token <real>   REAL
 219 %token <string> DURATION RESTNAME
 220 %token <string> STRING
 221 %token <i>      UNSIGNED
 222
 223
 224 %type <outputdef> output_def
 225 %type <scope>   mudela_header mudela_header_body
 226 %type <request> open_request_parens close_request_parens open_request close_request
 227 %type <i>       sub_quotes sup_quotes
 228 %type <music>   simple_element  request_chord command_element Simple_music  Composite_music
 229 %type <music>   Alternative_music Repeated_music
 230 %type <i>       abbrev_type
 231 %type <i>       int unsigned
 232 %type <i>       script_dir
 233 %type <i>       optional_modality
 234 %type <id>      identifier_init simple_identifier_init block_identifier
 235 %type <duration> steno_duration notemode_duration
 236 %type <duration> entered_notemode_duration explicit_duration
 237 %type <intvec>  intastint_list int_list
 238 %type <reqvec>  pre_requests post_requests
 239
 240 %type <pitch>   explicit_musical_pitch steno_musical_pitch musical_pitch absolute_musical_pitch
 241 %type <pitch>   steno_tonic_pitch
 242 %type <notereq> steno_notepitch
 243 %type <pitch_arr>       pitch_list
 244 %type <music>   chord notemode_chord
 245 %type <pitch_arr>       chord_additions chord_subtractions chord_notes
 246 %type <pitch>   chord_addsub chord_note chord_inversion notemode_chord_inversion
 247 %type <midi>    midi_block midi_body
 248 %type <duration>        duration_length
 249
 250 %type <scalar>  scalar
 251 %type <music>   Music  relative_music Sequential_music Simultaneous_music
 252 %type <music>   property_def translator_change
 253 %type <music_list> Music_list
 254 %type <paper>   paper_block paper_def_body
 255 %type <real>    real_expression real dimension
 256 %type <request> abbrev_command_req
 257 %type <request> post_request structured_post_request
 258 %type <request> command_req verbose_command_req
 259 %type <request> script_req  dynamic_req extender_req
 260 %type <string>  string
 261 %type <score>   score_block score_body
 262 %type <intarr>  shape_array
 263 %type <script>  script_definition script_body mudela_script gen_script_def
 264 %type <textdef> text_def finger
 265 %type <string>  script_abbreviation
 266 %type <trans>   translator_spec translator_spec_body
 267 %type <tempo>   tempo_request
 268 %type <notenametab> notenames_body notenames_block chordmodifiers_block
 269
 270 %expect 7
 271
 272
 273 %left '-' '+'
 274 %left '*' '/'
 275 %left UNARY_MINUS
 276
 277 %%
 278
 279 mudela: /* empty */
 280         | mudela toplevel_expression {}
 281         | mudela assignment { }
 282         | mudela error
 283         | mudela check_version { }
 284         ;
 285
 286 toplevel_expression:
 287         notenames_block                 {
 288                 THIS->lexer_p_->set_notename_table ($1);
 289         }
 290         | chordmodifiers_block                  {
 291                 THIS->lexer_p_->set_chordmodifier_table ($1);
 292         }
 293         | mudela_header {
 294                 delete header_global_p;
 295                 header_global_p = $1;
 296         }
 297         | score_block {
 298                 score_global_array.push ($1);
 299         }
 300         | paper_block {
 301                 Identifier * id = new
 302                         Paper_def_identifier ($1, PAPER_IDENTIFIER);
 303                 THIS->lexer_p_->set_identifier ("$defaultpaper", id)
 304         }
 305         | midi_block {
 306                 Identifier * id = new
 307                         Midi_def_identifier ($1, MIDI_IDENTIFIER);
 308                 THIS->lexer_p_->set_identifier ("$defaultmidi", id)
 309         }
 310         | embedded_scm {
 311         }
 312         ;
 313
 314 embedded_scm:
 315         SCMFILE STRING ';' {
 316                 read_lily_scm_file (*$2);
 317                 delete $2;
 318         }
 319         | SCM_T STRING ';' {
 320                 gh_eval_str ($2->ch_l ());
 321                 delete $2;
 322         };
 323
 324 check_version:
 325         VERSION STRING ';'              {
 326                 Mudela_version ver (*$2);
 327                 if (!((ver >= oldest_version) && (ver <= version))) {
 328                         if (THIS->ignore_version_b_) {
 329                                 THIS->here_input ().error (_f ("incorrect mudela version: %s (%s, %s)", ver.str (), oldest_version.str (), version.str ()));
 330                         } else {
 331                                 THIS->fatal_error_i_ = 1;
 332                                 THIS->parser_error (_f ("incorrect mudela version: %s (%s, %s)", ver.str (), oldest_version.str (), version.str ()));
 333                         }
 334                 }
 335         }
 336         ;
 337
 338
 339 chordmodifiers_block:
 340         CHORDMODIFIERS '{' notenames_body '}'  {  $$ = $3; }
 341         ;
 342
 343
 344 notenames_block:
 345         NOTENAMES '{' notenames_body '}'  {  $$ = $3; }
 346         ;
 347
 348
 349
 350 notenames_body:
 351         /**/    {
 352                 $$ = new Notename_table;
 353         }
 354         | NOTENAME_TABLE_IDENTIFIER     {
 355                 $$ = $1-> access_content_Notename_table(true);
 356         }
 357         | notenames_body STRING '=' explicit_musical_pitch {
 358                 (*$$)[*$2] = *$4;
 359
 360                 delete $4;
 361                 delete $2;
 362         }
 363         ;
 364
 365 mudela_header_body:
 366         {
 367                 $$ = new Scope;
 368                 THIS->lexer_p_-> scope_l_arr_.push ($$);
 369         }
 370         | mudela_header_body assignment ';' {
 371
 372         }
 373         ;
 374
 375 mudela_header:
 376         HEADER '{' mudela_header_body '}'       {
 377                 $$ = $3;
 378                 THIS->lexer_p_-> scope_l_arr_.pop ();
 379         }
 380         ;
 381
 382
 383 /*
 384         DECLARATIONS
 385 */
 386 assignment:
 387         STRING {
 388                 THIS->remember_spot ();
 389         }
 390         /* cont */ '=' identifier_init  {
 391             THIS->lexer_p_->set_identifier (*$1, $4);
 392             $4->init_b_ = THIS->init_parse_b_;
 393             $4->set_spot (THIS->pop_spot ());
 394         }
 395         ;
 396
 397
 398 simple_identifier_init: identifier_init
 399         ;
 400
 401 identifier_init:
 402         block_identifier
 403         ;
 404
 405 block_identifier:
 406         score_block {
 407                 $$ = new Score_identifier ($1, SCORE_IDENTIFIER);
 408
 409         }
 410         | chordmodifiers_block {
 411                 $$ = new Notename_table_identifier ($1, NOTENAME_TABLE_IDENTIFIER);
 412         }
 413         | notenames_block {
 414                 $$ = new Notename_table_identifier ($1, NOTENAME_TABLE_IDENTIFIER);
 415         }
 416         | paper_block {
 417                 $$ = new Paper_def_identifier ($1, PAPER_IDENTIFIER);
 418         }
 419         | midi_block {
 420                 $$ = new Midi_def_identifier ($1, MIDI_IDENTIFIER);
 421
 422         }
 423         | translator_spec {
 424                 $$ = new Translator_identifier ($1, TRANS_IDENTIFIER);
 425         }
 426         | Music  {
 427                 $$ = new Music_identifier ($1, MUSIC_IDENTIFIER);
 428         }
 429
 430         | post_request {
 431                 $$ = new Request_identifier ($1, POST_REQUEST_IDENTIFIER);
 432         }
 433         | explicit_duration {
 434                 $$ = new Duration_identifier ($1, DURATION_IDENTIFIER);
 435         }
 436         | real {
 437                 $$ = new Real_identifier (new Real ($1), REAL_IDENTIFIER);
 438         }
 439         | string {
 440                 $$ = new String_identifier ($1, STRING_IDENTIFIER);
 441         }
 442         | int   {
 443                 $$ = new int_identifier (new int ($1), INT_IDENTIFIER);
 444         }
 445         | script_definition {
 446                 $$ = new General_script_def_identifier ($1, SCRIPT_IDENTIFIER);
 447
 448         }
 449         ;
 450
 451 translator_spec:
 452         TRANSLATOR '{' translator_spec_body '}'
 453                 { $$ = $3; }
 454         ;
 455
 456 translator_spec_body:
 457         TRANS_IDENTIFIER        {
 458                 $$ = $1->access_content_Translator (true);
 459                 $$-> set_spot (THIS->here_input ());
 460         }
 461         | TYPE STRING ';'       {
 462                 Translator* t = get_translator_l (*$2);
 463                 Translator_group * tg = dynamic_cast<Translator_group*> (t);
 464
 465                 if (!tg)
 466                         THIS->parser_error (_("Need a translator group for a context"));
 467
 468                 t = t->clone ();
 469                 t->set_spot (THIS->here_input ());
 470                 $$ = t;
 471                 delete $2;
 472         }
 473         | translator_spec_body STRING '=' simple_identifier_init ';'    {
 474                 Identifier* id = $4;
 475                 String_identifier *s = dynamic_cast<String_identifier*> (id);
 476                 Real_identifier *r= dynamic_cast<Real_identifier*>(id);
 477                 int_identifier *i = dynamic_cast<int_identifier*> (id);
 478
 479                 String str;
 480                 if (s) str = *s->access_content_String (false);
 481                 if (i) str = to_str (*i->access_content_int (false));
 482                 if (r) str = to_str (*r->access_content_Real (false));
 483                 if (!s && !i && !r)
 484                         THIS->parser_error (_("Wrong type for property value"));
 485
 486                 delete $4;
 487                 /* ugh*/
 488                 Translator_group * tr = dynamic_cast<Translator_group*>($$);
 489                 tr->set_property (*$2, str);
 490         }
 491         | translator_spec_body NAME STRING ';' {
 492                 $$->type_str_ = *$3;
 493                 delete $3;
 494         }
 495         | translator_spec_body CONSISTS STRING ';' {
 496                 dynamic_cast<Translator_group*> ($$)-> set_element (*$3, true);
 497                 delete $3;
 498         }
 499         | translator_spec_body ACCEPTS STRING ';' {
 500                 dynamic_cast<Translator_group*> ($$)-> set_acceptor (*$3, true);
 501                 delete $3;
 502         }
 503         | translator_spec_body REMOVE STRING ';' {
 504                 dynamic_cast<Translator_group*> ($$)-> set_element (*$3, false);
 505                 delete $3;
 506         }
 507         ;
 508
 509 /*
 510         SCORE
 511 */
 512 score_block:
 513         SCORE { THIS->remember_spot ();
 514         }
 515         /*cont*/ '{' score_body '}'     {
 516                 $$ = $4;
 517                 $$->set_spot (THIS->pop_spot ());
 518                 if (!$$->def_p_arr_.size ())
 519                         $$->add_output (THIS->default_paper_p ());
 520
 521         }
 522         ;
 523
 524 score_body:             {
 525                 $$ = new Score;
 526         }
 527         | SCORE_IDENTIFIER {
 528                 $$ = $1->access_content_Score (true);
 529         }
 530         | score_body mudela_header      {
 531                 $$->header_p_ = $2;
 532         }
 533         | score_body Music      {
 534                 if ($$->music_p_)
 535                         $2->warning (_ ("More than one music block"));
 536                 $$->music_p_ = $2;
 537         }
 538         | score_body output_def {
 539                 $$->add_output ($2);
 540         }
 541         | score_body error {
 542
 543         }
 544         ;
 545
 546 output_def:
 547         paper_block {
 548                 $$ = $1;
 549         }
 550         |  midi_block           {
 551                 $$= $1;
 552         }
 553         ;
 554
 555 intastint_list:
 556         /* */   { $$ =new Array<int>; }
 557         | intastint_list int '*' int    {
 558                 $$->push ($2); $$->push ($4);
 559         }
 560         | intastint_list int    {
 561                 $$->push ($2); $$->push (1);
 562         }
 563         ;
 564
 565
 566 /*
 567         PAPER
 568 */
 569 paper_block:
 570         PAPER '{' paper_def_body '}'    {
 571                 $$ = $3;
 572                 THIS-> lexer_p_->scope_l_arr_.pop ();
 573         }
 574         ;
 575
 576 optional_semicolon:
 577         /* empty */
 578         | ';'
 579         ;
 580
 581 optional_dot:
 582         /* empty */
 583         | '.'
 584         ;
 585
 586 paper_def_body:
 587         /* empty */                     {
 588                 Paper_def *p = THIS->default_paper_p ();
 589                 THIS-> lexer_p_-> scope_l_arr_.push (p->scope_p_);
 590                 $$ = p;
 591         }
 592         | PAPER_IDENTIFIER optional_semicolon   {
 593                 Paper_def *p = $1->access_content_Paper_def (true);
 594                 THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 595                 $$ = p;
 596         }
 597         | paper_def_body int '=' FONT STRING            { // ugh, what a syntax
 598                 Lookup * l = new Lookup;
 599                 l->font_name_ = *$5;
 600                 delete $5;
 601                 $$->set_lookup ($2, l);
 602         }
 603         | paper_def_body assignment ';' {
 604
 605         }
 606         | paper_def_body translator_spec {
 607                 $$->assign_translator ($2);
 608         }
 609         | paper_def_body SHAPE '=' shape_array ';' {
 610                 $$->shape_int_a_ = *$4;
 611                 delete $4;
 612         }
 613         | paper_def_body error {
 614
 615         }
 616         ;
 617
 618
 619 real:
 620         real_expression         { $$ = $1; }
 621         ;
 622
 623
 624 dimension:
 625         REAL CM_T       {
 626                 $$ = $1 CM;
 627         }
 628         | REAL PT_T     {
 629                 $$ = $1 PT;
 630         }
 631         | REAL IN_T     {
 632                 $$ = $1 INCH;
 633         }
 634         | REAL MM_T     {
 635                 $$ = $1 MM;
 636         }
 637         ;
 638
 639 real_expression:
 640         REAL            {
 641                 $$ = $1;
 642         }
 643         | dimension
 644         | REAL_IDENTIFIER               {
 645                 $$= *$1->access_content_Real (false);
 646         }
 647         | '-'  real_expression %prec UNARY_MINUS {
 648                 $$ = -$2;
 649         }
 650         | real_expression '*' real_expression {
 651                 $$ = $1 * $3;
 652         }
 653         | real_expression '/' real_expression {
 654                 $$ = $1 / $3;
 655         }
 656         | real_expression '+' real_expression {
 657                 $$ = $1  + $3;
 658         }
 659         | real_expression '-' real_expression {
 660                 $$ = $1 - $3;
 661         }
 662         | '(' real_expression ')'       {
 663                 $$ = $2;
 664         }
 665         ;
 666
 667
 668 shape_array:
 669         /* empty */ {
 670                 $$ = new Array<Interval>;
 671         }
 672         | shape_array real real {
 673                 $$->push(Interval($2, $2 + $3));
 674         };
 675
 676 /*
 677         MIDI
 678 */
 679 midi_block:
 680         MIDI
 681
 682         '{' midi_body '}'       { $$ = $3; }
 683         ;
 684
 685 midi_body: /* empty */          {
 686                 $$ = THIS->default_midi_p ();
 687         }
 688         | MIDI_IDENTIFIER       {
 689                 $$ = $1-> access_content_Midi_def (true);
 690         }
 691         | midi_body translator_spec     {
 692                 $$-> assign_translator ($2);
 693         }
 694         | midi_body tempo_request ';' {
 695                 $$->set_tempo ($2->dur_.length_mom (), $2->metronome_i_);
 696                 delete $2;
 697         }
 698         | midi_body error {
 699
 700         }
 701         ;
 702
 703 tempo_request:
 704         TEMPO steno_duration '=' unsigned       {
 705                 $$ = new Tempo_req;
 706                 $$->dur_ = *$2;
 707                 delete $2;
 708                 $$-> metronome_i_ = $4;
 709         }
 710         ;
 711
 712 Music_list: /* empty */ {
 713                 $$ = new Music_list;
 714         }
 715         | Music_list Music {
 716                 $$->add_music ($2);
 717         }
 718         | Music_list error {
 719         }
 720         ;
 721
 722
 723 Music:
 724         Simple_music
 725         | Composite_music
 726         ;
 727
 728 Alternative_music: {
 729                 Music_list* m = new Music_list;
 730                 $$ = new Sequential_music (m);
 731         }
 732         | ALTERNATIVE Simultaneous_music {
 733                 $$ = $2;
 734         }
 735         | ALTERNATIVE Sequential_music {
 736                 $$ = $2;
 737         }
 738         ;
 739
 740 Repeated_music: REPEAT unsigned Music Alternative_music {
 741                 Music_sequence* m = dynamic_cast <Music_sequence*> ($4);
 742                 assert (m);
 743                 $$ = new Repeated_music ($3, $2 >? 1, m);
 744         }
 745         ;
 746
 747 Sequential_music: '{' Music_list '}'            {
 748                 $$ = new Sequential_music ($2);
 749         }
 750         ;
 751
 752 Simultaneous_music: '<' Music_list '>'  {
 753                 $$ = new Simultaneous_music ($2);
 754         }
 755         ;
 756
 757 Simple_music:
 758         request_chord           { $$ = $1; }
 759         | MUSIC_IDENTIFIER { $$ = $1->access_content_Music (true); }
 760         | property_def
 761         | translator_change
 762         | Simple_music '*' unsigned '/' unsigned        {
 763                 /* urg */
 764                 $$ = new Compressed_music ($3, $5, $1);
 765         }
 766         | Simple_music '*' unsigned              {
 767                 $$ = new Compressed_music ($3, 1, $1);
 768         }
 769         ;
 770
 771
 772 Composite_music:
 773         TYPE STRING Music       {
 774                 $$ = $3;
 775                 $$->translator_type_str_ = *$2;
 776                 delete $2;
 777         }
 778         | TYPE STRING '=' STRING Music {
 779                 $$ = $5;
 780                 $$->translator_type_str_ = *$2;
 781                 $$->translator_id_str_ = *$4;
 782                 delete $2;
 783                 delete $4;
 784         }
 785         | TIMES {
 786                 THIS->remember_spot ();
 787         }
 788         /* CONTINUED */
 789                 unsigned '/' unsigned Music
 790
 791         {
 792                 $$ = new Compressed_music ($3, $5, $6);
 793                 $$->set_spot (THIS->pop_spot ());
 794         }
 795         | Repeated_music                { $$ = $1; }
 796         | Simultaneous_music            { $$ = $1; }
 797         | Sequential_music              { $$ = $1; }
 798         | TRANSPOSE musical_pitch Music {
 799                 $$ = new Transposed_music ($3, *$2);
 800                 delete $2;
 801         }
 802         | TRANSPOSE steno_tonic_pitch Music {
 803                 $$ = new Transposed_music ($3, *$2);
 804                 delete $2;
 805         }
 806         | NOTES
 807                 { THIS->lexer_p_->push_note_state (); }
 808         Music
 809                 { $$ = $3;
 810                   THIS->lexer_p_->pop_state ();
 811                 }
 812         | CHORDS
 813                 { THIS->lexer_p_->push_chord_state (); }
 814         Music
 815                 {
 816                   $$ = $3;
 817                   THIS->lexer_p_->pop_state ();
 818         }
 819         | LYRICS
 820                 { THIS->lexer_p_->push_lyric_state (); }
 821         Music
 822                 {
 823                   $$ = $3;
 824                   THIS->lexer_p_->pop_state ();
 825         }
 826         | relative_music        { $$ = $1; }
 827         ;
 828
 829 relative_music:
 830         RELATIVE absolute_musical_pitch Music {
 831                 $$ = new Relative_octave_music ($3, *$2);
 832                 delete $2;
 833         }
 834         ;
 835
 836 translator_change:
 837         TRANSLATOR STRING '=' STRING  {
 838                 Change_translator * t = new Change_translator;
 839                 t-> change_to_type_str_ = *$2;
 840                 t-> change_to_id_str_ = *$4;
 841
 842                 $$ = t;
 843                 $$->set_spot (THIS->here_input ());
 844                 delete $2;
 845                 delete $4;
 846         }
 847         ;
 848
 849 property_def:
 850         PROPERTY STRING '.' STRING '=' scalar   {
 851                 Translation_property *t = new Translation_property;
 852                 t-> translator_type_str_ = *$2;
 853                 t-> var_str_ = *$4;
 854                 t-> value_ = *$6;
 855                 $$ = t;
 856                 $$->set_spot (THIS->here_input ());
 857                 delete $2;
 858                 delete $4;
 859                 delete $6;
 860         }
 861         ;
 862
 863 scalar:
 864         STRING          { $$ = new Scalar (*$1); delete $1; }
 865         | int           { $$ = new Scalar ($1); }
 866         ;
 867
 868
 869 request_chord:
 870         pre_requests simple_element post_requests       {
 871                 Music_sequence *l = dynamic_cast<Music_sequence*>($2);
 872                 for (int i=0; i < $1->size(); i++)
 873                         l->add_music ($1->elem(i));
 874                 for (int i=0; i < $3->size(); i++)
 875                         l->add_music ($3->elem(i));
 876                 $$ = $2;
 877
 878         }
 879         | command_element
 880         ;
 881
 882 command_element:
 883         command_req {
 884                 $$ = new Request_chord;
 885                 $$-> set_spot (THIS->here_input ());
 886                 $1-> set_spot (THIS->here_input ());
 887                 ((Simultaneous_music*)$$) ->add_music ($1);//ugh
 888         }
 889         ;
 890
 891 command_req:
 892         abbrev_command_req
 893         | verbose_command_req ';'       { $$ = $1; }
 894         ;
 895
 896 abbrev_command_req:
 897         extender_req {
 898                 $$ = $1;
 899         }
 900         | '|'                           {
 901                 $$ = new Barcheck_req;
 902         }
 903         | COMMAND_IDENTIFIER    {
 904                 $$ = $1->access_content_Request (true);
 905         }
 906         | '~'   {
 907                 $$ = new Tie_req;
 908         }
 909         | '['           {
 910                 Beam_req*b= new Beam_req;
 911                 b->spantype_ = START;
 912                 $$ =b;
 913         }
 914         | ']'           {
 915                 Beam_req*b= new Beam_req;
 916                 b->spantype_ = STOP;
 917                 $$ = b;
 918         }
 919         ;
 920
 921
 922 verbose_command_req:
 923         BAR STRING                      {
 924                 $$ = new Bar_req (*$2);
 925                 delete $2;
 926         }
 927         | MARK STRING {
 928                 $$ = new Mark_req (*$2);
 929                 delete $2;
 930         }
 931         | MARK unsigned {
 932                 $$ = new Mark_req (to_str ($2));
 933         }
 934         | TIME_T unsigned '/' unsigned  {
 935                 Time_signature_change_req *m = new Time_signature_change_req;
 936                 m->beats_i_ = $2;
 937                 m->one_beat_i_=$4;
 938                 $$ = m;
 939         }
 940         | PENALTY '=' int       {
 941                 Break_req * b = new Break_req;
 942                 b->penalty_i_ = $3;
 943                 b-> set_spot (THIS->here_input ());
 944                 $$ = b;
 945         }
 946         | SKIP duration_length {
 947                 Skip_req * skip_p = new Skip_req;
 948                 skip_p->duration_ = *$2;
 949                 delete $2;
 950                 $$ = skip_p;
 951         }
 952         | tempo_request {
 953                 $$ = $1;
 954         }
 955         | CADENZA unsigned      {
 956                 $$ = new Cadenza_req ($2);
 957         }
 958         | PARTIAL duration_length       {
 959                 $$ = new Partial_measure_req ($2->length_mom ());
 960                 delete $2;
 961         }
 962         | CLEF STRING {
 963                 $$ = new Clef_change_req (*$2);
 964                 delete $2;
 965         }
 966         | KEY NOTENAME_PITCH optional_modality  {
 967                 Key_change_req *key_p= new Key_change_req;
 968                 key_p->pitch_arr_.push(*$2);
 969                 key_p->ordinary_key_b_ = true;
 970                 key_p->modality_i_ = $3;
 971                 $$ = key_p;
 972                 delete $2;
 973         }
 974         | KEYSIGNATURE pitch_list       {
 975                 Key_change_req *key_p= new Key_change_req;
 976                 key_p->pitch_arr_ = *$2;
 977                 key_p->ordinary_key_b_ = false;
 978                 $$ = key_p;
 979                 delete $2;
 980         }
 981         | GROUPING intastint_list {
 982                 $$ = get_grouping_req (*$2); delete $2;
 983         }
 984         ;
 985
 986 post_requests:
 987         {
 988                 $$ = new Link_array<Request>;
 989         }
 990         | post_requests structured_post_request {
 991                 $2->set_spot (THIS->here_input ());
 992                 $$->push ($2);
 993         }
 994         | post_requests close_request   {
 995                 $$->push ($2);
 996         }
 997         ;
 998
 999 structured_post_request:
1000         script_req
1001         | post_request
1002         ;
1003
1004 post_request:
1005         POST_REQUEST_IDENTIFIER {
1006                 $$ = (Request*)$1->access_content_Request (true);
1007         }
1008         | dynamic_req {
1009                 $$ = $1;
1010         }
1011         | abbrev_type   {
1012                 Abbreviation_req* a = new Abbreviation_req;
1013                 a->type_i_ = $1;
1014                 $$ = a;
1015         }
1016
1017         ;
1018
1019 optional_modality:
1020         /* empty */     {
1021                 $$ = 0;
1022         }
1023         | int   {
1024                 $$ = $1;
1025         }
1026         ;
1027
1028 sup_quotes:
1029         '\'' {
1030                 $$ = 1;
1031         }
1032         | sup_quotes '\'' {
1033                 $$ ++;
1034         }
1035         ;
1036
1037 sub_quotes:
1038         ',' {
1039                 $$ = 1;
1040         }
1041         | sub_quotes ',' {
1042                 $$ ++ ;
1043         }
1044         ;
1045
1046 steno_musical_pitch:
1047         NOTENAME_PITCH  {
1048                 $$ = $1;
1049         }
1050         | NOTENAME_PITCH sup_quotes     {
1051                 $$ = $1;
1052                 $$->octave_i_ +=  $2;
1053         }
1054         | NOTENAME_PITCH sub_quotes      {
1055                 $$ = $1;
1056                 $$->octave_i_ += - $2;
1057         }
1058         ;
1059
1060 steno_tonic_pitch:
1061         TONICNAME_PITCH {
1062                 $$ = $1;
1063         }
1064         | TONICNAME_PITCH sup_quotes    {
1065                 $$ = $1;
1066                 $$->octave_i_ +=  $2;
1067         }
1068         | TONICNAME_PITCH sub_quotes     {
1069                 $$ = $1;
1070                 $$->octave_i_ += - $2;
1071         }
1072         ;
1073
1074 explicit_musical_pitch:
1075         MUSICAL_PITCH '{' int_list '}'  {/* ugh */
1076                 Array<int> &a = *$3;
1077                 ARRAY_SIZE(a,3);
1078                 $$ = new Musical_pitch;
1079                 $$->octave_i_ = a[0];
1080                 $$->notename_i_ = a[1];
1081                 $$->accidental_i_ = a[2];
1082                 delete &a;
1083         }
1084         ;
1085
1086 musical_pitch:
1087         steno_musical_pitch
1088         | explicit_musical_pitch
1089         ;
1090
1091 steno_notepitch:
1092         musical_pitch   {
1093                 $$ = new Note_req;
1094
1095                 $$->pitch_ = *$1;
1096                 delete $1;
1097         }
1098         | steno_notepitch  '!'          {
1099                 $$->forceacc_b_ = ! $$->forceacc_b_;
1100         }
1101         | steno_notepitch  '?'          {
1102                 $$->forceacc_b_ = ! $$->forceacc_b_;
1103                 $$->cautionary_b_ = ! $$->cautionary_b_;
1104         }
1105         ;
1106
1107
1108 explicit_duration:
1109         DURATION '{' int_list '}'       {
1110                 $$ = new Duration;
1111                 Array<int> &a = *$3;
1112                 ARRAY_SIZE(a,2);
1113
1114                 $$-> durlog_i_ = a[0];
1115                 $$-> dots_i_ = a[1];
1116
1117                 delete &a;
1118         }
1119         ;
1120
1121 extender_req:
1122         EXTENDER {
1123                 if (!THIS->lexer_p_->lyric_state_b ())
1124                         THIS->parser_error (_ ("have to be in Lyric mode for lyrics"));
1125                 $$ = new Extender_req;
1126         }
1127         ;
1128
1129 dynamic_req:
1130         ABSDYNAMIC '{' STRING '}'       {
1131                 Absolute_dynamic_req *ad_p = new Absolute_dynamic_req;
1132                 ad_p ->loudness_str_ = *$3;
1133                 delete $3;
1134                 $$ =ad_p;
1135         }
1136         | SPANDYNAMIC '{' int int '}' {
1137                 Span_dynamic_req * sp_p = new Span_dynamic_req;
1138                 sp_p-> dynamic_dir_  = Direction($3);
1139                 sp_p->spantype_ = Direction($4);
1140                 $$ = sp_p;
1141         }
1142         ;
1143
1144
1145 close_request:
1146         close_request_parens {
1147                 $$ = $1;
1148                 dynamic_cast<Span_req*> ($$)->spantype_ = START;
1149         }
1150
1151 close_request_parens:
1152         '('     {
1153                 $$= new Slur_req;
1154         }
1155         | E_SMALLER {
1156                 Span_dynamic_req*s =new Span_dynamic_req;
1157                 $$ = s;
1158                 s->dynamic_dir_ = SMALLER;
1159         }
1160         | E_BIGGER {
1161                 Span_dynamic_req*s =new Span_dynamic_req;
1162                 $$ = s;
1163                 s->dynamic_dir_ = BIGGER;
1164         }
1165         ;
1166
1167
1168 open_request:
1169         open_request_parens {
1170                 $$ = $1;
1171                 dynamic_cast<Span_req*> ($$)->spantype_ = STOP;
1172         }
1173         ;
1174
1175 open_request_parens:
1176         E_EXCLAMATION   {
1177                 Span_dynamic_req *s =  new Span_dynamic_req;
1178                 s->dynamic_dir_ = SMALLER;
1179                 $$ = s;
1180
1181         }
1182         | ')'   {
1183                 $$= new Slur_req
1184         }
1185         ;
1186
1187
1188
1189 script_definition:
1190         SCRIPT '{' script_body '}'      { $$ = $3; }
1191         ;
1192
1193 script_body:
1194         STRING int int int int int              {
1195                 Script_def *s = new Script_def;
1196                 s->set_from_input (*$1,$2, $3,$4,$5, $6);
1197                 $$  = s;
1198                 delete $1;
1199         }
1200         ;
1201
1202 script_req:
1203         script_dir gen_script_def       {
1204                 Musical_script_req *m = new Musical_script_req;
1205                 $$ = m;
1206                 m->scriptdef_p_ = $2;
1207                 m->set_spot (THIS->here_input ());
1208                 if (!m->dir_)
1209                   m->dir_  = (Direction)$1;
1210         }
1211         ;
1212
1213 gen_script_def:
1214         text_def        {
1215                 $$ = $1;
1216                 ((Text_def*) $$)->align_dir_ = LEFT; /* UGH */
1217         }
1218         | mudela_script {
1219                 $$ = $1;
1220                 $$-> set_spot (THIS->here_input ());
1221         }
1222         | finger {
1223                 $$ = $1;
1224                 ((Text_def*)$$)->align_dir_ = RIGHT; /* UGH */
1225         }
1226         ;
1227
1228 text_def:
1229         string {
1230                 Text_def *t  = new Text_def;
1231                 $$ = t;
1232                 t->text_str_ = *$1;
1233                 delete $1;
1234                 $$->set_spot (THIS->here_input ());
1235         }
1236         ;
1237
1238 finger:
1239          DIGIT {
1240                 Text_def* t  = new Text_def;
1241                 $$ = t;
1242                 t->text_str_ = to_str ($1);
1243                 t->style_str_ = "finger";
1244                 $$->set_spot (THIS->here_input ());
1245         }
1246         ;
1247
1248 script_abbreviation:
1249         '^'             { $$ = get_scriptdef ('^'); }
1250         | '+'           { $$ = get_scriptdef ('+'); }
1251         | '-'           { $$ = get_scriptdef ('-'); }
1252         | '|'           { $$ = get_scriptdef ('|'); }
1253         | 'o'           { $$ = get_scriptdef ('o'); }
1254         | '>'           { $$ = get_scriptdef ('>'); }
1255         | '.'           {
1256                 $$ = get_scriptdef ('.');
1257         }
1258         ;
1259
1260 mudela_script:
1261         SCRIPT_IDENTIFIER               { $$ = $1->access_content_General_script_def (true); }
1262         | script_definition             { $$ = $1; }
1263         | script_abbreviation           {
1264                 $$ = THIS->lexer_p_->lookup_identifier (*$1)->access_content_General_script_def (true);
1265                 delete $1;
1266         }
1267         ;
1268
1269 script_dir:
1270         '_'     { $$ = -1; }
1271         | '^'   { $$ = 1; }
1272         | '-'   { $$ = 0; }
1273         ;
1274
1275 pre_requests:
1276         {
1277                 $$ = new Link_array<Request>;
1278         }
1279         | pre_requests open_request {
1280                 $$->push ($2);
1281         }
1282         ;
1283
1284 absolute_musical_pitch:
1285         steno_musical_pitch     {
1286                 $$ = $1;
1287         }
1288         ;
1289
1290 duration_length:
1291         steno_duration {
1292                 $$ = $1;
1293         }
1294         | duration_length '*' unsigned {
1295                 $$->plet_.iso_i_ *= $3;
1296         }
1297         | duration_length '/' unsigned {
1298                 $$->plet_.type_i_ *= $3;
1299         }
1300         ;
1301
1302 dots:
1303         '.'             { $$ = 1; }
1304         | dots '.'      { $$ ++; }
1305         ;
1306
1307 entered_notemode_duration:
1308         /* */           {
1309                 $$ = new Duration (THIS->default_duration_);
1310         }
1311         | dots          {
1312                 $$ = new Duration (THIS->default_duration_);
1313                 $$->dots_i_  = $1;
1314         }
1315         | steno_duration        {
1316                 THIS->set_last_duration ($1);
1317         }
1318         ;
1319
1320 notemode_duration:
1321         entered_notemode_duration {
1322                 $$ = $1;
1323         }
1324         ;
1325
1326 steno_duration:
1327         unsigned                {
1328                 $$ = new Duration;
1329                 if (!Duration::duration_type_b ($1))
1330                         THIS->parser_error (_f ("not a duration: %d", $1));
1331                 else {
1332                         $$->durlog_i_ = Duration_convert::i2_type ($1);
1333                      }
1334         }
1335         | DURATION_IDENTIFIER   {
1336                 $$ = $1->access_content_Duration (true);
1337         }
1338         | steno_duration '.'    {
1339                 $$->dots_i_ ++;
1340         }
1341         ;
1342
1343
1344 abbrev_type:
1345         ':'     {
1346                 $$ =0;
1347         }
1348         | ':' unsigned {
1349                 if (!Duration::duration_type_b ($2))
1350                         THIS->parser_error (_f ("not a duration: %d", $2));
1351                 else if ($2 < 8)
1352                         THIS->parser_error (_ ("can't abbreviate"));
1353                 $$ = $2;
1354         }
1355         ;
1356
1357
1358
1359 simple_element:
1360         steno_notepitch notemode_duration  {
1361                 if (!THIS->lexer_p_->note_state_b ())
1362                         THIS->parser_error (_ ("have to be in Note mode for notes"));
1363                 $1->duration_ = *$2;
1364                 $$ = THIS->get_note_element ($1, $2);
1365         }
1366         | RESTNAME notemode_duration            {
1367                 $$ = THIS->get_rest_element (*$1, $2);
1368                 delete $1;  // delete notename
1369         }
1370         | MEASURES notemode_duration    {
1371                 Multi_measure_rest_req* m = new Multi_measure_rest_req;
1372                 m->duration_ = *$2;
1373                 delete $2;
1374
1375                 Simultaneous_music*velt_p = new Request_chord;
1376                 velt_p->set_spot (THIS->here_input ());
1377                 velt_p->add_music (m);
1378                 $$ = velt_p;
1379         }
1380         | STRING notemode_duration                      {
1381                 if (!THIS->lexer_p_->lyric_state_b ())
1382                         THIS->parser_error (_ ("have to be in Lyric mode for lyrics"));
1383                 $$ = THIS->get_word_element (*$1, $2);
1384                 delete $1;
1385         }
1386         | chord {
1387                 if (!THIS->lexer_p_->chord_state_b ())
1388                         THIS->parser_error (_ ("have to be in Chord mode for chords"));
1389                 $$ = $1;
1390         }
1391         | '@' notemode_chord '@' {
1392                 if (!THIS->lexer_p_->note_state_b ())
1393                         THIS->parser_error (_ ("have to be in Note mode for @chords"));
1394                 $$ = $2;
1395         }
1396         ;
1397
1398 chord:
1399         steno_tonic_pitch notemode_duration chord_additions chord_subtractions chord_inversion {
1400                 $$ = THIS->get_chord (*$1, $3, $4, $5, *$2);
1401         };
1402
1403 notemode_chord:
1404         steno_musical_pitch notemode_duration chord_additions chord_subtractions notemode_chord_inversion {
1405                 $$ = THIS->get_chord (*$1, $3, $4, $5, *$2);
1406         };
1407
1408 chord_additions:
1409         {
1410                 $$ = new Array<Musical_pitch>;
1411         }
1412         | '-' chord_notes {
1413                 $$ = $2;
1414         }
1415         ;
1416
1417 chord_notes:
1418         {
1419                 $$ = new Array<Musical_pitch>;
1420         }
1421         | chord_notes chord_addsub {
1422                 $$ = $1;
1423                 $$->push (*$2);
1424         }
1425         ;
1426
1427 chord_addsub:
1428         chord_note optional_dot
1429         | CHORDMODIFIER_PITCH optional_dot
1430         ;
1431
1432 chord_inversion:
1433         {
1434                 $$ = 0;
1435         }
1436         | '/' steno_tonic_pitch {
1437                 $$ = $2
1438         }
1439         ;
1440
1441 notemode_chord_inversion:
1442         {
1443                 $$ = 0;
1444         }
1445         | '/' steno_musical_pitch {
1446                 $$ = $2
1447         }
1448         ;
1449
1450 chord_note:
1451         unsigned {
1452                 $$ = new Musical_pitch;
1453                 $$->notename_i_ = ($1 - 1) % 7;
1454                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1455                 $$->accidental_i_ = 0;
1456         }
1457         | unsigned '+' {
1458                 $$ = new Musical_pitch;
1459                 $$->notename_i_ = ($1 - 1) % 7;
1460                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1461                 $$->accidental_i_ = 1;
1462         }
1463         | unsigned '-' {
1464                 $$ = new Musical_pitch;
1465                 $$->notename_i_ = ($1 - 1) % 7;
1466                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1467                 $$->accidental_i_ = -1;
1468         }
1469         ;
1470
1471 chord_subtractions:
1472         {
1473                 $$ = new Array<Musical_pitch>;
1474         }
1475         | '^' chord_notes {
1476                 $$ = $2;
1477         }
1478         ;
1479
1480 /*
1481         UTILITIES
1482  */
1483 pitch_list:                     {
1484                 $$ = new Array<Musical_pitch>;
1485         }
1486         | pitch_list musical_pitch      {
1487                 $$->push (*$2);
1488                 delete $2;
1489         }
1490         ;
1491
1492
1493 int_list:
1494         /**/                    {
1495                 $$ = new Array<int>
1496         }
1497         | int_list int          {
1498                 $$->push ($2);
1499         }
1500         ;
1501
1502 unsigned:
1503         UNSIGNED        {
1504                 $$ = $1;
1505         }
1506         | DIGIT {
1507                 $$ = $1;
1508         };
1509
1510 int:
1511         unsigned {
1512                 $$ = $1;
1513         }
1514         | '-' unsigned {
1515                 $$ = -$2;
1516         }
1517         | INT_IDENTIFIER        {
1518                 $$ = *$1->access_content_int (false);
1519         }
1520         ;
1521
1522
1523 string:
1524         STRING          {
1525                 $$ = $1;
1526         }
1527         | STRING_IDENTIFIER     {
1528                 $$ = $1->access_content_String (true);
1529         }
1530         | string '+' string {
1531                 *$$ += *$3;
1532                 delete $3;
1533         }
1534         ;
1535
1536
1537
1538
1539
1540
1541 %%
1542
1543 void
1544 My_lily_parser::set_yydebug (bool b)
1545 {
1546 #ifdef YYDEBUG
1547         yydebug = b;
1548 #endif
1549 }
1550 void
1551 My_lily_parser::do_yyparse ()
1552 {
1553         yyparse ((void*)this);
1554 }
1555
1556