lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29
  30 #include "context-def.hh"
  31 #include "dimensions.hh"
  32 #include "event.hh"
  33 #include "file-path.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "lily-lexer.hh"
  44 #include "lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "output-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((Lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (scm_is_symbol (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (scm_is_symbol (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
 123         p->internal_set_property (scm_caar (k), scm_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (scm_is_pair (x) && ly_c_procedure_p (scm_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left ADDLYRICS
 193
 194 %union {
 195         Book *book;
 196         Output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         Lily_parser *pars = (Lily_parser*) v;
 209         Lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226   (what? --hwn)
 227
 228 3. \markup { }
 229
 230   (what? --hwn)
 231
 232
 233 4.  \repeat
 234         \repeat .. \alternative
 235
 236
 237     \repeat { \repeat .. \alternative }
 238
 239 or
 240
 241     \repeat { \repeat } \alternative
 242
 243 )
 244  */
 245
 246
 247 %pure_parser
 248
 249 %token ACCEPTS
 250 %token ADDQUOTE
 251 %token LYRICSTO
 252 %token ALIAS
 253 %token ALTERNATIVE
 254 %token BAR
 255 %token BOOK
 256 %token CHANGE
 257 %token CHORDMODIFIERS
 258 %token CHORDS
 259 %token CHORDMODE
 260 %token DOUBLE_ANGLE_OPEN
 261 %token DOUBLE_ANGLE_CLOSE
 262 %token CLEF
 263 %token COMMANDSPANREQUEST
 264 %token CONSISTS
 265 %token CONTEXT
 266 %token DEFAULT
 267 %token DENIES
 268 %token DESCRIPTION
 269 %token EXTENDER
 270 %token FIGURES
 271 %token FIGUREMODE
 272 %token FIGURE_OPEN FIGURE_CLOSE
 273 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 274 %token GROBDESCRIPTIONS
 275 %token HEADER
 276 %token HYPHEN
 277 %token INVALID
 278 %token KEY
 279 %token LAYOUT
 280 %token LYRICS
 281 %token LYRICMODE
 282 %token MARK
 283 %token MIDI
 284 %token MULTI_MEASURE_REST
 285 %token NAME
 286 %token NEWCONTEXT
 287 %token NOTEMODE
 288 %token OCTAVE
 289 %token ONCE
 290 %token OVERRIDE SET REVERT
 291 %token PAPER
 292 %token PARTIAL
 293 %token QUOTE
 294 %token RELATIVE
 295 %token REMOVE
 296 %token REPEAT
 297 %token REST
 298 %token SCM_T
 299 %token SCORE
 300 %token SEQUENTIAL
 301 %token ADDLYRICS
 302 %token SIMULTANEOUS
 303 %token SKIP
 304 %token SPANREQUEST
 305 %token TAG
 306 %token TEMPO
 307 %token TIMES
 308 %token TIME_T
 309 %token TRANSPOSE
 310 %token TRANSPOSITION
 311 %token TYPE
 312 %token UNSET
 313 %token WITH
 314 %token MARKUP
 315
 316 /* escaped */
 317 /* FIXME: this sucks.  The user will get to see these names:
 318     syntax error, unexpected E_CHAR:
 319                 \
 320                  %%
 321   */
 322
 323 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 324 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 325 %token E_BACKSLASH
 326 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 327 %token FIGURE_SPACE
 328
 329 %token <i>      DIGIT
 330 %token <i>      UNSIGNED
 331 %token <i> E_UNSIGNED
 332 %token <id>     IDENTIFIER
 333 %token <scm>    CHORDMODIFIER_PITCH
 334 %token <scm>    DRUM_PITCH
 335 %token <scm>    DURATION_IDENTIFIER
 336 %token <scm>    EVENT_IDENTIFIER
 337 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 338 %token <scm>    NOTENAME_PITCH
 339 %token <scm>    NUMBER_IDENTIFIER
 340 %token <scm>    OUTPUT_DEF_IDENTIFIER
 341 %token <scm>    RESTNAME
 342 %token <scm> LYRICS_STRING
 343 %token <scm>    SCM_T
 344 %token <scm>    SCORE_IDENTIFIER
 345 %token <scm>    STRING
 346 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 347 %token <scm>    TONICNAME_PITCH
 348 %token <scm>    CHORD_MODIFIER
 349 %token <scm>    FRACTION
 350 %token <scm>   REAL
 351 %token <scm> MARKUP_HEAD_EMPTY
 352 %token <scm> MARKUP_HEAD_MARKUP0
 353 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 354 %token <scm> MARKUP_HEAD_SCM0
 355 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 356 %token <scm> MARKUP_HEAD_SCM0_SCM1
 357 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 358 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 359 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 360 %token <scm> MUSIC_FUNCTION
 361 %token <scm> MUSIC_FUNCTION_MUSIC
 362 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 363 %token <scm> MUSIC_FUNCTION_SCM
 364 %token <scm> MUSIC_FUNCTION_SCM_SCM
 365 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 366 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 367 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 368 %token <scm> MUSIC_FUNCTION_MARKUP
 369 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP
 370 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC
 371 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC
 372 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP_MUSIC
 373
 374 %token DRUMS
 375 %token DRUMMODE
 376
 377
 378 %type <book>    book_block book_body
 379 %type <i>       bare_int  bare_unsigned
 380 %type <i>       exclamations questions dots optional_rest
 381 %type <i>       script_dir
 382 %type <i>       sub_quotes sup_quotes
 383 %type <i>       tremolo_type
 384 %type <i>       bass_mod
 385
 386 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 387 %type <music>   Grouped_music_list
 388 %type <music>   Music Sequential_music Simultaneous_music
 389 %type <music>   Repeated_music
 390 %type <music>   command_req
 391 %type <music>   gen_text_def direction_less_event direction_reqd_event
 392 %type <music>   music_property_def context_change
 393 %type <music>   note_chord_element chord_body chord_body_element
 394 %type <music>   post_event tagged_post_event
 395 %type <music>   relative_music re_rhythmed_music
 396 %type <music>   simple_element event_chord command_element
 397 %type <music>   string_number_event
 398 %type <music>   toplevel_music
 399 %type <music>   tempo_event
 400
 401 %type <outputdef>       output_def_body output_def_head
 402 %type <outputdef> output_def paper_block
 403
 404 %type <scm>     Music_list
 405 %type <scm>     chord_body_elements
 406 %type <scm>     chord_item chord_items chord_separator new_chord
 407 %type <scm>     context_def_spec_block context_def_spec_body
 408 %type <scm>     context_mod context_def_mod optional_context_mod
 409 %type <scm>     context_prop_spec
 410 %type <scm>     direction_less_char
 411 %type <scm>     duration_length fraction
 412 %type <scm>     embedded_scm scalar
 413 %type <scm>     identifier_init
 414 %type <scm>     lilypond_header lilypond_header_body
 415 %type <scm>     new_lyrics
 416 %type <scm>     post_events
 417 %type <scm>     property_operation
 418 %type <scm>     script_abbreviation
 419 %type <scm>     simple_string
 420 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 421 %type <scm>     steno_tonic_pitch
 422 %type <scm>     step_number step_numbers
 423 %type <scm>     string bare_number number_expression number_term number_factor
 424 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 425 %type <scm>     context_mod_list
 426 %type <scm>     octave_check
 427 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 428 %type <scm>     Generic_prefix_music_scm
 429 %type <scm>     lyric_element
 430 %type <scm>     Alternative_music
 431 %type <scm>     markup markup_line markup_list markup_list_body full_markup
 432 %type <scm>     mode_changing_head
 433 %type <scm>     mode_changing_head_with_context
 434
 435 %type <score>   score_block score_body
 436
 437
 438 %left '-' '+'
 439
 440 /* We don't assign precedence to / and *, because we might need varied
 441 prec levels in different prods */
 442
 443 %left UNARY_MINUS
 444
 445 %%
 446
 447 lilypond:       /* empty */
 448         | lilypond toplevel_expression {
 449         }
 450         | lilypond assignment {
 451         }
 452         | lilypond error {
 453                 THIS->error_level_ = 1;
 454         }
 455         | lilypond INVALID      {
 456                 THIS->error_level_ = 1;
 457         }
 458         ;
 459
 460 toplevel_expression:
 461         lilypond_header {
 462                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 463         }
 464         | add_quote {
 465
 466         }
 467         | book_block {
 468                 Book *book = $1;
 469                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 470                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 471                 scm_gc_unprotect_object (book->self_scm ());
 472         }
 473         | score_block {
 474                 Score *score = $1;
 475
 476                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 477                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 478                 scm_gc_unprotect_object (score->self_scm ());
 479         }
 480         | toplevel_music {
 481                 Music *music = $1;
 482                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 483                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 484                 scm_gc_unprotect_object (music->self_scm ());
 485         }
 486         | output_def {
 487                 SCM id = SCM_EOL;
 488                 Output_def * od = $1;
 489
 490                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 491                         id = ly_symbol2scm ("$defaultpaper");
 492                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 493                         id = ly_symbol2scm ("$defaultmidi");
 494                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 495                         id = ly_symbol2scm ("$defaultlayout");
 496
 497                 THIS->lexer_->set_identifier (id, od->self_scm ());
 498                 scm_gc_unprotect_object (od->self_scm ());
 499         }
 500         ;
 501
 502 toplevel_music:
 503         Composite_music {
 504         }
 505         ;
 506
 507 embedded_scm:
 508         SCM_T
 509         | SCM_IDENTIFIER
 510         ;
 511
 512
 513 lilypond_header_body:
 514         {
 515                 $$ = ly_make_anonymous_module (safe_global_b);
 516                 THIS->lexer_->add_scope ($$);
 517         }
 518         | lilypond_header_body assignment  {
 519
 520         }
 521         ;
 522
 523 lilypond_header:
 524         HEADER '{' lilypond_header_body '}'     {
 525                 $$ = THIS->lexer_->remove_scope ();
 526         }
 527         ;
 528
 529
 530 /*
 531         DECLARATIONS
 532 */
 533 assignment:
 534         STRING {
 535                 THIS->push_spot ();
 536         }
 537         /* cont */ '=' identifier_init  {
 538
 539         /*
 540                 Should find generic way of associating input with objects.
 541         */
 542                 Input ip = THIS->pop_spot ();
 543
 544                 if (! is_regular_identifier ($1))
 545                 {
 546                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 547                 }
 548
 549                 THIS->lexer_->set_identifier ($1, $4);
 550
 551 /*
 552  TODO: devise standard for protection in parser.
 553
 554   The parser stack lives on the C-stack, which means that
 555 all objects can be unprotected as soon as they're here.
 556
 557 */
 558         }
 559         | embedded_scm { }
 560         ;
 561
 562
 563 identifier_init:
 564         score_block {
 565                 $$ = $1->self_scm ();
 566                 scm_gc_unprotect_object ($$);
 567         }
 568         | output_def {
 569                 $$ = $1->self_scm ();
 570                 scm_gc_unprotect_object ($$);
 571         }
 572         | context_def_spec_block {
 573                 $$ = $1;
 574         }
 575         | Music  {
 576                 $$ = $1->self_scm ();
 577                 scm_gc_unprotect_object ($$);
 578         }
 579         | post_event {
 580                 $$ = $1->self_scm ();
 581                 scm_gc_unprotect_object ($$);
 582         }
 583         | number_expression {
 584                 $$ = $1;
 585         }
 586         | string {
 587                 $$ = $1;
 588         }
 589         | embedded_scm {
 590                 $$ = $1;
 591         }
 592         | full_markup {
 593                 $$ = $1;
 594         }
 595         | DIGIT {
 596                 $$ = scm_int2num ($1);
 597         }
 598         ;
 599
 600 context_def_spec_block:
 601         CONTEXT '{' context_def_spec_body '}'
 602                 {
 603                 $$ = $3;
 604         }
 605         ;
 606
 607 context_def_spec_body:
 608         /**/ {
 609                 $$ = Context_def::make_scm ();
 610                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 611         }
 612         | CONTEXT_DEF_IDENTIFIER {
 613                 $$ = $1;
 614                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 615         }
 616         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 617                 Context_def*td = unsmob_context_def ($$);
 618
 619                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 620                         SCM tag = scm_caar (p);
 621
 622                         /* TODO: should make new tag "grob-definition" ? */
 623                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 624                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 625                 }
 626         }
 627         | context_def_spec_body context_mod {
 628                 unsmob_context_def ($$)->add_context_mod ($2);
 629         }
 630         ;
 631
 632
 633
 634 book_block:
 635         BOOK {
 636                 THIS->push_spot ();
 637         }
 638         /*cont*/ '{' book_body '}'      {
 639                 THIS->pop_spot ();
 640                 $$ = $4;
 641         }
 642         ;
 643
 644 /* FIXME:
 645    * Use 'handlers' like for toplevel-* stuff?
 646    * grok \layout and \midi?  */
 647 book_body:
 648         {
 649                 $$ = new Book;
 650                 $$->set_spot (THIS->here_input ());
 651                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 652                 scm_gc_unprotect_object ($$->paper_->self_scm ());
 653                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 654         }
 655         | book_body paper_block {
 656                 $$->paper_ = $2;
 657                 scm_gc_unprotect_object ($2->self_scm ());
 658         }
 659         | book_body score_block {
 660                 Score *score = $2;
 661                 $$->scores_.push (score);
 662                 scm_gc_unprotect_object (score->self_scm ());
 663         }
 664         | book_body lilypond_header {
 665                 $$->header_ = $2;
 666         }
 667         | book_body error {
 668                 $$->paper_ = 0;
 669                 $$->scores_.clear();
 670         }
 671         ;
 672
 673 score_block:
 674         SCORE {
 675                 THIS->push_spot ();
 676         }
 677         /*cont*/ '{' score_body '}'     {
 678                 THIS->pop_spot ();
 679                 $$ = $4;
 680         }
 681         ;
 682
 683 score_body:
 684         /**/    {
 685                 $$ = new Score;
 686
 687                 $$->set_spot (THIS->here_input ());
 688         }
 689         | SCORE_IDENTIFIER {
 690                 $$ = new Score ( *unsmob_score ($1));
 691                 $$->set_spot (THIS->here_input ());
 692         }
 693         | score_body Music {
 694                 SCM m = $2->self_scm ();
 695                 scm_gc_unprotect_object (m);
 696                 $$->set_music (m, THIS->self_scm ());
 697         }
 698         | score_body lilypond_header    {
 699                 $$->header_ = $2;
 700         }
 701         | score_body output_def {
 702                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 703                 {
 704                         THIS->parser_error (_("\\paper cannot be in \\score. Use \\layout instead"));
 705
 706                 }
 707                 else
 708                 {
 709                         $$->defs_.push ($2);
 710                 }
 711                 scm_gc_unprotect_object ($2->self_scm ());
 712         }
 713         | score_body error {
 714                 $$->error_found_ = true;
 715         }
 716         ;
 717
 718
 719 /*
 720         OUTPUT DEF
 721 */
 722
 723 paper_block:
 724         output_def {
 725                 $$ = $1;
 726                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 727                 {
 728                         THIS->parser_error (_("Need \\paper for paper block."));
 729                         $$ = get_paper (THIS);
 730                 }
 731         }
 732         ;
 733
 734
 735 output_def:
 736         output_def_body '}' {
 737                 $$ = $1;
 738
 739                 THIS->lexer_->remove_scope ();
 740                 THIS->lexer_->pop_state ();
 741         }
 742         ;
 743
 744 output_def_head:
 745         PAPER {
 746                 $$ = get_paper (THIS);
 747                 $$->input_origin_ = THIS->here_input ();
 748                 THIS->lexer_->add_scope ($$->scope_);
 749         }
 750         | MIDI    {
 751                 Output_def *p = get_midi (THIS);
 752                 $$ = p;
 753                 THIS->lexer_->add_scope (p->scope_);
 754         }
 755         | LAYOUT        {
 756                 Output_def *p = get_layout (THIS);
 757
 758                 THIS->lexer_->add_scope (p->scope_);
 759                 $$ = p;
 760         }
 761         ;
 762
 763
 764 output_def_body:
 765         output_def_head '{' {
 766                 $$ = $1;
 767                 $$->input_origin_.set_spot (THIS->here_input ());
 768                 THIS->lexer_->push_initial_state ();
 769         }
 770         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 771                 scm_gc_unprotect_object ($1->self_scm ());
 772                 Output_def *o = unsmob_output_def ($3);
 773                 o->input_origin_.set_spot (THIS->here_input ());
 774                 $$ = o;
 775                 THIS->lexer_->remove_scope ();
 776                 THIS->lexer_->add_scope (o->scope_);
 777                 THIS->lexer_->push_initial_state ();
 778         }
 779         | output_def_body assignment  {
 780
 781         }
 782         | output_def_body context_def_spec_block        {
 783                 assign_context_def ($$, $2);
 784         }
 785         | output_def_body tempo_event  {
 786                 /*
 787                         junk this ? there already is tempo stuff in
 788                         music.
 789                 */
 790                 int m = scm_to_int ($2->get_property ("metronome-count"));
 791                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 792                 set_tempo ($$, d->get_length (), m);
 793                 scm_gc_unprotect_object ($2->self_scm ());
 794         }
 795         | output_def_body error {
 796
 797         }
 798         ;
 799
 800 tempo_event:
 801         TEMPO steno_duration '=' bare_unsigned  {
 802                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 803                 $$->set_property ("tempo-unit", $2);
 804                 $$->set_property ("metronome-count", scm_int2num ( $4));
 805         }
 806         ;
 807
 808 /*
 809 The representation of a  list is the
 810
 811   (LIST . LAST-CONS)
 812
 813  to have efficient append.  */
 814
 815 Music_list:
 816         /* empty */ {
 817                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 818         }
 819         | Music_list Music {
 820                 SCM s = $$;
 821                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 822                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 823
 824                 if (scm_is_pair (scm_cdr (s)))
 825                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 826                 else
 827                         scm_set_car_x (s, c); /* set first cons */
 828                 scm_set_cdr_x (s, c);  /* remember last cell */
 829         }
 830         | Music_list embedded_scm {
 831
 832         }
 833         | Music_list error {
 834                 Music * m = MY_MAKE_MUSIC("Music");
 835                 // ugh. code dup
 836                 m->set_property ("error-found", SCM_BOOL_T);
 837                 SCM s = $$;
 838                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 839                 scm_gc_unprotect_object (m->self_scm ()); /* UGH */
 840
 841                 if (scm_is_pair (scm_cdr (s)))
 842                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 843                 else
 844                         scm_set_car_x (s, c); /* set first cons */
 845                 scm_set_cdr_x (s, c);  /* remember last cell */
 846         }
 847         ;
 848
 849 Music:
 850         Simple_music
 851         | Composite_music
 852         ;
 853
 854 Alternative_music:
 855         /* empty */ {
 856                 $$ = SCM_EOL;
 857         }
 858         | ALTERNATIVE '{' Music_list '}' {
 859                 $$ = $3;
 860         }
 861         ;
 862
 863
 864 Repeated_music:
 865         REPEAT simple_string bare_unsigned Music Alternative_music
 866         {
 867                 Music *beg = $4;
 868                 int times = $3;
 869                 SCM alts = scm_is_pair ($5) ? scm_car ($5) : SCM_EOL;
 870                 if (times < scm_ilength (alts)) {
 871                   unsmob_music (scm_car (alts))
 872                     ->origin ()->warning (
 873                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 874                   alts = ly_truncate_list (times, alts);
 875                 }
 876
 877
 878                 SCM proc = ly_scheme_function ("make-repeated-music");
 879
 880                 SCM mus = scm_call_1 (proc, $2);
 881                 scm_gc_protect_object (mus); // UGH.
 882                 Music *r = unsmob_music (mus);
 883                 if (beg)
 884                         {
 885                         r-> set_property ("element", beg->self_scm ());
 886                         scm_gc_unprotect_object (beg->self_scm ());
 887                         }
 888                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 889
 890                 r-> set_property ("elements",alts);
 891                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 892                         /*
 893                         TODO: move this code to Scheme.
 894                         */
 895
 896                         /*
 897                         we can not get durations and other stuff correct down the line, so we have to
 898                         add to the duration log here.
 899                         */
 900                         SCM func = ly_scheme_function ("shift-duration-log");
 901
 902                         int dots = ($3 % 3) ? 0 : 1;
 903                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 904
 905                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 906
 907                         if (seq) {
 908                                 int list_len = scm_ilength (seq->music_list ());
 909                                 if (list_len != 2)
 910                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 911                                 shift -= 1;
 912                                 r->compress (Moment (Rational (1, list_len)));
 913                                 }
 914                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 915
 916                 }
 917                 r->set_spot (*$4->origin ());
 918
 919                 $$ = r;
 920         }
 921         ;
 922
 923 Sequential_music:
 924         SEQUENTIAL '{' Music_list '}'           {
 925                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 926                 $$->set_property ("elements", scm_car ($3));
 927                 $$->set_spot (THIS->here_input ());
 928         }
 929         | '{' Music_list '}'            {
 930                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 931                 $$->set_property ("elements", scm_car ($2));
 932                 $$->set_spot (THIS->here_input ());
 933         }
 934         ;
 935
 936 Simultaneous_music:
 937         SIMULTANEOUS '{' Music_list '}'{
 938                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 939                 $$->set_property ("elements", scm_car ($3));
 940                 $$->set_spot (THIS->here_input ());
 941
 942         }
 943         | simul_open Music_list simul_close     {
 944                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 945                 $$->set_property ("elements", scm_car ($2));
 946                 $$->set_spot (THIS->here_input ());
 947         }
 948         ;
 949
 950 Simple_music:
 951         event_chord             { $$ = $1; }
 952         | MUSIC_IDENTIFIER {
 953                 $$ = unsmob_music ($1);
 954         }
 955         | music_property_def
 956         | context_change
 957         ;
 958
 959
 960 optional_context_mod:
 961         /**/ { $$ = SCM_EOL; }
 962         | WITH { THIS->lexer_->push_initial_state (); }
 963         '{' context_mod_list '}'
 964         {
 965                 THIS->lexer_->pop_state ();
 966                 $$ = $4;
 967         }
 968         ;
 969
 970 context_mod_list:
 971         /* */  { $$ = SCM_EOL; }
 972         | context_mod_list context_mod  {
 973                  $$ = scm_cons ($2, $1);
 974         }
 975         ;
 976
 977
 978 Composite_music:
 979         Prefix_composite_music { $$ = $1; }
 980         | Grouped_music_list { $$ = $1; }
 981         ;
 982
 983 Grouped_music_list:
 984         Simultaneous_music              { $$ = $1; }
 985         | Sequential_music              { $$ = $1; }
 986         ;
 987
 988 Generic_prefix_music_scm:
 989         MUSIC_FUNCTION {
 990                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 991         }
 992         | MUSIC_FUNCTION_SCM {
 993                 THIS->push_spot ();
 994         } embedded_scm {
 995                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 996         }
 997         | MUSIC_FUNCTION_MARKUP {
 998                 THIS->push_spot ();
 999         } full_markup {
1000                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
1001         }
1002         | MUSIC_FUNCTION_MUSIC {
1003                 THIS->push_spot ();
1004         } Music {
1005                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
1006                 scm_gc_unprotect_object ($3->self_scm ());
1007         }
1008         | MUSIC_FUNCTION_SCM_MUSIC {
1009                 THIS->push_spot ();
1010         }  embedded_scm Music {
1011                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
1012                 scm_gc_unprotect_object ($4->self_scm ());
1013         }
1014         | MUSIC_FUNCTION_SCM_SCM {
1015                 THIS->push_spot ();
1016         }  embedded_scm embedded_scm {
1017                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4);
1018         }
1019         | MUSIC_FUNCTION_MARKUP_MUSIC {
1020                 THIS->push_spot ();
1021         }  full_markup Music {
1022                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
1023                 scm_gc_unprotect_object ($4->self_scm ());
1024         }
1025         | MUSIC_FUNCTION_MARKUP_MARKUP {
1026                 THIS->push_spot ();
1027         }  full_markup full_markup {
1028                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4);
1029         }
1030         | MUSIC_FUNCTION_MUSIC_MUSIC {
1031                 THIS->push_spot ();
1032         }  Music  Music {
1033                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
1034                 scm_gc_unprotect_object ($3->self_scm ());
1035                 scm_gc_unprotect_object ($4->self_scm ());
1036         }
1037         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
1038                 THIS->push_spot ();
1039         } embedded_scm Music Music {
1040                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
1041                         $3, $4->self_scm (), $5->self_scm ());
1042                 scm_gc_unprotect_object ($5->self_scm ());
1043                 scm_gc_unprotect_object ($4->self_scm ());
1044         }
1045         | MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC {
1046                 THIS->push_spot ();
1047         } full_markup Music Music {
1048                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
1049                         $3, $4->self_scm (), $5->self_scm ());
1050                 scm_gc_unprotect_object ($5->self_scm ());
1051                 scm_gc_unprotect_object ($4->self_scm ());
1052         }
1053         ;
1054
1055 Generic_prefix_music:
1056         Generic_prefix_music_scm {
1057                 SCM func = scm_car ($1);
1058                 Input *loc = unsmob_input (scm_cadr ($1));
1059                 SCM args = scm_cddr ($1);
1060                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1061                 int k = 0;
1062                 bool ok  = true;
1063                 for (SCM s = sig, t = args;
1064                         ok && scm_is_pair (s) && scm_is_pair (t);
1065                         s = scm_cdr (s), t = scm_cdr (t)) {
1066                         k++;
1067                         if (scm_call_1 (scm_car (s), scm_car (t)) != SCM_BOOL_T)
1068                         {
1069                                 loc->error (_f ("Argument %d failed typecheck", k));
1070                                 THIS->error_level_ = 1;
1071                                 ok = false;
1072                         }
1073                 }
1074                 SCM m = SCM_EOL;
1075                 if (ok)
1076                         m = scm_apply_0 (func, scm_cdr ($1));
1077                 if (unsmob_music (m))
1078                         {
1079                         $$ = unsmob_music (m);
1080                         scm_gc_protect_object (m);
1081                         }
1082                 else
1083                         {
1084                         if (ok)
1085                                 loc->error (_ ("Music head function should return Music object."));
1086                         $$ = MY_MAKE_MUSIC ("Music");
1087                         }
1088                 $$->set_spot (*loc);
1089         }
1090         ;
1091
1092
1093 Prefix_composite_music:
1094         Generic_prefix_music {
1095                 $$ = $1;
1096         }
1097         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1098                 $$ = context_spec_music ($2, $4, $6, $5);
1099
1100         }
1101         | CONTEXT simple_string optional_context_mod Music {
1102                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1103         }
1104         | NEWCONTEXT simple_string optional_context_mod Music {
1105                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1106                         $3);
1107         }
1108
1109         | TIMES {
1110                 THIS->push_spot ();
1111         }
1112         /* CONTINUED */
1113                 fraction Music
1114
1115         {
1116                 int n = scm_to_int (scm_car ($3)); int d = scm_to_int (scm_cdr ($3));
1117                 Music *mp = $4;
1118
1119                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1120                 $$->set_spot (THIS->pop_spot ());
1121
1122                 $$->set_property ("element", mp->self_scm ());
1123                 scm_gc_unprotect_object (mp->self_scm ());
1124                 $$->set_property ("numerator", scm_int2num (n));
1125                 $$->set_property ("denominator", scm_int2num (d));
1126                 $$->compress (Moment (Rational (n,d)));
1127
1128         }
1129         | Repeated_music                { $$ = $1; }
1130         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1131                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1132                 Music *p = $4;
1133                 Pitch from = *unsmob_pitch ($2);
1134                 Pitch to = *unsmob_pitch ($3);
1135
1136                 p->transpose (pitch_interval (from, to));
1137                 $$->set_property ("element", p->self_scm ());
1138                 scm_gc_unprotect_object (p->self_scm ());
1139         }
1140         | mode_changing_head Grouped_music_list {
1141                 if ($1 == ly_symbol2scm ("figures"))
1142                 {
1143                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1144                   chm->set_property ("element", $2->self_scm ());
1145                   $$ = chm;
1146                   scm_gc_unprotect_object ($2->self_scm ());
1147                 }
1148                 else
1149                 {
1150                   $$ = $2;
1151                 }
1152                 THIS->lexer_->pop_state ();
1153         }
1154         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1155                 $$ = context_spec_music ($1, get_next_unique_context (),
1156                                          $3, $2);
1157                 if ($1 == ly_symbol2scm ("FiguredBass"))
1158                 {
1159                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1160                   chm->set_property ("element", $$->self_scm ());
1161                   scm_gc_unprotect_object ($$->self_scm ());
1162                   $$ = chm;
1163                 }
1164                 THIS->lexer_->pop_state ();
1165         }
1166         | relative_music        { $$ = $1; }
1167         | re_rhythmed_music     { $$ = $1; }
1168         | TAG embedded_scm Music {
1169                 tag_music ($3, $2, THIS->here_input ());
1170                 $$ = $3;
1171         }
1172         ;
1173
1174 mode_changing_head:
1175         NOTEMODE {
1176                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1177                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1178
1179                 $$ = ly_symbol2scm ("notes");
1180         }
1181         | DRUMMODE
1182                 {
1183                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1184                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1185
1186                 $$ = ly_symbol2scm ("drums");
1187         }
1188         | FIGUREMODE {
1189                 THIS->lexer_->push_figuredbass_state ();
1190
1191                 $$ = ly_symbol2scm ("figures");
1192         }
1193         | CHORDMODE {
1194                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1195                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1196                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1197                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1198                 $$ = ly_symbol2scm ("chords");
1199
1200         }
1201         | LYRICMODE
1202                 { THIS->lexer_->push_lyric_state ();
1203                 $$ = ly_symbol2scm ("lyrics");
1204         }
1205         ;
1206
1207 mode_changing_head_with_context:
1208         DRUMS {
1209                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1210                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1211
1212                 $$ = ly_symbol2scm ("DrumStaff");
1213         }
1214         | FIGURES {
1215                 THIS->lexer_->push_figuredbass_state ();
1216
1217                 $$ = ly_symbol2scm ("FiguredBass");
1218         }
1219         | CHORDS {
1220                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1221                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1222                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1223                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1224                 $$ = ly_symbol2scm ("ChordNames");
1225         }
1226         | LYRICS
1227                 { THIS->lexer_->push_lyric_state ();
1228                 $$ = ly_symbol2scm ("Lyrics");
1229         }
1230         ;
1231
1232
1233 relative_music:
1234         RELATIVE absolute_pitch Music {
1235                 Music *m = $3;
1236                 Pitch start = *unsmob_pitch ($2);
1237                 $$ = make_music_relative (start, m);
1238                 scm_gc_unprotect_object (m->self_scm ());
1239         }
1240         | RELATIVE Composite_music {
1241                 Music *m = $2;
1242
1243                 Pitch middle_c (0, 0, 0);
1244                 $$ = make_music_relative (middle_c, m);
1245                 scm_gc_unprotect_object (m->self_scm ());
1246         }
1247         ;
1248
1249 new_lyrics:
1250         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1251         /*cont */
1252         Grouped_music_list {
1253         /* Can also use Music at the expensive of two S/Rs similar to
1254            \repeat \alternative */
1255                 THIS->lexer_->pop_state ();
1256
1257                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1258         }
1259         | new_lyrics ADDLYRICS {
1260                 THIS->lexer_->push_lyric_state ();
1261         } Grouped_music_list {
1262                 THIS->lexer_->pop_state ();
1263                 $$ = scm_cons ($4->self_scm (), $1);
1264         }
1265         ;
1266
1267 re_rhythmed_music:
1268         Grouped_music_list new_lyrics {
1269
1270                 SCM name = $1->get_property ("context-id");
1271                 //if (name == SCM_EOL)
1272                 if (!scm_is_string (name))
1273                         name = scm_makfrom0str ("");
1274
1275                 SCM context = scm_makfrom0str ("Lyrics");
1276                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1277
1278                 SCM lst = SCM_EOL;
1279                 for (SCM s = $2; scm_is_pair (s); s = scm_cdr (s))
1280                 {
1281                         Music *music = unsmob_music (scm_car (s));
1282                         Music *com = make_lyric_combine_music (name, music);
1283                         Music *csm = context_spec_music (context,
1284                                 get_next_unique_context (), com, SCM_EOL);
1285                         lst = scm_cons (csm->self_scm (), lst);
1286                 }
1287                 /* FIXME: only first lyric music is accepted,
1288                           the rest is junked */
1289                 all->set_property ("elements", scm_cons ($1->self_scm (),
1290                         lst));
1291                 $$ = all;
1292                 scm_gc_unprotect_object ($1->self_scm ());
1293         }
1294         | LYRICSTO {
1295                 THIS->lexer_->push_lyric_state ();
1296         } simple_string Music {
1297                 THIS->lexer_->pop_state ();
1298                 Music *music = $4;
1299                 SCM name = $3;
1300                 $$ = make_lyric_combine_music (name, music);
1301                 scm_gc_unprotect_object (music->self_scm ());
1302         }
1303         ;
1304
1305 context_change:
1306         CHANGE STRING '=' STRING  {
1307                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1308                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1309                 t-> set_property ("change-to-id", $4);
1310
1311                 $$ = t;
1312                 $$->set_spot (THIS->here_input ());
1313         }
1314         ;
1315
1316 property_operation:
1317         STRING '=' scalar {
1318                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1319                         scm_string_to_symbol ($1), $3);
1320         }
1321         | UNSET simple_string {
1322                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1323                         scm_string_to_symbol ($2));
1324         }
1325         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1326                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1327                         scm_string_to_symbol ($2), $3, $5);
1328         }
1329         | REVERT simple_string embedded_scm {
1330                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1331                         scm_string_to_symbol ($2), $3);
1332         }
1333         ;
1334
1335 context_def_mod:
1336         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1337         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1338
1339         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1340         | DENIES { $$ = ly_symbol2scm ("denies"); }
1341
1342         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1343         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1344         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1345         | NAME { $$ = ly_symbol2scm ("context-name"); }
1346         ;
1347
1348 context_mod:
1349         property_operation { $$ = $1; }
1350         | context_def_mod STRING {
1351                 $$ = scm_list_2 ($1, $2);
1352         }
1353         ;
1354
1355 context_prop_spec:
1356         simple_string {
1357                 if (!is_regular_identifier ($1))
1358                 {
1359                         THIS->here_input ().error (_("Grob name should be alphanumeric"));
1360                 }
1361
1362                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1363                         scm_string_to_symbol ($1));
1364         }
1365         | simple_string '.' simple_string {
1366                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1367                         scm_string_to_symbol ($3));
1368         }
1369         ;
1370
1371 music_property_def:
1372         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1373                 $$ = property_op_to_music (scm_list_4 (
1374                         ly_symbol2scm ("poppush"),
1375                         scm_cadr ($2),
1376                         $3, $5));
1377                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1378         }
1379         | REVERT context_prop_spec embedded_scm {
1380                 $$ = property_op_to_music (scm_list_3 (
1381                         ly_symbol2scm ("pop"),
1382                         scm_cadr ($2),
1383                         $3));
1384
1385                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1386         }
1387         | SET context_prop_spec '=' scalar {
1388                 $$ = property_op_to_music (scm_list_3 (
1389                         ly_symbol2scm ("assign"),
1390                         scm_cadr ($2),
1391                         $4));
1392                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1393         }
1394         | UNSET context_prop_spec {
1395                 $$ = property_op_to_music (scm_list_2 (
1396                         ly_symbol2scm ("unset"),
1397                         scm_cadr ($2)));
1398                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1399         }
1400         | ONCE music_property_def {
1401                 SCM e = $2->get_property ("element");
1402                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1403                 $$ = $2;
1404
1405         }
1406         ;
1407
1408
1409 string:
1410         STRING {
1411                 $$ = $1;
1412         }
1413         | STRING_IDENTIFIER {
1414                 $$ = $1;
1415         }
1416         | string '+' string {
1417                 $$ = scm_string_append (scm_list_2 ($1, $3));
1418         }
1419         ;
1420
1421 simple_string: STRING {
1422                 $$ = $1;
1423         }
1424         | LYRICS_STRING {
1425                 $$ = $1;
1426         }
1427         ;
1428
1429 scalar: string {
1430                 $$ = $1;
1431         }
1432         | LYRICS_STRING {
1433                 $$ = $1;
1434         }
1435         | bare_int {
1436                 $$ = scm_int2num ($1);
1437         }
1438         | embedded_scm {
1439                 $$ = $1;
1440         }
1441         | full_markup {
1442                 $$ = $1;
1443         }
1444         | DIGIT {
1445                 $$ = scm_int2num ($1);
1446         }
1447         ;
1448
1449 /*
1450
1451 pre_events doesn't contain anything. It is a trick:
1452
1453 Adding pre_events to the simple_element
1454 makes the choice between
1455
1456   string:  STRING
1457
1458 and
1459
1460   simple_element: STRING
1461
1462 a single shift/reduction conflict.
1463
1464 nevertheless, this is not very clean, and we should find a different
1465 solution.
1466
1467 */
1468 pre_events: {
1469                 THIS->push_spot ();
1470         }
1471         ;
1472
1473 event_chord:
1474         pre_events simple_element post_events   {
1475                 SCM elts = $2-> get_property ("elements");
1476
1477                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1478
1479                 $2->set_property ("elements", elts);
1480                 $$ = $2;
1481         }
1482         | command_element
1483         | note_chord_element
1484         ;
1485
1486
1487 note_chord_element:
1488         chord_body optional_notemode_duration post_events
1489         {
1490                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1491                 SCM es = $1->get_property ("elements");
1492                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1493
1494                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1495                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1496                 es = ly_append2 (es, postevs);
1497
1498                 $1-> set_property ("elements", es);
1499                 $$ = $1;
1500         }
1501         ;
1502
1503 chord_open: '<'
1504         ;
1505
1506 chord_close: '>'
1507         ;
1508
1509 simul_open: DOUBLE_ANGLE_OPEN
1510         ;
1511
1512 simul_close: DOUBLE_ANGLE_CLOSE
1513         ;
1514
1515 chord_body:
1516         chord_open chord_body_elements chord_close
1517         {
1518                 $$ = MY_MAKE_MUSIC ("EventChord");
1519                 $$->set_property ("elements",
1520                         scm_reverse_x ($2, SCM_EOL));
1521         }
1522         ;
1523
1524 chord_body_elements:
1525         /* empty */             { $$ = SCM_EOL; }
1526         | chord_body_elements chord_body_element {
1527                 $$ = scm_cons ($2->self_scm (), $1);
1528                 scm_gc_unprotect_object ($2->self_scm ());
1529         }
1530         ;
1531
1532 chord_body_element:
1533         pitch  exclamations questions octave_check post_events
1534         {
1535                 int q = $3;
1536                 int ex = $2;
1537                 SCM check = $4;
1538                 SCM post = $5;
1539
1540                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1541                 n->set_property ("pitch", $1);
1542                 if (q % 2)
1543                         n->set_property ("cautionary", SCM_BOOL_T);
1544                 if (ex % 2 || q % 2)
1545                         n->set_property ("force-accidental", SCM_BOOL_T);
1546
1547                 if (scm_is_pair (post)) {
1548                         SCM arts = scm_reverse_x (post, SCM_EOL);
1549                         n->set_property ("articulations", arts);
1550                 }
1551                 if (scm_is_number (check))
1552                 {
1553                         int q = scm_to_int (check);
1554                         n->set_property ("absolute-octave", scm_int2num (q-1));
1555                 }
1556
1557
1558                 $$ = n;
1559         }
1560         | DRUM_PITCH post_events {
1561                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1562                 n->set_property ("duration", $2);
1563                 n->set_property ("drum-type", $1);
1564                 n->set_spot (THIS->here_input ());
1565
1566                 if (scm_is_pair ($2)) {
1567                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1568                         n->set_property ("articulations", arts);
1569                 }
1570                 $$ = n;
1571         }
1572         ;
1573
1574 add_quote:
1575         ADDQUOTE string Music {
1576                 SCM adder = ly_scheme_function ("add-quotable");
1577
1578                 scm_call_2 (adder, $2, $3->self_scm ());
1579                 scm_gc_unprotect_object ($3->self_scm ());
1580         }
1581         ;
1582
1583 command_element:
1584         command_req {
1585                 $$ = MY_MAKE_MUSIC ("EventChord");
1586                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1587                 scm_gc_unprotect_object ($1->self_scm ());
1588
1589                 $$-> set_spot (THIS->here_input ());
1590                 $1-> set_spot (THIS->here_input ());
1591         }
1592         | SKIP duration_length {
1593                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1594                 skip->set_property ("duration", $2);
1595
1596                 $$ = skip;
1597         }
1598         | QUOTE STRING duration_length {
1599                 Music *quote = MY_MAKE_MUSIC ("QuoteMusic");
1600                 quote->set_property ("duration", $3);
1601                 quote->set_property ("quoted-music-name", $2);
1602                 quote->set_spot (THIS->here_input ());
1603
1604                 $$ = quote;
1605         }
1606         | OCTAVE { THIS->push_spot (); }
1607           pitch {
1608                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1609                 $$ = m;
1610                 $$->set_spot (THIS->pop_spot ());
1611                 $$->set_property ("pitch", $3);
1612         }
1613         | E_LEFTSQUARE {
1614                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1615                 m->set_property ("span-direction", scm_int2num (START));
1616                 m->set_spot (THIS->here_input ());
1617
1618                 $$ = MY_MAKE_MUSIC ("EventChord");
1619                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1620                 scm_gc_unprotect_object (m->self_scm ());
1621                 $$->set_spot (THIS->here_input ());
1622         }
1623         | E_RIGHTSQUARE {
1624                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1625                 m->set_property ("span-direction", scm_int2num (STOP));
1626                 m->set_spot (THIS->here_input ());
1627
1628                 $$ = MY_MAKE_MUSIC ("EventChord");
1629                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1630                 $$->set_spot (THIS->here_input ());
1631                 scm_gc_unprotect_object (m->self_scm ());
1632         }
1633         | E_BACKSLASH {
1634                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1635                 $$->set_spot (THIS->here_input ());
1636         }
1637         | '|'      {
1638                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1639
1640                 if (Music * m = unsmob_music (pipe))
1641                         $$ = m->clone ();
1642                 else
1643                         $$ = MY_MAKE_MUSIC ("BarCheck");
1644
1645                 $$->set_spot (THIS->here_input ());
1646         }
1647         | TRANSPOSITION pitch {
1648                 Pitch middle_c;
1649                 Pitch sounds_as_c = pitch_interval (*unsmob_pitch ($2), middle_c);
1650                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1651                                          sounds_as_c.smobbed_copy());
1652                 $$->set_spot (THIS-> here_input ());
1653                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1654                         $$, SCM_EOL);
1655         }
1656         | BAR STRING                    {
1657                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1658
1659                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1660                                         t, SCM_EOL);
1661                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1662                 $$->set_spot (THIS->here_input ());
1663                 t->set_spot (THIS->here_input ());
1664         }
1665         | PARTIAL duration_length       {
1666                 Moment m = - unsmob_duration ($2)->get_length ();
1667                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1668                 p->set_spot (THIS->here_input ());
1669                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1670                                         p, SCM_EOL);
1671                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1672                                         p, SCM_EOL);
1673                 $$ = p;
1674         }
1675         | CLEF STRING  {
1676                 SCM proc = ly_scheme_function ("make-clef-set");
1677
1678                 SCM result = scm_call_1 (proc, $2);
1679                 scm_gc_protect_object (result);
1680                 $$ = unsmob_music (result);
1681         }
1682         | TIME_T fraction  {
1683                 SCM proc= ly_scheme_function ("make-time-signature-set");
1684
1685                 SCM result = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1686                 scm_gc_protect_object (result);
1687                 $$ = unsmob_music (result);
1688         }
1689         | MARK scalar {
1690                 SCM proc = ly_scheme_function ("make-mark-set");
1691
1692                 SCM result = scm_call_1 (proc, $2);
1693                 scm_gc_protect_object (result);
1694                 $$ = unsmob_music (result);
1695         }
1696         ;
1697
1698 command_req:
1699         E_TILDE {
1700                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1701         }
1702         | MARK DEFAULT  {
1703                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1704                 $$ = m;
1705         }
1706         | tempo_event {
1707                 $$ = $1;
1708         }
1709         | KEY DEFAULT {
1710                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1711                 $$ = key;
1712         }
1713         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1714
1715                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1716                 if (scm_ilength ($3) > 0)
1717                 {
1718                         key->set_property ("pitch-alist", $3);
1719                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1720                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1721                 } else {
1722                         THIS->parser_error (_ ("Second argument must be pitch list."));
1723                 }
1724
1725                 $$ = key;
1726         }
1727         ;
1728
1729 post_events:
1730         /* empty */ {
1731                 $$ = SCM_EOL;
1732         }
1733         | post_events post_event {
1734                 $2->set_spot (THIS->here_input ());
1735                 $$ = scm_cons ($2->self_scm (), $$);
1736                 scm_gc_unprotect_object ($2->self_scm ());
1737         }
1738         | post_events tagged_post_event {
1739                 $2 -> set_spot (THIS->here_input ());
1740                 $$ = scm_cons ($2->self_scm (), $$);
1741                 scm_gc_unprotect_object ($2->self_scm ());
1742         }
1743         ;
1744
1745
1746 tagged_post_event:
1747         '-' TAG embedded_scm post_event {
1748                 tag_music ($4, $3, THIS->here_input ());
1749                 $$ = $4;
1750         }
1751         ;
1752
1753 post_event:
1754         direction_less_event {
1755                 $$ = $1;
1756         }
1757         | HYPHEN {
1758                 if (!THIS->lexer_->is_lyric_state ())
1759                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1760                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1761         }
1762         | EXTENDER {
1763                 if (!THIS->lexer_->is_lyric_state ())
1764                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1765                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1766         }
1767         | script_dir direction_reqd_event {
1768                 if ($1)
1769                         $2->set_property ("direction", scm_int2num ($1));
1770                 $$ = $2;
1771         }
1772         | script_dir direction_less_event {
1773                 if ($1)
1774                         $2->set_property ("direction", scm_int2num ($1));
1775                 $$ = $2;
1776         }
1777         | string_number_event
1778         ;
1779
1780 string_number_event:
1781         E_UNSIGNED {
1782                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1783                 s->set_property ("string-number", scm_int2num ($1));
1784                 s->set_spot (THIS->here_input ());
1785                 $$ = s;
1786         }
1787         ;
1788
1789 direction_less_char:
1790         '['  {
1791                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1792         }
1793         | ']'  {
1794                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1795         }
1796         | '~'  {
1797                 $$ = ly_symbol2scm ("tildeSymbol");
1798         }
1799         | '('  {
1800                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1801         }
1802         | ')'  {
1803                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1804         }
1805         | E_EXCLAMATION  {
1806                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1807         }
1808         | E_OPEN  {
1809                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1810         }
1811         | E_CLOSE  {
1812                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1813         }
1814         | E_BIGGER  {
1815                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1816         }
1817         | E_SMALLER  {
1818                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1819         }
1820         ;
1821
1822 direction_less_event:
1823         direction_less_char {
1824                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1825                 Music * m = 0;
1826                 if (unsmob_music (predefd))
1827                 {
1828                         m = unsmob_music (predefd)->clone ();
1829                 }
1830                 else
1831                 {
1832                         m = MY_MAKE_MUSIC ("Music");
1833                 }
1834                 m->set_spot (THIS->here_input ());
1835                 $$ = m;
1836         }
1837         | EVENT_IDENTIFIER      {
1838                 $$ = unsmob_music ($1);
1839         }
1840         | tremolo_type  {
1841                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1842                a->set_spot (THIS->here_input ());
1843                a->set_property ("tremolo-type", scm_int2num ($1));
1844                $$ = a;
1845         }
1846         ;
1847
1848 direction_reqd_event:
1849         gen_text_def {
1850                 $$ = $1;
1851         }
1852         | script_abbreviation {
1853                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1854                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1855                 if (scm_is_string (s))
1856                         a->set_property ("articulation-type", s);
1857                 else THIS->parser_error (_ ("Expecting string as script definition"));
1858                 $$ = a;
1859         }
1860         ;
1861
1862 octave_check:
1863         /**/ { $$ = SCM_EOL; }
1864         | '='  { $$ = scm_int2num (0); }
1865         | '=' sub_quotes { $$ = scm_int2num ($2); }
1866         | '=' sup_quotes { $$ = scm_int2num ($2); }
1867         ;
1868
1869 sup_quotes:
1870         '\'' {
1871                 $$ = 1;
1872         }
1873         | sup_quotes '\'' {
1874                 $$ ++;
1875         }
1876         ;
1877
1878 sub_quotes:
1879         ',' {
1880                 $$ = 1;
1881         }
1882         | sub_quotes ',' {
1883                 $$++;
1884         }
1885         ;
1886
1887 steno_pitch:
1888         NOTENAME_PITCH  {
1889                 $$ = $1;
1890         }
1891         | NOTENAME_PITCH sup_quotes     {
1892                 Pitch p = *unsmob_pitch ($1);
1893                 p = p.transposed (Pitch ($2,0,0));
1894                 $$ = p.smobbed_copy ();
1895         }
1896         | NOTENAME_PITCH sub_quotes      {
1897                 Pitch p =* unsmob_pitch ($1);
1898                 p = p.transposed (Pitch (-$2,0,0));
1899                 $$ = p.smobbed_copy ();
1900         }
1901         ;
1902
1903 /*
1904 ugh. duplication
1905 */
1906
1907 steno_tonic_pitch:
1908         TONICNAME_PITCH {
1909                 $$ = $1;
1910         }
1911         | TONICNAME_PITCH sup_quotes    {
1912                 Pitch p = *unsmob_pitch ($1);
1913                 p = p.transposed (Pitch ($2,0,0));
1914                 $$ = p.smobbed_copy ();
1915         }
1916         | TONICNAME_PITCH sub_quotes     {
1917                 Pitch p =* unsmob_pitch ($1);
1918
1919                 p = p.transposed (Pitch (-$2,0,0));
1920                 $$ = p.smobbed_copy ();
1921         }
1922         ;
1923
1924 pitch:
1925         steno_pitch {
1926                 $$ = $1;
1927         }
1928         ;
1929
1930 pitch_also_in_chords:
1931         pitch
1932         | steno_tonic_pitch
1933         ;
1934
1935 gen_text_def:
1936         full_markup {
1937                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1938                 t->set_property ("text", $1);
1939                 t->set_spot (THIS->here_input ());
1940                 $$ = t;
1941         }
1942         | string {
1943                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1944                 t->set_property ("text",
1945                         make_simple_markup (THIS->lexer_->encoding (), $1));
1946                 t->set_spot (THIS->here_input ());
1947                 $$ = t;
1948
1949         }
1950         | DIGIT {
1951                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1952                 t->set_property ("digit", scm_int2num ($1));
1953                 t->set_spot (THIS->here_input ());
1954                 $$ = t;
1955         }
1956         ;
1957
1958 script_abbreviation:
1959         '^'             {
1960                 $$ = scm_makfrom0str ("Hat");
1961         }
1962         | '+'           {
1963                 $$ = scm_makfrom0str ("Plus");
1964         }
1965         | '-'           {
1966                 $$ = scm_makfrom0str ("Dash");
1967         }
1968         | '|'           {
1969                 $$ = scm_makfrom0str ("Bar");
1970         }
1971         | '>'           {
1972                 $$ = scm_makfrom0str ("Larger");
1973         }
1974         | '.'           {
1975                 $$ = scm_makfrom0str ("Dot");
1976         }
1977         | '_' {
1978                 $$ = scm_makfrom0str ("Underscore");
1979         }
1980         ;
1981
1982 script_dir:
1983         '_'     { $$ = DOWN; }
1984         | '^'   { $$ = UP; }
1985         | '-'   { $$ = CENTER; }
1986         ;
1987
1988
1989 absolute_pitch:
1990         steno_pitch     {
1991                 $$ = $1;
1992         }
1993         ;
1994
1995 duration_length:
1996         multiplied_duration {
1997                 $$ = $1;
1998         }
1999         ;
2000
2001 optional_notemode_duration:
2002         {
2003                 Duration dd = THIS->default_duration_;
2004                 $$ = dd.smobbed_copy ();
2005
2006                 THIS->beam_check ($$);
2007         }
2008         | multiplied_duration   {
2009                 $$ = $1;
2010                 THIS->default_duration_ = *unsmob_duration ($$);
2011
2012                 THIS->beam_check ($$);
2013         }
2014         ;
2015
2016 steno_duration:
2017         bare_unsigned dots              {
2018                 int len = 0;
2019                 if (!is_duration ($1))
2020                         THIS->parser_error (_f ("not a duration: %d", $1));
2021                 else
2022                         len = intlog2 ($1);
2023
2024                 $$ = Duration (len, $2).smobbed_copy ();
2025         }
2026         | DURATION_IDENTIFIER dots      {
2027                 Duration *d = unsmob_duration ($1);
2028                 Duration k (d->duration_log (), d->dot_count () + $2);
2029                 *d = k;
2030                 $$ = $1;
2031         }
2032         ;
2033
2034 multiplied_duration:
2035         steno_duration {
2036                 $$ = $1;
2037         }
2038         | multiplied_duration '*' bare_unsigned {
2039                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2040         }
2041         | multiplied_duration '*' FRACTION {
2042                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2043
2044                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2045         }
2046         ;
2047
2048 fraction:
2049         FRACTION { $$ = $1; }
2050         | UNSIGNED '/' UNSIGNED {
2051                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2052         }
2053         ;
2054
2055 dots:
2056         /* empty */     {
2057                 $$ = 0;
2058         }
2059         | dots '.' {
2060                 $$ ++;
2061         }
2062         ;
2063
2064 tremolo_type:
2065         ':'     {
2066                 $$ = 0;
2067         }
2068         | ':' bare_unsigned {
2069                 if (!is_duration ($2))
2070                         THIS->parser_error (_f ("not a duration: %d", $2));
2071                 $$ = $2;
2072         }
2073         ;
2074
2075 bass_number:
2076         DIGIT   {
2077                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2078                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2079                                 $$);
2080         }
2081         | UNSIGNED {
2082                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2083                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2084                                 $$);
2085         }
2086         | STRING { $$ = $1; }
2087         ;
2088
2089 bass_mod:
2090         '-'     { $$ = -2; }
2091         | '+'   { $$ = 2; }
2092         | '!'   { $$ = 0; }
2093         ;
2094
2095 bass_figure:
2096         FIGURE_SPACE {
2097                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2098                 $$ = bfr->self_scm ();
2099                 scm_gc_unprotect_object ($$);
2100         }
2101         | bass_number  {
2102                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2103                 $$ = bfr->self_scm ();
2104
2105                 bfr->set_property ("figure", $1);
2106
2107                 scm_gc_unprotect_object ($$);
2108         }
2109         | bass_figure bass_mod {
2110                 Music *m = unsmob_music ($1);
2111                 if ($2) {
2112                         SCM salter = m->get_property ("alteration");
2113                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2114                         m->set_property ("alteration",
2115                                 scm_int2num (alter + $2));
2116                 } else {
2117                         m->set_property ("alteration", scm_int2num (0));
2118                 }
2119         }
2120         ;
2121
2122 br_bass_figure:
2123         '[' bass_figure {
2124                 $$ = $2;
2125                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2126         }
2127         | bass_figure   {
2128                 $$ = $1;
2129         }
2130         | br_bass_figure ']' {
2131                 $$ = $1;
2132                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2133         }
2134         ;
2135
2136 figure_list:
2137         /**/            {
2138                 $$ = SCM_EOL;
2139         }
2140         | figure_list br_bass_figure {
2141                 $$ = scm_cons ($2, $1);
2142         }
2143         ;
2144
2145 figure_spec:
2146         FIGURE_OPEN figure_list FIGURE_CLOSE {
2147                 Music *m = MY_MAKE_MUSIC ("EventChord");
2148                 $2 = scm_reverse_x ($2, SCM_EOL);
2149                 m->set_property ("elements", $2);
2150                 $$ = m->self_scm ();
2151         }
2152         ;
2153
2154
2155 optional_rest:
2156         /**/   { $$ = 0; }
2157         | REST { $$ = 1; }
2158         ;
2159
2160 simple_element:
2161         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2162
2163                 Input i = THIS->pop_spot ();
2164                 if (!THIS->lexer_->is_note_state ())
2165                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2166
2167                 Music *n = 0;
2168                 if ($6)
2169                         n = MY_MAKE_MUSIC ("RestEvent");
2170                 else
2171                         n = MY_MAKE_MUSIC ("NoteEvent");
2172
2173                 n->set_property ("pitch", $1);
2174                 n->set_property ("duration", $5);
2175
2176                 if (scm_is_number ($4))
2177                 {
2178                         int q = scm_to_int ($4);
2179                         n->set_property ("absolute-octave", scm_int2num (q-1));
2180                 }
2181
2182                 if ($3 % 2)
2183                         n->set_property ("cautionary", SCM_BOOL_T);
2184                 if ($2 % 2 || $3 % 2)
2185                         n->set_property ("force-accidental", SCM_BOOL_T);
2186
2187                 Music *v = MY_MAKE_MUSIC ("EventChord");
2188                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2189                 scm_gc_unprotect_object (n->self_scm ());
2190
2191                 v->set_spot (i);
2192                 n->set_spot (i);
2193                 $$ = v;
2194         }
2195         | DRUM_PITCH optional_notemode_duration {
2196                 Input i = THIS->pop_spot ();
2197
2198                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2199                 n->set_property ("duration", $2);
2200                 n->set_property ("drum-type", $1);
2201
2202                 Music *v = MY_MAKE_MUSIC ("EventChord");
2203                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2204                 scm_gc_unprotect_object (n->self_scm ());
2205                 v->set_spot (i);
2206                 n->set_spot (i);
2207                 $$ = v;
2208
2209         }
2210         | figure_spec optional_notemode_duration {
2211                 Music *m = unsmob_music ($1);
2212                 Input i = THIS->pop_spot ();
2213                 m->set_spot (i);
2214                 for (SCM s = m->get_property ("elements"); scm_is_pair (s); s = scm_cdr (s))
2215                 {
2216                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2217                 }
2218                 $$ = m;
2219         }
2220         | RESTNAME optional_notemode_duration           {
2221
2222                 Input i = THIS->pop_spot ();
2223                 Music *ev = 0;
2224                 if (ly_scm2string ($1) == "s") {
2225                         /* Space */
2226                         ev = MY_MAKE_MUSIC ("SkipEvent");
2227                   }
2228                 else {
2229                         ev = MY_MAKE_MUSIC ("RestEvent");
2230
2231                     }
2232                 ev->set_property ("duration", $2);
2233                 ev->set_spot (i);
2234                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2235                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2236                 velt->set_spot (i);
2237
2238                 scm_gc_unprotect_object (ev->self_scm ());
2239
2240                 $$ = velt;
2241         }
2242         | MULTI_MEASURE_REST optional_notemode_duration         {
2243                 THIS->pop_spot ();
2244
2245                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2246                 SCM mus = scm_call_2 (proc, $2,
2247                         make_input (THIS->here_input ()));
2248                 scm_gc_protect_object (mus);
2249                 $$ = unsmob_music (mus);
2250         }
2251
2252         | lyric_element optional_notemode_duration      {
2253                 Input i = THIS->pop_spot ();
2254                 if (!THIS->lexer_->is_lyric_state ())
2255                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2256
2257                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2258                 lreq->set_property ("text", $1);
2259                 lreq->set_property ("duration",$2);
2260                 lreq->set_spot (i);
2261                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2262                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2263
2264                 $$= velt;
2265         }
2266         | new_chord {
2267                 THIS->pop_spot ();
2268
2269                 if (!THIS->lexer_->is_chord_state ())
2270                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2271                 $$ = unsmob_music ($1);
2272         }
2273         ;
2274
2275 lyric_element:
2276         /* FIXME: lyric flavoured markup would be better */
2277         full_markup {
2278                 $$ = $1;
2279         }
2280         | LYRICS_STRING {
2281                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2282         }
2283         ;
2284
2285 new_chord:
2286         steno_tonic_pitch optional_notemode_duration   {
2287                 $$ = make_chord ($1, $2, SCM_EOL);
2288         }
2289         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2290                 SCM its = scm_reverse_x ($4, SCM_EOL);
2291                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2292         }
2293         ;
2294
2295 chord_items:
2296         /**/ {
2297                 $$ = SCM_EOL;
2298         }
2299         | chord_items chord_item {
2300                 $$ = scm_cons ($2, $$);
2301         }
2302         ;
2303
2304 chord_separator:
2305         CHORD_COLON {
2306                 $$ = ly_symbol2scm ("chord-colon");
2307         }
2308         | CHORD_CARET {
2309                 $$ = ly_symbol2scm ("chord-caret");
2310         }
2311         | CHORD_SLASH steno_tonic_pitch {
2312                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2313         }
2314         | CHORD_BASS steno_tonic_pitch {
2315                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2316         }
2317         ;
2318
2319 chord_item:
2320         chord_separator {
2321                 $$ = $1;
2322         }
2323         | step_numbers {
2324                 $$ = scm_reverse_x ($1, SCM_EOL);
2325         }
2326         | CHORD_MODIFIER  {
2327                 $$ = $1;
2328         }
2329         ;
2330
2331 step_numbers:
2332         step_number { $$ = scm_cons ($1, SCM_EOL); }
2333         | step_numbers '.' step_number {
2334                 $$ = scm_cons ($3, $$);
2335         }
2336         ;
2337
2338 step_number:
2339         bare_unsigned {
2340                 $$ = make_chord_step ($1, 0);
2341         }
2342         | bare_unsigned '+' {
2343                 $$ = make_chord_step ($1, SHARP);
2344         }
2345         | bare_unsigned CHORD_MINUS {
2346                 $$ = make_chord_step ($1, FLAT);
2347         }
2348         ;
2349
2350 /*
2351         UTILITIES
2352
2353 TODO: should deprecate in favor of Scheme?
2354
2355  */
2356 number_expression:
2357         number_expression '+' number_term {
2358                 $$ = scm_sum ($1, $3);
2359         }
2360         | number_expression '-' number_term {
2361                 $$ = scm_difference ($1, $3);
2362         }
2363         | number_term
2364         ;
2365
2366 number_term:
2367         number_factor {
2368                 $$ = $1;
2369         }
2370         | number_factor '*' number_factor {
2371                 $$ = scm_product ($1, $3);
2372         }
2373         | number_factor '/' number_factor {
2374                 $$ = scm_divide ($1, $3);
2375         }
2376         ;
2377
2378 number_factor:
2379         '-'  number_factor { /* %prec UNARY_MINUS */
2380                 $$ = scm_difference ($2, SCM_UNDEFINED);
2381         }
2382         | bare_number
2383         ;
2384
2385
2386 bare_number:
2387         UNSIGNED        {
2388                 $$ = scm_int2num ($1);
2389         }
2390         | REAL          {
2391                 $$ = $1;
2392         }
2393         | NUMBER_IDENTIFIER             {
2394                 $$ = $1;
2395         }
2396         | REAL NUMBER_IDENTIFIER        {
2397                 $$ = scm_make_real (scm_to_double ($1) *scm_to_double ($2));
2398         }
2399         | UNSIGNED NUMBER_IDENTIFIER    {
2400                 $$ = scm_make_real ($1 *scm_to_double ($2));
2401         }
2402         ;
2403
2404
2405 bare_unsigned:
2406         UNSIGNED {
2407                         $$ = $1;
2408         }
2409         | DIGIT {
2410                 $$ = $1;
2411         }
2412         ;
2413
2414 bare_int:
2415         bare_number {
2416                 if (scm_integer_p ($1) == SCM_BOOL_T)
2417                 {
2418                         int k = scm_to_int ($1);
2419                         $$ = k;
2420                 } else
2421                 {
2422                         THIS->parser_error (_ ("need integer number arg"));
2423                         $$ = 0;
2424                 }
2425         }
2426         | '-' bare_int {
2427                 $$ = -$2;
2428         }
2429         ;
2430
2431 exclamations:
2432                 { $$ = 0; }
2433         | exclamations '!'      { $$ ++; }
2434         ;
2435
2436 questions:
2437                 { $$ = 0; }
2438         | questions '?' { $$ ++; }
2439         ;
2440
2441
2442
2443 full_markup:
2444         MARKUP_IDENTIFIER {
2445                 $$ = $1;
2446         }
2447         | MARKUP
2448                 { THIS->lexer_->push_markup_state (); }
2449         markup
2450                 { $$ = $3;
2451                   THIS->lexer_->pop_state ();
2452                 }
2453         ;
2454
2455
2456 /*
2457 This should be done more dynamically if possible.
2458 */
2459 markup:
2460         STRING {
2461                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2462         }
2463         | MARKUP_HEAD_EMPTY {
2464                 $$ = scm_list_1 ($1);
2465         }
2466         | MARKUP_HEAD_MARKUP0 markup {
2467                 $$ = scm_list_2 ($1, $2);
2468         }
2469         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2470                 $$ = scm_list_3 ($1, $2, $3);
2471         }
2472         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2473                 $$ = scm_list_3 ($1, $2, $3);
2474         }
2475         | markup_line {
2476                 $$ = $1;
2477         }
2478         | MARKUP_HEAD_LIST0 markup_list {
2479                 $$ = scm_list_2 ($1,$2);
2480         }
2481         | MARKUP_HEAD_SCM0 embedded_scm {
2482                 $$ = scm_list_2 ($1, $2);
2483         }
2484         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2485                 $$ = scm_list_4 ($1, $2, $3, $4);
2486         }
2487         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2488                 $$ = scm_list_4 ($1, $2, $3, $4);
2489         }
2490         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2491                 $$ = scm_list_3 ($1, $2, $3);
2492         }
2493         | MARKUP_IDENTIFIER {
2494                 $$ = $1;
2495         }
2496         | STRING_IDENTIFIER {
2497                 $$ = $1;
2498         }
2499         | SCORE {
2500                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2501                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2502         } '{' score_body '}' {
2503                 Score * sc = $4;
2504                 $$ = scm_list_2 (ly_scheme_function ("score-markup"), sc->self_scm ());
2505                 scm_gc_unprotect_object (sc->self_scm ());
2506                 THIS->lexer_->pop_state ();
2507         }
2508         ;
2509
2510 markup_list:
2511         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2512         ;
2513
2514 markup_line:
2515         '{' markup_list_body '}' {
2516                 SCM line = ly_scheme_function ("line-markup");
2517
2518                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2519         }
2520         ;
2521
2522 markup_list_body:
2523         /**/ {  $$ = SCM_EOL; }
2524         | markup_list_body markup {
2525                 $$ = scm_cons ($2, $1);
2526         }
2527         ;
2528
2529
2530 %%
2531
2532 void
2533 Lily_parser::set_yydebug (bool )
2534 {
2535 #if 0
2536         yydebug = 1;
2537 #endif
2538 }
2539
2540 void
2541 Lily_parser::do_yyparse ()
2542 {
2543         yyparse ((void*)this);
2544 }
2545
2546
2547 /*
2548 Should make this optional?    It will also complain when you do
2549
2550         [s4]
2551
2552 which is entirely legitimate.
2553
2554 Or we can scrap it. Barchecks should detect wrong durations, and
2555 skipTypesetting speeds it up a lot.
2556 */
2557
2558 void
2559 Lily_parser::beam_check (SCM dur)
2560 {
2561   Duration *d = unsmob_duration (dur);
2562   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2563     {
2564       Music *m = unsmob_music (last_beam_start_);
2565       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2566     }
2567   last_beam_start_ = SCM_EOL;
2568 }
2569
2570
2571
2572
2573 /*
2574
2575 It is a little strange to have this function in this file, but
2576 otherwise, we have to import music classes into the lexer.
2577
2578 */
2579 int
2580 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2581 {
2582         if (scm_is_string (sid)) {
2583                 *destination = sid;
2584                 return STRING_IDENTIFIER;
2585         } else if (scm_is_number (sid)) {
2586                 *destination = sid;
2587                 return NUMBER_IDENTIFIER;
2588         } else if (unsmob_context_def (sid)) {
2589                 *destination = unsmob_context_def (sid)->clone_scm ();
2590                 return CONTEXT_DEF_IDENTIFIER;
2591         } else if (unsmob_score (sid)) {
2592                 Score *score = new Score (*unsmob_score (sid));
2593                 *destination = score->self_scm ();
2594                 return SCORE_IDENTIFIER;
2595         } else if (Music *mus = unsmob_music (sid)) {
2596                 mus = mus->clone ();
2597                 *destination = mus->self_scm ();
2598                 unsmob_music (*destination)->
2599                         set_property ("origin", make_input (last_input_));
2600                 return dynamic_cast<Event*> (mus)
2601                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2602         } else if (unsmob_duration (sid)) {
2603                 *destination = unsmob_duration (sid)->smobbed_copy ();
2604                 return DURATION_IDENTIFIER;
2605         } else if (unsmob_output_def (sid)) {
2606                 Output_def *p = unsmob_output_def (sid);
2607                 p = p->clone ();
2608
2609                 *destination = p->self_scm ();
2610                 return OUTPUT_DEF_IDENTIFIER;
2611         } else if (Text_interface::markup_p (sid)) {
2612                 *destination = sid;
2613                 return MARKUP_IDENTIFIER;
2614         }
2615
2616         return -1;
2617 }
2618
2619 Music *
2620 property_op_to_music (SCM op)
2621 {
2622         Music *m = 0;
2623         SCM tag = scm_car (op);
2624         SCM symbol = scm_cadr (op);
2625         SCM args = scm_cddr (op);
2626         SCM grob_val = SCM_UNDEFINED;
2627         SCM grob_sym = SCM_UNDEFINED;
2628         SCM val = SCM_UNDEFINED;
2629
2630         if (tag == ly_symbol2scm ("assign"))
2631                 {
2632                 m = MY_MAKE_MUSIC ("PropertySet");
2633                 val = scm_car (args);
2634                 }
2635         else if (tag == ly_symbol2scm ("unset"))
2636                 m = MY_MAKE_MUSIC ("PropertyUnset");
2637         else if (tag == ly_symbol2scm ("poppush")
2638                  || tag == ly_symbol2scm ("push"))
2639                 {
2640                 m = MY_MAKE_MUSIC ("OverrideProperty");
2641                 grob_sym = scm_car (args);
2642                 grob_val = scm_cadr (args);
2643                 }
2644         else if (tag == ly_symbol2scm ("pop")) {
2645                 m = MY_MAKE_MUSIC ("RevertProperty");
2646                 grob_sym = scm_car (args);
2647                 }
2648
2649         m->set_property ("symbol", symbol);
2650
2651         if (val != SCM_UNDEFINED)
2652                 m->set_property ("value", val);
2653         if (grob_val != SCM_UNDEFINED)
2654                 m->set_property ("grob-value", grob_val);
2655
2656         if (grob_sym != SCM_UNDEFINED)
2657                 {
2658                 bool itc = internal_type_checking_global_b;
2659                 /* UGH.
2660                 */
2661                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2662                 if (autobeam)
2663                         internal_type_checking_global_b = false;
2664                 m->set_property ("grob-property", grob_sym);
2665                 if (autobeam)
2666                         internal_type_checking_global_b = itc;
2667                 }
2668
2669         if (tag == ly_symbol2scm ("poppush"))
2670                 m->set_property ("pop-first", SCM_BOOL_T);
2671
2672
2673         return m;
2674 }
2675
2676 Music*
2677 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2678 {
2679         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2680
2681         csm->set_property ("element", m->self_scm ());
2682         scm_gc_unprotect_object (m->self_scm ());
2683
2684         csm->set_property ("context-type",
2685                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2686         csm->set_property ("property-operations", ops);
2687
2688         if (scm_is_string (id))
2689                 csm->set_property ("context-id", id);
2690         return csm;
2691 }
2692
2693 /*
2694 FIXME: this should be postponed until the music hits \Score
2695 */
2696 SCM
2697 get_next_unique_context ()
2698 {
2699         static int new_context_count;
2700         char s[1024];
2701         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2702         return scm_makfrom0str (s);
2703 }
2704