lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2000 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 #include <iostream.h>
  13 #include "translator-def.hh"
  14 #include "lily-guile.hh"
  15 #include "change-iterator.hh"
  16 #include "misc.hh"
  17 #include "my-lily-lexer.hh"
  18 #include "paper-def.hh"
  19 #include "midi-def.hh"
  20 #include "main.hh"
  21 #include "file-path.hh"
  22 #include "debug.hh"
  23 #include "dimensions.hh"
  24 #include "identifier.hh"
  25 #include "command-request.hh"
  26 #include "musical-request.hh"
  27 #include "my-lily-parser.hh"
  28 #include "context-specced-music.hh"
  29 #include "score.hh"
  30 #include "music-list.hh"
  31 #include "output-property-music-iterator.hh"
  32 #include "property-iterator.hh"
  33 #include "file-results.hh"
  34 #include "input.hh"
  35 #include "scope.hh"
  36 #include "relative-music.hh"
  37 #include "lyric-combine-music.hh"
  38 #include "transposed-music.hh"
  39 #include "time-scaled-music.hh"
  40 #include "repeated-music.hh"
  41 #include "lilypond-input-version.hh"
  42 #include "grace-music.hh"
  43 #include "auto-change-music.hh"
  44 #include "part-combine-music.hh"
  45
  46 #include "chord.hh"
  47
  48 bool
  49 is_duration_b (int t)
  50 {
  51   return t && t == 1 << intlog2(t);
  52 }
  53
  54
  55 void
  56 set_music_properties (Music *p, SCM a)
  57 {
  58   for (SCM k = a; gh_pair_p (k); k = gh_cdr (k))
  59         {
  60         p->set_mus_property (gh_caar (k), gh_cdar (k));
  61         }
  62 }
  63
  64
  65 // mmm JUNKME ?
  66 Lilypond_version oldest_version ("1.3.59");
  67
  68 void
  69 print_lilypond_versions (ostream &os)
  70 {
  71   os << _f ("Oldest supported input version: %s", oldest_version.str ())
  72     << endl;
  73 }
  74
  75
  76 // needed for bison.simple's malloc() and free()
  77 #include <malloc.h>
  78
  79 #ifndef NDEBUG
  80 #define YYDEBUG 1
  81 #endif
  82
  83 #define YYERROR_VERBOSE 1
  84
  85 #define YYPARSE_PARAM my_lily_parser_l
  86 #define YYLEX_PARAM my_lily_parser_l
  87 #define THIS ((My_lily_parser *) my_lily_parser_l)
  88
  89 #define yyerror THIS->parser_error
  90 #define ARRAY_SIZE(a,s)   if (a.size () != s) THIS->parser_error (_f ("Expecting %d arguments", s))
  91
  92 %}
  93
  94
  95 %union {
  96
  97     Link_array<Request> *reqvec;
  98     Identifier *id;
  99     String * string;
 100     Music *music;
 101     Score *score;
 102     Scope *scope;
 103
 104     Musical_req* musreq;
 105     Music_output_def * outputdef;
 106
 107     Midi_def* midi;
 108     Real real;
 109     Request * request;
 110
 111     /* We use SCMs to do strings, because it saves us the trouble of
 112 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 113 of the parse stack onto the heap. */
 114
 115     SCM scm;
 116
 117     Tempo_req *tempo;
 118     int i;
 119 }
 120 %{
 121
 122 int
 123 yylex (YYSTYPE *s,  void * v_l)
 124 {
 125         My_lily_parser   *pars_l = (My_lily_parser*) v_l;
 126         My_lily_lexer * lex_l = pars_l->lexer_p_;
 127
 128         lex_l->lexval_l = (void*) s;
 129         return lex_l->yylex ();
 130 }
 131
 132
 133 %}
 134
 135 %pure_parser
 136
 137 /* tokens which are not keywords */
 138 %token AUTOCHANGE
 139 %token APPLY
 140 %token ARPEGGIO
 141 %token DYNAMICSCRIPT
 142 %token TEXTSCRIPT
 143 %token ACCEPTS
 144 %token ALTERNATIVE
 145 %token BAR
 146 %token BREATHE
 147 %token CHORDMODIFIERS
 148 %token CHORDS
 149 %token CHAR_T
 150 %token CLEF
 151 %token CM_T
 152 %token CONSISTS
 153 %token DURATION
 154 %token SEQUENTIAL
 155 %token ELEMENTDESCRIPTIONS
 156 %token SIMULTANEOUS
 157 %token CONSISTSEND
 158 %token DENIES
 159 %token DURATION
 160 %token EXTENDER
 161 %token FONT
 162 %token GRACE
 163 %token HEADER
 164 %token HYPHEN
 165 %token IN_T
 166 %token INVALID
 167 %token KEY
 168 %token LYRICS
 169 %token MARK
 170 %token MEASURES
 171 %token MIDI
 172 %token MM_T
 173 %token MUSICAL_PITCH
 174 %token NAME
 175 %token NOTENAMES
 176 %token NOTES
 177 %token PAPER
 178 %token PARTIAL
 179 %token PENALTY
 180 %token PROPERTY
 181 %token PUSH POP
 182 %token PT_T
 183 %token RELATIVE
 184 %token REMOVE
 185 %token REPEAT
 186 %token ADDLYRICS
 187 %token PARTCOMBINE
 188 %token SCM_T
 189 %token SCORE
 190 %token SCRIPT
 191 %token SKIP
 192 %token SPANREQUEST
 193 %token STYLESHEET
 194 %token COMMANDSPANREQUEST
 195 %token TEMPO
 196 %token OUTPUTPROPERTY
 197 %token TIME_T
 198 %token TIMES
 199 %token TRANSLATOR
 200 %token TRANSPOSE
 201 %token TYPE
 202 %token CONTEXT
 203
 204 /* escaped */
 205 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER
 206 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET
 207
 208 %type <i>       exclamations questions dots
 209 %token <i>      DIGIT
 210 %token <scm>    NOTENAME_PITCH
 211 %token <scm>    TONICNAME_PITCH
 212 %token <scm>    CHORDMODIFIER_PITCH
 213 %token <scm>    DURATION_IDENTIFIER
 214 %token <id>     IDENTIFIER
 215
 216
 217 %token <id>     SCORE_IDENTIFIER
 218 %token <id>     MUSIC_OUTPUT_DEF_IDENTIFIER
 219
 220 %token <scm>    NUMBER_IDENTIFIER
 221 %token <scm>    REQUEST_IDENTIFIER
 222 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 223 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 224 %token <scm>    RESTNAME
 225 %token <scm>    STRING
 226 %token <scm>    SCM_T
 227 %token <i>      UNSIGNED
 228 %token <real>   REAL
 229
 230 %type <outputdef> output_def
 231 %type <scope>   lilypond_header lilypond_header_body
 232 %type <request> open_request_parens close_request_parens open_request close_request
 233 %type <request> request_with_dir request_that_take_dir verbose_request
 234 %type <i>       sub_quotes sup_quotes
 235 %type <music>   simple_element  request_chord command_element Simple_music  Composite_music
 236 %type <music>   Alternative_music Repeated_music
 237 %type <i>       tremolo_type
 238 %type <i>       bare_int  bare_unsigned
 239 %type <i>       script_dir
 240
 241 %type <scm>     identifier_init
 242
 243 %type <scm> steno_duration optional_notemode_duration
 244 %type <scm> entered_notemode_duration explicit_duration
 245
 246 %type <reqvec>  pre_requests post_requests
 247 %type <request> gen_text_def
 248 %type <scm>   steno_musical_pitch musical_pitch absolute_musical_pitch
 249 %type <scm>   steno_tonic_pitch
 250
 251 %type <scm>     chord_additions chord_subtractions chord_notes chord_step
 252 %type <music>   chord
 253 %type <scm>     chord_note chord_inversion chord_bass
 254 %type <scm>     duration_length
 255
 256 %type <scm>  embedded_scm scalar
 257 %type <music>   Music Sequential_music Simultaneous_music Music_sequence
 258 %type <music>   relative_music re_rhythmed_music part_combined_music
 259 %type <music>   property_def translator_change
 260 %type <scm> Music_list
 261 %type <outputdef>  music_output_def_body
 262 %type <request> shorthand_command_req
 263 %type <request> post_request
 264 %type <music> command_req verbose_command_req
 265 %type <request> extender_req
 266 %type <request> hyphen_req
 267 %type <scm>     string bare_number number_expression
 268 %type <score>   score_block score_body
 269
 270 %type <scm>     translator_spec_block translator_spec_body
 271 %type <tempo>   tempo_request
 272 %type <scm> notenames_body notenames_block chordmodifiers_block
 273 %type <scm>     script_abbreviation
 274
 275
 276
 277 %left '-' '+'
 278 %left '*' '/'
 279 %left UNARY_MINUS
 280
 281 %%
 282
 283 lilypond:       /* empty */
 284         | lilypond toplevel_expression {}
 285         | lilypond assignment  { }
 286         | lilypond error {
 287                 THIS->error_level_i_  = 1;
 288                 //THIS->parser_error (_ ("ly invalid"));
 289         }
 290         | lilypond INVALID      {
 291                 THIS->error_level_i_  = 1;
 292                 //THIS->parser_error (_ ("ly invalid"));
 293         }
 294         ;
 295
 296 toplevel_expression:
 297         notenames_block                 {
 298                 THIS->lexer_p_->pitchname_tab_ =  $1;
 299         }
 300         | chordmodifiers_block                  {
 301                 THIS->lexer_p_->chordmodifier_tab_  = $1;
 302         }
 303         | lilypond_header {
 304                 delete header_global_p;
 305                 header_global_p = $1;
 306         }
 307         | score_block {
 308                 score_global_array.push ($1);
 309         }
 310         | output_def {
 311                 Identifier * id = new
 312                         Music_output_def_identifier ($1, MUSIC_OUTPUT_DEF_IDENTIFIER);
 313                 if (dynamic_cast<Paper_def*> ($1))
 314                         THIS->lexer_p_->set_identifier ("$defaultpaper", id->self_scm ());
 315                 else if (dynamic_cast<Midi_def*> ($1))
 316                         THIS->lexer_p_->set_identifier ("$defaultmidi", id->self_scm ());
 317         }
 318         | embedded_scm {
 319                 // junk value
 320         }
 321         ;
 322
 323 embedded_scm:
 324         SCM_T
 325         | SCM_IDENTIFIER
 326         ;
 327
 328
 329 chordmodifiers_block:
 330         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 331         ;
 332
 333
 334 notenames_block:
 335         NOTENAMES notenames_body   {  $$ = $2; }
 336         ;
 337
 338
 339
 340 notenames_body:
 341         embedded_scm    {
 342           int i = scm_ilength ($1);
 343
 344           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 345           for (SCM s = $1; gh_pair_p (s); s = gh_cdr (s)) {
 346                 SCM pt = gh_cdar (s);
 347                 if (!unsmob_pitch (pt))
 348                         THIS->parser_error ("Need pitch object.");
 349                 else
 350                         scm_hashq_set_x (tab, gh_caar(s), pt);
 351           }
 352
 353           $$ = tab;
 354         }
 355         ;
 356
 357 lilypond_header_body:
 358         {
 359                 $$ = new Scope;
 360                 THIS->lexer_p_-> scope_l_arr_.push ($$);
 361         }
 362         | lilypond_header_body assignment semicolon {
 363
 364         }
 365         ;
 366
 367 lilypond_header:
 368         HEADER '{' lilypond_header_body '}'     {
 369                 $$ = $3;
 370                 THIS->lexer_p_-> scope_l_arr_.pop ();
 371         }
 372         ;
 373
 374
 375 /*
 376         DECLARATIONS
 377 */
 378 assignment:
 379         STRING {
 380                 THIS->remember_spot ();
 381         }
 382         /* cont */ '=' identifier_init  {
 383                 THIS->lexer_p_->set_identifier (ly_scm2string ($1), $4);
 384
 385 /*
 386  TODO: devise standard for protection in parser.
 387
 388   The parser stack lives on the C-stack, which means that
 389 all objects can be unprotected as soon as they're here.
 390
 391 */
 392                 Identifier * id =unsmob_identifier ($4);
 393                 Input spot = THIS->pop_spot ();
 394                 if (id) id->set_spot (spot);
 395         }
 396         ;
 397
 398
 399
 400 identifier_init:
 401         score_block {
 402                 $$ = (new Score_identifier ($1, SCORE_IDENTIFIER))->self_scm();
 403         }
 404         | output_def {
 405                 $$ = (new Music_output_def_identifier ($1, MUSIC_OUTPUT_DEF_IDENTIFIER))->self_scm();
 406         }
 407         | translator_spec_block {
 408                 $$ = $1;
 409         }
 410         | Music  {
 411                 $$ = $1->self_scm ();
 412                 scm_unprotect_object ($$);
 413         }
 414         | post_request {
 415                 $$ = $1->self_scm ();
 416                 scm_unprotect_object ($$);
 417         }
 418         | explicit_duration {
 419                 $$ = $1;
 420         }
 421         | number_expression {
 422                 $$ = $1;
 423         }
 424         | string {
 425                 $$ = $1;
 426         }
 427         | embedded_scm  {
 428                 $$ = $1;
 429         }
 430         ;
 431
 432 translator_spec_block:
 433         TRANSLATOR '{' translator_spec_body '}'
 434                 {
 435                 $$ = $3;
 436         }
 437         ;
 438
 439 translator_spec_body:
 440         TRANSLATOR_IDENTIFIER   {
 441                 $$ = unsmob_translator_def ($1)->clone_scm ();
 442                 unsmob_translator_def ($$)-> set_spot (THIS->here_input ());
 443         }
 444         | TYPE STRING semicolon {
 445                 $$ = Translator_def::make_scm ();
 446                 Translator_def*td =  unsmob_translator_def ($$);
 447                 td->translator_group_type_ = $2;
 448                 td->set_spot (THIS->here_input ());
 449         }
 450         | translator_spec_body STRING '=' embedded_scm                  {
 451                 unsmob_translator_def ($$)->add_property_assign ($2, $4);
 452         }
 453         | translator_spec_body STRING PUSH embedded_scm '=' embedded_scm {
 454                 unsmob_translator_def ($$)
 455                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 456         }
 457         | translator_spec_body STRING POP embedded_scm  {
 458           unsmob_translator_def($$)->add_pop_property (
 459                 scm_string_to_symbol ($2), $4);
 460         }
 461         | translator_spec_body STRING '=' identifier_init semicolon     {
 462                 SCM v = gh_int2scm (0);
 463                 if (gh_string_p ($4) || gh_number_p ($4) || gh_boolean_p ($4))
 464                         v = $4;
 465                 else
 466                         THIS->parser_error (_("Wrong type for property value"));
 467
 468                 /* ugh*/
 469                 unsmob_translator_def($$)->add_property_assign ($2, v);
 470         }
 471         | translator_spec_body NAME STRING semicolon {
 472                 unsmob_translator_def ($$)->type_name_ = $3;
 473         }
 474         | translator_spec_body CONSISTS STRING semicolon {
 475                 unsmob_translator_def ($$)->add_element ($3);
 476         }
 477         | translator_spec_body ELEMENTDESCRIPTIONS embedded_scm {
 478                 for (SCM p = $3; gh_pair_p (p); p = gh_cdr (p))
 479                         unsmob_translator_def ($$)
 480                         ->add_property_assign (scm_symbol_to_string (gh_caar (p)), gh_cdar (p));
 481
 482         }
 483         | translator_spec_body CONSISTSEND STRING semicolon {
 484                 unsmob_translator_def ($$)->add_last_element ( $3);
 485         }
 486         | translator_spec_body ACCEPTS STRING semicolon {
 487                 unsmob_translator_def ($$)->set_acceptor ($3,true);
 488         }
 489         | translator_spec_body DENIES STRING semicolon {
 490                 unsmob_translator_def ($$)->set_acceptor ($3,false);
 491         }
 492         | translator_spec_body REMOVE STRING semicolon {
 493                 unsmob_translator_def ($$)->remove_element ($3);
 494         }
 495         ;
 496
 497 /*
 498         SCORE
 499 */
 500 score_block:
 501         SCORE {
 502                 THIS->remember_spot ();
 503         }
 504         /*cont*/ '{' score_body '}'     {
 505                 THIS->pop_spot ();
 506                 $$ = $4;
 507                 if (!$$->def_p_arr_.size ())
 508                 {
 509                   Identifier *id =
 510                         unsmob_identifier (THIS->lexer_p_->lookup_identifier ("$defaultpaper"));
 511                   $$->add_output (id ? id->access_content_Music_output_def (true) : new Paper_def );
 512                 }
 513         }
 514 /*
 515         | SCORE '{' score_body error {
 516                 $$ = $3
 517                 $$->set_spot (THIS->here_input ());
 518                 // THIS->here_input ().error ("SCORE INVALID");
 519                 $$->error ("SCORE INVALID");
 520                 THIS->parser_error (_f ("SCORE ERROR"));
 521         }
 522 */
 523         ;
 524
 525 score_body:
 526         Music   {
 527                 $$ = new Score;
 528
 529                 $$->set_spot (THIS->here_input ());
 530                 SCM m = $1->self_scm ();
 531                 scm_unprotect_object (m);
 532                 $$->music_ = m;
 533         }
 534         | SCORE_IDENTIFIER {
 535                 $$ = $1->access_content_Score (true);
 536         }
 537         | score_body lilypond_header    {
 538                 $$->header_p_ = $2;
 539         }
 540         | score_body output_def {
 541                 $$->add_output ($2);
 542         }
 543         | score_body error {
 544
 545         }
 546         ;
 547
 548
 549 /*
 550         MIDI
 551 */
 552 output_def:
 553         music_output_def_body '}' {
 554                 $$ = $1;
 555                 THIS-> lexer_p_-> scope_l_arr_.pop();
 556         }
 557         ;
 558
 559 music_output_def_body:
 560         MIDI '{'    {
 561          Identifier *id = unsmob_identifier (THIS->lexer_p_->lookup_identifier ("$defaultmidi"));
 562
 563
 564          Midi_def* p =0;
 565         if (id)
 566                 p = dynamic_cast<Midi_def*> (id->access_content_Music_output_def (true));
 567         else
 568                 p = new Midi_def;
 569
 570          $$ = p;
 571          THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 572         }
 573         | PAPER '{'     {
 574                   Identifier *id = unsmob_identifier (THIS->lexer_p_->lookup_identifier ("$defaultpaper"));
 575                   Paper_def *p = 0;
 576                 if (id)
 577                         p = dynamic_cast<Paper_def*> (id->access_content_Music_output_def (true));
 578                 else
 579                         p = new Paper_def;
 580                 THIS-> lexer_p_-> scope_l_arr_.push (p->scope_p_);
 581                 $$ = p;
 582         }
 583         | PAPER '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 584                 Music_output_def *p = $3->access_content_Music_output_def (true);
 585                 THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 586                 $$ = p;
 587         }
 588         | MIDI '{' MUSIC_OUTPUT_DEF_IDENTIFIER  {
 589                 Music_output_def *p = $3->access_content_Music_output_def (true);
 590                 THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 591                 $$ = p;
 592         }
 593         | music_output_def_body assignment semicolon {
 594
 595         }
 596         | music_output_def_body translator_spec_block   {
 597                 $$->assign_translator ($2);
 598         }
 599         | music_output_def_body STYLESHEET embedded_scm {
 600                 dynamic_cast<Paper_def*> ($$)-> style_sheet_ = $3;
 601         }
 602         | music_output_def_body tempo_request semicolon {
 603                 /*
 604                         junk this ? there already is tempo stuff in
 605                         music.
 606                 */
 607                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 608                 dynamic_cast<Midi_def*> ($$)->set_tempo ($2->dur_.length_mom (), m);
 609         }
 610         | music_output_def_body error {
 611
 612         }
 613         ;
 614
 615 tempo_request:
 616         TEMPO steno_duration '=' bare_unsigned  {
 617                 $$ = new Tempo_req;
 618                 $$->set_mus_property ("duration", $2);
 619                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 620         }
 621         ;
 622
 623 Music_list: /* empty */ {
 624                 $$ = gh_cons (SCM_EOL, SCM_EOL);
 625         }
 626         | Music_list Music {
 627                 SCM s = $$;
 628                 SCM c = gh_cons ($2->self_scm (), SCM_EOL);
 629                 scm_unprotect_object ($2->self_scm ()); /* UGH */
 630
 631
 632                 if (gh_pair_p (gh_cdr (s)))
 633                         gh_set_cdr_x (gh_cdr (s), c); /* append */
 634                 else
 635                         gh_set_car_x (s, c); /* set first cons */
 636                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 637         }
 638         | Music_list error {
 639         }
 640         ;
 641
 642
 643 Music:
 644         Simple_music
 645         | Composite_music
 646         ;
 647
 648 Alternative_music:
 649         /* empty */ {
 650                 $$ = 0;
 651         }
 652         | ALTERNATIVE Music_sequence {
 653                 $$ = $2;
 654                 $2->set_spot (THIS->here_input ());
 655         }
 656         ;
 657
 658
 659
 660
 661 Repeated_music:
 662         REPEAT STRING bare_unsigned Music Alternative_music
 663         {
 664                 Music_sequence* m = dynamic_cast <Music_sequence*> ($5);
 665                 if (m && $3 < m->length_i ())
 666                         $5->origin ()->warning (_ ("More alternatives than repeats.  Junking excess alternatives."));
 667
 668                 SCM func = scm_eval2 (ly_symbol2scm ("repeat-name-to-ctor"), SCM_EOL);
 669                 SCM result = gh_call1 (func, $2);
 670                 Repeated_music * r = new Repeated_music ($4, $3 >? 1, m);
 671                 set_music_properties (r, result);
 672
 673                 r->set_spot (*$4->origin ());
 674                 $$ = r;
 675         }
 676         ;
 677
 678 Music_sequence: '{' Music_list '}'      {
 679                 $$ = new Music_sequence (gh_car ($2));
 680         }
 681         ;
 682
 683 Sequential_music:
 684         SEQUENTIAL '{' Music_list '}'           {
 685                 $$ = new Sequential_music (gh_car ($3));
 686         }
 687         | '{' Music_list '}'            {
 688                 $$ = new Sequential_music (gh_car ($2));
 689         }
 690         ;
 691
 692 Simultaneous_music:
 693         SIMULTANEOUS '{' Music_list '}'{
 694                 $$ = new Simultaneous_music (gh_car ($3));
 695         }
 696         | '<' Music_list '>'    {
 697                 $$ = new Simultaneous_music (gh_car ($2));
 698         }
 699         ;
 700
 701 Simple_music:
 702         request_chord           { $$ = $1; }
 703         | OUTPUTPROPERTY embedded_scm embedded_scm '=' embedded_scm     {
 704                 SCM pred = $2;
 705                 if (!gh_symbol_p ($3))
 706                 {
 707                         THIS->parser_error (_("Second argument must be a symbol"));
 708                 }
 709                 /*hould check # args */
 710                 if (!gh_procedure_p (pred))
 711                 {
 712                         THIS->parser_error (_("First argument must be a procedure taking 1 argument"));
 713                 }
 714
 715           Music *m = new Music;
 716           m->set_mus_property ("predicate", pred);
 717           m->set_mus_property ("symbol", $3);
 718           m->set_mus_property ("value",  $5);
 719           m->set_mus_property ("type",
 720                         Output_property_music_iterator::constructor_cxx_function);
 721
 722                 $$ = m;
 723         }
 724         | MUSIC_IDENTIFIER {
 725                 $$ = unsmob_music ($1)->clone ();
 726         }
 727         | property_def
 728         | translator_change
 729         | Simple_music '*' bare_unsigned '/' bare_unsigned      {
 730                 $$ = $1;
 731                 $$->compress (Moment($3, $5 ));
 732         }
 733         | Simple_music '*' bare_unsigned                 {
 734                 $$ = $1;
 735                 $$->compress (Moment ($3, 1));
 736         }
 737         ;
 738
 739
 740 Composite_music:
 741         CONTEXT STRING Music    {
 742                 Context_specced_music *csm =  new Context_specced_music ($3);
 743
 744                 csm->set_mus_property ("context-type",$2);
 745                 csm->set_mus_property ("context-id", ly_str02scm (""));
 746
 747                 $$ = csm;
 748         }
 749         | AUTOCHANGE STRING Music       {
 750                 Auto_change_music * chm = new Auto_change_music ($3);
 751                 chm->set_mus_property ("what", $2);
 752
 753                 $$ = chm;
 754                 chm->set_spot (*$3->origin ());
 755         }
 756         | GRACE Music {
 757                 $$ = new Grace_music ($2);
 758         }
 759         | CONTEXT STRING '=' STRING Music {
 760                 Context_specced_music *csm =  new Context_specced_music ($5);
 761
 762                 csm->set_mus_property ("context-type", $2);
 763                 csm->set_mus_property ("context-id", $4);
 764
 765                 $$ = csm;
 766         }
 767         | TIMES {
 768                 THIS->remember_spot ();
 769         }
 770         /* CONTINUED */
 771                 bare_unsigned '/' bare_unsigned Music
 772
 773         {
 774                 $$ = new Time_scaled_music ($3, $5, $6);
 775                 $$->set_spot (THIS->pop_spot ());
 776         }
 777         | Repeated_music                { $$ = $1; }
 778         | Simultaneous_music            { $$ = $1; }
 779         | Sequential_music              { $$ = $1; }
 780         | TRANSPOSE musical_pitch Music {
 781                 $$ = new Transposed_music ($3, *unsmob_pitch ($2));
 782         }
 783         | TRANSPOSE steno_tonic_pitch Music {
 784                 $$ = new Transposed_music ($3, *unsmob_pitch ($2));
 785         }
 786         | APPLY embedded_scm Music  {
 787                 SCM ret = gh_call1 ($2, $3->self_scm ());
 788                 Music *m = unsmob_music (ret);
 789                 if (!m) {
 790                         THIS->parser_error ("\\apply must return a Music");
 791                         m = new Music ();
 792                         }
 793                 $$ = m;
 794         }
 795         | NOTES
 796                 { THIS->lexer_p_->push_note_state (); }
 797         Music
 798                 { $$ = $3;
 799                   THIS->lexer_p_->pop_state ();
 800                 }
 801         | CHORDS
 802                 { THIS->lexer_p_->push_chord_state (); }
 803         Music
 804                 {
 805                   $$ = $3;
 806                   THIS->lexer_p_->pop_state ();
 807         }
 808         | LYRICS
 809                 { THIS->lexer_p_->push_lyric_state (); }
 810         Music
 811                 {
 812                   $$ = $3;
 813                   THIS->lexer_p_->pop_state ();
 814         }
 815         | relative_music        { $$ = $1; }
 816         | re_rhythmed_music     { $$ = $1; }
 817         | part_combined_music   { $$ = $1; }
 818         ;
 819
 820 relative_music:
 821         RELATIVE absolute_musical_pitch Music {
 822                 $$ = new Relative_octave_music ($3, *unsmob_pitch ($2));
 823         }
 824         ;
 825
 826 re_rhythmed_music:
 827         ADDLYRICS Music Music {
 828                 Lyric_combine_music * l = new Lyric_combine_music ($2, $3);
 829                 $$ = l;
 830         }
 831         ;
 832
 833 part_combined_music:
 834         PARTCOMBINE STRING Music Music {
 835                 Part_combine_music * p = new Part_combine_music ($2, $3, $4);
 836                 $$ = p;
 837         }
 838         ;
 839
 840 translator_change:
 841         TRANSLATOR STRING '=' STRING  {
 842                 Music * t = new Music;
 843                 t->set_mus_property ("type",
 844                         Change_iterator::constructor_cxx_function);
 845                 t-> set_mus_property ("change-to-type", $2);
 846                 t-> set_mus_property ("change-to-id", $4);
 847
 848                 $$ = t;
 849                 $$->set_spot (THIS->here_input ());
 850         }
 851         ;
 852
 853 property_def:
 854         PROPERTY STRING '.' STRING '='  scalar {
 855                 Music *t = new Music;
 856
 857                 t->set_mus_property ("type",
 858                         Property_iterator::constructor_cxx_function);
 859                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
 860                 t->set_mus_property ("value", $6);
 861
 862                 Context_specced_music *csm = new Context_specced_music (t);
 863                 $$ = csm;
 864                 $$->set_spot (THIS->here_input ());
 865
 866                 csm-> set_mus_property ("context-type", $2);
 867         }
 868         | PROPERTY STRING '.' STRING PUSH embedded_scm '=' embedded_scm {
 869                 Music *t = new Music;
 870                 t->set_mus_property ("type",
 871                         Push_property_iterator::constructor_cxx_function);
 872                 t->set_mus_property ("symbols", scm_string_to_symbol ($4));
 873                 t->set_mus_property ("element-property", $6);
 874                 t->set_mus_property ("element-value", $8);
 875                 Context_specced_music *csm = new Context_specced_music (t);
 876                 $$ = csm;
 877                 $$->set_spot (THIS->here_input ());
 878
 879                 csm-> set_mus_property ("context-type", $2);
 880         }
 881         | PROPERTY STRING '.' STRING POP embedded_scm {
 882                 Music *t = new Music;
 883                 t->set_mus_property ("type",
 884                         Pop_property_iterator::constructor_cxx_function);
 885                 t->set_mus_property ("symbols", scm_string_to_symbol ($4));
 886                 t->set_mus_property ("element-property", $6);
 887
 888                 Context_specced_music *csm = new Context_specced_music (t);
 889                 $$ = csm;
 890                 $$->set_spot (THIS->here_input ());
 891
 892                 csm-> set_mus_property ("context-type", $2);
 893         }
 894         ;
 895
 896 scalar:
 897         string          { $$ = $1; }
 898         | bare_int      { $$ = gh_int2scm ($1); }
 899         | embedded_scm  { $$ = $1; }
 900         ;
 901
 902
 903 request_chord:
 904         pre_requests simple_element post_requests       {
 905                 Music_sequence *l = dynamic_cast<Music_sequence*>($2);
 906                 if (l) {
 907                         for (int i=0; i < $1->size(); i++)
 908                                 l->append_music ($1->elem(i));
 909                         for (int i=0; i < $3->size(); i++)
 910                                 l->append_music ($3->elem(i));
 911                         }
 912                 else
 913                         programming_error ("Need Sequence to add music to");
 914                 $$ = $2;
 915
 916         }
 917         | command_element
 918         ;
 919
 920 command_element:
 921         command_req {
 922                 $$ = new Request_chord (gh_cons ($1->self_scm (), SCM_EOL));
 923                 $$-> set_spot (THIS->here_input ());
 924                 $1-> set_spot (THIS->here_input ());
 925         }
 926         | BAR STRING ';'                        {
 927                 Music *t = new Music;
 928
 929                 t->set_mus_property ("type",
 930                         Property_iterator::constructor_cxx_function);
 931                 t->set_mus_property ("symbol", ly_symbol2scm ("whichBar"));
 932                 t->set_mus_property ("value", $2);
 933
 934                 Context_specced_music *csm = new Context_specced_music (t);
 935                 $$ = csm;
 936                 $$->set_spot (THIS->here_input ());
 937
 938                 csm->set_mus_property ("context-type", ly_str02scm ("Score"));
 939         }
 940         | PARTIAL duration_length ';'   {
 941                 Music * p = new Music;
 942                 p->set_mus_property ("symbol", ly_symbol2scm ( "measurePosition"));
 943                 p->set_mus_property ("type",
 944                         Property_iterator::constructor_cxx_function);
 945
 946                 Moment m = - unsmob_duration($2)->length_mom ();
 947                 p->set_mus_property ("value", m.smobbed_copy ());
 948
 949                 Context_specced_music * sp = new Context_specced_music (p);
 950                 $$ =sp ;
 951                 sp-> set_mus_property ("context-type", ly_str02scm ( "Score"));
 952         }
 953         | CLEF STRING ';' {
 954                 SCM func = scm_eval2 (ly_symbol2scm ("clef-name-to-properties"), SCM_EOL);
 955                 SCM result = gh_call1 (func, $2);
 956
 957                 SCM l = SCM_EOL;
 958                 for (SCM s = result ; gh_pair_p (s); s = gh_cdr (s)) {
 959                         Music * p = new Music;
 960                         set_music_properties(p, gh_car (s));
 961                         l = gh_cons (p->self_scm (), l);
 962                         scm_unprotect_object (p->self_scm ());
 963                 }
 964                 Sequential_music * seq = new Sequential_music (l);
 965
 966                 Context_specced_music * sp = new Context_specced_music (seq);
 967                 $$ =sp ;
 968                 sp-> set_mus_property("context-type", ly_str02scm("Staff"));
 969         }
 970         | TIME_T bare_unsigned '/' bare_unsigned ';' {
 971                 Music * p = new Music;
 972                 p->set_mus_property ("symbol",
 973                         ly_symbol2scm ( "timeSignatureFraction"));
 974                 p->set_mus_property ("type",
 975                         Property_iterator::constructor_cxx_function);
 976
 977                 p->set_mus_property ("value", gh_cons (gh_int2scm ($2),
 978                                                         gh_int2scm ($4)));
 979
 980                 Context_specced_music * sp = new Context_specced_music (p);
 981                 $$ =sp ;
 982                 sp-> set_mus_property ("context-type", ly_str02scm ( "Score"));
 983         }
 984         ;
 985
 986 command_req:
 987         shorthand_command_req   { $$ = $1; }
 988         | verbose_command_req semicolon { $$ = $1; }
 989         ;
 990
 991 shorthand_command_req:
 992         extender_req {
 993                 $$ = $1;
 994         }
 995         | hyphen_req {
 996                 $$ = $1;
 997         }
 998         | '|'                           {
 999                 $$ = new Barcheck_req;
1000         }
1001         | '~'   {
1002                 $$ = new Tie_req;
1003         }
1004         | '['           {
1005                 Span_req*b= new Span_req;
1006                 b->set_span_dir(START);
1007                 b->set_mus_property ("span-type", ly_str02scm ("beam"));
1008                 $$ =b;
1009         }
1010         | ']'           {
1011                 Span_req*b= new Span_req;
1012                 b->set_span_dir( STOP);
1013                 b->set_mus_property ("span-type", ly_str02scm ("beam"));
1014                 $$ = b;
1015         }
1016         | BREATHE {
1017                 $$ = new Breathing_sign_req;
1018         }
1019         ;
1020
1021
1022 verbose_command_req:
1023         COMMANDSPANREQUEST bare_int STRING {
1024                 Span_req * sp_p = new Span_req;
1025                 sp_p-> set_span_dir ( Direction($2));
1026                 sp_p->set_mus_property ("span-type",$3);
1027                 sp_p->set_spot (THIS->here_input ());
1028                 $$ = sp_p;
1029         }
1030         | MARK  {
1031                 Mark_req * m = new Mark_req;
1032                 $$ = m;
1033         }
1034         | MARK STRING {
1035                 Mark_req *m = new Mark_req;
1036                 m->set_mus_property ("label", $2);
1037                 $$ = m;
1038
1039         }
1040         | MARK bare_unsigned {
1041                 Mark_req *m = new Mark_req;
1042                 m->set_mus_property ("label",  gh_int2scm ($2));
1043                 $$ = m;
1044         }
1045         | PENALTY bare_int      {
1046                 Break_req * b = new Break_req;
1047                 b->set_mus_property ("penalty", gh_double2scm ( $2 / 100.0));
1048                 b->set_spot (THIS->here_input ());
1049                 $$ = b;
1050         }
1051         | SKIP duration_length {
1052                 Skip_req * skip_p = new Skip_req;
1053                 skip_p->set_mus_property ("duration", $2);
1054
1055                 $$ = skip_p;
1056         }
1057         | tempo_request {
1058                 $$ = $1;
1059         }
1060         | KEY {
1061                 Key_change_req *key_p= new Key_change_req;
1062                 $$ = key_p;
1063         }
1064         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1065                 Key_change_req *key_p= new Key_change_req;
1066
1067                 key_p->set_mus_property ("pitch-alist", $3);
1068                 ((Music* )key_p)->transpose (* unsmob_pitch ($2));
1069                 $$ = key_p;
1070         }
1071         ;
1072
1073 post_requests:
1074         {
1075                 $$ = new Link_array<Request>;
1076         }
1077         | post_requests post_request {
1078                 $2->set_spot (THIS->here_input ());
1079                 $$->push ($2);
1080         }
1081         ;
1082
1083 post_request:
1084         verbose_request
1085         | request_with_dir
1086         | close_request
1087         ;
1088
1089
1090 request_that_take_dir:
1091         gen_text_def
1092         | verbose_request
1093         | script_abbreviation {
1094                 SCM s = THIS->lexer_p_->lookup_identifier ("dash-" + ly_scm2string ($1));
1095                 Articulation_req *a = new Articulation_req;
1096                 if (gh_string_p (s))
1097                         a->set_mus_property ("articulation-type", s);
1098                 else THIS->parser_error (_ ("Expecting string as script definition"));
1099                 $$ = a;
1100         }
1101         ;
1102
1103 request_with_dir:
1104         script_dir request_that_take_dir        {
1105                 if (Script_req * gs = dynamic_cast<Script_req*> ($2))
1106                         gs->set_direction (Direction ($1));
1107                 else if ($1)
1108                         $2->origin ()->warning (_ ("Can't specify direction for this request"));
1109                 $$ = $2;
1110         }
1111         ;
1112
1113 verbose_request:
1114         REQUEST_IDENTIFIER      {
1115                 $$ = dynamic_cast<Request*> (unsmob_music ($1)->clone ());
1116                 $$->set_spot (THIS->here_input ());
1117         }
1118         | DYNAMICSCRIPT embedded_scm {
1119                 /*
1120                         TODO: junkme, use text-type == dynamic
1121                 */
1122                 Text_script_req *d = new Text_script_req;
1123                 d->set_mus_property ("text-type" , ly_symbol2scm ("dynamic"));
1124                 d->set_mus_property ("text", $2);
1125                 d->set_spot (THIS->here_input ());
1126                 $$ = d;
1127         }
1128         | TEXTSCRIPT embedded_scm {
1129                 Text_script_req *t = new Text_script_req;
1130                 t->set_mus_property ("text", $2);
1131                 t->set_spot (THIS->here_input ());
1132                 $$ = t;
1133         }
1134         | SPANREQUEST bare_int STRING {
1135                 Span_req * sp_p = new Span_req;
1136                 sp_p->set_span_dir( Direction($2));
1137                 sp_p->set_mus_property ("span-type", $3);
1138                 sp_p->set_spot (THIS->here_input ());
1139                 $$ = sp_p;
1140         }
1141         | tremolo_type  {
1142                 Tremolo_req* a = new Tremolo_req;
1143                 a->set_spot (THIS->here_input ());
1144                 a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1145                 $$ = a;
1146         }
1147         | SCRIPT STRING         {
1148                 Articulation_req * a = new Articulation_req;
1149                 a->set_mus_property ("articulation-type", $2);
1150                 a->set_spot (THIS->here_input ());
1151                 $$ = a;
1152         }
1153         | ARPEGGIO {
1154                 Arpeggio_req *a = new Arpeggio_req;
1155                 a->set_spot (THIS->here_input ());
1156                 $$ = a;
1157         }
1158         ;
1159
1160 sup_quotes:
1161         '\'' {
1162                 $$ = 1;
1163         }
1164         | sup_quotes '\'' {
1165                 $$ ++;
1166         }
1167         ;
1168
1169 sub_quotes:
1170         ',' {
1171                 $$ = 1;
1172         }
1173         | sub_quotes ',' {
1174                 $$ ++ ;
1175         }
1176         ;
1177
1178 steno_musical_pitch:
1179         NOTENAME_PITCH  {
1180                 $$ = $1;
1181         }
1182         | NOTENAME_PITCH sup_quotes     {
1183                 Musical_pitch p = *unsmob_pitch ($1);
1184                 p.octave_i_ +=  $2;
1185                 $$ = p.smobbed_copy ();
1186         }
1187         | NOTENAME_PITCH sub_quotes      {
1188                 Musical_pitch p =* unsmob_pitch ($1);
1189
1190                 p.octave_i_ +=  -$2;
1191                 $$ = p.smobbed_copy ();
1192
1193         }
1194         ;
1195
1196 /*
1197 ugh. duplication
1198 */
1199
1200 steno_tonic_pitch:
1201         TONICNAME_PITCH {
1202                 $$ = $1;
1203         }
1204         | TONICNAME_PITCH sup_quotes    {
1205                 Musical_pitch p = *unsmob_pitch ($1);
1206                 p.octave_i_ +=  $2;
1207                 $$ = p.smobbed_copy ();
1208         }
1209         | TONICNAME_PITCH sub_quotes     {
1210                 Musical_pitch p =* unsmob_pitch ($1);
1211
1212                 p.octave_i_ +=  -$2;
1213                 $$ = p.smobbed_copy ();
1214
1215         }
1216         ;
1217
1218 musical_pitch:
1219         steno_musical_pitch {
1220                 $$ = $1;
1221         }
1222         | MUSICAL_PITCH embedded_scm {
1223                 if (!unsmob_pitch ($2))
1224                         THIS->parser_error (_f ("Expecting musical-pitch value", 3));
1225                  Musical_pitch m;
1226                 $$ = m.smobbed_copy ();
1227         }
1228         ;
1229
1230 explicit_duration:
1231         DURATION embedded_scm   {
1232                 $$ = $2;
1233                 if (!unsmob_duration ($2))
1234                 {
1235                         THIS->parser_error (_("Must have duration object"));
1236                         $$ = Duration ().smobbed_copy ();
1237                 }
1238         }
1239         ;
1240
1241 extender_req:
1242         EXTENDER {
1243                 if (!THIS->lexer_p_->lyric_state_b ())
1244                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1245                 $$ = new Extender_req;
1246         }
1247         ;
1248
1249 hyphen_req:
1250         HYPHEN {
1251                 if (!THIS->lexer_p_->lyric_state_b ())
1252                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1253                 $$ = new Hyphen_req;
1254         }
1255         ;
1256
1257 close_request:
1258         close_request_parens {
1259                 $$ = $1;
1260                 dynamic_cast<Span_req*> ($$)->set_span_dir ( START);
1261         }
1262
1263 close_request_parens:
1264         '('     {
1265                 Span_req* s= new Span_req;
1266                 $$ = s;
1267                 s->set_mus_property ("span-type", ly_str02scm( "slur"));
1268         }
1269         | E_SMALLER {
1270                 Span_req*s =new Span_req;
1271                 $$ = s;
1272                 s->set_mus_property ("span-type", ly_str02scm ( "crescendo"));
1273         }
1274         | E_BIGGER {
1275                 Span_req*s =new Span_req;
1276                 $$ = s;
1277                 s->set_mus_property ("span-type", ly_str02scm ("decrescendo"));
1278         }
1279         ;
1280
1281
1282 open_request:
1283         open_request_parens {
1284                 $$ = $1;
1285                 dynamic_cast<Span_req*> ($$)->set_span_dir (STOP);
1286         }
1287         ;
1288
1289 open_request_parens:
1290         E_EXCLAMATION   {
1291                 Span_req *s =  new Span_req;
1292                 s->set_mus_property ("span-type", ly_str02scm ( "crescendo"));
1293
1294                 $$ = s;
1295         }
1296         | ')'   {
1297                 Span_req* s= new Span_req;
1298                 $$ = s;
1299                 s->set_mus_property ("span-type", ly_str02scm( "slur"));
1300         }
1301         ;
1302
1303 gen_text_def:
1304         embedded_scm {
1305                 Text_script_req *t = new Text_script_req;
1306                 t->set_mus_property ("text", $1);
1307                 t->set_spot (THIS->here_input ());
1308                 $$ = t;
1309         }
1310         | string {
1311                 Text_script_req *t = new Text_script_req;
1312                 t->set_mus_property ("text", $1);
1313                 t->set_spot (THIS->here_input ());
1314                 $$ = t;
1315         }
1316         | DIGIT {
1317                 String ds = to_str ($1);
1318                 Text_script_req* t = new Text_script_req;
1319
1320                 t->set_mus_property ("text",  ly_str02scm (ds.ch_C()));
1321                 t->set_mus_property ("text-type" , ly_symbol2scm ("finger"));
1322                 t->set_spot (THIS->here_input ());
1323                 $$ = t;
1324         }
1325         ;
1326
1327 script_abbreviation:
1328         '^'             {
1329                 $$ = gh_str02scm  ("hat");
1330         }
1331         | '+'           {
1332                 $$ = gh_str02scm("plus");
1333         }
1334         | '-'           {
1335                 $$ = gh_str02scm ("dash");
1336         }
1337         | '|'           {
1338                 $$ = gh_str02scm ("bar");
1339         }
1340         | '>'           {
1341                 $$ = gh_str02scm ("larger");
1342         }
1343         | '.'           {
1344                 $$ = gh_str02scm ("dot");
1345         }
1346         ;
1347
1348
1349 script_dir:
1350         '_'     { $$ = DOWN; }
1351         | '^'   { $$ = UP; }
1352         | '-'   { $$ = CENTER; }
1353         ;
1354
1355 pre_requests:
1356         {
1357                 $$ = new Link_array<Request>;
1358         }
1359         | pre_requests open_request {
1360                 $$->push ($2);
1361         }
1362         ;
1363
1364 absolute_musical_pitch:
1365         steno_musical_pitch     {
1366                 $$ = $1;
1367         }
1368         ;
1369
1370 duration_length:
1371         steno_duration {
1372                 $$ = $1;
1373         }
1374         | duration_length '*' bare_unsigned {
1375                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1376         }
1377         | duration_length '/' bare_unsigned {
1378                 $$ = unsmob_duration ($$)->compressed (Moment (1,$3)).smobbed_copy ();
1379         }
1380         ;
1381
1382 entered_notemode_duration:
1383         steno_duration  {
1384                 THIS->set_last_duration (unsmob_duration ($1));
1385         }
1386         ;
1387
1388 optional_notemode_duration:
1389         {
1390                 $$ = THIS->default_duration_.smobbed_copy ();
1391         }
1392         | entered_notemode_duration {
1393                 $$ = $1;
1394         }
1395         ;
1396
1397 steno_duration:
1398         bare_unsigned dots              {
1399                 int l = 0;
1400                 if (!is_duration_b ($1))
1401                         THIS->parser_error (_f ("not a duration: %d", $1));
1402                 else
1403                         l =  intlog2 ($1);
1404
1405                 $$ = Duration (l, $2).smobbed_copy ();
1406         }
1407         | DURATION_IDENTIFIER dots      {
1408                 Duration *d =unsmob_duration ($1);
1409                 Duration k (d->duration_log (),d->dot_count () + $2);
1410                 $$ = k.smobbed_copy ();
1411         }
1412         ;
1413
1414 dots:
1415         /* empty */     {
1416                 $$ = 0;
1417         }
1418         | dots '.' {
1419                 $$ ++;
1420         }
1421         ;
1422
1423
1424 tremolo_type:
1425         ':'     {
1426                 $$ =0;
1427         }
1428         | ':' bare_unsigned {
1429                 if (!is_duration_b ($2))
1430                         THIS->parser_error (_f ("not a duration: %d", $2));
1431                 $$ = $2;
1432         }
1433         ;
1434
1435
1436 simple_element:
1437         musical_pitch exclamations questions optional_notemode_duration {
1438                 if (!THIS->lexer_p_->note_state_b ())
1439                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1440
1441                 Note_req *n = new Note_req;
1442
1443                 n->set_mus_property ("pitch", $1);
1444                 n->set_mus_property ("duration", $4);
1445
1446                 if ($3 % 2)
1447                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1448                 if ($2 % 2 || $3 % 2)
1449                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1450
1451                 Simultaneous_music*v = new Request_chord (gh_list (n->self_scm (), SCM_UNDEFINED));
1452
1453 /*
1454 FIXME
1455 */
1456                 v->set_spot (THIS->here_input ());
1457                 n->set_spot (THIS->here_input ());
1458
1459                 $$ = v;
1460         }
1461         | RESTNAME optional_notemode_duration           {
1462
1463                 SCM e = SCM_UNDEFINED;
1464                   if (ly_scm2string ($1) =="s")
1465                     { /* Space */
1466                       Skip_req * skip_p = new Skip_req;
1467                       skip_p->set_mus_property ("duration" ,$2);
1468
1469                       skip_p->set_spot (THIS->here_input());
1470                         e = skip_p->self_scm ();
1471                     }
1472                   else
1473                     {
1474                       Rest_req * rest_req_p = new Rest_req;
1475                       rest_req_p->set_mus_property ("duration", $2);
1476                       rest_req_p->set_spot (THIS->here_input());
1477                         e = rest_req_p->self_scm ();
1478                     }
1479                   Simultaneous_music* velt_p = new Request_chord (gh_list (e,SCM_UNDEFINED));
1480                   velt_p->set_spot (THIS->here_input());
1481
1482
1483                   $$ = velt_p;
1484         }
1485         | MEASURES optional_notemode_duration   {
1486                 Skip_req * sk = new Skip_req;
1487                 sk->set_mus_property ("duration", $2);
1488                 Span_req *sp1 = new Span_req;
1489                 Span_req *sp2 = new Span_req;
1490                 sp1-> set_span_dir ( START);
1491                 sp2-> set_span_dir ( STOP);
1492                 SCM r = ly_str02scm ("rest");
1493                 sp1->set_mus_property ("span-type", r);
1494                 sp2->set_mus_property ("span-type", r);
1495
1496                 Request_chord * rqc1 = new Request_chord (gh_list (sp1->self_scm (), SCM_UNDEFINED));
1497                 Request_chord * rqc2 = new Request_chord (gh_list (sk->self_scm (), SCM_UNDEFINED));;
1498                 Request_chord * rqc3 = new Request_chord(gh_list (sp2->self_scm (), SCM_UNDEFINED));;
1499
1500                 SCM ms = gh_list (rqc1->self_scm (), rqc2->self_scm (), rqc3->self_scm (), SCM_UNDEFINED);
1501
1502                 $$ = new Sequential_music (ms);
1503         }
1504         | STRING {
1505                 THIS->remember_spot ();
1506         }
1507         /* cont */
1508         optional_notemode_duration      {
1509                 if (!THIS->lexer_p_->lyric_state_b ()) {
1510                         THIS->pop_spot ().error (_ ("Have to be in Lyric mode for lyrics"));
1511                         THIS->error_level_i_  = 1;
1512                         THIS->parser_error (_ ("Giving up"));
1513                 }
1514                 else
1515                         THIS->pop_spot ();
1516                 Lyric_req* lreq_p = new Lyric_req;
1517                 lreq_p->set_mus_property ("text", $1);
1518                 lreq_p->set_mus_property ("duration",$3);
1519                 lreq_p->set_spot (THIS->here_input());
1520                 Simultaneous_music* velt_p = new Request_chord (gh_list (lreq_p->self_scm (), SCM_UNDEFINED));
1521
1522
1523                 $$= velt_p;
1524
1525         }
1526         | chord {
1527                 if (!THIS->lexer_p_->chord_state_b ())
1528                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
1529                 $$ = $1;
1530         }
1531         ;
1532
1533
1534 chord:
1535         steno_tonic_pitch optional_notemode_duration chord_additions chord_subtractions chord_inversion chord_bass {
1536                 $$ = get_chord ($1, $3, $4, $5, $6, $2);
1537                 $$->set_spot (THIS->here_input ());
1538         };
1539
1540 chord_additions:
1541         {
1542                 $$ = SCM_EOL;
1543         }
1544         | CHORD_COLON chord_notes {
1545                 $$ = $2;
1546         }
1547         ;
1548
1549 chord_notes:
1550         chord_step {
1551                 $$ = $1
1552         }
1553         | chord_notes '.' chord_step {
1554                 $$ = gh_append2 ($$, $3);
1555         }
1556         ;
1557
1558 chord_subtractions:
1559         {
1560                 $$ = SCM_EOL;
1561         }
1562         | CHORD_CARET chord_notes {
1563                 $$ = $2;
1564         }
1565         ;
1566
1567
1568 chord_inversion:
1569         {
1570                 $$ = SCM_EOL;
1571         }
1572         | '/' steno_tonic_pitch {
1573                 $$ = $2;
1574         }
1575         ;
1576
1577 chord_bass:
1578         {
1579                 $$ = SCM_EOL;
1580         }
1581         | CHORD_BASS steno_tonic_pitch {
1582                 $$ = $2;
1583         }
1584         ;
1585
1586 chord_step:
1587         chord_note {
1588                 $$ = gh_cons ($1, SCM_EOL);
1589         }
1590         | CHORDMODIFIER_PITCH {
1591                 $$ = gh_cons ($1, SCM_EOL);
1592         }
1593         | CHORDMODIFIER_PITCH chord_note { /* Ugh. */
1594                 $$ = gh_list ($1, $2, SCM_UNDEFINED);
1595         }
1596         ;
1597
1598 chord_note:
1599         bare_unsigned {
1600                  Musical_pitch m;
1601                 m.notename_i_ = ($1 - 1) % 7;
1602                 m.octave_i_ = $1 > 7 ? 1 : 0;
1603                 m.alteration_i_ = 0;
1604
1605                 $$ = m.smobbed_copy ();
1606         }
1607         | bare_unsigned '+' {
1608                 Musical_pitch m;
1609                 m.notename_i_ = ($1 - 1) % 7;
1610                 m.octave_i_ = $1 > 7 ? 1 : 0;
1611                 m.alteration_i_ = 1;
1612
1613
1614                 $$ = m.smobbed_copy ();
1615         }
1616         | bare_unsigned CHORD_MINUS {
1617                 Musical_pitch m;
1618                 m.notename_i_ = ($1 - 1) % 7;
1619                 m.octave_i_ = $1 > 7 ? 1 : 0;
1620                 m.alteration_i_ = -1;
1621
1622                 $$ = m.smobbed_copy ();
1623         }
1624         ;
1625
1626 /*
1627         UTILITIES
1628  */
1629 number_expression:
1630         bare_number {
1631                 $$ = $1;
1632         }
1633         | '-'  number_expression %prec UNARY_MINUS {
1634                 $$ = scm_difference ($2, SCM_UNDEFINED);
1635         }
1636         | number_expression '*' number_expression {
1637                 $$ = scm_product ($1, $3);
1638         }
1639         | number_expression '/' number_expression {
1640                 $$ = scm_divide ($1, $3);
1641         }
1642         | number_expression '+' number_expression {
1643                 $$ = scm_sum ($1, $3);
1644         }
1645         | number_expression '-' number_expression {
1646                 $$ = scm_difference ($1, $3);
1647         }
1648         | '(' number_expression ')'     {
1649                 $$ = $2;
1650         }
1651         ;
1652
1653 bare_number:
1654         UNSIGNED        {
1655                 $$ = gh_int2scm ($1);
1656         }
1657         | DIGIT         {
1658                 $$ = gh_int2scm ($1);
1659         }
1660         | REAL          {
1661                 $$ = gh_double2scm ($1);
1662         }
1663         | NUMBER_IDENTIFIER             {
1664                 $$ = $1;
1665         }
1666         | REAL CM_T     {
1667                 $$ = gh_double2scm ($1 CM);
1668         }
1669         | REAL PT_T     {
1670                 $$ = gh_double2scm ($1 PT);
1671         }
1672         | REAL IN_T     {
1673                 $$ = gh_double2scm ($1 INCH);
1674         }
1675         | REAL MM_T     {
1676                 $$ = gh_double2scm ($1 MM);
1677         }
1678         | REAL CHAR_T   {
1679                 $$ = gh_double2scm ($1 CHAR);
1680         }
1681         ;
1682
1683
1684 bare_unsigned:
1685         bare_number {
1686                 if (scm_integer_p ($1) == SCM_BOOL_T) {
1687                         $$ = gh_scm2int ($1);
1688
1689                 } else {
1690                         THIS->parser_error (_("need integer number arg"));
1691                         $$ = 0;
1692                 }
1693                 if ($$ < 0) {
1694                         THIS->parser_error (_("Must be positive integer"));
1695                         $$ = -$$;
1696                         }
1697
1698         }
1699         ;
1700 bare_int:
1701         bare_number {
1702                 if (scm_integer_p ($1) == SCM_BOOL_T)
1703                 {
1704                         int k = gh_scm2int ($1);
1705                         $$ = k;
1706                 } else
1707                 {
1708                         THIS->parser_error (_("need integer number arg"));
1709                         $$ = 0;
1710                 }
1711         }
1712         | '-' bare_int {
1713                 $$ = -$2;
1714         }
1715         ;
1716
1717
1718 string:
1719         STRING          {
1720                 $$ = $1;
1721         }
1722         | STRING_IDENTIFIER     {
1723                 $$ = $1;
1724         }
1725         | string '+' string {
1726                 $$ = scm_string_append (scm_listify ($1, $3, SCM_UNDEFINED));
1727         }
1728         ;
1729
1730
1731 exclamations:
1732                 { $$ = 0; }
1733         | exclamations '!'      { $$ ++; }
1734         ;
1735
1736 questions:
1737                 { $$ = 0; }
1738         | questions '?' { $$ ++; }
1739         ;
1740
1741
1742 semicolon:
1743         ';'
1744         ;
1745
1746 %%
1747
1748 void
1749 My_lily_parser::set_yydebug (bool b)
1750 {
1751 #ifdef YYDEBUG
1752         yydebug = b;
1753 #endif
1754 }
1755
1756 extern My_lily_parser * current_parser;
1757
1758 void
1759 My_lily_parser::do_yyparse ()
1760 {
1761
1762         current_parser = this;;
1763         yyparse ((void*)this);
1764 }
1765
1766