lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29 #include "context-def.hh"
  30 #include "dimensions.hh"
  31 #include "event.hh"
  32 #include "file-path.hh"
  33 #include "input-smob.hh"
  34 #include "input.hh"
  35 #include "lily-guile.hh"
  36 #include "lilypond-input-version.hh"
  37 #include "ly-module.hh"
  38 #include "main.hh"
  39 #include "midi-def.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "paper-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84
  85
  86 bool
  87 is_regular_identifier (SCM id)
  88 {
  89   String str = ly_scm2string (id);
  90   char const *s = str.to_str0 ();
  91
  92   bool v = true;
  93 #if 0
  94   isalpha (*s);
  95   s++;
  96 #endif
  97   while (*s && v)
  98    {
  99         v = v && isalnum (*s);
 100         s++;
 101    }
 102   return v;
 103 }
 104
 105 SCM
 106 make_simple_markup (SCM encoding, SCM a)
 107 {
 108         SCM simple = ly_scheme_function ("simple-markup");
 109         if (ly_c_symbol_p (encoding))
 110                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 111                            encoding, a);
 112         return scm_list_2 (simple, a);
 113 }
 114
 115 bool
 116 is_duration (int t)
 117 {
 118   return t && t == 1 << intlog2 (t);
 119 }
 120
 121 void
 122 set_music_properties (Music *p, SCM a)
 123 {
 124   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 125         p->internal_set_property (ly_caar (k), ly_cdar (k));
 126 }
 127
 128 SCM
 129 make_chord_step (int step, int alter)
 130 {
 131         if (step == 7)
 132                 alter += FLAT;
 133
 134         while (step < 0)
 135                 step += 7;
 136         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 137         return m.smobbed_copy ();
 138 }
 139
 140
 141 SCM
 142 make_chord (SCM pitch, SCM dur, SCM modification_list)
 143 {
 144         SCM chord_ctor = ly_scheme_function ("construct-chord");
 145         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 146         scm_gc_protect_object (ch);
 147         return ch;
 148 }
 149
 150 /* Todo: actually also use apply iso. call too ...  */
 151 bool
 152 ly_input_procedure_p (SCM x)
 153 {
 154         return ly_c_procedure_p (x)
 155                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 156 }
 157
 158 Music*
 159 set_property_music (SCM sym, SCM value)
 160 {
 161         Music *p = MY_MAKE_MUSIC ("PropertySet");
 162         p->set_property ("symbol", sym);
 163         p->set_property ("value", value);
 164         return p;
 165 }
 166
 167 %}
 168
 169 /* We use SCMs to do strings, because it saves us the trouble of
 170 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 171 of the parse stack onto the heap. */
 172
 173
 174 %union {
 175         Book *book;
 176         Music_output_def *outputdef;
 177         SCM scm;
 178         String *string;
 179         Music *music;
 180         Score *score;
 181         int i;
 182 }
 183 %{
 184
 185 int
 186 yylex (YYSTYPE *s, void *v)
 187 {
 188         My_lily_parser *pars = (My_lily_parser*) v;
 189         My_lily_lexer *lex = pars->lexer_;
 190
 191         lex->lexval = (void*) s;
 192         lex->prepare_for_next_token ();
 193         return lex->yylex ();
 194 }
 195
 196
 197 %}
 198
 199 %expect 4
 200
 201 /*
 202   Four shift/reduce problems:
 203
 204 1.      foo = bar.
 205
 206         "bar" -> String -> Lyric -> Music -> music-assignment
 207
 208         "bar" -> String -> string-assignment
 209
 210
 211 Similar problem for
 212
 213 2. \markup identifier.
 214
 215 3. \markup { }
 216
 217 4.  \repeat
 218         \repeat .. \alternative
 219
 220
 221     \repeat { \repeat .. \alternative }
 222
 223 or
 224
 225     \repeat { \repeat } \alternative
 226
 227 )
 228
 229 --hwn
 230
 231  */
 232
 233
 234 %pure_parser
 235
 236 %token ACCEPTS
 237 %token ADDLYRICS
 238 %token ADDQUOTE
 239 %token NEWADDLYRICS
 240 %token ALIAS
 241 %token ALTERNATIVE
 242 %token APPLY
 243 %token APPLYCONTEXT
 244 %token APPLYOUTPUT
 245 %token AUTOCHANGE
 246 %token BAR
 247 %token BOOK
 248 %token BREATHE
 249 %token CHANGE
 250 %token CHORDMODIFIERS
 251 %token CHORDS
 252 %token LESSLESS
 253 %token MOREMORE
 254 %token CLEF
 255 %token COMMANDSPANREQUEST
 256 %token CONSISTS
 257 %token CONSISTSEND
 258 %token CONTEXT
 259 %token DEFAULT
 260 %token DENIES
 261 %token DESCRIPTION
 262 %token EXTENDER
 263 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 264 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 265 %token GRACE
 266 %token ACCIACCATURA
 267 %token APPOGGIATURA
 268 %token GROBDESCRIPTIONS
 269 %token HEADER
 270 %token HYPHEN
 271 %token INVALID
 272 %token KEY
 273 %token LYRICS
 274 %token MARK
 275 %token MIDI
 276 %token MULTI_MEASURE_REST
 277 %token NAME
 278 %token NEWCONTEXT
 279 %token NOTES
 280 %token OCTAVE
 281 %token ONCE
 282 %token OVERRIDE SET REVERT
 283 %token PAPER
 284 %token PARTCOMBINE
 285 %token PARTIAL
 286 %token QUOTE
 287 %token RELATIVE
 288 %token REMOVE
 289 %token REPEAT
 290 %token REST
 291 %token SCM_T
 292 %token SCORE
 293 %token SEQUENTIAL
 294 %token SIMULTANEOUS
 295 %token SKIP
 296 %token SPANREQUEST
 297 %token TAG
 298 %token TEMPO
 299 %token TIMES
 300 %token TIME_T
 301 %token TRANSPOSE
 302 %token TRANSPOSITION
 303 %token TYPE
 304 %token UNSET
 305 %token WITH
 306
 307 /* escaped */
 308 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 309 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 310 %token E_BACKSLASH
 311 %token <i> E_UNSIGNED
 312 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 313 %token FIGURE_SPACE
 314
 315 %type <book>    book_block book_body
 316 %type <i>       exclamations questions dots optional_rest
 317 %type <i>        bass_mod
 318 %type <scm>     grace_head
 319 %type <scm>     oct_check
 320 %type <scm>     context_mod_list
 321 %type <scm>     lyric_element
 322 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 323 %token <i>      DIGIT
 324 %token <scm>    NOTENAME_PITCH
 325 %token <scm>    TONICNAME_PITCH
 326 %token <scm>    CHORDMODIFIER_PITCH
 327 %token <scm>    DURATION_IDENTIFIER
 328 %token <scm>    FRACTION
 329 %token <id>     IDENTIFIER
 330 %token DRUMS
 331 %token <scm>    DRUM_PITCH
 332 %token <scm>    CHORD_MODIFIER
 333 %token <scm>    SCORE_IDENTIFIER
 334 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 335 %token <scm>    NUMBER_IDENTIFIER
 336 %token <scm>    EVENT_IDENTIFIER
 337 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 338 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 339 %token <scm>    RESTNAME
 340 %token <scm>    STRING
 341 %token <scm>    SCM_T
 342 %token <i>      UNSIGNED
 343 %token <scm>   REAL
 344
 345 %token MARKUP
 346 %token <scm> MARKUP_HEAD_MARKUP0
 347 %token <scm> MARKUP_HEAD_EMPTY
 348 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 349 %token <scm> MARKUP_HEAD_SCM0
 350 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 351 %token <scm> MARKUP_HEAD_SCM0_SCM1
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 353 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 354
 355 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 356 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 357
 358 %type <outputdef> output_def
 359 %type <scm>     lilypond_header lilypond_header_body
 360 %type <music>   open_event close_event
 361 %type <i>       sub_quotes sup_quotes
 362 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 363 %type <music>   Repeated_music
 364 %type <scm>     Alternative_music
 365 %type <i>       tremolo_type
 366 %type <i>       bare_int  bare_unsigned
 367 %type <i>       script_dir
 368 %type <scm>     identifier_init
 369
 370 %type <music> note_chord_element chord_body chord_body_element
 371 %type <scm>  chord_body_elements
 372 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 373
 374 %type <scm>   post_events
 375 %type <music> gen_text_def direction_less_event direction_reqd_event
 376 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 377 %type <scm>    steno_tonic_pitch
 378 %type <scm>     duration_length fraction
 379
 380 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 381
 382 %type <scm>  embedded_scm scalar
 383 %type <music>   Music Sequential_music Simultaneous_music
 384 %type <music>   relative_music re_rhythmed_music
 385 %type <music>   music_property_def context_change
 386 %type <scm> context_prop_spec
 387 %type <scm> Music_list
 388 %type <scm> property_operation context_mod context_def_mod optional_context_mod
 389 %type <outputdef>  music_output_def_body music_output_def_head
 390 %type <music>   post_event tagged_post_event
 391 %type <music> command_req
 392 %type <music> string_number_event
 393 %type <scm>     string bare_number number_expression number_term number_factor
 394 %type <score>   score_block score_body
 395
 396 %type <scm>     context_def_spec_block context_def_spec_body
 397 %type <music>   tempo_event
 398 %type <scm>     script_abbreviation
 399
 400
 401
 402 %left '-' '+'
 403
 404 /* We don't assign precedence to / and *, because we might need varied
 405 prec levels in different prods */
 406
 407 %left UNARY_MINUS
 408
 409 %%
 410
 411 lilypond:       /* empty */
 412         | lilypond toplevel_expression {}
 413         | lilypond assignment  { }
 414         | lilypond error {
 415                 THIS->error_level_ = 1;
 416         }
 417         | lilypond INVALID      {
 418                 THIS->error_level_ = 1;
 419         }
 420         ;
 421
 422 toplevel_expression:
 423         lilypond_header {
 424                 THIS->header_ = $1;
 425         }
 426         | add_quote {
 427         }
 428         | book_block {
 429                 Book *book = $1;
 430                 SCM header = THIS->header_;
 431                 Path outname = split_path (THIS->output_basename_);
 432                 int *c = &THIS->book_count_;
 433                 if (*c)
 434                         outname.base += "-" + to_string (*c);
 435                 (*c)++;
 436                 Music_output_def *dp = unsmob_music_output_def
 437                         (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 438                 book->process (outname.to_string (),
 439                         dp ? dp->clone () : new Paper_def, header);
 440                 scm_gc_unprotect_object (book->self_scm ());
 441         }
 442         | score_block {
 443                 Score *sc = $1;
 444                 SCM head = is_module (sc->header_) ? sc->header_
 445                         : THIS->header_.to_SCM ();
 446
 447                 Path p = split_path (THIS->output_basename_);
 448                 int *c = &THIS->score_count_;
 449                 if (*c)
 450                         p.base += "-" + to_string (*c);
 451
 452                 (*c)++;
 453                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 454
 455                 for (int i = 0; i < sc->defs_.size (); i++)
 456                         default_rendering (sc->music_,
 457                                            sc->defs_[i]->self_scm (), head,
 458                                            outname);
 459
 460                 if (sc->defs_.is_empty ())
 461                 {
 462                    Music_output_def *id = unsmob_music_output_def
 463                         (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 464                    id = id ? id->clone () : new Paper_def;
 465                    default_rendering (sc->music_, id->self_scm (), head,
 466                         outname);
 467                    scm_gc_unprotect_object (id->self_scm ());
 468                 }
 469                 scm_gc_unprotect_object (sc->self_scm ());
 470         }
 471         | output_def {
 472                 SCM id = SCM_EOL;
 473                 if (dynamic_cast<Paper_def*> ($1))
 474                         id = scm_makfrom0str ("$defaultpaper");
 475                 else if (dynamic_cast<Midi_def*> ($1))
 476                         id = scm_makfrom0str ("$defaultmidi");
 477                 THIS->lexer_->set_identifier (id, $1->self_scm ());
 478                 scm_gc_unprotect_object ($1->self_scm ());
 479         }
 480         ;
 481
 482
 483 embedded_scm:
 484         SCM_T
 485         | SCM_IDENTIFIER
 486         ;
 487
 488
 489
 490
 491 lilypond_header_body:
 492         {
 493                 $$ = ly_make_anonymous_module ();
 494                 THIS->lexer_->add_scope ($$);
 495         }
 496         | lilypond_header_body assignment  {
 497
 498         }
 499         ;
 500
 501 lilypond_header:
 502         HEADER '{' lilypond_header_body '}'     {
 503                 $$ = THIS->lexer_->remove_scope ();
 504         }
 505         ;
 506
 507
 508 /*
 509         DECLARATIONS
 510 */
 511 assignment:
 512         STRING {
 513                 THIS->push_spot ();
 514         }
 515         /* cont */ '=' identifier_init  {
 516
 517         /*
 518                 Should find generic way of associating input with objects.
 519         */
 520                 Input ip = THIS->pop_spot ();
 521
 522                 if (! is_regular_identifier ($1))
 523                 {
 524                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 525                 }
 526
 527                 THIS->lexer_->set_identifier ($1, $4);
 528
 529 /*
 530  TODO: devise standard for protection in parser.
 531
 532   The parser stack lives on the C-stack, which means that
 533 all objects can be unprotected as soon as they're here.
 534
 535 */
 536         }
 537         | embedded_scm { }
 538         ;
 539
 540
 541 identifier_init:
 542         score_block {
 543                 $$ = $1->self_scm ();
 544                 scm_gc_unprotect_object ($$);
 545         }
 546         | full_markup {
 547                 $$ = $1;
 548         }
 549         | output_def {
 550                 $$ = $1->self_scm ();
 551                 scm_gc_unprotect_object ($$);
 552         }
 553         | context_def_spec_block {
 554                 $$ = $1;
 555         }
 556         | Music  {
 557                 $$ = $1->self_scm ();
 558                 scm_gc_unprotect_object ($$);
 559         }
 560         | post_event {
 561                 $$ = $1->self_scm ();
 562                 scm_gc_unprotect_object ($$);
 563         }
 564         | number_expression {
 565                 $$ = $1;
 566         }
 567         | string {
 568                 $$ = $1;
 569         }
 570         | embedded_scm  {
 571                 $$ = $1;
 572         }
 573         ;
 574
 575 context_def_spec_block:
 576         CONTEXT '{' context_def_spec_body '}'
 577                 {
 578                 $$ = $3;
 579         }
 580         ;
 581
 582 context_def_spec_body:
 583         /**/ {
 584                 $$ = Context_def::make_scm ();
 585                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 586         }
 587         | CONTEXT_DEF_IDENTIFIER        {
 588                 $$ = $1;
 589                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 590         }
 591         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 592                 Context_def*td = unsmob_context_def ($$);
 593
 594                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 595                         SCM tag = ly_caar (p);
 596
 597                         /* TODO: should make new tag "grob-definition" ? */
 598                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 599                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 600                 }
 601         }
 602         | context_def_spec_body context_mod {
 603                 unsmob_context_def ($$)->add_context_mod ($2);
 604         }
 605         ;
 606
 607 book_block:
 608         BOOK {
 609                 THIS->push_spot ();
 610         }
 611         /*cont*/ '{' book_body '}'      {
 612                 THIS->pop_spot ();
 613                 $$ = $4;
 614         }
 615         ;
 616
 617 book_body:
 618         {
 619                 $$ = new Book;
 620                 $$->set_spot (THIS->here_input ());
 621         }
 622         | book_body score_block {
 623                 $$->scores_.push ($2);
 624                 scm_gc_unprotect_object ($2->self_scm ());
 625         }
 626         | book_body error {
 627         }
 628         ;
 629
 630 score_block:
 631         SCORE {
 632                 THIS->push_spot ();
 633         }
 634         /*cont*/ '{' score_body '}'     {
 635                 THIS->pop_spot ();
 636                 $$ = $4;
 637         }
 638         ;
 639
 640 score_body:
 641         Music   {
 642                 $$ = new Score;
 643
 644                 $$->set_spot (THIS->here_input ());
 645                 SCM m = $1->self_scm ();
 646                 scm_gc_unprotect_object (m);
 647
 648                 /*
 649                         guh.
 650                 */
 651                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 652                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 653                         m = scm_call_1 (ly_car (check_funcs), m);
 654                 $$->music_ = m;
 655
 656         }
 657         | SCORE_IDENTIFIER {
 658                 $$ = new Score ( *unsmob_score ($1));
 659                 $$->set_spot (THIS->here_input ());
 660         }
 661         | score_body lilypond_header    {
 662                 $$->header_ = $2;
 663         }
 664         | score_body output_def {
 665                 $$->defs_.push ($2);
 666                 scm_gc_unprotect_object ($2->self_scm ());
 667         }
 668         | score_body error {
 669
 670         }
 671         ;
 672
 673
 674 /*
 675         MIDI
 676 */
 677 output_def:
 678         music_output_def_body '}' {
 679                 $$ = $1;
 680                 THIS-> lexer_-> remove_scope ();
 681         }
 682         ;
 683
 684 music_output_def_head:
 685         MIDI    {
 686                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 687
 688
 689                 Midi_def *p = 0;
 690                 if (id)
 691                         p = dynamic_cast<Midi_def*> (id->clone ());
 692                 else
 693                         p = new Midi_def;
 694
 695                 $$ = p;
 696                 THIS->lexer_->add_scope (p->scope_);
 697         }
 698         | PAPER         {
 699                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 700                   Paper_def *p = 0;
 701                 if (id)
 702                         p = dynamic_cast<Paper_def*> (id->clone ());
 703                 else
 704                         p = new Paper_def;
 705
 706                 THIS->lexer_->add_scope (p->scope_);
 707                 $$ = p;
 708         }
 709         ;
 710
 711
 712 music_output_def_body:
 713         music_output_def_head '{' {
 714                 $$ = $1;
 715                 $$->input_origin_. set_spot (THIS->here_input ());
 716
 717         }
 718         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 719                 scm_gc_unprotect_object ($1->self_scm ());
 720                 Music_output_def *o = unsmob_music_output_def ($3);
 721                 o->input_origin_.set_spot (THIS->here_input ());
 722                 $$ = o;
 723                 THIS->lexer_->remove_scope ();
 724                 THIS->lexer_->add_scope (o->scope_);
 725         }
 726         | music_output_def_body assignment  {
 727
 728         }
 729         | music_output_def_body context_def_spec_block  {
 730                 $$->assign_context_def ($2);
 731         }
 732         | music_output_def_body tempo_event  {
 733                 /*
 734                         junk this ? there already is tempo stuff in
 735                         music.
 736                 */
 737                 int m = ly_scm2int ( $2->get_property ("metronome-count"));
 738                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 739                 Midi_def *md = dynamic_cast<Midi_def*> ($$);
 740                 if (md)
 741                         md->set_tempo (d->get_length (), m);
 742                 scm_gc_unprotect_object ($2->self_scm ());
 743         }
 744         | music_output_def_body error {
 745
 746         }
 747         ;
 748
 749 tempo_event:
 750         TEMPO steno_duration '=' bare_unsigned  {
 751                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 752                 $$->set_property ("tempo-unit", $2);
 753                 $$->set_property ("metronome-count", scm_int2num ( $4));
 754         }
 755         ;
 756
 757 /*
 758 The representation of a  list is the
 759
 760   (LIST . LAST-CONS)
 761
 762  to have  efficient append.
 763 */
 764 Music_list:
 765         /* empty */ {
 766                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 767         }
 768         | Music_list Music {
 769                 SCM s = $$;
 770                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 771                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 772                 if (ly_c_pair_p (ly_cdr (s)))
 773                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 774                 else
 775                         scm_set_car_x (s, c); /* set first cons */
 776                 scm_set_cdr_x (s, c);  /* remember last cell */
 777         }
 778         | Music_list error {
 779         }
 780         ;
 781
 782
 783 Music:
 784         Simple_music
 785         | Composite_music
 786         ;
 787
 788 Alternative_music:
 789         /* empty */ {
 790                 $$ = SCM_EOL;
 791         }
 792         | ALTERNATIVE '{' Music_list '}' {
 793                 $$ = $3;
 794         }
 795         ;
 796
 797 Repeated_music:
 798         REPEAT string bare_unsigned Music Alternative_music
 799         {
 800                 Music *beg = $4;
 801                 int times = $3;
 802                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 803                 if (times < scm_ilength (alts)) {
 804                   unsmob_music (ly_car (alts))
 805                     ->origin ()->warning (
 806                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 807                   alts = ly_truncate_list (times, alts);
 808                 }
 809
 810
 811                 SCM proc = ly_scheme_function ("make-repeated-music");
 812
 813                 SCM mus = scm_call_1 (proc, $2);
 814                 scm_gc_protect_object (mus); // UGH.
 815                 Music *r = unsmob_music (mus);
 816                 if (beg)
 817                         {
 818                         r-> set_property ("element", beg->self_scm ());
 819                         scm_gc_unprotect_object (beg->self_scm ());
 820                         }
 821                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 822
 823                 r-> set_property ("elements",alts);
 824                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 825                         /*
 826                         TODO: move this code to Scheme.
 827                         */
 828
 829                         /*
 830                         we can not get durations and other stuff correct down the line, so we have to
 831                         add to the duration log here.
 832                         */
 833                         SCM func = ly_scheme_function ("shift-duration-log");
 834
 835                         int dots = ($3 % 3) ? 0 : 1;
 836                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 837
 838                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 839
 840                         if (seq) {
 841                                 int list_len = scm_ilength (seq->music_list ());
 842                                 if (list_len != 2)
 843                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 844                                 shift -= 1;
 845                                 r->compress (Moment (Rational (1, list_len)));
 846                                 }
 847                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 848
 849                 }
 850                 r->set_spot (*$4->origin ());
 851
 852                 $$ = r;
 853         }
 854         ;
 855
 856 Sequential_music:
 857         SEQUENTIAL '{' Music_list '}'           {
 858                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 859                 $$->set_property ("elements", ly_car ($3));
 860                 $$->set_spot (THIS->here_input ());
 861         }
 862         | '{' Music_list '}'            {
 863                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 864                 $$->set_property ("elements", ly_car ($2));
 865                 $$->set_spot (THIS->here_input ());
 866         }
 867         ;
 868
 869 Simultaneous_music:
 870         SIMULTANEOUS '{' Music_list '}'{
 871                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 872                 $$->set_property ("elements", ly_car ($3));
 873                 $$->set_spot (THIS->here_input ());
 874
 875         }
 876         | simul_open Music_list simul_close     {
 877                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 878                 $$->set_property ("elements", ly_car ($2));
 879                 $$->set_spot (THIS->here_input ());
 880         }
 881         ;
 882
 883 Simple_music:
 884         event_chord             { $$ = $1; }
 885         | APPLYOUTPUT embedded_scm {
 886                 if (!ly_input_procedure_p ($2))
 887                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 888                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 889                 $$->set_property ("procedure", $2);
 890                 $$->set_spot (THIS->here_input ());
 891         }
 892         | APPLYCONTEXT embedded_scm {
 893                 if (!ly_input_procedure_p ($2))
 894                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 895                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 896                 $$->set_property ("procedure", $2);
 897                 $$->set_spot (THIS->here_input ());
 898         }
 899         | MUSIC_IDENTIFIER {
 900                 $$ = unsmob_music ($1);
 901         }
 902         | music_property_def
 903         | context_change
 904         ;
 905
 906
 907 optional_context_mod:
 908         /**/ { $$ = SCM_EOL; }
 909         | WITH '{' context_mod_list '}'  { $$ = $3; }
 910         ;
 911
 912 grace_head:
 913         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 914         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 915         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 916         ;
 917
 918 context_mod_list:
 919         /* */  { $$ = SCM_EOL; }
 920         | context_mod_list context_mod  {
 921                  $$ = scm_cons ($2, $1);
 922         }
 923         ;
 924
 925 Composite_music:
 926         AUTOCHANGE Music        {
 927                 SCM proc = ly_scheme_function ("make-autochange-music");
 928
 929                 SCM res = scm_call_1 (proc, $2->self_scm ());
 930                 scm_gc_unprotect_object ($2->self_scm ());
 931                 $$ = unsmob_music (res);
 932                 scm_gc_protect_object (res);
 933                 $$->set_spot (THIS->here_input ());
 934         }
 935         | PARTCOMBINE Music Music {
 936                 SCM proc = ly_scheme_function ("make-part-combine-music");
 937
 938                 SCM res = scm_call_1 (proc, scm_listify ($2->self_scm (),
 939                         $3->self_scm (), SCM_UNDEFINED));
 940                 scm_gc_unprotect_object ($3->self_scm ());
 941                 scm_gc_unprotect_object ($2->self_scm ());
 942                 $$ = unsmob_music (res);
 943                 scm_gc_protect_object (res);
 944                 $$->set_spot (THIS->here_input ());
 945         }
 946         | grace_head Music {
 947 #if 1
 948         /*
 949                 The other version is for easier debugging  of
 950                 Sequential_music_iterator in combination with grace notes.
 951         */
 952
 953 /*
 954
 955 TODO: should distinguish between both grace types in the
 956 basic music objects too, since the meaning is different.
 957
 958 */
 959
 960                 String start_str = "start" + ly_scm2string ($1) + "Music";
 961                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 962
 963                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 964                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 965
 966                 Music *startm = unsmob_music (start);
 967                 Music *stopm = unsmob_music (stop);
 968
 969                 SCM ms = SCM_EOL;
 970                 if (stopm) {
 971                         stopm = stopm->clone ();
 972                         ms = scm_cons (stopm->self_scm (), ms);
 973                         scm_gc_unprotect_object (stopm->self_scm ());
 974                 }
 975                 ms = scm_cons ($2->self_scm (), ms);
 976                 scm_gc_unprotect_object ($2->self_scm ());
 977                 if (startm) {
 978                         startm = startm->clone ();
 979                         ms = scm_cons (startm->self_scm (), ms);
 980                         scm_gc_unprotect_object (startm->self_scm ());
 981                 }
 982
 983                 Music* seq = MY_MAKE_MUSIC ("SequentialMusic");
 984                 seq->set_property ("elements", ms);
 985
 986
 987                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 988                 $$->set_property ("element", seq->self_scm ());
 989                 scm_gc_unprotect_object (seq->self_scm ());
 990 #else
 991                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 992                 $$->set_property ("element", $2->self_scm ());
 993                 scm_gc_unprotect_object ($2->self_scm ());
 994 #endif
 995         }
 996         | CONTEXT string '=' string optional_context_mod Music {
 997                 $$ = context_spec_music ($2, $4, $6, $5);
 998
 999         }
1000         | CONTEXT STRING optional_context_mod Music {
1001                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1002         }
1003         | NEWCONTEXT string optional_context_mod Music {
1004                 $$ = context_spec_music ($2, get_next_unique_context (),
1005                                          $4, $3);
1006         }
1007
1008         | TIMES {
1009                 THIS->push_spot ();
1010         }
1011         /* CONTINUED */
1012                 fraction Music
1013
1014         {
1015                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1016                 Music *mp = $4;
1017
1018                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1019                 $$->set_spot (THIS->pop_spot ());
1020
1021                 $$->set_property ("element", mp->self_scm ());
1022                 scm_gc_unprotect_object (mp->self_scm ());
1023                 $$->set_property ("numerator", scm_int2num (n));
1024                 $$->set_property ("denominator", scm_int2num (d));
1025                 $$->compress (Moment (Rational (n,d)));
1026
1027         }
1028         | Repeated_music                { $$ = $1; }
1029         | Simultaneous_music            { $$ = $1; }
1030         | Sequential_music              { $$ = $1; }
1031         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1032                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1033                 Music *p = $4;
1034                 Pitch from = *unsmob_pitch ($2);
1035                 Pitch to = *unsmob_pitch ($3);
1036
1037                 p->transpose (interval (from, to));
1038                 $$->set_property ("element", p->self_scm ());
1039                 scm_gc_unprotect_object (p->self_scm ());
1040         }
1041         | APPLY embedded_scm Music  {
1042                 if (!ly_input_procedure_p ($2))
1043                         {
1044                         THIS->parser_error (_ ("\\apply takes function argument"));
1045                         $$ = $3;
1046                         }
1047                 else
1048                         {
1049                         SCM ret = scm_call_1 ($2, $3->self_scm ());
1050                         Music *m = unsmob_music (ret);
1051                         if (!m) {
1052                                 THIS->parser_error ("\\apply must return a Music");
1053                                 m = MY_MAKE_MUSIC ("Music");
1054                                 }
1055                         $$ = m;
1056                         }
1057         }
1058         | NOTES
1059                 {
1060                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1061                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1062         }
1063         Music
1064                 { $$ = $3;
1065                   THIS->lexer_->pop_state ();
1066                 }
1067         | DRUMS
1068                 {
1069                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1070                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1071         }
1072         Music
1073                 { $$ = $3;
1074                   THIS->lexer_->pop_state ();
1075                 }
1076         | FIGURES
1077                 { THIS->lexer_->push_figuredbass_state (); }
1078         Music
1079                 {
1080                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1081                   chm->set_property ("element", $3->self_scm ());
1082                   $$ = chm;
1083                   scm_gc_unprotect_object ($3->self_scm ());
1084
1085                   THIS->lexer_->pop_state ();
1086         }
1087         | CHORDS {
1088                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1089                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1090                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1091                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1092
1093         } Music {
1094                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1095                   chm->set_property ("element", $3->self_scm ());
1096                   scm_gc_unprotect_object ($3->self_scm ());
1097                   $$ = chm;
1098
1099                   THIS->lexer_->pop_state ();
1100         }
1101         | LYRICS
1102                 { THIS->lexer_->push_lyric_state (); }
1103         Music
1104                 {
1105                   $$ = $3;
1106                   THIS->lexer_->pop_state ();
1107         }
1108         | relative_music        { $$ = $1; }
1109         | re_rhythmed_music     { $$ = $1; }
1110         | TAG embedded_scm Music {
1111                 tag_music ($3, $2, THIS->here_input ());
1112                 $$ = $3;
1113         }
1114         ;
1115
1116 relative_music:
1117         RELATIVE absolute_pitch Music {
1118                 Music *p = $3;
1119                 Pitch pit = *unsmob_pitch ($2);
1120                 $$ = MY_MAKE_MUSIC ("RelativeOctaveMusic");
1121
1122                 $$->set_property ("element", p->self_scm ());
1123                 scm_gc_unprotect_object (p->self_scm ());
1124
1125
1126                 Pitch retpitch = p->to_relative_octave (pit);
1127                 if (lily_1_8_relative)
1128                         $$->set_property ("last-pitch", retpitch.smobbed_copy ());
1129         }
1130         ;
1131
1132 re_rhythmed_music:
1133         ADDLYRICS Music Music {
1134         Music *l = MY_MAKE_MUSIC ("LyricCombineMusic");
1135           l->set_property ("elements", scm_listify ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1136           scm_gc_unprotect_object ($3->self_scm ());
1137           scm_gc_unprotect_object ($2->self_scm ());
1138           $$ = l;
1139         }
1140         | NEWADDLYRICS string Music {
1141           Music *l = MY_MAKE_MUSIC ("NewLyricCombineMusic");
1142           l->set_property ("element", $3->self_scm ());
1143           scm_gc_unprotect_object ($3->self_scm ());
1144           $$ = l;
1145           l->set_property ("associated-context", $2);
1146         }
1147         ;
1148
1149 context_change:
1150         CHANGE STRING '=' STRING  {
1151                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1152                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1153                 t-> set_property ("change-to-id", $4);
1154
1155                 $$ = t;
1156                 $$->set_spot (THIS->here_input ());
1157         }
1158         ;
1159
1160 property_operation:
1161         STRING '='  scalar {
1162                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1163                         scm_string_to_symbol ($1), $3);
1164         }
1165         | UNSET STRING {
1166                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1167                         scm_string_to_symbol ($2));
1168         }
1169         | OVERRIDE STRING embedded_scm '=' embedded_scm {
1170                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1171                         scm_string_to_symbol ($2), $3, $5);
1172         }
1173         | REVERT STRING embedded_scm {
1174                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1175                         scm_string_to_symbol ($2), $3);
1176         }
1177         ;
1178
1179 context_def_mod:
1180         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1181         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1182         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1183
1184         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1185         | DENIES { $$ = ly_symbol2scm ("denies"); }
1186
1187         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1188         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1189         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1190         | NAME { $$ = ly_symbol2scm ("context-name"); }
1191         ;
1192
1193 context_mod:
1194         property_operation { $$ = $1; }
1195         | context_def_mod STRING {
1196                 $$ = scm_list_2 ($1, $2);
1197         }
1198         ;
1199
1200 context_prop_spec:
1201         STRING  {
1202                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"), scm_string_to_symbol ($1));
1203         }
1204         | STRING '.' STRING {
1205                 $$ = scm_list_2 (scm_string_to_symbol ($1), scm_string_to_symbol ($3));
1206         }
1207         ;
1208
1209 music_property_def:
1210         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1211                 $$ = property_op_to_music (scm_list_4 (
1212                         ly_symbol2scm ("poppush"),
1213                         ly_cadr ($2),
1214                         $3, $5));
1215                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1216         }
1217         | REVERT context_prop_spec embedded_scm {
1218                 $$ = property_op_to_music (scm_list_3 (
1219                         ly_symbol2scm ("pop"),
1220                         ly_cadr ($2),
1221                         $3));
1222
1223                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1224         }
1225         | SET context_prop_spec '=' scalar {
1226                 $$ = property_op_to_music (scm_list_3 (
1227                         ly_symbol2scm ("assign"),
1228                         ly_cadr ($2),
1229                         $4));
1230                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1231         }
1232         | UNSET context_prop_spec {
1233                 $$ = property_op_to_music (scm_list_2 (
1234                         ly_symbol2scm ("unset"),
1235                         ly_cadr ($2)));
1236                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1237         }
1238         | ONCE music_property_def {
1239                 SCM e = $2->get_property ("element");
1240                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1241                 $$ = $2;
1242
1243         }
1244         ;
1245
1246
1247
1248 scalar:
1249         string          { $$ = $1; }
1250         | bare_int      { $$ = scm_int2num ($1); }
1251         | embedded_scm  { $$ = $1; }
1252         | full_markup {  $$ = $1; }
1253         | DIGIT { $$ = scm_int2num ($1); }
1254         ;
1255
1256 /*
1257 This is a trick:
1258
1259 Adding pre_events to the simple_element
1260 makes the choice between
1261
1262   string:  STRING
1263
1264 and
1265
1266   simple_element: STRING
1267
1268 a single shift/reduction conflict.
1269
1270 nevertheless, this is not very clean, and we should find a different
1271 solution.
1272
1273 */
1274 pre_events: {
1275                 THIS->push_spot ();
1276         }
1277         ;
1278
1279 event_chord:
1280         pre_events simple_element post_events   {
1281                 SCM elts = $2-> get_property ("elements");
1282
1283                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1284
1285                 $2->set_property ("elements", elts);
1286                 $$ = $2;
1287         }
1288         | command_element
1289         | note_chord_element
1290         ;
1291
1292
1293 note_chord_element:
1294         chord_body optional_notemode_duration post_events
1295         {
1296                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1297                 SCM es = $1->get_property ("elements");
1298                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1299
1300                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1301                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1302                 es = ly_append2 (es, postevs);
1303
1304                 $1-> set_property ("elements", es);
1305                 $$ = $1;
1306         }
1307         ;
1308
1309 chord_open: '<'
1310         ;
1311
1312 chord_close: '>'
1313         ;
1314
1315 simul_open: LESSLESS
1316         ;
1317
1318 simul_close: MOREMORE
1319         ;
1320
1321 chord_body:
1322         chord_open chord_body_elements chord_close
1323         {
1324                 $$ = MY_MAKE_MUSIC ("EventChord");
1325                 $$->set_property ("elements",
1326                         scm_reverse_x ($2, SCM_EOL));
1327         }
1328         ;
1329
1330 chord_body_elements:
1331         /* empty */             { $$ = SCM_EOL; }
1332         | chord_body_elements chord_body_element {
1333                 $$ = scm_cons ($2->self_scm (), $1);
1334                 scm_gc_unprotect_object ($2->self_scm ());
1335         }
1336         ;
1337
1338 chord_body_element:
1339         pitch exclamations questions post_events
1340         {
1341                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1342                 n->set_property ("pitch", $1);
1343                 if ($3 % 2)
1344                         n->set_property ("cautionary", SCM_BOOL_T);
1345                 if ($2 % 2 || $3 % 2)
1346                         n->set_property ("force-accidental", SCM_BOOL_T);
1347
1348                 if (ly_c_pair_p ($4)) {
1349                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1350                         n->set_property ("articulations", arts);
1351                 }
1352                 $$ = n;
1353         }
1354         | DRUM_PITCH post_events {
1355                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1356                 n->set_property ("duration", $2);
1357                 n->set_property ("drum-type", $1);
1358                 n->set_spot (THIS->here_input ());
1359
1360                 if (ly_c_pair_p ($2)) {
1361                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1362                         n->set_property ("articulations", arts);
1363                 }
1364                 $$ = n;
1365         }
1366         ;
1367
1368 add_quote:
1369         ADDQUOTE string Music {
1370                 SCM adder = ly_scheme_function ("add-quotable");
1371
1372                 scm_call_2 (adder, $2, $3->self_scm ());
1373                 scm_gc_unprotect_object ($3->self_scm ());
1374         }
1375         ;
1376
1377 command_element:
1378         command_req {
1379                 $$ = MY_MAKE_MUSIC ("EventChord");
1380                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1381                 scm_gc_unprotect_object ($1->self_scm ());
1382
1383                 $$-> set_spot (THIS->here_input ());
1384                 $1-> set_spot (THIS->here_input ());
1385         }
1386         | SKIP duration_length {
1387                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1388                 skip->set_property ("duration", $2);
1389
1390                 $$ = skip;
1391         }
1392         | QUOTE STRING duration_length {
1393                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1394                 SCM evs = SCM_EOL;
1395                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1396                 {
1397                         SCM key = $2; // use symbol?
1398                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1399                 }
1400                 Music *quote = 0;
1401                 if (ly_c_vector_p (evs))
1402                 {
1403                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1404                         quote->set_property ("duration", $3);
1405                         quote->set_property ("quoted-events", evs);
1406                 } else {
1407                         THIS->here_input ().warning (_f ("Can\'t find music"));
1408                         quote = MY_MAKE_MUSIC ("Event");
1409                 }
1410                 quote->set_spot (THIS->here_input ());
1411                 $$ = quote;
1412         }
1413         | OCTAVE { THIS->push_spot (); }
1414           pitch {
1415                 Music *l = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1416                 $$ = l;
1417                 $$->set_spot (THIS->pop_spot ());
1418                 $$->set_property ("pitch", $3);
1419         }
1420         | E_LEFTSQUARE {
1421                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1422                 l->set_property ("span-direction", scm_int2num (START));
1423                 l->set_spot (THIS->here_input ());
1424
1425                 $$ = MY_MAKE_MUSIC ("EventChord");
1426                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1427                 scm_gc_unprotect_object (l->self_scm ());
1428                 $$->set_spot (THIS->here_input ());
1429         }
1430         | E_RIGHTSQUARE {
1431                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1432                 l->set_property ("span-direction", scm_int2num (STOP));
1433                 l->set_spot (THIS->here_input ());
1434
1435                 $$ = MY_MAKE_MUSIC ("EventChord");
1436                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1437                 $$->set_spot (THIS->here_input ());
1438                 scm_gc_unprotect_object (l->self_scm ());
1439         }
1440         | E_BACKSLASH {
1441                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1442                 $$->set_spot (THIS->here_input ());
1443         }
1444         | '|'      {
1445                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1446
1447                 if (Music * m = unsmob_music (pipe))
1448                         $$ = m->clone ();
1449                 else
1450                         $$ = MY_MAKE_MUSIC ("BarCheck");
1451
1452                 $$->set_spot (THIS->here_input ());
1453         }
1454         | TRANSPOSITION pitch {
1455                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1456                                         $2);
1457                 $$->set_spot (THIS-> here_input ());
1458                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1459                         $$, SCM_EOL);
1460         }
1461         | BAR STRING                    {
1462                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1463
1464                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1465                                         t, SCM_EOL);
1466                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1467                 $$->set_spot (THIS->here_input ());
1468                 t->set_spot (THIS->here_input ());
1469         }
1470         | PARTIAL duration_length       {
1471                 Moment m = - unsmob_duration ($2)->get_length ();
1472                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1473                 p->set_spot (THIS->here_input ());
1474                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1475                                         p, SCM_EOL);
1476                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1477                                         p, SCM_EOL);
1478                 $$ = p;
1479         }
1480         | CLEF STRING  {
1481                 SCM proc = ly_scheme_function ("make-clef-set");
1482
1483                 SCM result = scm_call_1 (proc, $2);
1484                 scm_gc_protect_object (result);
1485                 $$ = unsmob_music (result);
1486         }
1487         | TIME_T fraction  {
1488                 SCM proc= ly_scheme_function ("make-time-signature-set");
1489
1490                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1491                 scm_gc_protect_object (result);
1492                 $$ = unsmob_music (result);
1493         }
1494         | MARK scalar {
1495                 SCM proc = ly_scheme_function ("make-mark-set");
1496
1497                 SCM result = scm_call_1 (proc, $2);
1498                 scm_gc_protect_object (result);
1499                 $$ = unsmob_music (result);
1500         }
1501         ;
1502
1503 command_req:
1504         BREATHE {
1505                 $$ = MY_MAKE_MUSIC ("BreathingSignEvent");
1506         }
1507         | E_TILDE {
1508                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1509         }
1510         | MARK DEFAULT  {
1511                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1512                 $$ = m;
1513         }
1514         | tempo_event {
1515                 $$ = $1;
1516         }
1517         | KEY DEFAULT {
1518                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1519                 $$ = key;
1520         }
1521         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1522
1523                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1524                 if (scm_ilength ($3) > 0)
1525                 {
1526                         key->set_property ("pitch-alist", $3);
1527                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1528                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1529                 } else {
1530                         THIS->parser_error (_ ("Second argument must be pitch list."));
1531                 }
1532
1533                 $$ = key;
1534         }
1535         ;
1536
1537 post_events:
1538         /* empty */ {
1539                 $$ = SCM_EOL;
1540         }
1541         | post_events post_event {
1542                 $2->set_spot (THIS->here_input ());
1543                 $$ = scm_cons ($2->self_scm (), $$);
1544                 scm_gc_unprotect_object ($2->self_scm ());
1545         }
1546         | post_events tagged_post_event {
1547                 $2 -> set_spot (THIS->here_input ());
1548                 $$ = scm_cons ($2->self_scm (), $$);
1549                 scm_gc_unprotect_object ($2->self_scm ());
1550         }
1551         ;
1552
1553
1554 tagged_post_event:
1555         '-' TAG embedded_scm post_event {
1556                 tag_music ($4, $3, THIS->here_input ());
1557                 $$ = $4;
1558         }
1559         ;
1560
1561 post_event:
1562         direction_less_event {
1563                 $$ = $1;
1564         }
1565         | HYPHEN {
1566                 if (!THIS->lexer_->is_lyric_state ())
1567                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1568                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1569         }
1570         | EXTENDER {
1571                 if (!THIS->lexer_->is_lyric_state ())
1572                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1573                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1574         }
1575         | script_dir direction_reqd_event {
1576                 if ($1)
1577                         $2->set_property ("direction", scm_int2num ($1));
1578                 $$ = $2;
1579         }
1580         | script_dir direction_less_event {
1581                 if ($1)
1582                         $2->set_property ("direction", scm_int2num ($1));
1583                 $$ = $2;
1584         }
1585         | string_number_event
1586         ;
1587
1588 string_number_event:
1589         E_UNSIGNED {
1590                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1591                 s->set_property ("string-number", scm_int2num ($1));
1592                 s->set_spot (THIS->here_input ());
1593                 $$ = s;
1594         }
1595         ;
1596
1597
1598 direction_less_event:
1599         '['  {
1600
1601
1602 /*
1603
1604 TODO: should take all these defs out of the parser, adn make use
1605 configurable, i.e.
1606
1607
1608 (set-articulation '~ "trill")
1609
1610 */
1611                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1612                 m->set_spot (THIS->here_input ());
1613                 m->set_property ("span-direction", scm_int2num (START));
1614                 $$ = m;
1615         }
1616         | ']'  {
1617                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1618                 m->set_spot (THIS->here_input ());
1619                 m->set_property ("span-direction", scm_int2num (STOP));
1620                 $$ = m;
1621         }
1622         | '~' {
1623                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1624                 m->set_spot (THIS->here_input ());
1625                 $$ = m;
1626         }
1627         | close_event {
1628                 $$ = $1;
1629                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1630                         scm_int2num (START));
1631         }
1632         | open_event {
1633                 $$ = $1;
1634                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1635                         scm_int2num (STOP));
1636         }
1637         | EVENT_IDENTIFIER      {
1638                 $$ = unsmob_music ($1);
1639         }
1640         | tremolo_type  {
1641                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1642                a->set_spot (THIS->here_input ());
1643                a->set_property ("tremolo-type", scm_int2num ($1));
1644                $$ = a;
1645         }
1646         ;
1647
1648 direction_reqd_event:
1649         gen_text_def {
1650                 $$ = $1;
1651         }
1652         | script_abbreviation {
1653                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1654                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1655                 if (ly_c_string_p (s))
1656                         a->set_property ("articulation-type", s);
1657                 else THIS->parser_error (_ ("Expecting string as script definition"));
1658                 $$ = a;
1659         }
1660         ;
1661
1662 oct_check:
1663         /**/ { $$ = SCM_EOL; }
1664         | '='  { $$ = scm_int2num (0); }
1665         | '=' sub_quotes { $$ = scm_int2num ($2); }
1666         | '=' sup_quotes { $$ = scm_int2num ($2); }
1667         ;
1668
1669 sup_quotes:
1670         '\'' {
1671                 $$ = 1;
1672         }
1673         | sup_quotes '\'' {
1674                 $$ ++;
1675         }
1676         ;
1677
1678 sub_quotes:
1679         ',' {
1680                 $$ = 1;
1681         }
1682         | sub_quotes ',' {
1683                 $$++;
1684         }
1685         ;
1686
1687 steno_pitch:
1688         NOTENAME_PITCH  {
1689                 $$ = $1;
1690         }
1691         | NOTENAME_PITCH sup_quotes     {
1692                 Pitch p = *unsmob_pitch ($1);
1693                 p = p.transposed (Pitch ($2,0,0));
1694                 $$ = p.smobbed_copy ();
1695         }
1696         | NOTENAME_PITCH sub_quotes      {
1697                 Pitch p =* unsmob_pitch ($1);
1698                 p = p.transposed (Pitch (-$2,0,0));
1699                 $$ = p.smobbed_copy ();
1700         }
1701         ;
1702
1703 /*
1704 ugh. duplication
1705 */
1706
1707 steno_tonic_pitch:
1708         TONICNAME_PITCH {
1709                 $$ = $1;
1710         }
1711         | TONICNAME_PITCH sup_quotes    {
1712                 Pitch p = *unsmob_pitch ($1);
1713                 p = p.transposed (Pitch ($2,0,0));
1714                 $$ = p.smobbed_copy ();
1715         }
1716         | TONICNAME_PITCH sub_quotes     {
1717                 Pitch p =* unsmob_pitch ($1);
1718
1719                 p = p.transposed (Pitch (-$2,0,0));
1720                 $$ = p.smobbed_copy ();
1721         }
1722         ;
1723
1724 pitch:
1725         steno_pitch {
1726                 $$ = $1;
1727         }
1728         ;
1729
1730 pitch_also_in_chords:
1731         pitch
1732         | steno_tonic_pitch
1733         ;
1734
1735 close_event:
1736         '('     {
1737                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1738                 $$ = s;
1739                 s->set_spot (THIS->here_input ());
1740         }
1741         | E_OPEN        {
1742                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1743                 $$ = s;
1744                 s->set_spot (THIS->here_input ());
1745         }
1746         | E_SMALLER {
1747                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1748                 $$ = s;
1749                 s->set_spot (THIS->here_input ());
1750         }
1751         | E_BIGGER {
1752                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1753                 $$ = s;
1754                 s->set_spot (THIS->here_input ());
1755         }
1756         ;
1757
1758
1759 open_event:
1760         E_EXCLAMATION   {
1761                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1762                 s->set_spot (THIS->here_input ());
1763
1764                 $$ = s;
1765         }
1766         | ')'   {
1767                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1768                 $$ = s;
1769                 s->set_spot (THIS->here_input ());
1770
1771         }
1772         | E_CLOSE       {
1773                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1774                 $$ = s;
1775                 s->set_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1776                 s->set_spot (THIS->here_input ());
1777         }
1778         ;
1779
1780 gen_text_def:
1781         full_markup {
1782                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1783                 t->set_property ("text", $1);
1784                 t->set_spot (THIS->here_input ());
1785                 $$ = t;
1786         }
1787         | string {
1788                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1789                 t->set_property ("text", make_simple_markup (THIS->lexer_->encoding (), $1));
1790                 t->set_spot (THIS->here_input ());
1791                 $$ = t;
1792
1793         }
1794         | DIGIT {
1795                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1796                 t->set_property ("digit", scm_int2num ($1));
1797                 t->set_spot (THIS->here_input ());
1798                 $$ = t;
1799         }
1800         ;
1801
1802 script_abbreviation:
1803         '^'             {
1804                 $$ = scm_makfrom0str ("Hat");
1805         }
1806         | '+'           {
1807                 $$ = scm_makfrom0str ("Plus");
1808         }
1809         | '-'           {
1810                 $$ = scm_makfrom0str ("Dash");
1811         }
1812         | '|'           {
1813                 $$ = scm_makfrom0str ("Bar");
1814         }
1815         | '>'           {
1816                 $$ = scm_makfrom0str ("Larger");
1817         }
1818         | '.'           {
1819                 $$ = scm_makfrom0str ("Dot");
1820         }
1821         | '_' {
1822                 $$ = scm_makfrom0str ("Underscore");
1823         }
1824         ;
1825
1826 script_dir:
1827         '_'     { $$ = DOWN; }
1828         | '^'   { $$ = UP; }
1829         | '-'   { $$ = CENTER; }
1830         ;
1831
1832
1833 absolute_pitch:
1834         steno_pitch     {
1835                 $$ = $1;
1836         }
1837         ;
1838
1839 duration_length:
1840         multiplied_duration {
1841                 $$ = $1;
1842         }
1843         ;
1844
1845 optional_notemode_duration:
1846         {
1847                 Duration dd = THIS->default_duration_;
1848                 $$ = dd.smobbed_copy ();
1849
1850                 THIS->beam_check ($$);
1851         }
1852         | multiplied_duration   {
1853                 $$ = $1;
1854                 THIS->default_duration_ = *unsmob_duration ($$);
1855
1856                 THIS->beam_check ($$);
1857         }
1858         ;
1859
1860 steno_duration:
1861         bare_unsigned dots              {
1862                 int len = 0;
1863                 if (!is_duration ($1))
1864                         THIS->parser_error (_f ("not a duration: %d", $1));
1865                 else
1866                         len = intlog2 ($1);
1867
1868                 $$ = Duration (len, $2).smobbed_copy ();
1869         }
1870         | DURATION_IDENTIFIER dots      {
1871                 Duration *d = unsmob_duration ($1);
1872                 Duration k (d->duration_log (), d->dot_count () + $2);
1873                 *d = k;
1874                 $$ = $1;
1875         }
1876         ;
1877
1878
1879
1880
1881 multiplied_duration:
1882         steno_duration {
1883                 $$ = $1;
1884         }
1885         | multiplied_duration '*' bare_unsigned {
1886                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1887         }
1888         | multiplied_duration '*' FRACTION {
1889                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
1890
1891                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1892         }
1893         ;
1894
1895 fraction:
1896         FRACTION { $$ = $1; }
1897         | UNSIGNED '/' UNSIGNED {
1898                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
1899         }
1900         ;
1901
1902 dots:
1903         /* empty */     {
1904                 $$ = 0;
1905         }
1906         | dots '.' {
1907                 $$ ++;
1908         }
1909         ;
1910
1911
1912 tremolo_type:
1913         ':'     {
1914                 $$ = 0;
1915         }
1916         | ':' bare_unsigned {
1917                 if (!is_duration ($2))
1918                         THIS->parser_error (_f ("not a duration: %d", $2));
1919                 $$ = $2;
1920         }
1921         ;
1922
1923
1924
1925 /*****************************************************************
1926                 BASS FIGURES
1927 *****************************************************************/
1928 bass_number:
1929         DIGIT   {
1930                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
1931         }
1932         | UNSIGNED {
1933                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
1934         }
1935         | STRING { $$ = $1; }
1936         ;
1937
1938 bass_mod:
1939         '-'     { $$ = -2; }
1940         | '+'   { $$ = 2; }
1941         | '!'   { $$ = 0; }
1942         ;
1943
1944 bass_figure:
1945         FIGURE_SPACE {
1946                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1947                 $$ = bfr->self_scm ();
1948                 scm_gc_unprotect_object ($$);
1949         }
1950         | bass_number  {
1951                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1952                 $$ = bfr->self_scm ();
1953
1954                 bfr->set_property ("figure", $1);
1955
1956                 scm_gc_unprotect_object ($$);
1957         }
1958         | bass_figure bass_mod {
1959                 Music *m = unsmob_music ($1);
1960                 if ($2) {
1961                         SCM salter = m->get_property ("alteration");
1962                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
1963                         m->set_property ("alteration",
1964                                 scm_int2num (alter + $2));
1965                 } else {
1966                         m->set_property ("alteration", scm_int2num (0));
1967                 }
1968         }
1969         ;
1970
1971 br_bass_figure:
1972         '[' bass_figure {
1973                 $$ = $2;
1974                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
1975         }
1976         | bass_figure   {
1977                 $$ = $1;
1978         }
1979         | br_bass_figure ']' {
1980                 $$ = $1;
1981                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
1982         }
1983         ;
1984
1985 figure_list:
1986         /**/            {
1987                 $$ = SCM_EOL;
1988         }
1989         | figure_list br_bass_figure {
1990                 $$ = scm_cons ($2, $1);
1991         }
1992         ;
1993
1994 figure_spec:
1995         FIGURE_OPEN figure_list FIGURE_CLOSE {
1996                 Music *m = MY_MAKE_MUSIC ("EventChord");
1997                 $2 = scm_reverse_x ($2, SCM_EOL);
1998                 m->set_property ("elements", $2);
1999                 $$ = m->self_scm ();
2000         }
2001         ;
2002
2003
2004 optional_rest:
2005         /**/   { $$ = 0; }
2006         | REST { $$ = 1; }
2007         ;
2008
2009 simple_element:
2010         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
2011
2012                 Input i = THIS->pop_spot ();
2013                 if (!THIS->lexer_->is_note_state ())
2014                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2015
2016                 Music *n = 0;
2017                 if ($6)
2018                         n = MY_MAKE_MUSIC ("RestEvent");
2019                 else
2020                         n = MY_MAKE_MUSIC ("NoteEvent");
2021
2022                 n->set_property ("pitch", $1);
2023                 n->set_property ("duration", $5);
2024
2025                 if (ly_c_number_p ($4))
2026                 {
2027                         int q = ly_scm2int ($4);
2028                         n->set_property ("absolute-octave", scm_int2num (q-1));
2029                 }
2030
2031                 if ($3 % 2)
2032                         n->set_property ("cautionary", SCM_BOOL_T);
2033                 if ($2 % 2 || $3 % 2)
2034                         n->set_property ("force-accidental", SCM_BOOL_T);
2035
2036                 Music *v = MY_MAKE_MUSIC ("EventChord");
2037                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2038                 scm_gc_unprotect_object (n->self_scm ());
2039
2040                 v->set_spot (i);
2041                 n->set_spot (i);
2042                 $$ = v;
2043         }
2044         | DRUM_PITCH optional_notemode_duration {
2045                 Input i = THIS->pop_spot ();
2046
2047                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2048                 n->set_property ("duration", $2);
2049                 n->set_property ("drum-type", $1);
2050
2051                 Music *v = MY_MAKE_MUSIC ("EventChord");
2052                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2053                 scm_gc_unprotect_object (n->self_scm ());
2054                 v->set_spot (i);
2055                 n->set_spot (i);
2056                 $$ = v;
2057
2058         }
2059         | figure_spec optional_notemode_duration {
2060                 Music *m = unsmob_music ($1);
2061                 Input i = THIS->pop_spot ();
2062                 m->set_spot (i);
2063                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2064                 {
2065                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2066                 }
2067                 $$ = m;
2068         }
2069         | RESTNAME optional_notemode_duration           {
2070
2071                 Input i = THIS->pop_spot ();
2072                 Music *ev = 0;
2073                 if (ly_scm2string ($1) == "s") {
2074                         /* Space */
2075                         ev = MY_MAKE_MUSIC ("SkipEvent");
2076                   }
2077                 else {
2078                         ev = MY_MAKE_MUSIC ("RestEvent");
2079
2080                     }
2081                 ev->set_property ("duration", $2);
2082                 ev->set_spot (i);
2083                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2084                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2085                 velt->set_spot (i);
2086
2087                 scm_gc_unprotect_object (ev->self_scm ());
2088
2089                 $$ = velt;
2090         }
2091         | MULTI_MEASURE_REST optional_notemode_duration         {
2092                 THIS->pop_spot ();
2093
2094                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2095                 SCM mus = scm_call_2 (proc, $2,
2096                         make_input (THIS->here_input ()));
2097                 scm_gc_protect_object (mus);
2098                 $$ = unsmob_music (mus);
2099         }
2100
2101         | lyric_element optional_notemode_duration      {
2102                 Input i = THIS->pop_spot ();
2103                 if (!THIS->lexer_->is_lyric_state ())
2104                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2105
2106                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2107                 lreq->set_property ("text", $1);
2108                 lreq->set_property ("duration",$2);
2109                 lreq->set_spot (i);
2110                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2111                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2112
2113                 $$= velt;
2114         }
2115         | new_chord {
2116                 THIS->pop_spot ();
2117
2118                 if (!THIS->lexer_->is_chord_state ())
2119                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2120                 $$ = unsmob_music ($1);
2121         }
2122         ;
2123
2124 lyric_element:
2125         full_markup { $$ = $1; }
2126         | STRING { $$ = $1; }
2127         ;
2128
2129 new_chord:
2130         steno_tonic_pitch optional_notemode_duration   {
2131                 $$ = make_chord ($1, $2, SCM_EOL);
2132         }
2133         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2134                 SCM its = scm_reverse_x ($4, SCM_EOL);
2135                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2136         }
2137         ;
2138
2139 chord_items:
2140         /**/ {
2141                 $$ = SCM_EOL;
2142         }
2143         | chord_items chord_item {
2144                 $$ = scm_cons ($2, $$);
2145         }
2146         ;
2147
2148 chord_separator:
2149         CHORD_COLON {
2150                 $$ = ly_symbol2scm ("chord-colon");
2151         }
2152         | CHORD_CARET {
2153                 $$ = ly_symbol2scm ("chord-caret");
2154         }
2155         | CHORD_SLASH steno_tonic_pitch {
2156                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2157         }
2158         | CHORD_BASS steno_tonic_pitch {
2159                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2160         }
2161         ;
2162
2163 chord_item:
2164         chord_separator {
2165                 $$ = $1;
2166         }
2167         | step_numbers {
2168                 $$ = scm_reverse_x ($1, SCM_EOL);
2169         }
2170         | CHORD_MODIFIER  {
2171                 $$ = $1;
2172         }
2173         ;
2174
2175 step_numbers:
2176         step_number { $$ = scm_cons ($1, SCM_EOL); }
2177         | step_numbers '.' step_number {
2178                 $$ = scm_cons ($3, $$);
2179         }
2180         ;
2181
2182 step_number:
2183         bare_unsigned {
2184                 $$ = make_chord_step ($1, 0);
2185         }
2186         | bare_unsigned '+' {
2187                 $$ = make_chord_step ($1, SHARP);
2188         }
2189         | bare_unsigned CHORD_MINUS {
2190                 $$ = make_chord_step ($1, FLAT);
2191         }
2192         ;
2193
2194 /*
2195         UTILITIES
2196
2197 TODO: should deprecate in favor of Scheme?
2198
2199  */
2200 number_expression:
2201         number_expression '+' number_term {
2202                 $$ = scm_sum ($1, $3);
2203         }
2204         | number_expression '-' number_term {
2205                 $$ = scm_difference ($1, $3);
2206         }
2207         | number_term
2208         ;
2209
2210 number_term:
2211         number_factor {
2212                 $$ = $1;
2213         }
2214         | number_factor '*' number_factor {
2215                 $$ = scm_product ($1, $3);
2216         }
2217         | number_factor '/' number_factor {
2218                 $$ = scm_divide ($1, $3);
2219         }
2220         ;
2221
2222 number_factor:
2223         '-'  number_factor { /* %prec UNARY_MINUS */
2224                 $$ = scm_difference ($2, SCM_UNDEFINED);
2225         }
2226         | bare_number
2227         ;
2228
2229
2230 bare_number:
2231         UNSIGNED        {
2232                 $$ = scm_int2num ($1);
2233         }
2234         | REAL          {
2235                 $$ = $1;
2236         }
2237         | NUMBER_IDENTIFIER             {
2238                 $$ = $1;
2239         }
2240         | REAL NUMBER_IDENTIFIER        {
2241                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2242         }
2243         | UNSIGNED NUMBER_IDENTIFIER    {
2244                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2245         }
2246         ;
2247
2248
2249 bare_unsigned:
2250         UNSIGNED {
2251                         $$ = $1;
2252         }
2253         | DIGIT {
2254                 $$ = $1;
2255         }
2256         ;
2257
2258 bare_int:
2259         bare_number {
2260                 if (scm_integer_p ($1) == SCM_BOOL_T)
2261                 {
2262                         int k = ly_scm2int ($1);
2263                         $$ = k;
2264                 } else
2265                 {
2266                         THIS->parser_error (_ ("need integer number arg"));
2267                         $$ = 0;
2268                 }
2269         }
2270         | '-' bare_int {
2271                 $$ = -$2;
2272         }
2273         ;
2274
2275
2276 string:
2277         STRING          {
2278                 $$ = $1;
2279         }
2280         | STRING_IDENTIFIER     {
2281                 $$ = $1;
2282         }
2283         | string '+' string {
2284                 $$ = scm_string_append (scm_list_2 ($1, $3));
2285         }
2286         ;
2287
2288
2289 exclamations:
2290                 { $$ = 0; }
2291         | exclamations '!'      { $$ ++; }
2292         ;
2293
2294 questions:
2295                 { $$ = 0; }
2296         | questions '?' { $$ ++; }
2297         ;
2298
2299
2300
2301 full_markup:
2302         MARKUP_IDENTIFIER {
2303                 $$ = $1;
2304         }
2305         | MARKUP
2306                 { THIS->lexer_->push_markup_state (); }
2307         markup
2308                 { $$ = $3;
2309                   THIS->lexer_->pop_state ();
2310                 }
2311         ;
2312
2313
2314 /*
2315 This should be done more dynamically if possible.
2316 */
2317 markup:
2318         STRING {
2319                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2320         }
2321         | MARKUP_HEAD_EMPTY {
2322                 $$ = scm_list_1 ($1);
2323         }
2324         | MARKUP_HEAD_MARKUP0 markup {
2325                 $$ = scm_list_2 ($1, $2);
2326         }
2327         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2328                 $$ = scm_list_3 ($1, $2, $3);
2329         }
2330         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2331                 $$ = scm_list_3 ($1, $2, $3);
2332         }
2333         | markup_line {
2334                 $$ = $1;
2335         }
2336         | MARKUP_HEAD_LIST0 markup_list {
2337                 $$ = scm_list_2 ($1,$2);
2338         }
2339         | MARKUP_HEAD_SCM0 embedded_scm {
2340                 $$ = scm_list_2 ($1, $2);
2341         }
2342         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2343                 $$ = scm_list_4 ($1, $2, $3, $4);
2344         }
2345         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2346                 $$ = scm_list_4 ($1, $2, $3, $4);
2347         }
2348         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2349                 $$ = scm_list_3 ($1, $2, $3);
2350         }
2351         | MARKUP_IDENTIFIER {
2352                 $$ = $1;
2353         }
2354         | STRING_IDENTIFIER {
2355                 $$ = $1;
2356         }
2357         ;
2358
2359 markup_list:
2360         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2361         ;
2362
2363 markup_line:
2364         '{' markup_list_body '}' {
2365                 SCM line = ly_scheme_function ("line-markup");
2366
2367                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2368         }
2369         ;
2370
2371 markup_list_body:
2372         /**/ {  $$ = SCM_EOL; }
2373         | markup_list_body markup {
2374                 $$ = scm_cons ($2, $1);
2375         }
2376         ;
2377
2378
2379 %%
2380
2381 void
2382 My_lily_parser::set_yydebug (bool )
2383 {
2384 #if 0
2385         yydebug = 1;
2386 #endif
2387 }
2388
2389 void
2390 My_lily_parser::do_yyparse ()
2391 {
2392         yyparse ((void*)this);
2393 }
2394
2395
2396 /*
2397 Should make this optional?    It will also complain when you do
2398
2399         [s4]
2400
2401 which is entirely legitimate.
2402
2403 Or we can scrap it. Barchecks should detect wrong durations, and
2404 skipTypesetting speeds it up a lot.
2405 */
2406
2407 void
2408 My_lily_parser::beam_check (SCM dur)
2409 {
2410   Duration *d = unsmob_duration (dur);
2411   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2412     {
2413       Music *m = unsmob_music (last_beam_start_);
2414       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2415     }
2416   last_beam_start_ = SCM_EOL;
2417 }
2418
2419
2420
2421
2422 /*
2423
2424 It is a little strange to have this function in this file, but
2425 otherwise, we have to import music classes into the lexer.
2426
2427 */
2428 int
2429 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2430 {
2431         if (ly_c_string_p (sid)) {
2432                 *destination = sid;
2433                 return STRING_IDENTIFIER;
2434         } else if (ly_c_number_p (sid)) {
2435                 *destination = sid;
2436                 return NUMBER_IDENTIFIER;
2437         } else if (unsmob_context_def (sid)) {
2438                 *destination = unsmob_context_def (sid)->clone_scm ();
2439                 return CONTEXT_DEF_IDENTIFIER;
2440         } else if (unsmob_score (sid)) {
2441                 Score *sc = new Score (*unsmob_score (sid));
2442                 *destination = sc->self_scm ();
2443                 return SCORE_IDENTIFIER;
2444         } else if (Music *mus = unsmob_music (sid)) {
2445                 mus = mus->clone ();
2446                 *destination = mus->self_scm ();
2447                 unsmob_music (*destination)->
2448                         set_property ("origin", make_input (last_input_));
2449                 return dynamic_cast<Event*> (mus)
2450                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2451         } else if (unsmob_duration (sid)) {
2452                 *destination = unsmob_duration (sid)->smobbed_copy ();
2453                 return DURATION_IDENTIFIER;
2454         } else if (unsmob_music_output_def (sid)) {
2455                 Music_output_def *p = unsmob_music_output_def (sid);
2456                 p = p->clone ();
2457
2458                 *destination = p->self_scm ();
2459                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2460         } else if (Text_item::markup_p (sid)) {
2461                 *destination = sid;
2462                 return MARKUP_IDENTIFIER;
2463         }
2464
2465         return -1;
2466 }
2467
2468 Music *
2469 property_op_to_music (SCM op)
2470 {
2471         Music *m = 0;
2472         SCM tag = ly_car (op);
2473         SCM symbol = ly_cadr (op);
2474         SCM args = ly_cddr (op);
2475         SCM grob_val = SCM_UNDEFINED;
2476         SCM grob_sym = SCM_UNDEFINED;
2477         SCM val = SCM_UNDEFINED;
2478
2479         if (tag == ly_symbol2scm ("assign"))
2480                 {
2481                 m = MY_MAKE_MUSIC ("PropertySet");
2482                 val = ly_car (args);
2483                 }
2484         else if (tag == ly_symbol2scm ("unset"))
2485                 m = MY_MAKE_MUSIC ("PropertyUnset");
2486         else if (tag == ly_symbol2scm ("poppush")
2487                  || tag == ly_symbol2scm ("push"))
2488                 {
2489                 m = MY_MAKE_MUSIC ("OverrideProperty");
2490                 grob_sym = ly_car (args);
2491                 grob_val = ly_cadr (args);
2492                 }
2493         else if (tag == ly_symbol2scm ("pop")) {
2494                 m = MY_MAKE_MUSIC ("RevertProperty");
2495                 grob_sym = ly_car (args);
2496                 }
2497
2498         m->set_property ("symbol", symbol);
2499
2500         if (val != SCM_UNDEFINED)
2501                 m->set_property ("value", val);
2502         if (grob_val != SCM_UNDEFINED)
2503                 m->set_property ("grob-value", grob_val);
2504
2505         if (grob_sym != SCM_UNDEFINED)
2506                 {
2507                 bool itc = internal_type_checking_global_b;
2508                 /* UGH.
2509                 */
2510                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2511                 if (autobeam)
2512                         internal_type_checking_global_b = false;
2513                 m->set_property ("grob-property", grob_sym);
2514                 if (autobeam)
2515                         internal_type_checking_global_b = itc;
2516                 }
2517
2518         if (op == ly_symbol2scm ("poppush"))
2519                 m->set_property ("pop-first", SCM_BOOL_T);
2520
2521
2522         return m;
2523 }
2524
2525 Music*
2526 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2527 {
2528         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2529
2530         csm->set_property ("element", m->self_scm ());
2531         scm_gc_unprotect_object (m->self_scm ());
2532
2533         csm->set_property ("context-type",
2534                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2535         csm->set_property ("property-operations", ops);
2536
2537         if (ly_c_string_p (id))
2538                 csm->set_property ("context-id", id);
2539         return csm;
2540 }
2541
2542
2543 SCM
2544 get_next_unique_context ()
2545 {
2546         static int new_context_count;
2547
2548         char s[1024];
2549         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2550
2551         return scm_makfrom0str (s);
2552 }
2553