lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29
  30 #include "context-def.hh"
  31 #include "dimensions.hh"
  32 #include "event.hh"
  33 #include "file-path.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "lily-lexer.hh"
  44 #include "lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "output-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((Lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (scm_is_symbol (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (scm_is_symbol (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
 123         p->internal_set_property (scm_caar (k), scm_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (scm_is_pair (x) && ly_c_procedure_p (scm_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left ADDLYRICS
 193
 194 %union {
 195         Book *book;
 196         Output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         Lily_parser *pars = (Lily_parser*) v;
 209         Lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226   (what? --hwn)
 227
 228 3. \markup { }
 229
 230   (what? --hwn)
 231
 232
 233 4.  \repeat
 234         \repeat .. \alternative
 235
 236
 237     \repeat { \repeat .. \alternative }
 238
 239 or
 240
 241     \repeat { \repeat } \alternative
 242
 243 )
 244  */
 245
 246
 247 %pure_parser
 248
 249 %token ACCEPTS
 250 %token ADDQUOTE
 251 %token LYRICSTO
 252 %token ALIAS
 253 %token ALTERNATIVE
 254 %token BAR
 255 %token BOOK
 256 %token BOOKPAPER
 257 %token CHANGE
 258 %token CHORDMODIFIERS
 259 %token CHORDS
 260 %token CHORDMODE
 261 %token DOUBLE_ANGLE_OPEN
 262 %token DOUBLE_ANGLE_CLOSE
 263 %token CLEF
 264 %token COMMANDSPANREQUEST
 265 %token CONSISTS
 266 %token CONTEXT
 267 %token DEFAULT
 268 %token DENIES
 269 %token DESCRIPTION
 270 %token EXTENDER
 271 %token FIGURES
 272 %token FIGUREMODE
 273 %token FIGURE_OPEN FIGURE_CLOSE
 274 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 275 %token GROBDESCRIPTIONS
 276 %token HEADER
 277 %token HYPHEN
 278 %token INVALID
 279 %token KEY
 280 %token LYRICS
 281 %token LYRICMODE
 282 %token MARK
 283 %token MIDI
 284 %token MULTI_MEASURE_REST
 285 %token NAME
 286 %token NEWCONTEXT
 287 %token NOTEMODE
 288 %token OCTAVE
 289 %token ONCE
 290 %token OVERRIDE SET REVERT
 291 %token PAPER
 292 %token PARTIAL
 293 %token QUOTE
 294 %token RELATIVE
 295 %token REMOVE
 296 %token REPEAT
 297 %token REST
 298 %token SCM_T
 299 %token SCORE
 300 %token SEQUENTIAL
 301 %token ADDLYRICS
 302 %token SIMULTANEOUS
 303 %token SKIP
 304 %token SPANREQUEST
 305 %token TAG
 306 %token TEMPO
 307 %token TIMES
 308 %token TIME_T
 309 %token TRANSPOSE
 310 %token TRANSPOSITION
 311 %token TYPE
 312 %token UNSET
 313 %token WITH
 314 %token MARKUP
 315
 316 /* escaped */
 317 /* FIXME: this sucks.  The user will get to see these names:
 318     syntax error, unexpected E_CHAR:
 319                 \
 320                  %%
 321   */
 322
 323 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 324 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 325 %token E_BACKSLASH
 326 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 327 %token FIGURE_SPACE
 328
 329 %token <i>      DIGIT
 330 %token <i>      UNSIGNED
 331 %token <i> E_UNSIGNED
 332 %token <id>     IDENTIFIER
 333 %token <scm>    CHORDMODIFIER_PITCH
 334 %token <scm>    DRUM_PITCH
 335 %token <scm>    DURATION_IDENTIFIER
 336 %token <scm>    EVENT_IDENTIFIER
 337 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 338 %token <scm>    NOTENAME_PITCH
 339 %token <scm>    NUMBER_IDENTIFIER
 340 %token <scm>    OUTPUT_DEF_IDENTIFIER
 341 %token <scm>    RESTNAME
 342 %token <scm> LYRICS_STRING
 343 %token <scm>    SCM_T
 344 %token <scm>    SCORE_IDENTIFIER
 345 %token <scm>    STRING
 346 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 347 %token <scm>    TONICNAME_PITCH
 348 %token <scm>    CHORD_MODIFIER
 349 %token <scm>    FRACTION
 350 %token <scm>   REAL
 351 %token <scm> MARKUP_HEAD_EMPTY
 352 %token <scm> MARKUP_HEAD_MARKUP0
 353 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 354 %token <scm> MARKUP_HEAD_SCM0
 355 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 356 %token <scm> MARKUP_HEAD_SCM0_SCM1
 357 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 358 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 359 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 360 %token <scm> MUSIC_FUNCTION
 361 %token <scm> MUSIC_FUNCTION_MUSIC
 362 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 363 %token <scm> MUSIC_FUNCTION_SCM
 364 %token <scm> MUSIC_FUNCTION_SCM_SCM
 365 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 366 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 367 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 368
 369 %token DRUMS
 370 %token DRUMMODE
 371
 372
 373 %type <book>    book_block book_body
 374 %type <i>       bare_int  bare_unsigned
 375 %type <i>       exclamations questions dots optional_rest
 376 %type <i>       script_dir
 377 %type <i>       sub_quotes sup_quotes
 378 %type <i>       tremolo_type
 379 %type <i>       bass_mod
 380
 381 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 382 %type <music>   Grouped_music_list
 383 %type <music>   Music Sequential_music Simultaneous_music
 384 %type <music>   Repeated_music
 385 %type <music>   command_req
 386 %type <music>   gen_text_def direction_less_event direction_reqd_event
 387 %type <music>   music_property_def context_change
 388 %type <music>   note_chord_element chord_body chord_body_element
 389 %type <music>   post_event tagged_post_event
 390 %type <music>   relative_music re_rhythmed_music
 391 %type <music>   simple_element event_chord command_element
 392 %type <music>   string_number_event
 393 %type <music>   toplevel_music
 394 %type <music>   tempo_event
 395
 396 %type <outputdef>       output_def_body output_def_head
 397 %type <outputdef> output_def book_paper_block
 398
 399 %type <scm>     Music_list
 400 %type <scm>     chord_body_elements
 401 %type <scm>     chord_item chord_items chord_separator new_chord
 402 %type <scm>     context_def_spec_block context_def_spec_body
 403 %type <scm>     context_mod context_def_mod optional_context_mod
 404 %type <scm>     context_prop_spec
 405 %type <scm>     direction_less_char
 406 %type <scm>     duration_length fraction
 407 %type <scm>     embedded_scm scalar
 408 %type <scm>     identifier_init
 409 %type <scm>     lilypond_header lilypond_header_body
 410 %type <scm>     new_lyrics
 411 %type <scm>     post_events
 412 %type <scm>     property_operation
 413 %type <scm>     script_abbreviation
 414 %type <scm>     simple_string
 415 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 416 %type <scm>     steno_tonic_pitch
 417 %type <scm>     step_number step_numbers
 418 %type <scm>     string bare_number number_expression number_term number_factor
 419 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 420 %type <scm>     context_mod_list
 421 %type <scm>     octave_check
 422 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 423 %type <scm>     Generic_prefix_music_scm
 424 %type <scm>     lyric_element
 425 %type <scm>     Alternative_music
 426 %type <scm>     markup markup_line markup_list markup_list_body full_markup
 427 %type <scm>     mode_changing_head
 428 %type <scm>     mode_changing_head_with_context
 429
 430 %type <score>   score_block score_body
 431
 432
 433 %left '-' '+'
 434
 435 /* We don't assign precedence to / and *, because we might need varied
 436 prec levels in different prods */
 437
 438 %left UNARY_MINUS
 439
 440 %%
 441
 442 lilypond:       /* empty */
 443         | lilypond toplevel_expression {
 444         }
 445         | lilypond assignment {
 446         }
 447         | lilypond error {
 448                 THIS->error_level_ = 1;
 449         }
 450         | lilypond INVALID      {
 451                 THIS->error_level_ = 1;
 452         }
 453         ;
 454
 455 toplevel_expression:
 456         lilypond_header {
 457                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 458         }
 459         | add_quote {
 460
 461         }
 462         | book_block {
 463                 Book *book = $1;
 464                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 465                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 466                 scm_gc_unprotect_object (book->self_scm ());
 467         }
 468         | score_block {
 469                 Score *score = $1;
 470
 471                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 472                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 473                 scm_gc_unprotect_object (score->self_scm ());
 474         }
 475         | toplevel_music {
 476                 Music *music = $1;
 477                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 478                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 479                 scm_gc_unprotect_object (music->self_scm ());
 480         }
 481         | output_def {
 482                 SCM id = SCM_EOL;
 483                 Output_def * od = $1;
 484
 485                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 486                         id = ly_symbol2scm ("$defaultpaper");
 487                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 488                         id = ly_symbol2scm ("$defaultmidi");
 489                 else if ($1->c_variable ("is-bookpaper") == SCM_BOOL_T)
 490                         id = ly_symbol2scm ("$defaultbookpaper");
 491
 492                 THIS->lexer_->set_identifier (id, od->self_scm ());
 493                 scm_gc_unprotect_object (od->self_scm ());
 494         }
 495         ;
 496
 497 toplevel_music:
 498         Composite_music {
 499         }
 500         ;
 501
 502 embedded_scm:
 503         SCM_T
 504         | SCM_IDENTIFIER
 505         ;
 506
 507
 508 lilypond_header_body:
 509         {
 510                 $$ = ly_make_anonymous_module (safe_global_b);
 511                 THIS->lexer_->add_scope ($$);
 512         }
 513         | lilypond_header_body assignment  {
 514
 515         }
 516         ;
 517
 518 lilypond_header:
 519         HEADER '{' lilypond_header_body '}'     {
 520                 $$ = THIS->lexer_->remove_scope ();
 521         }
 522         ;
 523
 524
 525 /*
 526         DECLARATIONS
 527 */
 528 assignment:
 529         STRING {
 530                 THIS->push_spot ();
 531         }
 532         /* cont */ '=' identifier_init  {
 533
 534         /*
 535                 Should find generic way of associating input with objects.
 536         */
 537                 Input ip = THIS->pop_spot ();
 538
 539                 if (! is_regular_identifier ($1))
 540                 {
 541                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 542                 }
 543
 544                 THIS->lexer_->set_identifier ($1, $4);
 545
 546 /*
 547  TODO: devise standard for protection in parser.
 548
 549   The parser stack lives on the C-stack, which means that
 550 all objects can be unprotected as soon as they're here.
 551
 552 */
 553         }
 554         | embedded_scm { }
 555         ;
 556
 557
 558 identifier_init:
 559         score_block {
 560                 $$ = $1->self_scm ();
 561                 scm_gc_unprotect_object ($$);
 562         }
 563         | output_def {
 564                 $$ = $1->self_scm ();
 565                 scm_gc_unprotect_object ($$);
 566         }
 567         | context_def_spec_block {
 568                 $$ = $1;
 569         }
 570         | Music  {
 571                 $$ = $1->self_scm ();
 572                 scm_gc_unprotect_object ($$);
 573         }
 574         | post_event {
 575                 $$ = $1->self_scm ();
 576                 scm_gc_unprotect_object ($$);
 577         }
 578         | number_expression {
 579                 $$ = $1;
 580         }
 581         | string {
 582                 $$ = $1;
 583         }
 584         | embedded_scm {
 585                 $$ = $1;
 586         }
 587         | full_markup {
 588                 $$ = $1;
 589         }
 590         | DIGIT {
 591                 $$ = scm_int2num ($1);
 592         }
 593         ;
 594
 595 context_def_spec_block:
 596         CONTEXT '{' context_def_spec_body '}'
 597                 {
 598                 $$ = $3;
 599         }
 600         ;
 601
 602 context_def_spec_body:
 603         /**/ {
 604                 $$ = Context_def::make_scm ();
 605                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 606         }
 607         | CONTEXT_DEF_IDENTIFIER {
 608                 $$ = $1;
 609                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 610         }
 611         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 612                 Context_def*td = unsmob_context_def ($$);
 613
 614                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 615                         SCM tag = scm_caar (p);
 616
 617                         /* TODO: should make new tag "grob-definition" ? */
 618                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 619                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 620                 }
 621         }
 622         | context_def_spec_body context_mod {
 623                 unsmob_context_def ($$)->add_context_mod ($2);
 624         }
 625         ;
 626
 627
 628
 629 book_block:
 630         BOOK {
 631                 THIS->push_spot ();
 632         }
 633         /*cont*/ '{' book_body '}'      {
 634                 THIS->pop_spot ();
 635                 $$ = $4;
 636         }
 637         ;
 638
 639 /* FIXME:
 640    * Use 'handlers' like for toplevel-* stuff?
 641    * grok \paper and \midi?  */
 642 book_body:
 643         {
 644                 $$ = new Book;
 645                 $$->set_spot (THIS->here_input ());
 646                 $$->bookpaper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultbookpaper"))->clone ());
 647                 scm_gc_unprotect_object ($$->bookpaper_->self_scm ());
 648                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 649         }
 650         | book_body book_paper_block {
 651                 $$->bookpaper_ = $2;
 652                 scm_gc_unprotect_object ($2->self_scm ());
 653         }
 654         | book_body score_block {
 655                 Score *score = $2;
 656                 $$->scores_.push (score);
 657                 scm_gc_unprotect_object (score->self_scm ());
 658         }
 659         | book_body lilypond_header {
 660                 $$->header_ = $2;
 661         }
 662         | book_body error {
 663                 $$->bookpaper_ = 0;
 664                 $$->scores_.clear();
 665         }
 666         ;
 667
 668 score_block:
 669         SCORE {
 670                 THIS->push_spot ();
 671         }
 672         /*cont*/ '{' score_body '}'     {
 673                 THIS->pop_spot ();
 674                 $$ = $4;
 675         }
 676         ;
 677
 678 score_body:
 679         /**/    {
 680                 $$ = new Score;
 681
 682                 $$->set_spot (THIS->here_input ());
 683         }
 684         | SCORE_IDENTIFIER {
 685                 $$ = new Score ( *unsmob_score ($1));
 686                 $$->set_spot (THIS->here_input ());
 687         }
 688         | score_body Music {
 689                 SCM m = $2->self_scm ();
 690                 scm_gc_unprotect_object (m);
 691                 $$->set_music (m, THIS->self_scm ());
 692         }
 693         | score_body lilypond_header    {
 694                 $$->header_ = $2;
 695         }
 696         | score_body output_def {
 697                 if ($2->lookup_variable (ly_symbol2scm ("is-bookpaper")) == SCM_BOOL_T)
 698                 {
 699                         THIS->parser_error (_("\\bookpaper cannot be in \\score. Use \\paper instead"));
 700
 701                 }
 702                 else
 703                 {
 704                         $$->defs_.push ($2);
 705                 }
 706                 scm_gc_unprotect_object ($2->self_scm ());
 707         }
 708         | score_body error {
 709                 $$->error_found_ = true;
 710         }
 711         ;
 712
 713
 714 /*
 715         OUTPUT DEF
 716 */
 717
 718 book_paper_block:
 719         output_def {
 720                 $$ = $1;
 721                 if ($$->lookup_variable (ly_symbol2scm ("is-bookpaper")) != SCM_BOOL_T)
 722                 {
 723                         THIS->parser_error (_("Need \\bookpaper for bookpaper block."));
 724                         $$ = get_bookpaper (THIS);
 725                 }
 726         }
 727         ;
 728
 729
 730 output_def:
 731         output_def_body '}' {
 732                 $$ = $1;
 733
 734                 THIS->lexer_->remove_scope ();
 735                 THIS->lexer_->pop_state ();
 736         }
 737         ;
 738
 739 output_def_head:
 740         BOOKPAPER {
 741                 $$ = get_bookpaper (THIS);
 742                 $$->input_origin_ = THIS->here_input ();
 743                 THIS->lexer_->add_scope ($$->scope_);
 744         }
 745         | MIDI    {
 746                 Output_def *p = get_midi (THIS);
 747                 $$ = p;
 748                 THIS->lexer_->add_scope (p->scope_);
 749         }
 750         | PAPER         {
 751                 Output_def *p = get_paper (THIS);
 752
 753                 THIS->lexer_->add_scope (p->scope_);
 754                 $$ = p;
 755         }
 756         ;
 757
 758
 759 output_def_body:
 760         output_def_head '{' {
 761                 $$ = $1;
 762                 $$->input_origin_.set_spot (THIS->here_input ());
 763                 THIS->lexer_->push_initial_state ();
 764         }
 765         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 766                 scm_gc_unprotect_object ($1->self_scm ());
 767                 Output_def *o = unsmob_output_def ($3);
 768                 o->input_origin_.set_spot (THIS->here_input ());
 769                 $$ = o;
 770                 THIS->lexer_->remove_scope ();
 771                 THIS->lexer_->add_scope (o->scope_);
 772                 THIS->lexer_->push_initial_state ();
 773         }
 774         | output_def_body assignment  {
 775
 776         }
 777         | output_def_body context_def_spec_block        {
 778                 assign_context_def ($$, $2);
 779         }
 780         | output_def_body tempo_event  {
 781                 /*
 782                         junk this ? there already is tempo stuff in
 783                         music.
 784                 */
 785                 int m = scm_to_int ($2->get_property ("metronome-count"));
 786                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 787                 set_tempo ($$, d->get_length (), m);
 788                 scm_gc_unprotect_object ($2->self_scm ());
 789         }
 790         | output_def_body error {
 791
 792         }
 793         ;
 794
 795 tempo_event:
 796         TEMPO steno_duration '=' bare_unsigned  {
 797                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 798                 $$->set_property ("tempo-unit", $2);
 799                 $$->set_property ("metronome-count", scm_int2num ( $4));
 800         }
 801         ;
 802
 803 /*
 804 The representation of a  list is the
 805
 806   (LIST . LAST-CONS)
 807
 808  to have efficient append.  */
 809
 810 Music_list:
 811         /* empty */ {
 812                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 813         }
 814         | Music_list Music {
 815                 SCM s = $$;
 816                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 817                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 818
 819                 if (scm_is_pair (scm_cdr (s)))
 820                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 821                 else
 822                         scm_set_car_x (s, c); /* set first cons */
 823                 scm_set_cdr_x (s, c);  /* remember last cell */
 824         }
 825         | Music_list embedded_scm {
 826
 827         }
 828         | Music_list error {
 829                 Music * m = MY_MAKE_MUSIC("Music");
 830                 // ugh. code dup
 831                 m->set_property ("error-found", SCM_BOOL_T);
 832                 SCM s = $$;
 833                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 834                 scm_gc_unprotect_object (m->self_scm ()); /* UGH */
 835
 836                 if (scm_is_pair (scm_cdr (s)))
 837                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 838                 else
 839                         scm_set_car_x (s, c); /* set first cons */
 840                 scm_set_cdr_x (s, c);  /* remember last cell */
 841         }
 842         ;
 843
 844 Music:
 845         Simple_music
 846         | Composite_music
 847         ;
 848
 849 Alternative_music:
 850         /* empty */ {
 851                 $$ = SCM_EOL;
 852         }
 853         | ALTERNATIVE '{' Music_list '}' {
 854                 $$ = $3;
 855         }
 856         ;
 857
 858
 859 Repeated_music:
 860         REPEAT simple_string bare_unsigned Music Alternative_music
 861         {
 862                 Music *beg = $4;
 863                 int times = $3;
 864                 SCM alts = scm_is_pair ($5) ? scm_car ($5) : SCM_EOL;
 865                 if (times < scm_ilength (alts)) {
 866                   unsmob_music (scm_car (alts))
 867                     ->origin ()->warning (
 868                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 869                   alts = ly_truncate_list (times, alts);
 870                 }
 871
 872
 873                 SCM proc = ly_scheme_function ("make-repeated-music");
 874
 875                 SCM mus = scm_call_1 (proc, $2);
 876                 scm_gc_protect_object (mus); // UGH.
 877                 Music *r = unsmob_music (mus);
 878                 if (beg)
 879                         {
 880                         r-> set_property ("element", beg->self_scm ());
 881                         scm_gc_unprotect_object (beg->self_scm ());
 882                         }
 883                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 884
 885                 r-> set_property ("elements",alts);
 886                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 887                         /*
 888                         TODO: move this code to Scheme.
 889                         */
 890
 891                         /*
 892                         we can not get durations and other stuff correct down the line, so we have to
 893                         add to the duration log here.
 894                         */
 895                         SCM func = ly_scheme_function ("shift-duration-log");
 896
 897                         int dots = ($3 % 3) ? 0 : 1;
 898                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 899
 900                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 901
 902                         if (seq) {
 903                                 int list_len = scm_ilength (seq->music_list ());
 904                                 if (list_len != 2)
 905                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 906                                 shift -= 1;
 907                                 r->compress (Moment (Rational (1, list_len)));
 908                                 }
 909                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 910
 911                 }
 912                 r->set_spot (*$4->origin ());
 913
 914                 $$ = r;
 915         }
 916         ;
 917
 918 Sequential_music:
 919         SEQUENTIAL '{' Music_list '}'           {
 920                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 921                 $$->set_property ("elements", scm_car ($3));
 922                 $$->set_spot (THIS->here_input ());
 923         }
 924         | '{' Music_list '}'            {
 925                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 926                 $$->set_property ("elements", scm_car ($2));
 927                 $$->set_spot (THIS->here_input ());
 928         }
 929         ;
 930
 931 Simultaneous_music:
 932         SIMULTANEOUS '{' Music_list '}'{
 933                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 934                 $$->set_property ("elements", scm_car ($3));
 935                 $$->set_spot (THIS->here_input ());
 936
 937         }
 938         | simul_open Music_list simul_close     {
 939                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 940                 $$->set_property ("elements", scm_car ($2));
 941                 $$->set_spot (THIS->here_input ());
 942         }
 943         ;
 944
 945 Simple_music:
 946         event_chord             { $$ = $1; }
 947         | MUSIC_IDENTIFIER {
 948                 $$ = unsmob_music ($1);
 949         }
 950         | music_property_def
 951         | context_change
 952         ;
 953
 954
 955 optional_context_mod:
 956         /**/ { $$ = SCM_EOL; }
 957         | WITH { THIS->lexer_->push_initial_state (); }
 958         '{' context_mod_list '}'
 959         {
 960                 THIS->lexer_->pop_state ();
 961                 $$ = $4;
 962         }
 963         ;
 964
 965 context_mod_list:
 966         /* */  { $$ = SCM_EOL; }
 967         | context_mod_list context_mod  {
 968                  $$ = scm_cons ($2, $1);
 969         }
 970         ;
 971
 972
 973 Composite_music:
 974         Prefix_composite_music { $$ = $1; }
 975         | Grouped_music_list { $$ = $1; }
 976         ;
 977
 978 Grouped_music_list:
 979         Simultaneous_music              { $$ = $1; }
 980         | Sequential_music              { $$ = $1; }
 981         ;
 982
 983 Generic_prefix_music_scm:
 984         MUSIC_FUNCTION {
 985                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 986         }
 987         | MUSIC_FUNCTION_SCM {
 988                 THIS->push_spot ();
 989         } embedded_scm {
 990                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 991         }
 992         | MUSIC_FUNCTION_MUSIC {
 993                 THIS->push_spot ();
 994         } Music {
 995                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 996                 scm_gc_unprotect_object ($3->self_scm ());
 997         }
 998         | MUSIC_FUNCTION_SCM_MUSIC {
 999                 THIS->push_spot ();
1000         }  embedded_scm Music {
1001                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
1002                 scm_gc_unprotect_object ($4->self_scm ());
1003         }
1004         | MUSIC_FUNCTION_SCM_SCM {
1005                 THIS->push_spot ();
1006         }  embedded_scm embedded_scm {
1007                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4);
1008         }
1009         | MUSIC_FUNCTION_MUSIC_MUSIC {
1010                 THIS->push_spot ();
1011         }  Music  Music {
1012                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
1013                 scm_gc_unprotect_object ($3->self_scm ());
1014                 scm_gc_unprotect_object ($4->self_scm ());
1015         }
1016         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
1017                 THIS->push_spot ();
1018         } embedded_scm Music Music {
1019                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
1020                         $3, $4->self_scm (), $5->self_scm ());
1021                 scm_gc_unprotect_object ($5->self_scm ());
1022                 scm_gc_unprotect_object ($4->self_scm ());
1023         }
1024         ;
1025
1026 Generic_prefix_music:
1027         Generic_prefix_music_scm {
1028                 SCM func = scm_car ($1);
1029                 Input *loc = unsmob_input (scm_cadr ($1));
1030                 SCM args = scm_cddr ($1);
1031                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1032                 int k = 0;
1033                 bool ok  = true;
1034                 for (SCM s = sig, t = args;
1035                         ok && scm_is_pair (s) && scm_is_pair (t);
1036                         s = scm_cdr (s), t = scm_cdr (t)) {
1037                         k++;
1038                         if (scm_call_1 (scm_car (s), scm_car (t)) != SCM_BOOL_T)
1039                         {
1040                                 loc->error (_f ("Argument %d failed typecheck", k));
1041                                 THIS->error_level_ = 1;
1042                                 ok = false;
1043                         }
1044                 }
1045                 SCM m = SCM_EOL;
1046                 if (ok)
1047                         m = scm_apply_0 (func, scm_cdr ($1));
1048                 if (unsmob_music (m))
1049                         {
1050                         $$ = unsmob_music (m);
1051                         scm_gc_protect_object (m);
1052                         }
1053                 else
1054                         {
1055                         if (ok)
1056                                 loc->error (_ ("Music head function should return Music object."));
1057                         $$ = MY_MAKE_MUSIC ("Music");
1058                         }
1059                 $$->set_spot (*loc);
1060         }
1061         ;
1062
1063
1064 Prefix_composite_music:
1065         Generic_prefix_music {
1066                 $$ = $1;
1067         }
1068         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1069                 $$ = context_spec_music ($2, $4, $6, $5);
1070
1071         }
1072         | CONTEXT simple_string optional_context_mod Music {
1073                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1074         }
1075         | NEWCONTEXT simple_string optional_context_mod Music {
1076                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1077                         $3);
1078         }
1079
1080         | TIMES {
1081                 THIS->push_spot ();
1082         }
1083         /* CONTINUED */
1084                 fraction Music
1085
1086         {
1087                 int n = scm_to_int (scm_car ($3)); int d = scm_to_int (scm_cdr ($3));
1088                 Music *mp = $4;
1089
1090                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1091                 $$->set_spot (THIS->pop_spot ());
1092
1093                 $$->set_property ("element", mp->self_scm ());
1094                 scm_gc_unprotect_object (mp->self_scm ());
1095                 $$->set_property ("numerator", scm_int2num (n));
1096                 $$->set_property ("denominator", scm_int2num (d));
1097                 $$->compress (Moment (Rational (n,d)));
1098
1099         }
1100         | Repeated_music                { $$ = $1; }
1101         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1102                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1103                 Music *p = $4;
1104                 Pitch from = *unsmob_pitch ($2);
1105                 Pitch to = *unsmob_pitch ($3);
1106
1107                 p->transpose (interval (from, to));
1108                 $$->set_property ("element", p->self_scm ());
1109                 scm_gc_unprotect_object (p->self_scm ());
1110         }
1111         | mode_changing_head Grouped_music_list {
1112                 if ($1 == ly_symbol2scm ("chords"))
1113                 {
1114                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1115                   chm->set_property ("element", $2->self_scm ());
1116                   $$ = chm;
1117                   scm_gc_unprotect_object ($2->self_scm ());
1118                 }
1119                 else
1120                 {
1121                   $$ = $2;
1122                 }
1123                 THIS->lexer_->pop_state ();
1124         }
1125         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1126                 $$ = context_spec_music ($1, get_next_unique_context (),
1127                                          $3, $2);
1128                 if ($1 == ly_symbol2scm ("ChordNames"))
1129                 {
1130                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1131                   chm->set_property ("element", $$->self_scm ());
1132                   scm_gc_unprotect_object ($$->self_scm ());
1133                   $$ = chm;
1134                 }
1135                 THIS->lexer_->pop_state ();
1136         }
1137         | relative_music        { $$ = $1; }
1138         | re_rhythmed_music     { $$ = $1; }
1139         | TAG embedded_scm Music {
1140                 tag_music ($3, $2, THIS->here_input ());
1141                 $$ = $3;
1142         }
1143         ;
1144
1145 mode_changing_head:
1146         NOTEMODE {
1147                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1148                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1149
1150                 $$ = ly_symbol2scm ("notes");
1151         }
1152         | DRUMMODE
1153                 {
1154                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1155                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1156
1157                 $$ = ly_symbol2scm ("drums");
1158         }
1159         | FIGUREMODE {
1160                 THIS->lexer_->push_figuredbass_state ();
1161
1162                 $$ = ly_symbol2scm ("figures");
1163         }
1164         | CHORDMODE {
1165                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1166                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1167                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1168                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1169                 $$ = ly_symbol2scm ("chords");
1170
1171         }
1172         | LYRICMODE
1173                 { THIS->lexer_->push_lyric_state ();
1174                 $$ = ly_symbol2scm ("lyrics");
1175         }
1176         ;
1177
1178 mode_changing_head_with_context:
1179         DRUMS {
1180                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1181                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1182
1183                 $$ = ly_symbol2scm ("DrumStaff");
1184         }
1185         | FIGURES {
1186                 THIS->lexer_->push_figuredbass_state ();
1187
1188                 $$ = ly_symbol2scm ("FiguredBass");
1189         }
1190         | CHORDS {
1191                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1192                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1193                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1194                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1195                 $$ = ly_symbol2scm ("ChordNames");
1196         }
1197         | LYRICS
1198                 { THIS->lexer_->push_lyric_state ();
1199                 $$ = ly_symbol2scm ("Lyrics");
1200         }
1201         ;
1202
1203
1204 relative_music:
1205         RELATIVE absolute_pitch Music {
1206                 Music *m = $3;
1207                 Pitch start = *unsmob_pitch ($2);
1208                 $$ = make_music_relative (start, m);
1209                 scm_gc_unprotect_object (m->self_scm ());
1210         }
1211         | RELATIVE Composite_music {
1212                 Music *m = $2;
1213
1214                 Pitch middle_c (0, 0, 0);
1215                 $$ = make_music_relative (middle_c, m);
1216                 scm_gc_unprotect_object (m->self_scm ());
1217         }
1218         ;
1219
1220 new_lyrics:
1221         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1222         /*cont */
1223         Grouped_music_list {
1224         /* Can also use Music at the expensive of two S/Rs similar to
1225            \repeat \alternative */
1226                 THIS->lexer_->pop_state ();
1227
1228                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1229         }
1230         | new_lyrics ADDLYRICS {
1231                 THIS->lexer_->push_lyric_state ();
1232         } Grouped_music_list {
1233                 THIS->lexer_->pop_state ();
1234                 $$ = scm_cons ($4->self_scm (), $1);
1235         }
1236         ;
1237
1238 re_rhythmed_music:
1239         Grouped_music_list new_lyrics {
1240
1241                 SCM name = $1->get_property ("context-id");
1242                 //if (name == SCM_EOL)
1243                 if (!scm_is_string (name))
1244                         name = scm_makfrom0str ("");
1245
1246                 SCM context = scm_makfrom0str ("Lyrics");
1247                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1248
1249                 SCM lst = SCM_EOL;
1250                 for (SCM s = $2; scm_is_pair (s); s = scm_cdr (s))
1251                 {
1252                         Music *music = unsmob_music (scm_car (s));
1253                         Music *com = make_lyric_combine_music (name, music);
1254                         Music *csm = context_spec_music (context,
1255                                 get_next_unique_context (), com, SCM_EOL);
1256                         lst = scm_cons (csm->self_scm (), lst);
1257                 }
1258                 /* FIXME: only first lyric music is accepted,
1259                           the rest is junked */
1260                 all->set_property ("elements", scm_cons ($1->self_scm (),
1261                         lst));
1262                 $$ = all;
1263                 scm_gc_unprotect_object ($1->self_scm ());
1264         }
1265         | LYRICSTO {
1266                 THIS->lexer_->push_lyric_state ();
1267         } simple_string Music {
1268                 THIS->lexer_->pop_state ();
1269                 Music *music = $4;
1270                 SCM name = $3;
1271                 $$ = make_lyric_combine_music (name, music);
1272                 scm_gc_unprotect_object (music->self_scm ());
1273         }
1274         ;
1275
1276 context_change:
1277         CHANGE STRING '=' STRING  {
1278                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1279                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1280                 t-> set_property ("change-to-id", $4);
1281
1282                 $$ = t;
1283                 $$->set_spot (THIS->here_input ());
1284         }
1285         ;
1286
1287 property_operation:
1288         STRING '=' scalar {
1289                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1290                         scm_string_to_symbol ($1), $3);
1291         }
1292         | UNSET simple_string {
1293                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1294                         scm_string_to_symbol ($2));
1295         }
1296         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1297                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1298                         scm_string_to_symbol ($2), $3, $5);
1299         }
1300         | REVERT simple_string embedded_scm {
1301                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1302                         scm_string_to_symbol ($2), $3);
1303         }
1304         ;
1305
1306 context_def_mod:
1307         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1308         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1309
1310         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1311         | DENIES { $$ = ly_symbol2scm ("denies"); }
1312
1313         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1314         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1315         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1316         | NAME { $$ = ly_symbol2scm ("context-name"); }
1317         ;
1318
1319 context_mod:
1320         property_operation { $$ = $1; }
1321         | context_def_mod STRING {
1322                 $$ = scm_list_2 ($1, $2);
1323         }
1324         ;
1325
1326 context_prop_spec:
1327         simple_string {
1328                 if (!is_regular_identifier ($1))
1329                 {
1330                         THIS->here_input ().error (_("Grob name should be alphanumeric"));
1331                 }
1332
1333                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1334                         scm_string_to_symbol ($1));
1335         }
1336         | simple_string '.' simple_string {
1337                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1338                         scm_string_to_symbol ($3));
1339         }
1340         ;
1341
1342 music_property_def:
1343         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1344                 $$ = property_op_to_music (scm_list_4 (
1345                         ly_symbol2scm ("poppush"),
1346                         scm_cadr ($2),
1347                         $3, $5));
1348                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1349         }
1350         | REVERT context_prop_spec embedded_scm {
1351                 $$ = property_op_to_music (scm_list_3 (
1352                         ly_symbol2scm ("pop"),
1353                         scm_cadr ($2),
1354                         $3));
1355
1356                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1357         }
1358         | SET context_prop_spec '=' scalar {
1359                 $$ = property_op_to_music (scm_list_3 (
1360                         ly_symbol2scm ("assign"),
1361                         scm_cadr ($2),
1362                         $4));
1363                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1364         }
1365         | UNSET context_prop_spec {
1366                 $$ = property_op_to_music (scm_list_2 (
1367                         ly_symbol2scm ("unset"),
1368                         scm_cadr ($2)));
1369                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1370         }
1371         | ONCE music_property_def {
1372                 SCM e = $2->get_property ("element");
1373                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1374                 $$ = $2;
1375
1376         }
1377         ;
1378
1379
1380 string:
1381         STRING {
1382                 $$ = $1;
1383         }
1384         | STRING_IDENTIFIER {
1385                 $$ = $1;
1386         }
1387         | string '+' string {
1388                 $$ = scm_string_append (scm_list_2 ($1, $3));
1389         }
1390         ;
1391
1392 simple_string: STRING {
1393                 $$ = $1;
1394         }
1395         | LYRICS_STRING {
1396                 $$ = $1;
1397         }
1398         ;
1399
1400 scalar: string {
1401                 $$ = $1;
1402         }
1403         | LYRICS_STRING {
1404                 $$ = $1;
1405         }
1406         | bare_int {
1407                 $$ = scm_int2num ($1);
1408         }
1409         | embedded_scm {
1410                 $$ = $1;
1411         }
1412         | full_markup {
1413                 $$ = $1;
1414         }
1415         | DIGIT {
1416                 $$ = scm_int2num ($1);
1417         }
1418         ;
1419
1420 /*
1421
1422 pre_events doesn't contain anything. It is a trick:
1423
1424 Adding pre_events to the simple_element
1425 makes the choice between
1426
1427   string:  STRING
1428
1429 and
1430
1431   simple_element: STRING
1432
1433 a single shift/reduction conflict.
1434
1435 nevertheless, this is not very clean, and we should find a different
1436 solution.
1437
1438 */
1439 pre_events: {
1440                 THIS->push_spot ();
1441         }
1442         ;
1443
1444 event_chord:
1445         pre_events simple_element post_events   {
1446                 SCM elts = $2-> get_property ("elements");
1447
1448                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1449
1450                 $2->set_property ("elements", elts);
1451                 $$ = $2;
1452         }
1453         | command_element
1454         | note_chord_element
1455         ;
1456
1457
1458 note_chord_element:
1459         chord_body optional_notemode_duration post_events
1460         {
1461                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1462                 SCM es = $1->get_property ("elements");
1463                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1464
1465                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1466                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1467                 es = ly_append2 (es, postevs);
1468
1469                 $1-> set_property ("elements", es);
1470                 $$ = $1;
1471         }
1472         ;
1473
1474 chord_open: '<'
1475         ;
1476
1477 chord_close: '>'
1478         ;
1479
1480 simul_open: DOUBLE_ANGLE_OPEN
1481         ;
1482
1483 simul_close: DOUBLE_ANGLE_CLOSE
1484         ;
1485
1486 chord_body:
1487         chord_open chord_body_elements chord_close
1488         {
1489                 $$ = MY_MAKE_MUSIC ("EventChord");
1490                 $$->set_property ("elements",
1491                         scm_reverse_x ($2, SCM_EOL));
1492         }
1493         ;
1494
1495 chord_body_elements:
1496         /* empty */             { $$ = SCM_EOL; }
1497         | chord_body_elements chord_body_element {
1498                 $$ = scm_cons ($2->self_scm (), $1);
1499                 scm_gc_unprotect_object ($2->self_scm ());
1500         }
1501         ;
1502
1503 chord_body_element:
1504         pitch  exclamations questions octave_check post_events
1505         {
1506                 int q = $3;
1507                 int ex = $2;
1508                 SCM check = $4;
1509                 SCM post = $5;
1510
1511                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1512                 n->set_property ("pitch", $1);
1513                 if (q % 2)
1514                         n->set_property ("cautionary", SCM_BOOL_T);
1515                 if (ex % 2 || q % 2)
1516                         n->set_property ("force-accidental", SCM_BOOL_T);
1517
1518                 if (scm_is_pair (post)) {
1519                         SCM arts = scm_reverse_x (post, SCM_EOL);
1520                         n->set_property ("articulations", arts);
1521                 }
1522                 if (scm_is_number (check))
1523                 {
1524                         int q = scm_to_int (check);
1525                         n->set_property ("absolute-octave", scm_int2num (q-1));
1526                 }
1527
1528
1529                 $$ = n;
1530         }
1531         | DRUM_PITCH post_events {
1532                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1533                 n->set_property ("duration", $2);
1534                 n->set_property ("drum-type", $1);
1535                 n->set_spot (THIS->here_input ());
1536
1537                 if (scm_is_pair ($2)) {
1538                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1539                         n->set_property ("articulations", arts);
1540                 }
1541                 $$ = n;
1542         }
1543         ;
1544
1545 add_quote:
1546         ADDQUOTE string Music {
1547                 SCM adder = ly_scheme_function ("add-quotable");
1548
1549                 scm_call_2 (adder, $2, $3->self_scm ());
1550                 scm_gc_unprotect_object ($3->self_scm ());
1551         }
1552         ;
1553
1554 command_element:
1555         command_req {
1556                 $$ = MY_MAKE_MUSIC ("EventChord");
1557                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1558                 scm_gc_unprotect_object ($1->self_scm ());
1559
1560                 $$-> set_spot (THIS->here_input ());
1561                 $1-> set_spot (THIS->here_input ());
1562         }
1563         | SKIP duration_length {
1564                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1565                 skip->set_property ("duration", $2);
1566
1567                 $$ = skip;
1568         }
1569         | QUOTE STRING duration_length {
1570                 Music *quote = MY_MAKE_MUSIC ("QuoteMusic");
1571                 quote->set_property ("duration", $3);
1572                 quote->set_property ("quoted-music-name", $2);
1573                 quote->set_spot (THIS->here_input ());
1574
1575                 $$ = quote;
1576         }
1577         | OCTAVE { THIS->push_spot (); }
1578           pitch {
1579                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1580                 $$ = m;
1581                 $$->set_spot (THIS->pop_spot ());
1582                 $$->set_property ("pitch", $3);
1583         }
1584         | E_LEFTSQUARE {
1585                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1586                 m->set_property ("span-direction", scm_int2num (START));
1587                 m->set_spot (THIS->here_input ());
1588
1589                 $$ = MY_MAKE_MUSIC ("EventChord");
1590                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1591                 scm_gc_unprotect_object (m->self_scm ());
1592                 $$->set_spot (THIS->here_input ());
1593         }
1594         | E_RIGHTSQUARE {
1595                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1596                 m->set_property ("span-direction", scm_int2num (STOP));
1597                 m->set_spot (THIS->here_input ());
1598
1599                 $$ = MY_MAKE_MUSIC ("EventChord");
1600                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1601                 $$->set_spot (THIS->here_input ());
1602                 scm_gc_unprotect_object (m->self_scm ());
1603         }
1604         | E_BACKSLASH {
1605                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1606                 $$->set_spot (THIS->here_input ());
1607         }
1608         | '|'      {
1609                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1610
1611                 if (Music * m = unsmob_music (pipe))
1612                         $$ = m->clone ();
1613                 else
1614                         $$ = MY_MAKE_MUSIC ("BarCheck");
1615
1616                 $$->set_spot (THIS->here_input ());
1617         }
1618         | TRANSPOSITION pitch {
1619                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1620                                         $2);
1621                 $$->set_spot (THIS-> here_input ());
1622                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1623                         $$, SCM_EOL);
1624         }
1625         | BAR STRING                    {
1626                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1627
1628                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1629                                         t, SCM_EOL);
1630                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1631                 $$->set_spot (THIS->here_input ());
1632                 t->set_spot (THIS->here_input ());
1633         }
1634         | PARTIAL duration_length       {
1635                 Moment m = - unsmob_duration ($2)->get_length ();
1636                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1637                 p->set_spot (THIS->here_input ());
1638                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1639                                         p, SCM_EOL);
1640                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1641                                         p, SCM_EOL);
1642                 $$ = p;
1643         }
1644         | CLEF STRING  {
1645                 SCM proc = ly_scheme_function ("make-clef-set");
1646
1647                 SCM result = scm_call_1 (proc, $2);
1648                 scm_gc_protect_object (result);
1649                 $$ = unsmob_music (result);
1650         }
1651         | TIME_T fraction  {
1652                 SCM proc= ly_scheme_function ("make-time-signature-set");
1653
1654                 SCM result = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1655                 scm_gc_protect_object (result);
1656                 $$ = unsmob_music (result);
1657         }
1658         | MARK scalar {
1659                 SCM proc = ly_scheme_function ("make-mark-set");
1660
1661                 SCM result = scm_call_1 (proc, $2);
1662                 scm_gc_protect_object (result);
1663                 $$ = unsmob_music (result);
1664         }
1665         ;
1666
1667 command_req:
1668         E_TILDE {
1669                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1670         }
1671         | MARK DEFAULT  {
1672                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1673                 $$ = m;
1674         }
1675         | tempo_event {
1676                 $$ = $1;
1677         }
1678         | KEY DEFAULT {
1679                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1680                 $$ = key;
1681         }
1682         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1683
1684                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1685                 if (scm_ilength ($3) > 0)
1686                 {
1687                         key->set_property ("pitch-alist", $3);
1688                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1689                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1690                 } else {
1691                         THIS->parser_error (_ ("Second argument must be pitch list."));
1692                 }
1693
1694                 $$ = key;
1695         }
1696         ;
1697
1698 post_events:
1699         /* empty */ {
1700                 $$ = SCM_EOL;
1701         }
1702         | post_events post_event {
1703                 $2->set_spot (THIS->here_input ());
1704                 $$ = scm_cons ($2->self_scm (), $$);
1705                 scm_gc_unprotect_object ($2->self_scm ());
1706         }
1707         | post_events tagged_post_event {
1708                 $2 -> set_spot (THIS->here_input ());
1709                 $$ = scm_cons ($2->self_scm (), $$);
1710                 scm_gc_unprotect_object ($2->self_scm ());
1711         }
1712         ;
1713
1714
1715 tagged_post_event:
1716         '-' TAG embedded_scm post_event {
1717                 tag_music ($4, $3, THIS->here_input ());
1718                 $$ = $4;
1719         }
1720         ;
1721
1722 post_event:
1723         direction_less_event {
1724                 $$ = $1;
1725         }
1726         | HYPHEN {
1727                 if (!THIS->lexer_->is_lyric_state ())
1728                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1729                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1730         }
1731         | EXTENDER {
1732                 if (!THIS->lexer_->is_lyric_state ())
1733                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1734                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1735         }
1736         | script_dir direction_reqd_event {
1737                 if ($1)
1738                         $2->set_property ("direction", scm_int2num ($1));
1739                 $$ = $2;
1740         }
1741         | script_dir direction_less_event {
1742                 if ($1)
1743                         $2->set_property ("direction", scm_int2num ($1));
1744                 $$ = $2;
1745         }
1746         | string_number_event
1747         ;
1748
1749 string_number_event:
1750         E_UNSIGNED {
1751                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1752                 s->set_property ("string-number", scm_int2num ($1));
1753                 s->set_spot (THIS->here_input ());
1754                 $$ = s;
1755         }
1756         ;
1757
1758 direction_less_char:
1759         '['  {
1760                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1761         }
1762         | ']'  {
1763                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1764         }
1765         | '~'  {
1766                 $$ = ly_symbol2scm ("tildeSymbol");
1767         }
1768         | '('  {
1769                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1770         }
1771         | ')'  {
1772                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1773         }
1774         | E_EXCLAMATION  {
1775                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1776         }
1777         | E_OPEN  {
1778                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1779         }
1780         | E_CLOSE  {
1781                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1782         }
1783         | E_BIGGER  {
1784                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1785         }
1786         | E_SMALLER  {
1787                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1788         }
1789         ;
1790
1791 direction_less_event:
1792         direction_less_char {
1793                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1794                 Music * m = 0;
1795                 if (unsmob_music (predefd))
1796                 {
1797                         m = unsmob_music (predefd)->clone ();
1798                 }
1799                 else
1800                 {
1801                         m = MY_MAKE_MUSIC ("Music");
1802                 }
1803                 m->set_spot (THIS->here_input ());
1804                 $$ = m;
1805         }
1806         | EVENT_IDENTIFIER      {
1807                 $$ = unsmob_music ($1);
1808         }
1809         | tremolo_type  {
1810                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1811                a->set_spot (THIS->here_input ());
1812                a->set_property ("tremolo-type", scm_int2num ($1));
1813                $$ = a;
1814         }
1815         ;
1816
1817 direction_reqd_event:
1818         gen_text_def {
1819                 $$ = $1;
1820         }
1821         | script_abbreviation {
1822                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1823                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1824                 if (scm_is_string (s))
1825                         a->set_property ("articulation-type", s);
1826                 else THIS->parser_error (_ ("Expecting string as script definition"));
1827                 $$ = a;
1828         }
1829         ;
1830
1831 octave_check:
1832         /**/ { $$ = SCM_EOL; }
1833         | '='  { $$ = scm_int2num (0); }
1834         | '=' sub_quotes { $$ = scm_int2num ($2); }
1835         | '=' sup_quotes { $$ = scm_int2num ($2); }
1836         ;
1837
1838 sup_quotes:
1839         '\'' {
1840                 $$ = 1;
1841         }
1842         | sup_quotes '\'' {
1843                 $$ ++;
1844         }
1845         ;
1846
1847 sub_quotes:
1848         ',' {
1849                 $$ = 1;
1850         }
1851         | sub_quotes ',' {
1852                 $$++;
1853         }
1854         ;
1855
1856 steno_pitch:
1857         NOTENAME_PITCH  {
1858                 $$ = $1;
1859         }
1860         | NOTENAME_PITCH sup_quotes     {
1861                 Pitch p = *unsmob_pitch ($1);
1862                 p = p.transposed (Pitch ($2,0,0));
1863                 $$ = p.smobbed_copy ();
1864         }
1865         | NOTENAME_PITCH sub_quotes      {
1866                 Pitch p =* unsmob_pitch ($1);
1867                 p = p.transposed (Pitch (-$2,0,0));
1868                 $$ = p.smobbed_copy ();
1869         }
1870         ;
1871
1872 /*
1873 ugh. duplication
1874 */
1875
1876 steno_tonic_pitch:
1877         TONICNAME_PITCH {
1878                 $$ = $1;
1879         }
1880         | TONICNAME_PITCH sup_quotes    {
1881                 Pitch p = *unsmob_pitch ($1);
1882                 p = p.transposed (Pitch ($2,0,0));
1883                 $$ = p.smobbed_copy ();
1884         }
1885         | TONICNAME_PITCH sub_quotes     {
1886                 Pitch p =* unsmob_pitch ($1);
1887
1888                 p = p.transposed (Pitch (-$2,0,0));
1889                 $$ = p.smobbed_copy ();
1890         }
1891         ;
1892
1893 pitch:
1894         steno_pitch {
1895                 $$ = $1;
1896         }
1897         ;
1898
1899 pitch_also_in_chords:
1900         pitch
1901         | steno_tonic_pitch
1902         ;
1903
1904 gen_text_def:
1905         full_markup {
1906                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1907                 t->set_property ("text", $1);
1908                 t->set_spot (THIS->here_input ());
1909                 $$ = t;
1910         }
1911         | string {
1912                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1913                 t->set_property ("text",
1914                         make_simple_markup (THIS->lexer_->encoding (), $1));
1915                 t->set_spot (THIS->here_input ());
1916                 $$ = t;
1917
1918         }
1919         | DIGIT {
1920                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1921                 t->set_property ("digit", scm_int2num ($1));
1922                 t->set_spot (THIS->here_input ());
1923                 $$ = t;
1924         }
1925         ;
1926
1927 script_abbreviation:
1928         '^'             {
1929                 $$ = scm_makfrom0str ("Hat");
1930         }
1931         | '+'           {
1932                 $$ = scm_makfrom0str ("Plus");
1933         }
1934         | '-'           {
1935                 $$ = scm_makfrom0str ("Dash");
1936         }
1937         | '|'           {
1938                 $$ = scm_makfrom0str ("Bar");
1939         }
1940         | '>'           {
1941                 $$ = scm_makfrom0str ("Larger");
1942         }
1943         | '.'           {
1944                 $$ = scm_makfrom0str ("Dot");
1945         }
1946         | '_' {
1947                 $$ = scm_makfrom0str ("Underscore");
1948         }
1949         ;
1950
1951 script_dir:
1952         '_'     { $$ = DOWN; }
1953         | '^'   { $$ = UP; }
1954         | '-'   { $$ = CENTER; }
1955         ;
1956
1957
1958 absolute_pitch:
1959         steno_pitch     {
1960                 $$ = $1;
1961         }
1962         ;
1963
1964 duration_length:
1965         multiplied_duration {
1966                 $$ = $1;
1967         }
1968         ;
1969
1970 optional_notemode_duration:
1971         {
1972                 Duration dd = THIS->default_duration_;
1973                 $$ = dd.smobbed_copy ();
1974
1975                 THIS->beam_check ($$);
1976         }
1977         | multiplied_duration   {
1978                 $$ = $1;
1979                 THIS->default_duration_ = *unsmob_duration ($$);
1980
1981                 THIS->beam_check ($$);
1982         }
1983         ;
1984
1985 steno_duration:
1986         bare_unsigned dots              {
1987                 int len = 0;
1988                 if (!is_duration ($1))
1989                         THIS->parser_error (_f ("not a duration: %d", $1));
1990                 else
1991                         len = intlog2 ($1);
1992
1993                 $$ = Duration (len, $2).smobbed_copy ();
1994         }
1995         | DURATION_IDENTIFIER dots      {
1996                 Duration *d = unsmob_duration ($1);
1997                 Duration k (d->duration_log (), d->dot_count () + $2);
1998                 *d = k;
1999                 $$ = $1;
2000         }
2001         ;
2002
2003 multiplied_duration:
2004         steno_duration {
2005                 $$ = $1;
2006         }
2007         | multiplied_duration '*' bare_unsigned {
2008                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2009         }
2010         | multiplied_duration '*' FRACTION {
2011                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2012
2013                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2014         }
2015         ;
2016
2017 fraction:
2018         FRACTION { $$ = $1; }
2019         | UNSIGNED '/' UNSIGNED {
2020                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2021         }
2022         ;
2023
2024 dots:
2025         /* empty */     {
2026                 $$ = 0;
2027         }
2028         | dots '.' {
2029                 $$ ++;
2030         }
2031         ;
2032
2033 tremolo_type:
2034         ':'     {
2035                 $$ = 0;
2036         }
2037         | ':' bare_unsigned {
2038                 if (!is_duration ($2))
2039                         THIS->parser_error (_f ("not a duration: %d", $2));
2040                 $$ = $2;
2041         }
2042         ;
2043
2044 bass_number:
2045         DIGIT   {
2046                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2047                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2048                                 $$);
2049         }
2050         | UNSIGNED {
2051                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2052                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2053                                 $$);
2054         }
2055         | STRING { $$ = $1; }
2056         ;
2057
2058 bass_mod:
2059         '-'     { $$ = -2; }
2060         | '+'   { $$ = 2; }
2061         | '!'   { $$ = 0; }
2062         ;
2063
2064 bass_figure:
2065         FIGURE_SPACE {
2066                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2067                 $$ = bfr->self_scm ();
2068                 scm_gc_unprotect_object ($$);
2069         }
2070         | bass_number  {
2071                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2072                 $$ = bfr->self_scm ();
2073
2074                 bfr->set_property ("figure", $1);
2075
2076                 scm_gc_unprotect_object ($$);
2077         }
2078         | bass_figure bass_mod {
2079                 Music *m = unsmob_music ($1);
2080                 if ($2) {
2081                         SCM salter = m->get_property ("alteration");
2082                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2083                         m->set_property ("alteration",
2084                                 scm_int2num (alter + $2));
2085                 } else {
2086                         m->set_property ("alteration", scm_int2num (0));
2087                 }
2088         }
2089         ;
2090
2091 br_bass_figure:
2092         '[' bass_figure {
2093                 $$ = $2;
2094                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2095         }
2096         | bass_figure   {
2097                 $$ = $1;
2098         }
2099         | br_bass_figure ']' {
2100                 $$ = $1;
2101                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2102         }
2103         ;
2104
2105 figure_list:
2106         /**/            {
2107                 $$ = SCM_EOL;
2108         }
2109         | figure_list br_bass_figure {
2110                 $$ = scm_cons ($2, $1);
2111         }
2112         ;
2113
2114 figure_spec:
2115         FIGURE_OPEN figure_list FIGURE_CLOSE {
2116                 Music *m = MY_MAKE_MUSIC ("EventChord");
2117                 $2 = scm_reverse_x ($2, SCM_EOL);
2118                 m->set_property ("elements", $2);
2119                 $$ = m->self_scm ();
2120         }
2121         ;
2122
2123
2124 optional_rest:
2125         /**/   { $$ = 0; }
2126         | REST { $$ = 1; }
2127         ;
2128
2129 simple_element:
2130         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2131
2132                 Input i = THIS->pop_spot ();
2133                 if (!THIS->lexer_->is_note_state ())
2134                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2135
2136                 Music *n = 0;
2137                 if ($6)
2138                         n = MY_MAKE_MUSIC ("RestEvent");
2139                 else
2140                         n = MY_MAKE_MUSIC ("NoteEvent");
2141
2142                 n->set_property ("pitch", $1);
2143                 n->set_property ("duration", $5);
2144
2145                 if (scm_is_number ($4))
2146                 {
2147                         int q = scm_to_int ($4);
2148                         n->set_property ("absolute-octave", scm_int2num (q-1));
2149                 }
2150
2151                 if ($3 % 2)
2152                         n->set_property ("cautionary", SCM_BOOL_T);
2153                 if ($2 % 2 || $3 % 2)
2154                         n->set_property ("force-accidental", SCM_BOOL_T);
2155
2156                 Music *v = MY_MAKE_MUSIC ("EventChord");
2157                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2158                 scm_gc_unprotect_object (n->self_scm ());
2159
2160                 v->set_spot (i);
2161                 n->set_spot (i);
2162                 $$ = v;
2163         }
2164         | DRUM_PITCH optional_notemode_duration {
2165                 Input i = THIS->pop_spot ();
2166
2167                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2168                 n->set_property ("duration", $2);
2169                 n->set_property ("drum-type", $1);
2170
2171                 Music *v = MY_MAKE_MUSIC ("EventChord");
2172                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2173                 scm_gc_unprotect_object (n->self_scm ());
2174                 v->set_spot (i);
2175                 n->set_spot (i);
2176                 $$ = v;
2177
2178         }
2179         | figure_spec optional_notemode_duration {
2180                 Music *m = unsmob_music ($1);
2181                 Input i = THIS->pop_spot ();
2182                 m->set_spot (i);
2183                 for (SCM s = m->get_property ("elements"); scm_is_pair (s); s = scm_cdr (s))
2184                 {
2185                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2186                 }
2187                 $$ = m;
2188         }
2189         | RESTNAME optional_notemode_duration           {
2190
2191                 Input i = THIS->pop_spot ();
2192                 Music *ev = 0;
2193                 if (ly_scm2string ($1) == "s") {
2194                         /* Space */
2195                         ev = MY_MAKE_MUSIC ("SkipEvent");
2196                   }
2197                 else {
2198                         ev = MY_MAKE_MUSIC ("RestEvent");
2199
2200                     }
2201                 ev->set_property ("duration", $2);
2202                 ev->set_spot (i);
2203                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2204                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2205                 velt->set_spot (i);
2206
2207                 scm_gc_unprotect_object (ev->self_scm ());
2208
2209                 $$ = velt;
2210         }
2211         | MULTI_MEASURE_REST optional_notemode_duration         {
2212                 THIS->pop_spot ();
2213
2214                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2215                 SCM mus = scm_call_2 (proc, $2,
2216                         make_input (THIS->here_input ()));
2217                 scm_gc_protect_object (mus);
2218                 $$ = unsmob_music (mus);
2219         }
2220
2221         | lyric_element optional_notemode_duration      {
2222                 Input i = THIS->pop_spot ();
2223                 if (!THIS->lexer_->is_lyric_state ())
2224                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2225
2226                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2227                 lreq->set_property ("text", $1);
2228                 lreq->set_property ("duration",$2);
2229                 lreq->set_spot (i);
2230                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2231                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2232
2233                 $$= velt;
2234         }
2235         | new_chord {
2236                 THIS->pop_spot ();
2237
2238                 if (!THIS->lexer_->is_chord_state ())
2239                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2240                 $$ = unsmob_music ($1);
2241         }
2242         ;
2243
2244 lyric_element:
2245         /* FIXME: lyric flavoured markup would be better */
2246         full_markup {
2247                 $$ = $1;
2248         }
2249         | LYRICS_STRING {
2250                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2251         }
2252         ;
2253
2254 new_chord:
2255         steno_tonic_pitch optional_notemode_duration   {
2256                 $$ = make_chord ($1, $2, SCM_EOL);
2257         }
2258         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2259                 SCM its = scm_reverse_x ($4, SCM_EOL);
2260                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2261         }
2262         ;
2263
2264 chord_items:
2265         /**/ {
2266                 $$ = SCM_EOL;
2267         }
2268         | chord_items chord_item {
2269                 $$ = scm_cons ($2, $$);
2270         }
2271         ;
2272
2273 chord_separator:
2274         CHORD_COLON {
2275                 $$ = ly_symbol2scm ("chord-colon");
2276         }
2277         | CHORD_CARET {
2278                 $$ = ly_symbol2scm ("chord-caret");
2279         }
2280         | CHORD_SLASH steno_tonic_pitch {
2281                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2282         }
2283         | CHORD_BASS steno_tonic_pitch {
2284                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2285         }
2286         ;
2287
2288 chord_item:
2289         chord_separator {
2290                 $$ = $1;
2291         }
2292         | step_numbers {
2293                 $$ = scm_reverse_x ($1, SCM_EOL);
2294         }
2295         | CHORD_MODIFIER  {
2296                 $$ = $1;
2297         }
2298         ;
2299
2300 step_numbers:
2301         step_number { $$ = scm_cons ($1, SCM_EOL); }
2302         | step_numbers '.' step_number {
2303                 $$ = scm_cons ($3, $$);
2304         }
2305         ;
2306
2307 step_number:
2308         bare_unsigned {
2309                 $$ = make_chord_step ($1, 0);
2310         }
2311         | bare_unsigned '+' {
2312                 $$ = make_chord_step ($1, SHARP);
2313         }
2314         | bare_unsigned CHORD_MINUS {
2315                 $$ = make_chord_step ($1, FLAT);
2316         }
2317         ;
2318
2319 /*
2320         UTILITIES
2321
2322 TODO: should deprecate in favor of Scheme?
2323
2324  */
2325 number_expression:
2326         number_expression '+' number_term {
2327                 $$ = scm_sum ($1, $3);
2328         }
2329         | number_expression '-' number_term {
2330                 $$ = scm_difference ($1, $3);
2331         }
2332         | number_term
2333         ;
2334
2335 number_term:
2336         number_factor {
2337                 $$ = $1;
2338         }
2339         | number_factor '*' number_factor {
2340                 $$ = scm_product ($1, $3);
2341         }
2342         | number_factor '/' number_factor {
2343                 $$ = scm_divide ($1, $3);
2344         }
2345         ;
2346
2347 number_factor:
2348         '-'  number_factor { /* %prec UNARY_MINUS */
2349                 $$ = scm_difference ($2, SCM_UNDEFINED);
2350         }
2351         | bare_number
2352         ;
2353
2354
2355 bare_number:
2356         UNSIGNED        {
2357                 $$ = scm_int2num ($1);
2358         }
2359         | REAL          {
2360                 $$ = $1;
2361         }
2362         | NUMBER_IDENTIFIER             {
2363                 $$ = $1;
2364         }
2365         | REAL NUMBER_IDENTIFIER        {
2366                 $$ = scm_make_real (scm_to_double ($1) *scm_to_double ($2));
2367         }
2368         | UNSIGNED NUMBER_IDENTIFIER    {
2369                 $$ = scm_make_real ($1 *scm_to_double ($2));
2370         }
2371         ;
2372
2373
2374 bare_unsigned:
2375         UNSIGNED {
2376                         $$ = $1;
2377         }
2378         | DIGIT {
2379                 $$ = $1;
2380         }
2381         ;
2382
2383 bare_int:
2384         bare_number {
2385                 if (scm_integer_p ($1) == SCM_BOOL_T)
2386                 {
2387                         int k = scm_to_int ($1);
2388                         $$ = k;
2389                 } else
2390                 {
2391                         THIS->parser_error (_ ("need integer number arg"));
2392                         $$ = 0;
2393                 }
2394         }
2395         | '-' bare_int {
2396                 $$ = -$2;
2397         }
2398         ;
2399
2400 exclamations:
2401                 { $$ = 0; }
2402         | exclamations '!'      { $$ ++; }
2403         ;
2404
2405 questions:
2406                 { $$ = 0; }
2407         | questions '?' { $$ ++; }
2408         ;
2409
2410
2411
2412 full_markup:
2413         MARKUP_IDENTIFIER {
2414                 $$ = $1;
2415         }
2416         | MARKUP
2417                 { THIS->lexer_->push_markup_state (); }
2418         markup
2419                 { $$ = $3;
2420                   THIS->lexer_->pop_state ();
2421                 }
2422         ;
2423
2424
2425 /*
2426 This should be done more dynamically if possible.
2427 */
2428 markup:
2429         STRING {
2430                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2431         }
2432         | MARKUP_HEAD_EMPTY {
2433                 $$ = scm_list_1 ($1);
2434         }
2435         | MARKUP_HEAD_MARKUP0 markup {
2436                 $$ = scm_list_2 ($1, $2);
2437         }
2438         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2439                 $$ = scm_list_3 ($1, $2, $3);
2440         }
2441         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2442                 $$ = scm_list_3 ($1, $2, $3);
2443         }
2444         | markup_line {
2445                 $$ = $1;
2446         }
2447         | MARKUP_HEAD_LIST0 markup_list {
2448                 $$ = scm_list_2 ($1,$2);
2449         }
2450         | MARKUP_HEAD_SCM0 embedded_scm {
2451                 $$ = scm_list_2 ($1, $2);
2452         }
2453         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2454                 $$ = scm_list_4 ($1, $2, $3, $4);
2455         }
2456         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2457                 $$ = scm_list_4 ($1, $2, $3, $4);
2458         }
2459         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2460                 $$ = scm_list_3 ($1, $2, $3);
2461         }
2462         | MARKUP_IDENTIFIER {
2463                 $$ = $1;
2464         }
2465         | STRING_IDENTIFIER {
2466                 $$ = $1;
2467         }
2468         | SCORE {
2469                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2470                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2471         } '{' score_body '}' {
2472                 Score * sc = $4;
2473                 $$ = scm_list_2 (ly_scheme_function ("score-markup"), sc->self_scm ());
2474                 scm_gc_unprotect_object (sc->self_scm ());
2475                 THIS->lexer_->pop_state ();
2476         }
2477         ;
2478
2479 markup_list:
2480         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2481         ;
2482
2483 markup_line:
2484         '{' markup_list_body '}' {
2485                 SCM line = ly_scheme_function ("line-markup");
2486
2487                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2488         }
2489         ;
2490
2491 markup_list_body:
2492         /**/ {  $$ = SCM_EOL; }
2493         | markup_list_body markup {
2494                 $$ = scm_cons ($2, $1);
2495         }
2496         ;
2497
2498
2499 %%
2500
2501 void
2502 Lily_parser::set_yydebug (bool )
2503 {
2504 #if 0
2505         yydebug = 1;
2506 #endif
2507 }
2508
2509 void
2510 Lily_parser::do_yyparse ()
2511 {
2512         yyparse ((void*)this);
2513 }
2514
2515
2516 /*
2517 Should make this optional?    It will also complain when you do
2518
2519         [s4]
2520
2521 which is entirely legitimate.
2522
2523 Or we can scrap it. Barchecks should detect wrong durations, and
2524 skipTypesetting speeds it up a lot.
2525 */
2526
2527 void
2528 Lily_parser::beam_check (SCM dur)
2529 {
2530   Duration *d = unsmob_duration (dur);
2531   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2532     {
2533       Music *m = unsmob_music (last_beam_start_);
2534       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2535     }
2536   last_beam_start_ = SCM_EOL;
2537 }
2538
2539
2540
2541
2542 /*
2543
2544 It is a little strange to have this function in this file, but
2545 otherwise, we have to import music classes into the lexer.
2546
2547 */
2548 int
2549 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2550 {
2551         if (scm_is_string (sid)) {
2552                 *destination = sid;
2553                 return STRING_IDENTIFIER;
2554         } else if (scm_is_number (sid)) {
2555                 *destination = sid;
2556                 return NUMBER_IDENTIFIER;
2557         } else if (unsmob_context_def (sid)) {
2558                 *destination = unsmob_context_def (sid)->clone_scm ();
2559                 return CONTEXT_DEF_IDENTIFIER;
2560         } else if (unsmob_score (sid)) {
2561                 Score *score = new Score (*unsmob_score (sid));
2562                 *destination = score->self_scm ();
2563                 return SCORE_IDENTIFIER;
2564         } else if (Music *mus = unsmob_music (sid)) {
2565                 mus = mus->clone ();
2566                 *destination = mus->self_scm ();
2567                 unsmob_music (*destination)->
2568                         set_property ("origin", make_input (last_input_));
2569                 return dynamic_cast<Event*> (mus)
2570                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2571         } else if (unsmob_duration (sid)) {
2572                 *destination = unsmob_duration (sid)->smobbed_copy ();
2573                 return DURATION_IDENTIFIER;
2574         } else if (unsmob_output_def (sid)) {
2575                 Output_def *p = unsmob_output_def (sid);
2576                 p = p->clone ();
2577
2578                 *destination = p->self_scm ();
2579                 return OUTPUT_DEF_IDENTIFIER;
2580         } else if (Text_interface::markup_p (sid)) {
2581                 *destination = sid;
2582                 return MARKUP_IDENTIFIER;
2583         }
2584
2585         return -1;
2586 }
2587
2588 Music *
2589 property_op_to_music (SCM op)
2590 {
2591         Music *m = 0;
2592         SCM tag = scm_car (op);
2593         SCM symbol = scm_cadr (op);
2594         SCM args = scm_cddr (op);
2595         SCM grob_val = SCM_UNDEFINED;
2596         SCM grob_sym = SCM_UNDEFINED;
2597         SCM val = SCM_UNDEFINED;
2598
2599         if (tag == ly_symbol2scm ("assign"))
2600                 {
2601                 m = MY_MAKE_MUSIC ("PropertySet");
2602                 val = scm_car (args);
2603                 }
2604         else if (tag == ly_symbol2scm ("unset"))
2605                 m = MY_MAKE_MUSIC ("PropertyUnset");
2606         else if (tag == ly_symbol2scm ("poppush")
2607                  || tag == ly_symbol2scm ("push"))
2608                 {
2609                 m = MY_MAKE_MUSIC ("OverrideProperty");
2610                 grob_sym = scm_car (args);
2611                 grob_val = scm_cadr (args);
2612                 }
2613         else if (tag == ly_symbol2scm ("pop")) {
2614                 m = MY_MAKE_MUSIC ("RevertProperty");
2615                 grob_sym = scm_car (args);
2616                 }
2617
2618         m->set_property ("symbol", symbol);
2619
2620         if (val != SCM_UNDEFINED)
2621                 m->set_property ("value", val);
2622         if (grob_val != SCM_UNDEFINED)
2623                 m->set_property ("grob-value", grob_val);
2624
2625         if (grob_sym != SCM_UNDEFINED)
2626                 {
2627                 bool itc = internal_type_checking_global_b;
2628                 /* UGH.
2629                 */
2630                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2631                 if (autobeam)
2632                         internal_type_checking_global_b = false;
2633                 m->set_property ("grob-property", grob_sym);
2634                 if (autobeam)
2635                         internal_type_checking_global_b = itc;
2636                 }
2637
2638         if (tag == ly_symbol2scm ("poppush"))
2639                 m->set_property ("pop-first", SCM_BOOL_T);
2640
2641
2642         return m;
2643 }
2644
2645 Music*
2646 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2647 {
2648         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2649
2650         csm->set_property ("element", m->self_scm ());
2651         scm_gc_unprotect_object (m->self_scm ());
2652
2653         csm->set_property ("context-type",
2654                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2655         csm->set_property ("property-operations", ops);
2656
2657         if (scm_is_string (id))
2658                 csm->set_property ("context-id", id);
2659         return csm;
2660 }
2661
2662 /*
2663 FIXME: this should be postponed until the music hits \Score
2664 */
2665 SCM
2666 get_next_unique_context ()
2667 {
2668         static int new_context_count;
2669         char s[1024];
2670         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2671         return scm_makfrom0str (s);
2672 }
2673