lily/parser.yy

   1 /*
   2   This file is part of LilyPond, the GNU music typesetter.
   3
   4   Copyright (C) 1997--2010 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5                  Jan Nieuwenhuizen <janneke@gnu.org>
   6
   7   LilyPond is free software: you can redistribute it and/or modify
   8   it under the terms of the GNU General Public License as published by
   9   the Free Software Foundation, either version 3 of the License, or
  10   (at your option) any later version.
  11
  12   LilyPond is distributed in the hope that it will be useful,
  13   but WITHOUT ANY WARRANTY; without even the implied warranty of
  14   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15   GNU General Public License for more details.
  16
  17   You should have received a copy of the GNU General Public License
  18   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  19 */
  20
  21 %{
  22
  23 #define YYDEBUG 1
  24 #define YYERROR_VERBOSE 1
  25 #define YYPARSE_PARAM my_lily_parser
  26 #define YYLEX_PARAM my_lily_parser
  27 #define PARSER ((Lily_parser *) my_lily_parser)
  28
  29 #define yyerror PARSER->parser_error
  30
  31 /* We use custom location type: Input objects */
  32 #define YYLTYPE Input
  33 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  34         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  35
  36
  37 %}
  38
  39 /* We use SCMs to do strings, because it saves us the trouble of
  40 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  41 of the parse stack onto the heap. */
  42
  43 %left PREC_TOP
  44 %left ADDLYRICS
  45 %left PREC_BOT
  46
  47 %expect 1
  48
  49 /* One shift/reduce problem
  50
  51 1.  \repeat
  52         \repeat .. \alternative
  53
  54     \repeat { \repeat .. \alternative }
  55
  56 or
  57
  58     \repeat { \repeat } \alternative
  59 */
  60
  61
  62 %pure_parser
  63 %locations
  64
  65
  66
  67 %{ // -*-Fundamental-*-
  68
  69 /*
  70 FIXME:
  71
  72    * The rules for who is protecting what are very shady.  Uniformise
  73      this.
  74
  75    * There are too many lexical modes?
  76 */
  77
  78 #include "config.hh"
  79
  80 #include <cctype>
  81 #include <cstdlib>
  82 #include <cstdio>
  83 using namespace std;
  84
  85 #include "book.hh"
  86 #include "context-def.hh"
  87 #include "context-mod.hh"
  88 #include "dimensions.hh"
  89 #include "file-path.hh"
  90 #include "input.hh"
  91 #include "international.hh"
  92 #include "lily-guile.hh"
  93 #include "lily-lexer.hh"
  94 #include "lily-parser.hh"
  95 #include "main.hh"
  96 #include "misc.hh"
  97 #include "music.hh"
  98 #include "music.hh"
  99 #include "output-def.hh"
 100 #include "paper-book.hh"
 101 #include "program-option.hh"
 102 #include "scm-hash.hh"
 103 #include "score.hh"
 104 #include "text-interface.hh"
 105 #include "warn.hh"
 106
 107 %}
 108
 109
 110 %union {
 111         Book *book;
 112         Output_def *outputdef;
 113         SCM scm;
 114         std::string *string;
 115         Music *music;
 116         Score *score;
 117         int i;
 118 }
 119
 120 %{
 121
 122 #define MY_MAKE_MUSIC(x, spot)  make_music_with_input (ly_symbol2scm (x), spot)
 123
 124 /* ES TODO:
 125 - Don't use lily module, create a new module instead.
 126 - delay application of the function
 127 */
 128 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 129   scm_apply_0 (proc, args)
 130 /* Syntactic Sugar. */
 131 #define MAKE_SYNTAX(name, location, ...)        \
 132   LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (PARSER->self_scm (), make_input (location), __VA_ARGS__, SCM_UNDEFINED));
 133
 134 SCM get_next_unique_context_id ();
 135 SCM get_next_unique_lyrics_context_id ();
 136
 137 #undef _
 138 #if !HAVE_GETTEXT
 139 #define _(x) x
 140 #else
 141 #include <libintl.h>
 142 #define _(x) gettext (x)
 143 #endif
 144
 145
 146 static Music *make_music_with_input (SCM name, Input where);
 147 SCM make_music_relative (Pitch start, SCM music, Input loc);
 148 SCM run_music_function (Lily_parser *, SCM expr);
 149 SCM get_first_context_id (SCM type, Music *m);
 150 SCM make_chord_elements (SCM pitch, SCM dur, SCM modification_list);
 151 SCM make_chord_step (int step, Rational alter);
 152 SCM make_simple_markup (SCM a);
 153 bool is_duration (int t);
 154 bool is_regular_identifier (SCM id);
 155 bool ly_input_procedure_p (SCM x);
 156 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 157 void set_music_properties (Music *p, SCM a);
 158
 159 %}
 160
 161 /* The third option is an alias that will be used to display the
 162    syntax error.  Bison CVS now correctly handles backslash escapes.
 163
 164    FIXME: Bison needs to translate some of these, eg, STRING.
 165
 166 */
 167
 168 /* Keyword tokens with plain escaped name.  */
 169 %token ACCEPTS "\\accepts"
 170 %token ADDLYRICS "\\addlyrics"
 171 %token ALIAS "\\alias"
 172 %token ALTERNATIVE "\\alternative"
 173 %token BOOK "\\book"
 174 %token BOOKPART "\\bookpart"
 175 %token CHANGE "\\change"
 176 %token CHORDMODE "\\chordmode"
 177 %token CHORDS "\\chords"
 178 %token CONSISTS "\\consists"
 179 %token CONTEXT "\\context"
 180 %token DEFAULT "\\default"
 181 %token DEFAULTCHILD "\\defaultchild"
 182 %token DENIES "\\denies"
 183 %token DESCRIPTION "\\description"
 184 %token DRUMMODE "\\drummode"
 185 %token DRUMS "\\drums"
 186 %token FIGUREMODE "\\figuremode"
 187 %token FIGURES "\\figures"
 188 %token GROBDESCRIPTIONS "\\grobdescriptions"
 189 %token HEADER "\\header"
 190 %token INVALID "\\invalid"
 191 %token KEY "\\key"
 192 %token LAYOUT "\\layout"
 193 %token LYRICMODE "\\lyricmode"
 194 %token LYRICS "\\lyrics"
 195 %token LYRICSTO "\\lyricsto"
 196 %token MARK "\\mark"
 197 %token MARKUP "\\markup"
 198 %token MARKUPLINES "\\markuplines"
 199 %token MIDI "\\midi"
 200 %token NAME "\\name"
 201 %token NOTEMODE "\\notemode"
 202 %token OCTAVE "\\octave"
 203 %token ONCE "\\once"
 204 %token OVERRIDE "\\override"
 205 %token PAPER "\\paper"
 206 %token PARTIAL "\\partial"
 207 %token RELATIVE "\\relative"
 208 %token REMOVE "\\remove"
 209 %token REPEAT "\\repeat"
 210 %token REST "\\rest"
 211 %token REVERT "\\revert"
 212 %token SCORE "\\score"
 213 %token SEQUENTIAL "\\sequential"
 214 %token SET "\\set"
 215 %token SIMULTANEOUS "\\simultaneous"
 216 %token SKIP "\\skip"
 217 %token TEMPO "\\tempo"
 218 %token TIMES "\\times"
 219 %token TRANSPOSE "\\transpose"
 220 %token TYPE "\\type"
 221 %token UNSET "\\unset"
 222 %token WITH "\\with"
 223
 224 /* Keyword token exceptions.  */
 225 %token TIME_T "\\time"
 226 %token NEWCONTEXT "\\new"
 227
 228
 229 /* Other string tokens.  */
 230
 231 %token CHORD_BASS "/+"
 232 %token CHORD_CARET "^"
 233 %token CHORD_COLON ":"
 234 %token CHORD_MINUS "-"
 235 %token CHORD_SLASH "/"
 236 %token ANGLE_OPEN "<"
 237 %token ANGLE_CLOSE ">"
 238 %token DOUBLE_ANGLE_OPEN "<<"
 239 %token DOUBLE_ANGLE_CLOSE ">>"
 240 %token E_BACKSLASH "\\"
 241 %token E_ANGLE_CLOSE "\\>"
 242 %token E_CHAR "\\C[haracter]"
 243 %token E_CLOSE "\\)"
 244 %token E_EXCLAMATION "\\!"
 245 %token E_BRACKET_OPEN "\\["
 246 %token E_OPEN "\\("
 247 %token E_BRACKET_CLOSE "\\]"
 248 %token E_ANGLE_OPEN "\\<"
 249 %token E_PLUS "\\+"
 250 %token E_TILDE "\\~"
 251 %token EXTENDER "__"
 252
 253 /*
 254 If we give names, Bison complains.
 255 */
 256 %token FIGURE_CLOSE /* "\\>" */
 257 %token FIGURE_OPEN /* "\\<" */
 258 %token FIGURE_SPACE "_"
 259 %token HYPHEN "--"
 260
 261 %token CHORDMODIFIERS
 262 %token LYRIC_MARKUP
 263 %token MULTI_MEASURE_REST
 264
 265
 266 %token <i> DIGIT
 267 %token <i> E_UNSIGNED
 268 %token <i> UNSIGNED
 269
 270 /* Artificial tokens, for more generic function syntax */
 271 %token <i> EXPECT_MARKUP;
 272 %token <i> EXPECT_MUSIC;
 273 %token <i> EXPECT_SCM;
 274 %token <i> EXPECT_MARKUP_LIST
 275 /* After the last argument. */
 276 %token <i> EXPECT_NO_MORE_ARGS;
 277
 278 %token <scm> BOOK_IDENTIFIER
 279 %token <scm> CHORDMODIFIER_PITCH
 280 %token <scm> CHORD_MODIFIER
 281 %token <scm> CHORD_REPETITION
 282 %token <scm> CONTEXT_DEF_IDENTIFIER
 283 %token <scm> CONTEXT_MOD_IDENTIFIER
 284 %token <scm> DRUM_PITCH
 285 %token <scm> DURATION_IDENTIFIER
 286 %token <scm> EVENT_IDENTIFIER
 287 %token <scm> FRACTION
 288 %token <scm> LYRICS_STRING
 289 %token <scm> LYRIC_MARKUP_IDENTIFIER
 290 %token <scm> MARKUP_FUNCTION
 291 %token <scm> MARKUP_LIST_FUNCTION
 292 %token <scm> MARKUP_IDENTIFIER
 293 %token <scm> MUSIC_FUNCTION
 294 %token <scm> MUSIC_IDENTIFIER
 295 %token <scm> NOTENAME_PITCH
 296 %token <scm> NUMBER_IDENTIFIER
 297 %token <scm> OUTPUT_DEF_IDENTIFIER
 298 %token <scm> REAL
 299 %token <scm> RESTNAME
 300 %token <scm> SCM_IDENTIFIER
 301 %token <scm> SCM_TOKEN
 302 %token <scm> SCORE_IDENTIFIER
 303 %token <scm> STRING
 304 %token <scm> STRING_IDENTIFIER
 305 %token <scm> TONICNAME_PITCH
 306
 307
 308 %type <book> book_block
 309 %type <book> book_body
 310 %type <book> bookpart_block
 311 %type <book> bookpart_body
 312
 313 %type <i> bare_unsigned
 314 %type <scm> figured_bass_alteration
 315 %type <i> dots
 316 %type <i> exclamations
 317 %type <i> optional_rest
 318 %type <i> questions
 319 %type <i> script_dir
 320 %type <i> sub_quotes
 321 %type <i> sup_quotes
 322 %type <i> tremolo_type
 323
 324 /* Music */
 325 %type <scm> composite_music
 326 %type <scm> grouped_music_list
 327 %type <scm> music
 328 %type <scm> prefix_composite_music
 329 %type <scm> repeated_music
 330 %type <scm> sequential_music
 331 %type <scm> simple_music
 332 %type <scm> simultaneous_music
 333 %type <scm> chord_body
 334 %type <scm> chord_body_element
 335 %type <scm> command_element
 336 %type <scm> command_event
 337 %type <scm> context_modification
 338 %type <scm> context_change
 339 %type <scm> direction_less_event
 340 %type <scm> direction_reqd_event
 341 %type <scm> event_chord
 342 %type <scm> gen_text_def
 343 %type <scm> music_property_def
 344 %type <scm> note_chord_element
 345 %type <scm> post_event
 346 %type <scm> re_rhythmed_music
 347 %type <scm> relative_music
 348 %type <scm> simple_element
 349 %type <scm> simple_music_property_def
 350 %type <scm> string_number_event
 351 %type <scm> tempo_event
 352
 353 %type <outputdef> output_def_body
 354 %type <outputdef> output_def_head
 355 %type <outputdef> output_def_head_with_mode_switch
 356 %type <outputdef> output_def
 357 %type <outputdef> paper_block
 358
 359 %type <scm> alternative_music
 360 %type <scm> generic_prefix_music_scm
 361 %type <scm> music_list
 362 %type <scm> absolute_pitch
 363 %type <scm> assignment_id
 364 %type <scm> bare_number
 365 %type <scm> unsigned_number
 366 %type <scm> bass_figure
 367 %type <scm> figured_bass_modification
 368 %type <scm> br_bass_figure
 369 %type <scm> bass_number
 370 %type <scm> chord_body_elements
 371 %type <scm> chord_item
 372 %type <scm> chord_items
 373 %type <scm> chord_separator
 374 %type <scm> context_def_mod
 375 %type <scm> context_def_spec_block
 376 %type <scm> context_def_spec_body
 377 %type <scm> context_mod
 378 %type <scm> context_mod_list
 379 %type <scm> context_prop_spec
 380 %type <scm> direction_less_char
 381 %type <scm> duration_length
 382 %type <scm> embedded_scm
 383 %type <scm> figure_list
 384 %type <scm> figure_spec
 385 %type <scm> fraction
 386 %type <scm> full_markup
 387 %type <scm> full_markup_list
 388 %type <scm> function_scm_argument
 389 %type <scm> function_arglist
 390 %type <scm> function_arglist_music_last
 391 %type <scm> function_arglist_nonmusic_last
 392 %type <scm> function_arglist_nonmusic
 393 %type <scm> identifier_init
 394 %type <scm> lilypond_header
 395 %type <scm> lilypond_header_body
 396 %type <scm> lyric_element
 397 %type <scm> lyric_markup
 398 %type <scm> markup
 399 %type <scm> markup_braced_list
 400 %type <scm> markup_braced_list_body
 401 %type <scm> markup_composed_list
 402 %type <scm> markup_command_list
 403 %type <scm> markup_command_list_arguments
 404 %type <scm> markup_command_basic_arguments
 405 %type <scm> markup_head_1_item
 406 %type <scm> markup_head_1_list
 407 %type <scm> markup_list
 408 %type <scm> markup_top
 409 %type <scm> mode_changing_head
 410 %type <scm> mode_changing_head_with_context
 411 %type <scm> multiplied_duration
 412 %type <scm> music_function_identifier_musicless_prefix
 413 %type <scm> music_function_event
 414 %type <scm> music_function_chord_body
 415 %type <scm> new_chord
 416 %type <scm> new_lyrics
 417 %type <scm> number_expression
 418 %type <scm> number_factor
 419 %type <scm> number_term
 420 %type <scm> octave_check
 421 %type <scm> optional_context_mod
 422 %type <scm> optional_id
 423 %type <scm> optional_notemode_duration
 424 %type <scm> pitch
 425 %type <scm> pitch_also_in_chords
 426 %type <scm> post_events
 427 %type <scm> property_operation
 428 %type <scm> property_path property_path_revved
 429 %type <scm> scalar
 430 %type <scm> script_abbreviation
 431 %type <scm> simple_chord_elements
 432 %type <scm> simple_markup
 433 %type <scm> simple_string
 434 %type <scm> steno_duration
 435 %type <scm> steno_pitch
 436 %type <scm> steno_tonic_pitch
 437 %type <scm> step_number
 438 %type <scm> step_numbers
 439 %type <scm> string
 440 %type <scm> tempo_range
 441
 442 %type <score> score_block
 443 %type <score> score_body
 444
 445
 446 %left '-' '+'
 447
 448 /* We don't assign precedence to / and *, because we might need varied
 449 prec levels in different prods */
 450
 451 %left UNARY_MINUS
 452
 453 %%
 454
 455 lilypond:       /* empty */
 456         | lilypond toplevel_expression {
 457         }
 458         | lilypond assignment {
 459         }
 460         | lilypond error {
 461                 PARSER->error_level_ = 1;
 462         }
 463         | lilypond INVALID      {
 464                 PARSER->error_level_ = 1;
 465         }
 466         ;
 467
 468
 469 toplevel_expression:
 470         lilypond_header {
 471                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 472         }
 473         | book_block {
 474                 Book *book = $1;
 475                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-book-handler");
 476                 scm_call_2 (proc, PARSER->self_scm (), book->self_scm ());
 477                 book->unprotect ();
 478         }
 479         | bookpart_block {
 480                 Book *bookpart = $1;
 481                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 482                 scm_call_2 (proc, PARSER->self_scm (), bookpart->self_scm ());
 483                 bookpart->unprotect ();
 484         }
 485         | score_block {
 486                 Score *score = $1;
 487
 488                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-score-handler");
 489                 scm_call_2 (proc, PARSER->self_scm (), score->self_scm ());
 490                 score->unprotect ();
 491         }
 492         | composite_music {
 493                 Music *music = unsmob_music ($1);
 494                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-music-handler");
 495                 scm_call_2 (proc, PARSER->self_scm (), music->self_scm ());
 496         }
 497         | full_markup {
 498                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 499                 scm_call_2 (proc, PARSER->self_scm (), scm_list_1 ($1));
 500         }
 501         | full_markup_list {
 502                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 503                 scm_call_2 (proc, PARSER->self_scm (), $1);
 504         }
 505         | output_def {
 506                 SCM id = SCM_EOL;
 507                 Output_def * od = $1;
 508
 509                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 510                         id = ly_symbol2scm ("$defaultpaper");
 511                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 512                         id = ly_symbol2scm ("$defaultmidi");
 513                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 514                         id = ly_symbol2scm ("$defaultlayout");
 515
 516                 PARSER->lexer_->set_identifier (id, od->self_scm ());
 517                 od->unprotect();
 518         }
 519         ;
 520
 521 embedded_scm:
 522         SCM_TOKEN
 523         | SCM_IDENTIFIER
 524         ;
 525
 526
 527 lilypond_header_body:
 528         {
 529                 $$ = get_header (PARSER);
 530                 PARSER->lexer_->add_scope ($$);
 531         }
 532         | lilypond_header_body assignment  {
 533
 534         }
 535         ;
 536
 537 lilypond_header:
 538         HEADER '{' lilypond_header_body '}'     {
 539                 $$ = PARSER->lexer_->remove_scope ();
 540         }
 541         ;
 542
 543 /*
 544         DECLARATIONS
 545 */
 546 assignment_id:
 547         STRING          { $$ = $1; }
 548         | LYRICS_STRING { $$ = $1; }
 549         ;
 550
 551 assignment:
 552         assignment_id '=' identifier_init  {
 553                 PARSER->lexer_->set_identifier ($1, $3);
 554         }
 555         | assignment_id property_path '=' identifier_init {
 556                 SCM path = scm_cons (scm_string_to_symbol ($1), $2);
 557                 PARSER->lexer_->set_identifier (path, $4);
 558         ;
 559 /*
 560  TODO: devise standard for protection in parser.
 561
 562   The parser stack lives on the C-stack, which means that
 563 all objects can be unprotected as soon as they're here.
 564
 565 */
 566         }
 567         | embedded_scm { }
 568         ;
 569
 570
 571 identifier_init:
 572         score_block {
 573                 $$ = $1->self_scm ();
 574                 $1->unprotect ();
 575         }
 576         | book_block {
 577                 $$ = $1->self_scm ();
 578                 $1->unprotect ();
 579         }
 580         | bookpart_block {
 581                 $$ = $1->self_scm ();
 582                 $1->unprotect ();
 583         }
 584         | output_def {
 585                 $$ = $1->self_scm ();
 586                 $1->unprotect ();
 587         }
 588         | context_def_spec_block {
 589                 $$ = $1;
 590         }
 591         | music  {
 592                 /* Hack: Create event-chord around standalone events.
 593                    Prevents the identifier from being interpreted as a post-event. */
 594                 Music *mus = unsmob_music ($1);
 595                 bool is_event = mus &&
 596                         (scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
 597                                 != SCM_BOOL_F);
 598                 if (!is_event)
 599                         $$ = $1;
 600                 else
 601                         $$ = MAKE_SYNTAX ("event-chord", @$, scm_list_1 ($1));
 602         }
 603         | post_event {
 604                 $$ = $1;
 605         }
 606         | number_expression {
 607                 $$ = $1;
 608         }
 609         | string {
 610                 $$ = $1;
 611         }
 612         | embedded_scm {
 613                 $$ = $1;
 614         }
 615         | full_markup {
 616                 $$ = $1;
 617         }
 618         | DIGIT {
 619                 $$ = scm_from_int ($1);
 620         }
 621         | context_modification {
 622                 $$ = $1;
 623         }
 624         ;
 625
 626 context_def_spec_block:
 627         CONTEXT '{' context_def_spec_body '}'
 628                 {
 629                 $$ = $3;
 630         }
 631         ;
 632
 633 context_def_spec_body:
 634         /**/ {
 635                 $$ = Context_def::make_scm ();
 636                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 637         }
 638         | CONTEXT_DEF_IDENTIFIER {
 639                 $$ = $1;
 640                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 641         }
 642         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 643                 Context_def*td = unsmob_context_def ($$);
 644
 645                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 646                         SCM tag = scm_caar (p);
 647
 648                         /* TODO: should make new tag "grob-definition" ? */
 649                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 650                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 651                 }
 652         }
 653         | context_def_spec_body context_mod {
 654                 unsmob_context_def ($$)->add_context_mod ($2);
 655         }
 656         | context_def_spec_body context_modification {
 657                 Context_def *td = unsmob_context_def ($$);
 658                 SCM new_mods = unsmob_context_mod ($2)->get_mods ();
 659                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 660                     td->add_context_mod (scm_car (m));
 661                 }
 662         }
 663         ;
 664
 665
 666
 667 book_block:
 668         BOOK '{' book_body '}'  {
 669                 $$ = $3;
 670                 pop_paper (PARSER);
 671                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 672         }
 673         ;
 674
 675 /* FIXME:
 676    * Use 'handlers' like for toplevel-* stuff?
 677    * grok \layout and \midi?  */
 678 book_body:
 679         {
 680                 $$ = new Book;
 681                 init_papers (PARSER);
 682                 $$->origin ()->set_spot (@$);
 683                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (PARSER->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 684                 $$->paper_->unprotect ();
 685                 push_paper (PARSER, $$->paper_);
 686                 $$->header_ = PARSER->lexer_->lookup_identifier ("$defaultheader");
 687                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$->self_scm ());
 688                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-output-suffix"), SCM_BOOL_F);
 689                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-filename"), SCM_BOOL_F);
 690         }
 691         | BOOK_IDENTIFIER {
 692                 $$ = unsmob_book ($1);
 693                 $$->protect ();
 694                 $$->origin ()->set_spot (@$);
 695                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 696         }
 697         | book_body paper_block {
 698                 $$->paper_ = $2;
 699                 $2->unprotect ();
 700                 set_paper (PARSER, $2);
 701         }
 702         | book_body bookpart_block {
 703                 Book *bookpart = $2;
 704                 SCM proc = PARSER->lexer_->lookup_identifier ("book-bookpart-handler");
 705                 scm_call_2 (proc, $$->self_scm (), bookpart->self_scm ());
 706                 bookpart->unprotect ();
 707         }
 708         | book_body score_block {
 709                 Score *score = $2;
 710                 SCM proc = PARSER->lexer_->lookup_identifier ("book-score-handler");
 711                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 712                 score->unprotect ();
 713         }
 714         | book_body composite_music {
 715                 Music *music = unsmob_music ($2);
 716                 SCM proc = PARSER->lexer_->lookup_identifier ("book-music-handler");
 717                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 718         }
 719         | book_body full_markup {
 720                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 721                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 722         }
 723         | book_body full_markup_list {
 724                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 725                 scm_call_2 (proc, $$->self_scm (), $2);
 726         }
 727         | book_body lilypond_header {
 728                 $$->header_ = $2;
 729         }
 730         | book_body error {
 731                 $$->paper_ = 0;
 732                 $$->scores_ = SCM_EOL;
 733                 $$->bookparts_ = SCM_EOL;
 734         }
 735         ;
 736
 737 bookpart_block:
 738         BOOKPART '{' bookpart_body '}' {
 739                 $$ = $3;
 740                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 741         }
 742         ;
 743
 744 bookpart_body:
 745         {
 746                 $$ = new Book;
 747                 $$->origin ()->set_spot (@$);
 748                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$->self_scm ());
 749         }
 750         | BOOK_IDENTIFIER {
 751                 $$ = unsmob_book ($1);
 752                 $$->protect ();
 753                 $$->origin ()->set_spot (@$);
 754                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 755         }
 756         | bookpart_body paper_block {
 757                 $$->paper_ = $2;
 758                 $2->unprotect ();
 759         }
 760         | bookpart_body score_block {
 761                 Score *score = $2;
 762                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-score-handler");
 763                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 764                 score->unprotect ();
 765         }
 766         | bookpart_body composite_music {
 767                 Music *music = unsmob_music ($2);
 768                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-music-handler");
 769                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 770         }
 771         | bookpart_body full_markup {
 772                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 773                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 774         }
 775         | bookpart_body full_markup_list {
 776                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 777                 scm_call_2 (proc, $$->self_scm (), $2);
 778         }
 779         | bookpart_body lilypond_header {
 780                 $$->header_ = $2;
 781         }
 782         | bookpart_body error {
 783                 $$->paper_ = 0;
 784                 $$->scores_ = SCM_EOL;
 785         }
 786         ;
 787
 788 score_block:
 789         SCORE '{' score_body '}'        {
 790                 $$ = $3;
 791         }
 792         ;
 793
 794 score_body:
 795         music {
 796                 SCM m = $1;
 797                 SCM scorify = ly_lily_module_constant ("scorify-music");
 798                 SCM score = scm_call_2 (scorify, m, PARSER->self_scm ());
 799
 800                 // pass ownernship to C++ again.
 801                 $$ = unsmob_score (score);
 802                 $$->protect ();
 803                 $$->origin ()->set_spot (@$);
 804         }
 805         | SCORE_IDENTIFIER {
 806                 $$ = unsmob_score ($1);
 807                 $$->protect ();
 808                 $$->origin ()->set_spot (@$);
 809         }
 810         | score_body lilypond_header    {
 811                 $$->set_header ($2);
 812         }
 813         | score_body output_def {
 814                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 815                 {
 816                         PARSER->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 817
 818                 }
 819                 else
 820                 {
 821                         $$->add_output_def ($2);
 822                 }
 823                 $2->unprotect ();
 824         }
 825         | score_body error {
 826                 $$->error_found_ = true;
 827         }
 828         ;
 829
 830
 831 /*
 832         OUTPUT DEF
 833 */
 834
 835 paper_block:
 836         output_def {
 837                 $$ = $1;
 838                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 839                 {
 840                         PARSER->parser_error (@1, _ ("need \\paper for paper block"));
 841                         $1->unprotect ();
 842                         $$ = get_paper (PARSER);
 843                 }
 844         }
 845         ;
 846
 847
 848 output_def:
 849         output_def_body '}' {
 850                 $$ = $1;
 851
 852                 PARSER->lexer_->remove_scope ();
 853                 PARSER->lexer_->pop_state ();
 854         }
 855         ;
 856
 857 output_def_head:
 858         PAPER {
 859                 $$ = get_paper (PARSER);
 860                 $$->input_origin_ = @$;
 861                 PARSER->lexer_->add_scope ($$->scope_);
 862         }
 863         | MIDI    {
 864                 Output_def *p = get_midi (PARSER);
 865                 $$ = p;
 866                 PARSER->lexer_->add_scope (p->scope_);
 867         }
 868         | LAYOUT        {
 869                 Output_def *p = get_layout (PARSER);
 870
 871                 PARSER->lexer_->add_scope (p->scope_);
 872                 $$ = p;
 873         }
 874         ;
 875
 876 output_def_head_with_mode_switch:
 877         output_def_head {
 878                 PARSER->lexer_->push_initial_state ();
 879                 $$ = $1;
 880         }
 881         ;
 882
 883 output_def_body:
 884         output_def_head_with_mode_switch '{' {
 885                 $$ = $1;
 886                 $$->input_origin_.set_spot (@$);
 887         }
 888         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 889                 $1->unprotect ();
 890
 891                 Output_def *o = unsmob_output_def ($3);
 892                 o->input_origin_.set_spot (@$);
 893                 $$ = o;
 894                 $$->protect ();
 895                 PARSER->lexer_->remove_scope ();
 896                 PARSER->lexer_->add_scope (o->scope_);
 897         }
 898         | output_def_body assignment  {
 899
 900         }
 901         | output_def_body context_def_spec_block        {
 902                 assign_context_def ($$, $2);
 903         }
 904         | output_def_body error {
 905
 906         }
 907         ;
 908
 909 tempo_event:
 910         TEMPO steno_duration '=' tempo_range    {
 911                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_BOOL_F, $2, $4);
 912         }
 913         | TEMPO string steno_duration '=' tempo_range   {
 914                 $$ = MAKE_SYNTAX ("tempo", @$, make_simple_markup($2), $3, $5);
 915         }
 916         | TEMPO full_markup steno_duration '=' tempo_range      {
 917                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, $5);
 918         }
 919         | TEMPO string {
 920                 $$ = MAKE_SYNTAX ("tempoText", @$, make_simple_markup($2) );
 921         }
 922         | TEMPO full_markup {
 923                 $$ = MAKE_SYNTAX ("tempoText", @$, $2 );
 924         }
 925         ;
 926
 927 /*
 928 The representation of a  list is the
 929
 930   (LIST . LAST-CONS)
 931
 932  to have efficient append.  */
 933
 934 music_list:
 935         /* empty */ {
 936                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 937         }
 938         | music_list music {
 939                 SCM s = $$;
 940                 SCM c = scm_cons ($2, SCM_EOL);
 941
 942                 if (scm_is_pair (scm_cdr (s)))
 943                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 944                 else
 945                         scm_set_car_x (s, c); /* set first cons */
 946                 scm_set_cdr_x (s, c);  /* remember last cell */
 947         }
 948         | music_list embedded_scm {
 949
 950         }
 951         | music_list error {
 952                 Music *m = MY_MAKE_MUSIC("Music", @$);
 953                 // ugh. code dup
 954                 m->set_property ("error-found", SCM_BOOL_T);
 955                 SCM s = $$;
 956                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 957                 m->unprotect (); /* UGH */
 958
 959                 if (scm_is_pair (scm_cdr (s)))
 960                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 961                 else
 962                         scm_set_car_x (s, c); /* set first cons */
 963                 scm_set_cdr_x (s, c);  /* remember last cell */
 964         }
 965         ;
 966
 967 music:
 968         simple_music
 969         | composite_music
 970         ;
 971
 972 alternative_music:
 973         /* empty */ {
 974                 $$ = SCM_EOL;
 975         }
 976         | ALTERNATIVE '{' music_list '}' {
 977                 $$ = scm_car ($3);
 978         }
 979         ;
 980
 981
 982 repeated_music:
 983         REPEAT simple_string unsigned_number music alternative_music
 984         {
 985                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $5);
 986         }
 987         ;
 988
 989 sequential_music:
 990         SEQUENTIAL '{' music_list '}'           {
 991                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($3));
 992         }
 993         | '{' music_list '}'            {
 994                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($2));
 995         }
 996         ;
 997
 998 simultaneous_music:
 999         SIMULTANEOUS '{' music_list '}'{
1000                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($3));
1001         }
1002         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1003                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($2));
1004         }
1005         ;
1006
1007 simple_music:
1008         event_chord
1009         | MUSIC_IDENTIFIER
1010         | music_property_def
1011         | context_change
1012         ;
1013
1014 context_modification:
1015         WITH { PARSER->lexer_->push_initial_state (); } '{' context_mod_list '}'
1016         {
1017                 PARSER->lexer_->pop_state ();
1018                 $$ = $4;
1019         }
1020         | WITH CONTEXT_MOD_IDENTIFIER
1021         {
1022                 $$ = $2;
1023         }
1024         | CONTEXT_MOD_IDENTIFIER
1025         {
1026                 $$ = $1;
1027         }
1028         ;
1029
1030 optional_context_mod:
1031         /**/ {
1032             $$ = SCM_EOL;
1033         }
1034         | context_modification
1035         {
1036               $$ = $1;
1037         }
1038         ;
1039
1040 context_mod_list:
1041         /**/ {
1042             $$ = Context_mod ().smobbed_copy ();
1043         }
1044         | context_mod_list context_mod  {
1045                  unsmob_context_mod ($1)->add_context_mod ($2);
1046         }
1047         | context_mod_list CONTEXT_MOD_IDENTIFIER {
1048                  Context_mod *md = unsmob_context_mod ($2);
1049                  if (md)
1050                      unsmob_context_mod ($1)->add_context_mods (md->get_mods ());
1051         }
1052         ;
1053
1054 composite_music:
1055         prefix_composite_music { $$ = $1; }
1056         | grouped_music_list { $$ = $1; }
1057         ;
1058
1059 grouped_music_list:
1060         simultaneous_music              { $$ = $1; }
1061         | sequential_music              { $$ = $1; }
1062         ;
1063
1064 function_scm_argument:
1065         embedded_scm
1066         | simple_string
1067         ;
1068
1069 /* An argument list. If a function \foo expects scm scm music, then the lexer expands \foo into the token sequence:
1070  MUSIC_FUNCTION EXPECT_MUSIC EXPECT_SCM EXPECT_SCM EXPECT_NO_MORE_ARGS
1071 and this rule returns the reversed list of arguments. */
1072
1073 function_arglist_music_last:
1074         EXPECT_MUSIC function_arglist music {
1075                 $$ = scm_cons ($3, $2);
1076         }
1077         ;
1078
1079 function_arglist_nonmusic_last:
1080         EXPECT_MARKUP function_arglist full_markup {
1081                 $$ = scm_cons ($3, $2);
1082         }
1083         | EXPECT_MARKUP function_arglist simple_string {
1084                 $$ = scm_cons ($3, $2);
1085         }
1086         | EXPECT_SCM function_arglist function_scm_argument {
1087                 $$ = scm_cons ($3, $2);
1088         }
1089         ;
1090
1091 function_arglist_nonmusic: EXPECT_NO_MORE_ARGS {
1092                 $$ = SCM_EOL;
1093         }
1094         | EXPECT_MARKUP function_arglist_nonmusic full_markup {
1095                 $$ = scm_cons ($3, $2);
1096         }
1097         | EXPECT_MARKUP function_arglist_nonmusic simple_string {
1098                 $$ = scm_cons ($3, $2);
1099         }
1100         | EXPECT_SCM function_arglist_nonmusic function_scm_argument {
1101                 $$ = scm_cons ($3, $2);
1102         }
1103         ;
1104
1105 function_arglist: EXPECT_NO_MORE_ARGS {
1106                 /* This is for 0-ary functions, so they don't need to
1107                    read a lookahead token */
1108                 $$ = SCM_EOL;
1109         }
1110         | function_arglist_music_last
1111         | function_arglist_nonmusic_last
1112         ;
1113
1114 generic_prefix_music_scm:
1115         MUSIC_FUNCTION function_arglist {
1116                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
1117         }
1118         ;
1119
1120
1121 optional_id:
1122         /**/ { $$ = SCM_EOL; }
1123         | '=' simple_string {
1124                 $$ = $2;
1125         }
1126         ;
1127
1128
1129 prefix_composite_music:
1130         generic_prefix_music_scm {
1131                 $$ = run_music_function (PARSER, $1);
1132         }
1133         | CONTEXT simple_string optional_id optional_context_mod music {
1134                 Context_mod *ctxmod = unsmob_context_mod ($4);
1135                 SCM mods = SCM_EOL;
1136                 if (ctxmod)
1137                         mods = ctxmod->get_mods ();
1138                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, mods, SCM_BOOL_F);
1139         }
1140         | NEWCONTEXT simple_string optional_id optional_context_mod music {
1141                 Context_mod *ctxmod = unsmob_context_mod ($4);
1142                 SCM mods = SCM_EOL;
1143                 if (ctxmod)
1144                         mods = ctxmod->get_mods ();
1145                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, mods, SCM_BOOL_T);
1146         }
1147
1148         | TIMES fraction music {
1149                 $$ = MAKE_SYNTAX ("time-scaled-music", @$, $2, $3);
1150         }
1151         | repeated_music                { $$ = $1; }
1152         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords music {
1153                 Pitch from = *unsmob_pitch ($2);
1154                 Pitch to = *unsmob_pitch ($3);
1155                 SCM pitch = pitch_interval (from, to).smobbed_copy ();
1156                 $$ = MAKE_SYNTAX ("transpose-music", @$, pitch, $4);
1157         }
1158         | mode_changing_head grouped_music_list {
1159                 if ($1 == ly_symbol2scm ("chords"))
1160                 {
1161                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
1162                 }
1163                 else
1164                 {
1165                   $$ = $2;
1166                 }
1167                 PARSER->lexer_->pop_state ();
1168         }
1169         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1170                 Context_mod *ctxmod = unsmob_context_mod ($2);
1171                 SCM mods = SCM_EOL;
1172                 if (ctxmod)
1173                         mods = ctxmod->get_mods ();
1174                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, $3, mods, SCM_BOOL_T);
1175                 if ($1 == ly_symbol2scm ("ChordNames"))
1176                 {
1177                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1178                 }
1179                 PARSER->lexer_->pop_state ();
1180         }
1181         | relative_music        { $$ = $1; }
1182         | re_rhythmed_music     { $$ = $1; }
1183         ;
1184
1185 mode_changing_head:
1186         NOTEMODE {
1187                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1188                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1189
1190                 $$ = ly_symbol2scm ("notes");
1191         }
1192         | DRUMMODE
1193                 {
1194                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1195                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1196
1197                 $$ = ly_symbol2scm ("drums");
1198         }
1199         | FIGUREMODE {
1200                 PARSER->lexer_->push_figuredbass_state ();
1201
1202                 $$ = ly_symbol2scm ("figures");
1203         }
1204         | CHORDMODE {
1205                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1206                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1207                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1208                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1209                 $$ = ly_symbol2scm ("chords");
1210
1211         }
1212         | LYRICMODE
1213                 { PARSER->lexer_->push_lyric_state ();
1214                 $$ = ly_symbol2scm ("lyrics");
1215         }
1216         ;
1217
1218 mode_changing_head_with_context:
1219         DRUMS {
1220                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1221                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1222
1223                 $$ = ly_symbol2scm ("DrumStaff");
1224         }
1225         | FIGURES {
1226                 PARSER->lexer_->push_figuredbass_state ();
1227
1228                 $$ = ly_symbol2scm ("FiguredBass");
1229         }
1230         | CHORDS {
1231                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1232                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1233                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1234                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1235                 $$ = ly_symbol2scm ("ChordNames");
1236         }
1237         | LYRICS
1238                 { PARSER->lexer_->push_lyric_state ();
1239                 $$ = ly_symbol2scm ("Lyrics");
1240         }
1241         ;
1242
1243
1244 relative_music:
1245         RELATIVE absolute_pitch music {
1246                 Pitch start = *unsmob_pitch ($2);
1247                 $$ = make_music_relative (start, $3, @$);
1248         }
1249         | RELATIVE composite_music {
1250                 Pitch middle_c (0, 0, 0);
1251                 $$ = make_music_relative (middle_c, $2, @$);
1252         }
1253         ;
1254
1255 new_lyrics:
1256         ADDLYRICS { PARSER->lexer_->push_lyric_state (); }
1257         /*cont */
1258         grouped_music_list {
1259         /* Can also use music at the expensive of two S/Rs similar to
1260            \repeat \alternative */
1261                 PARSER->lexer_->pop_state ();
1262
1263                 $$ = scm_cons ($3, SCM_EOL);
1264         }
1265         | ADDLYRICS {
1266                 PARSER->lexer_->push_lyric_state (); }
1267         MUSIC_IDENTIFIER {
1268                 PARSER->lexer_->pop_state ();
1269                 $$ = scm_cons ($3, SCM_EOL);
1270         }
1271         | new_lyrics ADDLYRICS {
1272                 PARSER->lexer_->push_lyric_state ();
1273         } grouped_music_list {
1274                 PARSER->lexer_->pop_state ();
1275                 $$ = scm_cons ($4, $1);
1276         }
1277         | new_lyrics ADDLYRICS {
1278                 PARSER->lexer_->push_lyric_state ();
1279         } MUSIC_IDENTIFIER {
1280                 PARSER->lexer_->pop_state ();
1281                 $$ = scm_cons ($4, $1);
1282         }
1283         ;
1284
1285 re_rhythmed_music:
1286         grouped_music_list new_lyrics {
1287                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1288         }
1289         | MUSIC_IDENTIFIER new_lyrics {
1290                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1291         }
1292         | LYRICSTO simple_string {
1293                 PARSER->lexer_->push_lyric_state ();
1294         } music {
1295                 PARSER->lexer_->pop_state ();
1296                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
1297         }
1298         ;
1299
1300 context_change:
1301         CHANGE STRING '=' STRING  {
1302                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
1303         }
1304         ;
1305
1306
1307 property_path_revved:
1308         embedded_scm {
1309                 $$ = scm_cons ($1, SCM_EOL);
1310         }
1311         | property_path_revved embedded_scm {
1312                 $$ = scm_cons ($2, $1);
1313         }
1314         ;
1315
1316 property_path:
1317         property_path_revved  {
1318                 $$ = scm_reverse_x ($1, SCM_EOL);
1319         }
1320         ;
1321
1322 property_operation:
1323         STRING '=' scalar {
1324                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1325                         scm_string_to_symbol ($1), $3);
1326         }
1327         | UNSET simple_string {
1328                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1329                         scm_string_to_symbol ($2));
1330         }
1331         | OVERRIDE simple_string property_path '=' scalar {
1332                 $$ = scm_append (scm_list_2 (scm_list_3 (ly_symbol2scm ("push"),
1333                                                         scm_string_to_symbol ($2), $5),
1334                                              $3));
1335         }
1336         | REVERT simple_string embedded_scm {
1337                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1338                         scm_string_to_symbol ($2), $3);
1339         }
1340         ;
1341
1342 context_def_mod:
1343         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1344         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1345
1346         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1347         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1348         | DENIES { $$ = ly_symbol2scm ("denies"); }
1349
1350         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1351         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1352         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1353         | NAME { $$ = ly_symbol2scm ("context-name"); }
1354         ;
1355
1356 context_mod:
1357         property_operation { $$ = $1; }
1358         | context_def_mod STRING {
1359                 $$ = scm_list_2 ($1, $2);
1360         }
1361         | context_def_mod embedded_scm {
1362            if (ly_symbol2scm ("consists") != $1)
1363            {
1364              $$ = SCM_EOL;
1365              PARSER->parser_error (@1, _ ("only \\consists takes non-string argument."));
1366            }
1367            else
1368            {
1369              $$ = scm_list_2 ($1, $2);
1370            }
1371         }
1372         ;
1373
1374 context_prop_spec:
1375         simple_string {
1376                 if (!is_regular_identifier ($1))
1377                 {
1378                         @$.error (_("Grob name should be alphanumeric"));
1379                 }
1380
1381                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1382                         scm_string_to_symbol ($1));
1383         }
1384         | simple_string '.' simple_string {
1385                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1386                         scm_string_to_symbol ($3));
1387         }
1388         ;
1389
1390 simple_music_property_def:
1391         OVERRIDE context_prop_spec property_path '=' scalar {
1392                 $$ = scm_append (scm_list_2 (scm_list_n (scm_car ($2),
1393                                 ly_symbol2scm ("OverrideProperty"),
1394                                 scm_cadr ($2),
1395                                 $5, SCM_UNDEFINED),
1396                                 $3));
1397         }
1398         | REVERT context_prop_spec embedded_scm {
1399                 $$ = scm_list_4 (scm_car ($2),
1400                         ly_symbol2scm ("RevertProperty"),
1401                         scm_cadr ($2),
1402                         $3);
1403         }
1404         | SET context_prop_spec '=' scalar {
1405                 $$ = scm_list_4 (scm_car ($2),
1406                         ly_symbol2scm ("PropertySet"),
1407                         scm_cadr ($2),
1408                         $4);
1409         }
1410         | UNSET context_prop_spec {
1411                 $$ = scm_list_3 (scm_car ($2),
1412                         ly_symbol2scm ("PropertyUnset"),
1413                         scm_cadr ($2));
1414         }
1415         ;
1416
1417 music_property_def:
1418         simple_music_property_def {
1419                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_F, $1)));
1420         }
1421         | ONCE simple_music_property_def {
1422                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_T, $2)));
1423         }
1424         ;
1425
1426 string:
1427         STRING {
1428                 $$ = $1;
1429         }
1430         | STRING_IDENTIFIER {
1431                 $$ = $1;
1432         }
1433         | string '+' string {
1434                 $$ = scm_string_append (scm_list_2 ($1, $3));
1435         }
1436         ;
1437
1438 simple_string: STRING {
1439                 $$ = $1;
1440         }
1441         | LYRICS_STRING {
1442                 $$ = $1;
1443         }
1444         | STRING_IDENTIFIER {
1445                 $$ = $1;
1446         }
1447         ;
1448
1449 scalar: string {
1450                 $$ = $1;
1451         }
1452         | LYRICS_STRING {
1453                 $$ = $1;
1454         }
1455         | bare_number {
1456                 $$ = $1;
1457         }
1458         | embedded_scm {
1459                 $$ = $1;
1460         }
1461         | full_markup {
1462                 $$ = $1;
1463         }
1464         | DIGIT {
1465                 $$ = scm_from_int ($1);
1466         }
1467         ;
1468
1469 event_chord:
1470         /* TODO: Create a special case that avoids the creation of
1471            EventChords around simple_elements that have no post_events?
1472          */
1473         simple_chord_elements post_events       {
1474                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
1475
1476                 Input i;
1477                 /* why is this giving wrong start location? -ns
1478                  * i = @$; */
1479                 i.set_location (@1, @2);
1480                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
1481         }
1482         | CHORD_REPETITION optional_notemode_duration post_events {
1483                 Input i;
1484                 i.set_location (@1, @3);
1485                 $$ = MAKE_SYNTAX ("repetition-chord", i,
1486                                   PARSER->lexer_->chord_repetition_.last_chord_,
1487                                   PARSER->lexer_->chord_repetition_.repetition_function_,
1488                                   $2, scm_reverse_x ($3, SCM_EOL));
1489         }
1490         | MULTI_MEASURE_REST optional_notemode_duration post_events {
1491                 Input i;
1492                 i.set_location (@1, @3);
1493                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2,
1494                                   scm_reverse_x ($3, SCM_EOL));
1495         }
1496         | command_element
1497         /* note chord elements are memorized into
1498            PARSER->lexer_->chord_repetition_ so that the chord repetition
1499            mechanism copy them when a chord repetition symbol is found
1500         */
1501         | note_chord_element    {
1502                 PARSER->lexer_->chord_repetition_.last_chord_ = $$;
1503         }
1504         ;
1505
1506
1507 note_chord_element:
1508         chord_body optional_notemode_duration post_events
1509         {
1510                 Music *m = unsmob_music ($1);
1511                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1512                 SCM es = m->get_property ("elements");
1513                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1514
1515                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1516                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1517                 es = ly_append2 (es, postevs);
1518
1519                 m-> set_property ("elements", es);
1520                 m->set_spot (@$);
1521                 $$ = m->self_scm ();
1522         }
1523         ;
1524
1525 chord_body:
1526         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
1527         {
1528                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
1529         }
1530         ;
1531
1532 chord_body_elements:
1533         /* empty */             { $$ = SCM_EOL; }
1534         | chord_body_elements chord_body_element {
1535                 $$ = scm_cons ($2, $1);
1536         }
1537         ;
1538
1539 chord_body_element:
1540         pitch exclamations questions octave_check post_events
1541         {
1542                 int q = $3;
1543                 int ex = $2;
1544                 SCM check = $4;
1545                 SCM post = $5;
1546
1547                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1548                 n->set_property ("pitch", $1);
1549                 if (q % 2)
1550                         n->set_property ("cautionary", SCM_BOOL_T);
1551                 if (ex % 2 || q % 2)
1552                         n->set_property ("force-accidental", SCM_BOOL_T);
1553
1554                 if (scm_is_pair (post)) {
1555                         SCM arts = scm_reverse_x (post, SCM_EOL);
1556                         n->set_property ("articulations", arts);
1557                 }
1558                 if (scm_is_number (check))
1559                 {
1560                         int q = scm_to_int (check);
1561                         n->set_property ("absolute-octave", scm_from_int (q-1));
1562                 }
1563
1564                 $$ = n->unprotect ();
1565         }
1566         | DRUM_PITCH post_events {
1567                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1568                 n->set_property ("duration", $2);
1569                 n->set_property ("drum-type", $1);
1570
1571                 if (scm_is_pair ($2)) {
1572                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1573                         n->set_property ("articulations", arts);
1574                 }
1575                 $$ = n->unprotect ();
1576         }
1577         | music_function_chord_body {
1578                 $$ = run_music_function (PARSER, $1);
1579         }
1580         ;
1581
1582 music_function_identifier_musicless_prefix: MUSIC_FUNCTION {
1583                 SCM sig = scm_object_property (yylval.scm, ly_symbol2scm ("music-function-signature"));
1584                 if (scm_is_pair (sig) && to_boolean (scm_memq (ly_music_p_proc, scm_cdr (scm_reverse (sig)))))
1585                 {
1586                         PARSER->parser_error (@$, "Music function applied to event may not have a Music argument, except as the last argument.");
1587                 }
1588         }
1589         ;
1590
1591 music_function_chord_body:
1592         /* We could allow chord functions to have multiple music arguments,
1593            but it's more consistent with music_function_event if we
1594            prohibit it here too */
1595         music_function_identifier_musicless_prefix EXPECT_MUSIC function_arglist_nonmusic chord_body_element {
1596                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($3, scm_list_1 ($4)));
1597         }
1598         | music_function_identifier_musicless_prefix function_arglist_nonmusic {
1599                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
1600         }
1601         ;
1602
1603 music_function_event:
1604         /* Post-events can only have the last argument as music, without this
1605            restriction we get a shift/reduce conflict from e.g.
1606            c8-\partcombine c8 -. */
1607         music_function_identifier_musicless_prefix EXPECT_MUSIC function_arglist_nonmusic post_event {
1608                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($3, scm_list_1 ($4)));
1609         }
1610         | music_function_identifier_musicless_prefix function_arglist_nonmusic {
1611                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
1612         }
1613         ;
1614
1615 command_element:
1616         command_event {
1617                 $$ = $1;
1618         }
1619         | SKIP duration_length {
1620                 $$ = MAKE_SYNTAX ("skip-music", @$, $2);
1621         }
1622         | E_BRACKET_OPEN {
1623                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1624                 m->set_property ("span-direction", scm_from_int (START));
1625                 $$ = m->unprotect();
1626         }
1627         | E_BRACKET_CLOSE {
1628                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1629                 m->set_property ("span-direction", scm_from_int (STOP));
1630                 $$ = m->unprotect ();
1631         }
1632         | E_BACKSLASH {
1633                 $$ = MAKE_SYNTAX ("voice-separator", @$, SCM_UNDEFINED);
1634         }
1635         | '|'      {
1636                 SCM pipe = PARSER->lexer_->lookup_identifier ("pipeSymbol");
1637
1638                 Music *m = unsmob_music (pipe);
1639                 if (m)
1640                 {
1641                         m = m->clone ();
1642                         m->set_spot (@$);
1643                         $$ = m->unprotect ();
1644                 }
1645                 else
1646                         $$ = MAKE_SYNTAX ("bar-check", @$, SCM_UNDEFINED);
1647
1648         }
1649         | PARTIAL duration_length       {
1650                 $$ = MAKE_SYNTAX ("partial", @$, $2);
1651         }
1652
1653         | TIME_T fraction  {
1654                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1655
1656                 $$ = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1657         }
1658         | MARK scalar {
1659                 $$ = MAKE_SYNTAX ("make-mark-set", @$, $2);
1660         }
1661         ;
1662
1663 command_event:
1664         E_TILDE {
1665                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent", @$)->unprotect ();
1666         }
1667         | MARK DEFAULT  {
1668                 Music *m = MY_MAKE_MUSIC ("MarkEvent", @$);
1669                 $$ = m->unprotect ();
1670         }
1671         | tempo_event {
1672                 $$ = $1;
1673         }
1674         | KEY DEFAULT {
1675                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1676                 $$ = key->unprotect ();
1677         }
1678         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1679
1680                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1681                 if (scm_ilength ($3) > 0)
1682                 {
1683                         key->set_property ("pitch-alist", $3);
1684                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1685                         key->transpose (* unsmob_pitch ($2));
1686                 } else {
1687                         PARSER->parser_error (@3, _ ("second argument must be pitch list"));
1688                 }
1689
1690                 $$ = key->unprotect ();
1691         }
1692         ;
1693
1694
1695 post_events:
1696         /* empty */ {
1697                 $$ = SCM_EOL;
1698         }
1699         | post_events post_event {
1700                 unsmob_music ($2)->set_spot (@2);
1701                 $$ = scm_cons ($2, $$);
1702         }
1703         ;
1704
1705 post_event:
1706         direction_less_event {
1707                 $$ = $1;
1708         }
1709         | '-' music_function_event {
1710                 $$ = run_music_function (PARSER, $2);
1711         }
1712         | HYPHEN {
1713                 if (!PARSER->lexer_->is_lyric_state ())
1714                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1715                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
1716         }
1717         | EXTENDER {
1718                 if (!PARSER->lexer_->is_lyric_state ())
1719                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1720                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
1721         }
1722         | script_dir direction_reqd_event {
1723                 if ($1)
1724                 {
1725                         Music *m = unsmob_music ($2);
1726                         m->set_property ("direction", scm_from_int ($1));
1727                 }
1728                 $$ = $2;
1729         }
1730         | script_dir direction_less_event {
1731                 if ($1)
1732                 {
1733                         Music *m = unsmob_music ($2);
1734                         m->set_property ("direction", scm_from_int ($1));
1735                 }
1736                 $$ = $2;
1737         }
1738         | string_number_event
1739         ;
1740
1741 string_number_event:
1742         E_UNSIGNED {
1743                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
1744                 s->set_property ("string-number", scm_from_int ($1));
1745                 $$ = s->unprotect ();
1746         }
1747         ;
1748
1749 direction_less_char:
1750         '['  {
1751                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1752         }
1753         | ']'  {
1754                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1755         }
1756         | '~'  {
1757                 $$ = ly_symbol2scm ("tildeSymbol");
1758         }
1759         | '('  {
1760                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1761         }
1762         | ')'  {
1763                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1764         }
1765         | E_EXCLAMATION  {
1766                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1767         }
1768         | E_OPEN  {
1769                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1770         }
1771         | E_CLOSE  {
1772                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1773         }
1774         | E_ANGLE_CLOSE  {
1775                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1776         }
1777         | E_ANGLE_OPEN  {
1778                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1779         }
1780         ;
1781
1782 direction_less_event:
1783         direction_less_char {
1784                 SCM predefd = PARSER->lexer_->lookup_identifier_symbol ($1);
1785                 Music *m = 0;
1786                 if (unsmob_music (predefd))
1787                 {
1788                         m = unsmob_music (predefd)->clone ();
1789                         m->set_spot (@$);
1790                 }
1791                 else
1792                 {
1793                         m = MY_MAKE_MUSIC ("Music", @$);
1794                 }
1795                 $$ = m->unprotect ();
1796         }
1797         | EVENT_IDENTIFIER      {
1798                 $$ = $1;
1799         }
1800         | tremolo_type  {
1801                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
1802                a->set_property ("tremolo-type", scm_from_int ($1));
1803                $$ = a->unprotect ();
1804         }
1805         ;
1806
1807 direction_reqd_event:
1808         gen_text_def {
1809                 $$ = $1;
1810         }
1811         | script_abbreviation {
1812                 SCM s = PARSER->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1813                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
1814                 if (scm_is_string (s))
1815                         a->set_property ("articulation-type", s);
1816                 else PARSER->parser_error (@1, _ ("expecting string as script definition"));
1817                 $$ = a->unprotect ();
1818         }
1819         ;
1820
1821 octave_check:
1822         /**/ { $$ = SCM_EOL; }
1823         | '='  { $$ = scm_from_int (0); }
1824         | '=' sub_quotes { $$ = scm_from_int (-$2); }
1825         | '=' sup_quotes { $$ = scm_from_int ($2); }
1826         ;
1827
1828 sup_quotes:
1829         '\'' {
1830                 $$ = 1;
1831         }
1832         | sup_quotes '\'' {
1833                 $$ ++;
1834         }
1835         ;
1836
1837 sub_quotes:
1838         ',' {
1839                 $$ = 1;
1840         }
1841         | sub_quotes ',' {
1842                 $$++;
1843         }
1844         ;
1845
1846 steno_pitch:
1847         NOTENAME_PITCH  {
1848                 $$ = $1;
1849         }
1850         | NOTENAME_PITCH sup_quotes     {
1851                 Pitch p = *unsmob_pitch ($1);
1852                 p = p.transposed (Pitch ($2,0,0));
1853                 $$ = p.smobbed_copy ();
1854         }
1855         | NOTENAME_PITCH sub_quotes      {
1856                 Pitch p =* unsmob_pitch ($1);
1857                 p = p.transposed (Pitch (-$2,0,0));
1858                 $$ = p.smobbed_copy ();
1859         }
1860         ;
1861
1862 /*
1863 ugh. duplication
1864 */
1865
1866 steno_tonic_pitch:
1867         TONICNAME_PITCH {
1868                 $$ = $1;
1869         }
1870         | TONICNAME_PITCH sup_quotes    {
1871                 Pitch p = *unsmob_pitch ($1);
1872                 p = p.transposed (Pitch ($2,0,0));
1873                 $$ = p.smobbed_copy ();
1874         }
1875         | TONICNAME_PITCH sub_quotes     {
1876                 Pitch p = *unsmob_pitch ($1);
1877
1878                 p = p.transposed (Pitch (-$2,0,0));
1879                 $$ = p.smobbed_copy ();
1880         }
1881         ;
1882
1883 pitch:
1884         steno_pitch {
1885                 $$ = $1;
1886         }
1887         ;
1888
1889 pitch_also_in_chords:
1890         pitch
1891         | steno_tonic_pitch
1892         ;
1893
1894 gen_text_def:
1895         full_markup {
1896                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
1897                 t->set_property ("text", $1);
1898                 $$ = t->unprotect ();
1899         }
1900         | string {
1901                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
1902                 t->set_property ("text",
1903                         make_simple_markup ($1));
1904                 $$ = t->unprotect ();
1905         }
1906         | DIGIT {
1907                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
1908                 t->set_property ("digit", scm_from_int ($1));
1909                 $$ = t->unprotect ();
1910         }
1911         ;
1912
1913 script_abbreviation:
1914         '^'             {
1915                 $$ = scm_from_locale_string ("Hat");
1916         }
1917         | '+'           {
1918                 $$ = scm_from_locale_string ("Plus");
1919         }
1920         | '-'           {
1921                 $$ = scm_from_locale_string ("Dash");
1922         }
1923         | '|'           {
1924                 $$ = scm_from_locale_string ("Bar");
1925         }
1926         | ANGLE_CLOSE   {
1927                 $$ = scm_from_locale_string ("Larger");
1928         }
1929         | '.'           {
1930                 $$ = scm_from_locale_string ("Dot");
1931         }
1932         | '_' {
1933                 $$ = scm_from_locale_string ("Underscore");
1934         }
1935         ;
1936
1937 script_dir:
1938         '_'     { $$ = DOWN; }
1939         | '^'   { $$ = UP; }
1940         | '-'   { $$ = CENTER; }
1941         ;
1942
1943
1944 absolute_pitch:
1945         steno_pitch     {
1946                 $$ = $1;
1947         }
1948         ;
1949
1950 duration_length:
1951         multiplied_duration {
1952                 $$ = $1;
1953         }
1954         ;
1955
1956 optional_notemode_duration:
1957         {
1958                 Duration dd = PARSER->default_duration_;
1959                 $$ = dd.smobbed_copy ();
1960         }
1961         | multiplied_duration   {
1962                 $$ = $1;
1963                 PARSER->default_duration_ = *unsmob_duration ($$);
1964         }
1965         ;
1966
1967 steno_duration:
1968         bare_unsigned dots              {
1969                 int len = 0;
1970                 if (!is_duration ($1))
1971                         PARSER->parser_error (@1, _f ("not a duration: %d", $1));
1972                 else
1973                         len = intlog2 ($1);
1974
1975                 $$ = Duration (len, $2).smobbed_copy ();
1976         }
1977         | DURATION_IDENTIFIER dots      {
1978                 Duration *d = unsmob_duration ($1);
1979                 Duration k (d->duration_log (), d->dot_count () + $2);
1980                 k = k.compressed (d->factor ());
1981                 *d = k;
1982                 $$ = $1;
1983         }
1984         ;
1985
1986 multiplied_duration:
1987         steno_duration {
1988                 $$ = $1;
1989         }
1990         | multiplied_duration '*' bare_unsigned {
1991                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1992         }
1993         | multiplied_duration '*' FRACTION {
1994                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
1995
1996                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1997         }
1998         ;
1999
2000 fraction:
2001         FRACTION { $$ = $1; }
2002         | UNSIGNED '/' UNSIGNED {
2003                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2004         }
2005         ;
2006
2007 dots:
2008         /* empty */     {
2009                 $$ = 0;
2010         }
2011         | dots '.' {
2012                 $$ ++;
2013         }
2014         ;
2015
2016 tremolo_type:
2017         ':'     {
2018                 $$ = 0;
2019         }
2020         | ':' bare_unsigned {
2021                 if (!is_duration ($2))
2022                         PARSER->parser_error (@2, _f ("not a duration: %d", $2));
2023                 $$ = $2;
2024         }
2025         ;
2026
2027 bass_number:
2028         DIGIT   {
2029                 $$ = scm_from_int ($1);
2030         }
2031         | UNSIGNED {
2032                 $$ = scm_from_int ($1);
2033         }
2034         | STRING { $$ = $1; }
2035         | full_markup { $$ = $1; }
2036         ;
2037
2038 figured_bass_alteration:
2039         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
2040         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
2041         | '!'   { $$ = scm_from_int (0); }
2042         ;
2043
2044 bass_figure:
2045         FIGURE_SPACE {
2046                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2047                 $$ = bfr->unprotect ();
2048         }
2049         | bass_number  {
2050                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2051                 $$ = bfr->self_scm ();
2052
2053                 if (scm_is_number ($1))
2054                         bfr->set_property ("figure", $1);
2055                 else if (Text_interface::is_markup ($1))
2056                         bfr->set_property ("text", $1);
2057
2058                 bfr->unprotect ();
2059         }
2060         | bass_figure ']' {
2061                 $$ = $1;
2062                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2063         }
2064         | bass_figure figured_bass_alteration {
2065                 Music *m = unsmob_music ($1);
2066                 if (scm_to_double ($2)) {
2067                         SCM salter = m->get_property ("alteration");
2068                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
2069                         m->set_property ("alteration",
2070                                          scm_sum (alter, $2));
2071                 } else {
2072                         m->set_property ("alteration", scm_from_int (0));
2073                 }
2074         }
2075         | bass_figure figured_bass_modification  {
2076                 Music *m = unsmob_music ($1);
2077                 if ($2 == ly_symbol2scm ("plus"))
2078                         {
2079                         m->set_property ("augmented", SCM_BOOL_T);
2080                         }
2081                 else if ($2 == ly_symbol2scm ("slash"))
2082                         {
2083                         m->set_property ("diminished", SCM_BOOL_T);
2084                         }
2085                 else if ($2 == ly_symbol2scm ("exclamation"))
2086                         {
2087                         m->set_property ("no-continuation", SCM_BOOL_T);
2088                         }
2089                 else if ($2 == ly_symbol2scm ("backslash"))
2090                         {
2091                         m->set_property ("augmented-slash", SCM_BOOL_T);
2092                         }
2093         }
2094         ;
2095
2096
2097 figured_bass_modification:
2098         E_PLUS          {
2099                 $$ = ly_symbol2scm ("plus");
2100         }
2101         | E_EXCLAMATION {
2102                 $$ = ly_symbol2scm ("exclamation");
2103         }
2104         | '/'           {
2105                 $$ = ly_symbol2scm ("slash");
2106         }
2107         | E_BACKSLASH {
2108                 $$ = ly_symbol2scm ("backslash");
2109         }
2110         ;
2111
2112 br_bass_figure:
2113         bass_figure {
2114                 $$ = $1;
2115         }
2116         | '[' bass_figure {
2117                 $$ = $2;
2118                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2119         }
2120         ;
2121
2122 figure_list:
2123         /**/            {
2124                 $$ = SCM_EOL;
2125         }
2126         | figure_list br_bass_figure {
2127                 $$ = scm_cons ($2, $1);
2128         }
2129         ;
2130
2131 figure_spec:
2132         FIGURE_OPEN figure_list FIGURE_CLOSE {
2133                 $$ = scm_reverse_x ($2, SCM_EOL);
2134         }
2135         ;
2136
2137
2138 optional_rest:
2139         /**/   { $$ = 0; }
2140         | REST { $$ = 1; }
2141         ;
2142
2143 simple_element:
2144         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2145                 if (!PARSER->lexer_->is_note_state ())
2146                         PARSER->parser_error (@1, _ ("have to be in Note mode for notes"));
2147
2148                 Music *n = 0;
2149                 if ($6)
2150                         n = MY_MAKE_MUSIC ("RestEvent", @$);
2151                 else
2152                         n = MY_MAKE_MUSIC ("NoteEvent", @$);
2153
2154                 n->set_property ("pitch", $1);
2155                 n->set_property ("duration", $5);
2156
2157                 if (scm_is_number ($4))
2158                 {
2159                         int q = scm_to_int ($4);
2160                         n->set_property ("absolute-octave", scm_from_int (q-1));
2161                 }
2162
2163                 if ($3 % 2)
2164                         n->set_property ("cautionary", SCM_BOOL_T);
2165                 if ($2 % 2 || $3 % 2)
2166                         n->set_property ("force-accidental", SCM_BOOL_T);
2167
2168                 $$ = n->unprotect ();
2169         }
2170         | DRUM_PITCH optional_notemode_duration {
2171                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2172                 n->set_property ("duration", $2);
2173                 n->set_property ("drum-type", $1);
2174
2175                 $$ = n->unprotect ();
2176         }
2177         | RESTNAME optional_notemode_duration           {
2178                 Music *ev = 0;
2179                 if (ly_scm2string ($1) == "s") {
2180                         /* Space */
2181                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
2182                   }
2183                 else {
2184                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
2185
2186                     }
2187                 ev->set_property ("duration", $2);
2188                 $$ = ev->unprotect ();
2189         }
2190         | lyric_element optional_notemode_duration      {
2191                 if (!PARSER->lexer_->is_lyric_state ())
2192                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2193
2194                 Music *levent = MY_MAKE_MUSIC ("LyricEvent", @$);
2195                 levent->set_property ("text", $1);
2196                 levent->set_property ("duration",$2);
2197                 $$= levent->unprotect ();
2198         }
2199         ;
2200
2201 simple_chord_elements:
2202         simple_element  {
2203                 $$ = scm_list_1 ($1);
2204         }
2205         | new_chord {
2206                 if (!PARSER->lexer_->is_chord_state ())
2207                         PARSER->parser_error (@1, _ ("have to be in Chord mode for chords"));
2208                 $$ = $1;
2209         }
2210         | figure_spec optional_notemode_duration {
2211                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
2212                 {
2213                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2214                 }
2215                 $$ = $1;
2216         }
2217         ;
2218
2219 lyric_element:
2220         lyric_markup {
2221                 $$ = $1;
2222         }
2223         | LYRICS_STRING {
2224                 $$ = $1;
2225         }
2226         ;
2227
2228 new_chord:
2229         steno_tonic_pitch optional_notemode_duration   {
2230                 $$ = make_chord_elements ($1, $2, SCM_EOL);
2231         }
2232         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2233                 SCM its = scm_reverse_x ($4, SCM_EOL);
2234                 $$ = make_chord_elements ($1, $2, scm_cons ($3, its));
2235         }
2236         ;
2237
2238 chord_items:
2239         /**/ {
2240                 $$ = SCM_EOL;
2241         }
2242         | chord_items chord_item {
2243                 $$ = scm_cons ($2, $$);
2244         }
2245         ;
2246
2247 chord_separator:
2248         CHORD_COLON {
2249                 $$ = ly_symbol2scm ("chord-colon");
2250         }
2251         | CHORD_CARET {
2252                 $$ = ly_symbol2scm ("chord-caret");
2253         }
2254         | CHORD_SLASH steno_tonic_pitch {
2255                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2256         }
2257         | CHORD_BASS steno_tonic_pitch {
2258                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2259         }
2260         ;
2261
2262 chord_item:
2263         chord_separator {
2264                 $$ = $1;
2265         }
2266         | step_numbers {
2267                 $$ = scm_reverse_x ($1, SCM_EOL);
2268         }
2269         | CHORD_MODIFIER  {
2270                 $$ = $1;
2271         }
2272         ;
2273
2274 step_numbers:
2275         step_number { $$ = scm_cons ($1, SCM_EOL); }
2276         | step_numbers '.' step_number {
2277                 $$ = scm_cons ($3, $$);
2278         }
2279         ;
2280
2281 step_number:
2282         bare_unsigned {
2283                 $$ = make_chord_step ($1, 0);
2284         }
2285         | bare_unsigned '+' {
2286                 $$ = make_chord_step ($1, SHARP_ALTERATION);
2287         }
2288         | bare_unsigned CHORD_MINUS {
2289                 $$ = make_chord_step ($1, FLAT_ALTERATION);
2290         }
2291         ;
2292
2293 tempo_range:
2294         bare_unsigned {
2295                 $$ = scm_from_int ($1);
2296         }
2297         | bare_unsigned '~' bare_unsigned {
2298                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2299         }
2300         ;
2301
2302 /*
2303         UTILITIES
2304
2305 TODO: should deprecate in favor of Scheme?
2306
2307  */
2308 number_expression:
2309         number_expression '+' number_term {
2310                 $$ = scm_sum ($1, $3);
2311         }
2312         | number_expression '-' number_term {
2313                 $$ = scm_difference ($1, $3);
2314         }
2315         | number_term
2316         ;
2317
2318 number_term:
2319         number_factor {
2320                 $$ = $1;
2321         }
2322         | number_factor '*' number_factor {
2323                 $$ = scm_product ($1, $3);
2324         }
2325         | number_factor '/' number_factor {
2326                 $$ = scm_divide ($1, $3);
2327         }
2328         ;
2329
2330 number_factor:
2331         '-'  number_factor { /* %prec UNARY_MINUS */
2332                 $$ = scm_difference ($2, SCM_UNDEFINED);
2333         }
2334         | bare_number
2335         ;
2336
2337
2338 bare_number:
2339         UNSIGNED        {
2340                 $$ = scm_from_int ($1);
2341         }
2342         | REAL          {
2343                 $$ = $1;
2344         }
2345         | NUMBER_IDENTIFIER             {
2346                 $$ = $1;
2347         }
2348         | REAL NUMBER_IDENTIFIER        {
2349                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2350         }
2351         | UNSIGNED NUMBER_IDENTIFIER    {
2352                 $$ = scm_from_double ($1 *scm_to_double ($2));
2353         }
2354         ;
2355
2356
2357 bare_unsigned:
2358         UNSIGNED {
2359                         $$ = $1;
2360         }
2361         | DIGIT {
2362                 $$ = $1;
2363         }
2364         ;
2365
2366 unsigned_number:
2367         bare_unsigned  { $$ = scm_from_int ($1); }
2368         | NUMBER_IDENTIFIER {
2369                 $$ = $1;
2370         }
2371         ;
2372
2373 exclamations:
2374                 { $$ = 0; }
2375         | exclamations '!'      { $$ ++; }
2376         ;
2377
2378 questions:
2379                 { $$ = 0; }
2380         | questions '?' { $$ ++; }
2381         ;
2382
2383 /*
2384 This should be done more dynamically if possible.
2385 */
2386
2387 lyric_markup:
2388         LYRIC_MARKUP_IDENTIFIER {
2389                 $$ = $1;
2390         }
2391         | LYRIC_MARKUP
2392                 { PARSER->lexer_->push_markup_state (); }
2393         markup_top {
2394                 $$ = $3;
2395                 PARSER->lexer_->pop_state ();
2396         }
2397         ;
2398
2399 full_markup_list:
2400         MARKUPLINES
2401                 { PARSER->lexer_->push_markup_state (); }
2402         markup_list {
2403                 $$ = $3;
2404                 PARSER->lexer_->pop_state ();
2405         }
2406         ;
2407
2408 full_markup:
2409         MARKUP_IDENTIFIER {
2410                 $$ = $1;
2411         }
2412         | MARKUP
2413                 { PARSER->lexer_->push_markup_state (); }
2414         markup_top {
2415                 $$ = $3;
2416                 PARSER->lexer_->pop_state ();
2417         }
2418         ;
2419
2420 markup_top:
2421         markup_list {
2422                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2423         }
2424         | markup_head_1_list simple_markup      {
2425                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2426         }
2427         | simple_markup {
2428                 $$ = $1;
2429         }
2430         ;
2431
2432 markup_list:
2433         markup_composed_list {
2434                 $$ = $1;
2435         }
2436         | markup_braced_list {
2437                 $$ = $1;
2438         }
2439         | markup_command_list {
2440                 $$ = scm_list_1 ($1);
2441         }
2442         ;
2443
2444 markup_composed_list:
2445         markup_head_1_list markup_braced_list {
2446                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2447
2448         }
2449         ;
2450
2451 markup_braced_list:
2452         '{' markup_braced_list_body '}' {
2453                 $$ = scm_reverse_x ($2, SCM_EOL);
2454         }
2455         ;
2456
2457 markup_braced_list_body:
2458         /* empty */     {  $$ = SCM_EOL; }
2459         | markup_braced_list_body markup {
2460                 $$ = scm_cons ($2, $1);
2461         }
2462         | markup_braced_list_body markup_list {
2463                 $$ = scm_reverse_x ($2, $1);
2464         }
2465         ;
2466
2467 markup_command_list:
2468         MARKUP_LIST_FUNCTION markup_command_list_arguments {
2469           $$ = scm_cons ($1, scm_reverse_x($2, SCM_EOL));
2470         }
2471         ;
2472
2473 markup_command_basic_arguments:
2474         EXPECT_MARKUP_LIST markup_command_list_arguments markup_list {
2475           $$ = scm_cons ($3, $2);
2476         }
2477         | EXPECT_SCM markup_command_list_arguments embedded_scm {
2478           $$ = scm_cons ($3, $2);
2479         }
2480         | EXPECT_NO_MORE_ARGS {
2481           $$ = SCM_EOL;
2482         }
2483         ;
2484
2485 markup_command_list_arguments:
2486         markup_command_basic_arguments { $$ = $1; }
2487         | EXPECT_MARKUP markup_command_list_arguments markup {
2488           $$ = scm_cons ($3, $2);
2489         }
2490         ;
2491
2492 markup_head_1_item:
2493         MARKUP_FUNCTION EXPECT_MARKUP markup_command_list_arguments {
2494           $$ = scm_cons ($1, scm_reverse_x ($3, SCM_EOL));
2495         }
2496         ;
2497
2498 markup_head_1_list:
2499         markup_head_1_item      {
2500                 $$ = scm_list_1 ($1);
2501         }
2502         | markup_head_1_list markup_head_1_item {
2503                 $$ = scm_cons ($2, $1);
2504         }
2505         ;
2506
2507 simple_markup:
2508         STRING {
2509                 $$ = make_simple_markup ($1);
2510         }
2511         | MARKUP_IDENTIFIER {
2512                 $$ = $1;
2513         }
2514         | LYRIC_MARKUP_IDENTIFIER {
2515                 $$ = $1;
2516         }
2517         | STRING_IDENTIFIER {
2518                 $$ = $1;
2519         }
2520         | SCORE {
2521                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
2522                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
2523         } '{' score_body '}' {
2524                 Score * sc = $4;
2525                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2526                 sc->unprotect ();
2527                 PARSER->lexer_->pop_state ();
2528         }
2529         | MARKUP_FUNCTION markup_command_basic_arguments {
2530                 $$ = scm_cons ($1, scm_reverse_x ($2, SCM_EOL));
2531         }
2532         ;
2533
2534 markup:
2535         markup_head_1_list simple_markup        {
2536                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2537                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2538         }
2539         | simple_markup {
2540                 $$ = $1;
2541         }
2542         ;
2543
2544 %%
2545
2546 void
2547 Lily_parser::set_yydebug (bool x)
2548 {
2549         yydebug = x;
2550 }
2551
2552 void
2553 Lily_parser::do_yyparse ()
2554 {
2555         yyparse ((void*)this);
2556 }
2557
2558
2559
2560
2561
2562 /*
2563
2564 It is a little strange to have this function in this file, but
2565 otherwise, we have to import music classes into the lexer.
2566
2567 */
2568 int
2569 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2570 {
2571         if (scm_is_string (sid)) {
2572                 *destination = sid;
2573                 return STRING_IDENTIFIER;
2574         } else if (unsmob_book (sid)) {
2575                 Book *book =  unsmob_book (sid)->clone ();
2576                 *destination = book->self_scm ();
2577                 book->unprotect ();
2578
2579                 return BOOK_IDENTIFIER;
2580         } else if (scm_is_number (sid)) {
2581                 *destination = sid;
2582                 return NUMBER_IDENTIFIER;
2583         } else if (unsmob_context_def (sid)) {
2584                 Context_def *def= unsmob_context_def (sid)->clone ();
2585
2586                 *destination = def->self_scm ();
2587                 def->unprotect ();
2588
2589                 return CONTEXT_DEF_IDENTIFIER;
2590         } else if (unsmob_context_mod (sid)) {
2591                 *destination = unsmob_context_mod (sid)->smobbed_copy ();
2592
2593                 return CONTEXT_MOD_IDENTIFIER;
2594         } else if (unsmob_score (sid)) {
2595                 Score *score = new Score (*unsmob_score (sid));
2596                 *destination = score->self_scm ();
2597
2598                 score->unprotect ();
2599                 return SCORE_IDENTIFIER;
2600         } else if (Music *mus = unsmob_music (sid)) {
2601                 mus = mus->clone ();
2602                 *destination = mus->self_scm ();
2603                 unsmob_music (*destination)->
2604                         set_property ("origin", make_input (last_input_));
2605
2606                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2607                         != SCM_BOOL_F;
2608
2609                 mus->unprotect ();
2610                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2611         } else if (unsmob_duration (sid)) {
2612                 *destination = unsmob_duration (sid)->smobbed_copy ();
2613                 return DURATION_IDENTIFIER;
2614         } else if (unsmob_output_def (sid)) {
2615                 Output_def *p = unsmob_output_def (sid);
2616                 p = p->clone ();
2617
2618                 *destination = p->self_scm ();
2619                 p->unprotect ();
2620                 return OUTPUT_DEF_IDENTIFIER;
2621         } else if (Text_interface::is_markup (sid)) {
2622                 *destination = sid;
2623                 if (is_lyric_state ())
2624                         return LYRIC_MARKUP_IDENTIFIER;
2625                 return MARKUP_IDENTIFIER;
2626         }
2627
2628         return -1;
2629 }
2630
2631 SCM
2632 get_next_unique_context_id ()
2633 {
2634         return scm_from_locale_string ("$uniqueContextId");
2635 }
2636
2637
2638 SCM
2639 get_next_unique_lyrics_context_id ()
2640 {
2641         static int new_context_count;
2642         char s[128];
2643         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2644         return scm_from_locale_string (s);
2645 }
2646
2647
2648 SCM
2649 run_music_function (Lily_parser *parser, SCM expr)
2650 {
2651         SCM func = scm_car (expr);
2652         Input *loc = unsmob_input (scm_cadr (expr));
2653         SCM args = scm_cddr (expr);
2654         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2655
2656         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2657
2658         if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr (expr), sig, args)))
2659         {
2660                 parser->error_level_ = 1;
2661                 return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("void-music"), scm_list_2 (parser->self_scm (), make_input (*loc)));
2662         }
2663
2664         SCM syntax_args = scm_list_4 (parser->self_scm (), make_input (*loc), func, args);
2665         return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("music-function"), syntax_args);
2666 }
2667
2668 bool
2669 is_regular_identifier (SCM id)
2670 {
2671   string str = ly_scm2string (id);
2672   char const *s = str.c_str ();
2673
2674   bool v = true;
2675 #if 0
2676   isalpha (*s);
2677   s++;
2678 #endif
2679   while (*s && v)
2680    {
2681         v = v && isalnum (*s);
2682         s++;
2683    }
2684   return v;
2685 }
2686
2687 Music *
2688 make_music_with_input (SCM name, Input where)
2689 {
2690        Music *m = make_music_by_name (name);
2691        m->set_spot (where);
2692        return m;
2693 }
2694
2695 SCM
2696 get_first_context_id (SCM type, Music *m)
2697 {
2698         SCM id = m->get_property ("context-id");
2699         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2700             && scm_is_string (m->get_property ("context-id"))
2701             && scm_c_string_length (id) > 0)
2702         {
2703                 return id;
2704         }
2705         return SCM_EOL;
2706 }
2707
2708 SCM
2709 make_simple_markup (SCM a)
2710 {
2711         return a;
2712 }
2713
2714 bool
2715 is_duration (int t)
2716 {
2717   return t && t == 1 << intlog2 (t);
2718 }
2719
2720 void
2721 set_music_properties (Music *p, SCM a)
2722 {
2723   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2724         p->set_property (scm_caar (k), scm_cdar (k));
2725 }
2726
2727
2728 SCM
2729 make_chord_step (int step, Rational alter)
2730 {
2731         if (step == 7)
2732                 alter += FLAT_ALTERATION;
2733
2734         while (step < 0)
2735                 step += 7;
2736         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2737         return m.smobbed_copy ();
2738 }
2739
2740
2741 SCM
2742 make_chord_elements (SCM pitch, SCM dur, SCM modification_list)
2743 {
2744         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
2745         return scm_call_3 (chord_ctor, pitch, dur, modification_list);
2746 }
2747
2748
2749 /* Todo: actually also use apply iso. call too ...  */
2750 bool
2751 ly_input_procedure_p (SCM x)
2752 {
2753         return ly_is_procedure (x)
2754                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2755 }
2756
2757 SCM
2758 make_music_relative (Pitch start, SCM music, Input loc)
2759 {
2760         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic", loc);
2761         relative->set_property ("element", music);
2762
2763         Music *m = unsmob_music (music);
2764         Pitch last = m->to_relative_octave (start);
2765         if (lily_1_8_relative)
2766                 m->set_property ("last-pitch", last.smobbed_copy ());
2767         return relative->unprotect ();
2768 }
2769
2770 int
2771 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2772 {
2773         Lily_parser *pars = (Lily_parser*) v;
2774         Lily_lexer *lex = pars->lexer_;
2775
2776         lex->lexval_ = (void*) s;
2777         lex->lexloc_ = loc;
2778         lex->prepare_for_next_token ();
2779         return lex->yylex ();
2780 }