lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29
  30 #include "context-def.hh"
  31 #include "dimensions.hh"
  32 #include "event.hh"
  33 #include "file-path.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "lily-lexer.hh"
  44 #include "lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "output-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((Lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (scm_is_symbol (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (scm_is_symbol (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
 123         p->internal_set_property (scm_caar (k), scm_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (scm_is_pair (x) && ly_c_procedure_p (scm_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left ADDLYRICS
 193
 194 %union {
 195         Book *book;
 196         Output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         Lily_parser *pars = (Lily_parser*) v;
 209         Lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226   (what? --hwn)
 227
 228 3. \markup { }
 229
 230   (what? --hwn)
 231
 232
 233 4.  \repeat
 234         \repeat .. \alternative
 235
 236
 237     \repeat { \repeat .. \alternative }
 238
 239 or
 240
 241     \repeat { \repeat } \alternative
 242
 243 )
 244  */
 245
 246
 247 %pure_parser
 248
 249 %token ACCEPTS
 250 %token ADDQUOTE
 251 %token LYRICSTO
 252 %token ALIAS
 253 %token ALTERNATIVE
 254 %token BAR
 255 %token BOOK
 256 %token CHANGE
 257 %token CHORDMODIFIERS
 258 %token CHORDS
 259 %token CHORDMODE
 260 %token DOUBLE_ANGLE_OPEN
 261 %token DOUBLE_ANGLE_CLOSE
 262 %token CLEF
 263 %token COMMANDSPANREQUEST
 264 %token CONSISTS
 265 %token CONTEXT
 266 %token DEFAULT
 267 %token DENIES
 268 %token DESCRIPTION
 269 %token EXTENDER
 270 %token FIGURES
 271 %token FIGUREMODE
 272 %token FIGURE_OPEN FIGURE_CLOSE
 273 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 274 %token GROBDESCRIPTIONS
 275 %token HEADER
 276 %token HYPHEN
 277 %token INVALID
 278 %token KEY
 279 %token LAYOUT
 280 %token LYRICS
 281 %token LYRICMODE
 282 %token MARK
 283 %token MIDI
 284 %token MULTI_MEASURE_REST
 285 %token NAME
 286 %token NEWCONTEXT
 287 %token NOTEMODE
 288 %token OCTAVE
 289 %token ONCE
 290 %token OVERRIDE SET REVERT
 291 %token PAPER
 292 %token PARTIAL
 293 %token QUOTE
 294 %token RELATIVE
 295 %token REMOVE
 296 %token REPEAT
 297 %token REST
 298 %token SCM_T
 299 %token SCORE
 300 %token SEQUENTIAL
 301 %token ADDLYRICS
 302 %token SIMULTANEOUS
 303 %token SKIP
 304 %token SPANREQUEST
 305 %token TAG
 306 %token TEMPO
 307 %token TIMES
 308 %token TIME_T
 309 %token TRANSPOSE
 310 %token TRANSPOSITION
 311 %token TYPE
 312 %token UNSET
 313 %token WITH
 314 %token MARKUP
 315
 316 /* escaped */
 317 /* FIXME: this sucks.  The user will get to see these names:
 318     syntax error, unexpected E_CHAR:
 319                 \
 320                  %%
 321   */
 322
 323 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 324 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 325 %token E_BACKSLASH
 326 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 327 %token FIGURE_SPACE
 328
 329 %token <i>      DIGIT
 330 %token <i>      UNSIGNED
 331 %token <i> E_UNSIGNED
 332 %token <id>     IDENTIFIER
 333 %token <scm>    CHORDMODIFIER_PITCH
 334 %token <scm>    DRUM_PITCH
 335 %token <scm>    DURATION_IDENTIFIER
 336 %token <scm>    EVENT_IDENTIFIER
 337 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 338 %token <scm>    NOTENAME_PITCH
 339 %token <scm>    NUMBER_IDENTIFIER
 340 %token <scm>    OUTPUT_DEF_IDENTIFIER
 341 %token <scm>    RESTNAME
 342 %token <scm> LYRICS_STRING
 343 %token <scm>    SCM_T
 344 %token <scm>    SCORE_IDENTIFIER
 345 %token <scm>    STRING
 346 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 347 %token <scm>    TONICNAME_PITCH
 348 %token <scm>    CHORD_MODIFIER
 349 %token <scm>    FRACTION
 350 %token <scm>   REAL
 351 %token <scm> MARKUP_HEAD_EMPTY
 352 %token <scm> MARKUP_HEAD_MARKUP0
 353 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 354 %token <scm> MARKUP_HEAD_SCM0
 355 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 356 %token <scm> MARKUP_HEAD_SCM0_SCM1
 357 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 358 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 359 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 360 %token <scm> MUSIC_FUNCTION
 361 %token <scm> MUSIC_FUNCTION_MUSIC
 362 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 363 %token <scm> MUSIC_FUNCTION_SCM
 364 %token <scm> MUSIC_FUNCTION_SCM_SCM
 365 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 366 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 367 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 368
 369 %token DRUMS
 370 %token DRUMMODE
 371
 372
 373 %type <book>    book_block book_body
 374 %type <i>       bare_int  bare_unsigned
 375 %type <i>       exclamations questions dots optional_rest
 376 %type <i>       script_dir
 377 %type <i>       sub_quotes sup_quotes
 378 %type <i>       tremolo_type
 379 %type <i>       bass_mod
 380
 381 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 382 %type <music>   Grouped_music_list
 383 %type <music>   Music Sequential_music Simultaneous_music
 384 %type <music>   Repeated_music
 385 %type <music>   command_req
 386 %type <music>   gen_text_def direction_less_event direction_reqd_event
 387 %type <music>   music_property_def context_change
 388 %type <music>   note_chord_element chord_body chord_body_element
 389 %type <music>   post_event tagged_post_event
 390 %type <music>   relative_music re_rhythmed_music
 391 %type <music>   simple_element event_chord command_element
 392 %type <music>   string_number_event
 393 %type <music>   toplevel_music
 394 %type <music>   tempo_event
 395
 396 %type <outputdef>       output_def_body output_def_head
 397 %type <outputdef> output_def paper_block
 398
 399 %type <scm>     Music_list
 400 %type <scm>     chord_body_elements
 401 %type <scm>     chord_item chord_items chord_separator new_chord
 402 %type <scm>     context_def_spec_block context_def_spec_body
 403 %type <scm>     context_mod context_def_mod optional_context_mod
 404 %type <scm>     context_prop_spec
 405 %type <scm>     direction_less_char
 406 %type <scm>     duration_length fraction
 407 %type <scm>     embedded_scm scalar
 408 %type <scm>     identifier_init
 409 %type <scm>     lilypond_header lilypond_header_body
 410 %type <scm>     new_lyrics
 411 %type <scm>     post_events
 412 %type <scm>     property_operation
 413 %type <scm>     script_abbreviation
 414 %type <scm>     simple_string
 415 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 416 %type <scm>     steno_tonic_pitch
 417 %type <scm>     step_number step_numbers
 418 %type <scm>     string bare_number number_expression number_term number_factor
 419 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 420 %type <scm>     context_mod_list
 421 %type <scm>     octave_check
 422 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 423 %type <scm>     Generic_prefix_music_scm
 424 %type <scm>     lyric_element
 425 %type <scm>     Alternative_music
 426 %type <scm>     markup markup_line markup_list markup_list_body full_markup
 427 %type <scm>     mode_changing_head
 428 %type <scm>     mode_changing_head_with_context
 429
 430 %type <score>   score_block score_body
 431
 432
 433 %left '-' '+'
 434
 435 /* We don't assign precedence to / and *, because we might need varied
 436 prec levels in different prods */
 437
 438 %left UNARY_MINUS
 439
 440 %%
 441
 442 lilypond:       /* empty */
 443         | lilypond toplevel_expression {
 444         }
 445         | lilypond assignment {
 446         }
 447         | lilypond error {
 448                 THIS->error_level_ = 1;
 449         }
 450         | lilypond INVALID      {
 451                 THIS->error_level_ = 1;
 452         }
 453         ;
 454
 455 toplevel_expression:
 456         lilypond_header {
 457                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 458         }
 459         | add_quote {
 460
 461         }
 462         | book_block {
 463                 Book *book = $1;
 464                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 465                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 466                 scm_gc_unprotect_object (book->self_scm ());
 467         }
 468         | score_block {
 469                 Score *score = $1;
 470
 471                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 472                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 473                 scm_gc_unprotect_object (score->self_scm ());
 474         }
 475         | toplevel_music {
 476                 Music *music = $1;
 477                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 478                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 479                 scm_gc_unprotect_object (music->self_scm ());
 480         }
 481         | output_def {
 482                 SCM id = SCM_EOL;
 483                 Output_def * od = $1;
 484
 485                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 486                         id = ly_symbol2scm ("$defaultpaper");
 487                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 488                         id = ly_symbol2scm ("$defaultmidi");
 489                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 490                         id = ly_symbol2scm ("$defaultlayout");
 491
 492                 THIS->lexer_->set_identifier (id, od->self_scm ());
 493                 scm_gc_unprotect_object (od->self_scm ());
 494         }
 495         ;
 496
 497 toplevel_music:
 498         Composite_music {
 499         }
 500         ;
 501
 502 embedded_scm:
 503         SCM_T
 504         | SCM_IDENTIFIER
 505         ;
 506
 507
 508 lilypond_header_body:
 509         {
 510                 $$ = ly_make_anonymous_module (safe_global_b);
 511                 THIS->lexer_->add_scope ($$);
 512         }
 513         | lilypond_header_body assignment  {
 514
 515         }
 516         ;
 517
 518 lilypond_header:
 519         HEADER '{' lilypond_header_body '}'     {
 520                 $$ = THIS->lexer_->remove_scope ();
 521         }
 522         ;
 523
 524
 525 /*
 526         DECLARATIONS
 527 */
 528 assignment:
 529         STRING {
 530                 THIS->push_spot ();
 531         }
 532         /* cont */ '=' identifier_init  {
 533
 534         /*
 535                 Should find generic way of associating input with objects.
 536         */
 537                 Input ip = THIS->pop_spot ();
 538
 539                 if (! is_regular_identifier ($1))
 540                 {
 541                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 542                 }
 543
 544                 THIS->lexer_->set_identifier ($1, $4);
 545
 546 /*
 547  TODO: devise standard for protection in parser.
 548
 549   The parser stack lives on the C-stack, which means that
 550 all objects can be unprotected as soon as they're here.
 551
 552 */
 553         }
 554         | embedded_scm { }
 555         ;
 556
 557
 558 identifier_init:
 559         score_block {
 560                 $$ = $1->self_scm ();
 561                 scm_gc_unprotect_object ($$);
 562         }
 563         | output_def {
 564                 $$ = $1->self_scm ();
 565                 scm_gc_unprotect_object ($$);
 566         }
 567         | context_def_spec_block {
 568                 $$ = $1;
 569         }
 570         | Music  {
 571                 $$ = $1->self_scm ();
 572                 scm_gc_unprotect_object ($$);
 573         }
 574         | post_event {
 575                 $$ = $1->self_scm ();
 576                 scm_gc_unprotect_object ($$);
 577         }
 578         | number_expression {
 579                 $$ = $1;
 580         }
 581         | string {
 582                 $$ = $1;
 583         }
 584         | embedded_scm {
 585                 $$ = $1;
 586         }
 587         | full_markup {
 588                 $$ = $1;
 589         }
 590         | DIGIT {
 591                 $$ = scm_int2num ($1);
 592         }
 593         ;
 594
 595 context_def_spec_block:
 596         CONTEXT '{' context_def_spec_body '}'
 597                 {
 598                 $$ = $3;
 599         }
 600         ;
 601
 602 context_def_spec_body:
 603         /**/ {
 604                 $$ = Context_def::make_scm ();
 605                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 606         }
 607         | CONTEXT_DEF_IDENTIFIER {
 608                 $$ = $1;
 609                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 610         }
 611         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 612                 Context_def*td = unsmob_context_def ($$);
 613
 614                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 615                         SCM tag = scm_caar (p);
 616
 617                         /* TODO: should make new tag "grob-definition" ? */
 618                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 619                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 620                 }
 621         }
 622         | context_def_spec_body context_mod {
 623                 unsmob_context_def ($$)->add_context_mod ($2);
 624         }
 625         ;
 626
 627
 628
 629 book_block:
 630         BOOK {
 631                 THIS->push_spot ();
 632         }
 633         /*cont*/ '{' book_body '}'      {
 634                 THIS->pop_spot ();
 635                 $$ = $4;
 636         }
 637         ;
 638
 639 /* FIXME:
 640    * Use 'handlers' like for toplevel-* stuff?
 641    * grok \layout and \midi?  */
 642 book_body:
 643         {
 644                 $$ = new Book;
 645                 $$->set_spot (THIS->here_input ());
 646                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 647                 scm_gc_unprotect_object ($$->paper_->self_scm ());
 648                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 649         }
 650         | book_body paper_block {
 651                 $$->paper_ = $2;
 652                 scm_gc_unprotect_object ($2->self_scm ());
 653         }
 654         | book_body score_block {
 655                 Score *score = $2;
 656                 $$->scores_.push (score);
 657                 scm_gc_unprotect_object (score->self_scm ());
 658         }
 659         | book_body lilypond_header {
 660                 $$->header_ = $2;
 661         }
 662         | book_body error {
 663                 $$->paper_ = 0;
 664                 $$->scores_.clear();
 665         }
 666         ;
 667
 668 score_block:
 669         SCORE {
 670                 THIS->push_spot ();
 671         }
 672         /*cont*/ '{' score_body '}'     {
 673                 THIS->pop_spot ();
 674                 $$ = $4;
 675         }
 676         ;
 677
 678 score_body:
 679         /**/    {
 680                 $$ = new Score;
 681
 682                 $$->set_spot (THIS->here_input ());
 683         }
 684         | SCORE_IDENTIFIER {
 685                 $$ = new Score ( *unsmob_score ($1));
 686                 $$->set_spot (THIS->here_input ());
 687         }
 688         | score_body Music {
 689                 SCM m = $2->self_scm ();
 690                 scm_gc_unprotect_object (m);
 691                 $$->set_music (m, THIS->self_scm ());
 692         }
 693         | score_body lilypond_header    {
 694                 $$->header_ = $2;
 695         }
 696         | score_body output_def {
 697                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 698                 {
 699                         THIS->parser_error (_("\\paper cannot be in \\score. Use \\layout instead"));
 700
 701                 }
 702                 else
 703                 {
 704                         $$->defs_.push ($2);
 705                 }
 706                 scm_gc_unprotect_object ($2->self_scm ());
 707         }
 708         | score_body error {
 709                 $$->error_found_ = true;
 710         }
 711         ;
 712
 713
 714 /*
 715         OUTPUT DEF
 716 */
 717
 718 paper_block:
 719         output_def {
 720                 $$ = $1;
 721                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 722                 {
 723                         THIS->parser_error (_("Need \\paper for paper block."));
 724                         $$ = get_paper (THIS);
 725                 }
 726         }
 727         ;
 728
 729
 730 output_def:
 731         output_def_body '}' {
 732                 $$ = $1;
 733
 734                 THIS->lexer_->remove_scope ();
 735                 THIS->lexer_->pop_state ();
 736         }
 737         ;
 738
 739 output_def_head:
 740         PAPER {
 741                 $$ = get_paper (THIS);
 742                 $$->input_origin_ = THIS->here_input ();
 743                 THIS->lexer_->add_scope ($$->scope_);
 744         }
 745         | MIDI    {
 746                 Output_def *p = get_midi (THIS);
 747                 $$ = p;
 748                 THIS->lexer_->add_scope (p->scope_);
 749         }
 750         | LAYOUT        {
 751                 Output_def *p = get_layout (THIS);
 752
 753                 THIS->lexer_->add_scope (p->scope_);
 754                 $$ = p;
 755         }
 756         ;
 757
 758
 759 output_def_body:
 760         output_def_head '{' {
 761                 $$ = $1;
 762                 $$->input_origin_.set_spot (THIS->here_input ());
 763                 THIS->lexer_->push_initial_state ();
 764         }
 765         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 766                 scm_gc_unprotect_object ($1->self_scm ());
 767                 Output_def *o = unsmob_output_def ($3);
 768                 o->input_origin_.set_spot (THIS->here_input ());
 769                 $$ = o;
 770                 THIS->lexer_->remove_scope ();
 771                 THIS->lexer_->add_scope (o->scope_);
 772                 THIS->lexer_->push_initial_state ();
 773         }
 774         | output_def_body assignment  {
 775
 776         }
 777         | output_def_body context_def_spec_block        {
 778                 assign_context_def ($$, $2);
 779         }
 780         | output_def_body tempo_event  {
 781                 /*
 782                         junk this ? there already is tempo stuff in
 783                         music.
 784                 */
 785                 int m = scm_to_int ($2->get_property ("metronome-count"));
 786                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 787                 set_tempo ($$, d->get_length (), m);
 788                 scm_gc_unprotect_object ($2->self_scm ());
 789         }
 790         | output_def_body error {
 791
 792         }
 793         ;
 794
 795 tempo_event:
 796         TEMPO steno_duration '=' bare_unsigned  {
 797                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 798                 $$->set_property ("tempo-unit", $2);
 799                 $$->set_property ("metronome-count", scm_int2num ( $4));
 800         }
 801         ;
 802
 803 /*
 804 The representation of a  list is the
 805
 806   (LIST . LAST-CONS)
 807
 808  to have efficient append.  */
 809
 810 Music_list:
 811         /* empty */ {
 812                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 813         }
 814         | Music_list Music {
 815                 SCM s = $$;
 816                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 817                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 818
 819                 if (scm_is_pair (scm_cdr (s)))
 820                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 821                 else
 822                         scm_set_car_x (s, c); /* set first cons */
 823                 scm_set_cdr_x (s, c);  /* remember last cell */
 824         }
 825         | Music_list embedded_scm {
 826
 827         }
 828         | Music_list error {
 829                 Music * m = MY_MAKE_MUSIC("Music");
 830                 // ugh. code dup
 831                 m->set_property ("error-found", SCM_BOOL_T);
 832                 SCM s = $$;
 833                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 834                 scm_gc_unprotect_object (m->self_scm ()); /* UGH */
 835
 836                 if (scm_is_pair (scm_cdr (s)))
 837                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 838                 else
 839                         scm_set_car_x (s, c); /* set first cons */
 840                 scm_set_cdr_x (s, c);  /* remember last cell */
 841         }
 842         ;
 843
 844 Music:
 845         Simple_music
 846         | Composite_music
 847         ;
 848
 849 Alternative_music:
 850         /* empty */ {
 851                 $$ = SCM_EOL;
 852         }
 853         | ALTERNATIVE '{' Music_list '}' {
 854                 $$ = $3;
 855         }
 856         ;
 857
 858
 859 Repeated_music:
 860         REPEAT simple_string bare_unsigned Music Alternative_music
 861         {
 862                 Music *beg = $4;
 863                 int times = $3;
 864                 SCM alts = scm_is_pair ($5) ? scm_car ($5) : SCM_EOL;
 865                 if (times < scm_ilength (alts)) {
 866                   unsmob_music (scm_car (alts))
 867                     ->origin ()->warning (
 868                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 869                   alts = ly_truncate_list (times, alts);
 870                 }
 871
 872
 873                 SCM proc = ly_scheme_function ("make-repeated-music");
 874
 875                 SCM mus = scm_call_1 (proc, $2);
 876                 scm_gc_protect_object (mus); // UGH.
 877                 Music *r = unsmob_music (mus);
 878                 if (beg)
 879                         {
 880                         r-> set_property ("element", beg->self_scm ());
 881                         scm_gc_unprotect_object (beg->self_scm ());
 882                         }
 883                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 884
 885                 r-> set_property ("elements",alts);
 886                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 887                         /*
 888                         TODO: move this code to Scheme.
 889                         */
 890
 891                         /*
 892                         we can not get durations and other stuff correct down the line, so we have to
 893                         add to the duration log here.
 894                         */
 895                         SCM func = ly_scheme_function ("shift-duration-log");
 896
 897                         int dots = ($3 % 3) ? 0 : 1;
 898                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 899
 900                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 901
 902                         if (seq) {
 903                                 int list_len = scm_ilength (seq->music_list ());
 904                                 if (list_len != 2)
 905                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 906                                 shift -= 1;
 907                                 r->compress (Moment (Rational (1, list_len)));
 908                                 }
 909                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 910
 911                 }
 912                 r->set_spot (*$4->origin ());
 913
 914                 $$ = r;
 915         }
 916         ;
 917
 918 Sequential_music:
 919         SEQUENTIAL '{' Music_list '}'           {
 920                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 921                 $$->set_property ("elements", scm_car ($3));
 922                 $$->set_spot (THIS->here_input ());
 923         }
 924         | '{' Music_list '}'            {
 925                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 926                 $$->set_property ("elements", scm_car ($2));
 927                 $$->set_spot (THIS->here_input ());
 928         }
 929         ;
 930
 931 Simultaneous_music:
 932         SIMULTANEOUS '{' Music_list '}'{
 933                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 934                 $$->set_property ("elements", scm_car ($3));
 935                 $$->set_spot (THIS->here_input ());
 936
 937         }
 938         | simul_open Music_list simul_close     {
 939                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 940                 $$->set_property ("elements", scm_car ($2));
 941                 $$->set_spot (THIS->here_input ());
 942         }
 943         ;
 944
 945 Simple_music:
 946         event_chord             { $$ = $1; }
 947         | MUSIC_IDENTIFIER {
 948                 $$ = unsmob_music ($1);
 949         }
 950         | music_property_def
 951         | context_change
 952         ;
 953
 954
 955 optional_context_mod:
 956         /**/ { $$ = SCM_EOL; }
 957         | WITH { THIS->lexer_->push_initial_state (); }
 958         '{' context_mod_list '}'
 959         {
 960                 THIS->lexer_->pop_state ();
 961                 $$ = $4;
 962         }
 963         ;
 964
 965 context_mod_list:
 966         /* */  { $$ = SCM_EOL; }
 967         | context_mod_list context_mod  {
 968                  $$ = scm_cons ($2, $1);
 969         }
 970         ;
 971
 972
 973 Composite_music:
 974         Prefix_composite_music { $$ = $1; }
 975         | Grouped_music_list { $$ = $1; }
 976         ;
 977
 978 Grouped_music_list:
 979         Simultaneous_music              { $$ = $1; }
 980         | Sequential_music              { $$ = $1; }
 981         ;
 982
 983 Generic_prefix_music_scm:
 984         MUSIC_FUNCTION {
 985                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 986         }
 987         | MUSIC_FUNCTION_SCM {
 988                 THIS->push_spot ();
 989         } embedded_scm {
 990                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 991         }
 992         | MUSIC_FUNCTION_MUSIC {
 993                 THIS->push_spot ();
 994         } Music {
 995                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 996                 scm_gc_unprotect_object ($3->self_scm ());
 997         }
 998         | MUSIC_FUNCTION_SCM_MUSIC {
 999                 THIS->push_spot ();
1000         }  embedded_scm Music {
1001                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
1002                 scm_gc_unprotect_object ($4->self_scm ());
1003         }
1004         | MUSIC_FUNCTION_SCM_SCM {
1005                 THIS->push_spot ();
1006         }  embedded_scm embedded_scm {
1007                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4);
1008         }
1009         | MUSIC_FUNCTION_MUSIC_MUSIC {
1010                 THIS->push_spot ();
1011         }  Music  Music {
1012                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
1013                 scm_gc_unprotect_object ($3->self_scm ());
1014                 scm_gc_unprotect_object ($4->self_scm ());
1015         }
1016         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
1017                 THIS->push_spot ();
1018         } embedded_scm Music Music {
1019                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
1020                         $3, $4->self_scm (), $5->self_scm ());
1021                 scm_gc_unprotect_object ($5->self_scm ());
1022                 scm_gc_unprotect_object ($4->self_scm ());
1023         }
1024         ;
1025
1026 Generic_prefix_music:
1027         Generic_prefix_music_scm {
1028                 SCM func = scm_car ($1);
1029                 Input *loc = unsmob_input (scm_cadr ($1));
1030                 SCM args = scm_cddr ($1);
1031                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1032                 int k = 0;
1033                 bool ok  = true;
1034                 for (SCM s = sig, t = args;
1035                         ok && scm_is_pair (s) && scm_is_pair (t);
1036                         s = scm_cdr (s), t = scm_cdr (t)) {
1037                         k++;
1038                         if (scm_call_1 (scm_car (s), scm_car (t)) != SCM_BOOL_T)
1039                         {
1040                                 loc->error (_f ("Argument %d failed typecheck", k));
1041                                 THIS->error_level_ = 1;
1042                                 ok = false;
1043                         }
1044                 }
1045                 SCM m = SCM_EOL;
1046                 if (ok)
1047                         m = scm_apply_0 (func, scm_cdr ($1));
1048                 if (unsmob_music (m))
1049                         {
1050                         $$ = unsmob_music (m);
1051                         scm_gc_protect_object (m);
1052                         }
1053                 else
1054                         {
1055                         if (ok)
1056                                 loc->error (_ ("Music head function should return Music object."));
1057                         $$ = MY_MAKE_MUSIC ("Music");
1058                         }
1059                 $$->set_spot (*loc);
1060         }
1061         ;
1062
1063
1064 Prefix_composite_music:
1065         Generic_prefix_music {
1066                 $$ = $1;
1067         }
1068         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1069                 $$ = context_spec_music ($2, $4, $6, $5);
1070
1071         }
1072         | CONTEXT simple_string optional_context_mod Music {
1073                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1074         }
1075         | NEWCONTEXT simple_string optional_context_mod Music {
1076                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1077                         $3);
1078         }
1079
1080         | TIMES {
1081                 THIS->push_spot ();
1082         }
1083         /* CONTINUED */
1084                 fraction Music
1085
1086         {
1087                 int n = scm_to_int (scm_car ($3)); int d = scm_to_int (scm_cdr ($3));
1088                 Music *mp = $4;
1089
1090                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1091                 $$->set_spot (THIS->pop_spot ());
1092
1093                 $$->set_property ("element", mp->self_scm ());
1094                 scm_gc_unprotect_object (mp->self_scm ());
1095                 $$->set_property ("numerator", scm_int2num (n));
1096                 $$->set_property ("denominator", scm_int2num (d));
1097                 $$->compress (Moment (Rational (n,d)));
1098
1099         }
1100         | Repeated_music                { $$ = $1; }
1101         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1102                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1103                 Music *p = $4;
1104                 Pitch from = *unsmob_pitch ($2);
1105                 Pitch to = *unsmob_pitch ($3);
1106
1107                 p->transpose (pitch_interval (from, to));
1108                 $$->set_property ("element", p->self_scm ());
1109                 scm_gc_unprotect_object (p->self_scm ());
1110         }
1111         | mode_changing_head Grouped_music_list {
1112                 if ($1 == ly_symbol2scm ("figures"))
1113                 {
1114                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1115                   chm->set_property ("element", $2->self_scm ());
1116                   $$ = chm;
1117                   scm_gc_unprotect_object ($2->self_scm ());
1118                 }
1119                 else
1120                 {
1121                   $$ = $2;
1122                 }
1123                 THIS->lexer_->pop_state ();
1124         }
1125         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1126                 $$ = context_spec_music ($1, get_next_unique_context (),
1127                                          $3, $2);
1128                 if ($1 == ly_symbol2scm ("FiguredBass"))
1129                 {
1130                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1131                   chm->set_property ("element", $$->self_scm ());
1132                   scm_gc_unprotect_object ($$->self_scm ());
1133                   $$ = chm;
1134                 }
1135                 THIS->lexer_->pop_state ();
1136         }
1137         | relative_music        { $$ = $1; }
1138         | re_rhythmed_music     { $$ = $1; }
1139         | TAG embedded_scm Music {
1140                 tag_music ($3, $2, THIS->here_input ());
1141                 $$ = $3;
1142         }
1143         ;
1144
1145 mode_changing_head:
1146         NOTEMODE {
1147                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1148                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1149
1150                 $$ = ly_symbol2scm ("notes");
1151         }
1152         | DRUMMODE
1153                 {
1154                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1155                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1156
1157                 $$ = ly_symbol2scm ("drums");
1158         }
1159         | FIGUREMODE {
1160                 THIS->lexer_->push_figuredbass_state ();
1161
1162                 $$ = ly_symbol2scm ("figures");
1163         }
1164         | CHORDMODE {
1165                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1166                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1167                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1168                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1169                 $$ = ly_symbol2scm ("chords");
1170
1171         }
1172         | LYRICMODE
1173                 { THIS->lexer_->push_lyric_state ();
1174                 $$ = ly_symbol2scm ("lyrics");
1175         }
1176         ;
1177
1178 mode_changing_head_with_context:
1179         DRUMS {
1180                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1181                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1182
1183                 $$ = ly_symbol2scm ("DrumStaff");
1184         }
1185         | FIGURES {
1186                 THIS->lexer_->push_figuredbass_state ();
1187
1188                 $$ = ly_symbol2scm ("FiguredBass");
1189         }
1190         | CHORDS {
1191                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1192                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1193                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1194                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1195                 $$ = ly_symbol2scm ("ChordNames");
1196         }
1197         | LYRICS
1198                 { THIS->lexer_->push_lyric_state ();
1199                 $$ = ly_symbol2scm ("Lyrics");
1200         }
1201         ;
1202
1203
1204 relative_music:
1205         RELATIVE absolute_pitch Music {
1206                 Music *m = $3;
1207                 Pitch start = *unsmob_pitch ($2);
1208                 $$ = make_music_relative (start, m);
1209                 scm_gc_unprotect_object (m->self_scm ());
1210         }
1211         | RELATIVE Composite_music {
1212                 Music *m = $2;
1213
1214                 Pitch middle_c (0, 0, 0);
1215                 $$ = make_music_relative (middle_c, m);
1216                 scm_gc_unprotect_object (m->self_scm ());
1217         }
1218         ;
1219
1220 new_lyrics:
1221         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1222         /*cont */
1223         Grouped_music_list {
1224         /* Can also use Music at the expensive of two S/Rs similar to
1225            \repeat \alternative */
1226                 THIS->lexer_->pop_state ();
1227
1228                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1229         }
1230         | new_lyrics ADDLYRICS {
1231                 THIS->lexer_->push_lyric_state ();
1232         } Grouped_music_list {
1233                 THIS->lexer_->pop_state ();
1234                 $$ = scm_cons ($4->self_scm (), $1);
1235         }
1236         ;
1237
1238 re_rhythmed_music:
1239         Grouped_music_list new_lyrics {
1240
1241                 SCM name = $1->get_property ("context-id");
1242                 //if (name == SCM_EOL)
1243                 if (!scm_is_string (name))
1244                         name = scm_makfrom0str ("");
1245
1246                 SCM context = scm_makfrom0str ("Lyrics");
1247                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1248
1249                 SCM lst = SCM_EOL;
1250                 for (SCM s = $2; scm_is_pair (s); s = scm_cdr (s))
1251                 {
1252                         Music *music = unsmob_music (scm_car (s));
1253                         Music *com = make_lyric_combine_music (name, music);
1254                         Music *csm = context_spec_music (context,
1255                                 get_next_unique_context (), com, SCM_EOL);
1256                         lst = scm_cons (csm->self_scm (), lst);
1257                 }
1258                 /* FIXME: only first lyric music is accepted,
1259                           the rest is junked */
1260                 all->set_property ("elements", scm_cons ($1->self_scm (),
1261                         lst));
1262                 $$ = all;
1263                 scm_gc_unprotect_object ($1->self_scm ());
1264         }
1265         | LYRICSTO {
1266                 THIS->lexer_->push_lyric_state ();
1267         } simple_string Music {
1268                 THIS->lexer_->pop_state ();
1269                 Music *music = $4;
1270                 SCM name = $3;
1271                 $$ = make_lyric_combine_music (name, music);
1272                 scm_gc_unprotect_object (music->self_scm ());
1273         }
1274         ;
1275
1276 context_change:
1277         CHANGE STRING '=' STRING  {
1278                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1279                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1280                 t-> set_property ("change-to-id", $4);
1281
1282                 $$ = t;
1283                 $$->set_spot (THIS->here_input ());
1284         }
1285         ;
1286
1287 property_operation:
1288         STRING '=' scalar {
1289                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1290                         scm_string_to_symbol ($1), $3);
1291         }
1292         | UNSET simple_string {
1293                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1294                         scm_string_to_symbol ($2));
1295         }
1296         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1297                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1298                         scm_string_to_symbol ($2), $3, $5);
1299         }
1300         | REVERT simple_string embedded_scm {
1301                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1302                         scm_string_to_symbol ($2), $3);
1303         }
1304         ;
1305
1306 context_def_mod:
1307         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1308         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1309
1310         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1311         | DENIES { $$ = ly_symbol2scm ("denies"); }
1312
1313         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1314         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1315         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1316         | NAME { $$ = ly_symbol2scm ("context-name"); }
1317         ;
1318
1319 context_mod:
1320         property_operation { $$ = $1; }
1321         | context_def_mod STRING {
1322                 $$ = scm_list_2 ($1, $2);
1323         }
1324         ;
1325
1326 context_prop_spec:
1327         simple_string {
1328                 if (!is_regular_identifier ($1))
1329                 {
1330                         THIS->here_input ().error (_("Grob name should be alphanumeric"));
1331                 }
1332
1333                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1334                         scm_string_to_symbol ($1));
1335         }
1336         | simple_string '.' simple_string {
1337                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1338                         scm_string_to_symbol ($3));
1339         }
1340         ;
1341
1342 music_property_def:
1343         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1344                 $$ = property_op_to_music (scm_list_4 (
1345                         ly_symbol2scm ("poppush"),
1346                         scm_cadr ($2),
1347                         $3, $5));
1348                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1349         }
1350         | REVERT context_prop_spec embedded_scm {
1351                 $$ = property_op_to_music (scm_list_3 (
1352                         ly_symbol2scm ("pop"),
1353                         scm_cadr ($2),
1354                         $3));
1355
1356                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1357         }
1358         | SET context_prop_spec '=' scalar {
1359                 $$ = property_op_to_music (scm_list_3 (
1360                         ly_symbol2scm ("assign"),
1361                         scm_cadr ($2),
1362                         $4));
1363                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1364         }
1365         | UNSET context_prop_spec {
1366                 $$ = property_op_to_music (scm_list_2 (
1367                         ly_symbol2scm ("unset"),
1368                         scm_cadr ($2)));
1369                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1370         }
1371         | ONCE music_property_def {
1372                 SCM e = $2->get_property ("element");
1373                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1374                 $$ = $2;
1375
1376         }
1377         ;
1378
1379
1380 string:
1381         STRING {
1382                 $$ = $1;
1383         }
1384         | STRING_IDENTIFIER {
1385                 $$ = $1;
1386         }
1387         | string '+' string {
1388                 $$ = scm_string_append (scm_list_2 ($1, $3));
1389         }
1390         ;
1391
1392 simple_string: STRING {
1393                 $$ = $1;
1394         }
1395         | LYRICS_STRING {
1396                 $$ = $1;
1397         }
1398         ;
1399
1400 scalar: string {
1401                 $$ = $1;
1402         }
1403         | LYRICS_STRING {
1404                 $$ = $1;
1405         }
1406         | bare_int {
1407                 $$ = scm_int2num ($1);
1408         }
1409         | embedded_scm {
1410                 $$ = $1;
1411         }
1412         | full_markup {
1413                 $$ = $1;
1414         }
1415         | DIGIT {
1416                 $$ = scm_int2num ($1);
1417         }
1418         ;
1419
1420 /*
1421
1422 pre_events doesn't contain anything. It is a trick:
1423
1424 Adding pre_events to the simple_element
1425 makes the choice between
1426
1427   string:  STRING
1428
1429 and
1430
1431   simple_element: STRING
1432
1433 a single shift/reduction conflict.
1434
1435 nevertheless, this is not very clean, and we should find a different
1436 solution.
1437
1438 */
1439 pre_events: {
1440                 THIS->push_spot ();
1441         }
1442         ;
1443
1444 event_chord:
1445         pre_events simple_element post_events   {
1446                 SCM elts = $2-> get_property ("elements");
1447
1448                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1449
1450                 $2->set_property ("elements", elts);
1451                 $$ = $2;
1452         }
1453         | command_element
1454         | note_chord_element
1455         ;
1456
1457
1458 note_chord_element:
1459         chord_body optional_notemode_duration post_events
1460         {
1461                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1462                 SCM es = $1->get_property ("elements");
1463                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1464
1465                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1466                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1467                 es = ly_append2 (es, postevs);
1468
1469                 $1-> set_property ("elements", es);
1470                 $$ = $1;
1471         }
1472         ;
1473
1474 chord_open: '<'
1475         ;
1476
1477 chord_close: '>'
1478         ;
1479
1480 simul_open: DOUBLE_ANGLE_OPEN
1481         ;
1482
1483 simul_close: DOUBLE_ANGLE_CLOSE
1484         ;
1485
1486 chord_body:
1487         chord_open chord_body_elements chord_close
1488         {
1489                 $$ = MY_MAKE_MUSIC ("EventChord");
1490                 $$->set_property ("elements",
1491                         scm_reverse_x ($2, SCM_EOL));
1492         }
1493         ;
1494
1495 chord_body_elements:
1496         /* empty */             { $$ = SCM_EOL; }
1497         | chord_body_elements chord_body_element {
1498                 $$ = scm_cons ($2->self_scm (), $1);
1499                 scm_gc_unprotect_object ($2->self_scm ());
1500         }
1501         ;
1502
1503 chord_body_element:
1504         pitch  exclamations questions octave_check post_events
1505         {
1506                 int q = $3;
1507                 int ex = $2;
1508                 SCM check = $4;
1509                 SCM post = $5;
1510
1511                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1512                 n->set_property ("pitch", $1);
1513                 if (q % 2)
1514                         n->set_property ("cautionary", SCM_BOOL_T);
1515                 if (ex % 2 || q % 2)
1516                         n->set_property ("force-accidental", SCM_BOOL_T);
1517
1518                 if (scm_is_pair (post)) {
1519                         SCM arts = scm_reverse_x (post, SCM_EOL);
1520                         n->set_property ("articulations", arts);
1521                 }
1522                 if (scm_is_number (check))
1523                 {
1524                         int q = scm_to_int (check);
1525                         n->set_property ("absolute-octave", scm_int2num (q-1));
1526                 }
1527
1528
1529                 $$ = n;
1530         }
1531         | DRUM_PITCH post_events {
1532                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1533                 n->set_property ("duration", $2);
1534                 n->set_property ("drum-type", $1);
1535                 n->set_spot (THIS->here_input ());
1536
1537                 if (scm_is_pair ($2)) {
1538                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1539                         n->set_property ("articulations", arts);
1540                 }
1541                 $$ = n;
1542         }
1543         ;
1544
1545 add_quote:
1546         ADDQUOTE string Music {
1547                 SCM adder = ly_scheme_function ("add-quotable");
1548
1549                 scm_call_2 (adder, $2, $3->self_scm ());
1550                 scm_gc_unprotect_object ($3->self_scm ());
1551         }
1552         ;
1553
1554 command_element:
1555         command_req {
1556                 $$ = MY_MAKE_MUSIC ("EventChord");
1557                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1558                 scm_gc_unprotect_object ($1->self_scm ());
1559
1560                 $$-> set_spot (THIS->here_input ());
1561                 $1-> set_spot (THIS->here_input ());
1562         }
1563         | SKIP duration_length {
1564                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1565                 skip->set_property ("duration", $2);
1566
1567                 $$ = skip;
1568         }
1569         | QUOTE STRING duration_length {
1570                 Music *quote = MY_MAKE_MUSIC ("QuoteMusic");
1571                 quote->set_property ("duration", $3);
1572                 quote->set_property ("quoted-music-name", $2);
1573                 quote->set_spot (THIS->here_input ());
1574
1575                 $$ = quote;
1576         }
1577         | OCTAVE { THIS->push_spot (); }
1578           pitch {
1579                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1580                 $$ = m;
1581                 $$->set_spot (THIS->pop_spot ());
1582                 $$->set_property ("pitch", $3);
1583         }
1584         | E_LEFTSQUARE {
1585                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1586                 m->set_property ("span-direction", scm_int2num (START));
1587                 m->set_spot (THIS->here_input ());
1588
1589                 $$ = MY_MAKE_MUSIC ("EventChord");
1590                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1591                 scm_gc_unprotect_object (m->self_scm ());
1592                 $$->set_spot (THIS->here_input ());
1593         }
1594         | E_RIGHTSQUARE {
1595                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1596                 m->set_property ("span-direction", scm_int2num (STOP));
1597                 m->set_spot (THIS->here_input ());
1598
1599                 $$ = MY_MAKE_MUSIC ("EventChord");
1600                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1601                 $$->set_spot (THIS->here_input ());
1602                 scm_gc_unprotect_object (m->self_scm ());
1603         }
1604         | E_BACKSLASH {
1605                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1606                 $$->set_spot (THIS->here_input ());
1607         }
1608         | '|'      {
1609                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1610
1611                 if (Music * m = unsmob_music (pipe))
1612                         $$ = m->clone ();
1613                 else
1614                         $$ = MY_MAKE_MUSIC ("BarCheck");
1615
1616                 $$->set_spot (THIS->here_input ());
1617         }
1618         | TRANSPOSITION pitch {
1619                 Pitch middle_c;
1620                 Pitch sounds_as_c = pitch_interval (*unsmob_pitch ($2), middle_c);
1621                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1622                                          sounds_as_c.smobbed_copy());
1623                 $$->set_spot (THIS-> here_input ());
1624                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1625                         $$, SCM_EOL);
1626         }
1627         | BAR STRING                    {
1628                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1629
1630                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1631                                         t, SCM_EOL);
1632                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1633                 $$->set_spot (THIS->here_input ());
1634                 t->set_spot (THIS->here_input ());
1635         }
1636         | PARTIAL duration_length       {
1637                 Moment m = - unsmob_duration ($2)->get_length ();
1638                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1639                 p->set_spot (THIS->here_input ());
1640                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1641                                         p, SCM_EOL);
1642                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1643                                         p, SCM_EOL);
1644                 $$ = p;
1645         }
1646         | CLEF STRING  {
1647                 SCM proc = ly_scheme_function ("make-clef-set");
1648
1649                 SCM result = scm_call_1 (proc, $2);
1650                 scm_gc_protect_object (result);
1651                 $$ = unsmob_music (result);
1652         }
1653         | TIME_T fraction  {
1654                 SCM proc= ly_scheme_function ("make-time-signature-set");
1655
1656                 SCM result = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1657                 scm_gc_protect_object (result);
1658                 $$ = unsmob_music (result);
1659         }
1660         | MARK scalar {
1661                 SCM proc = ly_scheme_function ("make-mark-set");
1662
1663                 SCM result = scm_call_1 (proc, $2);
1664                 scm_gc_protect_object (result);
1665                 $$ = unsmob_music (result);
1666         }
1667         ;
1668
1669 command_req:
1670         E_TILDE {
1671                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1672         }
1673         | MARK DEFAULT  {
1674                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1675                 $$ = m;
1676         }
1677         | tempo_event {
1678                 $$ = $1;
1679         }
1680         | KEY DEFAULT {
1681                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1682                 $$ = key;
1683         }
1684         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1685
1686                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1687                 if (scm_ilength ($3) > 0)
1688                 {
1689                         key->set_property ("pitch-alist", $3);
1690                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1691                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1692                 } else {
1693                         THIS->parser_error (_ ("Second argument must be pitch list."));
1694                 }
1695
1696                 $$ = key;
1697         }
1698         ;
1699
1700 post_events:
1701         /* empty */ {
1702                 $$ = SCM_EOL;
1703         }
1704         | post_events post_event {
1705                 $2->set_spot (THIS->here_input ());
1706                 $$ = scm_cons ($2->self_scm (), $$);
1707                 scm_gc_unprotect_object ($2->self_scm ());
1708         }
1709         | post_events tagged_post_event {
1710                 $2 -> set_spot (THIS->here_input ());
1711                 $$ = scm_cons ($2->self_scm (), $$);
1712                 scm_gc_unprotect_object ($2->self_scm ());
1713         }
1714         ;
1715
1716
1717 tagged_post_event:
1718         '-' TAG embedded_scm post_event {
1719                 tag_music ($4, $3, THIS->here_input ());
1720                 $$ = $4;
1721         }
1722         ;
1723
1724 post_event:
1725         direction_less_event {
1726                 $$ = $1;
1727         }
1728         | HYPHEN {
1729                 if (!THIS->lexer_->is_lyric_state ())
1730                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1731                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1732         }
1733         | EXTENDER {
1734                 if (!THIS->lexer_->is_lyric_state ())
1735                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1736                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1737         }
1738         | script_dir direction_reqd_event {
1739                 if ($1)
1740                         $2->set_property ("direction", scm_int2num ($1));
1741                 $$ = $2;
1742         }
1743         | script_dir direction_less_event {
1744                 if ($1)
1745                         $2->set_property ("direction", scm_int2num ($1));
1746                 $$ = $2;
1747         }
1748         | string_number_event
1749         ;
1750
1751 string_number_event:
1752         E_UNSIGNED {
1753                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1754                 s->set_property ("string-number", scm_int2num ($1));
1755                 s->set_spot (THIS->here_input ());
1756                 $$ = s;
1757         }
1758         ;
1759
1760 direction_less_char:
1761         '['  {
1762                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1763         }
1764         | ']'  {
1765                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1766         }
1767         | '~'  {
1768                 $$ = ly_symbol2scm ("tildeSymbol");
1769         }
1770         | '('  {
1771                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1772         }
1773         | ')'  {
1774                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1775         }
1776         | E_EXCLAMATION  {
1777                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1778         }
1779         | E_OPEN  {
1780                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1781         }
1782         | E_CLOSE  {
1783                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1784         }
1785         | E_BIGGER  {
1786                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1787         }
1788         | E_SMALLER  {
1789                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1790         }
1791         ;
1792
1793 direction_less_event:
1794         direction_less_char {
1795                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1796                 Music * m = 0;
1797                 if (unsmob_music (predefd))
1798                 {
1799                         m = unsmob_music (predefd)->clone ();
1800                 }
1801                 else
1802                 {
1803                         m = MY_MAKE_MUSIC ("Music");
1804                 }
1805                 m->set_spot (THIS->here_input ());
1806                 $$ = m;
1807         }
1808         | EVENT_IDENTIFIER      {
1809                 $$ = unsmob_music ($1);
1810         }
1811         | tremolo_type  {
1812                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1813                a->set_spot (THIS->here_input ());
1814                a->set_property ("tremolo-type", scm_int2num ($1));
1815                $$ = a;
1816         }
1817         ;
1818
1819 direction_reqd_event:
1820         gen_text_def {
1821                 $$ = $1;
1822         }
1823         | script_abbreviation {
1824                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1825                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1826                 if (scm_is_string (s))
1827                         a->set_property ("articulation-type", s);
1828                 else THIS->parser_error (_ ("Expecting string as script definition"));
1829                 $$ = a;
1830         }
1831         ;
1832
1833 octave_check:
1834         /**/ { $$ = SCM_EOL; }
1835         | '='  { $$ = scm_int2num (0); }
1836         | '=' sub_quotes { $$ = scm_int2num ($2); }
1837         | '=' sup_quotes { $$ = scm_int2num ($2); }
1838         ;
1839
1840 sup_quotes:
1841         '\'' {
1842                 $$ = 1;
1843         }
1844         | sup_quotes '\'' {
1845                 $$ ++;
1846         }
1847         ;
1848
1849 sub_quotes:
1850         ',' {
1851                 $$ = 1;
1852         }
1853         | sub_quotes ',' {
1854                 $$++;
1855         }
1856         ;
1857
1858 steno_pitch:
1859         NOTENAME_PITCH  {
1860                 $$ = $1;
1861         }
1862         | NOTENAME_PITCH sup_quotes     {
1863                 Pitch p = *unsmob_pitch ($1);
1864                 p = p.transposed (Pitch ($2,0,0));
1865                 $$ = p.smobbed_copy ();
1866         }
1867         | NOTENAME_PITCH sub_quotes      {
1868                 Pitch p =* unsmob_pitch ($1);
1869                 p = p.transposed (Pitch (-$2,0,0));
1870                 $$ = p.smobbed_copy ();
1871         }
1872         ;
1873
1874 /*
1875 ugh. duplication
1876 */
1877
1878 steno_tonic_pitch:
1879         TONICNAME_PITCH {
1880                 $$ = $1;
1881         }
1882         | TONICNAME_PITCH sup_quotes    {
1883                 Pitch p = *unsmob_pitch ($1);
1884                 p = p.transposed (Pitch ($2,0,0));
1885                 $$ = p.smobbed_copy ();
1886         }
1887         | TONICNAME_PITCH sub_quotes     {
1888                 Pitch p =* unsmob_pitch ($1);
1889
1890                 p = p.transposed (Pitch (-$2,0,0));
1891                 $$ = p.smobbed_copy ();
1892         }
1893         ;
1894
1895 pitch:
1896         steno_pitch {
1897                 $$ = $1;
1898         }
1899         ;
1900
1901 pitch_also_in_chords:
1902         pitch
1903         | steno_tonic_pitch
1904         ;
1905
1906 gen_text_def:
1907         full_markup {
1908                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1909                 t->set_property ("text", $1);
1910                 t->set_spot (THIS->here_input ());
1911                 $$ = t;
1912         }
1913         | string {
1914                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1915                 t->set_property ("text",
1916                         make_simple_markup (THIS->lexer_->encoding (), $1));
1917                 t->set_spot (THIS->here_input ());
1918                 $$ = t;
1919
1920         }
1921         | DIGIT {
1922                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1923                 t->set_property ("digit", scm_int2num ($1));
1924                 t->set_spot (THIS->here_input ());
1925                 $$ = t;
1926         }
1927         ;
1928
1929 script_abbreviation:
1930         '^'             {
1931                 $$ = scm_makfrom0str ("Hat");
1932         }
1933         | '+'           {
1934                 $$ = scm_makfrom0str ("Plus");
1935         }
1936         | '-'           {
1937                 $$ = scm_makfrom0str ("Dash");
1938         }
1939         | '|'           {
1940                 $$ = scm_makfrom0str ("Bar");
1941         }
1942         | '>'           {
1943                 $$ = scm_makfrom0str ("Larger");
1944         }
1945         | '.'           {
1946                 $$ = scm_makfrom0str ("Dot");
1947         }
1948         | '_' {
1949                 $$ = scm_makfrom0str ("Underscore");
1950         }
1951         ;
1952
1953 script_dir:
1954         '_'     { $$ = DOWN; }
1955         | '^'   { $$ = UP; }
1956         | '-'   { $$ = CENTER; }
1957         ;
1958
1959
1960 absolute_pitch:
1961         steno_pitch     {
1962                 $$ = $1;
1963         }
1964         ;
1965
1966 duration_length:
1967         multiplied_duration {
1968                 $$ = $1;
1969         }
1970         ;
1971
1972 optional_notemode_duration:
1973         {
1974                 Duration dd = THIS->default_duration_;
1975                 $$ = dd.smobbed_copy ();
1976
1977                 THIS->beam_check ($$);
1978         }
1979         | multiplied_duration   {
1980                 $$ = $1;
1981                 THIS->default_duration_ = *unsmob_duration ($$);
1982
1983                 THIS->beam_check ($$);
1984         }
1985         ;
1986
1987 steno_duration:
1988         bare_unsigned dots              {
1989                 int len = 0;
1990                 if (!is_duration ($1))
1991                         THIS->parser_error (_f ("not a duration: %d", $1));
1992                 else
1993                         len = intlog2 ($1);
1994
1995                 $$ = Duration (len, $2).smobbed_copy ();
1996         }
1997         | DURATION_IDENTIFIER dots      {
1998                 Duration *d = unsmob_duration ($1);
1999                 Duration k (d->duration_log (), d->dot_count () + $2);
2000                 *d = k;
2001                 $$ = $1;
2002         }
2003         ;
2004
2005 multiplied_duration:
2006         steno_duration {
2007                 $$ = $1;
2008         }
2009         | multiplied_duration '*' bare_unsigned {
2010                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2011         }
2012         | multiplied_duration '*' FRACTION {
2013                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2014
2015                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2016         }
2017         ;
2018
2019 fraction:
2020         FRACTION { $$ = $1; }
2021         | UNSIGNED '/' UNSIGNED {
2022                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2023         }
2024         ;
2025
2026 dots:
2027         /* empty */     {
2028                 $$ = 0;
2029         }
2030         | dots '.' {
2031                 $$ ++;
2032         }
2033         ;
2034
2035 tremolo_type:
2036         ':'     {
2037                 $$ = 0;
2038         }
2039         | ':' bare_unsigned {
2040                 if (!is_duration ($2))
2041                         THIS->parser_error (_f ("not a duration: %d", $2));
2042                 $$ = $2;
2043         }
2044         ;
2045
2046 bass_number:
2047         DIGIT   {
2048                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2049                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2050                                 $$);
2051         }
2052         | UNSIGNED {
2053                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2054                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2055                                 $$);
2056         }
2057         | STRING { $$ = $1; }
2058         ;
2059
2060 bass_mod:
2061         '-'     { $$ = -2; }
2062         | '+'   { $$ = 2; }
2063         | '!'   { $$ = 0; }
2064         ;
2065
2066 bass_figure:
2067         FIGURE_SPACE {
2068                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2069                 $$ = bfr->self_scm ();
2070                 scm_gc_unprotect_object ($$);
2071         }
2072         | bass_number  {
2073                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2074                 $$ = bfr->self_scm ();
2075
2076                 bfr->set_property ("figure", $1);
2077
2078                 scm_gc_unprotect_object ($$);
2079         }
2080         | bass_figure bass_mod {
2081                 Music *m = unsmob_music ($1);
2082                 if ($2) {
2083                         SCM salter = m->get_property ("alteration");
2084                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2085                         m->set_property ("alteration",
2086                                 scm_int2num (alter + $2));
2087                 } else {
2088                         m->set_property ("alteration", scm_int2num (0));
2089                 }
2090         }
2091         ;
2092
2093 br_bass_figure:
2094         '[' bass_figure {
2095                 $$ = $2;
2096                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2097         }
2098         | bass_figure   {
2099                 $$ = $1;
2100         }
2101         | br_bass_figure ']' {
2102                 $$ = $1;
2103                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2104         }
2105         ;
2106
2107 figure_list:
2108         /**/            {
2109                 $$ = SCM_EOL;
2110         }
2111         | figure_list br_bass_figure {
2112                 $$ = scm_cons ($2, $1);
2113         }
2114         ;
2115
2116 figure_spec:
2117         FIGURE_OPEN figure_list FIGURE_CLOSE {
2118                 Music *m = MY_MAKE_MUSIC ("EventChord");
2119                 $2 = scm_reverse_x ($2, SCM_EOL);
2120                 m->set_property ("elements", $2);
2121                 $$ = m->self_scm ();
2122         }
2123         ;
2124
2125
2126 optional_rest:
2127         /**/   { $$ = 0; }
2128         | REST { $$ = 1; }
2129         ;
2130
2131 simple_element:
2132         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2133
2134                 Input i = THIS->pop_spot ();
2135                 if (!THIS->lexer_->is_note_state ())
2136                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2137
2138                 Music *n = 0;
2139                 if ($6)
2140                         n = MY_MAKE_MUSIC ("RestEvent");
2141                 else
2142                         n = MY_MAKE_MUSIC ("NoteEvent");
2143
2144                 n->set_property ("pitch", $1);
2145                 n->set_property ("duration", $5);
2146
2147                 if (scm_is_number ($4))
2148                 {
2149                         int q = scm_to_int ($4);
2150                         n->set_property ("absolute-octave", scm_int2num (q-1));
2151                 }
2152
2153                 if ($3 % 2)
2154                         n->set_property ("cautionary", SCM_BOOL_T);
2155                 if ($2 % 2 || $3 % 2)
2156                         n->set_property ("force-accidental", SCM_BOOL_T);
2157
2158                 Music *v = MY_MAKE_MUSIC ("EventChord");
2159                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2160                 scm_gc_unprotect_object (n->self_scm ());
2161
2162                 v->set_spot (i);
2163                 n->set_spot (i);
2164                 $$ = v;
2165         }
2166         | DRUM_PITCH optional_notemode_duration {
2167                 Input i = THIS->pop_spot ();
2168
2169                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2170                 n->set_property ("duration", $2);
2171                 n->set_property ("drum-type", $1);
2172
2173                 Music *v = MY_MAKE_MUSIC ("EventChord");
2174                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2175                 scm_gc_unprotect_object (n->self_scm ());
2176                 v->set_spot (i);
2177                 n->set_spot (i);
2178                 $$ = v;
2179
2180         }
2181         | figure_spec optional_notemode_duration {
2182                 Music *m = unsmob_music ($1);
2183                 Input i = THIS->pop_spot ();
2184                 m->set_spot (i);
2185                 for (SCM s = m->get_property ("elements"); scm_is_pair (s); s = scm_cdr (s))
2186                 {
2187                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2188                 }
2189                 $$ = m;
2190         }
2191         | RESTNAME optional_notemode_duration           {
2192
2193                 Input i = THIS->pop_spot ();
2194                 Music *ev = 0;
2195                 if (ly_scm2string ($1) == "s") {
2196                         /* Space */
2197                         ev = MY_MAKE_MUSIC ("SkipEvent");
2198                   }
2199                 else {
2200                         ev = MY_MAKE_MUSIC ("RestEvent");
2201
2202                     }
2203                 ev->set_property ("duration", $2);
2204                 ev->set_spot (i);
2205                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2206                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2207                 velt->set_spot (i);
2208
2209                 scm_gc_unprotect_object (ev->self_scm ());
2210
2211                 $$ = velt;
2212         }
2213         | MULTI_MEASURE_REST optional_notemode_duration         {
2214                 THIS->pop_spot ();
2215
2216                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2217                 SCM mus = scm_call_2 (proc, $2,
2218                         make_input (THIS->here_input ()));
2219                 scm_gc_protect_object (mus);
2220                 $$ = unsmob_music (mus);
2221         }
2222
2223         | lyric_element optional_notemode_duration      {
2224                 Input i = THIS->pop_spot ();
2225                 if (!THIS->lexer_->is_lyric_state ())
2226                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2227
2228                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2229                 lreq->set_property ("text", $1);
2230                 lreq->set_property ("duration",$2);
2231                 lreq->set_spot (i);
2232                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2233                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2234
2235                 $$= velt;
2236         }
2237         | new_chord {
2238                 THIS->pop_spot ();
2239
2240                 if (!THIS->lexer_->is_chord_state ())
2241                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2242                 $$ = unsmob_music ($1);
2243         }
2244         ;
2245
2246 lyric_element:
2247         /* FIXME: lyric flavoured markup would be better */
2248         full_markup {
2249                 $$ = $1;
2250         }
2251         | LYRICS_STRING {
2252                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2253         }
2254         ;
2255
2256 new_chord:
2257         steno_tonic_pitch optional_notemode_duration   {
2258                 $$ = make_chord ($1, $2, SCM_EOL);
2259         }
2260         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2261                 SCM its = scm_reverse_x ($4, SCM_EOL);
2262                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2263         }
2264         ;
2265
2266 chord_items:
2267         /**/ {
2268                 $$ = SCM_EOL;
2269         }
2270         | chord_items chord_item {
2271                 $$ = scm_cons ($2, $$);
2272         }
2273         ;
2274
2275 chord_separator:
2276         CHORD_COLON {
2277                 $$ = ly_symbol2scm ("chord-colon");
2278         }
2279         | CHORD_CARET {
2280                 $$ = ly_symbol2scm ("chord-caret");
2281         }
2282         | CHORD_SLASH steno_tonic_pitch {
2283                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2284         }
2285         | CHORD_BASS steno_tonic_pitch {
2286                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2287         }
2288         ;
2289
2290 chord_item:
2291         chord_separator {
2292                 $$ = $1;
2293         }
2294         | step_numbers {
2295                 $$ = scm_reverse_x ($1, SCM_EOL);
2296         }
2297         | CHORD_MODIFIER  {
2298                 $$ = $1;
2299         }
2300         ;
2301
2302 step_numbers:
2303         step_number { $$ = scm_cons ($1, SCM_EOL); }
2304         | step_numbers '.' step_number {
2305                 $$ = scm_cons ($3, $$);
2306         }
2307         ;
2308
2309 step_number:
2310         bare_unsigned {
2311                 $$ = make_chord_step ($1, 0);
2312         }
2313         | bare_unsigned '+' {
2314                 $$ = make_chord_step ($1, SHARP);
2315         }
2316         | bare_unsigned CHORD_MINUS {
2317                 $$ = make_chord_step ($1, FLAT);
2318         }
2319         ;
2320
2321 /*
2322         UTILITIES
2323
2324 TODO: should deprecate in favor of Scheme?
2325
2326  */
2327 number_expression:
2328         number_expression '+' number_term {
2329                 $$ = scm_sum ($1, $3);
2330         }
2331         | number_expression '-' number_term {
2332                 $$ = scm_difference ($1, $3);
2333         }
2334         | number_term
2335         ;
2336
2337 number_term:
2338         number_factor {
2339                 $$ = $1;
2340         }
2341         | number_factor '*' number_factor {
2342                 $$ = scm_product ($1, $3);
2343         }
2344         | number_factor '/' number_factor {
2345                 $$ = scm_divide ($1, $3);
2346         }
2347         ;
2348
2349 number_factor:
2350         '-'  number_factor { /* %prec UNARY_MINUS */
2351                 $$ = scm_difference ($2, SCM_UNDEFINED);
2352         }
2353         | bare_number
2354         ;
2355
2356
2357 bare_number:
2358         UNSIGNED        {
2359                 $$ = scm_int2num ($1);
2360         }
2361         | REAL          {
2362                 $$ = $1;
2363         }
2364         | NUMBER_IDENTIFIER             {
2365                 $$ = $1;
2366         }
2367         | REAL NUMBER_IDENTIFIER        {
2368                 $$ = scm_make_real (scm_to_double ($1) *scm_to_double ($2));
2369         }
2370         | UNSIGNED NUMBER_IDENTIFIER    {
2371                 $$ = scm_make_real ($1 *scm_to_double ($2));
2372         }
2373         ;
2374
2375
2376 bare_unsigned:
2377         UNSIGNED {
2378                         $$ = $1;
2379         }
2380         | DIGIT {
2381                 $$ = $1;
2382         }
2383         ;
2384
2385 bare_int:
2386         bare_number {
2387                 if (scm_integer_p ($1) == SCM_BOOL_T)
2388                 {
2389                         int k = scm_to_int ($1);
2390                         $$ = k;
2391                 } else
2392                 {
2393                         THIS->parser_error (_ ("need integer number arg"));
2394                         $$ = 0;
2395                 }
2396         }
2397         | '-' bare_int {
2398                 $$ = -$2;
2399         }
2400         ;
2401
2402 exclamations:
2403                 { $$ = 0; }
2404         | exclamations '!'      { $$ ++; }
2405         ;
2406
2407 questions:
2408                 { $$ = 0; }
2409         | questions '?' { $$ ++; }
2410         ;
2411
2412
2413
2414 full_markup:
2415         MARKUP_IDENTIFIER {
2416                 $$ = $1;
2417         }
2418         | MARKUP
2419                 { THIS->lexer_->push_markup_state (); }
2420         markup
2421                 { $$ = $3;
2422                   THIS->lexer_->pop_state ();
2423                 }
2424         ;
2425
2426
2427 /*
2428 This should be done more dynamically if possible.
2429 */
2430 markup:
2431         STRING {
2432                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2433         }
2434         | MARKUP_HEAD_EMPTY {
2435                 $$ = scm_list_1 ($1);
2436         }
2437         | MARKUP_HEAD_MARKUP0 markup {
2438                 $$ = scm_list_2 ($1, $2);
2439         }
2440         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2441                 $$ = scm_list_3 ($1, $2, $3);
2442         }
2443         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2444                 $$ = scm_list_3 ($1, $2, $3);
2445         }
2446         | markup_line {
2447                 $$ = $1;
2448         }
2449         | MARKUP_HEAD_LIST0 markup_list {
2450                 $$ = scm_list_2 ($1,$2);
2451         }
2452         | MARKUP_HEAD_SCM0 embedded_scm {
2453                 $$ = scm_list_2 ($1, $2);
2454         }
2455         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2456                 $$ = scm_list_4 ($1, $2, $3, $4);
2457         }
2458         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2459                 $$ = scm_list_4 ($1, $2, $3, $4);
2460         }
2461         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2462                 $$ = scm_list_3 ($1, $2, $3);
2463         }
2464         | MARKUP_IDENTIFIER {
2465                 $$ = $1;
2466         }
2467         | STRING_IDENTIFIER {
2468                 $$ = $1;
2469         }
2470         | SCORE {
2471                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2472                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2473         } '{' score_body '}' {
2474                 Score * sc = $4;
2475                 $$ = scm_list_2 (ly_scheme_function ("score-markup"), sc->self_scm ());
2476                 scm_gc_unprotect_object (sc->self_scm ());
2477                 THIS->lexer_->pop_state ();
2478         }
2479         ;
2480
2481 markup_list:
2482         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2483         ;
2484
2485 markup_line:
2486         '{' markup_list_body '}' {
2487                 SCM line = ly_scheme_function ("line-markup");
2488
2489                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2490         }
2491         ;
2492
2493 markup_list_body:
2494         /**/ {  $$ = SCM_EOL; }
2495         | markup_list_body markup {
2496                 $$ = scm_cons ($2, $1);
2497         }
2498         ;
2499
2500
2501 %%
2502
2503 void
2504 Lily_parser::set_yydebug (bool )
2505 {
2506 #if 0
2507         yydebug = 1;
2508 #endif
2509 }
2510
2511 void
2512 Lily_parser::do_yyparse ()
2513 {
2514         yyparse ((void*)this);
2515 }
2516
2517
2518 /*
2519 Should make this optional?    It will also complain when you do
2520
2521         [s4]
2522
2523 which is entirely legitimate.
2524
2525 Or we can scrap it. Barchecks should detect wrong durations, and
2526 skipTypesetting speeds it up a lot.
2527 */
2528
2529 void
2530 Lily_parser::beam_check (SCM dur)
2531 {
2532   Duration *d = unsmob_duration (dur);
2533   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2534     {
2535       Music *m = unsmob_music (last_beam_start_);
2536       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2537     }
2538   last_beam_start_ = SCM_EOL;
2539 }
2540
2541
2542
2543
2544 /*
2545
2546 It is a little strange to have this function in this file, but
2547 otherwise, we have to import music classes into the lexer.
2548
2549 */
2550 int
2551 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2552 {
2553         if (scm_is_string (sid)) {
2554                 *destination = sid;
2555                 return STRING_IDENTIFIER;
2556         } else if (scm_is_number (sid)) {
2557                 *destination = sid;
2558                 return NUMBER_IDENTIFIER;
2559         } else if (unsmob_context_def (sid)) {
2560                 *destination = unsmob_context_def (sid)->clone_scm ();
2561                 return CONTEXT_DEF_IDENTIFIER;
2562         } else if (unsmob_score (sid)) {
2563                 Score *score = new Score (*unsmob_score (sid));
2564                 *destination = score->self_scm ();
2565                 return SCORE_IDENTIFIER;
2566         } else if (Music *mus = unsmob_music (sid)) {
2567                 mus = mus->clone ();
2568                 *destination = mus->self_scm ();
2569                 unsmob_music (*destination)->
2570                         set_property ("origin", make_input (last_input_));
2571                 return dynamic_cast<Event*> (mus)
2572                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2573         } else if (unsmob_duration (sid)) {
2574                 *destination = unsmob_duration (sid)->smobbed_copy ();
2575                 return DURATION_IDENTIFIER;
2576         } else if (unsmob_output_def (sid)) {
2577                 Output_def *p = unsmob_output_def (sid);
2578                 p = p->clone ();
2579
2580                 *destination = p->self_scm ();
2581                 return OUTPUT_DEF_IDENTIFIER;
2582         } else if (Text_interface::markup_p (sid)) {
2583                 *destination = sid;
2584                 return MARKUP_IDENTIFIER;
2585         }
2586
2587         return -1;
2588 }
2589
2590 Music *
2591 property_op_to_music (SCM op)
2592 {
2593         Music *m = 0;
2594         SCM tag = scm_car (op);
2595         SCM symbol = scm_cadr (op);
2596         SCM args = scm_cddr (op);
2597         SCM grob_val = SCM_UNDEFINED;
2598         SCM grob_sym = SCM_UNDEFINED;
2599         SCM val = SCM_UNDEFINED;
2600
2601         if (tag == ly_symbol2scm ("assign"))
2602                 {
2603                 m = MY_MAKE_MUSIC ("PropertySet");
2604                 val = scm_car (args);
2605                 }
2606         else if (tag == ly_symbol2scm ("unset"))
2607                 m = MY_MAKE_MUSIC ("PropertyUnset");
2608         else if (tag == ly_symbol2scm ("poppush")
2609                  || tag == ly_symbol2scm ("push"))
2610                 {
2611                 m = MY_MAKE_MUSIC ("OverrideProperty");
2612                 grob_sym = scm_car (args);
2613                 grob_val = scm_cadr (args);
2614                 }
2615         else if (tag == ly_symbol2scm ("pop")) {
2616                 m = MY_MAKE_MUSIC ("RevertProperty");
2617                 grob_sym = scm_car (args);
2618                 }
2619
2620         m->set_property ("symbol", symbol);
2621
2622         if (val != SCM_UNDEFINED)
2623                 m->set_property ("value", val);
2624         if (grob_val != SCM_UNDEFINED)
2625                 m->set_property ("grob-value", grob_val);
2626
2627         if (grob_sym != SCM_UNDEFINED)
2628                 {
2629                 bool itc = internal_type_checking_global_b;
2630                 /* UGH.
2631                 */
2632                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2633                 if (autobeam)
2634                         internal_type_checking_global_b = false;
2635                 m->set_property ("grob-property", grob_sym);
2636                 if (autobeam)
2637                         internal_type_checking_global_b = itc;
2638                 }
2639
2640         if (tag == ly_symbol2scm ("poppush"))
2641                 m->set_property ("pop-first", SCM_BOOL_T);
2642
2643
2644         return m;
2645 }
2646
2647 Music*
2648 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2649 {
2650         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2651
2652         csm->set_property ("element", m->self_scm ());
2653         scm_gc_unprotect_object (m->self_scm ());
2654
2655         csm->set_property ("context-type",
2656                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2657         csm->set_property ("property-operations", ops);
2658
2659         if (scm_is_string (id))
2660                 csm->set_property ("context-id", id);
2661         return csm;
2662 }
2663
2664 /*
2665 FIXME: this should be postponed until the music hits \Score
2666 */
2667 SCM
2668 get_next_unique_context ()
2669 {
2670         static int new_context_count;
2671         char s[1024];
2672         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2673         return scm_makfrom0str (s);
2674 }
2675