lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29
  30 #include "context-def.hh"
  31 #include "dimensions.hh"
  32 #include "event.hh"
  33 #include "file-path.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "lily-lexer.hh"
  44 #include "lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "output-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((Lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (scm_is_symbol (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (scm_is_symbol (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left ADDLYRICS
 193
 194 %union {
 195         Book *book;
 196         Output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         Lily_parser *pars = (Lily_parser*) v;
 209         Lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226   (what? --hwn)
 227
 228 3. \markup { }
 229
 230   (what? --hwn)
 231
 232
 233 4.  \repeat
 234         \repeat .. \alternative
 235
 236
 237     \repeat { \repeat .. \alternative }
 238
 239 or
 240
 241     \repeat { \repeat } \alternative
 242
 243 )
 244  */
 245
 246
 247 %pure_parser
 248
 249 %token ACCEPTS
 250 %token ADDQUOTE
 251 %token LYRICSTO
 252 %token ALIAS
 253 %token ALTERNATIVE
 254 %token BAR
 255 %token BOOK
 256 %token BOOKPAPER
 257 %token CHANGE
 258 %token CHORDMODIFIERS
 259 %token CHORDS
 260 %token CHORDMODE
 261 %token DOUBLE_ANGLE_OPEN
 262 %token DOUBLE_ANGLE_CLOSE
 263 %token CLEF
 264 %token COMMANDSPANREQUEST
 265 %token CONSISTS
 266 %token CONTEXT
 267 %token DEFAULT
 268 %token DENIES
 269 %token DESCRIPTION
 270 %token EXTENDER
 271 %token FIGURES
 272 %token FIGUREMODE
 273 %token FIGURE_OPEN FIGURE_CLOSE
 274 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 275 %token GROBDESCRIPTIONS
 276 %token HEADER
 277 %token HYPHEN
 278 %token INVALID
 279 %token KEY
 280 %token LYRICS
 281 %token LYRICMODE
 282 %token MARK
 283 %token MIDI
 284 %token MULTI_MEASURE_REST
 285 %token NAME
 286 %token NEWCONTEXT
 287 %token NOTEMODE
 288 %token OCTAVE
 289 %token ONCE
 290 %token OVERRIDE SET REVERT
 291 %token PAPER
 292 %token PARTIAL
 293 %token QUOTE
 294 %token RELATIVE
 295 %token REMOVE
 296 %token REPEAT
 297 %token REST
 298 %token SCM_T
 299 %token SCORE
 300 %token SEQUENTIAL
 301 %token ADDLYRICS
 302 %token SIMULTANEOUS
 303 %token SKIP
 304 %token SPANREQUEST
 305 %token TAG
 306 %token TEMPO
 307 %token TIMES
 308 %token TIME_T
 309 %token TRANSPOSE
 310 %token TRANSPOSITION
 311 %token TYPE
 312 %token UNSET
 313 %token WITH
 314 %token MARKUP
 315
 316 /* escaped */
 317 /* FIXME: this sucks.  The user will get to see these names:
 318     syntax error, unexpected E_CHAR:
 319                 \
 320                  %%
 321   */
 322
 323 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 324 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 325 %token E_BACKSLASH
 326 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 327 %token FIGURE_SPACE
 328
 329 %token <i>      DIGIT
 330 %token <i>      UNSIGNED
 331 %token <i> E_UNSIGNED
 332 %token <id>     IDENTIFIER
 333 %token <scm>    CHORDMODIFIER_PITCH
 334 %token <scm>    DRUM_PITCH
 335 %token <scm>    DURATION_IDENTIFIER
 336 %token <scm>    EVENT_IDENTIFIER
 337 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 338 %token <scm>    NOTENAME_PITCH
 339 %token <scm>    NUMBER_IDENTIFIER
 340 %token <scm>    OUTPUT_DEF_IDENTIFIER
 341 %token <scm>    RESTNAME
 342 %token <scm> LYRICS_STRING
 343 %token <scm>    SCM_T
 344 %token <scm>    SCORE_IDENTIFIER
 345 %token <scm>    STRING
 346 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 347 %token <scm>    TONICNAME_PITCH
 348 %token <scm>    CHORD_MODIFIER
 349 %token <scm>    FRACTION
 350 %token <scm>   REAL
 351 %token <scm> MARKUP_HEAD_EMPTY
 352 %token <scm> MARKUP_HEAD_MARKUP0
 353 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 354 %token <scm> MARKUP_HEAD_SCM0
 355 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 356 %token <scm> MARKUP_HEAD_SCM0_SCM1
 357 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 358 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 359 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 360 %token <scm> MUSIC_FUNCTION
 361 %token <scm> MUSIC_FUNCTION_MUSIC
 362 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 363 %token <scm> MUSIC_FUNCTION_SCM
 364 %token <scm> MUSIC_FUNCTION_SCM_SCM
 365 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 366 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 367 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 368
 369 %token DRUMS
 370 %token DRUMMODE
 371
 372
 373 %type <book>    book_block book_body
 374 %type <i>       bare_int  bare_unsigned
 375 %type <i>       exclamations questions dots optional_rest
 376 %type <i>       script_dir
 377 %type <i>       sub_quotes sup_quotes
 378 %type <i>       tremolo_type
 379 %type <i>       bass_mod
 380
 381 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 382 %type <music>   Grouped_music_list
 383 %type <music>   Music Sequential_music Simultaneous_music
 384 %type <music>   Repeated_music
 385 %type <music>   command_req
 386 %type <music>   gen_text_def direction_less_event direction_reqd_event
 387 %type <music>   music_property_def context_change
 388 %type <music>   note_chord_element chord_body chord_body_element
 389 %type <music>   post_event tagged_post_event
 390 %type <music>   relative_music re_rhythmed_music
 391 %type <music>   simple_element event_chord command_element
 392 %type <music>   string_number_event
 393 %type <music>   toplevel_music
 394 %type <music>   tempo_event
 395
 396 %type <outputdef>       output_def_body output_def_head
 397 %type <outputdef> output_def book_paper_block
 398
 399 %type <scm>     Music_list
 400 %type <scm>     chord_body_elements
 401 %type <scm>     chord_item chord_items chord_separator new_chord
 402 %type <scm>     context_def_spec_block context_def_spec_body
 403 %type <scm>     context_mod context_def_mod optional_context_mod
 404 %type <scm>     context_prop_spec
 405 %type <scm>     direction_less_char
 406 %type <scm>     duration_length fraction
 407 %type <scm>     embedded_scm scalar
 408 %type <scm>     identifier_init
 409 %type <scm>     lilypond_header lilypond_header_body
 410 %type <scm>     new_lyrics
 411 %type <scm>     post_events
 412 %type <scm>     property_operation
 413 %type <scm>     script_abbreviation
 414 %type <scm>     simple_string
 415 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 416 %type <scm>     steno_tonic_pitch
 417 %type <scm>     step_number step_numbers
 418 %type <scm>     string bare_number number_expression number_term number_factor
 419 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 420 %type <scm>     context_mod_list
 421 %type <scm>     octave_check
 422 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 423 %type <scm>     Generic_prefix_music_scm
 424 %type <scm>     lyric_element
 425 %type <scm>     Alternative_music
 426 %type <scm>     markup markup_line markup_list markup_list_body full_markup
 427 %type <scm>     mode_changing_head
 428 %type <scm>     mode_changing_head_with_context
 429
 430 %type <score>   score_block score_body
 431
 432
 433 %left '-' '+'
 434
 435 /* We don't assign precedence to / and *, because we might need varied
 436 prec levels in different prods */
 437
 438 %left UNARY_MINUS
 439
 440 %%
 441
 442 lilypond:       /* empty */
 443         | lilypond toplevel_expression {
 444         }
 445         | lilypond assignment {
 446         }
 447         | lilypond error {
 448                 THIS->error_level_ = 1;
 449         }
 450         | lilypond INVALID      {
 451                 THIS->error_level_ = 1;
 452         }
 453         ;
 454
 455 toplevel_expression:
 456         lilypond_header {
 457                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 458         }
 459         | add_quote {
 460
 461         }
 462         | book_block {
 463                 Book *book = $1;
 464                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 465                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 466                 scm_gc_unprotect_object (book->self_scm ());
 467         }
 468         | score_block {
 469                 Score *score = $1;
 470
 471                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 472                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 473                 scm_gc_unprotect_object (score->self_scm ());
 474         }
 475         | toplevel_music {
 476                 Music *music = $1;
 477                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 478                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 479                 scm_gc_unprotect_object (music->self_scm ());
 480         }
 481         | output_def {
 482                 SCM id = SCM_EOL;
 483                 Output_def * od = $1;
 484
 485                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 486                         id = ly_symbol2scm ("$defaultpaper");
 487                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 488                         id = ly_symbol2scm ("$defaultmidi");
 489                 else if ($1->c_variable ("is-bookpaper") == SCM_BOOL_T)
 490                         id = ly_symbol2scm ("$defaultbookpaper");
 491
 492                 THIS->lexer_->set_identifier (id, od->self_scm ());
 493                 scm_gc_unprotect_object (od->self_scm ());
 494         }
 495         ;
 496
 497 toplevel_music:
 498         Composite_music {
 499         }
 500         ;
 501
 502 embedded_scm:
 503         SCM_T
 504         | SCM_IDENTIFIER
 505         ;
 506
 507
 508 lilypond_header_body:
 509         {
 510                 $$ = ly_make_anonymous_module (safe_global_b);
 511                 THIS->lexer_->add_scope ($$);
 512         }
 513         | lilypond_header_body assignment  {
 514
 515         }
 516         ;
 517
 518 lilypond_header:
 519         HEADER '{' lilypond_header_body '}'     {
 520                 $$ = THIS->lexer_->remove_scope ();
 521         }
 522         ;
 523
 524
 525 /*
 526         DECLARATIONS
 527 */
 528 assignment:
 529         STRING {
 530                 THIS->push_spot ();
 531         }
 532         /* cont */ '=' identifier_init  {
 533
 534         /*
 535                 Should find generic way of associating input with objects.
 536         */
 537                 Input ip = THIS->pop_spot ();
 538
 539                 if (! is_regular_identifier ($1))
 540                 {
 541                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 542                 }
 543
 544                 THIS->lexer_->set_identifier ($1, $4);
 545
 546 /*
 547  TODO: devise standard for protection in parser.
 548
 549   The parser stack lives on the C-stack, which means that
 550 all objects can be unprotected as soon as they're here.
 551
 552 */
 553         }
 554         | embedded_scm { }
 555         ;
 556
 557
 558 identifier_init:
 559         score_block {
 560                 $$ = $1->self_scm ();
 561                 scm_gc_unprotect_object ($$);
 562         }
 563         | output_def {
 564                 $$ = $1->self_scm ();
 565                 scm_gc_unprotect_object ($$);
 566         }
 567         | context_def_spec_block {
 568                 $$ = $1;
 569         }
 570         | Music  {
 571                 $$ = $1->self_scm ();
 572                 scm_gc_unprotect_object ($$);
 573         }
 574         | post_event {
 575                 $$ = $1->self_scm ();
 576                 scm_gc_unprotect_object ($$);
 577         }
 578         | number_expression {
 579                 $$ = $1;
 580         }
 581         | string {
 582                 $$ = $1;
 583         }
 584         | embedded_scm {
 585                 $$ = $1;
 586         }
 587         | full_markup {
 588                 $$ = $1;
 589         }
 590         | DIGIT {
 591                 $$ = scm_int2num ($1);
 592         }
 593         ;
 594
 595 context_def_spec_block:
 596         CONTEXT '{' context_def_spec_body '}'
 597                 {
 598                 $$ = $3;
 599         }
 600         ;
 601
 602 context_def_spec_body:
 603         /**/ {
 604                 $$ = Context_def::make_scm ();
 605                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 606         }
 607         | CONTEXT_DEF_IDENTIFIER {
 608                 $$ = $1;
 609                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 610         }
 611         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 612                 Context_def*td = unsmob_context_def ($$);
 613
 614                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 615                         SCM tag = ly_caar (p);
 616
 617                         /* TODO: should make new tag "grob-definition" ? */
 618                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 619                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 620                 }
 621         }
 622         | context_def_spec_body context_mod {
 623                 unsmob_context_def ($$)->add_context_mod ($2);
 624         }
 625         ;
 626
 627
 628
 629 book_block:
 630         BOOK {
 631                 THIS->push_spot ();
 632         }
 633         /*cont*/ '{' book_body '}'      {
 634                 THIS->pop_spot ();
 635                 $$ = $4;
 636         }
 637         ;
 638
 639 /* FIXME:
 640    * Use 'handlers' like for toplevel-* stuff?
 641    * grok \paper and \midi?  */
 642 book_body:
 643         {
 644                 $$ = new Book;
 645                 $$->set_spot (THIS->here_input ());
 646                 $$->bookpaper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultbookpaper"))->clone ());
 647                 scm_gc_unprotect_object ($$->bookpaper_->self_scm ());
 648                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 649         }
 650         | book_body book_paper_block {
 651                 $$->bookpaper_ = $2;
 652                 scm_gc_unprotect_object ($2->self_scm ());
 653         }
 654         | book_body score_block {
 655                 Score *score = $2;
 656                 $$->scores_.push (score);
 657                 scm_gc_unprotect_object (score->self_scm ());
 658         }
 659         | book_body lilypond_header {
 660                 $$->header_ = $2;
 661         }
 662         | book_body error {
 663
 664         }
 665         ;
 666
 667 score_block:
 668         SCORE {
 669                 THIS->push_spot ();
 670         }
 671         /*cont*/ '{' score_body '}'     {
 672                 THIS->pop_spot ();
 673                 $$ = $4;
 674         }
 675         ;
 676
 677 score_body:
 678         /**/    {
 679                 $$ = new Score;
 680
 681                 $$->set_spot (THIS->here_input ());
 682         }
 683         | SCORE_IDENTIFIER {
 684                 $$ = new Score ( *unsmob_score ($1));
 685                 $$->set_spot (THIS->here_input ());
 686         }
 687         | score_body Music {
 688                 SCM m = $2->self_scm ();
 689                 scm_gc_unprotect_object (m);
 690                 $$->set_music (m, THIS->self_scm ());
 691         }
 692         | score_body lilypond_header    {
 693                 $$->header_ = $2;
 694         }
 695         | score_body output_def {
 696                 if ($2->lookup_variable (ly_symbol2scm ("is-bookpaper")) == SCM_BOOL_T)
 697                 {
 698                         THIS->parser_error (_("\\bookpaper cannot be in \\score. Use \\paper instead"));
 699
 700                 }
 701                 else
 702                 {
 703                         $$->defs_.push ($2);
 704                 }
 705                 scm_gc_unprotect_object ($2->self_scm ());
 706         }
 707         | score_body error {
 708
 709         }
 710         ;
 711
 712
 713 /*
 714         OUTPUT DEF
 715 */
 716
 717 book_paper_block:
 718         output_def {
 719                 $$ = $1;
 720                 if ($$->lookup_variable (ly_symbol2scm ("is-bookpaper")) != SCM_BOOL_T)
 721                 {
 722                         THIS->parser_error (_("Need \\bookpaper for bookpaper block."));
 723                         $$ = get_bookpaper (THIS);
 724                 }
 725         }
 726         ;
 727
 728
 729 output_def:
 730         output_def_body '}' {
 731                 $$ = $1;
 732
 733                 THIS->lexer_->remove_scope ();
 734                 THIS->lexer_->pop_state ();
 735         }
 736         ;
 737
 738 output_def_head:
 739         BOOKPAPER {
 740                 $$ = get_bookpaper (THIS);
 741                 $$->input_origin_ = THIS->here_input ();
 742                 THIS->lexer_->add_scope ($$->scope_);
 743         }
 744         | MIDI    {
 745                 Output_def *p = get_midi (THIS);
 746                 $$ = p;
 747                 THIS->lexer_->add_scope (p->scope_);
 748         }
 749         | PAPER         {
 750                 Output_def *p = get_paper (THIS);
 751
 752                 THIS->lexer_->add_scope (p->scope_);
 753                 $$ = p;
 754         }
 755         ;
 756
 757
 758 output_def_body:
 759         output_def_head '{' {
 760                 $$ = $1;
 761                 $$->input_origin_.set_spot (THIS->here_input ());
 762                 THIS->lexer_->push_initial_state ();
 763         }
 764         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 765                 scm_gc_unprotect_object ($1->self_scm ());
 766                 Output_def *o = unsmob_output_def ($3);
 767                 o->input_origin_.set_spot (THIS->here_input ());
 768                 $$ = o;
 769                 THIS->lexer_->remove_scope ();
 770                 THIS->lexer_->add_scope (o->scope_);
 771                 THIS->lexer_->push_initial_state ();
 772         }
 773         | output_def_body assignment  {
 774
 775         }
 776         | output_def_body context_def_spec_block        {
 777                 assign_context_def ($$, $2);
 778         }
 779         | output_def_body tempo_event  {
 780                 /*
 781                         junk this ? there already is tempo stuff in
 782                         music.
 783                 */
 784                 int m = scm_to_int ($2->get_property ("metronome-count"));
 785                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 786                 set_tempo ($$, d->get_length (), m);
 787                 scm_gc_unprotect_object ($2->self_scm ());
 788         }
 789         | output_def_body error {
 790
 791         }
 792         ;
 793
 794 tempo_event:
 795         TEMPO steno_duration '=' bare_unsigned  {
 796                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 797                 $$->set_property ("tempo-unit", $2);
 798                 $$->set_property ("metronome-count", scm_int2num ( $4));
 799         }
 800         ;
 801
 802 /*
 803 The representation of a  list is the
 804
 805   (LIST . LAST-CONS)
 806
 807  to have  efficient append.
 808 */
 809 Music_list:
 810         /* empty */ {
 811                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 812         }
 813         | Music_list Music {
 814                 SCM s = $$;
 815                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 816                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 817                 if (ly_c_pair_p (ly_cdr (s)))
 818                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 819                 else
 820                         scm_set_car_x (s, c); /* set first cons */
 821                 scm_set_cdr_x (s, c);  /* remember last cell */
 822         }
 823         | Music_list embedded_scm {
 824         }
 825         | Music_list error {
 826         }
 827         ;
 828
 829
 830 Music:
 831         Simple_music
 832         | Composite_music
 833         ;
 834
 835 Alternative_music:
 836         /* empty */ {
 837                 $$ = SCM_EOL;
 838         }
 839         | ALTERNATIVE '{' Music_list '}' {
 840                 $$ = $3;
 841         }
 842         ;
 843
 844
 845 Repeated_music:
 846         REPEAT simple_string bare_unsigned Music Alternative_music
 847         {
 848                 Music *beg = $4;
 849                 int times = $3;
 850                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 851                 if (times < scm_ilength (alts)) {
 852                   unsmob_music (ly_car (alts))
 853                     ->origin ()->warning (
 854                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 855                   alts = ly_truncate_list (times, alts);
 856                 }
 857
 858
 859                 SCM proc = ly_scheme_function ("make-repeated-music");
 860
 861                 SCM mus = scm_call_1 (proc, $2);
 862                 scm_gc_protect_object (mus); // UGH.
 863                 Music *r = unsmob_music (mus);
 864                 if (beg)
 865                         {
 866                         r-> set_property ("element", beg->self_scm ());
 867                         scm_gc_unprotect_object (beg->self_scm ());
 868                         }
 869                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 870
 871                 r-> set_property ("elements",alts);
 872                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 873                         /*
 874                         TODO: move this code to Scheme.
 875                         */
 876
 877                         /*
 878                         we can not get durations and other stuff correct down the line, so we have to
 879                         add to the duration log here.
 880                         */
 881                         SCM func = ly_scheme_function ("shift-duration-log");
 882
 883                         int dots = ($3 % 3) ? 0 : 1;
 884                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 885
 886                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 887
 888                         if (seq) {
 889                                 int list_len = scm_ilength (seq->music_list ());
 890                                 if (list_len != 2)
 891                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 892                                 shift -= 1;
 893                                 r->compress (Moment (Rational (1, list_len)));
 894                                 }
 895                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 896
 897                 }
 898                 r->set_spot (*$4->origin ());
 899
 900                 $$ = r;
 901         }
 902         ;
 903
 904 Sequential_music:
 905         SEQUENTIAL '{' Music_list '}'           {
 906                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 907                 $$->set_property ("elements", ly_car ($3));
 908                 $$->set_spot (THIS->here_input ());
 909         }
 910         | '{' Music_list '}'            {
 911                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 912                 $$->set_property ("elements", ly_car ($2));
 913                 $$->set_spot (THIS->here_input ());
 914         }
 915         ;
 916
 917 Simultaneous_music:
 918         SIMULTANEOUS '{' Music_list '}'{
 919                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 920                 $$->set_property ("elements", ly_car ($3));
 921                 $$->set_spot (THIS->here_input ());
 922
 923         }
 924         | simul_open Music_list simul_close     {
 925                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 926                 $$->set_property ("elements", ly_car ($2));
 927                 $$->set_spot (THIS->here_input ());
 928         }
 929         ;
 930
 931 Simple_music:
 932         event_chord             { $$ = $1; }
 933         | MUSIC_IDENTIFIER {
 934                 $$ = unsmob_music ($1);
 935         }
 936         | music_property_def
 937         | context_change
 938         ;
 939
 940
 941 optional_context_mod:
 942         /**/ { $$ = SCM_EOL; }
 943         | WITH { THIS->lexer_->push_initial_state (); }
 944         '{' context_mod_list '}'
 945         {
 946                 THIS->lexer_->pop_state ();
 947                 $$ = $4;
 948         }
 949         ;
 950
 951 context_mod_list:
 952         /* */  { $$ = SCM_EOL; }
 953         | context_mod_list context_mod  {
 954                  $$ = scm_cons ($2, $1);
 955         }
 956         ;
 957
 958
 959 Composite_music:
 960         Prefix_composite_music { $$ = $1; }
 961         | Grouped_music_list { $$ = $1; }
 962         ;
 963
 964 Grouped_music_list:
 965         Simultaneous_music              { $$ = $1; }
 966         | Sequential_music              { $$ = $1; }
 967         ;
 968
 969 Generic_prefix_music_scm:
 970         MUSIC_FUNCTION {
 971                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 972         }
 973         | MUSIC_FUNCTION_SCM {
 974                 THIS->push_spot ();
 975         } embedded_scm {
 976                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 977         }
 978         | MUSIC_FUNCTION_MUSIC {
 979                 THIS->push_spot ();
 980         } Music {
 981                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 982                 scm_gc_unprotect_object ($3->self_scm ());
 983         }
 984         | MUSIC_FUNCTION_SCM_MUSIC {
 985                 THIS->push_spot ();
 986         }  embedded_scm Music {
 987                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
 988                 scm_gc_unprotect_object ($4->self_scm ());
 989         }
 990         | MUSIC_FUNCTION_SCM_SCM {
 991                 THIS->push_spot ();
 992         }  embedded_scm embedded_scm {
 993                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4);
 994         }
 995         | MUSIC_FUNCTION_MUSIC_MUSIC {
 996                 THIS->push_spot ();
 997         }  Music  Music {
 998                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
 999                 scm_gc_unprotect_object ($3->self_scm ());
1000                 scm_gc_unprotect_object ($4->self_scm ());
1001         }
1002         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
1003                 THIS->push_spot ();
1004         } embedded_scm Music Music {
1005                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
1006                         $3, $4->self_scm (), $5->self_scm ());
1007                 scm_gc_unprotect_object ($5->self_scm ());
1008                 scm_gc_unprotect_object ($4->self_scm ());
1009         }
1010         ;
1011
1012 Generic_prefix_music:
1013         Generic_prefix_music_scm {
1014                 SCM func = ly_car ($1);
1015                 Input *loc = unsmob_input (ly_cadr ($1));
1016                 SCM args = ly_cddr ($1);
1017                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1018                 int k = 0;
1019                 bool ok  = true;
1020                 for (SCM s = sig, t = args;
1021                         ok && ly_c_pair_p (s) && ly_c_pair_p (t);
1022                         s = ly_cdr (s), t = ly_cdr (t)) {
1023                         k++;
1024                         if (scm_call_1 (ly_car (s), ly_car (t)) != SCM_BOOL_T)
1025                         {
1026                                 loc->error (_f ("Argument %d failed typecheck", k));
1027                                 THIS->error_level_ = 1;
1028                                 ok = false;
1029                         }
1030                 }
1031                 SCM m = SCM_EOL;
1032                 if (ok)
1033                         m = scm_apply_0 (func, ly_cdr ($1));
1034                 if (unsmob_music (m))
1035                         {
1036                         $$ = unsmob_music (m);
1037                         scm_gc_protect_object (m);
1038                         }
1039                 else
1040                         {
1041                         if (ok)
1042                                 loc->error (_ ("Music head function should return Music object."));
1043                         $$ = MY_MAKE_MUSIC ("Music");
1044                         }
1045                 $$->set_spot (*loc);
1046         }
1047         ;
1048
1049
1050 Prefix_composite_music:
1051         Generic_prefix_music {
1052                 $$ = $1;
1053         }
1054         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1055                 $$ = context_spec_music ($2, $4, $6, $5);
1056
1057         }
1058         | CONTEXT simple_string optional_context_mod Music {
1059                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1060         }
1061         | NEWCONTEXT simple_string optional_context_mod Music {
1062                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1063                         $3);
1064         }
1065
1066         | TIMES {
1067                 THIS->push_spot ();
1068         }
1069         /* CONTINUED */
1070                 fraction Music
1071
1072         {
1073                 int n = scm_to_int (ly_car ($3)); int d = scm_to_int (ly_cdr ($3));
1074                 Music *mp = $4;
1075
1076                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1077                 $$->set_spot (THIS->pop_spot ());
1078
1079                 $$->set_property ("element", mp->self_scm ());
1080                 scm_gc_unprotect_object (mp->self_scm ());
1081                 $$->set_property ("numerator", scm_int2num (n));
1082                 $$->set_property ("denominator", scm_int2num (d));
1083                 $$->compress (Moment (Rational (n,d)));
1084
1085         }
1086         | Repeated_music                { $$ = $1; }
1087         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1088                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1089                 Music *p = $4;
1090                 Pitch from = *unsmob_pitch ($2);
1091                 Pitch to = *unsmob_pitch ($3);
1092
1093                 p->transpose (interval (from, to));
1094                 $$->set_property ("element", p->self_scm ());
1095                 scm_gc_unprotect_object (p->self_scm ());
1096         }
1097         | mode_changing_head Grouped_music_list {
1098                 if ($1 == ly_symbol2scm ("chords"))
1099                 {
1100                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1101                   chm->set_property ("element", $2->self_scm ());
1102                   $$ = chm;
1103                   scm_gc_unprotect_object ($2->self_scm ());
1104                 }
1105                 else
1106                 {
1107                   $$ = $2;
1108                 }
1109                 THIS->lexer_->pop_state ();
1110         }
1111         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1112                 $$ = context_spec_music ($1, get_next_unique_context (),
1113                                          $3, $2);
1114                 if ($1 == ly_symbol2scm ("ChordNames"))
1115                 {
1116                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1117                   chm->set_property ("element", $$->self_scm ());
1118                   scm_gc_unprotect_object ($$->self_scm ());
1119                   $$ = chm;
1120                 }
1121                 THIS->lexer_->pop_state ();
1122         }
1123         | relative_music        { $$ = $1; }
1124         | re_rhythmed_music     { $$ = $1; }
1125         | TAG embedded_scm Music {
1126                 tag_music ($3, $2, THIS->here_input ());
1127                 $$ = $3;
1128         }
1129         ;
1130
1131 mode_changing_head:
1132         NOTEMODE {
1133                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1134                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1135
1136                 $$ = ly_symbol2scm ("notes");
1137         }
1138         | DRUMMODE
1139                 {
1140                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1141                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1142
1143                 $$ = ly_symbol2scm ("drums");
1144         }
1145         | FIGUREMODE {
1146                 THIS->lexer_->push_figuredbass_state ();
1147
1148                 $$ = ly_symbol2scm ("figures");
1149         }
1150         | CHORDMODE {
1151                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1152                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1153                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1154                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1155                 $$ = ly_symbol2scm ("chords");
1156
1157         }
1158         | LYRICMODE
1159                 { THIS->lexer_->push_lyric_state ();
1160                 $$ = ly_symbol2scm ("lyrics");
1161         }
1162         ;
1163
1164 mode_changing_head_with_context:
1165         DRUMS {
1166                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1167                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1168
1169                 $$ = ly_symbol2scm ("DrumStaff");
1170         }
1171         | FIGURES {
1172                 THIS->lexer_->push_figuredbass_state ();
1173
1174                 $$ = ly_symbol2scm ("FiguredBass");
1175         }
1176         | CHORDS {
1177                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1178                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1179                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1180                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1181                 $$ = ly_symbol2scm ("ChordNames");
1182         }
1183         | LYRICS
1184                 { THIS->lexer_->push_lyric_state ();
1185                 $$ = ly_symbol2scm ("Lyrics");
1186         }
1187         ;
1188
1189
1190 relative_music:
1191         RELATIVE absolute_pitch Music {
1192                 Music *m = $3;
1193                 Pitch start = *unsmob_pitch ($2);
1194                 $$ = make_music_relative (start, m);
1195                 scm_gc_unprotect_object (m->self_scm ());
1196         }
1197         | RELATIVE Composite_music {
1198                 Music *m = $2;
1199
1200                 Pitch middle_c (0, 0, 0);
1201                 $$ = make_music_relative (middle_c, m);
1202                 scm_gc_unprotect_object (m->self_scm ());
1203         }
1204         ;
1205
1206 new_lyrics:
1207         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1208         /*cont */
1209         Grouped_music_list {
1210         /* Can also use Music at the expensive of two S/Rs similar to
1211            \repeat \alternative */
1212                 THIS->lexer_->pop_state ();
1213
1214                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1215         }
1216         | new_lyrics ADDLYRICS {
1217                 THIS->lexer_->push_lyric_state ();
1218         } Grouped_music_list {
1219                 THIS->lexer_->pop_state ();
1220                 $$ = scm_cons ($4->self_scm (), $1);
1221         }
1222         ;
1223
1224 re_rhythmed_music:
1225         Grouped_music_list new_lyrics {
1226
1227                 SCM name = $1->get_property ("context-id");
1228                 //if (name == SCM_EOL)
1229                 if (!scm_is_string (name))
1230                         name = scm_makfrom0str ("");
1231
1232                 SCM context = scm_makfrom0str ("Lyrics");
1233                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1234
1235                 SCM lst = SCM_EOL;
1236                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1237                 {
1238                         Music *music = unsmob_music (ly_car (s));
1239                         Music *com = make_lyric_combine_music (name, music);
1240                         Music *csm = context_spec_music (context,
1241                                 get_next_unique_context (), com, SCM_EOL);
1242                         lst = scm_cons (csm->self_scm (), lst);
1243                 }
1244                 /* FIXME: only first lyric music is accepted,
1245                           the rest is junked */
1246                 all->set_property ("elements", scm_cons ($1->self_scm (),
1247                         lst));
1248                 $$ = all;
1249                 scm_gc_unprotect_object ($1->self_scm ());
1250         }
1251         | LYRICSTO {
1252                 THIS->lexer_->push_lyric_state ();
1253         } simple_string Music {
1254                 THIS->lexer_->pop_state ();
1255                 Music *music = $4;
1256                 SCM name = $3;
1257                 $$ = make_lyric_combine_music (name, music);
1258                 scm_gc_unprotect_object (music->self_scm ());
1259         }
1260         ;
1261
1262 context_change:
1263         CHANGE STRING '=' STRING  {
1264                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1265                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1266                 t-> set_property ("change-to-id", $4);
1267
1268                 $$ = t;
1269                 $$->set_spot (THIS->here_input ());
1270         }
1271         ;
1272
1273 property_operation:
1274         STRING '=' scalar {
1275                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1276                         scm_string_to_symbol ($1), $3);
1277         }
1278         | UNSET simple_string {
1279                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1280                         scm_string_to_symbol ($2));
1281         }
1282         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1283                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1284                         scm_string_to_symbol ($2), $3, $5);
1285         }
1286         | REVERT simple_string embedded_scm {
1287                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1288                         scm_string_to_symbol ($2), $3);
1289         }
1290         ;
1291
1292 context_def_mod:
1293         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1294         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1295
1296         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1297         | DENIES { $$ = ly_symbol2scm ("denies"); }
1298
1299         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1300         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1301         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1302         | NAME { $$ = ly_symbol2scm ("context-name"); }
1303         ;
1304
1305 context_mod:
1306         property_operation { $$ = $1; }
1307         | context_def_mod STRING {
1308                 $$ = scm_list_2 ($1, $2);
1309         }
1310         ;
1311
1312 context_prop_spec:
1313         simple_string {
1314                 if (!is_regular_identifier ($1))
1315                 {
1316                         THIS->here_input ().error (_("Grob name should be alphanumeric"));
1317                 }
1318
1319                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1320                         scm_string_to_symbol ($1));
1321         }
1322         | simple_string '.' simple_string {
1323                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1324                         scm_string_to_symbol ($3));
1325         }
1326         ;
1327
1328 music_property_def:
1329         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1330                 $$ = property_op_to_music (scm_list_4 (
1331                         ly_symbol2scm ("poppush"),
1332                         ly_cadr ($2),
1333                         $3, $5));
1334                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1335         }
1336         | REVERT context_prop_spec embedded_scm {
1337                 $$ = property_op_to_music (scm_list_3 (
1338                         ly_symbol2scm ("pop"),
1339                         ly_cadr ($2),
1340                         $3));
1341
1342                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1343         }
1344         | SET context_prop_spec '=' scalar {
1345                 $$ = property_op_to_music (scm_list_3 (
1346                         ly_symbol2scm ("assign"),
1347                         ly_cadr ($2),
1348                         $4));
1349                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1350         }
1351         | UNSET context_prop_spec {
1352                 $$ = property_op_to_music (scm_list_2 (
1353                         ly_symbol2scm ("unset"),
1354                         ly_cadr ($2)));
1355                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1356         }
1357         | ONCE music_property_def {
1358                 SCM e = $2->get_property ("element");
1359                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1360                 $$ = $2;
1361
1362         }
1363         ;
1364
1365
1366 string:
1367         STRING {
1368                 $$ = $1;
1369         }
1370         | STRING_IDENTIFIER {
1371                 $$ = $1;
1372         }
1373         | string '+' string {
1374                 $$ = scm_string_append (scm_list_2 ($1, $3));
1375         }
1376         ;
1377
1378 simple_string: STRING {
1379                 $$ = $1;
1380         }
1381         | LYRICS_STRING {
1382                 $$ = $1;
1383         }
1384         ;
1385
1386 scalar: string {
1387                 $$ = $1;
1388         }
1389         | LYRICS_STRING {
1390                 $$ = $1;
1391         }
1392         | bare_int {
1393                 $$ = scm_int2num ($1);
1394         }
1395         | embedded_scm {
1396                 $$ = $1;
1397         }
1398         | full_markup {
1399                 $$ = $1;
1400         }
1401         | DIGIT {
1402                 $$ = scm_int2num ($1);
1403         }
1404         ;
1405
1406 /*
1407
1408 pre_events doesn't contain anything. It is a trick:
1409
1410 Adding pre_events to the simple_element
1411 makes the choice between
1412
1413   string:  STRING
1414
1415 and
1416
1417   simple_element: STRING
1418
1419 a single shift/reduction conflict.
1420
1421 nevertheless, this is not very clean, and we should find a different
1422 solution.
1423
1424 */
1425 pre_events: {
1426                 THIS->push_spot ();
1427         }
1428         ;
1429
1430 event_chord:
1431         pre_events simple_element post_events   {
1432                 SCM elts = $2-> get_property ("elements");
1433
1434                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1435
1436                 $2->set_property ("elements", elts);
1437                 $$ = $2;
1438         }
1439         | command_element
1440         | note_chord_element
1441         ;
1442
1443
1444 note_chord_element:
1445         chord_body optional_notemode_duration post_events
1446         {
1447                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1448                 SCM es = $1->get_property ("elements");
1449                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1450
1451                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1452                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1453                 es = ly_append2 (es, postevs);
1454
1455                 $1-> set_property ("elements", es);
1456                 $$ = $1;
1457         }
1458         ;
1459
1460 chord_open: '<'
1461         ;
1462
1463 chord_close: '>'
1464         ;
1465
1466 simul_open: DOUBLE_ANGLE_OPEN
1467         ;
1468
1469 simul_close: DOUBLE_ANGLE_CLOSE
1470         ;
1471
1472 chord_body:
1473         chord_open chord_body_elements chord_close
1474         {
1475                 $$ = MY_MAKE_MUSIC ("EventChord");
1476                 $$->set_property ("elements",
1477                         scm_reverse_x ($2, SCM_EOL));
1478         }
1479         ;
1480
1481 chord_body_elements:
1482         /* empty */             { $$ = SCM_EOL; }
1483         | chord_body_elements chord_body_element {
1484                 $$ = scm_cons ($2->self_scm (), $1);
1485                 scm_gc_unprotect_object ($2->self_scm ());
1486         }
1487         ;
1488
1489 chord_body_element:
1490         pitch  exclamations questions octave_check post_events
1491         {
1492                 int q = $3;
1493                 int ex = $2;
1494                 SCM check = $4;
1495                 SCM post = $5;
1496
1497                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1498                 n->set_property ("pitch", $1);
1499                 if (q % 2)
1500                         n->set_property ("cautionary", SCM_BOOL_T);
1501                 if (ex % 2 || q % 2)
1502                         n->set_property ("force-accidental", SCM_BOOL_T);
1503
1504                 if (ly_c_pair_p (post)) {
1505                         SCM arts = scm_reverse_x (post, SCM_EOL);
1506                         n->set_property ("articulations", arts);
1507                 }
1508                 if (scm_is_number (check))
1509                 {
1510                         int q = scm_to_int (check);
1511                         n->set_property ("absolute-octave", scm_int2num (q-1));
1512                 }
1513
1514
1515                 $$ = n;
1516         }
1517         | DRUM_PITCH post_events {
1518                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1519                 n->set_property ("duration", $2);
1520                 n->set_property ("drum-type", $1);
1521                 n->set_spot (THIS->here_input ());
1522
1523                 if (ly_c_pair_p ($2)) {
1524                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1525                         n->set_property ("articulations", arts);
1526                 }
1527                 $$ = n;
1528         }
1529         ;
1530
1531 add_quote:
1532         ADDQUOTE string Music {
1533                 SCM adder = ly_scheme_function ("add-quotable");
1534
1535                 scm_call_2 (adder, $2, $3->self_scm ());
1536                 scm_gc_unprotect_object ($3->self_scm ());
1537         }
1538         ;
1539
1540 command_element:
1541         command_req {
1542                 $$ = MY_MAKE_MUSIC ("EventChord");
1543                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1544                 scm_gc_unprotect_object ($1->self_scm ());
1545
1546                 $$-> set_spot (THIS->here_input ());
1547                 $1-> set_spot (THIS->here_input ());
1548         }
1549         | SKIP duration_length {
1550                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1551                 skip->set_property ("duration", $2);
1552
1553                 $$ = skip;
1554         }
1555         | QUOTE STRING duration_length {
1556                 Music *quote = MY_MAKE_MUSIC ("QuoteMusic");
1557                 quote->set_property ("duration", $3);
1558                 quote->set_property ("quoted-music-name", $2);
1559                 quote->set_spot (THIS->here_input ());
1560
1561                 $$ = quote;
1562         }
1563         | OCTAVE { THIS->push_spot (); }
1564           pitch {
1565                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1566                 $$ = m;
1567                 $$->set_spot (THIS->pop_spot ());
1568                 $$->set_property ("pitch", $3);
1569         }
1570         | E_LEFTSQUARE {
1571                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1572                 m->set_property ("span-direction", scm_int2num (START));
1573                 m->set_spot (THIS->here_input ());
1574
1575                 $$ = MY_MAKE_MUSIC ("EventChord");
1576                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1577                 scm_gc_unprotect_object (m->self_scm ());
1578                 $$->set_spot (THIS->here_input ());
1579         }
1580         | E_RIGHTSQUARE {
1581                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1582                 m->set_property ("span-direction", scm_int2num (STOP));
1583                 m->set_spot (THIS->here_input ());
1584
1585                 $$ = MY_MAKE_MUSIC ("EventChord");
1586                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1587                 $$->set_spot (THIS->here_input ());
1588                 scm_gc_unprotect_object (m->self_scm ());
1589         }
1590         | E_BACKSLASH {
1591                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1592                 $$->set_spot (THIS->here_input ());
1593         }
1594         | '|'      {
1595                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1596
1597                 if (Music * m = unsmob_music (pipe))
1598                         $$ = m->clone ();
1599                 else
1600                         $$ = MY_MAKE_MUSIC ("BarCheck");
1601
1602                 $$->set_spot (THIS->here_input ());
1603         }
1604         | TRANSPOSITION pitch {
1605                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1606                                         $2);
1607                 $$->set_spot (THIS-> here_input ());
1608                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1609                         $$, SCM_EOL);
1610         }
1611         | BAR STRING                    {
1612                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1613
1614                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1615                                         t, SCM_EOL);
1616                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1617                 $$->set_spot (THIS->here_input ());
1618                 t->set_spot (THIS->here_input ());
1619         }
1620         | PARTIAL duration_length       {
1621                 Moment m = - unsmob_duration ($2)->get_length ();
1622                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1623                 p->set_spot (THIS->here_input ());
1624                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1625                                         p, SCM_EOL);
1626                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1627                                         p, SCM_EOL);
1628                 $$ = p;
1629         }
1630         | CLEF STRING  {
1631                 SCM proc = ly_scheme_function ("make-clef-set");
1632
1633                 SCM result = scm_call_1 (proc, $2);
1634                 scm_gc_protect_object (result);
1635                 $$ = unsmob_music (result);
1636         }
1637         | TIME_T fraction  {
1638                 SCM proc= ly_scheme_function ("make-time-signature-set");
1639
1640                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1641                 scm_gc_protect_object (result);
1642                 $$ = unsmob_music (result);
1643         }
1644         | MARK scalar {
1645                 SCM proc = ly_scheme_function ("make-mark-set");
1646
1647                 SCM result = scm_call_1 (proc, $2);
1648                 scm_gc_protect_object (result);
1649                 $$ = unsmob_music (result);
1650         }
1651         ;
1652
1653 command_req:
1654         E_TILDE {
1655                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1656         }
1657         | MARK DEFAULT  {
1658                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1659                 $$ = m;
1660         }
1661         | tempo_event {
1662                 $$ = $1;
1663         }
1664         | KEY DEFAULT {
1665                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1666                 $$ = key;
1667         }
1668         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1669
1670                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1671                 if (scm_ilength ($3) > 0)
1672                 {
1673                         key->set_property ("pitch-alist", $3);
1674                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1675                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1676                 } else {
1677                         THIS->parser_error (_ ("Second argument must be pitch list."));
1678                 }
1679
1680                 $$ = key;
1681         }
1682         ;
1683
1684 post_events:
1685         /* empty */ {
1686                 $$ = SCM_EOL;
1687         }
1688         | post_events post_event {
1689                 $2->set_spot (THIS->here_input ());
1690                 $$ = scm_cons ($2->self_scm (), $$);
1691                 scm_gc_unprotect_object ($2->self_scm ());
1692         }
1693         | post_events tagged_post_event {
1694                 $2 -> set_spot (THIS->here_input ());
1695                 $$ = scm_cons ($2->self_scm (), $$);
1696                 scm_gc_unprotect_object ($2->self_scm ());
1697         }
1698         ;
1699
1700
1701 tagged_post_event:
1702         '-' TAG embedded_scm post_event {
1703                 tag_music ($4, $3, THIS->here_input ());
1704                 $$ = $4;
1705         }
1706         ;
1707
1708 post_event:
1709         direction_less_event {
1710                 $$ = $1;
1711         }
1712         | HYPHEN {
1713                 if (!THIS->lexer_->is_lyric_state ())
1714                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1715                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1716         }
1717         | EXTENDER {
1718                 if (!THIS->lexer_->is_lyric_state ())
1719                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1720                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1721         }
1722         | script_dir direction_reqd_event {
1723                 if ($1)
1724                         $2->set_property ("direction", scm_int2num ($1));
1725                 $$ = $2;
1726         }
1727         | script_dir direction_less_event {
1728                 if ($1)
1729                         $2->set_property ("direction", scm_int2num ($1));
1730                 $$ = $2;
1731         }
1732         | string_number_event
1733         ;
1734
1735 string_number_event:
1736         E_UNSIGNED {
1737                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1738                 s->set_property ("string-number", scm_int2num ($1));
1739                 s->set_spot (THIS->here_input ());
1740                 $$ = s;
1741         }
1742         ;
1743
1744 direction_less_char:
1745         '['  {
1746                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1747         }
1748         | ']'  {
1749                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1750         }
1751         | '~'  {
1752                 $$ = ly_symbol2scm ("tildeSymbol");
1753         }
1754         | '('  {
1755                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1756         }
1757         | ')'  {
1758                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1759         }
1760         | E_EXCLAMATION  {
1761                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1762         }
1763         | E_OPEN  {
1764                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1765         }
1766         | E_CLOSE  {
1767                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1768         }
1769         | E_BIGGER  {
1770                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1771         }
1772         | E_SMALLER  {
1773                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1774         }
1775         ;
1776
1777 direction_less_event:
1778         direction_less_char {
1779                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1780                 Music * m = 0;
1781                 if (unsmob_music (predefd))
1782                 {
1783                         m = unsmob_music (predefd)->clone ();
1784                 }
1785                 else
1786                 {
1787                         m = MY_MAKE_MUSIC ("Music");
1788                 }
1789                 m->set_spot (THIS->here_input ());
1790                 $$ = m;
1791         }
1792         | EVENT_IDENTIFIER      {
1793                 $$ = unsmob_music ($1);
1794         }
1795         | tremolo_type  {
1796                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1797                a->set_spot (THIS->here_input ());
1798                a->set_property ("tremolo-type", scm_int2num ($1));
1799                $$ = a;
1800         }
1801         ;
1802
1803 direction_reqd_event:
1804         gen_text_def {
1805                 $$ = $1;
1806         }
1807         | script_abbreviation {
1808                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1809                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1810                 if (scm_is_string (s))
1811                         a->set_property ("articulation-type", s);
1812                 else THIS->parser_error (_ ("Expecting string as script definition"));
1813                 $$ = a;
1814         }
1815         ;
1816
1817 octave_check:
1818         /**/ { $$ = SCM_EOL; }
1819         | '='  { $$ = scm_int2num (0); }
1820         | '=' sub_quotes { $$ = scm_int2num ($2); }
1821         | '=' sup_quotes { $$ = scm_int2num ($2); }
1822         ;
1823
1824 sup_quotes:
1825         '\'' {
1826                 $$ = 1;
1827         }
1828         | sup_quotes '\'' {
1829                 $$ ++;
1830         }
1831         ;
1832
1833 sub_quotes:
1834         ',' {
1835                 $$ = 1;
1836         }
1837         | sub_quotes ',' {
1838                 $$++;
1839         }
1840         ;
1841
1842 steno_pitch:
1843         NOTENAME_PITCH  {
1844                 $$ = $1;
1845         }
1846         | NOTENAME_PITCH sup_quotes     {
1847                 Pitch p = *unsmob_pitch ($1);
1848                 p = p.transposed (Pitch ($2,0,0));
1849                 $$ = p.smobbed_copy ();
1850         }
1851         | NOTENAME_PITCH sub_quotes      {
1852                 Pitch p =* unsmob_pitch ($1);
1853                 p = p.transposed (Pitch (-$2,0,0));
1854                 $$ = p.smobbed_copy ();
1855         }
1856         ;
1857
1858 /*
1859 ugh. duplication
1860 */
1861
1862 steno_tonic_pitch:
1863         TONICNAME_PITCH {
1864                 $$ = $1;
1865         }
1866         | TONICNAME_PITCH sup_quotes    {
1867                 Pitch p = *unsmob_pitch ($1);
1868                 p = p.transposed (Pitch ($2,0,0));
1869                 $$ = p.smobbed_copy ();
1870         }
1871         | TONICNAME_PITCH sub_quotes     {
1872                 Pitch p =* unsmob_pitch ($1);
1873
1874                 p = p.transposed (Pitch (-$2,0,0));
1875                 $$ = p.smobbed_copy ();
1876         }
1877         ;
1878
1879 pitch:
1880         steno_pitch {
1881                 $$ = $1;
1882         }
1883         ;
1884
1885 pitch_also_in_chords:
1886         pitch
1887         | steno_tonic_pitch
1888         ;
1889
1890 gen_text_def:
1891         full_markup {
1892                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1893                 t->set_property ("text", $1);
1894                 t->set_spot (THIS->here_input ());
1895                 $$ = t;
1896         }
1897         | string {
1898                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1899                 t->set_property ("text",
1900                         make_simple_markup (THIS->lexer_->encoding (), $1));
1901                 t->set_spot (THIS->here_input ());
1902                 $$ = t;
1903
1904         }
1905         | DIGIT {
1906                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1907                 t->set_property ("digit", scm_int2num ($1));
1908                 t->set_spot (THIS->here_input ());
1909                 $$ = t;
1910         }
1911         ;
1912
1913 script_abbreviation:
1914         '^'             {
1915                 $$ = scm_makfrom0str ("Hat");
1916         }
1917         | '+'           {
1918                 $$ = scm_makfrom0str ("Plus");
1919         }
1920         | '-'           {
1921                 $$ = scm_makfrom0str ("Dash");
1922         }
1923         | '|'           {
1924                 $$ = scm_makfrom0str ("Bar");
1925         }
1926         | '>'           {
1927                 $$ = scm_makfrom0str ("Larger");
1928         }
1929         | '.'           {
1930                 $$ = scm_makfrom0str ("Dot");
1931         }
1932         | '_' {
1933                 $$ = scm_makfrom0str ("Underscore");
1934         }
1935         ;
1936
1937 script_dir:
1938         '_'     { $$ = DOWN; }
1939         | '^'   { $$ = UP; }
1940         | '-'   { $$ = CENTER; }
1941         ;
1942
1943
1944 absolute_pitch:
1945         steno_pitch     {
1946                 $$ = $1;
1947         }
1948         ;
1949
1950 duration_length:
1951         multiplied_duration {
1952                 $$ = $1;
1953         }
1954         ;
1955
1956 optional_notemode_duration:
1957         {
1958                 Duration dd = THIS->default_duration_;
1959                 $$ = dd.smobbed_copy ();
1960
1961                 THIS->beam_check ($$);
1962         }
1963         | multiplied_duration   {
1964                 $$ = $1;
1965                 THIS->default_duration_ = *unsmob_duration ($$);
1966
1967                 THIS->beam_check ($$);
1968         }
1969         ;
1970
1971 steno_duration:
1972         bare_unsigned dots              {
1973                 int len = 0;
1974                 if (!is_duration ($1))
1975                         THIS->parser_error (_f ("not a duration: %d", $1));
1976                 else
1977                         len = intlog2 ($1);
1978
1979                 $$ = Duration (len, $2).smobbed_copy ();
1980         }
1981         | DURATION_IDENTIFIER dots      {
1982                 Duration *d = unsmob_duration ($1);
1983                 Duration k (d->duration_log (), d->dot_count () + $2);
1984                 *d = k;
1985                 $$ = $1;
1986         }
1987         ;
1988
1989 multiplied_duration:
1990         steno_duration {
1991                 $$ = $1;
1992         }
1993         | multiplied_duration '*' bare_unsigned {
1994                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1995         }
1996         | multiplied_duration '*' FRACTION {
1997                 Rational  m (scm_to_int (ly_car ($3)), scm_to_int (ly_cdr ($3)));
1998
1999                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2000         }
2001         ;
2002
2003 fraction:
2004         FRACTION { $$ = $1; }
2005         | UNSIGNED '/' UNSIGNED {
2006                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2007         }
2008         ;
2009
2010 dots:
2011         /* empty */     {
2012                 $$ = 0;
2013         }
2014         | dots '.' {
2015                 $$ ++;
2016         }
2017         ;
2018
2019 tremolo_type:
2020         ':'     {
2021                 $$ = 0;
2022         }
2023         | ':' bare_unsigned {
2024                 if (!is_duration ($2))
2025                         THIS->parser_error (_f ("not a duration: %d", $2));
2026                 $$ = $2;
2027         }
2028         ;
2029
2030 bass_number:
2031         DIGIT   {
2032                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2033                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2034                                 $$);
2035         }
2036         | UNSIGNED {
2037                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2038                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2039                                 $$);
2040         }
2041         | STRING { $$ = $1; }
2042         ;
2043
2044 bass_mod:
2045         '-'     { $$ = -2; }
2046         | '+'   { $$ = 2; }
2047         | '!'   { $$ = 0; }
2048         ;
2049
2050 bass_figure:
2051         FIGURE_SPACE {
2052                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2053                 $$ = bfr->self_scm ();
2054                 scm_gc_unprotect_object ($$);
2055         }
2056         | bass_number  {
2057                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2058                 $$ = bfr->self_scm ();
2059
2060                 bfr->set_property ("figure", $1);
2061
2062                 scm_gc_unprotect_object ($$);
2063         }
2064         | bass_figure bass_mod {
2065                 Music *m = unsmob_music ($1);
2066                 if ($2) {
2067                         SCM salter = m->get_property ("alteration");
2068                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2069                         m->set_property ("alteration",
2070                                 scm_int2num (alter + $2));
2071                 } else {
2072                         m->set_property ("alteration", scm_int2num (0));
2073                 }
2074         }
2075         ;
2076
2077 br_bass_figure:
2078         '[' bass_figure {
2079                 $$ = $2;
2080                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2081         }
2082         | bass_figure   {
2083                 $$ = $1;
2084         }
2085         | br_bass_figure ']' {
2086                 $$ = $1;
2087                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2088         }
2089         ;
2090
2091 figure_list:
2092         /**/            {
2093                 $$ = SCM_EOL;
2094         }
2095         | figure_list br_bass_figure {
2096                 $$ = scm_cons ($2, $1);
2097         }
2098         ;
2099
2100 figure_spec:
2101         FIGURE_OPEN figure_list FIGURE_CLOSE {
2102                 Music *m = MY_MAKE_MUSIC ("EventChord");
2103                 $2 = scm_reverse_x ($2, SCM_EOL);
2104                 m->set_property ("elements", $2);
2105                 $$ = m->self_scm ();
2106         }
2107         ;
2108
2109
2110 optional_rest:
2111         /**/   { $$ = 0; }
2112         | REST { $$ = 1; }
2113         ;
2114
2115 simple_element:
2116         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2117
2118                 Input i = THIS->pop_spot ();
2119                 if (!THIS->lexer_->is_note_state ())
2120                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2121
2122                 Music *n = 0;
2123                 if ($6)
2124                         n = MY_MAKE_MUSIC ("RestEvent");
2125                 else
2126                         n = MY_MAKE_MUSIC ("NoteEvent");
2127
2128                 n->set_property ("pitch", $1);
2129                 n->set_property ("duration", $5);
2130
2131                 if (scm_is_number ($4))
2132                 {
2133                         int q = scm_to_int ($4);
2134                         n->set_property ("absolute-octave", scm_int2num (q-1));
2135                 }
2136
2137                 if ($3 % 2)
2138                         n->set_property ("cautionary", SCM_BOOL_T);
2139                 if ($2 % 2 || $3 % 2)
2140                         n->set_property ("force-accidental", SCM_BOOL_T);
2141
2142                 Music *v = MY_MAKE_MUSIC ("EventChord");
2143                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2144                 scm_gc_unprotect_object (n->self_scm ());
2145
2146                 v->set_spot (i);
2147                 n->set_spot (i);
2148                 $$ = v;
2149         }
2150         | DRUM_PITCH optional_notemode_duration {
2151                 Input i = THIS->pop_spot ();
2152
2153                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2154                 n->set_property ("duration", $2);
2155                 n->set_property ("drum-type", $1);
2156
2157                 Music *v = MY_MAKE_MUSIC ("EventChord");
2158                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2159                 scm_gc_unprotect_object (n->self_scm ());
2160                 v->set_spot (i);
2161                 n->set_spot (i);
2162                 $$ = v;
2163
2164         }
2165         | figure_spec optional_notemode_duration {
2166                 Music *m = unsmob_music ($1);
2167                 Input i = THIS->pop_spot ();
2168                 m->set_spot (i);
2169                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2170                 {
2171                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2172                 }
2173                 $$ = m;
2174         }
2175         | RESTNAME optional_notemode_duration           {
2176
2177                 Input i = THIS->pop_spot ();
2178                 Music *ev = 0;
2179                 if (ly_scm2string ($1) == "s") {
2180                         /* Space */
2181                         ev = MY_MAKE_MUSIC ("SkipEvent");
2182                   }
2183                 else {
2184                         ev = MY_MAKE_MUSIC ("RestEvent");
2185
2186                     }
2187                 ev->set_property ("duration", $2);
2188                 ev->set_spot (i);
2189                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2190                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2191                 velt->set_spot (i);
2192
2193                 scm_gc_unprotect_object (ev->self_scm ());
2194
2195                 $$ = velt;
2196         }
2197         | MULTI_MEASURE_REST optional_notemode_duration         {
2198                 THIS->pop_spot ();
2199
2200                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2201                 SCM mus = scm_call_2 (proc, $2,
2202                         make_input (THIS->here_input ()));
2203                 scm_gc_protect_object (mus);
2204                 $$ = unsmob_music (mus);
2205         }
2206
2207         | lyric_element optional_notemode_duration      {
2208                 Input i = THIS->pop_spot ();
2209                 if (!THIS->lexer_->is_lyric_state ())
2210                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2211
2212                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2213                 lreq->set_property ("text", $1);
2214                 lreq->set_property ("duration",$2);
2215                 lreq->set_spot (i);
2216                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2217                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2218
2219                 $$= velt;
2220         }
2221         | new_chord {
2222                 THIS->pop_spot ();
2223
2224                 if (!THIS->lexer_->is_chord_state ())
2225                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2226                 $$ = unsmob_music ($1);
2227         }
2228         ;
2229
2230 lyric_element:
2231         /* FIXME: lyric flavoured markup would be better */
2232         full_markup {
2233                 $$ = $1;
2234         }
2235         | LYRICS_STRING {
2236                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2237         }
2238         ;
2239
2240 new_chord:
2241         steno_tonic_pitch optional_notemode_duration   {
2242                 $$ = make_chord ($1, $2, SCM_EOL);
2243         }
2244         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2245                 SCM its = scm_reverse_x ($4, SCM_EOL);
2246                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2247         }
2248         ;
2249
2250 chord_items:
2251         /**/ {
2252                 $$ = SCM_EOL;
2253         }
2254         | chord_items chord_item {
2255                 $$ = scm_cons ($2, $$);
2256         }
2257         ;
2258
2259 chord_separator:
2260         CHORD_COLON {
2261                 $$ = ly_symbol2scm ("chord-colon");
2262         }
2263         | CHORD_CARET {
2264                 $$ = ly_symbol2scm ("chord-caret");
2265         }
2266         | CHORD_SLASH steno_tonic_pitch {
2267                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2268         }
2269         | CHORD_BASS steno_tonic_pitch {
2270                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2271         }
2272         ;
2273
2274 chord_item:
2275         chord_separator {
2276                 $$ = $1;
2277         }
2278         | step_numbers {
2279                 $$ = scm_reverse_x ($1, SCM_EOL);
2280         }
2281         | CHORD_MODIFIER  {
2282                 $$ = $1;
2283         }
2284         ;
2285
2286 step_numbers:
2287         step_number { $$ = scm_cons ($1, SCM_EOL); }
2288         | step_numbers '.' step_number {
2289                 $$ = scm_cons ($3, $$);
2290         }
2291         ;
2292
2293 step_number:
2294         bare_unsigned {
2295                 $$ = make_chord_step ($1, 0);
2296         }
2297         | bare_unsigned '+' {
2298                 $$ = make_chord_step ($1, SHARP);
2299         }
2300         | bare_unsigned CHORD_MINUS {
2301                 $$ = make_chord_step ($1, FLAT);
2302         }
2303         ;
2304
2305 /*
2306         UTILITIES
2307
2308 TODO: should deprecate in favor of Scheme?
2309
2310  */
2311 number_expression:
2312         number_expression '+' number_term {
2313                 $$ = scm_sum ($1, $3);
2314         }
2315         | number_expression '-' number_term {
2316                 $$ = scm_difference ($1, $3);
2317         }
2318         | number_term
2319         ;
2320
2321 number_term:
2322         number_factor {
2323                 $$ = $1;
2324         }
2325         | number_factor '*' number_factor {
2326                 $$ = scm_product ($1, $3);
2327         }
2328         | number_factor '/' number_factor {
2329                 $$ = scm_divide ($1, $3);
2330         }
2331         ;
2332
2333 number_factor:
2334         '-'  number_factor { /* %prec UNARY_MINUS */
2335                 $$ = scm_difference ($2, SCM_UNDEFINED);
2336         }
2337         | bare_number
2338         ;
2339
2340
2341 bare_number:
2342         UNSIGNED        {
2343                 $$ = scm_int2num ($1);
2344         }
2345         | REAL          {
2346                 $$ = $1;
2347         }
2348         | NUMBER_IDENTIFIER             {
2349                 $$ = $1;
2350         }
2351         | REAL NUMBER_IDENTIFIER        {
2352                 $$ = scm_make_real (scm_to_double ($1) *scm_to_double ($2));
2353         }
2354         | UNSIGNED NUMBER_IDENTIFIER    {
2355                 $$ = scm_make_real ($1 *scm_to_double ($2));
2356         }
2357         ;
2358
2359
2360 bare_unsigned:
2361         UNSIGNED {
2362                         $$ = $1;
2363         }
2364         | DIGIT {
2365                 $$ = $1;
2366         }
2367         ;
2368
2369 bare_int:
2370         bare_number {
2371                 if (scm_integer_p ($1) == SCM_BOOL_T)
2372                 {
2373                         int k = scm_to_int ($1);
2374                         $$ = k;
2375                 } else
2376                 {
2377                         THIS->parser_error (_ ("need integer number arg"));
2378                         $$ = 0;
2379                 }
2380         }
2381         | '-' bare_int {
2382                 $$ = -$2;
2383         }
2384         ;
2385
2386 exclamations:
2387                 { $$ = 0; }
2388         | exclamations '!'      { $$ ++; }
2389         ;
2390
2391 questions:
2392                 { $$ = 0; }
2393         | questions '?' { $$ ++; }
2394         ;
2395
2396
2397
2398 full_markup:
2399         MARKUP_IDENTIFIER {
2400                 $$ = $1;
2401         }
2402         | MARKUP
2403                 { THIS->lexer_->push_markup_state (); }
2404         markup
2405                 { $$ = $3;
2406                   THIS->lexer_->pop_state ();
2407                 }
2408         ;
2409
2410
2411 /*
2412 This should be done more dynamically if possible.
2413 */
2414 markup:
2415         STRING {
2416                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2417         }
2418         | MARKUP_HEAD_EMPTY {
2419                 $$ = scm_list_1 ($1);
2420         }
2421         | MARKUP_HEAD_MARKUP0 markup {
2422                 $$ = scm_list_2 ($1, $2);
2423         }
2424         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2425                 $$ = scm_list_3 ($1, $2, $3);
2426         }
2427         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2428                 $$ = scm_list_3 ($1, $2, $3);
2429         }
2430         | markup_line {
2431                 $$ = $1;
2432         }
2433         | MARKUP_HEAD_LIST0 markup_list {
2434                 $$ = scm_list_2 ($1,$2);
2435         }
2436         | MARKUP_HEAD_SCM0 embedded_scm {
2437                 $$ = scm_list_2 ($1, $2);
2438         }
2439         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2440                 $$ = scm_list_4 ($1, $2, $3, $4);
2441         }
2442         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2443                 $$ = scm_list_4 ($1, $2, $3, $4);
2444         }
2445         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2446                 $$ = scm_list_3 ($1, $2, $3);
2447         }
2448         | MARKUP_IDENTIFIER {
2449                 $$ = $1;
2450         }
2451         | STRING_IDENTIFIER {
2452                 $$ = $1;
2453         }
2454         | SCORE {
2455                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2456                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2457         } '{' score_body '}' {
2458                 Score * sc = $4;
2459                 $$ = scm_list_2 (ly_scheme_function ("score-markup"), sc->self_scm ());
2460                 scm_gc_unprotect_object (sc->self_scm ());
2461                 THIS->lexer_->pop_state ();
2462         }
2463         ;
2464
2465 markup_list:
2466         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2467         ;
2468
2469 markup_line:
2470         '{' markup_list_body '}' {
2471                 SCM line = ly_scheme_function ("line-markup");
2472
2473                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2474         }
2475         ;
2476
2477 markup_list_body:
2478         /**/ {  $$ = SCM_EOL; }
2479         | markup_list_body markup {
2480                 $$ = scm_cons ($2, $1);
2481         }
2482         ;
2483
2484
2485 %%
2486
2487 void
2488 Lily_parser::set_yydebug (bool )
2489 {
2490 #if 0
2491         yydebug = 1;
2492 #endif
2493 }
2494
2495 void
2496 Lily_parser::do_yyparse ()
2497 {
2498         yyparse ((void*)this);
2499 }
2500
2501
2502 /*
2503 Should make this optional?    It will also complain when you do
2504
2505         [s4]
2506
2507 which is entirely legitimate.
2508
2509 Or we can scrap it. Barchecks should detect wrong durations, and
2510 skipTypesetting speeds it up a lot.
2511 */
2512
2513 void
2514 Lily_parser::beam_check (SCM dur)
2515 {
2516   Duration *d = unsmob_duration (dur);
2517   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2518     {
2519       Music *m = unsmob_music (last_beam_start_);
2520       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2521     }
2522   last_beam_start_ = SCM_EOL;
2523 }
2524
2525
2526
2527
2528 /*
2529
2530 It is a little strange to have this function in this file, but
2531 otherwise, we have to import music classes into the lexer.
2532
2533 */
2534 int
2535 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2536 {
2537         if (scm_is_string (sid)) {
2538                 *destination = sid;
2539                 return STRING_IDENTIFIER;
2540         } else if (scm_is_number (sid)) {
2541                 *destination = sid;
2542                 return NUMBER_IDENTIFIER;
2543         } else if (unsmob_context_def (sid)) {
2544                 *destination = unsmob_context_def (sid)->clone_scm ();
2545                 return CONTEXT_DEF_IDENTIFIER;
2546         } else if (unsmob_score (sid)) {
2547                 Score *score = new Score (*unsmob_score (sid));
2548                 *destination = score->self_scm ();
2549                 return SCORE_IDENTIFIER;
2550         } else if (Music *mus = unsmob_music (sid)) {
2551                 mus = mus->clone ();
2552                 *destination = mus->self_scm ();
2553                 unsmob_music (*destination)->
2554                         set_property ("origin", make_input (last_input_));
2555                 return dynamic_cast<Event*> (mus)
2556                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2557         } else if (unsmob_duration (sid)) {
2558                 *destination = unsmob_duration (sid)->smobbed_copy ();
2559                 return DURATION_IDENTIFIER;
2560         } else if (unsmob_output_def (sid)) {
2561                 Output_def *p = unsmob_output_def (sid);
2562                 p = p->clone ();
2563
2564                 *destination = p->self_scm ();
2565                 return OUTPUT_DEF_IDENTIFIER;
2566         } else if (Text_item::markup_p (sid)) {
2567                 *destination = sid;
2568                 return MARKUP_IDENTIFIER;
2569         }
2570
2571         return -1;
2572 }
2573
2574 Music *
2575 property_op_to_music (SCM op)
2576 {
2577         Music *m = 0;
2578         SCM tag = ly_car (op);
2579         SCM symbol = ly_cadr (op);
2580         SCM args = ly_cddr (op);
2581         SCM grob_val = SCM_UNDEFINED;
2582         SCM grob_sym = SCM_UNDEFINED;
2583         SCM val = SCM_UNDEFINED;
2584
2585         if (tag == ly_symbol2scm ("assign"))
2586                 {
2587                 m = MY_MAKE_MUSIC ("PropertySet");
2588                 val = ly_car (args);
2589                 }
2590         else if (tag == ly_symbol2scm ("unset"))
2591                 m = MY_MAKE_MUSIC ("PropertyUnset");
2592         else if (tag == ly_symbol2scm ("poppush")
2593                  || tag == ly_symbol2scm ("push"))
2594                 {
2595                 m = MY_MAKE_MUSIC ("OverrideProperty");
2596                 grob_sym = ly_car (args);
2597                 grob_val = ly_cadr (args);
2598                 }
2599         else if (tag == ly_symbol2scm ("pop")) {
2600                 m = MY_MAKE_MUSIC ("RevertProperty");
2601                 grob_sym = ly_car (args);
2602                 }
2603
2604         m->set_property ("symbol", symbol);
2605
2606         if (val != SCM_UNDEFINED)
2607                 m->set_property ("value", val);
2608         if (grob_val != SCM_UNDEFINED)
2609                 m->set_property ("grob-value", grob_val);
2610
2611         if (grob_sym != SCM_UNDEFINED)
2612                 {
2613                 bool itc = internal_type_checking_global_b;
2614                 /* UGH.
2615                 */
2616                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2617                 if (autobeam)
2618                         internal_type_checking_global_b = false;
2619                 m->set_property ("grob-property", grob_sym);
2620                 if (autobeam)
2621                         internal_type_checking_global_b = itc;
2622                 }
2623
2624         if (tag == ly_symbol2scm ("poppush"))
2625                 m->set_property ("pop-first", SCM_BOOL_T);
2626
2627
2628         return m;
2629 }
2630
2631 Music*
2632 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2633 {
2634         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2635
2636         csm->set_property ("element", m->self_scm ());
2637         scm_gc_unprotect_object (m->self_scm ());
2638
2639         csm->set_property ("context-type",
2640                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2641         csm->set_property ("property-operations", ops);
2642
2643         if (scm_is_string (id))
2644                 csm->set_property ("context-id", id);
2645         return csm;
2646 }
2647
2648 /*
2649 FIXME: this should be postponed until the music hits \Score
2650 */
2651 SCM
2652 get_next_unique_context ()
2653 {
2654         static int new_context_count;
2655         char s[1024];
2656         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2657         return scm_makfrom0str (s);
2658 }
2659