lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "context-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "ly-modules.hh"
  78 #include "music-sequence.hh"
  79 #include "input-smob.hh"
  80 #include "event.hh"
  81 #include "text-item.hh"
  82 #include "music-list.hh"
  83
  84 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  85
  86 Music *property_op_to_music (SCM op);
  87 Music *context_spec_music (SCM type, SCM id, Music * m, SCM ops_);
  88 SCM get_next_unique_context ();
  89
  90 #define YYERROR_VERBOSE 1
  91
  92 My_lily_parser* my_lily_parser;
  93 #define YYPARSE_PARAM my_lily_parser
  94 #define YYLEX_PARAM my_lily_parser
  95 #define THIS\
  96         ((My_lily_parser *) my_lily_parser)
  97
  98 #define yyerror THIS->parser_error
  99
 100 /*
 101   Add symbols to the  TAGS field of a music object.
 102 */
 103
 104 void
 105 tag_music (Music*m,  SCM tag, Input ip)
 106 {
 107         SCM tags = m->get_mus_property ("tags");
 108         if (gh_symbol_p (tag))
 109                 tags = scm_cons (tag, tags);
 110         else if (gh_list_p (tag))
 111                 tags = gh_append2 (tag, tags);
 112         else
 113                 ip.warning (_("Tag must be symbol or list of symbols."));
 114
 115         m->set_mus_property ("tags", tags);
 116 }
 117
 118
 119
 120 bool
 121 regular_identifier_b (SCM id)
 122 {
 123   String str = ly_scm2string (id);
 124   char const *s = str.to_str0 () ;
 125
 126   bool v = true;
 127   while (*s && v)
 128    {
 129         v = v && isalpha (*s);
 130         s++;
 131    }
 132   return v;
 133 }
 134
 135 SCM
 136 make_simple_markup (SCM a)
 137 {
 138         static SCM simple;
 139         if (!simple)
 140         simple = scm_c_eval_string ("simple-markup");
 141
 142         return scm_list_n (simple, a, SCM_UNDEFINED);
 143 }
 144
 145
 146 bool
 147 is_duration_b (int t)
 148 {
 149   return t && t == 1 << intlog2 (t);
 150 }
 151
 152 void
 153 set_music_properties (Music *p, SCM a)
 154 {
 155   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 156         {
 157         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 158         }
 159 }
 160
 161 SCM
 162 make_chord_step (int step, int alter)
 163 {
 164         if (step == 7)
 165                 alter += FLAT;
 166
 167         while(step < 0)
 168                 step += 7;
 169         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 170         return m.smobbed_copy ();
 171 }
 172
 173
 174 SCM
 175 make_chord (SCM pitch, SCM dur, SCM modification_list)
 176 {
 177         static SCM chord_ctor;
 178         if (!chord_ctor)
 179                 chord_ctor= scm_c_eval_string ("construct-chord");
 180         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 181         scm_gc_protect_object (ch);
 182         return ch;
 183 }
 184
 185 /*
 186   Todo: actually also use apply iso. call too ...
 187 */
 188 bool
 189 ly_input_procedure_p (SCM x)
 190 {
 191         return gh_procedure_p (x)
 192                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 193 }
 194
 195 Music*
 196 set_property_music (SCM sym, SCM value)
 197 {
 198         Music * p = MY_MAKE_MUSIC("PropertySet");
 199         p->set_mus_property ("symbol", sym);
 200         p->set_mus_property ("value", value);
 201         return p;
 202 }
 203
 204 %}
 205
 206 /* We use SCMs to do strings, because it saves us the trouble of
 207 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 208 of the parse stack onto the heap. */
 209
 210
 211 %union {
 212         String * string;
 213     Music *music;
 214     Score *score;
 215     Music_output_def * outputdef;
 216     SCM scm;
 217     int i;
 218 }
 219 %{
 220
 221 int
 222 yylex (YYSTYPE *s,  void * v)
 223 {
 224         My_lily_parser   *pars = (My_lily_parser*) v;
 225         My_lily_lexer * lex = pars->lexer_;
 226
 227         lex->lexval = (void*) s;
 228         lex->prepare_for_next_token();
 229         return lex->yylex ();
 230 }
 231
 232
 233 %}
 234
 235 %pure_parser
 236
 237
 238 %token ACCEPTS
 239 %token ADDLYRICS
 240 %token NEWADDLYRICS
 241 %token ALIAS
 242 %token ALTERNATIVE
 243 %token APPLY
 244 %token APPLYCONTEXT
 245 %token APPLYOUTPUT
 246 %token AUTOCHANGE
 247 %token BAR
 248 %token BREATHE
 249 %token CHANGE
 250 %token CHORDMODIFIERS
 251 %token CHORDS
 252 %token LESSLESS
 253 %token MOREMORE
 254 %token CLEF
 255 %token COMMANDSPANREQUEST
 256 %token CONSISTS
 257 %token CONSISTSEND
 258 %token CONTEXT
 259 %token DEFAULT
 260 %token DENIES
 261 %token DESCRIPTION
 262 %token EXTENDER
 263 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 264 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 265 %token GRACE
 266 %token ACCIACCATURA
 267 %token APPOGGIATURA
 268 %token GROBDESCRIPTIONS
 269 %token HEADER
 270 %token HYPHEN
 271 %token INVALID
 272 %token KEY
 273 %token LYRICS
 274 %token MARK
 275 %token MIDI
 276 %token MULTI_MEASURE_REST
 277 %token NAME
 278 %token NEWCONTEXT
 279 %token NOTES
 280 %token OCTAVE
 281 %token ONCE
 282 %token OVERRIDE SET REVERT
 283 %token PAPER
 284 %token PARTCOMBINE
 285 %token PARTIAL
 286 %token RELATIVE
 287 %token REMOVE
 288 %token REPEAT
 289 %token REST
 290 %token SCM_T
 291 %token SCORE
 292 %token SEQUENTIAL
 293 %token SIMULTANEOUS
 294 %token SKIP
 295 %token SPANREQUEST
 296 %token TAG
 297 %token TEMPO
 298 %token TIMES
 299 %token TIME_T
 300 %token TRANSLATOR
 301 %token TRANSPOSE
 302 %token TYPE
 303 %token UNSET
 304 %token WITH
 305
 306 /* escaped */
 307 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 308 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 309 %token E_BACKSLASH
 310 %token <i> E_UNSIGNED
 311 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 312 %token FIGURE_SPACE
 313
 314 %type <i>       exclamations questions dots optional_rest
 315 %type <i>        bass_mod
 316 %type <scm>     grace_head
 317 %type <scm>     oct_check
 318 %type <scm>     context_mod_list
 319 %type <scm>     lyric_element
 320 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 321 %token <i>      DIGIT
 322 %token <scm>    NOTENAME_PITCH
 323 %token <scm>    TONICNAME_PITCH
 324 %token <scm>    CHORDMODIFIER_PITCH
 325 %token <scm>    DURATION_IDENTIFIER
 326 %token <scm>    FRACTION
 327 %token <id>     IDENTIFIER
 328 %token DRUMS
 329 %token <scm>    DRUM_PITCH
 330 %token <scm>    CHORD_MODIFIER
 331 %token <scm>    SCORE_IDENTIFIER
 332 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 333 %token <scm>    NUMBER_IDENTIFIER
 334 %token <scm>    EVENT_IDENTIFIER
 335 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 336 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 337 %token <scm>    RESTNAME
 338 %token <scm>    STRING
 339 %token <scm>    SCM_T
 340 %token <i>      UNSIGNED
 341 %token <scm>   REAL
 342
 343 %token MARKUP
 344 %token <scm> MARKUP_HEAD_MARKUP0
 345 %token <scm> MARKUP_HEAD_EMPTY
 346 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 347 %token <scm> MARKUP_HEAD_SCM0
 348 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 349 %token <scm> MARKUP_HEAD_SCM0_SCM1
 350 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 351 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 352
 353 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 354 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 355
 356 %type <outputdef> output_def
 357 %type <scm>     lilypond_header lilypond_header_body
 358 %type <music>   open_event close_event
 359 %type <i>       sub_quotes sup_quotes
 360 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 361 %type <music>   Repeated_music
 362 %type <scm>     Alternative_music
 363 %type <i>       tremolo_type
 364 %type <i>       bare_int  bare_unsigned
 365 %type <i>       script_dir
 366 %type <scm>     identifier_init
 367
 368 %type <music> note_chord_element chord_body chord_body_element
 369 %type <scm>  chord_body_elements
 370 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 371
 372 %type <scm>   post_events
 373 %type <music> gen_text_def direction_less_event direction_reqd_event
 374 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 375 %type <scm>    steno_tonic_pitch
 376 %type <scm>     duration_length fraction
 377
 378 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 379
 380 %type <scm>  embedded_scm scalar
 381 %type <music>   Music Sequential_music Simultaneous_music
 382 %type <music>   relative_music re_rhythmed_music
 383 %type <music>   music_property_def context_change
 384 %type <scm> context_prop_spec
 385 %type <scm> Music_list
 386 %type <scm> property_operation context_mod translator_mod optional_context_mod
 387 %type <outputdef>  music_output_def_body music_output_def_head
 388 %type <music>   post_event tagged_post_event
 389 %type <music> command_req
 390 %type <music> string_number_event
 391 %type <scm>     string bare_number number_expression number_term number_factor
 392 %type <score>   score_block score_body
 393
 394 %type <scm>     translator_spec_block translator_spec_body
 395 %type <music>   tempo_event
 396 %type <scm>     script_abbreviation
 397
 398
 399
 400 %left '-' '+'
 401
 402 /* We don't assign precedence to / and *, because we might need varied
 403 prec levels in different prods */
 404
 405 %left UNARY_MINUS
 406
 407 %%
 408
 409 lilypond:       /* empty */
 410         | lilypond toplevel_expression {}
 411         | lilypond assignment  { }
 412         | lilypond error {
 413                 THIS->error_level_  = 1;
 414         }
 415         | lilypond INVALID      {
 416                 THIS->error_level_  = 1;
 417         }
 418         ;
 419
 420 toplevel_expression:
 421         lilypond_header {
 422                 THIS->input_file_->header_ = $1;
 423         }
 424         | score_block {
 425                 Score * sc = $1;
 426
 427                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 428
 429                 Path p = split_path (THIS->output_basename_);
 430                 int *c =  &THIS->input_file_->score_count_;
 431                 if (*c)
 432                         {
 433                         p.base += "-" + to_string (*c);
 434                         }
 435
 436                 (*c)++;
 437                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 438
 439                 for (int i=0; i < sc->defs_.size (); i++)
 440                         default_rendering (sc->music_, sc->defs_[i]->self_scm(),head, outname);
 441
 442                 if (sc->defs_.is_empty ())
 443                 {
 444                    Music_output_def *id =
 445                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 446                                 ("$defaultpaper"));
 447
 448                    id = id ? id->clone () : new Paper_def;
 449
 450                    default_rendering (sc->music_, id->self_scm(), head, outname);
 451
 452                    scm_gc_unprotect_object (id->self_scm ());
 453                 }
 454                 scm_gc_unprotect_object (sc->self_scm());
 455         }
 456         | output_def {
 457                 SCM id = SCM_EOL;
 458                 if (dynamic_cast<Paper_def*> ($1))
 459                         id = scm_makfrom0str ("$defaultpaper");
 460                 else if (dynamic_cast<Midi_def*> ($1))
 461                         id = scm_makfrom0str ("$defaultmidi");
 462                 THIS->lexer_->set_identifier (id,   $1->self_scm ());
 463                 scm_gc_unprotect_object ($1->self_scm ());
 464         }
 465         ;
 466
 467 embedded_scm:
 468         SCM_T
 469         | SCM_IDENTIFIER
 470         ;
 471
 472
 473
 474
 475 lilypond_header_body:
 476         {
 477                 $$ = ly_make_anonymous_module ();
 478                 THIS->lexer_->add_scope ($$);
 479         }
 480         | lilypond_header_body assignment  {
 481
 482         }
 483         ;
 484
 485 lilypond_header:
 486         HEADER '{' lilypond_header_body '}'     {
 487                 $$ = THIS->lexer_-> remove_scope();
 488         }
 489         ;
 490
 491
 492 /*
 493         DECLARATIONS
 494 */
 495 assignment:
 496         STRING {
 497                 THIS->push_spot ();
 498         }
 499         /* cont */ '=' identifier_init  {
 500
 501         /*
 502                 Should find generic way of associating input with objects.
 503         */
 504                 Input ip = THIS->pop_spot ();
 505
 506                 if (! regular_identifier_b ($1))
 507                 {
 508                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 509                 }
 510
 511                 THIS->lexer_->set_identifier ($1, $4);
 512
 513 /*
 514  TODO: devise standard for protection in parser.
 515
 516   The parser stack lives on the C-stack, which means that
 517 all objects can be unprotected as soon as they're here.
 518
 519 */
 520         }
 521         | embedded_scm { }
 522         ;
 523
 524
 525 identifier_init:
 526         score_block {
 527                 $$ = $1->self_scm ();
 528                 scm_gc_unprotect_object ($$);
 529         }
 530         | full_markup {
 531                 $$ = $1;
 532         }
 533         | output_def {
 534                 $$ = $1->self_scm ();
 535                 scm_gc_unprotect_object ($$);
 536         }
 537         | translator_spec_block {
 538                 $$ = $1;
 539         }
 540         | Music  {
 541                 $$ = $1->self_scm ();
 542                 scm_gc_unprotect_object ($$);
 543         }
 544         | post_event {
 545                 $$ = $1->self_scm ();
 546                 scm_gc_unprotect_object ($$);
 547         }
 548         | number_expression {
 549                 $$ = $1;
 550         }
 551         | string {
 552                 $$ = $1;
 553         }
 554         | embedded_scm  {
 555                 $$ = $1;
 556         }
 557         ;
 558
 559 translator_spec_block:
 560         TRANSLATOR '{' translator_spec_body '}'
 561                 {
 562                 $$ = $3;
 563         }
 564         ;
 565
 566 translator_spec_body:
 567         /**/ {
 568                 $$ = Context_def::make_scm ();
 569                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 570         }
 571         | TRANSLATOR_IDENTIFIER {
 572                 $$ = $1;
 573                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 574         }
 575         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 576                 Context_def*td = unsmob_context_def($$);
 577
 578                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 579                         SCM tag = gh_caar (p);
 580
 581                         /* TODO: should make new tag "grob-definition" ? */
 582                         td->add_context_mod (scm_list_n (ly_symbol2scm ("assign"),
 583                                                         tag, gh_cons (ly_cdar (p), SCM_EOL), SCM_UNDEFINED));
 584                 }
 585         }
 586         | translator_spec_body context_mod {
 587                 unsmob_context_def ($$)->add_context_mod ($2);
 588         }
 589         ;
 590
 591 /*
 592         SCORE
 593 */
 594 score_block:
 595         SCORE {
 596                 THIS->push_spot ();
 597         }
 598         /*cont*/ '{' score_body '}'     {
 599                 THIS->pop_spot ();
 600                 $$ = $4;
 601
 602         }
 603         ;
 604
 605 score_body:
 606         Music   {
 607                 $$ = new Score;
 608
 609                 $$->set_spot (THIS->here_input ());
 610                 SCM m = $1->self_scm ();
 611                 scm_gc_unprotect_object (m);
 612
 613                 /*
 614                         guh.
 615                 */
 616                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 617                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 618                         m = gh_call1 (gh_car (check_funcs), m);
 619                 $$->music_ = m;
 620
 621         }
 622         | SCORE_IDENTIFIER {
 623                 $$ = new Score ( *unsmob_score ($1));
 624                 $$->set_spot (THIS->here_input ());
 625         }
 626         | score_body lilypond_header    {
 627                 $$->header_ = $2;
 628         }
 629         | score_body output_def {
 630                 $$->defs_.push ($2);
 631                 scm_gc_unprotect_object ($2->self_scm ());
 632         }
 633         | score_body error {
 634
 635         }
 636         ;
 637
 638
 639 /*
 640         MIDI
 641 */
 642 output_def:
 643         music_output_def_body '}' {
 644                 $$ = $1;
 645                 THIS-> lexer_-> remove_scope ();
 646         }
 647         ;
 648
 649 music_output_def_head:
 650         MIDI    {
 651                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 652
 653
 654                 Midi_def* p =0;
 655                 if (id)
 656                         p = dynamic_cast<Midi_def*> (id->clone ());
 657                 else
 658                         p = new Midi_def;
 659
 660                 $$ = p;
 661                 THIS->lexer_->add_scope (p->scope_);
 662         }
 663         | PAPER         {
 664                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 665                   Paper_def *p = 0;
 666                 if (id)
 667                         p = dynamic_cast<Paper_def*> (id->clone ());
 668                 else
 669                         p = new Paper_def;
 670
 671                 THIS->lexer_->add_scope (p->scope_);
 672                 $$ = p;
 673         }
 674         ;
 675
 676
 677 music_output_def_body:
 678         music_output_def_head '{' {
 679
 680         }
 681         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 682                 scm_gc_unprotect_object ($1->self_scm ());
 683                 Music_output_def * o =  unsmob_music_output_def ($3);
 684                 $$ = o;
 685                 THIS->lexer_->remove_scope ();
 686                 THIS->lexer_->add_scope (o->scope_);
 687         }
 688         | music_output_def_body assignment  {
 689
 690         }
 691         | music_output_def_body translator_spec_block   {
 692                 $$->assign_translator ($2);
 693         }
 694         | music_output_def_body tempo_event  {
 695                 /*
 696                         junk this ? there already is tempo stuff in
 697                         music.
 698                 */
 699                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 700                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 701                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 702                 if (md)
 703                         md->set_tempo (d->get_length (), m);
 704                 scm_gc_unprotect_object ($2->self_scm ());
 705         }
 706         | music_output_def_body error {
 707
 708         }
 709         ;
 710
 711 tempo_event:
 712         TEMPO steno_duration '=' bare_unsigned  {
 713                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 714                 $$->set_mus_property ("tempo-unit", $2);
 715                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 716         }
 717         ;
 718
 719 /*
 720 The representation of a  list is the
 721
 722   (LIST . LAST-CONS)
 723
 724  to have  efficient append.
 725 */
 726 Music_list:
 727         /* empty */ {
 728                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 729         }
 730         | Music_list Music {
 731                 SCM s = $$;
 732                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 733                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 734                 if (gh_pair_p (ly_cdr (s)))
 735                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 736                 else
 737                         gh_set_car_x (s, c); /* set first cons */
 738                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 739         }
 740         | Music_list error {
 741         }
 742         ;
 743
 744
 745 Music:
 746         Simple_music
 747         | Composite_music
 748         ;
 749
 750 Alternative_music:
 751         /* empty */ {
 752                 $$ = SCM_EOL;
 753         }
 754         | ALTERNATIVE '{' Music_list '}' {
 755                 $$ = $3;
 756         }
 757         ;
 758
 759 Repeated_music:
 760         REPEAT string bare_unsigned Music Alternative_music
 761         {
 762                 Music *beg = $4;
 763                 int times = $3;
 764                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 765                 if (times < scm_ilength (alts)) {
 766                   unsmob_music (gh_car (alts))
 767                     ->origin ()->warning (
 768                     _("More alternatives than repeats.  Junking excess alternatives."));
 769                   alts = ly_truncate_list (times, alts);
 770                 }
 771
 772
 773                 static SCM proc;
 774                 if (!proc)
 775                         proc = scm_c_eval_string ("make-repeated-music");
 776
 777                 SCM mus = scm_call_1 (proc, $2);
 778                 scm_gc_protect_object (mus); // UGH.
 779                 Music *r =unsmob_music (mus);
 780                 if (beg)
 781                         {
 782                         r-> set_mus_property ("element", beg->self_scm ());
 783                         scm_gc_unprotect_object (beg->self_scm ());
 784                         }
 785                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 786
 787                 r-> set_mus_property ("elements",alts);
 788                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 789                         /*
 790                         we can not get durations and other stuff correct down the line, so we have to
 791                         add to the duration log here.
 792                         */
 793                         static SCM func;
 794
 795                         if (!func)
 796                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 797
 798                         int dots = ($3 % 3) ? 0 : 1;
 799                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 800
 801                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 802
 803                         if (seq) {
 804                                 int list_len =scm_ilength (seq->music_list ());
 805                                 if (list_len != 2)
 806                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 807                                 shift -= 1;
 808                                 r->compress (Moment (Rational (1,list_len)));
 809                                 }
 810                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 811
 812                 }
 813                 r->set_spot (*$4->origin ());
 814
 815                 $$ = r;
 816         }
 817         ;
 818
 819 Sequential_music:
 820         SEQUENTIAL '{' Music_list '}'           {
 821                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 822                 $$->set_mus_property ("elements", ly_car ($3));
 823                 $$->set_spot(THIS->here_input());
 824         }
 825         | '{' Music_list '}'            {
 826                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 827                 $$->set_mus_property ("elements", ly_car ($2));
 828                 $$->set_spot(THIS->here_input());
 829         }
 830         ;
 831
 832 Simultaneous_music:
 833         SIMULTANEOUS '{' Music_list '}'{
 834                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 835                 $$->set_mus_property ("elements", ly_car ($3));
 836                 $$->set_spot(THIS->here_input());
 837
 838         }
 839         | simul_open Music_list simul_close     {
 840                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 841                 $$->set_mus_property ("elements", ly_car ($2));
 842                 $$->set_spot(THIS->here_input());
 843         }
 844         ;
 845
 846 Simple_music:
 847         event_chord             { $$ = $1; }
 848         | APPLYOUTPUT embedded_scm {
 849                 if (!ly_input_procedure_p ($2))
 850                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 851                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 852                 $$->set_mus_property ("procedure", $2);
 853                 $$->set_spot (THIS->here_input());
 854         }
 855         | APPLYCONTEXT embedded_scm {
 856                 if (!ly_input_procedure_p ($2))
 857                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 858                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 859                 $$->set_mus_property ("procedure", $2);
 860                 $$->set_spot (THIS->here_input());
 861         }
 862         | MUSIC_IDENTIFIER {
 863                 $$ = unsmob_music ($1);
 864         }
 865         | music_property_def
 866         | context_change
 867         ;
 868
 869
 870 optional_context_mod:
 871         /**/ { $$ = SCM_EOL; }
 872         | WITH '{' context_mod_list '}'  { $$ = $3; }
 873         ;
 874
 875 grace_head:
 876         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 877         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 878         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 879         ;
 880
 881 context_mod_list:
 882         /* */  { $$ = SCM_EOL; }
 883         | context_mod_list context_mod  {
 884                  $$ = gh_cons ($2, $1);
 885         }
 886         ;
 887
 888 Composite_music:
 889         AUTOCHANGE Music        {
 890                 static SCM proc ;
 891                 if (!proc)
 892                         proc = scm_c_eval_string ("make-autochange-music");
 893
 894                 SCM res = scm_call_1 (proc,  $2->self_scm ());
 895                 scm_gc_unprotect_object ($2->self_scm ());
 896                 $$ = unsmob_music (res);
 897                 scm_gc_protect_object (res);
 898                 $$->set_spot (THIS->here_input());
 899         }
 900         | PARTCOMBINE Music Music {
 901                 static SCM proc;
 902                 if (!proc)
 903                         proc = scm_c_eval_string ("make-part-combine-music");
 904
 905                 SCM res = scm_call_1 (proc, gh_list ($2->self_scm (),
 906                         $3->self_scm (), SCM_UNDEFINED));
 907                 scm_gc_unprotect_object ($3->self_scm ());
 908                 scm_gc_unprotect_object ($2->self_scm ());
 909                 $$ = unsmob_music (res);
 910                 scm_gc_protect_object (res);
 911                 $$->set_spot (THIS->here_input());
 912         }
 913         | grace_head Music {
 914 #if 1
 915         /*
 916                 The other version is for easier debugging  of
 917                 Sequential_music_iterator in combination with grace notes.
 918         */
 919
 920 /*
 921
 922 TODO: should distinguish between both grace types in the
 923 basic music objects too, since the meaning is different.
 924
 925 */
 926
 927                 String start_str = "start" + ly_scm2string ($1) + "Music";
 928                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 929
 930                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 931                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 932
 933                 Music *startm = unsmob_music (start);
 934                 Music *stopm = unsmob_music (stop);
 935
 936                 SCM ms = SCM_EOL;
 937                 if (stopm) {
 938                         stopm = stopm->clone ();
 939                         ms = scm_cons (stopm->self_scm (), ms);
 940                         scm_gc_unprotect_object (stopm->self_scm ());
 941                 }
 942                 ms = scm_cons ($2->self_scm (), ms);
 943                 scm_gc_unprotect_object ($2->self_scm());
 944                 if (startm) {
 945                         startm = startm->clone ();
 946                         ms = scm_cons (startm->self_scm () , ms);
 947                         scm_gc_unprotect_object (startm->self_scm ());
 948                 }
 949
 950                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 951                 seq->set_mus_property ("elements", ms);
 952
 953
 954                 $$ = MY_MAKE_MUSIC("GraceMusic");
 955                 $$->set_mus_property ("element", seq->self_scm ());
 956                 scm_gc_unprotect_object (seq->self_scm ());
 957 #else
 958                 $$ = MY_MAKE_MUSIC("GraceMusic");
 959                 $$->set_mus_property ("element", $2->self_scm ());
 960                 scm_gc_unprotect_object ($2->self_scm ());
 961 #endif
 962         }
 963         | CONTEXT string '=' string optional_context_mod Music {
 964                 $$ = context_spec_music ($2, $4, $6, $5);
 965
 966         }
 967         | CONTEXT STRING optional_context_mod Music {
 968                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 969         }
 970         | NEWCONTEXT string optional_context_mod Music {
 971                 $$ = context_spec_music ($2, get_next_unique_context (),
 972                                          $4, $3);
 973         }
 974
 975         | TIMES {
 976                 THIS->push_spot ();
 977         }
 978         /* CONTINUED */
 979                 fraction Music
 980
 981         {
 982                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 983                 Music *mp = $4;
 984
 985                 $$= MY_MAKE_MUSIC("TimeScaledMusic");
 986                 $$->set_spot (THIS->pop_spot ());
 987
 988                 $$->set_mus_property ("element", mp->self_scm ());
 989                 scm_gc_unprotect_object (mp->self_scm ());
 990                 $$->set_mus_property ("numerator", gh_int2scm (n));
 991                 $$->set_mus_property ("denominator", gh_int2scm (d));
 992                 $$->compress (Moment (Rational (n,d)));
 993
 994         }
 995         | Repeated_music                { $$ = $1; }
 996         | Simultaneous_music            { $$ = $1; }
 997         | Sequential_music              { $$ = $1; }
 998         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
 999                 $$ = MY_MAKE_MUSIC("TransposedMusic");
1000                 Music *p = $4;
1001                 Pitch from = *unsmob_pitch ($2);
1002                 Pitch to = *unsmob_pitch ($3);
1003
1004                 p->transpose (interval (from, to));
1005                 $$->set_mus_property ("element", p->self_scm ());
1006                 scm_gc_unprotect_object (p->self_scm ());
1007         }
1008         | APPLY embedded_scm Music  {
1009                 if (!ly_input_procedure_p ($2))
1010                         {
1011                         THIS->parser_error (_ ("\\apply takes function argument"));
1012                         $$ = $3;
1013                         }
1014                 else
1015                         {
1016                         SCM ret = gh_call1 ($2, $3->self_scm ());
1017                         Music *m = unsmob_music (ret);
1018                         if (!m) {
1019                                 THIS->parser_error ("\\apply must return a Music");
1020                                 m = MY_MAKE_MUSIC("Music");
1021                                 }
1022                         $$ = m;
1023                         }
1024         }
1025         | NOTES
1026                 {
1027                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1028                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1029         }
1030         Music
1031                 { $$ = $3;
1032                   THIS->lexer_->pop_state ();
1033                 }
1034         | DRUMS
1035                 {
1036                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1037                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1038         }
1039         Music
1040                 { $$ = $3;
1041                   THIS->lexer_->pop_state ();
1042                 }
1043         | FIGURES
1044                 { THIS->lexer_->push_figuredbass_state (); }
1045         Music
1046                 {
1047                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1048                   chm->set_mus_property ("element", $3->self_scm ());
1049                   $$ = chm;
1050                   scm_gc_unprotect_object ($3->self_scm());
1051
1052                   THIS->lexer_->pop_state ();
1053         }
1054         | CHORDS {
1055                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1056                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1057                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1058                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1059
1060         } Music {
1061                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1062                   chm->set_mus_property ("element", $3->self_scm ());
1063                   scm_gc_unprotect_object ($3->self_scm());
1064                   $$ = chm;
1065
1066                   THIS->lexer_->pop_state ();
1067         }
1068         | LYRICS
1069                 { THIS->lexer_->push_lyric_state (); }
1070         Music
1071                 {
1072                   $$ = $3;
1073                   THIS->lexer_->pop_state ();
1074         }
1075         | relative_music        { $$ = $1; }
1076         | re_rhythmed_music     { $$ = $1; }
1077         | TAG embedded_scm Music {
1078                 tag_music ($3, $2, THIS->here_input ());
1079                 $$ = $3;
1080         }
1081         ;
1082
1083 relative_music:
1084         RELATIVE absolute_pitch Music {
1085                 Music * p = $3;
1086                 Pitch pit = *unsmob_pitch ($2);
1087                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1088
1089                 $$->set_mus_property ("element", p->self_scm ());
1090                 scm_gc_unprotect_object (p->self_scm ());
1091
1092
1093                 Pitch retpitch = p->to_relative_octave (pit);
1094                 if (lily_1_8_relative)
1095                         $$->set_mus_property ("last-pitch", retpitch.smobbed_copy ());
1096         }
1097         ;
1098
1099 re_rhythmed_music:
1100         ADDLYRICS Music Music {
1101         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1102           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1103           scm_gc_unprotect_object ($3->self_scm ());
1104           scm_gc_unprotect_object ($2->self_scm ());
1105           $$ = l;
1106         }
1107         | NEWADDLYRICS string Music {
1108           Music*l =MY_MAKE_MUSIC("NewLyricCombineMusic");
1109           l->set_mus_property ("element", $3->self_scm ());
1110           scm_gc_unprotect_object ($3->self_scm ());
1111           $$ = l;
1112           l->set_mus_property ("associated-context", $2);
1113         }
1114         ;
1115
1116 context_change:
1117         CHANGE STRING '=' STRING  {
1118                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1119                 t-> set_mus_property ("change-to-type", scm_string_to_symbol ($2));
1120                 t-> set_mus_property ("change-to-id", $4);
1121
1122                 $$ = t;
1123                 $$->set_spot (THIS->here_input ());
1124         }
1125         ;
1126
1127 property_operation:
1128         STRING '='  scalar {
1129                 $$ = scm_list_n (ly_symbol2scm ("assign"),
1130                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1131         }
1132         | STRING UNSET {
1133                 $$ = scm_list_n (ly_symbol2scm ("unset"),
1134                         scm_string_to_symbol ($1), SCM_UNDEFINED);
1135         }
1136         | STRING SET embedded_scm '=' embedded_scm {
1137                 $$ = scm_list_n (ly_symbol2scm ("poppush"),
1138                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1139         }
1140         | STRING OVERRIDE embedded_scm '=' embedded_scm {
1141                 $$ = scm_list_n (ly_symbol2scm ("push"),
1142                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1143         }
1144         | STRING REVERT embedded_scm {
1145                 $$ = scm_list_n (ly_symbol2scm ("pop"),
1146                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1147         }
1148         ;
1149
1150 translator_mod:
1151         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1152         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1153         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1154
1155         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1156         | DENIES { $$ = ly_symbol2scm ("denies"); }
1157
1158         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1159         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1160         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1161         | NAME { $$ = ly_symbol2scm ("context-name"); }
1162         ;
1163
1164 context_mod:
1165         property_operation { $$ = $1; }
1166         | translator_mod STRING {
1167                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
1168         }
1169         ;
1170
1171 context_prop_spec:
1172         STRING  {
1173                 $$ = scm_list_n (ly_symbol2scm ("Bottom"), scm_string_to_symbol ($1), SCM_UNDEFINED);
1174         }
1175         | STRING '.' STRING {
1176                 $$ = scm_list_n (scm_string_to_symbol ($1), scm_string_to_symbol ($3), SCM_UNDEFINED);
1177         }
1178         ;
1179
1180 music_property_def:
1181         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1182                 $$ = property_op_to_music (scm_list_n (
1183                         ly_symbol2scm ("poppush"),
1184                         gh_cadr ($2),
1185                         $3, $5, SCM_UNDEFINED));
1186                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1187         }
1188         | SET context_prop_spec '=' scalar {
1189                 $$ = property_op_to_music (scm_list_n (
1190                         ly_symbol2scm ("assign"),
1191                         gh_cadr ($2),
1192                         $4, SCM_UNDEFINED));
1193                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1194         }
1195         | REVERT context_prop_spec embedded_scm {
1196                 $$ = property_op_to_music (scm_list_n (
1197                         ly_symbol2scm ("pop"),
1198                         gh_cadr ($2),
1199                         $3, SCM_UNDEFINED));
1200
1201                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1202         }
1203         | UNSET context_prop_spec {
1204                 $$ = property_op_to_music (scm_list_n (
1205                         ly_symbol2scm ("unset"),
1206                         gh_cadr ($2)));
1207                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1208         }
1209         | ONCE music_property_def {
1210                 $$ = $2;
1211                 $$->set_mus_property ("once", SCM_BOOL_T);
1212         }
1213         ;
1214
1215
1216
1217 scalar:
1218         string          { $$ = $1; }
1219         | bare_int      { $$ = gh_int2scm ($1); }
1220         | embedded_scm  { $$ = $1; }
1221         | full_markup {  $$ = $1; }
1222         | DIGIT { $$ = gh_int2scm ($1); }
1223         ;
1224
1225 /*
1226 This is a trick:
1227
1228 Adding pre_events to the simple_element
1229 makes the choice between
1230
1231   string:  STRING
1232
1233 and
1234
1235   simple_element: STRING
1236
1237 a single shift/reduction conflict.
1238
1239 nevertheless, this is not very clean, and we should find a different
1240 solution.
1241
1242 */
1243 pre_events: {
1244                 THIS->push_spot ();
1245         }
1246         ;
1247
1248 event_chord:
1249         pre_events simple_element post_events   {
1250                 SCM elts = $2-> get_mus_property ("elements");
1251
1252                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1253
1254                 $2->set_mus_property ("elements", elts);
1255                 $$ = $2;
1256         }
1257         | command_element
1258         | note_chord_element
1259         ;
1260
1261
1262 note_chord_element:
1263         chord_body optional_notemode_duration post_events
1264         {
1265                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1266                 SCM es = $1->get_mus_property ("elements");
1267                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1268
1269                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1270                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1271                 es = gh_append2 (es, postevs);
1272
1273                 $1-> set_mus_property ("elements", es);
1274                 $$ = $1;
1275         }
1276         ;
1277
1278 chord_open: '<'
1279         ;
1280
1281 chord_close: '>'
1282         ;
1283
1284 simul_open: LESSLESS
1285         ;
1286
1287 simul_close: MOREMORE
1288         ;
1289
1290 chord_body:
1291         chord_open chord_body_elements chord_close
1292         {
1293                 $$ = MY_MAKE_MUSIC("EventChord");
1294                 $$->set_mus_property ("elements",
1295                         scm_reverse_x ($2, SCM_EOL));
1296         }
1297         ;
1298
1299 chord_body_elements:
1300         /* empty */             { $$ = SCM_EOL; }
1301         | chord_body_elements chord_body_element {
1302                 $$ = gh_cons ($2->self_scm(), $1);
1303                 scm_gc_unprotect_object ($2->self_scm());
1304         }
1305         ;
1306
1307 chord_body_element:
1308         pitch exclamations questions post_events
1309         {
1310                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1311                 n->set_mus_property ("pitch", $1);
1312                 if ($3 % 2)
1313                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1314                 if ($2 % 2 || $3 % 2)
1315                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1316
1317                 if (gh_pair_p ($4)) {
1318                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1319                         n->set_mus_property ("articulations", arts);
1320                 }
1321                 $$ = n;
1322         }
1323         | DRUM_PITCH post_events {
1324                 Music *n =  MY_MAKE_MUSIC("NoteEvent");
1325                 n->set_mus_property ("duration" ,$2);
1326                 n->set_mus_property ("drum-type" , $1);
1327                 n->set_spot (THIS->here_input());
1328
1329                 if (gh_pair_p ($2)) {
1330                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1331                         n->set_mus_property ("articulations", arts);
1332                 }
1333                 $$ = n;
1334         }
1335         ;
1336
1337 command_element:
1338         command_req {
1339                 $$ = MY_MAKE_MUSIC("EventChord");
1340                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1341                 scm_gc_unprotect_object ($1->self_scm());
1342
1343                 $$-> set_spot (THIS->here_input ());
1344                 $1-> set_spot (THIS->here_input ());
1345         }
1346         | SKIP duration_length {
1347                 Music * skip = MY_MAKE_MUSIC("SkipMusic");
1348                 skip->set_mus_property ("duration", $2);
1349
1350                 $$ = skip;
1351         }
1352         | OCTAVE { THIS->push_spot (); }
1353           pitch {
1354                 Music *l = MY_MAKE_MUSIC("RelativeOctaveCheck");
1355                 $$ = l;
1356                 $$->set_spot (THIS->pop_spot ());
1357                 $$->set_mus_property ("pitch", $3);
1358         }
1359         | E_LEFTSQUARE {
1360                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1361                 l->set_mus_property ("span-direction", gh_int2scm (START));
1362                 l->set_spot (THIS->here_input ());
1363
1364                 $$ = MY_MAKE_MUSIC("EventChord");
1365                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1366                 scm_gc_unprotect_object (l->self_scm());
1367                 $$->set_spot (THIS->here_input ());
1368         }
1369         | E_RIGHTSQUARE {
1370                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1371                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1372                 l->set_spot (THIS->here_input ());
1373
1374                 $$ = MY_MAKE_MUSIC("EventChord");
1375                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1376                 $$->set_spot (THIS->here_input ());
1377                 scm_gc_unprotect_object (l->self_scm());
1378         }
1379         | E_BACKSLASH {
1380                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1381                 $$->set_spot (THIS->here_input ());
1382         }
1383         | '|'      {
1384
1385                 $$ = MY_MAKE_MUSIC("BarCheck");
1386                 $$->set_spot (THIS->here_input ());
1387         }
1388         | BAR STRING                    {
1389                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1390
1391                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1392                 csm->set_mus_property ("element", t->self_scm ());
1393                 scm_gc_unprotect_object (t->self_scm ());
1394
1395                 $$ = csm;
1396                 $$->set_spot (THIS->here_input ());
1397
1398                 csm->set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1399         }
1400         | PARTIAL duration_length       {
1401                 Moment m = - unsmob_duration ($2)->get_length ();
1402                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1403
1404                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1405                 sp->set_mus_property ("element", p->self_scm ());
1406                 scm_gc_unprotect_object (p->self_scm ());
1407
1408                 $$ =sp ;
1409                 sp-> set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1410         }
1411         | CLEF STRING  {
1412                 static SCM proc ;
1413                 if (!proc)
1414                         proc = scm_c_eval_string ("make-clef-set");
1415
1416                 SCM result = scm_call_1 (proc, $2);
1417                 scm_gc_protect_object (result);
1418                 $$ = unsmob_music (result);
1419         }
1420         | TIME_T fraction  {
1421                 static SCM proc;
1422                 if (!proc)
1423                         proc = scm_c_eval_string ("make-time-signature-set");
1424
1425                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1426                 scm_gc_protect_object (result);
1427                 $$ = unsmob_music (result);
1428         }
1429         | MARK scalar {
1430                 static SCM proc;
1431                 if (!proc)
1432                         proc = scm_c_eval_string ("make-mark-set");
1433
1434                 SCM result = scm_call_1 (proc, $2);
1435                 scm_gc_protect_object (result);
1436                 $$ = unsmob_music (result);
1437         }
1438         ;
1439
1440 command_req:
1441         BREATHE {
1442                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1443         }
1444         | E_TILDE {
1445                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1446         }
1447         | MARK DEFAULT  {
1448                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1449                 $$ = m;
1450         }
1451         | tempo_event {
1452                 $$ = $1;
1453         }
1454         | KEY DEFAULT {
1455                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1456                 $$ = key;
1457         }
1458         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1459
1460                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1461                 if (scm_ilength ($3) > 0)
1462                 {
1463                         key->set_mus_property ("pitch-alist", $3);
1464                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1465                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1466                 } else {
1467                         THIS->parser_error (_("Second argument must be pitch list."));
1468                 }
1469
1470                 $$ = key;
1471         }
1472         ;
1473
1474 post_events:
1475         /* empty */ {
1476                 $$ = SCM_EOL;
1477         }
1478         | post_events post_event {
1479                 $2->set_spot (THIS->here_input ());
1480                 $$ = gh_cons ($2->self_scm(), $$);
1481                 scm_gc_unprotect_object ($2->self_scm());
1482         }
1483         | post_events tagged_post_event {
1484                 $2 -> set_spot (THIS->here_input ());
1485                 $$ = scm_cons ($2->self_scm(), $$);
1486                 scm_gc_unprotect_object ($2->self_scm());
1487         }
1488         ;
1489
1490
1491 tagged_post_event:
1492         '-' TAG embedded_scm post_event {
1493                 tag_music ($4, $3, THIS->here_input ());
1494                 $$ = $4;
1495         }
1496         ;
1497
1498 post_event:
1499         direction_less_event {
1500                 $$ = $1;
1501         }
1502         | HYPHEN {
1503                 if (!THIS->lexer_->lyric_state_b ())
1504                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1505                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1506         }
1507         | EXTENDER {
1508                 if (!THIS->lexer_->lyric_state_b ())
1509                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1510                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1511         }
1512         | script_dir direction_reqd_event {
1513                 if ($1)
1514                         $2->set_mus_property ("direction", gh_int2scm ($1));
1515                 $$ = $2;
1516         }
1517         | script_dir direction_less_event {
1518                 if ($1)
1519                         $2->set_mus_property ("direction", gh_int2scm ($1));
1520                 $$ = $2;
1521         }
1522         | string_number_event
1523         ;
1524
1525 string_number_event:
1526         E_UNSIGNED {
1527                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1528                 s->set_mus_property ("string-number",  gh_int2scm($1));
1529                 s->set_spot (THIS->here_input ());
1530                 $$ = s;
1531         }
1532         ;
1533
1534
1535 direction_less_event:
1536         '['  {
1537
1538
1539 /*
1540
1541 TODO: should take all these defs out of the parser, adn make use
1542 configurable, i.e.
1543
1544
1545 (set-articulation '~ "trill")
1546
1547 */
1548                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1549                 m->set_spot (THIS->here_input());
1550                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1551                 $$ = m;
1552         }
1553         | ']'  {
1554                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1555                 m->set_spot (THIS->here_input());
1556                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1557                 $$ = m;
1558         }
1559         | '~' {
1560                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1561                 m->set_spot (THIS->here_input());
1562                 $$ = m;
1563         }
1564         | close_event {
1565                 $$ = $1;
1566                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1567                         gh_int2scm (START));
1568         }
1569         | open_event {
1570                 $$ = $1;
1571                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1572                         gh_int2scm (STOP));
1573         }
1574         | EVENT_IDENTIFIER      {
1575                 $$ = unsmob_music ($1);
1576         }
1577         | tremolo_type  {
1578                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1579                a->set_spot (THIS->here_input ());
1580                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1581                $$ = a;
1582         }
1583         ;
1584
1585 direction_reqd_event:
1586         gen_text_def {
1587                 $$ = $1;
1588         }
1589         | script_abbreviation {
1590                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1591                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1592                 if (gh_string_p (s))
1593                         a->set_mus_property ("articulation-type", s);
1594                 else THIS->parser_error (_ ("Expecting string as script definition"));
1595                 $$ = a;
1596         }
1597         ;
1598
1599 oct_check:
1600         /**/ { $$ = SCM_EOL; }
1601         | '='  { $$ = gh_int2scm (0); }
1602         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1603         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1604         ;
1605
1606 sup_quotes:
1607         '\'' {
1608                 $$ = 1;
1609         }
1610         | sup_quotes '\'' {
1611                 $$ ++;
1612         }
1613         ;
1614
1615 sub_quotes:
1616         ',' {
1617                 $$ = 1;
1618         }
1619         | sub_quotes ',' {
1620                 $$ ++ ;
1621         }
1622         ;
1623
1624 steno_pitch:
1625         NOTENAME_PITCH  {
1626                 $$ = $1;
1627         }
1628         | NOTENAME_PITCH sup_quotes     {
1629                 Pitch p = *unsmob_pitch ($1);
1630                 p = p.transposed (Pitch ($2,0,0));
1631                 $$ = p.smobbed_copy ();
1632         }
1633         | NOTENAME_PITCH sub_quotes      {
1634                 Pitch p =* unsmob_pitch ($1);
1635                 p = p.transposed (Pitch (-$2,0,0));
1636                 $$ = p.smobbed_copy ();
1637         }
1638         ;
1639
1640 /*
1641 ugh. duplication
1642 */
1643
1644 steno_tonic_pitch:
1645         TONICNAME_PITCH {
1646                 $$ = $1;
1647         }
1648         | TONICNAME_PITCH sup_quotes    {
1649                 Pitch p = *unsmob_pitch ($1);
1650                 p = p.transposed (Pitch ($2,0,0));
1651                 $$ = p.smobbed_copy ();
1652         }
1653         | TONICNAME_PITCH sub_quotes     {
1654                 Pitch p =* unsmob_pitch ($1);
1655
1656                 p = p.transposed (Pitch (-$2,0,0));
1657                 $$ = p.smobbed_copy ();
1658         }
1659         ;
1660
1661 pitch:
1662         steno_pitch {
1663                 $$ = $1;
1664         }
1665         ;
1666
1667 pitch_also_in_chords:
1668         pitch
1669         | steno_tonic_pitch
1670         ;
1671
1672 close_event:
1673         '('     {
1674                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1675                 $$ = s;
1676                 s->set_spot (THIS->here_input());
1677         }
1678         | E_OPEN        {
1679                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1680                 $$ = s;
1681                 s->set_spot (THIS->here_input());
1682         }
1683         | E_SMALLER {
1684                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1685                 $$ = s;
1686                 s->set_spot (THIS->here_input());
1687         }
1688         | E_BIGGER {
1689                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1690                 $$ = s;
1691                 s->set_spot (THIS->here_input());
1692         }
1693         ;
1694
1695
1696 open_event:
1697         E_EXCLAMATION   {
1698                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1699                 s->set_spot (THIS->here_input());
1700
1701                 $$ = s;
1702         }
1703         | ')'   {
1704                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1705                 $$ = s;
1706                 s->set_spot (THIS->here_input());
1707
1708         }
1709         | E_CLOSE       {
1710                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1711                 $$ = s;
1712                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1713                 s->set_spot (THIS->here_input());
1714         }
1715         ;
1716
1717 gen_text_def:
1718         full_markup {
1719                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1720                 t->set_mus_property ("text", $1);
1721                 t->set_spot (THIS->here_input ());
1722                 $$ = t;
1723         }
1724         | string {
1725                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1726                 t->set_mus_property ("text", make_simple_markup ($1));
1727                 t->set_spot (THIS->here_input ());
1728                 $$ = t;
1729
1730         }
1731         | DIGIT {
1732                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1733                 t->set_mus_property ("digit",  gh_int2scm ($1));
1734                 t->set_spot (THIS->here_input ());
1735                 $$ = t;
1736         }
1737         ;
1738
1739 script_abbreviation:
1740         '^'             {
1741                 $$ = scm_makfrom0str ("Hat");
1742         }
1743         | '+'           {
1744                 $$ = scm_makfrom0str ("Plus");
1745         }
1746         | '-'           {
1747                 $$ = scm_makfrom0str ("Dash");
1748         }
1749         | '|'           {
1750                 $$ = scm_makfrom0str ("Bar");
1751         }
1752         | '>'           {
1753                 $$ = scm_makfrom0str ("Larger");
1754         }
1755         | '.'           {
1756                 $$ = scm_makfrom0str ("Dot");
1757         }
1758         | '_' {
1759                 $$ = scm_makfrom0str ("Underscore");
1760         }
1761         ;
1762
1763 script_dir:
1764         '_'     { $$ = DOWN; }
1765         | '^'   { $$ = UP; }
1766         | '-'   { $$ = CENTER; }
1767         ;
1768
1769
1770 absolute_pitch:
1771         steno_pitch     {
1772                 $$ = $1;
1773         }
1774         ;
1775
1776 duration_length:
1777         multiplied_duration {
1778                 $$ = $1;
1779         }
1780         ;
1781
1782 optional_notemode_duration:
1783         {
1784                 Duration dd = THIS->default_duration_;
1785                 $$ = dd.smobbed_copy ();
1786
1787                 THIS->beam_check ($$);
1788         }
1789         | multiplied_duration   {
1790                 $$ = $1;
1791                 THIS->default_duration_ = *unsmob_duration ($$);
1792
1793                 THIS->beam_check ($$);
1794         }
1795         ;
1796
1797 steno_duration:
1798         bare_unsigned dots              {
1799                 int l = 0;
1800                 if (!is_duration_b ($1))
1801                         THIS->parser_error (_f ("not a duration: %d", $1));
1802                 else
1803                         l =  intlog2 ($1);
1804
1805                 $$ = Duration (l, $2).smobbed_copy ();
1806         }
1807         | DURATION_IDENTIFIER dots      {
1808                 Duration *d =unsmob_duration ($1);
1809                 Duration k (d->duration_log (),d->dot_count () + $2);
1810
1811                 *d = k;
1812                 $$ = $1;
1813         }
1814         ;
1815
1816
1817
1818
1819 multiplied_duration:
1820         steno_duration {
1821                 $$ = $1;
1822         }
1823         | multiplied_duration '*' bare_unsigned {
1824                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1825         }
1826         | multiplied_duration '*' FRACTION {
1827                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1828
1829                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1830         }
1831         ;
1832
1833 fraction:
1834         FRACTION { $$ = $1; }
1835         | UNSIGNED '/' UNSIGNED {
1836                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1837         }
1838         ;
1839
1840 dots:
1841         /* empty */     {
1842                 $$ = 0;
1843         }
1844         | dots '.' {
1845                 $$ ++;
1846         }
1847         ;
1848
1849
1850 tremolo_type:
1851         ':'     {
1852                 $$ =0;
1853         }
1854         | ':' bare_unsigned {
1855                 if (!is_duration_b ($2))
1856                         THIS->parser_error (_f ("not a duration: %d", $2));
1857                 $$ = $2;
1858         }
1859         ;
1860
1861
1862
1863 /*****************************************************************
1864                 BASS FIGURES
1865 *****************************************************************/
1866 bass_number:
1867         DIGIT   {
1868                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1869         }
1870         | UNSIGNED {
1871                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1872         }
1873         | STRING { $$ =  $1; }
1874         ;
1875
1876 bass_mod:
1877         '-'     { $$ = -2; }
1878         | '+'   { $$ = 2; }
1879         | '!'   { $$ = 0; }
1880         ;
1881
1882 bass_figure:
1883         FIGURE_SPACE {
1884                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1885                 $$ = bfr->self_scm();
1886                 scm_gc_unprotect_object ($$);
1887         }
1888         | bass_number  {
1889                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1890                 $$ = bfr->self_scm();
1891
1892                 bfr->set_mus_property ("figure", $1);
1893
1894                 scm_gc_unprotect_object ($$);
1895         }
1896         | bass_figure bass_mod {
1897                 Music *m = unsmob_music ($1);
1898                 if ($2) {
1899                         SCM salter =m->get_mus_property ("alteration");
1900                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1901                         m->set_mus_property ("alteration",
1902                                 gh_int2scm (alter + $2));
1903                 } else {
1904                         m->set_mus_property ("alteration", gh_int2scm (0));
1905                 }
1906         }
1907         ;
1908
1909 br_bass_figure:
1910         '[' bass_figure {
1911                 $$ = $2;
1912                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1913         }
1914         | bass_figure   {
1915                 $$ = $1;
1916         }
1917         | br_bass_figure ']' {
1918                 $$ = $1;
1919                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1920         }
1921         ;
1922
1923 figure_list:
1924         /**/            {
1925                 $$ = SCM_EOL;
1926         }
1927         | figure_list br_bass_figure {
1928                 $$ = scm_cons ($2, $1);
1929         }
1930         ;
1931
1932 figure_spec:
1933         FIGURE_OPEN figure_list FIGURE_CLOSE {
1934                 Music * m = MY_MAKE_MUSIC("EventChord");
1935                 $2 = scm_reverse_x ($2, SCM_EOL);
1936                 m->set_mus_property ("elements",  $2);
1937                 $$ = m->self_scm ();
1938         }
1939         ;
1940
1941
1942 optional_rest:
1943         /**/   { $$ = 0; }
1944         | REST { $$ = 1; }
1945         ;
1946
1947 simple_element:
1948         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1949
1950                 Input i = THIS->pop_spot ();
1951                 if (!THIS->lexer_->note_state_b ())
1952                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1953
1954                 Music *n = 0;
1955                 if ($6)
1956                         n =  MY_MAKE_MUSIC("RestEvent");
1957                 else
1958                         n =  MY_MAKE_MUSIC("NoteEvent");
1959
1960                 n->set_mus_property ("pitch", $1);
1961                 n->set_mus_property ("duration", $5);
1962
1963                 if (gh_number_p ($4))
1964                 {
1965                         int q = gh_scm2int ($4);
1966                         n->set_mus_property ("absolute-octave", gh_int2scm (q-1));
1967                 }
1968
1969                 if ($3 % 2)
1970                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1971                 if ($2 % 2 || $3 % 2)
1972                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1973
1974                 Music *v = MY_MAKE_MUSIC("EventChord");
1975                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1976                 scm_gc_unprotect_object (n->self_scm());
1977
1978                 v->set_spot (i);
1979                 n->set_spot (i);
1980                 $$ = v;
1981         }
1982         | DRUM_PITCH optional_notemode_duration {
1983                 Input i = THIS->pop_spot ();
1984
1985                 Music *n =  MY_MAKE_MUSIC("NoteEvent");
1986                 n->set_mus_property ("duration" ,$2);
1987                 n->set_mus_property ("drum-type" , $1);
1988
1989                 Music *v = MY_MAKE_MUSIC("EventChord");
1990                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1991                 scm_gc_unprotect_object (n->self_scm());
1992                 v->set_spot (i);
1993                 n->set_spot (i);
1994                 $$ = v;
1995
1996         }
1997         | figure_spec optional_notemode_duration {
1998                 Music * m = unsmob_music ($1);
1999                 Input i = THIS->pop_spot ();
2000                 m->set_spot (i);
2001                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
2002                 {
2003                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
2004                 }
2005                 $$ = m;
2006         }
2007         | RESTNAME optional_notemode_duration           {
2008
2009                 Input i = THIS->pop_spot ();
2010                 Music * ev = 0;
2011                 if (ly_scm2string ($1) =="s") {
2012                         /* Space */
2013                         ev = MY_MAKE_MUSIC("SkipEvent");
2014                   }
2015                 else {
2016                         ev = MY_MAKE_MUSIC("RestEvent");
2017
2018                     }
2019                 ev->set_mus_property ("duration" ,$2);
2020                 ev->set_spot (i);
2021                 Music * velt = MY_MAKE_MUSIC("EventChord");
2022                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
2023                 velt->set_spot (i);
2024
2025                 scm_gc_unprotect_object (ev->self_scm());
2026
2027                 $$ = velt;
2028         }
2029         | MULTI_MEASURE_REST optional_notemode_duration         {
2030                 THIS->pop_spot ();
2031
2032                 static SCM proc ;
2033                 if (!proc)
2034                         proc = scm_c_eval_string ("make-multi-measure-rest");
2035
2036                 SCM mus = scm_call_2 (proc, $2,
2037                         make_input (THIS->here_input()));
2038                 scm_gc_protect_object (mus);
2039                 $$ = unsmob_music (mus);
2040         }
2041
2042         | lyric_element optional_notemode_duration      {
2043                 Input i = THIS->pop_spot ();
2044                 if (!THIS->lexer_->lyric_state_b ())
2045                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2046
2047                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2048                 lreq->set_mus_property ("text", $1);
2049                 lreq->set_mus_property ("duration",$2);
2050                 lreq->set_spot (i);
2051                 Music * velt = MY_MAKE_MUSIC("EventChord");
2052                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2053
2054                 $$= velt;
2055         }
2056         | new_chord {
2057                 THIS->pop_spot ();
2058
2059                 if (!THIS->lexer_->chord_state_b ())
2060                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2061                 $$ = unsmob_music ($1);
2062         }
2063         ;
2064
2065 lyric_element:
2066         full_markup { $$ = $1; }
2067         | STRING {  $$ = $1 ; }
2068         ;
2069
2070 new_chord:
2071         steno_tonic_pitch optional_notemode_duration   {
2072                 $$ = make_chord ($1, $2, SCM_EOL);
2073         }
2074         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2075                 SCM its = scm_reverse_x ($4, SCM_EOL);
2076                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2077         }
2078         ;
2079
2080 chord_items:
2081         /**/ {
2082                 $$ = SCM_EOL;
2083         }
2084         | chord_items chord_item {
2085                 $$ = gh_cons ($2, $$);
2086         }
2087         ;
2088
2089 chord_separator:
2090         CHORD_COLON {
2091                 $$ = ly_symbol2scm ("chord-colon");
2092         }
2093         | CHORD_CARET {
2094                 $$ = ly_symbol2scm ("chord-caret");
2095         }
2096         | CHORD_SLASH steno_tonic_pitch {
2097                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2098         }
2099         | CHORD_BASS steno_tonic_pitch {
2100                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2101         }
2102         ;
2103
2104 chord_item:
2105         chord_separator {
2106                 $$ = $1;
2107         }
2108         | step_numbers {
2109                 $$ = scm_reverse_x ($1, SCM_EOL);
2110         }
2111         | CHORD_MODIFIER  {
2112                 $$ = $1;
2113         }
2114         ;
2115
2116 step_numbers:
2117         step_number { $$ = gh_cons ($1, SCM_EOL); }
2118         | step_numbers '.' step_number {
2119                 $$ = gh_cons ($3, $$);
2120         }
2121         ;
2122
2123 step_number:
2124         bare_unsigned {
2125                 $$ = make_chord_step ($1, 0);
2126         }
2127         | bare_unsigned '+' {
2128                 $$ = make_chord_step ($1, SHARP);
2129         }
2130         | bare_unsigned CHORD_MINUS {
2131                 $$ = make_chord_step ($1, FLAT);
2132         }
2133         ;
2134
2135 /*
2136         UTILITIES
2137
2138 TODO: should deprecate in favor of Scheme?
2139
2140  */
2141 number_expression:
2142         number_expression '+' number_term {
2143                 $$ = scm_sum ($1, $3);
2144         }
2145         | number_expression '-' number_term {
2146                 $$ = scm_difference ($1, $3);
2147         }
2148         | number_term
2149         ;
2150
2151 number_term:
2152         number_factor {
2153                 $$ = $1;
2154         }
2155         | number_factor '*' number_factor {
2156                 $$ = scm_product ($1, $3);
2157         }
2158         | number_factor '/' number_factor {
2159                 $$ = scm_divide ($1, $3);
2160         }
2161         ;
2162
2163 number_factor:
2164         '-'  number_factor { /* %prec UNARY_MINUS */
2165                 $$ = scm_difference ($2, SCM_UNDEFINED);
2166         }
2167         | bare_number
2168         ;
2169
2170
2171 bare_number:
2172         UNSIGNED        {
2173                 $$ = gh_int2scm ($1);
2174         }
2175         | REAL          {
2176                 $$ = $1;
2177         }
2178         | NUMBER_IDENTIFIER             {
2179                 $$ = $1;
2180         }
2181         | REAL NUMBER_IDENTIFIER        {
2182                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2183         }
2184         | UNSIGNED NUMBER_IDENTIFIER    {
2185                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2186         }
2187         ;
2188
2189
2190 bare_unsigned:
2191         UNSIGNED {
2192                         $$ = $1;
2193         }
2194         | DIGIT {
2195                 $$ = $1;
2196         }
2197         ;
2198
2199 bare_int:
2200         bare_number {
2201                 if (scm_integer_p ($1) == SCM_BOOL_T)
2202                 {
2203                         int k = gh_scm2int ($1);
2204                         $$ = k;
2205                 } else
2206                 {
2207                         THIS->parser_error (_ ("need integer number arg"));
2208                         $$ = 0;
2209                 }
2210         }
2211         | '-' bare_int {
2212                 $$ = -$2;
2213         }
2214         ;
2215
2216
2217 string:
2218         STRING          {
2219                 $$ = $1;
2220         }
2221         | STRING_IDENTIFIER     {
2222                 $$ = $1;
2223         }
2224         | string '+' string {
2225                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2226         }
2227         ;
2228
2229
2230 exclamations:
2231                 { $$ = 0; }
2232         | exclamations '!'      { $$ ++; }
2233         ;
2234
2235 questions:
2236                 { $$ = 0; }
2237         | questions '?' { $$ ++; }
2238         ;
2239
2240
2241
2242 full_markup:
2243         MARKUP_IDENTIFIER {
2244                 $$ = $1;
2245         }
2246         | MARKUP
2247                 { THIS->lexer_->push_markup_state (); }
2248         markup
2249                 { $$ = $3;
2250                   THIS->lexer_->pop_state ();
2251                 }
2252         ;
2253
2254
2255 /*
2256 This should be done more dynamically if possible.
2257 */
2258 markup:
2259         STRING {
2260                 $$ = make_simple_markup ($1);
2261         }
2262         | MARKUP_HEAD_EMPTY {
2263                 $$ = scm_list_n ($1, SCM_UNDEFINED);
2264         }
2265         | MARKUP_HEAD_MARKUP0 markup {
2266                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2267         }
2268         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2269                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2270         }
2271         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2272                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2273         }
2274         | markup_line {
2275                 $$ = $1;
2276         }
2277         | MARKUP_HEAD_LIST0 markup_list {
2278                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2279         }
2280         | MARKUP_HEAD_SCM0 embedded_scm {
2281                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2282         }
2283         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2284                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2285         }
2286         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2287                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2288         }
2289         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2290                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2291         }
2292         | MARKUP_IDENTIFIER {
2293                 $$ = $1;
2294         }
2295
2296         ;
2297
2298 markup_list:
2299         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2300         ;
2301
2302 markup_line:
2303         '{' markup_list_body '}' {
2304                 static SCM line ;
2305                 if (!line)
2306                         line = scm_c_eval_string ("line-markup");
2307
2308                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2309         }
2310         ;
2311
2312 markup_list_body:
2313         /**/ {  $$ = SCM_EOL; }
2314         | markup_list_body markup {
2315                 $$ = gh_cons ($2, $1) ;
2316         }
2317         ;
2318
2319
2320 %%
2321
2322 void
2323 My_lily_parser::set_yydebug (bool )
2324 {
2325 #if 0
2326         yydebug = 1;
2327 #endif
2328 }
2329
2330 extern My_lily_parser * current_parser;
2331
2332 void
2333 My_lily_parser::do_yyparse ()
2334 {
2335         current_parser = this;;
2336         yyparse ((void*)this);
2337 }
2338
2339
2340 /*
2341 Should make this optional?    It will also complain when you do
2342
2343         [s4]
2344
2345 which is entirely legitimate.
2346
2347 Or we can scrap it. Barchecks should detect wrong durations, and
2348 skipTypesetting speeds it up a lot.
2349 */
2350
2351 void
2352 My_lily_parser::beam_check (SCM dur)
2353 {
2354   Duration *d = unsmob_duration (dur);
2355   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2356     {
2357       Music * m = unsmob_music (last_beam_start_);
2358       m->origin ()->warning (_("Suspect duration found following this beam"));
2359     }
2360   last_beam_start_ = SCM_EOL;
2361 }
2362
2363
2364
2365
2366 /*
2367
2368 It is a little strange to have this function in this file, but
2369 otherwise, we have to import music classes into the lexer.
2370
2371 */
2372 int
2373 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2374 {
2375         if (gh_string_p (sid)) {
2376                 *destination = sid;
2377                 return STRING_IDENTIFIER;
2378         } else if (gh_number_p (sid)) {
2379                 *destination = sid;
2380                 return NUMBER_IDENTIFIER;
2381         } else if (unsmob_context_def (sid)) {
2382                 *destination = unsmob_context_def (sid)->clone_scm();
2383                 return TRANSLATOR_IDENTIFIER;
2384         } else if (unsmob_score (sid)) {
2385                 Score *sc =  new Score (*unsmob_score (sid));
2386                 *destination =sc->self_scm ();
2387                 return SCORE_IDENTIFIER;
2388         } else if (Music * mus =unsmob_music (sid)) {
2389                 *destination = unsmob_music (sid)->clone ()->self_scm();
2390                 unsmob_music (*destination)->
2391                         set_mus_property ("origin", make_input (last_input_));
2392                 return dynamic_cast<Event*> (mus)
2393                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2394         } else if (unsmob_duration (sid)) {
2395                 *destination = unsmob_duration (sid)->smobbed_copy();
2396                 return DURATION_IDENTIFIER;
2397         } else if (unsmob_music_output_def (sid)) {
2398                 Music_output_def *p = unsmob_music_output_def (sid);
2399                 p = p->clone ();
2400
2401                 *destination = p->self_scm();
2402                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2403         } else if (Text_item::markup_p (sid)) {
2404                 *destination = sid;
2405                 return MARKUP_IDENTIFIER;
2406         }
2407
2408         return -1;
2409 }
2410
2411 Music *
2412 property_op_to_music (SCM op)
2413 {
2414         Music * m = 0;
2415         SCM tag = gh_car (op);
2416         SCM symbol  = gh_cadr (op);
2417         SCM args = gh_cddr (op);
2418         SCM grob_val = SCM_UNDEFINED;
2419         SCM grob_sym = SCM_UNDEFINED;
2420         SCM val = SCM_UNDEFINED;
2421
2422         if (tag == ly_symbol2scm ("assign"))
2423                 {
2424                 m =  MY_MAKE_MUSIC("PropertySet");
2425                 val = gh_car (args);
2426                 }
2427         else if (tag == ly_symbol2scm ("unset"))
2428                 m =  MY_MAKE_MUSIC("PropertyUnset");
2429         else if (tag == ly_symbol2scm ("poppush")
2430                  || tag == ly_symbol2scm ("push"))
2431                 {
2432                 m  = MY_MAKE_MUSIC("OverrideProperty");
2433                 grob_sym = gh_car (args);
2434                 grob_val = gh_cadr (args);
2435                 }
2436         else if (tag == ly_symbol2scm ("pop")) {
2437                 m = MY_MAKE_MUSIC("RevertProperty");
2438                 grob_sym = gh_car (args);
2439                 }
2440
2441         m->set_mus_property ("symbol", symbol);
2442
2443         if (val != SCM_UNDEFINED)
2444                 m->set_mus_property ("value", val);
2445         if (grob_val != SCM_UNDEFINED)
2446                 m->set_mus_property ("grob-value", grob_val);
2447
2448         if (grob_sym != SCM_UNDEFINED)
2449                 {
2450                 bool itc = internal_type_checking_global_b;
2451                 /* UGH.
2452                 */
2453                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2454                 if (autobeam)
2455                         internal_type_checking_global_b = false;
2456                 m->set_mus_property ("grob-property", grob_sym);
2457                 if (autobeam)
2458                         internal_type_checking_global_b = itc;
2459                 }
2460
2461         if (op == ly_symbol2scm ("poppush"))
2462                 m->set_mus_property ("pop-first", SCM_BOOL_T);
2463
2464
2465         return m;
2466 }
2467
2468 Music*
2469 context_spec_music (SCM type, SCM id, Music * m, SCM ops)
2470 {
2471         Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
2472
2473         csm->set_mus_property ("element", m->self_scm ());
2474         scm_gc_unprotect_object (m->self_scm ());
2475
2476         csm->set_mus_property ("context-type",
2477                 gh_symbol_p (type) ? type : scm_string_to_symbol (type));
2478         csm->set_mus_property ("property-operations", ops);
2479
2480         if (gh_string_p (id))
2481                 csm->set_mus_property ("context-id", id);
2482         return csm;
2483 }
2484
2485
2486 SCM
2487 get_next_unique_context ()
2488 {
2489         static int new_context_count;
2490
2491         char s[1024];
2492         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2493
2494         return scm_makfrom0str (s);
2495 }
2496