lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "scm-option.hh"
  29 #include "context-def.hh"
  30 #include "lily-guile.hh"
  31 #include "misc.hh"
  32 #include "my-lily-lexer.hh"
  33 #include "paper-def.hh"
  34 #include "midi-def.hh"
  35 #include "main.hh"
  36 #include "file-path.hh"
  37 #include "warn.hh"
  38 #include "dimensions.hh"
  39 #include "my-lily-parser.hh"
  40 #include "score.hh"
  41 #include "input-file-results.hh"
  42 #include "input.hh"
  43 #include "lilypond-input-version.hh"
  44 #include "scm-hash.hh"
  45 #include "ly-module.hh"
  46 #include "music-sequence.hh"
  47 #include "input-smob.hh"
  48 #include "event.hh"
  49 #include "text-item.hh"
  50 #include "music-list.hh"
  51 #include "paper-book.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (is_symbol (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (is_list (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84
  85
  86 bool
  87 is_regular_identifier (SCM id)
  88 {
  89   String str = ly_scm2string (id);
  90   char const *s = str.to_str0 ();
  91
  92   bool v = true;
  93 #if 0
  94   isalpha (*s);
  95   s++;
  96 #endif
  97   while (*s && v)
  98    {
  99         v = v && isalnum (*s);
 100         s++;
 101    }
 102   return v;
 103 }
 104
 105 SCM
 106 make_simple_markup (SCM encoding, SCM a)
 107 {
 108         SCM simple = ly_scheme_function ("simple-markup");
 109         if (gh_symbol_p (encoding))
 110         {
 111                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 112                            encoding, a);
 113         } else
 114                 return scm_list_2 (simple, a);
 115
 116         return markup;
 117 }
 118
 119
 120 bool
 121 is_duration (int t)
 122 {
 123   return t && t == 1 << intlog2 (t);
 124 }
 125
 126 void
 127 set_music_properties (Music *p, SCM a)
 128 {
 129   for (SCM k = a; is_pair (k); k = ly_cdr (k))
 130         p->internal_set_property (ly_caar (k), ly_cdar (k));
 131 }
 132
 133 SCM
 134 make_chord_step (int step, int alter)
 135 {
 136         if (step == 7)
 137                 alter += FLAT;
 138
 139         while (step < 0)
 140                 step += 7;
 141         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 142         return m.smobbed_copy ();
 143 }
 144
 145
 146 SCM
 147 make_chord (SCM pitch, SCM dur, SCM modification_list)
 148 {
 149         SCM chord_ctor = ly_scheme_function ("construct-chord");
 150         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 151         scm_gc_protect_object (ch);
 152         return ch;
 153 }
 154
 155 /* Todo: actually also use apply iso. call too ...  */
 156 bool
 157 ly_input_procedure_p (SCM x)
 158 {
 159         return is_procedure (x)
 160                 || (is_pair (x) && is_procedure (ly_car (x)));
 161 }
 162
 163 Music*
 164 set_property_music (SCM sym, SCM value)
 165 {
 166         Music *p = MY_MAKE_MUSIC ("PropertySet");
 167         p->set_property ("symbol", sym);
 168         p->set_property ("value", value);
 169         return p;
 170 }
 171
 172 %}
 173
 174 /* We use SCMs to do strings, because it saves us the trouble of
 175 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 176 of the parse stack onto the heap. */
 177
 178
 179 %union {
 180         String *string;
 181     Music *music;
 182     Score *score;
 183     Music_output_def *outputdef;
 184     SCM scm;
 185     int i;
 186 }
 187 %{
 188
 189 int
 190 yylex (YYSTYPE *s, void *v)
 191 {
 192         My_lily_parser *pars = (My_lily_parser*) v;
 193         My_lily_lexer *lex = pars->lexer_;
 194
 195         lex->lexval = (void*) s;
 196         lex->prepare_for_next_token ();
 197         return lex->yylex ();
 198 }
 199
 200
 201 %}
 202
 203 %expect 4
 204
 205 /*
 206   Four shift/reduce problems:
 207
 208 1.      foo = bar.
 209
 210         "bar" -> String -> Lyric -> Music -> music-assignment
 211
 212         "bar" -> String -> string-assignment
 213
 214
 215 Similar problem for
 216
 217 2. \markup identifier.
 218
 219 3. \markup { }
 220
 221 4.  \repeat
 222         \repeat .. \alternative
 223
 224
 225     \repeat { \repeat .. \alternative }
 226
 227 or
 228
 229     \repeat { \repeat } \alternative
 230
 231 )
 232
 233 --hwn
 234
 235  */
 236
 237
 238 %pure_parser
 239
 240 %token ACCEPTS
 241 %token ADDLYRICS
 242 %token ADDQUOTE
 243 %token NEWADDLYRICS
 244 %token ALIAS
 245 %token ALTERNATIVE
 246 %token APPLY
 247 %token APPLYCONTEXT
 248 %token APPLYOUTPUT
 249 %token AUTOCHANGE
 250 %token BAR
 251 %token BREATHE
 252 %token CHANGE
 253 %token CHORDMODIFIERS
 254 %token CHORDS
 255 %token LESSLESS
 256 %token MOREMORE
 257 %token CLEF
 258 %token COMMANDSPANREQUEST
 259 %token CONSISTS
 260 %token CONSISTSEND
 261 %token CONTEXT
 262 %token DEFAULT
 263 %token DENIES
 264 %token DESCRIPTION
 265 %token EXTENDER
 266 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 267 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 268 %token GRACE
 269 %token ACCIACCATURA
 270 %token APPOGGIATURA
 271 %token GROBDESCRIPTIONS
 272 %token HEADER
 273 %token HYPHEN
 274 %token INVALID
 275 %token KEY
 276 %token LYRICS
 277 %token MARK
 278 %token MIDI
 279 %token MULTI_MEASURE_REST
 280 %token NAME
 281 %token NEWCONTEXT
 282 %token NOTES
 283 %token OCTAVE
 284 %token ONCE
 285 %token OVERRIDE SET REVERT
 286 %token PAPER
 287 %token PARTCOMBINE
 288 %token PARTIAL
 289 %token QUOTE
 290 %token RELATIVE
 291 %token REMOVE
 292 %token REPEAT
 293 %token REST
 294 %token SCM_T
 295 %token SCORE
 296 %token SEQUENTIAL
 297 %token SIMULTANEOUS
 298 %token SKIP
 299 %token SPANREQUEST
 300 %token TAG
 301 %token TEMPO
 302 %token TIMES
 303 %token TIME_T
 304 %token TRANSPOSE
 305 %token TRANSPOSITION
 306 %token TYPE
 307 %token UNSET
 308 %token WITH
 309
 310 /* escaped */
 311 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 312 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 313 %token E_BACKSLASH
 314 %token <i> E_UNSIGNED
 315 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 316 %token FIGURE_SPACE
 317
 318 %type <i>       exclamations questions dots optional_rest
 319 %type <i>        bass_mod
 320 %type <scm>     grace_head
 321 %type <scm>     oct_check
 322 %type <scm>     context_mod_list
 323 %type <scm>     lyric_element
 324 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 325 %token <i>      DIGIT
 326 %token <scm>    NOTENAME_PITCH
 327 %token <scm>    TONICNAME_PITCH
 328 %token <scm>    CHORDMODIFIER_PITCH
 329 %token <scm>    DURATION_IDENTIFIER
 330 %token <scm>    FRACTION
 331 %token <id>     IDENTIFIER
 332 %token DRUMS
 333 %token <scm>    DRUM_PITCH
 334 %token <scm>    CHORD_MODIFIER
 335 %token <scm>    SCORE_IDENTIFIER
 336 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 337 %token <scm>    NUMBER_IDENTIFIER
 338 %token <scm>    EVENT_IDENTIFIER
 339 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 340 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 341 %token <scm>    RESTNAME
 342 %token <scm>    STRING
 343 %token <scm>    SCM_T
 344 %token <i>      UNSIGNED
 345 %token <scm>   REAL
 346
 347 %token MARKUP
 348 %token <scm> MARKUP_HEAD_MARKUP0
 349 %token <scm> MARKUP_HEAD_EMPTY
 350 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 351 %token <scm> MARKUP_HEAD_SCM0
 352 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 353 %token <scm> MARKUP_HEAD_SCM0_SCM1
 354 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 355 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 356
 357 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 358 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 359
 360 %type <outputdef> output_def
 361 %type <scm>     lilypond_header lilypond_header_body
 362 %type <music>   open_event close_event
 363 %type <i>       sub_quotes sup_quotes
 364 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 365 %type <music>   Repeated_music
 366 %type <scm>     Alternative_music
 367 %type <i>       tremolo_type
 368 %type <i>       bare_int  bare_unsigned
 369 %type <i>       script_dir
 370 %type <scm>     identifier_init
 371
 372 %type <music> note_chord_element chord_body chord_body_element
 373 %type <scm>  chord_body_elements
 374 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 375
 376 %type <scm>   post_events
 377 %type <music> gen_text_def direction_less_event direction_reqd_event
 378 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 379 %type <scm>    steno_tonic_pitch
 380 %type <scm>     duration_length fraction
 381
 382 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 383
 384 %type <scm>  embedded_scm scalar
 385 %type <music>   Music Sequential_music Simultaneous_music
 386 %type <music>   relative_music re_rhythmed_music
 387 %type <music>   music_property_def context_change
 388 %type <scm> context_prop_spec
 389 %type <scm> Music_list
 390 %type <scm> property_operation context_mod context_def_mod optional_context_mod
 391 %type <outputdef>  music_output_def_body music_output_def_head
 392 %type <music>   post_event tagged_post_event
 393 %type <music> command_req
 394 %type <music> string_number_event
 395 %type <scm>     string bare_number number_expression number_term number_factor
 396 %type <score>   score_block score_body
 397
 398 %type <scm>     context_def_spec_block context_def_spec_body
 399 %type <music>   tempo_event
 400 %type <scm>     script_abbreviation
 401
 402
 403
 404 %left '-' '+'
 405
 406 /* We don't assign precedence to / and *, because we might need varied
 407 prec levels in different prods */
 408
 409 %left UNARY_MINUS
 410
 411 %%
 412
 413 lilypond:       /* empty */
 414         | lilypond toplevel_expression {}
 415         | lilypond assignment  { }
 416         | lilypond error {
 417                 THIS->error_level_ = 1;
 418         }
 419         | lilypond INVALID      {
 420                 THIS->error_level_ = 1;
 421         }
 422         ;
 423
 424 toplevel_expression:
 425         lilypond_header {
 426                 THIS->input_file_->header_ = $1;
 427         }
 428         | add_quote {
 429         }
 430         | score_block {
 431                 Score *sc = $1;
 432
 433                 SCM head = is_module (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 434
 435                 Path p = split_path (THIS->output_basename_);
 436                 int *c = &THIS->input_file_->score_count_;
 437                 if (*c)
 438                         {
 439                         p.base += "-" + to_string (*c);
 440                         }
 441
 442                 (*c)++;
 443                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 444
 445                 for (int i = 0; i < sc->defs_.size (); i++)
 446                         default_rendering (sc->music_, sc->defs_[i]->self_scm (), head, outname);
 447
 448                 if (sc->defs_.is_empty ())
 449                 {
 450                    Music_output_def *id = unsmob_music_output_def
 451                         (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 452                    id = id ? id->clone () : new Paper_def;
 453                    default_rendering (sc->music_, id->self_scm (), head,
 454                         outname);
 455                    scm_gc_unprotect_object (id->self_scm ());
 456                 }
 457                 scm_gc_unprotect_object (sc->self_scm ());
 458         }
 459         | output_def {
 460                 SCM id = SCM_EOL;
 461                 if (dynamic_cast<Paper_def*> ($1))
 462                         id = scm_makfrom0str ("$defaultpaper");
 463                 else if (dynamic_cast<Midi_def*> ($1))
 464                         id = scm_makfrom0str ("$defaultmidi");
 465                 THIS->lexer_->set_identifier (id, $1->self_scm ());
 466                 scm_gc_unprotect_object ($1->self_scm ());
 467         }
 468         ;
 469
 470
 471 embedded_scm:
 472         SCM_T
 473         | SCM_IDENTIFIER
 474         ;
 475
 476
 477
 478
 479 lilypond_header_body:
 480         {
 481                 $$ = ly_make_anonymous_module ();
 482                 THIS->lexer_->add_scope ($$);
 483         }
 484         | lilypond_header_body assignment  {
 485
 486         }
 487         ;
 488
 489 lilypond_header:
 490         HEADER '{' lilypond_header_body '}'     {
 491                 $$ = THIS->lexer_->remove_scope ();
 492         }
 493         ;
 494
 495
 496 /*
 497         DECLARATIONS
 498 */
 499 assignment:
 500         STRING {
 501                 THIS->push_spot ();
 502         }
 503         /* cont */ '=' identifier_init  {
 504
 505         /*
 506                 Should find generic way of associating input with objects.
 507         */
 508                 Input ip = THIS->pop_spot ();
 509
 510                 if (! is_regular_identifier ($1))
 511                 {
 512                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 513                 }
 514
 515                 THIS->lexer_->set_identifier ($1, $4);
 516
 517 /*
 518  TODO: devise standard for protection in parser.
 519
 520   The parser stack lives on the C-stack, which means that
 521 all objects can be unprotected as soon as they're here.
 522
 523 */
 524         }
 525         | embedded_scm { }
 526         ;
 527
 528
 529 identifier_init:
 530         score_block {
 531                 $$ = $1->self_scm ();
 532                 scm_gc_unprotect_object ($$);
 533         }
 534         | full_markup {
 535                 $$ = $1;
 536         }
 537         | output_def {
 538                 $$ = $1->self_scm ();
 539                 scm_gc_unprotect_object ($$);
 540         }
 541         | context_def_spec_block {
 542                 $$ = $1;
 543         }
 544         | Music  {
 545                 $$ = $1->self_scm ();
 546                 scm_gc_unprotect_object ($$);
 547         }
 548         | post_event {
 549                 $$ = $1->self_scm ();
 550                 scm_gc_unprotect_object ($$);
 551         }
 552         | number_expression {
 553                 $$ = $1;
 554         }
 555         | string {
 556                 $$ = $1;
 557         }
 558         | embedded_scm  {
 559                 $$ = $1;
 560         }
 561         ;
 562
 563 context_def_spec_block:
 564         CONTEXT '{' context_def_spec_body '}'
 565                 {
 566                 $$ = $3;
 567         }
 568         ;
 569
 570 context_def_spec_body:
 571         /**/ {
 572                 $$ = Context_def::make_scm ();
 573                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 574         }
 575         | CONTEXT_DEF_IDENTIFIER        {
 576                 $$ = $1;
 577                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 578         }
 579         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 580                 Context_def*td = unsmob_context_def ($$);
 581
 582                 for (SCM p = $3; is_pair (p); p = ly_cdr (p)) {
 583                         SCM tag = ly_caar (p);
 584
 585                         /* TODO: should make new tag "grob-definition" ? */
 586                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 587                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 588                 }
 589         }
 590         | context_def_spec_body context_mod {
 591                 unsmob_context_def ($$)->add_context_mod ($2);
 592         }
 593         ;
 594
 595 /*
 596         SCORE
 597 */
 598 score_block:
 599         SCORE {
 600                 THIS->push_spot ();
 601         }
 602         /*cont*/ '{' score_body '}'     {
 603                 THIS->pop_spot ();
 604                 $$ = $4;
 605
 606         }
 607         ;
 608
 609 score_body:
 610         Music   {
 611                 $$ = new Score;
 612
 613                 $$->set_spot (THIS->here_input ());
 614                 SCM m = $1->self_scm ();
 615                 scm_gc_unprotect_object (m);
 616
 617                 /*
 618                         guh.
 619                 */
 620                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 621                 for (; is_pair (check_funcs); check_funcs = ly_cdr (check_funcs))
 622                         m = scm_call_1 (ly_car (check_funcs), m);
 623                 $$->music_ = m;
 624
 625         }
 626         | SCORE_IDENTIFIER {
 627                 $$ = new Score ( *unsmob_score ($1));
 628                 $$->set_spot (THIS->here_input ());
 629         }
 630         | score_body lilypond_header    {
 631                 $$->header_ = $2;
 632         }
 633         | score_body output_def {
 634                 $$->defs_.push ($2);
 635                 scm_gc_unprotect_object ($2->self_scm ());
 636         }
 637         | score_body error {
 638
 639         }
 640         ;
 641
 642
 643 /*
 644         MIDI
 645 */
 646 output_def:
 647         music_output_def_body '}' {
 648                 $$ = $1;
 649                 THIS-> lexer_-> remove_scope ();
 650         }
 651         ;
 652
 653 music_output_def_head:
 654         MIDI    {
 655                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 656
 657
 658                 Midi_def *p = 0;
 659                 if (id)
 660                         p = dynamic_cast<Midi_def*> (id->clone ());
 661                 else
 662                         p = new Midi_def;
 663
 664                 $$ = p;
 665                 THIS->lexer_->add_scope (p->scope_);
 666         }
 667         | PAPER         {
 668                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 669                   Paper_def *p = 0;
 670                 if (id)
 671                         p = dynamic_cast<Paper_def*> (id->clone ());
 672                 else
 673                         p = new Paper_def;
 674
 675                 THIS->lexer_->add_scope (p->scope_);
 676                 $$ = p;
 677         }
 678         ;
 679
 680
 681 music_output_def_body:
 682         music_output_def_head '{' {
 683                 $$ = $1;
 684                 $$->input_origin_. set_spot (THIS->here_input ());
 685
 686         }
 687         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 688                 scm_gc_unprotect_object ($1->self_scm ());
 689                 Music_output_def *o = unsmob_music_output_def ($3);
 690                 o->input_origin_.set_spot (THIS->here_input ());
 691                 $$ = o;
 692                 THIS->lexer_->remove_scope ();
 693                 THIS->lexer_->add_scope (o->scope_);
 694         }
 695         | music_output_def_body assignment  {
 696
 697         }
 698         | music_output_def_body context_def_spec_block  {
 699                 $$->assign_context_def ($2);
 700         }
 701         | music_output_def_body tempo_event  {
 702                 /*
 703                         junk this ? there already is tempo stuff in
 704                         music.
 705                 */
 706                 int m = ly_scm2int ( $2->get_property ("metronome-count"));
 707                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 708                 Midi_def *md = dynamic_cast<Midi_def*> ($$);
 709                 if (md)
 710                         md->set_tempo (d->get_length (), m);
 711                 scm_gc_unprotect_object ($2->self_scm ());
 712         }
 713         | music_output_def_body error {
 714
 715         }
 716         ;
 717
 718 tempo_event:
 719         TEMPO steno_duration '=' bare_unsigned  {
 720                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 721                 $$->set_property ("tempo-unit", $2);
 722                 $$->set_property ("metronome-count", scm_int2num ( $4));
 723         }
 724         ;
 725
 726 /*
 727 The representation of a  list is the
 728
 729   (LIST . LAST-CONS)
 730
 731  to have  efficient append.
 732 */
 733 Music_list:
 734         /* empty */ {
 735                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 736         }
 737         | Music_list Music {
 738                 SCM s = $$;
 739                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 740                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 741                 if (is_pair (ly_cdr (s)))
 742                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 743                 else
 744                         scm_set_car_x (s, c); /* set first cons */
 745                 scm_set_cdr_x (s, c);  /* remember last cell */
 746         }
 747         | Music_list error {
 748         }
 749         ;
 750
 751
 752 Music:
 753         Simple_music
 754         | Composite_music
 755         ;
 756
 757 Alternative_music:
 758         /* empty */ {
 759                 $$ = SCM_EOL;
 760         }
 761         | ALTERNATIVE '{' Music_list '}' {
 762                 $$ = $3;
 763         }
 764         ;
 765
 766 Repeated_music:
 767         REPEAT string bare_unsigned Music Alternative_music
 768         {
 769                 Music *beg = $4;
 770                 int times = $3;
 771                 SCM alts = is_pair ($5) ? ly_car ($5) : SCM_EOL;
 772                 if (times < scm_ilength (alts)) {
 773                   unsmob_music (ly_car (alts))
 774                     ->origin ()->warning (
 775                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 776                   alts = ly_truncate_list (times, alts);
 777                 }
 778
 779
 780                 SCM proc = ly_scheme_function ("make-repeated-music");
 781
 782                 SCM mus = scm_call_1 (proc, $2);
 783                 scm_gc_protect_object (mus); // UGH.
 784                 Music *r = unsmob_music (mus);
 785                 if (beg)
 786                         {
 787                         r-> set_property ("element", beg->self_scm ());
 788                         scm_gc_unprotect_object (beg->self_scm ());
 789                         }
 790                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 791
 792                 r-> set_property ("elements",alts);
 793                 if (is_equal ($2, scm_makfrom0str ("tremolo"))) {
 794                         /*
 795                         TODO: move this code to Scheme.
 796                         */
 797
 798                         /*
 799                         we can not get durations and other stuff correct down the line, so we have to
 800                         add to the duration log here.
 801                         */
 802                         SCM func = ly_scheme_function ("shift-duration-log");
 803
 804                         int dots = ($3 % 3) ? 0 : 1;
 805                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 806
 807                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 808
 809                         if (seq) {
 810                                 int list_len = scm_ilength (seq->music_list ());
 811                                 if (list_len != 2)
 812                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 813                                 shift -= 1;
 814                                 r->compress (Moment (Rational (1, list_len)));
 815                                 }
 816                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 817
 818                 }
 819                 r->set_spot (*$4->origin ());
 820
 821                 $$ = r;
 822         }
 823         ;
 824
 825 Sequential_music:
 826         SEQUENTIAL '{' Music_list '}'           {
 827                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 828                 $$->set_property ("elements", ly_car ($3));
 829                 $$->set_spot (THIS->here_input ());
 830         }
 831         | '{' Music_list '}'            {
 832                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 833                 $$->set_property ("elements", ly_car ($2));
 834                 $$->set_spot (THIS->here_input ());
 835         }
 836         ;
 837
 838 Simultaneous_music:
 839         SIMULTANEOUS '{' Music_list '}'{
 840                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 841                 $$->set_property ("elements", ly_car ($3));
 842                 $$->set_spot (THIS->here_input ());
 843
 844         }
 845         | simul_open Music_list simul_close     {
 846                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 847                 $$->set_property ("elements", ly_car ($2));
 848                 $$->set_spot (THIS->here_input ());
 849         }
 850         ;
 851
 852 Simple_music:
 853         event_chord             { $$ = $1; }
 854         | APPLYOUTPUT embedded_scm {
 855                 if (!ly_input_procedure_p ($2))
 856                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 857                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 858                 $$->set_property ("procedure", $2);
 859                 $$->set_spot (THIS->here_input ());
 860         }
 861         | APPLYCONTEXT embedded_scm {
 862                 if (!ly_input_procedure_p ($2))
 863                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 864                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 865                 $$->set_property ("procedure", $2);
 866                 $$->set_spot (THIS->here_input ());
 867         }
 868         | MUSIC_IDENTIFIER {
 869                 $$ = unsmob_music ($1);
 870         }
 871         | music_property_def
 872         | context_change
 873         ;
 874
 875
 876 optional_context_mod:
 877         /**/ { $$ = SCM_EOL; }
 878         | WITH '{' context_mod_list '}'  { $$ = $3; }
 879         ;
 880
 881 grace_head:
 882         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 883         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 884         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 885         ;
 886
 887 context_mod_list:
 888         /* */  { $$ = SCM_EOL; }
 889         | context_mod_list context_mod  {
 890                  $$ = scm_cons ($2, $1);
 891         }
 892         ;
 893
 894 Composite_music:
 895         AUTOCHANGE Music        {
 896                 SCM proc = ly_scheme_function ("make-autochange-music");
 897
 898                 SCM res = scm_call_1 (proc, $2->self_scm ());
 899                 scm_gc_unprotect_object ($2->self_scm ());
 900                 $$ = unsmob_music (res);
 901                 scm_gc_protect_object (res);
 902                 $$->set_spot (THIS->here_input ());
 903         }
 904         | PARTCOMBINE Music Music {
 905                 SCM proc = ly_scheme_function ("make-part-combine-music");
 906
 907                 SCM res = scm_call_1 (proc, scm_listify ($2->self_scm (),
 908                         $3->self_scm (), SCM_UNDEFINED));
 909                 scm_gc_unprotect_object ($3->self_scm ());
 910                 scm_gc_unprotect_object ($2->self_scm ());
 911                 $$ = unsmob_music (res);
 912                 scm_gc_protect_object (res);
 913                 $$->set_spot (THIS->here_input ());
 914         }
 915         | grace_head Music {
 916 #if 1
 917         /*
 918                 The other version is for easier debugging  of
 919                 Sequential_music_iterator in combination with grace notes.
 920         */
 921
 922 /*
 923
 924 TODO: should distinguish between both grace types in the
 925 basic music objects too, since the meaning is different.
 926
 927 */
 928
 929                 String start_str = "start" + ly_scm2string ($1) + "Music";
 930                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 931
 932                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 933                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 934
 935                 Music *startm = unsmob_music (start);
 936                 Music *stopm = unsmob_music (stop);
 937
 938                 SCM ms = SCM_EOL;
 939                 if (stopm) {
 940                         stopm = stopm->clone ();
 941                         ms = scm_cons (stopm->self_scm (), ms);
 942                         scm_gc_unprotect_object (stopm->self_scm ());
 943                 }
 944                 ms = scm_cons ($2->self_scm (), ms);
 945                 scm_gc_unprotect_object ($2->self_scm ());
 946                 if (startm) {
 947                         startm = startm->clone ();
 948                         ms = scm_cons (startm->self_scm (), ms);
 949                         scm_gc_unprotect_object (startm->self_scm ());
 950                 }
 951
 952                 Music* seq = MY_MAKE_MUSIC ("SequentialMusic");
 953                 seq->set_property ("elements", ms);
 954
 955
 956                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 957                 $$->set_property ("element", seq->self_scm ());
 958                 scm_gc_unprotect_object (seq->self_scm ());
 959 #else
 960                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 961                 $$->set_property ("element", $2->self_scm ());
 962                 scm_gc_unprotect_object ($2->self_scm ());
 963 #endif
 964         }
 965         | CONTEXT string '=' string optional_context_mod Music {
 966                 $$ = context_spec_music ($2, $4, $6, $5);
 967
 968         }
 969         | CONTEXT STRING optional_context_mod Music {
 970                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 971         }
 972         | NEWCONTEXT string optional_context_mod Music {
 973                 $$ = context_spec_music ($2, get_next_unique_context (),
 974                                          $4, $3);
 975         }
 976
 977         | TIMES {
 978                 THIS->push_spot ();
 979         }
 980         /* CONTINUED */
 981                 fraction Music
 982
 983         {
 984                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
 985                 Music *mp = $4;
 986
 987                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
 988                 $$->set_spot (THIS->pop_spot ());
 989
 990                 $$->set_property ("element", mp->self_scm ());
 991                 scm_gc_unprotect_object (mp->self_scm ());
 992                 $$->set_property ("numerator", scm_int2num (n));
 993                 $$->set_property ("denominator", scm_int2num (d));
 994                 $$->compress (Moment (Rational (n,d)));
 995
 996         }
 997         | Repeated_music                { $$ = $1; }
 998         | Simultaneous_music            { $$ = $1; }
 999         | Sequential_music              { $$ = $1; }
1000         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1001                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1002                 Music *p = $4;
1003                 Pitch from = *unsmob_pitch ($2);
1004                 Pitch to = *unsmob_pitch ($3);
1005
1006                 p->transpose (interval (from, to));
1007                 $$->set_property ("element", p->self_scm ());
1008                 scm_gc_unprotect_object (p->self_scm ());
1009         }
1010         | APPLY embedded_scm Music  {
1011                 if (!ly_input_procedure_p ($2))
1012                         {
1013                         THIS->parser_error (_ ("\\apply takes function argument"));
1014                         $$ = $3;
1015                         }
1016                 else
1017                         {
1018                         SCM ret = scm_call_1 ($2, $3->self_scm ());
1019                         Music *m = unsmob_music (ret);
1020                         if (!m) {
1021                                 THIS->parser_error ("\\apply must return a Music");
1022                                 m = MY_MAKE_MUSIC ("Music");
1023                                 }
1024                         $$ = m;
1025                         }
1026         }
1027         | NOTES
1028                 {
1029                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1030                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1031         }
1032         Music
1033                 { $$ = $3;
1034                   THIS->lexer_->pop_state ();
1035                 }
1036         | DRUMS
1037                 {
1038                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1039                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1040         }
1041         Music
1042                 { $$ = $3;
1043                   THIS->lexer_->pop_state ();
1044                 }
1045         | FIGURES
1046                 { THIS->lexer_->push_figuredbass_state (); }
1047         Music
1048                 {
1049                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1050                   chm->set_property ("element", $3->self_scm ());
1051                   $$ = chm;
1052                   scm_gc_unprotect_object ($3->self_scm ());
1053
1054                   THIS->lexer_->pop_state ();
1055         }
1056         | CHORDS {
1057                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1058                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1059                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1060                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1061
1062         } Music {
1063                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1064                   chm->set_property ("element", $3->self_scm ());
1065                   scm_gc_unprotect_object ($3->self_scm ());
1066                   $$ = chm;
1067
1068                   THIS->lexer_->pop_state ();
1069         }
1070         | LYRICS
1071                 { THIS->lexer_->push_lyric_state (); }
1072         Music
1073                 {
1074                   $$ = $3;
1075                   THIS->lexer_->pop_state ();
1076         }
1077         | relative_music        { $$ = $1; }
1078         | re_rhythmed_music     { $$ = $1; }
1079         | TAG embedded_scm Music {
1080                 tag_music ($3, $2, THIS->here_input ());
1081                 $$ = $3;
1082         }
1083         ;
1084
1085 relative_music:
1086         RELATIVE absolute_pitch Music {
1087                 Music *p = $3;
1088                 Pitch pit = *unsmob_pitch ($2);
1089                 $$ = MY_MAKE_MUSIC ("RelativeOctaveMusic");
1090
1091                 $$->set_property ("element", p->self_scm ());
1092                 scm_gc_unprotect_object (p->self_scm ());
1093
1094
1095                 Pitch retpitch = p->to_relative_octave (pit);
1096                 if (lily_1_8_relative)
1097                         $$->set_property ("last-pitch", retpitch.smobbed_copy ());
1098         }
1099         ;
1100
1101 re_rhythmed_music:
1102         ADDLYRICS Music Music {
1103         Music *l = MY_MAKE_MUSIC ("LyricCombineMusic");
1104           l->set_property ("elements", scm_listify ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1105           scm_gc_unprotect_object ($3->self_scm ());
1106           scm_gc_unprotect_object ($2->self_scm ());
1107           $$ = l;
1108         }
1109         | NEWADDLYRICS string Music {
1110           Music *l = MY_MAKE_MUSIC ("NewLyricCombineMusic");
1111           l->set_property ("element", $3->self_scm ());
1112           scm_gc_unprotect_object ($3->self_scm ());
1113           $$ = l;
1114           l->set_property ("associated-context", $2);
1115         }
1116         ;
1117
1118 context_change:
1119         CHANGE STRING '=' STRING  {
1120                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1121                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1122                 t-> set_property ("change-to-id", $4);
1123
1124                 $$ = t;
1125                 $$->set_spot (THIS->here_input ());
1126         }
1127         ;
1128
1129 property_operation:
1130         STRING '='  scalar {
1131                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1132                         scm_string_to_symbol ($1), $3);
1133         }
1134         | UNSET STRING {
1135                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1136                         scm_string_to_symbol ($2));
1137         }
1138         | OVERRIDE STRING embedded_scm '=' embedded_scm {
1139                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1140                         scm_string_to_symbol ($2), $3, $5);
1141         }
1142         | REVERT STRING embedded_scm {
1143                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1144                         scm_string_to_symbol ($2), $3);
1145         }
1146         ;
1147
1148 context_def_mod:
1149         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1150         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1151         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1152
1153         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1154         | DENIES { $$ = ly_symbol2scm ("denies"); }
1155
1156         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1157         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1158         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1159         | NAME { $$ = ly_symbol2scm ("context-name"); }
1160         ;
1161
1162 context_mod:
1163         property_operation { $$ = $1; }
1164         | context_def_mod STRING {
1165                 $$ = scm_list_2 ($1, $2);
1166         }
1167         ;
1168
1169 context_prop_spec:
1170         STRING  {
1171                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"), scm_string_to_symbol ($1));
1172         }
1173         | STRING '.' STRING {
1174                 $$ = scm_list_2 (scm_string_to_symbol ($1), scm_string_to_symbol ($3));
1175         }
1176         ;
1177
1178 music_property_def:
1179         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1180                 $$ = property_op_to_music (scm_list_4 (
1181                         ly_symbol2scm ("poppush"),
1182                         ly_cadr ($2),
1183                         $3, $5));
1184                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1185         }
1186         | REVERT context_prop_spec embedded_scm {
1187                 $$ = property_op_to_music (scm_list_3 (
1188                         ly_symbol2scm ("pop"),
1189                         ly_cadr ($2),
1190                         $3));
1191
1192                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1193         }
1194         | SET context_prop_spec '=' scalar {
1195                 $$ = property_op_to_music (scm_list_3 (
1196                         ly_symbol2scm ("assign"),
1197                         ly_cadr ($2),
1198                         $4));
1199                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1200         }
1201         | UNSET context_prop_spec {
1202                 $$ = property_op_to_music (scm_list_2 (
1203                         ly_symbol2scm ("unset"),
1204                         ly_cadr ($2)));
1205                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1206         }
1207         | ONCE music_property_def {
1208                 SCM e = $2->get_property ("element");
1209                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1210                 $$ = $2;
1211
1212         }
1213         ;
1214
1215
1216
1217 scalar:
1218         string          { $$ = $1; }
1219         | bare_int      { $$ = scm_int2num ($1); }
1220         | embedded_scm  { $$ = $1; }
1221         | full_markup {  $$ = $1; }
1222         | DIGIT { $$ = scm_int2num ($1); }
1223         ;
1224
1225 /*
1226 This is a trick:
1227
1228 Adding pre_events to the simple_element
1229 makes the choice between
1230
1231   string:  STRING
1232
1233 and
1234
1235   simple_element: STRING
1236
1237 a single shift/reduction conflict.
1238
1239 nevertheless, this is not very clean, and we should find a different
1240 solution.
1241
1242 */
1243 pre_events: {
1244                 THIS->push_spot ();
1245         }
1246         ;
1247
1248 event_chord:
1249         pre_events simple_element post_events   {
1250                 SCM elts = $2-> get_property ("elements");
1251
1252                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1253
1254                 $2->set_property ("elements", elts);
1255                 $$ = $2;
1256         }
1257         | command_element
1258         | note_chord_element
1259         ;
1260
1261
1262 note_chord_element:
1263         chord_body optional_notemode_duration post_events
1264         {
1265                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1266                 SCM es = $1->get_property ("elements");
1267                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1268
1269                 for (SCM s = es; is_pair (s); s = ly_cdr (s))
1270                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1271                 es = ly_append2 (es, postevs);
1272
1273                 $1-> set_property ("elements", es);
1274                 $$ = $1;
1275         }
1276         ;
1277
1278 chord_open: '<'
1279         ;
1280
1281 chord_close: '>'
1282         ;
1283
1284 simul_open: LESSLESS
1285         ;
1286
1287 simul_close: MOREMORE
1288         ;
1289
1290 chord_body:
1291         chord_open chord_body_elements chord_close
1292         {
1293                 $$ = MY_MAKE_MUSIC ("EventChord");
1294                 $$->set_property ("elements",
1295                         scm_reverse_x ($2, SCM_EOL));
1296         }
1297         ;
1298
1299 chord_body_elements:
1300         /* empty */             { $$ = SCM_EOL; }
1301         | chord_body_elements chord_body_element {
1302                 $$ = scm_cons ($2->self_scm (), $1);
1303                 scm_gc_unprotect_object ($2->self_scm ());
1304         }
1305         ;
1306
1307 chord_body_element:
1308         pitch exclamations questions post_events
1309         {
1310                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1311                 n->set_property ("pitch", $1);
1312                 if ($3 % 2)
1313                         n->set_property ("cautionary", SCM_BOOL_T);
1314                 if ($2 % 2 || $3 % 2)
1315                         n->set_property ("force-accidental", SCM_BOOL_T);
1316
1317                 if (is_pair ($4)) {
1318                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1319                         n->set_property ("articulations", arts);
1320                 }
1321                 $$ = n;
1322         }
1323         | DRUM_PITCH post_events {
1324                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1325                 n->set_property ("duration", $2);
1326                 n->set_property ("drum-type", $1);
1327                 n->set_spot (THIS->here_input ());
1328
1329                 if (is_pair ($2)) {
1330                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1331                         n->set_property ("articulations", arts);
1332                 }
1333                 $$ = n;
1334         }
1335         ;
1336
1337 add_quote:
1338         ADDQUOTE string Music {
1339                 SCM adder = ly_scheme_function ("add-quotable");
1340
1341                 scm_call_2 (adder, $2, $3->self_scm ());
1342                 scm_gc_unprotect_object ($3->self_scm ());
1343         }
1344         ;
1345
1346 command_element:
1347         command_req {
1348                 $$ = MY_MAKE_MUSIC ("EventChord");
1349                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1350                 scm_gc_unprotect_object ($1->self_scm ());
1351
1352                 $$-> set_spot (THIS->here_input ());
1353                 $1-> set_spot (THIS->here_input ());
1354         }
1355         | SKIP duration_length {
1356                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1357                 skip->set_property ("duration", $2);
1358
1359                 $$ = skip;
1360         }
1361         | QUOTE STRING duration_length {
1362                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1363                 SCM evs = SCM_EOL;
1364                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1365                 {
1366                         SCM key = $2; // use symbol?
1367                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1368                 }
1369                 Music *quote = 0;
1370                 if (is_vector (evs))
1371                 {
1372                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1373                         quote->set_property ("duration", $3);
1374                         quote->set_property ("quoted-events", evs);
1375                 } else {
1376                         THIS->here_input ().warning (_f ("Can\'t find music"));
1377                         quote = MY_MAKE_MUSIC ("Event");
1378                 }
1379                 quote->set_spot (THIS->here_input ());
1380                 $$ = quote;
1381         }
1382         | OCTAVE { THIS->push_spot (); }
1383           pitch {
1384                 Music *l = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1385                 $$ = l;
1386                 $$->set_spot (THIS->pop_spot ());
1387                 $$->set_property ("pitch", $3);
1388         }
1389         | E_LEFTSQUARE {
1390                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1391                 l->set_property ("span-direction", scm_int2num (START));
1392                 l->set_spot (THIS->here_input ());
1393
1394                 $$ = MY_MAKE_MUSIC ("EventChord");
1395                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1396                 scm_gc_unprotect_object (l->self_scm ());
1397                 $$->set_spot (THIS->here_input ());
1398         }
1399         | E_RIGHTSQUARE {
1400                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1401                 l->set_property ("span-direction", scm_int2num (STOP));
1402                 l->set_spot (THIS->here_input ());
1403
1404                 $$ = MY_MAKE_MUSIC ("EventChord");
1405                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1406                 $$->set_spot (THIS->here_input ());
1407                 scm_gc_unprotect_object (l->self_scm ());
1408         }
1409         | E_BACKSLASH {
1410                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1411                 $$->set_spot (THIS->here_input ());
1412         }
1413         | '|'      {
1414                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1415
1416                 if (Music * m = unsmob_music (pipe))
1417                         $$ = m->clone ();
1418                 else
1419                         $$ = MY_MAKE_MUSIC ("BarCheck");
1420
1421                 $$->set_spot (THIS->here_input ());
1422         }
1423         | TRANSPOSITION pitch {
1424                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1425                                         $2);
1426                 $$->set_spot (THIS-> here_input ());
1427                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1428                         $$, SCM_EOL);
1429         }
1430         | BAR STRING                    {
1431                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1432
1433                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1434                                         t, SCM_EOL);
1435                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1436                 $$->set_spot (THIS->here_input ());
1437                 t->set_spot (THIS->here_input ());
1438         }
1439         | PARTIAL duration_length       {
1440                 Moment m = - unsmob_duration ($2)->get_length ();
1441                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1442                 p->set_spot (THIS->here_input ());
1443                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1444                                         p, SCM_EOL);
1445                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1446                                         p, SCM_EOL);
1447                 $$ = p;
1448         }
1449         | CLEF STRING  {
1450                 SCM proc = ly_scheme_function ("make-clef-set");
1451
1452                 SCM result = scm_call_1 (proc, $2);
1453                 scm_gc_protect_object (result);
1454                 $$ = unsmob_music (result);
1455         }
1456         | TIME_T fraction  {
1457                 SCM proc= ly_scheme_function ("make-time-signature-set");
1458
1459                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1460                 scm_gc_protect_object (result);
1461                 $$ = unsmob_music (result);
1462         }
1463         | MARK scalar {
1464                 SCM proc = ly_scheme_function ("make-mark-set");
1465
1466                 SCM result = scm_call_1 (proc, $2);
1467                 scm_gc_protect_object (result);
1468                 $$ = unsmob_music (result);
1469         }
1470         ;
1471
1472 command_req:
1473         BREATHE {
1474                 $$ = MY_MAKE_MUSIC ("BreathingSignEvent");
1475         }
1476         | E_TILDE {
1477                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1478         }
1479         | MARK DEFAULT  {
1480                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1481                 $$ = m;
1482         }
1483         | tempo_event {
1484                 $$ = $1;
1485         }
1486         | KEY DEFAULT {
1487                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1488                 $$ = key;
1489         }
1490         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1491
1492                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1493                 if (scm_ilength ($3) > 0)
1494                 {
1495                         key->set_property ("pitch-alist", $3);
1496                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1497                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1498                 } else {
1499                         THIS->parser_error (_ ("Second argument must be pitch list."));
1500                 }
1501
1502                 $$ = key;
1503         }
1504         ;
1505
1506 post_events:
1507         /* empty */ {
1508                 $$ = SCM_EOL;
1509         }
1510         | post_events post_event {
1511                 $2->set_spot (THIS->here_input ());
1512                 $$ = scm_cons ($2->self_scm (), $$);
1513                 scm_gc_unprotect_object ($2->self_scm ());
1514         }
1515         | post_events tagged_post_event {
1516                 $2 -> set_spot (THIS->here_input ());
1517                 $$ = scm_cons ($2->self_scm (), $$);
1518                 scm_gc_unprotect_object ($2->self_scm ());
1519         }
1520         ;
1521
1522
1523 tagged_post_event:
1524         '-' TAG embedded_scm post_event {
1525                 tag_music ($4, $3, THIS->here_input ());
1526                 $$ = $4;
1527         }
1528         ;
1529
1530 post_event:
1531         direction_less_event {
1532                 $$ = $1;
1533         }
1534         | HYPHEN {
1535                 if (!THIS->lexer_->is_lyric_state ())
1536                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1537                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1538         }
1539         | EXTENDER {
1540                 if (!THIS->lexer_->is_lyric_state ())
1541                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1542                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1543         }
1544         | script_dir direction_reqd_event {
1545                 if ($1)
1546                         $2->set_property ("direction", scm_int2num ($1));
1547                 $$ = $2;
1548         }
1549         | script_dir direction_less_event {
1550                 if ($1)
1551                         $2->set_property ("direction", scm_int2num ($1));
1552                 $$ = $2;
1553         }
1554         | string_number_event
1555         ;
1556
1557 string_number_event:
1558         E_UNSIGNED {
1559                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1560                 s->set_property ("string-number", scm_int2num ($1));
1561                 s->set_spot (THIS->here_input ());
1562                 $$ = s;
1563         }
1564         ;
1565
1566
1567 direction_less_event:
1568         '['  {
1569
1570
1571 /*
1572
1573 TODO: should take all these defs out of the parser, adn make use
1574 configurable, i.e.
1575
1576
1577 (set-articulation '~ "trill")
1578
1579 */
1580                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1581                 m->set_spot (THIS->here_input ());
1582                 m->set_property ("span-direction", scm_int2num (START));
1583                 $$ = m;
1584         }
1585         | ']'  {
1586                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1587                 m->set_spot (THIS->here_input ());
1588                 m->set_property ("span-direction", scm_int2num (STOP));
1589                 $$ = m;
1590         }
1591         | '~' {
1592                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1593                 m->set_spot (THIS->here_input ());
1594                 $$ = m;
1595         }
1596         | close_event {
1597                 $$ = $1;
1598                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1599                         scm_int2num (START));
1600         }
1601         | open_event {
1602                 $$ = $1;
1603                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1604                         scm_int2num (STOP));
1605         }
1606         | EVENT_IDENTIFIER      {
1607                 $$ = unsmob_music ($1);
1608         }
1609         | tremolo_type  {
1610                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1611                a->set_spot (THIS->here_input ());
1612                a->set_property ("tremolo-type", scm_int2num ($1));
1613                $$ = a;
1614         }
1615         ;
1616
1617 direction_reqd_event:
1618         gen_text_def {
1619                 $$ = $1;
1620         }
1621         | script_abbreviation {
1622                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1623                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1624                 if (is_string (s))
1625                         a->set_property ("articulation-type", s);
1626                 else THIS->parser_error (_ ("Expecting string as script definition"));
1627                 $$ = a;
1628         }
1629         ;
1630
1631 oct_check:
1632         /**/ { $$ = SCM_EOL; }
1633         | '='  { $$ = scm_int2num (0); }
1634         | '=' sub_quotes { $$ = scm_int2num ($2); }
1635         | '=' sup_quotes { $$ = scm_int2num ($2); }
1636         ;
1637
1638 sup_quotes:
1639         '\'' {
1640                 $$ = 1;
1641         }
1642         | sup_quotes '\'' {
1643                 $$ ++;
1644         }
1645         ;
1646
1647 sub_quotes:
1648         ',' {
1649                 $$ = 1;
1650         }
1651         | sub_quotes ',' {
1652                 $$++;
1653         }
1654         ;
1655
1656 steno_pitch:
1657         NOTENAME_PITCH  {
1658                 $$ = $1;
1659         }
1660         | NOTENAME_PITCH sup_quotes     {
1661                 Pitch p = *unsmob_pitch ($1);
1662                 p = p.transposed (Pitch ($2,0,0));
1663                 $$ = p.smobbed_copy ();
1664         }
1665         | NOTENAME_PITCH sub_quotes      {
1666                 Pitch p =* unsmob_pitch ($1);
1667                 p = p.transposed (Pitch (-$2,0,0));
1668                 $$ = p.smobbed_copy ();
1669         }
1670         ;
1671
1672 /*
1673 ugh. duplication
1674 */
1675
1676 steno_tonic_pitch:
1677         TONICNAME_PITCH {
1678                 $$ = $1;
1679         }
1680         | TONICNAME_PITCH sup_quotes    {
1681                 Pitch p = *unsmob_pitch ($1);
1682                 p = p.transposed (Pitch ($2,0,0));
1683                 $$ = p.smobbed_copy ();
1684         }
1685         | TONICNAME_PITCH sub_quotes     {
1686                 Pitch p =* unsmob_pitch ($1);
1687
1688                 p = p.transposed (Pitch (-$2,0,0));
1689                 $$ = p.smobbed_copy ();
1690         }
1691         ;
1692
1693 pitch:
1694         steno_pitch {
1695                 $$ = $1;
1696         }
1697         ;
1698
1699 pitch_also_in_chords:
1700         pitch
1701         | steno_tonic_pitch
1702         ;
1703
1704 close_event:
1705         '('     {
1706                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1707                 $$ = s;
1708                 s->set_spot (THIS->here_input ());
1709         }
1710         | E_OPEN        {
1711                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1712                 $$ = s;
1713                 s->set_spot (THIS->here_input ());
1714         }
1715         | E_SMALLER {
1716                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1717                 $$ = s;
1718                 s->set_spot (THIS->here_input ());
1719         }
1720         | E_BIGGER {
1721                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1722                 $$ = s;
1723                 s->set_spot (THIS->here_input ());
1724         }
1725         ;
1726
1727
1728 open_event:
1729         E_EXCLAMATION   {
1730                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1731                 s->set_spot (THIS->here_input ());
1732
1733                 $$ = s;
1734         }
1735         | ')'   {
1736                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1737                 $$ = s;
1738                 s->set_spot (THIS->here_input ());
1739
1740         }
1741         | E_CLOSE       {
1742                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1743                 $$ = s;
1744                 s->set_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1745                 s->set_spot (THIS->here_input ());
1746         }
1747         ;
1748
1749 gen_text_def:
1750         full_markup {
1751                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1752                 t->set_property ("text", $1);
1753                 t->set_spot (THIS->here_input ());
1754                 $$ = t;
1755         }
1756         | string {
1757                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1758                 t->set_property ("text", make_simple_markup (THIS->lexer_->encoding (), $1));
1759                 t->set_spot (THIS->here_input ());
1760                 $$ = t;
1761
1762         }
1763         | DIGIT {
1764                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1765                 t->set_property ("digit", scm_int2num ($1));
1766                 t->set_spot (THIS->here_input ());
1767                 $$ = t;
1768         }
1769         ;
1770
1771 script_abbreviation:
1772         '^'             {
1773                 $$ = scm_makfrom0str ("Hat");
1774         }
1775         | '+'           {
1776                 $$ = scm_makfrom0str ("Plus");
1777         }
1778         | '-'           {
1779                 $$ = scm_makfrom0str ("Dash");
1780         }
1781         | '|'           {
1782                 $$ = scm_makfrom0str ("Bar");
1783         }
1784         | '>'           {
1785                 $$ = scm_makfrom0str ("Larger");
1786         }
1787         | '.'           {
1788                 $$ = scm_makfrom0str ("Dot");
1789         }
1790         | '_' {
1791                 $$ = scm_makfrom0str ("Underscore");
1792         }
1793         ;
1794
1795 script_dir:
1796         '_'     { $$ = DOWN; }
1797         | '^'   { $$ = UP; }
1798         | '-'   { $$ = CENTER; }
1799         ;
1800
1801
1802 absolute_pitch:
1803         steno_pitch     {
1804                 $$ = $1;
1805         }
1806         ;
1807
1808 duration_length:
1809         multiplied_duration {
1810                 $$ = $1;
1811         }
1812         ;
1813
1814 optional_notemode_duration:
1815         {
1816                 Duration dd = THIS->default_duration_;
1817                 $$ = dd.smobbed_copy ();
1818
1819                 THIS->beam_check ($$);
1820         }
1821         | multiplied_duration   {
1822                 $$ = $1;
1823                 THIS->default_duration_ = *unsmob_duration ($$);
1824
1825                 THIS->beam_check ($$);
1826         }
1827         ;
1828
1829 steno_duration:
1830         bare_unsigned dots              {
1831                 int len = 0;
1832                 if (!is_duration ($1))
1833                         THIS->parser_error (_f ("not a duration: %d", $1));
1834                 else
1835                         len = intlog2 ($1);
1836
1837                 $$ = Duration (len, $2).smobbed_copy ();
1838         }
1839         | DURATION_IDENTIFIER dots      {
1840                 Duration *d = unsmob_duration ($1);
1841                 Duration k (d->duration_log (), d->dot_count () + $2);
1842                 *d = k;
1843                 $$ = $1;
1844         }
1845         ;
1846
1847
1848
1849
1850 multiplied_duration:
1851         steno_duration {
1852                 $$ = $1;
1853         }
1854         | multiplied_duration '*' bare_unsigned {
1855                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1856         }
1857         | multiplied_duration '*' FRACTION {
1858                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
1859
1860                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1861         }
1862         ;
1863
1864 fraction:
1865         FRACTION { $$ = $1; }
1866         | UNSIGNED '/' UNSIGNED {
1867                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
1868         }
1869         ;
1870
1871 dots:
1872         /* empty */     {
1873                 $$ = 0;
1874         }
1875         | dots '.' {
1876                 $$ ++;
1877         }
1878         ;
1879
1880
1881 tremolo_type:
1882         ':'     {
1883                 $$ = 0;
1884         }
1885         | ':' bare_unsigned {
1886                 if (!is_duration ($2))
1887                         THIS->parser_error (_f ("not a duration: %d", $2));
1888                 $$ = $2;
1889         }
1890         ;
1891
1892
1893
1894 /*****************************************************************
1895                 BASS FIGURES
1896 *****************************************************************/
1897 bass_number:
1898         DIGIT   {
1899                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
1900         }
1901         | UNSIGNED {
1902                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
1903         }
1904         | STRING { $$ = $1; }
1905         ;
1906
1907 bass_mod:
1908         '-'     { $$ = -2; }
1909         | '+'   { $$ = 2; }
1910         | '!'   { $$ = 0; }
1911         ;
1912
1913 bass_figure:
1914         FIGURE_SPACE {
1915                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1916                 $$ = bfr->self_scm ();
1917                 scm_gc_unprotect_object ($$);
1918         }
1919         | bass_number  {
1920                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1921                 $$ = bfr->self_scm ();
1922
1923                 bfr->set_property ("figure", $1);
1924
1925                 scm_gc_unprotect_object ($$);
1926         }
1927         | bass_figure bass_mod {
1928                 Music *m = unsmob_music ($1);
1929                 if ($2) {
1930                         SCM salter = m->get_property ("alteration");
1931                         int alter = is_number (salter) ? ly_scm2int (salter) : 0;
1932                         m->set_property ("alteration",
1933                                 scm_int2num (alter + $2));
1934                 } else {
1935                         m->set_property ("alteration", scm_int2num (0));
1936                 }
1937         }
1938         ;
1939
1940 br_bass_figure:
1941         '[' bass_figure {
1942                 $$ = $2;
1943                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
1944         }
1945         | bass_figure   {
1946                 $$ = $1;
1947         }
1948         | br_bass_figure ']' {
1949                 $$ = $1;
1950                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
1951         }
1952         ;
1953
1954 figure_list:
1955         /**/            {
1956                 $$ = SCM_EOL;
1957         }
1958         | figure_list br_bass_figure {
1959                 $$ = scm_cons ($2, $1);
1960         }
1961         ;
1962
1963 figure_spec:
1964         FIGURE_OPEN figure_list FIGURE_CLOSE {
1965                 Music *m = MY_MAKE_MUSIC ("EventChord");
1966                 $2 = scm_reverse_x ($2, SCM_EOL);
1967                 m->set_property ("elements", $2);
1968                 $$ = m->self_scm ();
1969         }
1970         ;
1971
1972
1973 optional_rest:
1974         /**/   { $$ = 0; }
1975         | REST { $$ = 1; }
1976         ;
1977
1978 simple_element:
1979         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1980
1981                 Input i = THIS->pop_spot ();
1982                 if (!THIS->lexer_->is_note_state ())
1983                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1984
1985                 Music *n = 0;
1986                 if ($6)
1987                         n = MY_MAKE_MUSIC ("RestEvent");
1988                 else
1989                         n = MY_MAKE_MUSIC ("NoteEvent");
1990
1991                 n->set_property ("pitch", $1);
1992                 n->set_property ("duration", $5);
1993
1994                 if (is_number ($4))
1995                 {
1996                         int q = ly_scm2int ($4);
1997                         n->set_property ("absolute-octave", scm_int2num (q-1));
1998                 }
1999
2000                 if ($3 % 2)
2001                         n->set_property ("cautionary", SCM_BOOL_T);
2002                 if ($2 % 2 || $3 % 2)
2003                         n->set_property ("force-accidental", SCM_BOOL_T);
2004
2005                 Music *v = MY_MAKE_MUSIC ("EventChord");
2006                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2007                 scm_gc_unprotect_object (n->self_scm ());
2008
2009                 v->set_spot (i);
2010                 n->set_spot (i);
2011                 $$ = v;
2012         }
2013         | DRUM_PITCH optional_notemode_duration {
2014                 Input i = THIS->pop_spot ();
2015
2016                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2017                 n->set_property ("duration", $2);
2018                 n->set_property ("drum-type", $1);
2019
2020                 Music *v = MY_MAKE_MUSIC ("EventChord");
2021                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2022                 scm_gc_unprotect_object (n->self_scm ());
2023                 v->set_spot (i);
2024                 n->set_spot (i);
2025                 $$ = v;
2026
2027         }
2028         | figure_spec optional_notemode_duration {
2029                 Music *m = unsmob_music ($1);
2030                 Input i = THIS->pop_spot ();
2031                 m->set_spot (i);
2032                 for (SCM s = m->get_property ("elements"); is_pair (s); s = ly_cdr (s))
2033                 {
2034                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2035                 }
2036                 $$ = m;
2037         }
2038         | RESTNAME optional_notemode_duration           {
2039
2040                 Input i = THIS->pop_spot ();
2041                 Music *ev = 0;
2042                 if (ly_scm2string ($1) == "s") {
2043                         /* Space */
2044                         ev = MY_MAKE_MUSIC ("SkipEvent");
2045                   }
2046                 else {
2047                         ev = MY_MAKE_MUSIC ("RestEvent");
2048
2049                     }
2050                 ev->set_property ("duration", $2);
2051                 ev->set_spot (i);
2052                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2053                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2054                 velt->set_spot (i);
2055
2056                 scm_gc_unprotect_object (ev->self_scm ());
2057
2058                 $$ = velt;
2059         }
2060         | MULTI_MEASURE_REST optional_notemode_duration         {
2061                 THIS->pop_spot ();
2062
2063                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2064                 SCM mus = scm_call_2 (proc, $2,
2065                         make_input (THIS->here_input ()));
2066                 scm_gc_protect_object (mus);
2067                 $$ = unsmob_music (mus);
2068         }
2069
2070         | lyric_element optional_notemode_duration      {
2071                 Input i = THIS->pop_spot ();
2072                 if (!THIS->lexer_->is_lyric_state ())
2073                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2074
2075                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2076                 lreq->set_property ("text", $1);
2077                 lreq->set_property ("duration",$2);
2078                 lreq->set_spot (i);
2079                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2080                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2081
2082                 $$= velt;
2083         }
2084         | new_chord {
2085                 THIS->pop_spot ();
2086
2087                 if (!THIS->lexer_->is_chord_state ())
2088                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2089                 $$ = unsmob_music ($1);
2090         }
2091         ;
2092
2093 lyric_element:
2094         full_markup { $$ = $1; }
2095         | STRING { $$ = $1; }
2096         ;
2097
2098 new_chord:
2099         steno_tonic_pitch optional_notemode_duration   {
2100                 $$ = make_chord ($1, $2, SCM_EOL);
2101         }
2102         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2103                 SCM its = scm_reverse_x ($4, SCM_EOL);
2104                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2105         }
2106         ;
2107
2108 chord_items:
2109         /**/ {
2110                 $$ = SCM_EOL;
2111         }
2112         | chord_items chord_item {
2113                 $$ = scm_cons ($2, $$);
2114         }
2115         ;
2116
2117 chord_separator:
2118         CHORD_COLON {
2119                 $$ = ly_symbol2scm ("chord-colon");
2120         }
2121         | CHORD_CARET {
2122                 $$ = ly_symbol2scm ("chord-caret");
2123         }
2124         | CHORD_SLASH steno_tonic_pitch {
2125                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2126         }
2127         | CHORD_BASS steno_tonic_pitch {
2128                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2129         }
2130         ;
2131
2132 chord_item:
2133         chord_separator {
2134                 $$ = $1;
2135         }
2136         | step_numbers {
2137                 $$ = scm_reverse_x ($1, SCM_EOL);
2138         }
2139         | CHORD_MODIFIER  {
2140                 $$ = $1;
2141         }
2142         ;
2143
2144 step_numbers:
2145         step_number { $$ = scm_cons ($1, SCM_EOL); }
2146         | step_numbers '.' step_number {
2147                 $$ = scm_cons ($3, $$);
2148         }
2149         ;
2150
2151 step_number:
2152         bare_unsigned {
2153                 $$ = make_chord_step ($1, 0);
2154         }
2155         | bare_unsigned '+' {
2156                 $$ = make_chord_step ($1, SHARP);
2157         }
2158         | bare_unsigned CHORD_MINUS {
2159                 $$ = make_chord_step ($1, FLAT);
2160         }
2161         ;
2162
2163 /*
2164         UTILITIES
2165
2166 TODO: should deprecate in favor of Scheme?
2167
2168  */
2169 number_expression:
2170         number_expression '+' number_term {
2171                 $$ = scm_sum ($1, $3);
2172         }
2173         | number_expression '-' number_term {
2174                 $$ = scm_difference ($1, $3);
2175         }
2176         | number_term
2177         ;
2178
2179 number_term:
2180         number_factor {
2181                 $$ = $1;
2182         }
2183         | number_factor '*' number_factor {
2184                 $$ = scm_product ($1, $3);
2185         }
2186         | number_factor '/' number_factor {
2187                 $$ = scm_divide ($1, $3);
2188         }
2189         ;
2190
2191 number_factor:
2192         '-'  number_factor { /* %prec UNARY_MINUS */
2193                 $$ = scm_difference ($2, SCM_UNDEFINED);
2194         }
2195         | bare_number
2196         ;
2197
2198
2199 bare_number:
2200         UNSIGNED        {
2201                 $$ = scm_int2num ($1);
2202         }
2203         | REAL          {
2204                 $$ = $1;
2205         }
2206         | NUMBER_IDENTIFIER             {
2207                 $$ = $1;
2208         }
2209         | REAL NUMBER_IDENTIFIER        {
2210                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2211         }
2212         | UNSIGNED NUMBER_IDENTIFIER    {
2213                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2214         }
2215         ;
2216
2217
2218 bare_unsigned:
2219         UNSIGNED {
2220                         $$ = $1;
2221         }
2222         | DIGIT {
2223                 $$ = $1;
2224         }
2225         ;
2226
2227 bare_int:
2228         bare_number {
2229                 if (scm_integer_p ($1) == SCM_BOOL_T)
2230                 {
2231                         int k = ly_scm2int ($1);
2232                         $$ = k;
2233                 } else
2234                 {
2235                         THIS->parser_error (_ ("need integer number arg"));
2236                         $$ = 0;
2237                 }
2238         }
2239         | '-' bare_int {
2240                 $$ = -$2;
2241         }
2242         ;
2243
2244
2245 string:
2246         STRING          {
2247                 $$ = $1;
2248         }
2249         | STRING_IDENTIFIER     {
2250                 $$ = $1;
2251         }
2252         | string '+' string {
2253                 $$ = scm_string_append (scm_list_2 ($1, $3));
2254         }
2255         ;
2256
2257
2258 exclamations:
2259                 { $$ = 0; }
2260         | exclamations '!'      { $$ ++; }
2261         ;
2262
2263 questions:
2264                 { $$ = 0; }
2265         | questions '?' { $$ ++; }
2266         ;
2267
2268
2269
2270 full_markup:
2271         MARKUP_IDENTIFIER {
2272                 $$ = $1;
2273         }
2274         | MARKUP
2275                 { THIS->lexer_->push_markup_state (); }
2276         markup
2277                 { $$ = $3;
2278                   THIS->lexer_->pop_state ();
2279                 }
2280         ;
2281
2282
2283 /*
2284 This should be done more dynamically if possible.
2285 */
2286 markup:
2287         STRING {
2288                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2289         }
2290         | MARKUP_HEAD_EMPTY {
2291                 $$ = scm_list_1 ($1);
2292         }
2293         | MARKUP_HEAD_MARKUP0 markup {
2294                 $$ = scm_list_2 ($1, $2);
2295         }
2296         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2297                 $$ = scm_list_3 ($1, $2, $3);
2298         }
2299         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2300                 $$ = scm_list_3 ($1, $2, $3);
2301         }
2302         | markup_line {
2303                 $$ = $1;
2304         }
2305         | MARKUP_HEAD_LIST0 markup_list {
2306                 $$ = scm_list_2 ($1,$2);
2307         }
2308         | MARKUP_HEAD_SCM0 embedded_scm {
2309                 $$ = scm_list_2 ($1, $2);
2310         }
2311         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2312                 $$ = scm_list_4 ($1, $2, $3, $4);
2313         }
2314         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2315                 $$ = scm_list_4 ($1, $2, $3, $4);
2316         }
2317         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2318                 $$ = scm_list_3 ($1, $2, $3);
2319         }
2320         | MARKUP_IDENTIFIER {
2321                 $$ = $1;
2322         }
2323         | STRING_IDENTIFIER {
2324                 $$ = $1;
2325         }
2326         ;
2327
2328 markup_list:
2329         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2330         ;
2331
2332 markup_line:
2333         '{' markup_list_body '}' {
2334                 SCM line = ly_scheme_function ("line-markup");
2335
2336                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2337         }
2338         ;
2339
2340 markup_list_body:
2341         /**/ {  $$ = SCM_EOL; }
2342         | markup_list_body markup {
2343                 $$ = scm_cons ($2, $1);
2344         }
2345         ;
2346
2347
2348 %%
2349
2350 void
2351 My_lily_parser::set_yydebug (bool )
2352 {
2353 #if 0
2354         yydebug = 1;
2355 #endif
2356 }
2357
2358 extern My_lily_parser *current_parser;
2359
2360 void
2361 My_lily_parser::do_yyparse ()
2362 {
2363         current_parser = this;;
2364         yyparse ((void*)this);
2365 }
2366
2367
2368 /*
2369 Should make this optional?    It will also complain when you do
2370
2371         [s4]
2372
2373 which is entirely legitimate.
2374
2375 Or we can scrap it. Barchecks should detect wrong durations, and
2376 skipTypesetting speeds it up a lot.
2377 */
2378
2379 void
2380 My_lily_parser::beam_check (SCM dur)
2381 {
2382   Duration *d = unsmob_duration (dur);
2383   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2384     {
2385       Music *m = unsmob_music (last_beam_start_);
2386       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2387     }
2388   last_beam_start_ = SCM_EOL;
2389 }
2390
2391
2392
2393
2394 /*
2395
2396 It is a little strange to have this function in this file, but
2397 otherwise, we have to import music classes into the lexer.
2398
2399 */
2400 int
2401 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2402 {
2403         if (is_string (sid)) {
2404                 *destination = sid;
2405                 return STRING_IDENTIFIER;
2406         } else if (is_number (sid)) {
2407                 *destination = sid;
2408                 return NUMBER_IDENTIFIER;
2409         } else if (unsmob_context_def (sid)) {
2410                 *destination = unsmob_context_def (sid)->clone_scm ();
2411                 return CONTEXT_DEF_IDENTIFIER;
2412         } else if (unsmob_score (sid)) {
2413                 Score *sc = new Score (*unsmob_score (sid));
2414                 *destination = sc->self_scm ();
2415                 return SCORE_IDENTIFIER;
2416         } else if (Music *mus = unsmob_music (sid)) {
2417                 mus = mus->clone ();
2418                 *destination = mus->self_scm ();
2419                 unsmob_music (*destination)->
2420                         set_property ("origin", make_input (last_input_));
2421                 return dynamic_cast<Event*> (mus)
2422                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2423         } else if (unsmob_duration (sid)) {
2424                 *destination = unsmob_duration (sid)->smobbed_copy ();
2425                 return DURATION_IDENTIFIER;
2426         } else if (unsmob_music_output_def (sid)) {
2427                 Music_output_def *p = unsmob_music_output_def (sid);
2428                 p = p->clone ();
2429
2430                 *destination = p->self_scm ();
2431                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2432         } else if (Text_item::markup_p (sid)) {
2433                 *destination = sid;
2434                 return MARKUP_IDENTIFIER;
2435         }
2436
2437         return -1;
2438 }
2439
2440 Music *
2441 property_op_to_music (SCM op)
2442 {
2443         Music *m = 0;
2444         SCM tag = ly_car (op);
2445         SCM symbol = ly_cadr (op);
2446         SCM args = ly_cddr (op);
2447         SCM grob_val = SCM_UNDEFINED;
2448         SCM grob_sym = SCM_UNDEFINED;
2449         SCM val = SCM_UNDEFINED;
2450
2451         if (tag == ly_symbol2scm ("assign"))
2452                 {
2453                 m = MY_MAKE_MUSIC ("PropertySet");
2454                 val = ly_car (args);
2455                 }
2456         else if (tag == ly_symbol2scm ("unset"))
2457                 m = MY_MAKE_MUSIC ("PropertyUnset");
2458         else if (tag == ly_symbol2scm ("poppush")
2459                  || tag == ly_symbol2scm ("push"))
2460                 {
2461                 m = MY_MAKE_MUSIC ("OverrideProperty");
2462                 grob_sym = ly_car (args);
2463                 grob_val = ly_cadr (args);
2464                 }
2465         else if (tag == ly_symbol2scm ("pop")) {
2466                 m = MY_MAKE_MUSIC ("RevertProperty");
2467                 grob_sym = ly_car (args);
2468                 }
2469
2470         m->set_property ("symbol", symbol);
2471
2472         if (val != SCM_UNDEFINED)
2473                 m->set_property ("value", val);
2474         if (grob_val != SCM_UNDEFINED)
2475                 m->set_property ("grob-value", grob_val);
2476
2477         if (grob_sym != SCM_UNDEFINED)
2478                 {
2479                 bool itc = internal_type_checking_global_b;
2480                 /* UGH.
2481                 */
2482                 bool autobeam = is_equal (symbol, ly_symbol2scm ("autoBeamSettings"));
2483                 if (autobeam)
2484                         internal_type_checking_global_b = false;
2485                 m->set_property ("grob-property", grob_sym);
2486                 if (autobeam)
2487                         internal_type_checking_global_b = itc;
2488                 }
2489
2490         if (op == ly_symbol2scm ("poppush"))
2491                 m->set_property ("pop-first", SCM_BOOL_T);
2492
2493
2494         return m;
2495 }
2496
2497 Music*
2498 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2499 {
2500         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2501
2502         csm->set_property ("element", m->self_scm ());
2503         scm_gc_unprotect_object (m->self_scm ());
2504
2505         csm->set_property ("context-type",
2506                 is_symbol (type) ? type : scm_string_to_symbol (type));
2507         csm->set_property ("property-operations", ops);
2508
2509         if (is_string (id))
2510                 csm->set_property ("context-id", id);
2511         return csm;
2512 }
2513
2514
2515 SCM
2516 get_next_unique_context ()
2517 {
2518         static int new_context_count;
2519
2520         char s[1024];
2521         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2522
2523         return scm_makfrom0str (s);
2524 }
2525