lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2003 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "context-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "auto-change-iterator.hh"
  78 #include "ly-modules.hh"
  79 #include "music-sequence.hh"
  80 #include "input-smob.hh"
  81 #include "event.hh"
  82 #include "text-item.hh"
  83 #include "music-list.hh"
  84
  85 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  86
  87 Music *property_op_to_music (SCM op);
  88 Music *context_spec_music (SCM type, SCM id, Music * m, SCM ops_);
  89 SCM get_next_unique_context ();
  90
  91 #define YYERROR_VERBOSE 1
  92
  93 My_lily_parser* my_lily_parser;
  94 #define YYPARSE_PARAM my_lily_parser
  95 #define YYLEX_PARAM my_lily_parser
  96 #define THIS\
  97         ((My_lily_parser *) my_lily_parser)
  98
  99 #define yyerror THIS->parser_error
 100
 101 /*
 102   Add symbols to the  TAGS field of a music object.
 103 */
 104
 105 void
 106 tag_music (Music*m,  SCM tag, Input ip)
 107 {
 108         SCM tags = m->get_mus_property ("tags");
 109         if (gh_symbol_p (tag))
 110                 tags = scm_cons (tag, tags);
 111         else if (gh_list_p (tag))
 112                 tags = gh_append2 (tag, tags);
 113         else
 114                 ip.warning (_("Tag must be symbol or list of symbols."));
 115
 116         m->set_mus_property ("tags", tags);
 117 }
 118
 119
 120
 121 bool
 122 regular_identifier_b (SCM id)
 123 {
 124   String str = ly_scm2string (id);
 125   char const *s = str.to_str0 () ;
 126
 127   bool v = true;
 128   while (*s && v)
 129    {
 130         v = v && isalpha (*s);
 131         s++;
 132    }
 133   return v;
 134 }
 135
 136 SCM
 137 make_simple_markup (SCM a)
 138 {
 139         static SCM simple;
 140         if (!simple)
 141         simple = scm_c_eval_string ("simple-markup");
 142
 143         return scm_list_n (simple, a, SCM_UNDEFINED);
 144 }
 145
 146
 147 bool
 148 is_duration_b (int t)
 149 {
 150   return t && t == 1 << intlog2 (t);
 151 }
 152
 153 void
 154 set_music_properties (Music *p, SCM a)
 155 {
 156   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 157         {
 158         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 159         }
 160 }
 161
 162 SCM
 163 make_chord_step (int step, int alter)
 164 {
 165         if (step == 7)
 166                 alter += FLAT;
 167
 168         while(step < 0)
 169                 step += 7;
 170         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 171         return m.smobbed_copy ();
 172 }
 173
 174
 175 SCM
 176 make_chord (SCM pitch, SCM dur, SCM modification_list)
 177 {
 178         static SCM chord_ctor;
 179         if (!chord_ctor)
 180                 chord_ctor= scm_c_eval_string ("construct-chord");
 181         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 182         scm_gc_protect_object (ch);
 183         return ch;
 184 }
 185
 186 /*
 187   Todo: actually also use apply iso. call too ...
 188 */
 189 bool
 190 ly_input_procedure_p (SCM x)
 191 {
 192         return gh_procedure_p (x)
 193                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 194 }
 195
 196 Music*
 197 set_property_music (SCM sym, SCM value)
 198 {
 199         Music * p = MY_MAKE_MUSIC("PropertySet");
 200         p->set_mus_property ("symbol", sym);
 201         p->set_mus_property ("value", value);
 202         return p;
 203 }
 204
 205 %}
 206
 207 /* We use SCMs to do strings, because it saves us the trouble of
 208 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 209 of the parse stack onto the heap. */
 210
 211
 212 %union {
 213         String * string;
 214     Music *music;
 215     Score *score;
 216     Music_output_def * outputdef;
 217     SCM scm;
 218     int i;
 219 }
 220 %{
 221
 222 int
 223 yylex (YYSTYPE *s,  void * v)
 224 {
 225         My_lily_parser   *pars = (My_lily_parser*) v;
 226         My_lily_lexer * lex = pars->lexer_;
 227
 228         lex->lexval = (void*) s;
 229         lex->prepare_for_next_token();
 230         return lex->yylex ();
 231 }
 232
 233
 234 %}
 235
 236 %pure_parser
 237
 238
 239 %token ACCEPTS
 240 %token ADDLYRICS
 241 %token NEWADDLYRICS
 242 %token ALIAS
 243 %token ALTERNATIVE
 244 %token APPLY
 245 %token APPLYCONTEXT
 246 %token APPLYOUTPUT
 247 %token AUTOCHANGE
 248 %token BAR
 249 %token BREATHE
 250 %token CHANGE
 251 %token CHORDMODIFIERS
 252 %token CHORDS
 253 %token LESSLESS
 254 %token MOREMORE
 255 %token CLEF
 256 %token COMMANDSPANREQUEST
 257 %token CONSISTS
 258 %token CONSISTSEND
 259 %token CONTEXT
 260 %token DEFAULT
 261 %token DENIES
 262 %token DESCRIPTION
 263 %token EXTENDER
 264 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 265 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 266 %token GRACE
 267 %token ACCIACCATURA
 268 %token APPOGGIATURA
 269 %token GROBDESCRIPTIONS
 270 %token HEADER
 271 %token HYPHEN
 272 %token INVALID
 273 %token KEY
 274 %token LYRICS
 275 %token MARK
 276 %token MIDI
 277 %token MULTI_MEASURE_REST
 278 %token NAME
 279 %token NEWCONTEXT
 280 %token NOTES
 281 %token OCTAVE
 282 %token ONCE
 283 %token OVERRIDE SET REVERT
 284 %token PAPER
 285 %token PARTCOMBINE
 286 %token NEWPARTCOMBINE
 287 %token PARTIAL
 288 %token PITCHNAMES
 289 %token PROPERTY
 290 %token RELATIVE
 291 %token REMOVE
 292 %token REPEAT
 293 %token REST
 294 %token SCM_T
 295 %token SCORE
 296 %token SEQUENTIAL
 297 %token SIMULTANEOUS
 298 %token SKIP
 299 %token SPANREQUEST
 300 %token TAG
 301 %token TEMPO
 302 %token TIMES
 303 %token TIME_T
 304 %token TRANSLATOR
 305 %token TRANSPOSE
 306 %token TYPE
 307 %token UNSET
 308 %token WITH
 309
 310 /* escaped */
 311 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 312 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 313 %token E_BACKSLASH
 314 %token <i> E_UNSIGNED
 315 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 316 %token FIGURE_SPACE
 317
 318 %type <i>       exclamations questions dots optional_rest
 319 %type <i>        bass_mod
 320 %type <scm>     grace_head
 321 %type <scm>     oct_check
 322 %type <scm>     context_mod_list
 323 %type <scm>     lyric_element
 324 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 325 %token <i>      DIGIT
 326 %token <scm>    NOTENAME_PITCH
 327 %token <scm>    TONICNAME_PITCH
 328 %token <scm>    CHORDMODIFIER_PITCH
 329 %token <scm>    DURATION_IDENTIFIER
 330 %token <scm>    FRACTION
 331 %token <id>     IDENTIFIER
 332 %token <scm>    CHORDNAMES
 333 %token <scm>    CHORD_MODIFIER
 334 %token <scm>    SCORE_IDENTIFIER
 335 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 336 %token <scm>    NUMBER_IDENTIFIER
 337 %token <scm>    EVENT_IDENTIFIER
 338 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 339 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 340 %token <scm>    RESTNAME
 341 %token <scm>    STRING
 342 %token <scm>    SCM_T
 343 %token <i>      UNSIGNED
 344 %token <scm>   REAL
 345
 346 %token MARKUP
 347 %token <scm> MARKUP_HEAD_MARKUP0
 348 %token <scm> MARKUP_HEAD_EMPTY
 349 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 350 %token <scm> MARKUP_HEAD_SCM0
 351 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1
 353 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 354 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 355
 356 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 357 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 358
 359 %type <outputdef> output_def
 360 %type <scm>     lilypond_header lilypond_header_body
 361 %type <music>   open_event close_event
 362 %type <i>       sub_quotes sup_quotes
 363 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 364 %type <music>   Repeated_music
 365 %type <scm>     Alternative_music
 366 %type <i>       tremolo_type
 367 %type <i>       bare_int  bare_unsigned
 368 %type <i>       script_dir
 369 %type <scm>     identifier_init
 370
 371 %type <music> note_chord_element chord_body chord_body_element
 372 %type <scm>  chord_body_elements
 373 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 374
 375 %type <scm>   post_events
 376 %type <music> gen_text_def direction_less_event direction_reqd_event
 377 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 378 %type <scm>    steno_tonic_pitch
 379 %type <scm>     duration_length fraction
 380
 381 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 382
 383 %type <scm>  embedded_scm scalar
 384 %type <music>   Music Sequential_music Simultaneous_music
 385 %type <music>   relative_music re_rhythmed_music part_combined_music
 386 %type <music>   music_property_def context_change
 387 %type <scm> Music_list
 388 %type <scm> property_operation context_mod translator_mod optional_context_mod
 389 %type <outputdef>  music_output_def_body music_output_def_head
 390 %type <music> shorthand_command_req
 391 %type <music>   post_event tagged_post_event
 392 %type <music> command_req verbose_command_req
 393 %type <music> string_number_event
 394 %type <scm>     string bare_number number_expression number_term number_factor
 395 %type <score>   score_block score_body
 396
 397 %type <scm>     translator_spec_block translator_spec_body
 398 %type <music>   tempo_event
 399 %type <scm> notenames_body notenames_block chordmodifiers_block
 400 %type <scm>     script_abbreviation
 401
 402
 403
 404 %left '-' '+'
 405
 406 /* We don't assign precedence to / and *, because we might need varied
 407 prec levels in different prods */
 408
 409 %left UNARY_MINUS
 410
 411 %%
 412
 413 lilypond:       /* empty */
 414         | lilypond toplevel_expression {}
 415         | lilypond assignment  { }
 416         | lilypond error {
 417                 THIS->error_level_  = 1;
 418         }
 419         | lilypond INVALID      {
 420                 THIS->error_level_  = 1;
 421         }
 422         ;
 423
 424 toplevel_expression:
 425         notenames_block                 {
 426                 THIS->lexer_->pitchname_tab_ =  $1;
 427         }
 428         | chordmodifiers_block                  {
 429                 THIS->lexer_->chordmodifier_tab_  = $1;
 430         }
 431         | lilypond_header {
 432                 THIS->input_file_->header_ = $1;
 433         }
 434         | score_block {
 435                 Score * sc = $1;
 436
 437                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 438
 439                 Path p = split_path (THIS->output_basename_);
 440                 int *c =  &THIS->input_file_->score_count_;
 441                 if (*c)
 442                         {
 443                         p.base += "-" + to_string (*c);
 444                         }
 445
 446                 (*c)++;
 447                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 448
 449                 for (int i=0; i < sc->defs_.size (); i++)
 450                         default_rendering (sc->music_, sc->defs_[i]->self_scm(),head, outname);
 451
 452                 if (sc->defs_.empty ())
 453                 {
 454                    Music_output_def *id =
 455                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 456                                 ("$defaultpaper"));
 457
 458                    id = id ? id->clone () : new Paper_def;
 459
 460                    default_rendering (sc->music_, id->self_scm(), head, outname);
 461
 462                    scm_gc_unprotect_object (id->self_scm ());
 463                 }
 464                 scm_gc_unprotect_object (sc->self_scm());
 465         }
 466         | output_def {
 467                 SCM id = SCM_EOL;
 468                 if (dynamic_cast<Paper_def*> ($1))
 469                         id = scm_makfrom0str ("$defaultpaper");
 470                 else if (dynamic_cast<Midi_def*> ($1))
 471                         id = scm_makfrom0str ("$defaultmidi");
 472                 THIS->lexer_->set_identifier (id,   $1->self_scm ());
 473                 scm_gc_unprotect_object ($1->self_scm ());
 474         }
 475         ;
 476
 477 embedded_scm:
 478         SCM_T
 479         | SCM_IDENTIFIER
 480         ;
 481
 482
 483 chordmodifiers_block:
 484         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 485         ;
 486
 487 notenames_block:
 488         PITCHNAMES notenames_body   {  $$ = $2; }
 489         ;
 490
 491 notenames_body:
 492         embedded_scm    {
 493           int i = scm_ilength ($1);
 494
 495           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 496           for (SCM s = $1; gh_pair_p (s); s = ly_cdr (s)) {
 497                 SCM pt = ly_cdar (s);
 498                 scm_hashq_set_x (tab, ly_caar (s), pt);
 499           }
 500           $$ = tab;
 501         }
 502         ;
 503
 504 lilypond_header_body:
 505         {
 506                 $$ = ly_make_anonymous_module ();
 507                 THIS->lexer_->add_scope ($$);
 508         }
 509         | lilypond_header_body assignment  {
 510
 511         }
 512         ;
 513
 514 lilypond_header:
 515         HEADER '{' lilypond_header_body '}'     {
 516                 $$ = THIS->lexer_-> remove_scope();
 517         }
 518         ;
 519
 520
 521 /*
 522         DECLARATIONS
 523 */
 524 assignment:
 525         STRING {
 526                 THIS->push_spot ();
 527         }
 528         /* cont */ '=' identifier_init  {
 529
 530         /*
 531                 Should find generic way of associating input with objects.
 532         */
 533                 Input ip = THIS->pop_spot ();
 534
 535                 if (! regular_identifier_b ($1))
 536                 {
 537                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 538                 }
 539
 540                 THIS->lexer_->set_identifier ($1, $4);
 541
 542 /*
 543  TODO: devise standard for protection in parser.
 544
 545   The parser stack lives on the C-stack, which means that
 546 all objects can be unprotected as soon as they're here.
 547
 548 */
 549         }
 550         | embedded_scm { }
 551         ;
 552
 553
 554 identifier_init:
 555         score_block {
 556                 $$ = $1->self_scm ();
 557                 scm_gc_unprotect_object ($$);
 558         }
 559         | full_markup {
 560                 $$ = $1;
 561         }
 562         | output_def {
 563                 $$ = $1->self_scm ();
 564                 scm_gc_unprotect_object ($$);
 565         }
 566         | translator_spec_block {
 567                 $$ = $1;
 568         }
 569         | Music  {
 570                 $$ = $1->self_scm ();
 571                 scm_gc_unprotect_object ($$);
 572         }
 573         | post_event {
 574                 $$ = $1->self_scm ();
 575                 scm_gc_unprotect_object ($$);
 576         }
 577         | number_expression {
 578                 $$ = $1;
 579         }
 580         | string {
 581                 $$ = $1;
 582         }
 583         | embedded_scm  {
 584                 $$ = $1;
 585         }
 586         ;
 587
 588 translator_spec_block:
 589         TRANSLATOR '{' translator_spec_body '}'
 590                 {
 591                 $$ = $3;
 592         }
 593         ;
 594
 595 translator_spec_body:
 596         /**/ {
 597                 $$ = Context_def::make_scm ();
 598                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 599         }
 600         | TRANSLATOR_IDENTIFIER {
 601                 $$ = $1;
 602                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 603         }
 604         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 605                 Context_def*td = unsmob_context_def($$);
 606
 607                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 608                         SCM tag = gh_caar (p);
 609                         td->add_context_mod (scm_list_n (ly_symbol2scm ("assign"),
 610                                                         tag, ly_cdar (p), SCM_UNDEFINED));
 611                 }
 612         }
 613         | translator_spec_body context_mod {
 614                 unsmob_context_def ($$)->add_context_mod ($2);
 615         }
 616         ;
 617
 618 /*
 619         SCORE
 620 */
 621 score_block:
 622         SCORE {
 623                 THIS->push_spot ();
 624         }
 625         /*cont*/ '{' score_body '}'     {
 626                 THIS->pop_spot ();
 627                 $$ = $4;
 628
 629         }
 630         ;
 631
 632 score_body:
 633         Music   {
 634                 $$ = new Score;
 635
 636                 $$->set_spot (THIS->here_input ());
 637                 SCM m = $1->self_scm ();
 638                 scm_gc_unprotect_object (m);
 639
 640                 /*
 641                         guh.
 642                 */
 643                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 644                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 645                         m = gh_call1 (gh_car (check_funcs), m);
 646                 $$->music_ = m;
 647
 648         }
 649         | SCORE_IDENTIFIER {
 650                 $$ = new Score ( *unsmob_score ($1));
 651                 $$->set_spot (THIS->here_input ());
 652         }
 653         | score_body lilypond_header    {
 654                 $$->header_ = $2;
 655         }
 656         | score_body output_def {
 657                 $$->defs_.push ($2);
 658                 scm_gc_unprotect_object ($2->self_scm ());
 659         }
 660         | score_body error {
 661
 662         }
 663         ;
 664
 665
 666 /*
 667         MIDI
 668 */
 669 output_def:
 670         music_output_def_body '}' {
 671                 $$ = $1;
 672                 THIS-> lexer_-> remove_scope ();
 673         }
 674         ;
 675
 676 music_output_def_head:
 677         MIDI    {
 678                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 679
 680
 681                 Midi_def* p =0;
 682                 if (id)
 683                         p = dynamic_cast<Midi_def*> (id->clone ());
 684                 else
 685                         p = new Midi_def;
 686
 687                 $$ = p;
 688                 THIS->lexer_->add_scope (p->scope_);
 689         }
 690         | PAPER         {
 691                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 692                   Paper_def *p = 0;
 693                 if (id)
 694                         p = dynamic_cast<Paper_def*> (id->clone ());
 695                 else
 696                         p = new Paper_def;
 697
 698                 THIS->lexer_->add_scope (p->scope_);
 699                 $$ = p;
 700         }
 701         ;
 702
 703
 704 music_output_def_body:
 705         music_output_def_head '{' {
 706
 707         }
 708         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 709                 Music_output_def * o =  unsmob_music_output_def ($3);
 710                 $$ = o;
 711                 THIS->lexer_->remove_scope ();
 712                 THIS->lexer_->add_scope (o->scope_);
 713         }
 714         | music_output_def_body assignment  {
 715
 716         }
 717         | music_output_def_body translator_spec_block   {
 718                 $$->assign_translator ($2);
 719         }
 720         | music_output_def_body tempo_event  {
 721                 /*
 722                         junk this ? there already is tempo stuff in
 723                         music.
 724                 */
 725                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 726                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 727                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 728                 if (md)
 729                         md->set_tempo (d->get_length (), m);
 730                 scm_gc_unprotect_object ($2->self_scm ());
 731         }
 732         | music_output_def_body error {
 733
 734         }
 735         ;
 736
 737 tempo_event:
 738         TEMPO steno_duration '=' bare_unsigned  {
 739                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 740                 $$->set_mus_property ("tempo-unit", $2);
 741                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 742         }
 743         ;
 744
 745 /*
 746 The representation of a  list is the
 747
 748   (LIST . LAST-CONS)
 749
 750  to have  efficient append.
 751 */
 752 Music_list:
 753         /* empty */ {
 754                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 755         }
 756         | Music_list Music {
 757                 SCM s = $$;
 758                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 759                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 760                 if (gh_pair_p (ly_cdr (s)))
 761                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 762                 else
 763                         gh_set_car_x (s, c); /* set first cons */
 764                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 765         }
 766         | Music_list error {
 767         }
 768         ;
 769
 770
 771 Music:
 772         Simple_music
 773         | Composite_music
 774         ;
 775
 776 Alternative_music:
 777         /* empty */ {
 778                 $$ = SCM_EOL;
 779         }
 780         | ALTERNATIVE '{' Music_list '}' {
 781                 $$ = $3;
 782         }
 783         ;
 784
 785 Repeated_music:
 786         REPEAT string bare_unsigned Music Alternative_music
 787         {
 788                 Music *beg = $4;
 789                 int times = $3;
 790                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 791                 if (times < scm_ilength (alts)) {
 792                   unsmob_music (gh_car (alts))
 793                     ->origin ()->warning (
 794                     _("More alternatives than repeats.  Junking excess alternatives."));
 795                   alts = ly_truncate_list (times, alts);
 796                 }
 797
 798
 799                 static SCM proc;
 800                 if (!proc)
 801                         proc = scm_c_eval_string ("make-repeated-music");
 802
 803                 SCM mus = scm_call_1 (proc, $2);
 804                 scm_gc_protect_object (mus); // UGH.
 805                 Music *r =unsmob_music (mus);
 806                 if (beg)
 807                         {
 808                         r-> set_mus_property ("element", beg->self_scm ());
 809                         scm_gc_unprotect_object (beg->self_scm ());
 810                         }
 811                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 812
 813                 r-> set_mus_property ("elements",alts);
 814                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 815                         /*
 816                         we can not get durations and other stuff correct down the line, so we have to
 817                         add to the duration log here.
 818                         */
 819                         static SCM func;
 820
 821                         if (!func)
 822                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 823
 824                         int dots = ($3 % 3) ? 0 : 1;
 825                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 826
 827                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 828
 829                         if (seq) {
 830                                 int list_len =scm_ilength (seq->music_list ());
 831                                 if (list_len != 2)
 832                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 833                                 shift -= 1;
 834                                 r->compress (Moment (Rational (1,list_len)));
 835                                 }
 836                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 837
 838                 }
 839                 r->set_spot (*$4->origin ());
 840
 841                 $$ = r;
 842         }
 843         ;
 844
 845 Sequential_music:
 846         SEQUENTIAL '{' Music_list '}'           {
 847                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 848                 $$->set_mus_property ("elements", ly_car ($3));
 849                 $$->set_spot(THIS->here_input());
 850         }
 851         | '{' Music_list '}'            {
 852                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 853                 $$->set_mus_property ("elements", ly_car ($2));
 854                 $$->set_spot(THIS->here_input());
 855         }
 856         ;
 857
 858 Simultaneous_music:
 859         SIMULTANEOUS '{' Music_list '}'{
 860                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 861                 $$->set_mus_property ("elements", ly_car ($3));
 862                 $$->set_spot(THIS->here_input());
 863
 864         }
 865         | simul_open Music_list simul_close     {
 866                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 867                 $$->set_mus_property ("elements", ly_car ($2));
 868                 $$->set_spot(THIS->here_input());
 869         }
 870         ;
 871
 872 Simple_music:
 873         event_chord             { $$ = $1; }
 874         | APPLYOUTPUT embedded_scm {
 875                 if (!ly_input_procedure_p ($2))
 876                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 877                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 878                 $$->set_mus_property ("procedure", $2);
 879                 $$->set_spot (THIS->here_input());
 880         }
 881         | APPLYCONTEXT embedded_scm {
 882                 if (!ly_input_procedure_p ($2))
 883                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 884                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 885                 $$->set_mus_property ("procedure", $2);
 886                 $$->set_spot (THIS->here_input());
 887         }
 888         | MUSIC_IDENTIFIER {
 889                 $$ = unsmob_music ($1);
 890         }
 891         | music_property_def
 892         | context_change
 893         ;
 894
 895
 896 optional_context_mod:
 897         /**/ { $$ = SCM_EOL; }
 898         | WITH '{' context_mod_list '}'  { $$ = $3; }
 899         ;
 900
 901 grace_head:
 902         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 903         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 904         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 905         ;
 906
 907 context_mod_list:
 908         /* */  { $$ = SCM_EOL; }
 909         | context_mod_list context_mod  {
 910                  $$ = gh_cons ($2, $1);
 911         }
 912         ;
 913
 914 Composite_music:
 915         AUTOCHANGE STRING Music {
 916                 Music*chm = MY_MAKE_MUSIC("AutoChangeMusic");
 917                 chm->set_mus_property ("element", $3->self_scm ());
 918                 chm->set_mus_property ("iterator-ctor", Auto_change_iterator::constructor_proc);
 919
 920                 scm_gc_unprotect_object ($3->self_scm ());
 921                 chm->set_mus_property ("what", scm_string_to_symbol ($2));
 922
 923                 $$ = chm;
 924                 chm->set_spot (*$3->origin ());
 925         }
 926         | grace_head Music {
 927 #if 1
 928         /*
 929                 The other version is for easier debugging  of
 930                 Sequential_music_iterator in combination with grace notes.
 931         */
 932
 933 /*
 934
 935 TODO: should distinguish between both grace types in the
 936 basic music objects too, since the meaning is different.
 937
 938 */
 939
 940                 String start_str = "start" + ly_scm2string ($1) + "Music";
 941                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 942
 943                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 944                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 945
 946                 Music *startm = unsmob_music (start);
 947                 Music *stopm = unsmob_music (stop);
 948
 949                 SCM ms = SCM_EOL;
 950                 if (stopm) {
 951                         stopm = stopm->clone ();
 952                         ms = scm_cons (stopm->self_scm (), ms);
 953                         scm_gc_unprotect_object (stopm->self_scm ());
 954                 }
 955                 ms = scm_cons ($2->self_scm (), ms);
 956                 scm_gc_unprotect_object ($2->self_scm());
 957                 if (startm) {
 958                         startm = startm->clone ();
 959                         ms = scm_cons (startm->self_scm () , ms);
 960                         scm_gc_unprotect_object (startm->self_scm ());
 961                 }
 962
 963
 964                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 965                 seq->set_mus_property ("elements", ms);
 966
 967
 968                 $$ = MY_MAKE_MUSIC("GraceMusic");
 969                 $$->set_mus_property ("element", seq->self_scm ());
 970                 scm_gc_unprotect_object (seq->self_scm ());
 971 #else
 972                 $$ = MY_MAKE_MUSIC("GraceMusic");
 973                 $$->set_mus_property ("element", $2->self_scm ());
 974                 scm_gc_unprotect_object ($2->self_scm ());
 975 #endif
 976         }
 977         | CONTEXT string '=' string optional_context_mod Music {
 978                 $$ = context_spec_music ($2, $4, $6, $5);
 979
 980         }
 981         | CONTEXT STRING optional_context_mod Music {
 982                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 983         }
 984         | NEWCONTEXT string optional_context_mod Music {
 985                 $$ = context_spec_music ($2, get_next_unique_context (),
 986                                          $4, $3);
 987         }
 988
 989         | TIMES {
 990                 THIS->push_spot ();
 991         }
 992         /* CONTINUED */
 993                 fraction Music
 994
 995         {
 996                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 997                 Music *mp = $4;
 998
 999                 $$= MY_MAKE_MUSIC("TimeScaledMusic");
1000                 $$->set_spot (THIS->pop_spot ());
1001
1002                 $$->set_mus_property ("element", mp->self_scm ());
1003                 scm_gc_unprotect_object (mp->self_scm ());
1004                 $$->set_mus_property ("numerator", gh_int2scm (n));
1005                 $$->set_mus_property ("denominator", gh_int2scm (d));
1006                 $$->compress (Moment (Rational (n,d)));
1007
1008         }
1009         | Repeated_music                { $$ = $1; }
1010         | Simultaneous_music            { $$ = $1; }
1011         | Sequential_music              { $$ = $1; }
1012         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1013                 $$ = MY_MAKE_MUSIC("TransposedMusic");
1014                 Music *p = $4;
1015                 Pitch from = *unsmob_pitch ($2);
1016                 Pitch to = *unsmob_pitch ($3);
1017
1018                 p->transpose (interval (from, to));
1019                 $$->set_mus_property ("element", p->self_scm ());
1020                 scm_gc_unprotect_object (p->self_scm ());
1021         }
1022         | APPLY embedded_scm Music  {
1023                 if (!ly_input_procedure_p ($2))
1024                         {
1025                         THIS->parser_error (_ ("\\apply takes function argument"));
1026                         $$ = $3;
1027                         }
1028                 else
1029                         {
1030                         SCM ret = gh_call1 ($2, $3->self_scm ());
1031                         Music *m = unsmob_music (ret);
1032                         if (!m) {
1033                                 THIS->parser_error ("\\apply must return a Music");
1034                                 m = MY_MAKE_MUSIC("Music");
1035                                 }
1036                         $$ = m;
1037                         }
1038         }
1039         | NOTES
1040                 { THIS->lexer_->push_note_state (); }
1041         Music
1042                 { $$ = $3;
1043                   THIS->lexer_->pop_state ();
1044                 }
1045         | FIGURES
1046                 { THIS->lexer_->push_figuredbass_state (); }
1047         Music
1048                 {
1049                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1050                   chm->set_mus_property ("element", $3->self_scm ());
1051                   $$ = chm;
1052                   scm_gc_unprotect_object ($3->self_scm());
1053
1054                   THIS->lexer_->pop_state ();
1055         }
1056         | CHORDS
1057                 { THIS->lexer_->push_chord_state (); }
1058         Music
1059                 {
1060                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1061                   chm->set_mus_property ("element", $3->self_scm ());
1062                   scm_gc_unprotect_object ($3->self_scm());
1063                   $$ = chm;
1064
1065                   THIS->lexer_->pop_state ();
1066         }
1067         | LYRICS
1068                 { THIS->lexer_->push_lyric_state (); }
1069         Music
1070                 {
1071                   $$ = $3;
1072                   THIS->lexer_->pop_state ();
1073         }
1074         | relative_music        { $$ = $1; }
1075         | re_rhythmed_music     { $$ = $1; }
1076         | part_combined_music   { $$ = $1; }
1077         | TAG embedded_scm Music {
1078                 tag_music ($3, $2, THIS->here_input ());
1079                 $$ = $3;
1080         }
1081         ;
1082
1083 relative_music:
1084         RELATIVE absolute_pitch Music {
1085                 Music * p = $3;
1086                 Pitch pit = *unsmob_pitch ($2);
1087                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1088
1089                 $$->set_mus_property ("element", p->self_scm ());
1090                 scm_gc_unprotect_object (p->self_scm ());
1091
1092
1093                 Pitch retpitch = p->to_relative_octave (pit);
1094                 if (lily_1_8_relative)
1095                         $$->set_mus_property ("last-pitch", retpitch.smobbed_copy ());
1096         }
1097         ;
1098
1099 re_rhythmed_music:
1100         ADDLYRICS Music Music {
1101         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1102           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1103           scm_gc_unprotect_object ($3->self_scm ());
1104           scm_gc_unprotect_object ($2->self_scm ());
1105           $$ = l;
1106         }
1107         | NEWADDLYRICS string Music {
1108           Music*l =MY_MAKE_MUSIC("NewLyricCombineMusic");
1109           l->set_mus_property ("element", $3->self_scm ());
1110           scm_gc_unprotect_object ($3->self_scm ());
1111           $$ = l;
1112           l->set_mus_property ("associated-context", $2);
1113         }
1114         ;
1115
1116 part_combined_music:
1117         PARTCOMBINE STRING Music Music {
1118                 Music * p= MY_MAKE_MUSIC("PartCombineMusic");
1119                 p->set_mus_property ("what", scm_string_to_symbol ($2));
1120                 p->set_mus_property ("elements", gh_list ($3->self_scm (),$4->self_scm (), SCM_UNDEFINED));
1121
1122                 scm_gc_unprotect_object ($3->self_scm ());
1123                 scm_gc_unprotect_object ($4->self_scm ());
1124
1125                 $$ = p;
1126         }
1127         | NEWPARTCOMBINE Music Music {
1128                 static SCM proc;
1129                 if (!proc)
1130                         proc = scm_c_eval_string ("make-new-part-combine-music");
1131
1132                 SCM res = scm_call_1 (proc, gh_list ($2->self_scm (),
1133                         $3->self_scm (), SCM_UNDEFINED));
1134                 scm_gc_unprotect_object ($3->self_scm ());
1135                 scm_gc_unprotect_object ($2->self_scm ());
1136                 $$ = unsmob_music (res);
1137                 scm_gc_protect_object (res);
1138         }
1139         ;
1140
1141 context_change:
1142         CHANGE STRING '=' STRING  {
1143                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1144                 t-> set_mus_property ("change-to-type", scm_string_to_symbol ($2));
1145                 t-> set_mus_property ("change-to-id", $4);
1146
1147                 $$ = t;
1148                 $$->set_spot (THIS->here_input ());
1149         }
1150         ;
1151
1152 property_operation:
1153         STRING '='  scalar {
1154                 $$ = scm_list_n (ly_symbol2scm ("assign"),
1155                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1156         }
1157         | STRING UNSET {
1158                 $$ = scm_list_n (ly_symbol2scm ("unset"),
1159                         scm_string_to_symbol ($1), SCM_UNDEFINED);
1160         }
1161         | STRING SET embedded_scm '=' embedded_scm {
1162                 $$ = scm_list_n (ly_symbol2scm ("poppush"),
1163                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1164         }
1165         | STRING OVERRIDE embedded_scm '=' embedded_scm {
1166                 $$ = scm_list_n (ly_symbol2scm ("push"),
1167                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1168         }
1169         | STRING REVERT embedded_scm {
1170                 $$ = scm_list_n (ly_symbol2scm ("pop"),
1171                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1172         }
1173         ;
1174
1175 translator_mod:
1176         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1177         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1178         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1179
1180         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1181         | DENIES { $$ = ly_symbol2scm ("denies"); }
1182
1183         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1184         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1185         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1186         | NAME { $$ = ly_symbol2scm ("context-name"); }
1187         ;
1188
1189 context_mod:
1190         property_operation { $$ = $1; }
1191         | translator_mod STRING {
1192                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
1193         }
1194         ;
1195
1196 music_property_def:
1197         PROPERTY STRING '.' property_operation {
1198                 Music * t = property_op_to_music ($4);
1199                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1200
1201                 csm->set_mus_property ("element", t->self_scm ());
1202                 scm_gc_unprotect_object (t->self_scm ());
1203
1204                 $$ = csm;
1205                 $$->set_spot (THIS->here_input ());
1206
1207                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1208         }
1209         | ONCE music_property_def {
1210                 $$ = $2;
1211                 SCM e = $2->get_mus_property ("element");
1212                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1213         }
1214         ;
1215
1216
1217 scalar:
1218         string          { $$ = $1; }
1219         | bare_int      { $$ = gh_int2scm ($1); }
1220         | embedded_scm  { $$ = $1; }
1221         | full_markup {  $$ = $1; }
1222         | DIGIT { $$ = gh_int2scm ($1); }
1223         ;
1224
1225 /*
1226 This is a trick:
1227
1228 Adding pre_events to the simple_element
1229 makes the choice between
1230
1231   string:  STRING
1232
1233 and
1234
1235   simple_element: STRING
1236
1237 a single shift/reduction conflict.
1238
1239 nevertheless, this is not very clean, and we should find a different
1240 solution.
1241
1242 */
1243 pre_events: {
1244                 THIS->push_spot ();
1245         }
1246         ;
1247
1248 event_chord:
1249         pre_events simple_element post_events   {
1250                 SCM elts = $2-> get_mus_property ("elements");
1251
1252                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1253
1254                 $2->set_mus_property ("elements", elts);
1255                 $$ = $2;
1256         }
1257         | command_element
1258         | note_chord_element
1259         ;
1260
1261
1262 note_chord_element:
1263         chord_body optional_notemode_duration post_events
1264         {
1265                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1266                 SCM es = $1->get_mus_property ("elements");
1267                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1268
1269                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1270                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1271                 es = gh_append2 (es, postevs);
1272
1273                 $1-> set_mus_property ("elements", es);
1274                 $$ = $1;
1275         }
1276         ;
1277
1278 chord_open: '<'
1279         ;
1280
1281 chord_close: '>'
1282         ;
1283
1284 simul_open: LESSLESS
1285         ;
1286
1287 simul_close: MOREMORE
1288         ;
1289
1290 chord_body:
1291         chord_open chord_body_elements chord_close
1292         {
1293                 $$ = MY_MAKE_MUSIC("EventChord");
1294                 $$->set_mus_property ("elements",
1295                         scm_reverse_x ($2, SCM_EOL));
1296         }
1297         ;
1298
1299 chord_body_elements:
1300         /* empty */             { $$ = SCM_EOL; }
1301         | chord_body_elements chord_body_element {
1302                 $$ = gh_cons ($2->self_scm(), $1);
1303                 scm_gc_unprotect_object ($2->self_scm());
1304         }
1305         ;
1306
1307 chord_body_element:
1308         pitch exclamations questions post_events
1309         {
1310                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1311                 n->set_mus_property ("pitch", $1);
1312                 if ($3 % 2)
1313                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1314                 if ($2 % 2 || $3 % 2)
1315                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1316
1317                 SCM arts = scm_reverse_x ($4, SCM_EOL);
1318                 n->set_mus_property ("articulations", arts);
1319
1320                 $$ = n;
1321         }
1322         ;
1323
1324 command_element:
1325         command_req {
1326                 $$ = MY_MAKE_MUSIC("EventChord");
1327                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1328                 scm_gc_unprotect_object ($1->self_scm());
1329
1330                 $$-> set_spot (THIS->here_input ());
1331                 $1-> set_spot (THIS->here_input ());
1332         }
1333         | OCTAVE { THIS->push_spot (); }
1334           pitch {
1335                 Music *l = MY_MAKE_MUSIC("RelativeOctaveCheck");
1336                 $$ = l;
1337                 $$->set_spot (THIS->pop_spot ());
1338                 $$->set_mus_property ("pitch", $3);
1339         }
1340         | E_LEFTSQUARE {
1341                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1342                 l->set_mus_property ("span-direction", gh_int2scm (START));
1343                 l->set_spot (THIS->here_input ());
1344
1345                 $$ = MY_MAKE_MUSIC("EventChord");
1346                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1347                 scm_gc_unprotect_object (l->self_scm());
1348                 $$->set_spot (THIS->here_input ());
1349         }
1350         | E_RIGHTSQUARE {
1351                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1352                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1353                 l->set_spot (THIS->here_input ());
1354
1355                 $$ = MY_MAKE_MUSIC("EventChord");
1356                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1357                 $$->set_spot (THIS->here_input ());
1358                 scm_gc_unprotect_object (l->self_scm());
1359         }
1360         | E_BACKSLASH {
1361                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1362                 $$->set_spot (THIS->here_input ());
1363         }
1364         | '|'      {
1365
1366                 $$ = MY_MAKE_MUSIC("BarCheck");
1367                 $$->set_spot (THIS->here_input ());
1368         }
1369         | BAR STRING                    {
1370                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1371
1372                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1373                 csm->set_mus_property ("element", t->self_scm ());
1374                 scm_gc_unprotect_object (t->self_scm ());
1375
1376                 $$ = csm;
1377                 $$->set_spot (THIS->here_input ());
1378
1379                 csm->set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1380         }
1381         | PARTIAL duration_length       {
1382                 Moment m = - unsmob_duration ($2)->get_length ();
1383                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1384
1385                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1386                 sp->set_mus_property ("element", p->self_scm ());
1387                 scm_gc_unprotect_object (p->self_scm ());
1388
1389                 $$ =sp ;
1390                 sp-> set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1391         }
1392         | CLEF STRING  {
1393                 static SCM proc ;
1394                 if (!proc)
1395                         proc = scm_c_eval_string ("make-clef-set");
1396
1397                 SCM result = scm_call_1 (proc, $2);
1398                 scm_gc_protect_object (result);
1399                 $$ = unsmob_music (result);
1400         }
1401         | TIME_T fraction  {
1402                 static SCM proc;
1403                 if (!proc)
1404                         proc = scm_c_eval_string ("make-time-signature-set");
1405
1406                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1407                 scm_gc_protect_object (result);
1408                 $$ = unsmob_music (result);
1409         }
1410         | MARK scalar {
1411                 static SCM proc;
1412                 if (!proc)
1413                         proc = scm_c_eval_string ("make-mark-set");
1414
1415                 SCM result = scm_call_1 (proc, $2);
1416                 scm_gc_protect_object (result);
1417                 $$ = unsmob_music (result);
1418         }
1419         ;
1420
1421 command_req:
1422         shorthand_command_req   { $$ = $1; }
1423         | verbose_command_req   { $$ = $1; }
1424         ;
1425
1426 shorthand_command_req:
1427         BREATHE {
1428                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1429         }
1430         | E_TILDE {
1431                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1432         }
1433         ;
1434
1435 verbose_command_req:
1436         MARK DEFAULT  {
1437                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1438                 $$ = m;
1439         }
1440
1441         | SKIP duration_length {
1442                 Music * skip = MY_MAKE_MUSIC("SkipEvent");
1443                 skip->set_mus_property ("duration", $2);
1444
1445                 $$ = skip;
1446         }
1447         | tempo_event {
1448                 $$ = $1;
1449         }
1450         | KEY DEFAULT {
1451                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1452                 $$ = key;
1453         }
1454         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1455
1456                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1457                 if (scm_ilength ($3) > 0)
1458                 {
1459                         key->set_mus_property ("pitch-alist", $3);
1460                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1461                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1462                 } else {
1463                         THIS->parser_error (_("Second argument must be pitch list."));
1464                 }
1465
1466                 $$ = key;
1467         }
1468         ;
1469
1470 post_events:
1471         /* empty */ {
1472                 $$ = SCM_EOL;
1473         }
1474         | post_events post_event {
1475                 $2->set_spot (THIS->here_input ());
1476                 $$ = gh_cons ($2->self_scm(), $$);
1477                 scm_gc_unprotect_object ($2->self_scm());
1478         }
1479         | post_events tagged_post_event {
1480                 $2 -> set_spot (THIS->here_input ());
1481                 $$ = scm_cons ($2->self_scm(), $$);
1482                 scm_gc_unprotect_object ($2->self_scm());
1483         }
1484         ;
1485
1486
1487 tagged_post_event:
1488         '-' TAG embedded_scm post_event {
1489                 tag_music ($4, $3, THIS->here_input ());
1490                 $$ = $4;
1491         }
1492         ;
1493
1494 post_event:
1495         direction_less_event {
1496                 $$ = $1;
1497         }
1498         | HYPHEN {
1499                 if (!THIS->lexer_->lyric_state_b ())
1500                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1501                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1502         }
1503         | EXTENDER {
1504                 if (!THIS->lexer_->lyric_state_b ())
1505                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1506                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1507         }
1508         | script_dir direction_reqd_event {
1509                 if ($1)
1510                         $2->set_mus_property ("direction", gh_int2scm ($1));
1511                 $$ = $2;
1512         }
1513         | script_dir direction_less_event {
1514                 if ($1)
1515                         $2->set_mus_property ("direction", gh_int2scm ($1));
1516                 $$ = $2;
1517         }
1518         | string_number_event
1519         ;
1520
1521 string_number_event:
1522         E_UNSIGNED {
1523                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1524                 s->set_mus_property ("string-number",  gh_int2scm($1));
1525                 s->set_spot (THIS->here_input ());
1526                 $$ = s;
1527         }
1528         ;
1529
1530
1531 direction_less_event:
1532         '['  {
1533
1534
1535 /*
1536
1537 TODO: should take all these defs out of the parser, adn make use
1538 configurable, i.e.
1539
1540
1541 (set-articulation '~ "trill")
1542
1543 */
1544                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1545                 m->set_spot (THIS->here_input());
1546                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1547                 $$ = m;
1548         }
1549         | ']'  {
1550                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1551                 m->set_spot (THIS->here_input());
1552                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1553                 $$ = m;
1554         }
1555         | '~' {
1556                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1557                 m->set_spot (THIS->here_input());
1558                 $$ = m;
1559         }
1560         | close_event {
1561                 $$ = $1;
1562                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1563                         gh_int2scm (START));
1564         }
1565         | open_event {
1566                 $$ = $1;
1567                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1568                         gh_int2scm (STOP));
1569         }
1570         | EVENT_IDENTIFIER      {
1571                 $$ = unsmob_music ($1);
1572         }
1573         | tremolo_type  {
1574                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1575                a->set_spot (THIS->here_input ());
1576                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1577                $$ = a;
1578         }
1579         ;
1580
1581 direction_reqd_event:
1582         gen_text_def {
1583                 $$ = $1;
1584         }
1585         | script_abbreviation {
1586                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1587                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1588                 if (gh_string_p (s))
1589                         a->set_mus_property ("articulation-type", s);
1590                 else THIS->parser_error (_ ("Expecting string as script definition"));
1591                 $$ = a;
1592         }
1593         ;
1594
1595 oct_check:
1596         /**/ { $$ = SCM_EOL; }
1597         | '='  { $$ = gh_int2scm (0); }
1598         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1599         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1600         ;
1601
1602 sup_quotes:
1603         '\'' {
1604                 $$ = 1;
1605         }
1606         | sup_quotes '\'' {
1607                 $$ ++;
1608         }
1609         ;
1610
1611 sub_quotes:
1612         ',' {
1613                 $$ = 1;
1614         }
1615         | sub_quotes ',' {
1616                 $$ ++ ;
1617         }
1618         ;
1619
1620 steno_pitch:
1621         NOTENAME_PITCH  {
1622                 $$ = $1;
1623         }
1624         | NOTENAME_PITCH sup_quotes     {
1625                 Pitch p = *unsmob_pitch ($1);
1626                 p = p.transposed (Pitch ($2,0,0));
1627                 $$ = p.smobbed_copy ();
1628         }
1629         | NOTENAME_PITCH sub_quotes      {
1630                 Pitch p =* unsmob_pitch ($1);
1631                 p = p.transposed (Pitch (-$2,0,0));
1632                 $$ = p.smobbed_copy ();
1633         }
1634         ;
1635
1636 /*
1637 ugh. duplication
1638 */
1639
1640 steno_tonic_pitch:
1641         TONICNAME_PITCH {
1642                 $$ = $1;
1643         }
1644         | TONICNAME_PITCH sup_quotes    {
1645                 Pitch p = *unsmob_pitch ($1);
1646                 p = p.transposed (Pitch ($2,0,0));
1647                 $$ = p.smobbed_copy ();
1648         }
1649         | TONICNAME_PITCH sub_quotes     {
1650                 Pitch p =* unsmob_pitch ($1);
1651
1652                 p = p.transposed (Pitch (-$2,0,0));
1653                 $$ = p.smobbed_copy ();
1654         }
1655         ;
1656
1657 pitch:
1658         steno_pitch {
1659                 $$ = $1;
1660         }
1661         ;
1662
1663 pitch_also_in_chords:
1664         pitch
1665         | steno_tonic_pitch
1666         ;
1667
1668 close_event:
1669         '('     {
1670                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1671                 $$ = s;
1672                 s->set_spot (THIS->here_input());
1673         }
1674         | E_OPEN        {
1675                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1676                 $$ = s;
1677                 s->set_spot (THIS->here_input());
1678         }
1679         | E_SMALLER {
1680                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1681                 $$ = s;
1682                 s->set_spot (THIS->here_input());
1683         }
1684         | E_BIGGER {
1685                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1686                 $$ = s;
1687                 s->set_spot (THIS->here_input());
1688         }
1689         ;
1690
1691
1692 open_event:
1693         E_EXCLAMATION   {
1694                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1695                 s->set_spot (THIS->here_input());
1696
1697                 $$ = s;
1698         }
1699         | ')'   {
1700                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1701                 $$ = s;
1702                 s->set_spot (THIS->here_input());
1703
1704         }
1705         | E_CLOSE       {
1706                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1707                 $$ = s;
1708                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1709                 s->set_spot (THIS->here_input());
1710         }
1711         ;
1712
1713 gen_text_def:
1714         full_markup {
1715                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1716                 t->set_mus_property ("text", $1);
1717                 t->set_spot (THIS->here_input ());
1718                 $$ = t;
1719         }
1720         | string {
1721                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1722                 t->set_mus_property ("text", make_simple_markup ($1));
1723                 t->set_spot (THIS->here_input ());
1724                 $$ = t;
1725
1726         }
1727         | DIGIT {
1728                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1729                 t->set_mus_property ("digit",  gh_int2scm ($1));
1730                 t->set_spot (THIS->here_input ());
1731                 $$ = t;
1732         }
1733         ;
1734
1735 script_abbreviation:
1736         '^'             {
1737                 $$ = scm_makfrom0str ("Hat");
1738         }
1739         | '+'           {
1740                 $$ = scm_makfrom0str ("Plus");
1741         }
1742         | '-'           {
1743                 $$ = scm_makfrom0str ("Dash");
1744         }
1745         | '|'           {
1746                 $$ = scm_makfrom0str ("Bar");
1747         }
1748         | '>'           {
1749                 $$ = scm_makfrom0str ("Larger");
1750         }
1751         | '.'           {
1752                 $$ = scm_makfrom0str ("Dot");
1753         }
1754         | '_' {
1755                 $$ = scm_makfrom0str ("Underscore");
1756         }
1757         ;
1758
1759 script_dir:
1760         '_'     { $$ = DOWN; }
1761         | '^'   { $$ = UP; }
1762         | '-'   { $$ = CENTER; }
1763         ;
1764
1765
1766 absolute_pitch:
1767         steno_pitch     {
1768                 $$ = $1;
1769         }
1770         ;
1771
1772 duration_length:
1773         multiplied_duration {
1774                 $$ = $1;
1775         }
1776         ;
1777
1778 optional_notemode_duration:
1779         {
1780                 Duration dd = THIS->default_duration_;
1781                 $$ = dd.smobbed_copy ();
1782
1783                 THIS->beam_check ($$);
1784         }
1785         | multiplied_duration   {
1786                 $$ = $1;
1787                 THIS->default_duration_ = *unsmob_duration ($$);
1788
1789                 THIS->beam_check ($$);
1790         }
1791         ;
1792
1793 steno_duration:
1794         bare_unsigned dots              {
1795                 int l = 0;
1796                 if (!is_duration_b ($1))
1797                         THIS->parser_error (_f ("not a duration: %d", $1));
1798                 else
1799                         l =  intlog2 ($1);
1800
1801                 $$ = Duration (l, $2).smobbed_copy ();
1802         }
1803         | DURATION_IDENTIFIER dots      {
1804                 Duration *d =unsmob_duration ($1);
1805                 Duration k (d->duration_log (),d->dot_count () + $2);
1806
1807                 *d = k;
1808                 $$ = $1;
1809         }
1810         ;
1811
1812
1813
1814
1815 multiplied_duration:
1816         steno_duration {
1817                 $$ = $1;
1818         }
1819         | multiplied_duration '*' bare_unsigned {
1820                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1821         }
1822         | multiplied_duration '*' FRACTION {
1823                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1824
1825                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1826         }
1827         ;
1828
1829 fraction:
1830         FRACTION { $$ = $1; }
1831         | UNSIGNED '/' UNSIGNED {
1832                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1833         }
1834         ;
1835
1836 dots:
1837         /* empty */     {
1838                 $$ = 0;
1839         }
1840         | dots '.' {
1841                 $$ ++;
1842         }
1843         ;
1844
1845
1846 tremolo_type:
1847         ':'     {
1848                 $$ =0;
1849         }
1850         | ':' bare_unsigned {
1851                 if (!is_duration_b ($2))
1852                         THIS->parser_error (_f ("not a duration: %d", $2));
1853                 $$ = $2;
1854         }
1855         ;
1856
1857
1858
1859 /*****************************************************************
1860                 BASS FIGURES
1861 *****************************************************************/
1862 bass_number:
1863         DIGIT   {
1864                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1865         }
1866         | UNSIGNED {
1867                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1868         }
1869         | STRING { $$ =  $1; }
1870         ;
1871
1872 bass_mod:
1873         '-'     { $$ = -2; }
1874         | '+'   { $$ = 2; }
1875         | '!'   { $$ = 0; }
1876         ;
1877
1878 bass_figure:
1879         FIGURE_SPACE {
1880                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1881                 $$ = bfr->self_scm();
1882                 scm_gc_unprotect_object ($$);
1883         }
1884         | bass_number  {
1885                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1886                 $$ = bfr->self_scm();
1887
1888                 bfr->set_mus_property ("figure", $1);
1889
1890                 scm_gc_unprotect_object ($$);
1891         }
1892         | bass_figure bass_mod {
1893                 Music *m = unsmob_music ($1);
1894                 if ($2) {
1895                         SCM salter =m->get_mus_property ("alteration");
1896                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1897                         m->set_mus_property ("alteration",
1898                                 gh_int2scm (alter + $2));
1899                 } else {
1900                         m->set_mus_property ("alteration", gh_int2scm (0));
1901                 }
1902         }
1903         ;
1904
1905 br_bass_figure:
1906         '[' bass_figure {
1907                 $$ = $2;
1908                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1909         }
1910         | bass_figure   {
1911                 $$ = $1;
1912         }
1913         | br_bass_figure ']' {
1914                 $$ = $1;
1915                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1916         }
1917         ;
1918
1919 figure_list:
1920         /**/            {
1921                 $$ = SCM_EOL;
1922         }
1923         | figure_list br_bass_figure {
1924                 $$ = scm_cons ($2, $1);
1925         }
1926         ;
1927
1928 figure_spec:
1929         FIGURE_OPEN figure_list FIGURE_CLOSE {
1930                 Music * m = MY_MAKE_MUSIC("EventChord");
1931                 $2 = scm_reverse_x ($2, SCM_EOL);
1932                 m->set_mus_property ("elements",  $2);
1933                 $$ = m->self_scm ();
1934         }
1935         ;
1936
1937
1938 optional_rest:
1939         /**/   { $$ = 0; }
1940         | REST { $$ = 1; }
1941         ;
1942
1943 simple_element:
1944         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1945
1946                 Input i = THIS->pop_spot ();
1947                 if (!THIS->lexer_->note_state_b ())
1948                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1949
1950                 Music *n = 0;
1951                 if ($6)
1952                         n =  MY_MAKE_MUSIC("RestEvent");
1953                 else
1954                         n =  MY_MAKE_MUSIC("NoteEvent");
1955
1956                 n->set_mus_property ("pitch", $1);
1957                 n->set_mus_property ("duration", $5);
1958
1959                 if (gh_number_p ($4))
1960                 {
1961                         int q = gh_scm2int ($4);
1962                         n->set_mus_property ("absolute-octave", gh_int2scm (q-1));
1963                 }
1964
1965                 if ($3 % 2)
1966                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1967                 if ($2 % 2 || $3 % 2)
1968                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1969
1970                 Music *v = MY_MAKE_MUSIC("EventChord");
1971                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1972                 scm_gc_unprotect_object (n->self_scm());
1973
1974                 v->set_spot (i);
1975                 n->set_spot (i);
1976                 $$ = v;
1977         }
1978         | figure_spec optional_notemode_duration {
1979                 Music * m = unsmob_music ($1);
1980                 Input i = THIS->pop_spot ();
1981                 m->set_spot (i);
1982                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
1983                 {
1984                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
1985                 }
1986                 $$ = m;
1987         }
1988         | RESTNAME optional_notemode_duration           {
1989
1990                 Input i = THIS->pop_spot ();
1991                 Music * ev = 0;
1992                 if (ly_scm2string ($1) =="s") {
1993                         /* Space */
1994                         ev = MY_MAKE_MUSIC("SkipEvent");
1995                   }
1996                 else {
1997                         ev = MY_MAKE_MUSIC("RestEvent");
1998
1999                     }
2000                 ev->set_mus_property ("duration" ,$2);
2001                 ev->set_spot (i);
2002                 Music * velt = MY_MAKE_MUSIC("EventChord");
2003                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
2004                 velt->set_spot (i);
2005
2006                 scm_gc_unprotect_object (ev->self_scm());
2007
2008                 $$ = velt;
2009         }
2010         | MULTI_MEASURE_REST optional_notemode_duration         {
2011                 THIS->pop_spot ();
2012
2013                 static SCM proc ;
2014                 if (!proc)
2015                         proc = scm_c_eval_string ("make-multi-measure-rest");
2016
2017                 SCM mus = scm_call_2 (proc, $2,
2018                         make_input (THIS->here_input()));
2019                 scm_gc_protect_object (mus);
2020                 $$ = unsmob_music (mus);
2021         }
2022
2023         | lyric_element optional_notemode_duration      {
2024                 Input i = THIS->pop_spot ();
2025                 if (!THIS->lexer_->lyric_state_b ())
2026                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2027
2028                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2029                 lreq->set_mus_property ("text", $1);
2030                 lreq->set_mus_property ("duration",$2);
2031                 lreq->set_spot (i);
2032                 Music * velt = MY_MAKE_MUSIC("EventChord");
2033                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2034
2035                 $$= velt;
2036         }
2037         | new_chord {
2038                 THIS->pop_spot ();
2039
2040                 if (!THIS->lexer_->chord_state_b ())
2041                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2042                 $$ = unsmob_music ($1);
2043         }
2044         ;
2045
2046 lyric_element:
2047         full_markup { $$ = $1; }
2048         | STRING {  $$ = $1 ; }
2049         ;
2050
2051 new_chord:
2052         steno_tonic_pitch optional_notemode_duration   {
2053                 $$ = make_chord ($1, $2, SCM_EOL);
2054         }
2055         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2056                 SCM its = scm_reverse_x ($4, SCM_EOL);
2057                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2058         }
2059         ;
2060
2061 chord_items:
2062         /**/ {
2063                 $$ = SCM_EOL;
2064         }
2065         | chord_items chord_item {
2066                 $$ = gh_cons ($2, $$);
2067         }
2068         ;
2069
2070 chord_separator:
2071         CHORD_COLON {
2072                 $$ = ly_symbol2scm ("chord-colon");
2073         }
2074         | CHORD_CARET {
2075                 $$ = ly_symbol2scm ("chord-caret");
2076         }
2077         | CHORD_SLASH steno_tonic_pitch {
2078                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2079         }
2080         | CHORD_BASS steno_tonic_pitch {
2081                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2082         }
2083         ;
2084
2085 chord_item:
2086         chord_separator {
2087                 $$ = $1;
2088         }
2089         | step_numbers {
2090                 $$ = scm_reverse_x ($1, SCM_EOL);
2091         }
2092         | CHORD_MODIFIER  {
2093                 $$ = $1;
2094         }
2095         ;
2096
2097 step_numbers:
2098         step_number { $$ = gh_cons ($1, SCM_EOL); }
2099         | step_numbers '.' step_number {
2100                 $$ = gh_cons ($3, $$);
2101         }
2102         ;
2103
2104 step_number:
2105         bare_unsigned {
2106                 $$ = make_chord_step ($1, 0);
2107         }
2108         | bare_unsigned '+' {
2109                 $$ = make_chord_step ($1, SHARP);
2110         }
2111         | bare_unsigned CHORD_MINUS {
2112                 $$ = make_chord_step ($1, FLAT);
2113         }
2114         ;
2115
2116 /*
2117         UTILITIES
2118
2119 TODO: should deprecate in favor of Scheme?
2120
2121  */
2122 number_expression:
2123         number_expression '+' number_term {
2124                 $$ = scm_sum ($1, $3);
2125         }
2126         | number_expression '-' number_term {
2127                 $$ = scm_difference ($1, $3);
2128         }
2129         | number_term
2130         ;
2131
2132 number_term:
2133         number_factor {
2134                 $$ = $1;
2135         }
2136         | number_factor '*' number_factor {
2137                 $$ = scm_product ($1, $3);
2138         }
2139         | number_factor '/' number_factor {
2140                 $$ = scm_divide ($1, $3);
2141         }
2142         ;
2143
2144 number_factor:
2145         '-'  number_factor { /* %prec UNARY_MINUS */
2146                 $$ = scm_difference ($2, SCM_UNDEFINED);
2147         }
2148         | bare_number
2149         ;
2150
2151
2152 bare_number:
2153         UNSIGNED        {
2154                 $$ = gh_int2scm ($1);
2155         }
2156         | REAL          {
2157                 $$ = $1;
2158         }
2159         | NUMBER_IDENTIFIER             {
2160                 $$ = $1;
2161         }
2162         | REAL NUMBER_IDENTIFIER        {
2163                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2164         }
2165         | UNSIGNED NUMBER_IDENTIFIER    {
2166                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2167         }
2168         ;
2169
2170
2171 bare_unsigned:
2172         UNSIGNED {
2173                         $$ = $1;
2174         }
2175         | DIGIT {
2176                 $$ = $1;
2177         }
2178         ;
2179
2180 bare_int:
2181         bare_number {
2182                 if (scm_integer_p ($1) == SCM_BOOL_T)
2183                 {
2184                         int k = gh_scm2int ($1);
2185                         $$ = k;
2186                 } else
2187                 {
2188                         THIS->parser_error (_ ("need integer number arg"));
2189                         $$ = 0;
2190                 }
2191         }
2192         | '-' bare_int {
2193                 $$ = -$2;
2194         }
2195         ;
2196
2197
2198 string:
2199         STRING          {
2200                 $$ = $1;
2201         }
2202         | STRING_IDENTIFIER     {
2203                 $$ = $1;
2204         }
2205         | string '+' string {
2206                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2207         }
2208         ;
2209
2210
2211 exclamations:
2212                 { $$ = 0; }
2213         | exclamations '!'      { $$ ++; }
2214         ;
2215
2216 questions:
2217                 { $$ = 0; }
2218         | questions '?' { $$ ++; }
2219         ;
2220
2221
2222
2223 full_markup:
2224         MARKUP_IDENTIFIER {
2225                 $$ = $1;
2226         }
2227         | MARKUP
2228                 { THIS->lexer_->push_markup_state (); }
2229         markup
2230                 { $$ = $3;
2231                   THIS->lexer_->pop_state ();
2232                 }
2233         ;
2234
2235
2236 /*
2237 This should be done more dynamically if possible.
2238 */
2239 markup:
2240         STRING {
2241                 $$ = make_simple_markup ($1);
2242         }
2243         | MARKUP_HEAD_EMPTY {
2244                 $$ = scm_list_n ($1, SCM_UNDEFINED);
2245         }
2246         | MARKUP_HEAD_MARKUP0 markup {
2247                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2248         }
2249         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2250                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2251         }
2252         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2253                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2254         }
2255         | markup_line {
2256                 $$ = $1;
2257         }
2258         | MARKUP_HEAD_LIST0 markup_list {
2259                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2260         }
2261         | MARKUP_HEAD_SCM0 embedded_scm {
2262                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2263         }
2264         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2265                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2266         }
2267         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2268                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2269         }
2270         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2271                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2272         }
2273         | MARKUP_IDENTIFIER {
2274                 $$ = $1;
2275         }
2276
2277         ;
2278
2279 markup_list:
2280         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2281         ;
2282
2283 markup_line:
2284         '{' markup_list_body '}' {
2285                 static SCM line ;
2286                 if (!line)
2287                         line = scm_c_eval_string ("line-markup");
2288
2289                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2290         }
2291         ;
2292
2293 markup_list_body:
2294         /**/ {  $$ = SCM_EOL; }
2295         | markup_list_body markup {
2296                 $$ = gh_cons ($2, $1) ;
2297         }
2298         ;
2299
2300
2301 %%
2302
2303 void
2304 My_lily_parser::set_yydebug (bool )
2305 {
2306 #if 0
2307         yydebug = 1;
2308 #endif
2309 }
2310
2311 extern My_lily_parser * current_parser;
2312
2313 void
2314 My_lily_parser::do_yyparse ()
2315 {
2316         current_parser = this;;
2317         yyparse ((void*)this);
2318 }
2319
2320
2321 /*
2322 Should make this optional?    It will also complain when you do
2323
2324         [s4]
2325
2326 which is entirely legitimate.
2327
2328 Or we can scrap it. Barchecks should detect wrong durations, and
2329 skipTypesetting speeds it up a lot.
2330 */
2331
2332 void
2333 My_lily_parser::beam_check (SCM dur)
2334 {
2335   Duration *d = unsmob_duration (dur);
2336   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2337     {
2338       Music * m = unsmob_music (last_beam_start_);
2339       m->origin ()->warning (_("Suspect duration found following this beam"));
2340     }
2341   last_beam_start_ = SCM_EOL;
2342 }
2343
2344
2345
2346
2347 /*
2348
2349 It is a little strange to have this function in this file, but
2350 otherwise, we have to import music classes into the lexer.
2351
2352 */
2353 int
2354 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2355 {
2356         if (gh_string_p (sid)) {
2357                 *destination = sid;
2358                 return STRING_IDENTIFIER;
2359         } else if (gh_number_p (sid)) {
2360                 *destination = sid;
2361                 return NUMBER_IDENTIFIER;
2362         } else if (unsmob_context_def (sid)) {
2363                 *destination = unsmob_context_def (sid)->clone_scm();
2364                 return TRANSLATOR_IDENTIFIER;
2365         } else if (unsmob_score (sid)) {
2366                 Score *sc =  new Score (*unsmob_score (sid));
2367                 *destination =sc->self_scm ();
2368                 return SCORE_IDENTIFIER;
2369         } else if (Music * mus =unsmob_music (sid)) {
2370                 *destination = unsmob_music (sid)->clone ()->self_scm();
2371                 unsmob_music (*destination)->
2372                         set_mus_property ("origin", make_input (last_input_));
2373                 return dynamic_cast<Event*> (mus)
2374                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2375         } else if (unsmob_duration (sid)) {
2376                 *destination = unsmob_duration (sid)->smobbed_copy();
2377                 return DURATION_IDENTIFIER;
2378         } else if (unsmob_music_output_def (sid)) {
2379                 Music_output_def *p = unsmob_music_output_def (sid);
2380                 p = p->clone ();
2381
2382                 *destination = p->self_scm();
2383                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2384         } else if (Text_item::markup_p (sid)) {
2385                 *destination = sid;
2386                 return MARKUP_IDENTIFIER;
2387         }
2388
2389         return -1;
2390 }
2391
2392 Music *
2393 property_op_to_music (SCM op)
2394 {
2395         Music * m = 0;
2396         SCM tag = gh_car (op);
2397         SCM symbol  = gh_cadr (op);
2398         SCM args = gh_cddr (op);
2399         SCM grob_val = SCM_UNDEFINED;
2400         SCM grob_sym = SCM_UNDEFINED;
2401         SCM val = SCM_UNDEFINED;
2402
2403         if (tag == ly_symbol2scm ("assign"))
2404                 {
2405                 m =  MY_MAKE_MUSIC("PropertySet");
2406                 val = gh_car (args);
2407                 }
2408         else if (tag == ly_symbol2scm ("unset"))
2409                 m =  MY_MAKE_MUSIC("PropertyUnset");
2410         else if (tag == ly_symbol2scm ("poppush")
2411                  || tag == ly_symbol2scm ("push"))
2412                 {
2413                 m  = MY_MAKE_MUSIC("OverrideProperty");
2414                 grob_sym = gh_car (args);
2415                 grob_val = gh_cadr (args);
2416                 }
2417         else if (tag == ly_symbol2scm ("pop")) {
2418                 m = MY_MAKE_MUSIC("RevertProperty");
2419                 grob_sym = gh_car (args);
2420                 }
2421
2422         m->set_mus_property ("symbol", symbol);
2423
2424         if (val != SCM_UNDEFINED)
2425                 m->set_mus_property ("value", val);
2426         if (grob_val != SCM_UNDEFINED)
2427                 m->set_mus_property ("grob-value", grob_val);
2428
2429         if (grob_sym != SCM_UNDEFINED)
2430                 {
2431                 bool itc = internal_type_checking_global_b;
2432                 /* UGH.
2433                 */
2434                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2435                 if (autobeam)
2436                         internal_type_checking_global_b = false;
2437                 m->set_mus_property ("grob-property", grob_sym);
2438                 if (autobeam)
2439                         internal_type_checking_global_b = itc;
2440                 }
2441
2442         if (op == ly_symbol2scm ("poppush"))
2443                 m->set_mus_property ("pop-first", SCM_BOOL_T);
2444
2445
2446         return m;
2447 }
2448
2449 Music*
2450 context_spec_music (SCM type, SCM id, Music * m, SCM ops)
2451 {
2452         Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
2453
2454         csm->set_mus_property ("element", m->self_scm ());
2455         scm_gc_unprotect_object (m->self_scm ());
2456
2457         csm->set_mus_property ("context-type", scm_string_to_symbol (type));
2458         csm->set_mus_property ("property-operations", ops);
2459
2460         if (gh_string_p (id))
2461                 csm->set_mus_property ("context-id", id);
2462         return csm;
2463 }
2464
2465
2466 SCM
2467 get_next_unique_context ()
2468 {
2469         static int new_context_count;
2470
2471         char s[1024];
2472         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2473
2474         return scm_makfrom0str (s);
2475 }