lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29
  30 #include "context-def.hh"
  31 #include "dimensions.hh"
  32 #include "event.hh"
  33 #include "file-path.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "output-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left NEWLYRICS
 193
 194 %union {
 195         Book *book;
 196         Output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         My_lily_parser *pars = (My_lily_parser*) v;
 209         My_lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226 3. \markup { }
 227
 228 4.  \repeat
 229         \repeat .. \alternative
 230
 231
 232     \repeat { \repeat .. \alternative }
 233
 234 or
 235
 236     \repeat { \repeat } \alternative
 237
 238 )
 239  */
 240
 241
 242 %pure_parser
 243
 244 %token ACCEPTS
 245 %token ADDQUOTE
 246 %token LYRICSTO
 247 %token ALIAS
 248 %token ALTERNATIVE
 249 %token BAR
 250 %token BOOK
 251 %token BOOKPAPER
 252 %token CHANGE
 253 %token CHORDMODIFIERS
 254 %token CHORDS
 255 %token DOUBLE_ANGLE_OPEN
 256 %token DOUBLE_ANGLE_CLOSE
 257 %token CLEF
 258 %token COMMANDSPANREQUEST
 259 %token CONSISTS
 260 %token CONTEXT
 261 %token DEFAULT
 262 %token DENIES
 263 %token DESCRIPTION
 264 %token EXTENDER
 265 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 266 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 267 %token GROBDESCRIPTIONS
 268 %token HEADER
 269 %token HYPHEN
 270 %token INVALID
 271 %token KEY
 272 %token LYRICS
 273 %token LYRICS_STRING
 274 %token MARK
 275 %token MIDI
 276 %token MULTI_MEASURE_REST
 277 %token NAME
 278 %token NEWCONTEXT
 279 %token NOTES
 280 %token OCTAVE
 281 %token ONCE
 282 %token OVERRIDE SET REVERT
 283 %token PAPER
 284 %token PARTIAL
 285 %token QUOTE
 286 %token RELATIVE
 287 %token REMOVE
 288 %token REPEAT
 289 %token REST
 290 %token SCM_T
 291 %token SCORE
 292 %token SEQUENTIAL
 293 %token NEWLYRICS
 294 %token SIMULTANEOUS
 295 %token SKIP
 296 %token SPANREQUEST
 297 %token TAG
 298 %token TEMPO
 299 %token TIMES
 300 %token TIME_T
 301 %token TRANSPOSE
 302 %token TRANSPOSITION
 303 %token TYPE
 304 %token UNSET
 305 %token WITH
 306 %token MARKUP
 307
 308 /* escaped */
 309 /* FIXME: this sucks.  The user will get to see these names:
 310     syntax error, unexpected E_CHAR:
 311                 \
 312                  %%
 313   */
 314
 315 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 316 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 317 %token E_BACKSLASH
 318 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 319 %token FIGURE_SPACE
 320
 321 %token <i>      DIGIT
 322 %token <i>      UNSIGNED
 323 %token <i> E_UNSIGNED
 324 %token <id>     IDENTIFIER
 325 %token <scm>    CHORDMODIFIER_PITCH
 326 %token <scm>    DRUM_PITCH
 327 %token <scm>    DURATION_IDENTIFIER
 328 %token <scm>    EVENT_IDENTIFIER
 329 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 330 %token <scm>    NOTENAME_PITCH
 331 %token <scm>    NUMBER_IDENTIFIER
 332 %token <scm>    OUTPUT_DEF_IDENTIFIER
 333 %token <scm>    RESTNAME
 334 %token <scm>    SCM_T
 335 %token <scm>    SCORE_IDENTIFIER
 336 %token <scm>    STRING
 337 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 338 %token <scm>    TONICNAME_PITCH
 339 %token <scm>    CHORD_MODIFIER
 340 %token <scm>    FRACTION
 341 %token <scm>   REAL
 342 %token <scm> MARKUP_HEAD_EMPTY
 343 %token <scm> MARKUP_HEAD_MARKUP0
 344 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 345 %token <scm> MARKUP_HEAD_SCM0
 346 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 347 %token <scm> MARKUP_HEAD_SCM0_SCM1
 348 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 349 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 350 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 351 %token <scm> MUSIC_FUNCTION
 352 %token <scm> MUSIC_FUNCTION_MUSIC
 353 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 354 %token <scm> MUSIC_FUNCTION_SCM
 355 %token <scm> MUSIC_FUNCTION_SCM_SCM
 356 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 357 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 358 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 359 %token DRUMS
 360
 361
 362
 363 %type <book>    book_block book_body
 364 %type <i>       bare_int  bare_unsigned
 365 %type <i>       exclamations questions dots optional_rest
 366 %type <i>       script_dir
 367 %type <i>       sub_quotes sup_quotes
 368 %type <i>       tremolo_type
 369 %type <i>       bass_mod
 370
 371 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 372 %type <music>   Grouped_music_list
 373 %type <music>   Music Sequential_music Simultaneous_music
 374 %type <music>   Repeated_music
 375 %type <music>   command_req
 376 %type <music>   gen_text_def direction_less_event direction_reqd_event
 377 %type <music>   music_property_def context_change
 378 %type <music>   note_chord_element chord_body chord_body_element
 379 %type <music>   open_event close_event
 380 %type <music>   post_event tagged_post_event
 381 %type <music>   relative_music re_rhythmed_music
 382 %type <music>   simple_element event_chord command_element
 383 %type <music>   string_number_event
 384 %type <music>   toplevel_music
 385 %type <music>   tempo_event
 386
 387 %type <outputdef>       output_def_body output_def_head
 388 %type <outputdef> output_def book_paper_block
 389
 390 %type <scm>     Music_list
 391 %type <scm>     chord_body_elements
 392 %type <scm>     chord_item chord_items chord_separator new_chord
 393 %type <scm>     context_def_spec_block context_def_spec_body
 394 %type <scm>     context_mod context_def_mod optional_context_mod
 395 %type <scm>     context_prop_spec
 396 %type <scm>     duration_length fraction
 397 %type <scm>     embedded_scm scalar
 398 %type <scm>     identifier_init
 399 %type <scm>     lilypond_header lilypond_header_body
 400 %type <scm>     new_lyrics
 401 %type <scm>     post_events
 402 %type <scm>     property_operation
 403 %type <scm>     script_abbreviation
 404 %type <scm>     simple_string
 405 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 406 %type <scm>     steno_tonic_pitch
 407 %type <scm>     step_number step_numbers
 408 %type <scm>     string bare_number number_expression number_term number_factor
 409 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 410 %type <scm>     context_mod_list
 411 %type <scm>     octave_check
 412 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 413 %type <scm>     Generic_prefix_music_scm
 414 %type <scm>     lyric_element
 415 %type <scm>     Alternative_music
 416 %type <scm>     markup markup_line markup_list markup_list_body full_markup
 417
 418 %type <score>   score_block score_body
 419
 420
 421 %left '-' '+'
 422
 423 /* We don't assign precedence to / and *, because we might need varied
 424 prec levels in different prods */
 425
 426 %left UNARY_MINUS
 427
 428 %%
 429
 430 lilypond:       /* empty */
 431         | lilypond toplevel_expression {
 432         }
 433         | lilypond assignment {
 434         }
 435         | lilypond error {
 436                 THIS->error_level_ = 1;
 437         }
 438         | lilypond INVALID      {
 439                 THIS->error_level_ = 1;
 440         }
 441         ;
 442
 443 toplevel_expression:
 444         lilypond_header {
 445                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 446         }
 447         | add_quote {
 448
 449         }
 450         | book_block {
 451                 Book *book = $1;
 452                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 453                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 454                 scm_gc_unprotect_object (book->self_scm ());
 455         }
 456         | score_block {
 457                 Score *score = $1;
 458
 459                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 460                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 461                 scm_gc_unprotect_object (score->self_scm ());
 462         }
 463         | toplevel_music {
 464                 Music *music = $1;
 465                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 466                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 467                 scm_gc_unprotect_object (music->self_scm ());
 468         }
 469         | output_def {
 470                 SCM id = SCM_EOL;
 471                 Output_def * od = $1;
 472
 473                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 474                         id = ly_symbol2scm ("$defaultpaper");
 475                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 476                         id = ly_symbol2scm ("$defaultmidi");
 477                 else if ($1->c_variable ("is-bookpaper") == SCM_BOOL_T)
 478                         id = ly_symbol2scm ("$defaultbookpaper");
 479
 480                 THIS->lexer_->set_identifier (id, od->self_scm ());
 481                 scm_gc_unprotect_object (od->self_scm ());
 482         }
 483         ;
 484
 485 toplevel_music:
 486         Composite_music {
 487         }
 488         ;
 489
 490 embedded_scm:
 491         SCM_T
 492         | SCM_IDENTIFIER
 493         ;
 494
 495
 496 lilypond_header_body:
 497         {
 498                 $$ = ly_make_anonymous_module (safe_global_b);
 499                 THIS->lexer_->add_scope ($$);
 500         }
 501         | lilypond_header_body assignment  {
 502
 503         }
 504         ;
 505
 506 lilypond_header:
 507         HEADER '{' lilypond_header_body '}'     {
 508                 $$ = THIS->lexer_->remove_scope ();
 509         }
 510         ;
 511
 512
 513 /*
 514         DECLARATIONS
 515 */
 516 assignment:
 517         STRING {
 518                 THIS->push_spot ();
 519         }
 520         /* cont */ '=' identifier_init  {
 521
 522         /*
 523                 Should find generic way of associating input with objects.
 524         */
 525                 Input ip = THIS->pop_spot ();
 526
 527                 if (! is_regular_identifier ($1))
 528                 {
 529                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 530                 }
 531
 532                 THIS->lexer_->set_identifier ($1, $4);
 533
 534 /*
 535  TODO: devise standard for protection in parser.
 536
 537   The parser stack lives on the C-stack, which means that
 538 all objects can be unprotected as soon as they're here.
 539
 540 */
 541         }
 542         | embedded_scm { }
 543         ;
 544
 545
 546 identifier_init:
 547         score_block {
 548                 $$ = $1->self_scm ();
 549                 scm_gc_unprotect_object ($$);
 550         }
 551         | full_markup {
 552                 $$ = $1;
 553         }
 554         | output_def {
 555                 $$ = $1->self_scm ();
 556                 scm_gc_unprotect_object ($$);
 557         }
 558         | context_def_spec_block {
 559                 $$ = $1;
 560         }
 561         | Music  {
 562                 $$ = $1->self_scm ();
 563                 scm_gc_unprotect_object ($$);
 564         }
 565         | post_event {
 566                 $$ = $1->self_scm ();
 567                 scm_gc_unprotect_object ($$);
 568         }
 569         | number_expression {
 570                 $$ = $1;
 571         }
 572         | string {
 573                 $$ = $1;
 574         }
 575         | embedded_scm  {
 576                 $$ = $1;
 577         }
 578         ;
 579
 580 context_def_spec_block:
 581         CONTEXT '{' context_def_spec_body '}'
 582                 {
 583                 $$ = $3;
 584         }
 585         ;
 586
 587 context_def_spec_body:
 588         /**/ {
 589                 $$ = Context_def::make_scm ();
 590                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 591         }
 592         | CONTEXT_DEF_IDENTIFIER {
 593                 $$ = $1;
 594                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 595         }
 596         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 597                 Context_def*td = unsmob_context_def ($$);
 598
 599                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 600                         SCM tag = ly_caar (p);
 601
 602                         /* TODO: should make new tag "grob-definition" ? */
 603                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 604                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 605                 }
 606         }
 607         | context_def_spec_body context_mod {
 608                 unsmob_context_def ($$)->add_context_mod ($2);
 609         }
 610         ;
 611
 612
 613
 614 book_block:
 615         BOOK {
 616                 THIS->push_spot ();
 617         }
 618         /*cont*/ '{' book_body '}'      {
 619                 THIS->pop_spot ();
 620                 $$ = $4;
 621         }
 622         ;
 623
 624 /* FIXME:
 625    * Use 'handlers' like for toplevel-* stuff?
 626    * grok \paper and \midi?  */
 627 book_body:
 628         {
 629                 $$ = new Book;
 630                 $$->set_spot (THIS->here_input ());
 631                 $$->bookpaper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultbookpaper"))->clone ());
 632                 scm_gc_unprotect_object ($$->bookpaper_->self_scm ());
 633                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 634         }
 635         | book_body book_paper_block {
 636                 $$->bookpaper_ = $2;
 637                 scm_gc_unprotect_object ($2->self_scm ());
 638         }
 639         | book_body score_block {
 640                 Score *score = $2;
 641                 $$->scores_.push (score);
 642                 scm_gc_unprotect_object (score->self_scm ());
 643         }
 644         | book_body Composite_music {
 645                 Music *music = $2;
 646                 Score *score
 647                         = unsmob_score (ly_music_scorify (music->self_scm ()));
 648                 $$->scores_.push (score);
 649                 scm_gc_unprotect_object (music->self_scm ());
 650         }
 651         | book_body lilypond_header {
 652                 $$->header_ = $2;
 653         }
 654         | book_body error {
 655
 656         }
 657         ;
 658
 659 score_block:
 660         SCORE {
 661                 THIS->push_spot ();
 662         }
 663         /*cont*/ '{' score_body '}'     {
 664                 THIS->pop_spot ();
 665                 $$ = $4;
 666         }
 667         ;
 668
 669 score_body:
 670         /**/    {
 671                 $$ = new Score;
 672
 673                 $$->set_spot (THIS->here_input ());
 674         }
 675         | SCORE_IDENTIFIER {
 676                 $$ = new Score ( *unsmob_score ($1));
 677                 $$->set_spot (THIS->here_input ());
 678         }
 679         | score_body Music {
 680                 SCM m = $2->self_scm ();
 681                 scm_gc_unprotect_object (m);
 682
 683                 /*
 684                         guh.
 685                 */
 686                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 687                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 688                         m = scm_call_1 (ly_car (check_funcs), m);
 689                 if (unsmob_music ($$->music_))
 690                 {
 691                         THIS->parser_error (_("Already have music in score"));
 692                         unsmob_music ($$->music_)->origin ()->error (_("This is the previous music"));
 693                 }
 694                 $$->music_ = m;
 695         }
 696         | score_body lilypond_header    {
 697                 $$->header_ = $2;
 698         }
 699         | score_body output_def {
 700                 $$->defs_.push ($2);
 701                 scm_gc_unprotect_object ($2->self_scm ());
 702         }
 703         | score_body error {
 704
 705         }
 706         ;
 707
 708
 709 /*
 710         OUTPUT DEF
 711 */
 712
 713 book_paper_block:
 714         output_def {
 715                 $$ = $1;
 716                 if ($$->lookup_variable (ly_symbol2scm ("is-bookpaper")) != SCM_BOOL_T)
 717                 {
 718                         THIS->parser_error (_("Need \\bookpaper for bookpaper block."));
 719                         $$ = get_bookpaper (THIS);
 720                 }
 721         }
 722         ;
 723
 724
 725 output_def:
 726         output_def_body '}' {
 727                 $$ = $1;
 728                 if ($1->parent_)
 729                         THIS->lexer_->remove_scope ();
 730
 731                 THIS->lexer_->remove_scope ();
 732                 THIS->lexer_->pop_state ();
 733         }
 734         ;
 735
 736 output_def_head:
 737         BOOKPAPER {
 738                 $$ = get_bookpaper (THIS);
 739                 $$->input_origin_ = THIS->here_input ();
 740                 THIS->lexer_->add_scope ($$->scope_);
 741         }
 742         | MIDI    {
 743                 Output_def *p = get_midi (THIS);
 744                 $$ = p;
 745                 THIS->lexer_->add_scope (p->scope_);
 746         }
 747         | PAPER         {
 748                 Output_def* p = get_paper (THIS);
 749
 750                 if (p->parent_)
 751                         THIS->lexer_->add_scope (p->parent_->scope_);
 752
 753                 THIS->lexer_->add_scope (p->scope_);
 754                 $$ = p;
 755         }
 756         ;
 757
 758
 759 output_def_body:
 760         output_def_head '{' {
 761                 $$ = $1;
 762                 $$->input_origin_.set_spot (THIS->here_input ());
 763                 THIS->lexer_->push_initial_state ();
 764         }
 765         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 766                 scm_gc_unprotect_object ($1->self_scm ());
 767                 Output_def *o = unsmob_output_def ($3);
 768                 o->input_origin_.set_spot (THIS->here_input ());
 769                 $$ = o;
 770                 THIS->lexer_->remove_scope ();
 771                 THIS->lexer_->add_scope (o->scope_);
 772                 THIS->lexer_->push_initial_state ();
 773         }
 774         | output_def_body assignment  {
 775
 776         }
 777         | output_def_body context_def_spec_block        {
 778                 assign_context_def ($$, $2);
 779         }
 780         | output_def_body tempo_event  {
 781                 /*
 782                         junk this ? there already is tempo stuff in
 783                         music.
 784                 */
 785                 int m = ly_scm2int ($2->get_property ("metronome-count"));
 786                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 787                 set_tempo ($$, d->get_length (), m);
 788                 scm_gc_unprotect_object ($2->self_scm ());
 789         }
 790         | output_def_body error {
 791
 792         }
 793         ;
 794
 795 tempo_event:
 796         TEMPO steno_duration '=' bare_unsigned  {
 797                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 798                 $$->set_property ("tempo-unit", $2);
 799                 $$->set_property ("metronome-count", scm_int2num ( $4));
 800         }
 801         ;
 802
 803 /*
 804 The representation of a  list is the
 805
 806   (LIST . LAST-CONS)
 807
 808  to have  efficient append.
 809 */
 810 Music_list:
 811         /* empty */ {
 812                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 813         }
 814         | Music_list Music {
 815                 SCM s = $$;
 816                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 817                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 818                 if (ly_c_pair_p (ly_cdr (s)))
 819                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 820                 else
 821                         scm_set_car_x (s, c); /* set first cons */
 822                 scm_set_cdr_x (s, c);  /* remember last cell */
 823         }
 824         | Music_list embedded_scm {
 825         }
 826         | Music_list error {
 827         }
 828         ;
 829
 830
 831 Music:
 832         Simple_music
 833         | Composite_music
 834         ;
 835
 836 Alternative_music:
 837         /* empty */ {
 838                 $$ = SCM_EOL;
 839         }
 840         | ALTERNATIVE '{' Music_list '}' {
 841                 $$ = $3;
 842         }
 843         ;
 844
 845
 846 Repeated_music:
 847         REPEAT simple_string bare_unsigned Music Alternative_music
 848         {
 849                 Music *beg = $4;
 850                 int times = $3;
 851                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 852                 if (times < scm_ilength (alts)) {
 853                   unsmob_music (ly_car (alts))
 854                     ->origin ()->warning (
 855                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 856                   alts = ly_truncate_list (times, alts);
 857                 }
 858
 859
 860                 SCM proc = ly_scheme_function ("make-repeated-music");
 861
 862                 SCM mus = scm_call_1 (proc, $2);
 863                 scm_gc_protect_object (mus); // UGH.
 864                 Music *r = unsmob_music (mus);
 865                 if (beg)
 866                         {
 867                         r-> set_property ("element", beg->self_scm ());
 868                         scm_gc_unprotect_object (beg->self_scm ());
 869                         }
 870                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 871
 872                 r-> set_property ("elements",alts);
 873                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 874                         /*
 875                         TODO: move this code to Scheme.
 876                         */
 877
 878                         /*
 879                         we can not get durations and other stuff correct down the line, so we have to
 880                         add to the duration log here.
 881                         */
 882                         SCM func = ly_scheme_function ("shift-duration-log");
 883
 884                         int dots = ($3 % 3) ? 0 : 1;
 885                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 886
 887                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 888
 889                         if (seq) {
 890                                 int list_len = scm_ilength (seq->music_list ());
 891                                 if (list_len != 2)
 892                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 893                                 shift -= 1;
 894                                 r->compress (Moment (Rational (1, list_len)));
 895                                 }
 896                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 897
 898                 }
 899                 r->set_spot (*$4->origin ());
 900
 901                 $$ = r;
 902         }
 903         ;
 904
 905 Sequential_music:
 906         SEQUENTIAL '{' Music_list '}'           {
 907                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 908                 $$->set_property ("elements", ly_car ($3));
 909                 $$->set_spot (THIS->here_input ());
 910         }
 911         | '{' Music_list '}'            {
 912                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 913                 $$->set_property ("elements", ly_car ($2));
 914                 $$->set_spot (THIS->here_input ());
 915         }
 916         ;
 917
 918 Simultaneous_music:
 919         SIMULTANEOUS '{' Music_list '}'{
 920                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 921                 $$->set_property ("elements", ly_car ($3));
 922                 $$->set_spot (THIS->here_input ());
 923
 924         }
 925         | simul_open Music_list simul_close     {
 926                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 927                 $$->set_property ("elements", ly_car ($2));
 928                 $$->set_spot (THIS->here_input ());
 929         }
 930         ;
 931
 932 Simple_music:
 933         event_chord             { $$ = $1; }
 934         | MUSIC_IDENTIFIER {
 935                 $$ = unsmob_music ($1);
 936         }
 937         | music_property_def
 938         | context_change
 939         ;
 940
 941
 942 optional_context_mod:
 943         /**/ { $$ = SCM_EOL; }
 944         | WITH { THIS->lexer_->push_initial_state (); }
 945         '{' context_mod_list '}'
 946         {
 947                 THIS->lexer_->pop_state ();
 948                 $$ = $4;
 949         }
 950         ;
 951
 952 context_mod_list:
 953         /* */  { $$ = SCM_EOL; }
 954         | context_mod_list context_mod  {
 955                  $$ = scm_cons ($2, $1);
 956         }
 957         ;
 958
 959
 960 Composite_music:
 961         Prefix_composite_music { $$ = $1; }
 962         | Grouped_music_list { $$ = $1; }
 963         ;
 964
 965 Grouped_music_list:
 966         Simultaneous_music              { $$ = $1; }
 967         | Sequential_music              { $$ = $1; }
 968         ;
 969
 970 Generic_prefix_music_scm:
 971         MUSIC_FUNCTION {
 972                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 973         }
 974         | MUSIC_FUNCTION_SCM {
 975                 THIS->push_spot ();
 976         } embedded_scm {
 977                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 978         }
 979         | MUSIC_FUNCTION_MUSIC {
 980                 THIS->push_spot ();
 981         } Music {
 982                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 983                 scm_gc_unprotect_object ($3->self_scm ());
 984         }
 985         | MUSIC_FUNCTION_SCM_MUSIC {
 986                 THIS->push_spot ();
 987         }  embedded_scm Music {
 988                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
 989                 scm_gc_unprotect_object ($4->self_scm ());
 990         }
 991         | MUSIC_FUNCTION_SCM_SCM {
 992                 THIS->push_spot ();
 993         }  embedded_scm embedded_scm {
 994                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4);
 995         }
 996         | MUSIC_FUNCTION_MUSIC_MUSIC {
 997                 THIS->push_spot ();
 998         }  Music  Music {
 999                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
1000                 scm_gc_unprotect_object ($3->self_scm ());
1001                 scm_gc_unprotect_object ($4->self_scm ());
1002         }
1003         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
1004                 THIS->push_spot ();
1005         } embedded_scm Music Music {
1006                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
1007                         $3, $4->self_scm (), $5->self_scm ());
1008                 scm_gc_unprotect_object ($5->self_scm ());
1009                 scm_gc_unprotect_object ($4->self_scm ());
1010         }
1011         ;
1012
1013 Generic_prefix_music:
1014         Generic_prefix_music_scm {
1015                 SCM func = ly_car ($1);
1016                 Input *loc = unsmob_input (ly_cadr ($1));
1017                 SCM args = ly_cddr ($1);
1018                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1019                 int k = 0;
1020                 bool ok  = true;
1021                 for (SCM s = sig, t = args;
1022                         ok && ly_c_pair_p (s) && ly_c_pair_p (t);
1023                         s = ly_cdr (s), t = ly_cdr (t)) {
1024                         k++;
1025                         if (scm_call_1 (ly_car (s), ly_car (t)) != SCM_BOOL_T)
1026                         {
1027                                 loc->error (_f ("Argument %d failed typecheck", k));
1028                                 THIS->error_level_ = 1;
1029                                 ok = false;
1030                         }
1031                 }
1032                 SCM m = SCM_EOL;
1033                 if (ok)
1034                         m = scm_apply_0 (func, ly_cdr ($1));
1035                 if (unsmob_music (m))
1036                         {
1037                         $$ = unsmob_music (m);
1038                         scm_gc_protect_object (m);
1039                         }
1040                 else
1041                         {
1042                         if (ok)
1043                                 loc->error (_ ("Music head function should return Music object."));
1044                         $$ = MY_MAKE_MUSIC ("Music");
1045                         }
1046                 $$->set_spot (*loc);
1047         }
1048         ;
1049
1050
1051 Prefix_composite_music:
1052         Generic_prefix_music {
1053                 $$ = $1;
1054         }
1055         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1056                 $$ = context_spec_music ($2, $4, $6, $5);
1057
1058         }
1059         | CONTEXT simple_string optional_context_mod Music {
1060                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1061         }
1062         | NEWCONTEXT simple_string optional_context_mod Music {
1063                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1064                         $3);
1065         }
1066
1067         | TIMES {
1068                 THIS->push_spot ();
1069         }
1070         /* CONTINUED */
1071                 fraction Music
1072
1073         {
1074                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1075                 Music *mp = $4;
1076
1077                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1078                 $$->set_spot (THIS->pop_spot ());
1079
1080                 $$->set_property ("element", mp->self_scm ());
1081                 scm_gc_unprotect_object (mp->self_scm ());
1082                 $$->set_property ("numerator", scm_int2num (n));
1083                 $$->set_property ("denominator", scm_int2num (d));
1084                 $$->compress (Moment (Rational (n,d)));
1085
1086         }
1087         | Repeated_music                { $$ = $1; }
1088         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1089                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1090                 Music *p = $4;
1091                 Pitch from = *unsmob_pitch ($2);
1092                 Pitch to = *unsmob_pitch ($3);
1093
1094                 p->transpose (interval (from, to));
1095                 $$->set_property ("element", p->self_scm ());
1096                 scm_gc_unprotect_object (p->self_scm ());
1097         }
1098         | NOTES
1099                 {
1100                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1101                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1102         }
1103         Music
1104                 { $$ = $3;
1105                   THIS->lexer_->pop_state ();
1106                 }
1107         | DRUMS
1108                 {
1109                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1110                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1111         }
1112         /* FIXME: This used to be: */
1113         Music
1114 /*      Grouped_music_list */
1115                 { $$ = $3;
1116                   THIS->lexer_->pop_state ();
1117                 }
1118         | FIGURES
1119                 { THIS->lexer_->push_figuredbass_state (); }
1120         /* FIXME: This used to be:
1121         Music
1122         but that breaks web build
1123         */
1124         Grouped_music_list
1125                 {
1126                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1127                   chm->set_property ("element", $3->self_scm ());
1128                   $$ = chm;
1129                   scm_gc_unprotect_object ($3->self_scm ());
1130
1131                   THIS->lexer_->pop_state ();
1132         }
1133         | CHORDS {
1134                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1135                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1136                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1137                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1138
1139         }
1140         /* FIXME:
1141         Music
1142 */
1143         Grouped_music_list
1144         {
1145                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1146                   chm->set_property ("element", $3->self_scm ());
1147                   scm_gc_unprotect_object ($3->self_scm ());
1148                   $$ = chm;
1149
1150                   THIS->lexer_->pop_state ();
1151         }
1152         | LYRICS
1153                 { THIS->lexer_->push_lyric_state (); }
1154         /* FIXME:
1155         Music
1156 */
1157         Grouped_music_list
1158                 {
1159                   $$ = $3;
1160                   THIS->lexer_->pop_state ();
1161         }
1162         | relative_music        { $$ = $1; }
1163         | re_rhythmed_music     { $$ = $1; }
1164         | TAG embedded_scm Music {
1165                 tag_music ($3, $2, THIS->here_input ());
1166                 $$ = $3;
1167         }
1168         ;
1169
1170 relative_music:
1171         RELATIVE absolute_pitch Music {
1172                 Music *m = $3;
1173                 Pitch start = *unsmob_pitch ($2);
1174                 $$ = make_music_relative (start, m);
1175                 scm_gc_unprotect_object (m->self_scm ());
1176         }
1177         | RELATIVE Composite_music {
1178                 Music *m = $2;
1179
1180                 Pitch middle_c (0, 0, 0);
1181                 $$ = make_music_relative (middle_c, m);
1182                 scm_gc_unprotect_object (m->self_scm ());
1183         }
1184         ;
1185
1186 new_lyrics:
1187         NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1188         /*cont */
1189         Grouped_music_list {
1190         /* Can also use Music at the expensive of two S/Rs similar to
1191            \repeat \alternative */
1192                 THIS->lexer_->pop_state ();
1193 #if 0
1194                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1195                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1196                 $$ = music;
1197 #else
1198                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1199 #endif
1200         }
1201         | new_lyrics NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1202         Grouped_music_list {
1203                 THIS->lexer_->pop_state ();
1204                 $$ = scm_cons ($4->self_scm (), $1);
1205         }
1206         ;
1207
1208 re_rhythmed_music:
1209         Grouped_music_list new_lyrics {
1210
1211                 /* FIXME: should find out uniqueXXX name from music */
1212                 SCM name = $1->get_property ("context-id");
1213                 //if (name == SCM_EOL)
1214                 if (!ly_c_string_p (name))
1215                         name = scm_makfrom0str ("");
1216
1217                 SCM context = scm_makfrom0str ("Lyrics");
1218                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1219
1220                 SCM lst = SCM_EOL;
1221                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1222                 {
1223                         Music *music = unsmob_music (ly_car (s));
1224                         Music *com = make_lyric_combine_music (name, music);
1225                         Music *csm = context_spec_music (context,
1226                                 get_next_unique_context (), com, SCM_EOL);
1227                         lst = scm_cons (csm->self_scm (), lst);
1228                 }
1229                 /* FIXME: only first lyric music is accepted,
1230                           the rest is junked */
1231                 all->set_property ("elements", scm_cons ($1->self_scm (),
1232                         lst));
1233                 $$ = all;
1234                 scm_gc_unprotect_object ($1->self_scm ());
1235         }
1236         | LYRICSTO {
1237                 THIS->lexer_->push_lyric_state ();
1238         } simple_string Music {
1239                 THIS->lexer_->pop_state ();
1240                 Music *music = $4;
1241                 SCM name = $3;
1242                 $$ = make_lyric_combine_music (name, music);
1243                 scm_gc_unprotect_object (music->self_scm ());
1244         }
1245         ;
1246
1247 context_change:
1248         CHANGE STRING '=' STRING  {
1249                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1250                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1251                 t-> set_property ("change-to-id", $4);
1252
1253                 $$ = t;
1254                 $$->set_spot (THIS->here_input ());
1255         }
1256         ;
1257
1258 property_operation:
1259         STRING '=' scalar {
1260                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1261                         scm_string_to_symbol ($1), $3);
1262         }
1263         | UNSET simple_string {
1264                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1265                         scm_string_to_symbol ($2));
1266         }
1267         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1268                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1269                         scm_string_to_symbol ($2), $3, $5);
1270         }
1271         | REVERT simple_string embedded_scm {
1272                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1273                         scm_string_to_symbol ($2), $3);
1274         }
1275         ;
1276
1277 context_def_mod:
1278         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1279         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1280
1281         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1282         | DENIES { $$ = ly_symbol2scm ("denies"); }
1283
1284         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1285         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1286         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1287         | NAME { $$ = ly_symbol2scm ("context-name"); }
1288         ;
1289
1290 context_mod:
1291         property_operation { $$ = $1; }
1292         | context_def_mod STRING {
1293                 $$ = scm_list_2 ($1, $2);
1294         }
1295         ;
1296
1297 context_prop_spec:
1298         simple_string {
1299                 if (!is_regular_identifier ($1))
1300                 {
1301                         THIS->here_input ().error (_("Grob name should be alphanumeric"));
1302                 }
1303
1304                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1305                         scm_string_to_symbol ($1));
1306         }
1307         | simple_string '.' simple_string {
1308                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1309                         scm_string_to_symbol ($3));
1310         }
1311         ;
1312
1313 music_property_def:
1314         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1315                 $$ = property_op_to_music (scm_list_4 (
1316                         ly_symbol2scm ("poppush"),
1317                         ly_cadr ($2),
1318                         $3, $5));
1319                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1320         }
1321         | REVERT context_prop_spec embedded_scm {
1322                 $$ = property_op_to_music (scm_list_3 (
1323                         ly_symbol2scm ("pop"),
1324                         ly_cadr ($2),
1325                         $3));
1326
1327                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1328         }
1329         | SET context_prop_spec '=' scalar {
1330                 $$ = property_op_to_music (scm_list_3 (
1331                         ly_symbol2scm ("assign"),
1332                         ly_cadr ($2),
1333                         $4));
1334                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1335         }
1336         | UNSET context_prop_spec {
1337                 $$ = property_op_to_music (scm_list_2 (
1338                         ly_symbol2scm ("unset"),
1339                         ly_cadr ($2)));
1340                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1341         }
1342         | ONCE music_property_def {
1343                 SCM e = $2->get_property ("element");
1344                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1345                 $$ = $2;
1346
1347         }
1348         ;
1349
1350
1351 string:
1352         STRING {
1353                 $$ = $1;
1354         }
1355         | STRING_IDENTIFIER {
1356                 $$ = $1;
1357         }
1358         | string '+' string {
1359                 $$ = scm_string_append (scm_list_2 ($1, $3));
1360         }
1361         ;
1362
1363 simple_string: STRING {
1364         }
1365         | LYRICS_STRING {
1366         }
1367         ;
1368
1369 scalar: string {
1370         }
1371         | LYRICS_STRING {
1372         }
1373         | bare_int {
1374                 $$ = scm_int2num ($1);
1375         }
1376         | embedded_scm {
1377         }
1378         | full_markup {
1379         }
1380         | DIGIT {
1381                 $$ = scm_int2num ($1);
1382         }
1383         ;
1384
1385 /*
1386 FIXME: remove or fix this comment.  What is `This'?
1387
1388 This is a trick:
1389
1390 Adding pre_events to the simple_element
1391 makes the choice between
1392
1393   string:  STRING
1394
1395 and
1396
1397   simple_element: STRING
1398
1399 a single shift/reduction conflict.
1400
1401 nevertheless, this is not very clean, and we should find a different
1402 solution.
1403
1404 */
1405 pre_events: {
1406                 THIS->push_spot ();
1407         }
1408         ;
1409
1410 event_chord:
1411         pre_events simple_element post_events   {
1412                 SCM elts = $2-> get_property ("elements");
1413
1414                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1415
1416                 $2->set_property ("elements", elts);
1417                 $$ = $2;
1418         }
1419         | command_element
1420         | note_chord_element
1421         ;
1422
1423
1424 note_chord_element:
1425         chord_body optional_notemode_duration post_events
1426         {
1427                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1428                 SCM es = $1->get_property ("elements");
1429                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1430
1431                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1432                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1433                 es = ly_append2 (es, postevs);
1434
1435                 $1-> set_property ("elements", es);
1436                 $$ = $1;
1437         }
1438         ;
1439
1440 chord_open: '<'
1441         ;
1442
1443 chord_close: '>'
1444         ;
1445
1446 simul_open: DOUBLE_ANGLE_OPEN
1447         ;
1448
1449 simul_close: DOUBLE_ANGLE_CLOSE
1450         ;
1451
1452 chord_body:
1453         chord_open chord_body_elements chord_close
1454         {
1455                 $$ = MY_MAKE_MUSIC ("EventChord");
1456                 $$->set_property ("elements",
1457                         scm_reverse_x ($2, SCM_EOL));
1458         }
1459         ;
1460
1461 chord_body_elements:
1462         /* empty */             { $$ = SCM_EOL; }
1463         | chord_body_elements chord_body_element {
1464                 $$ = scm_cons ($2->self_scm (), $1);
1465                 scm_gc_unprotect_object ($2->self_scm ());
1466         }
1467         ;
1468
1469 chord_body_element:
1470         pitch  exclamations questions octave_check post_events
1471         {
1472                 int q = $3;
1473                 int ex = $2;
1474                 SCM check = $4;
1475                 SCM post = $5;
1476
1477                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1478                 n->set_property ("pitch", $1);
1479                 if (q % 2)
1480                         n->set_property ("cautionary", SCM_BOOL_T);
1481                 if (ex % 2 || q % 2)
1482                         n->set_property ("force-accidental", SCM_BOOL_T);
1483
1484                 if (ly_c_pair_p (post)) {
1485                         SCM arts = scm_reverse_x (post, SCM_EOL);
1486                         n->set_property ("articulations", arts);
1487                 }
1488                 if (ly_c_number_p (check))
1489                 {
1490                         int q = ly_scm2int (check);
1491                         n->set_property ("absolute-octave", scm_int2num (q-1));
1492                 }
1493
1494
1495                 $$ = n;
1496         }
1497         | DRUM_PITCH post_events {
1498                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1499                 n->set_property ("duration", $2);
1500                 n->set_property ("drum-type", $1);
1501                 n->set_spot (THIS->here_input ());
1502
1503                 if (ly_c_pair_p ($2)) {
1504                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1505                         n->set_property ("articulations", arts);
1506                 }
1507                 $$ = n;
1508         }
1509         ;
1510
1511 add_quote:
1512         ADDQUOTE string Music {
1513                 SCM adder = ly_scheme_function ("add-quotable");
1514
1515                 scm_call_2 (adder, $2, $3->self_scm ());
1516                 scm_gc_unprotect_object ($3->self_scm ());
1517         }
1518         ;
1519
1520 command_element:
1521         command_req {
1522                 $$ = MY_MAKE_MUSIC ("EventChord");
1523                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1524                 scm_gc_unprotect_object ($1->self_scm ());
1525
1526                 $$-> set_spot (THIS->here_input ());
1527                 $1-> set_spot (THIS->here_input ());
1528         }
1529         | SKIP duration_length {
1530                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1531                 skip->set_property ("duration", $2);
1532
1533                 $$ = skip;
1534         }
1535         | QUOTE STRING duration_length {
1536                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1537                 SCM evs = SCM_EOL;
1538                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1539                 {
1540                         SCM key = $2; // use symbol?
1541                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1542                 }
1543                 Music *quote = 0;
1544                 if (ly_c_vector_p (evs))
1545                 {
1546                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1547                         quote->set_property ("duration", $3);
1548                         quote->set_property ("quoted-events", evs);
1549                 } else {
1550                         THIS->here_input ().warning (_f ("Can\'t find music"));
1551                         quote = MY_MAKE_MUSIC ("Event");
1552                 }
1553                 quote->set_spot (THIS->here_input ());
1554                 $$ = quote;
1555         }
1556         | OCTAVE { THIS->push_spot (); }
1557           pitch {
1558                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1559                 $$ = m;
1560                 $$->set_spot (THIS->pop_spot ());
1561                 $$->set_property ("pitch", $3);
1562         }
1563         | E_LEFTSQUARE {
1564                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1565                 m->set_property ("span-direction", scm_int2num (START));
1566                 m->set_spot (THIS->here_input ());
1567
1568                 $$ = MY_MAKE_MUSIC ("EventChord");
1569                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1570                 scm_gc_unprotect_object (m->self_scm ());
1571                 $$->set_spot (THIS->here_input ());
1572         }
1573         | E_RIGHTSQUARE {
1574                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1575                 m->set_property ("span-direction", scm_int2num (STOP));
1576                 m->set_spot (THIS->here_input ());
1577
1578                 $$ = MY_MAKE_MUSIC ("EventChord");
1579                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1580                 $$->set_spot (THIS->here_input ());
1581                 scm_gc_unprotect_object (m->self_scm ());
1582         }
1583         | E_BACKSLASH {
1584                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1585                 $$->set_spot (THIS->here_input ());
1586         }
1587         | '|'      {
1588                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1589
1590                 if (Music * m = unsmob_music (pipe))
1591                         $$ = m->clone ();
1592                 else
1593                         $$ = MY_MAKE_MUSIC ("BarCheck");
1594
1595                 $$->set_spot (THIS->here_input ());
1596         }
1597         | TRANSPOSITION pitch {
1598                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1599                                         $2);
1600                 $$->set_spot (THIS-> here_input ());
1601                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1602                         $$, SCM_EOL);
1603         }
1604         | BAR STRING                    {
1605                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1606
1607                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1608                                         t, SCM_EOL);
1609                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1610                 $$->set_spot (THIS->here_input ());
1611                 t->set_spot (THIS->here_input ());
1612         }
1613         | PARTIAL duration_length       {
1614                 Moment m = - unsmob_duration ($2)->get_length ();
1615                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1616                 p->set_spot (THIS->here_input ());
1617                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1618                                         p, SCM_EOL);
1619                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1620                                         p, SCM_EOL);
1621                 $$ = p;
1622         }
1623         | CLEF STRING  {
1624                 SCM proc = ly_scheme_function ("make-clef-set");
1625
1626                 SCM result = scm_call_1 (proc, $2);
1627                 scm_gc_protect_object (result);
1628                 $$ = unsmob_music (result);
1629         }
1630         | TIME_T fraction  {
1631                 SCM proc= ly_scheme_function ("make-time-signature-set");
1632
1633                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1634                 scm_gc_protect_object (result);
1635                 $$ = unsmob_music (result);
1636         }
1637         | MARK scalar {
1638                 SCM proc = ly_scheme_function ("make-mark-set");
1639
1640                 SCM result = scm_call_1 (proc, $2);
1641                 scm_gc_protect_object (result);
1642                 $$ = unsmob_music (result);
1643         }
1644         ;
1645
1646 command_req:
1647         E_TILDE {
1648                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1649         }
1650         | MARK DEFAULT  {
1651                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1652                 $$ = m;
1653         }
1654         | tempo_event {
1655                 $$ = $1;
1656         }
1657         | KEY DEFAULT {
1658                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1659                 $$ = key;
1660         }
1661         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1662
1663                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1664                 if (scm_ilength ($3) > 0)
1665                 {
1666                         key->set_property ("pitch-alist", $3);
1667                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1668                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1669                 } else {
1670                         THIS->parser_error (_ ("Second argument must be pitch list."));
1671                 }
1672
1673                 $$ = key;
1674         }
1675         ;
1676
1677 post_events:
1678         /* empty */ {
1679                 $$ = SCM_EOL;
1680         }
1681         | post_events post_event {
1682                 $2->set_spot (THIS->here_input ());
1683                 $$ = scm_cons ($2->self_scm (), $$);
1684                 scm_gc_unprotect_object ($2->self_scm ());
1685         }
1686         | post_events tagged_post_event {
1687                 $2 -> set_spot (THIS->here_input ());
1688                 $$ = scm_cons ($2->self_scm (), $$);
1689                 scm_gc_unprotect_object ($2->self_scm ());
1690         }
1691         ;
1692
1693
1694 tagged_post_event:
1695         '-' TAG embedded_scm post_event {
1696                 tag_music ($4, $3, THIS->here_input ());
1697                 $$ = $4;
1698         }
1699         ;
1700
1701 post_event:
1702         direction_less_event {
1703                 $$ = $1;
1704         }
1705         | HYPHEN {
1706                 if (!THIS->lexer_->is_lyric_state ())
1707                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1708                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1709         }
1710         | EXTENDER {
1711                 if (!THIS->lexer_->is_lyric_state ())
1712                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1713                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1714         }
1715         | script_dir direction_reqd_event {
1716                 if ($1)
1717                         $2->set_property ("direction", scm_int2num ($1));
1718                 $$ = $2;
1719         }
1720         | script_dir direction_less_event {
1721                 if ($1)
1722                         $2->set_property ("direction", scm_int2num ($1));
1723                 $$ = $2;
1724         }
1725         | string_number_event
1726         ;
1727
1728 string_number_event:
1729         E_UNSIGNED {
1730                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1731                 s->set_property ("string-number", scm_int2num ($1));
1732                 s->set_spot (THIS->here_input ());
1733                 $$ = s;
1734         }
1735         ;
1736
1737
1738 direction_less_event:
1739         '['  {
1740
1741
1742 /*
1743
1744 TODO: should take all these defs out of the parser, adn make use
1745 configurable, i.e.
1746
1747
1748 (set-articulation '~ "trill")
1749
1750 */
1751                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1752                 m->set_spot (THIS->here_input ());
1753                 m->set_property ("span-direction", scm_int2num (START));
1754                 $$ = m;
1755         }
1756         | ']'  {
1757                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1758                 m->set_spot (THIS->here_input ());
1759                 m->set_property ("span-direction", scm_int2num (STOP));
1760                 $$ = m;
1761         }
1762         | '~' {
1763                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1764                 m->set_spot (THIS->here_input ());
1765                 $$ = m;
1766         }
1767         | close_event {
1768                 $$ = $1;
1769                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1770                         scm_int2num (START));
1771         }
1772         | open_event {
1773                 $$ = $1;
1774                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1775                         scm_int2num (STOP));
1776         }
1777         | EVENT_IDENTIFIER      {
1778                 $$ = unsmob_music ($1);
1779         }
1780         | tremolo_type  {
1781                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1782                a->set_spot (THIS->here_input ());
1783                a->set_property ("tremolo-type", scm_int2num ($1));
1784                $$ = a;
1785         }
1786         ;
1787
1788 direction_reqd_event:
1789         gen_text_def {
1790                 $$ = $1;
1791         }
1792         | script_abbreviation {
1793                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1794                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1795                 if (ly_c_string_p (s))
1796                         a->set_property ("articulation-type", s);
1797                 else THIS->parser_error (_ ("Expecting string as script definition"));
1798                 $$ = a;
1799         }
1800         ;
1801
1802 octave_check:
1803         /**/ { $$ = SCM_EOL; }
1804         | '='  { $$ = scm_int2num (0); }
1805         | '=' sub_quotes { $$ = scm_int2num ($2); }
1806         | '=' sup_quotes { $$ = scm_int2num ($2); }
1807         ;
1808
1809 sup_quotes:
1810         '\'' {
1811                 $$ = 1;
1812         }
1813         | sup_quotes '\'' {
1814                 $$ ++;
1815         }
1816         ;
1817
1818 sub_quotes:
1819         ',' {
1820                 $$ = 1;
1821         }
1822         | sub_quotes ',' {
1823                 $$++;
1824         }
1825         ;
1826
1827 steno_pitch:
1828         NOTENAME_PITCH  {
1829                 $$ = $1;
1830         }
1831         | NOTENAME_PITCH sup_quotes     {
1832                 Pitch p = *unsmob_pitch ($1);
1833                 p = p.transposed (Pitch ($2,0,0));
1834                 $$ = p.smobbed_copy ();
1835         }
1836         | NOTENAME_PITCH sub_quotes      {
1837                 Pitch p =* unsmob_pitch ($1);
1838                 p = p.transposed (Pitch (-$2,0,0));
1839                 $$ = p.smobbed_copy ();
1840         }
1841         ;
1842
1843 /*
1844 ugh. duplication
1845 */
1846
1847 steno_tonic_pitch:
1848         TONICNAME_PITCH {
1849                 $$ = $1;
1850         }
1851         | TONICNAME_PITCH sup_quotes    {
1852                 Pitch p = *unsmob_pitch ($1);
1853                 p = p.transposed (Pitch ($2,0,0));
1854                 $$ = p.smobbed_copy ();
1855         }
1856         | TONICNAME_PITCH sub_quotes     {
1857                 Pitch p =* unsmob_pitch ($1);
1858
1859                 p = p.transposed (Pitch (-$2,0,0));
1860                 $$ = p.smobbed_copy ();
1861         }
1862         ;
1863
1864 pitch:
1865         steno_pitch {
1866                 $$ = $1;
1867         }
1868         ;
1869
1870 pitch_also_in_chords:
1871         pitch
1872         | steno_tonic_pitch
1873         ;
1874
1875 close_event:
1876         '('     {
1877                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1878                 $$ = s;
1879                 s->set_spot (THIS->here_input ());
1880         }
1881         | E_OPEN        {
1882                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1883                 $$ = s;
1884                 s->set_spot (THIS->here_input ());
1885         }
1886         | E_SMALLER {
1887                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1888                 $$ = s;
1889                 s->set_spot (THIS->here_input ());
1890         }
1891         | E_BIGGER {
1892                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1893                 $$ = s;
1894                 s->set_spot (THIS->here_input ());
1895         }
1896         ;
1897
1898
1899 open_event:
1900         E_EXCLAMATION   {
1901                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1902                 s->set_spot (THIS->here_input ());
1903
1904                 $$ = s;
1905         }
1906         | ')'   {
1907                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1908                 $$ = s;
1909                 s->set_spot (THIS->here_input ());
1910
1911         }
1912         | E_CLOSE       {
1913                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1914                 $$ = s;
1915                 s->set_property ("span-type",
1916                         scm_makfrom0str ("phrasing-slur"));
1917                 s->set_spot (THIS->here_input ());
1918         }
1919         ;
1920
1921 gen_text_def:
1922         full_markup {
1923                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1924                 t->set_property ("text", $1);
1925                 t->set_spot (THIS->here_input ());
1926                 $$ = t;
1927         }
1928         | string {
1929                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1930                 t->set_property ("text",
1931                         make_simple_markup (THIS->lexer_->encoding (), $1));
1932                 t->set_spot (THIS->here_input ());
1933                 $$ = t;
1934
1935         }
1936         | DIGIT {
1937                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1938                 t->set_property ("digit", scm_int2num ($1));
1939                 t->set_spot (THIS->here_input ());
1940                 $$ = t;
1941         }
1942         ;
1943
1944 script_abbreviation:
1945         '^'             {
1946                 $$ = scm_makfrom0str ("Hat");
1947         }
1948         | '+'           {
1949                 $$ = scm_makfrom0str ("Plus");
1950         }
1951         | '-'           {
1952                 $$ = scm_makfrom0str ("Dash");
1953         }
1954         | '|'           {
1955                 $$ = scm_makfrom0str ("Bar");
1956         }
1957         | '>'           {
1958                 $$ = scm_makfrom0str ("Larger");
1959         }
1960         | '.'           {
1961                 $$ = scm_makfrom0str ("Dot");
1962         }
1963         | '_' {
1964                 $$ = scm_makfrom0str ("Underscore");
1965         }
1966         ;
1967
1968 script_dir:
1969         '_'     { $$ = DOWN; }
1970         | '^'   { $$ = UP; }
1971         | '-'   { $$ = CENTER; }
1972         ;
1973
1974
1975 absolute_pitch:
1976         steno_pitch     {
1977                 $$ = $1;
1978         }
1979         ;
1980
1981 duration_length:
1982         multiplied_duration {
1983                 $$ = $1;
1984         }
1985         ;
1986
1987 optional_notemode_duration:
1988         {
1989                 Duration dd = THIS->default_duration_;
1990                 $$ = dd.smobbed_copy ();
1991
1992                 THIS->beam_check ($$);
1993         }
1994         | multiplied_duration   {
1995                 $$ = $1;
1996                 THIS->default_duration_ = *unsmob_duration ($$);
1997
1998                 THIS->beam_check ($$);
1999         }
2000         ;
2001
2002 steno_duration:
2003         bare_unsigned dots              {
2004                 int len = 0;
2005                 if (!is_duration ($1))
2006                         THIS->parser_error (_f ("not a duration: %d", $1));
2007                 else
2008                         len = intlog2 ($1);
2009
2010                 $$ = Duration (len, $2).smobbed_copy ();
2011         }
2012         | DURATION_IDENTIFIER dots      {
2013                 Duration *d = unsmob_duration ($1);
2014                 Duration k (d->duration_log (), d->dot_count () + $2);
2015                 *d = k;
2016                 $$ = $1;
2017         }
2018         ;
2019
2020 multiplied_duration:
2021         steno_duration {
2022                 $$ = $1;
2023         }
2024         | multiplied_duration '*' bare_unsigned {
2025                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2026         }
2027         | multiplied_duration '*' FRACTION {
2028                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
2029
2030                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2031         }
2032         ;
2033
2034 fraction:
2035         FRACTION { $$ = $1; }
2036         | UNSIGNED '/' UNSIGNED {
2037                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2038         }
2039         ;
2040
2041 dots:
2042         /* empty */     {
2043                 $$ = 0;
2044         }
2045         | dots '.' {
2046                 $$ ++;
2047         }
2048         ;
2049
2050 tremolo_type:
2051         ':'     {
2052                 $$ = 0;
2053         }
2054         | ':' bare_unsigned {
2055                 if (!is_duration ($2))
2056                         THIS->parser_error (_f ("not a duration: %d", $2));
2057                 $$ = $2;
2058         }
2059         ;
2060
2061 bass_number:
2062         DIGIT   {
2063                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2064                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2065                                 $$);
2066         }
2067         | UNSIGNED {
2068                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2069                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2070                                 $$);
2071         }
2072         | STRING { $$ = $1; }
2073         ;
2074
2075 bass_mod:
2076         '-'     { $$ = -2; }
2077         | '+'   { $$ = 2; }
2078         | '!'   { $$ = 0; }
2079         ;
2080
2081 bass_figure:
2082         FIGURE_SPACE {
2083                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2084                 $$ = bfr->self_scm ();
2085                 scm_gc_unprotect_object ($$);
2086         }
2087         | bass_number  {
2088                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2089                 $$ = bfr->self_scm ();
2090
2091                 bfr->set_property ("figure", $1);
2092
2093                 scm_gc_unprotect_object ($$);
2094         }
2095         | bass_figure bass_mod {
2096                 Music *m = unsmob_music ($1);
2097                 if ($2) {
2098                         SCM salter = m->get_property ("alteration");
2099                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
2100                         m->set_property ("alteration",
2101                                 scm_int2num (alter + $2));
2102                 } else {
2103                         m->set_property ("alteration", scm_int2num (0));
2104                 }
2105         }
2106         ;
2107
2108 br_bass_figure:
2109         '[' bass_figure {
2110                 $$ = $2;
2111                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2112         }
2113         | bass_figure   {
2114                 $$ = $1;
2115         }
2116         | br_bass_figure ']' {
2117                 $$ = $1;
2118                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2119         }
2120         ;
2121
2122 figure_list:
2123         /**/            {
2124                 $$ = SCM_EOL;
2125         }
2126         | figure_list br_bass_figure {
2127                 $$ = scm_cons ($2, $1);
2128         }
2129         ;
2130
2131 figure_spec:
2132         FIGURE_OPEN figure_list FIGURE_CLOSE {
2133                 Music *m = MY_MAKE_MUSIC ("EventChord");
2134                 $2 = scm_reverse_x ($2, SCM_EOL);
2135                 m->set_property ("elements", $2);
2136                 $$ = m->self_scm ();
2137         }
2138         ;
2139
2140
2141 optional_rest:
2142         /**/   { $$ = 0; }
2143         | REST { $$ = 1; }
2144         ;
2145
2146 simple_element:
2147         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2148
2149                 Input i = THIS->pop_spot ();
2150                 if (!THIS->lexer_->is_note_state ())
2151                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2152
2153                 Music *n = 0;
2154                 if ($6)
2155                         n = MY_MAKE_MUSIC ("RestEvent");
2156                 else
2157                         n = MY_MAKE_MUSIC ("NoteEvent");
2158
2159                 n->set_property ("pitch", $1);
2160                 n->set_property ("duration", $5);
2161
2162                 if (ly_c_number_p ($4))
2163                 {
2164                         int q = ly_scm2int ($4);
2165                         n->set_property ("absolute-octave", scm_int2num (q-1));
2166                 }
2167
2168                 if ($3 % 2)
2169                         n->set_property ("cautionary", SCM_BOOL_T);
2170                 if ($2 % 2 || $3 % 2)
2171                         n->set_property ("force-accidental", SCM_BOOL_T);
2172
2173                 Music *v = MY_MAKE_MUSIC ("EventChord");
2174                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2175                 scm_gc_unprotect_object (n->self_scm ());
2176
2177                 v->set_spot (i);
2178                 n->set_spot (i);
2179                 $$ = v;
2180         }
2181         | DRUM_PITCH optional_notemode_duration {
2182                 Input i = THIS->pop_spot ();
2183
2184                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2185                 n->set_property ("duration", $2);
2186                 n->set_property ("drum-type", $1);
2187
2188                 Music *v = MY_MAKE_MUSIC ("EventChord");
2189                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2190                 scm_gc_unprotect_object (n->self_scm ());
2191                 v->set_spot (i);
2192                 n->set_spot (i);
2193                 $$ = v;
2194
2195         }
2196         | figure_spec optional_notemode_duration {
2197                 Music *m = unsmob_music ($1);
2198                 Input i = THIS->pop_spot ();
2199                 m->set_spot (i);
2200                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2201                 {
2202                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2203                 }
2204                 $$ = m;
2205         }
2206         | RESTNAME optional_notemode_duration           {
2207
2208                 Input i = THIS->pop_spot ();
2209                 Music *ev = 0;
2210                 if (ly_scm2string ($1) == "s") {
2211                         /* Space */
2212                         ev = MY_MAKE_MUSIC ("SkipEvent");
2213                   }
2214                 else {
2215                         ev = MY_MAKE_MUSIC ("RestEvent");
2216
2217                     }
2218                 ev->set_property ("duration", $2);
2219                 ev->set_spot (i);
2220                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2221                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2222                 velt->set_spot (i);
2223
2224                 scm_gc_unprotect_object (ev->self_scm ());
2225
2226                 $$ = velt;
2227         }
2228         | MULTI_MEASURE_REST optional_notemode_duration         {
2229                 THIS->pop_spot ();
2230
2231                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2232                 SCM mus = scm_call_2 (proc, $2,
2233                         make_input (THIS->here_input ()));
2234                 scm_gc_protect_object (mus);
2235                 $$ = unsmob_music (mus);
2236         }
2237
2238         | lyric_element optional_notemode_duration      {
2239                 Input i = THIS->pop_spot ();
2240                 if (!THIS->lexer_->is_lyric_state ())
2241                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2242
2243                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2244                 lreq->set_property ("text", $1);
2245                 lreq->set_property ("duration",$2);
2246                 lreq->set_spot (i);
2247                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2248                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2249
2250                 $$= velt;
2251         }
2252         | new_chord {
2253                 THIS->pop_spot ();
2254
2255                 if (!THIS->lexer_->is_chord_state ())
2256                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2257                 $$ = unsmob_music ($1);
2258         }
2259         ;
2260
2261 lyric_element:
2262         /* FIXME: lyric flavoured markup would be better */
2263         full_markup {
2264         }
2265         | LYRICS_STRING {
2266         }
2267         ;
2268
2269 new_chord:
2270         steno_tonic_pitch optional_notemode_duration   {
2271                 $$ = make_chord ($1, $2, SCM_EOL);
2272         }
2273         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2274                 SCM its = scm_reverse_x ($4, SCM_EOL);
2275                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2276         }
2277         ;
2278
2279 chord_items:
2280         /**/ {
2281                 $$ = SCM_EOL;
2282         }
2283         | chord_items chord_item {
2284                 $$ = scm_cons ($2, $$);
2285         }
2286         ;
2287
2288 chord_separator:
2289         CHORD_COLON {
2290                 $$ = ly_symbol2scm ("chord-colon");
2291         }
2292         | CHORD_CARET {
2293                 $$ = ly_symbol2scm ("chord-caret");
2294         }
2295         | CHORD_SLASH steno_tonic_pitch {
2296                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2297         }
2298         | CHORD_BASS steno_tonic_pitch {
2299                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2300         }
2301         ;
2302
2303 chord_item:
2304         chord_separator {
2305                 $$ = $1;
2306         }
2307         | step_numbers {
2308                 $$ = scm_reverse_x ($1, SCM_EOL);
2309         }
2310         | CHORD_MODIFIER  {
2311                 $$ = $1;
2312         }
2313         ;
2314
2315 step_numbers:
2316         step_number { $$ = scm_cons ($1, SCM_EOL); }
2317         | step_numbers '.' step_number {
2318                 $$ = scm_cons ($3, $$);
2319         }
2320         ;
2321
2322 step_number:
2323         bare_unsigned {
2324                 $$ = make_chord_step ($1, 0);
2325         }
2326         | bare_unsigned '+' {
2327                 $$ = make_chord_step ($1, SHARP);
2328         }
2329         | bare_unsigned CHORD_MINUS {
2330                 $$ = make_chord_step ($1, FLAT);
2331         }
2332         ;
2333
2334 /*
2335         UTILITIES
2336
2337 TODO: should deprecate in favor of Scheme?
2338
2339  */
2340 number_expression:
2341         number_expression '+' number_term {
2342                 $$ = scm_sum ($1, $3);
2343         }
2344         | number_expression '-' number_term {
2345                 $$ = scm_difference ($1, $3);
2346         }
2347         | number_term
2348         ;
2349
2350 number_term:
2351         number_factor {
2352                 $$ = $1;
2353         }
2354         | number_factor '*' number_factor {
2355                 $$ = scm_product ($1, $3);
2356         }
2357         | number_factor '/' number_factor {
2358                 $$ = scm_divide ($1, $3);
2359         }
2360         ;
2361
2362 number_factor:
2363         '-'  number_factor { /* %prec UNARY_MINUS */
2364                 $$ = scm_difference ($2, SCM_UNDEFINED);
2365         }
2366         | bare_number
2367         ;
2368
2369
2370 bare_number:
2371         UNSIGNED        {
2372                 $$ = scm_int2num ($1);
2373         }
2374         | REAL          {
2375                 $$ = $1;
2376         }
2377         | NUMBER_IDENTIFIER             {
2378                 $$ = $1;
2379         }
2380         | REAL NUMBER_IDENTIFIER        {
2381                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2382         }
2383         | UNSIGNED NUMBER_IDENTIFIER    {
2384                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2385         }
2386         ;
2387
2388
2389 bare_unsigned:
2390         UNSIGNED {
2391                         $$ = $1;
2392         }
2393         | DIGIT {
2394                 $$ = $1;
2395         }
2396         ;
2397
2398 bare_int:
2399         bare_number {
2400                 if (scm_integer_p ($1) == SCM_BOOL_T)
2401                 {
2402                         int k = ly_scm2int ($1);
2403                         $$ = k;
2404                 } else
2405                 {
2406                         THIS->parser_error (_ ("need integer number arg"));
2407                         $$ = 0;
2408                 }
2409         }
2410         | '-' bare_int {
2411                 $$ = -$2;
2412         }
2413         ;
2414
2415 exclamations:
2416                 { $$ = 0; }
2417         | exclamations '!'      { $$ ++; }
2418         ;
2419
2420 questions:
2421                 { $$ = 0; }
2422         | questions '?' { $$ ++; }
2423         ;
2424
2425
2426
2427 full_markup:
2428         MARKUP_IDENTIFIER {
2429                 $$ = $1;
2430         }
2431         | MARKUP
2432                 { THIS->lexer_->push_markup_state (); }
2433         markup
2434                 { $$ = $3;
2435                   THIS->lexer_->pop_state ();
2436                 }
2437         ;
2438
2439
2440 /*
2441 This should be done more dynamically if possible.
2442 */
2443 markup:
2444         STRING {
2445                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2446         }
2447         | MARKUP_HEAD_EMPTY {
2448                 $$ = scm_list_1 ($1);
2449         }
2450         | MARKUP_HEAD_MARKUP0 markup {
2451                 $$ = scm_list_2 ($1, $2);
2452         }
2453         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2454                 $$ = scm_list_3 ($1, $2, $3);
2455         }
2456         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2457                 $$ = scm_list_3 ($1, $2, $3);
2458         }
2459         | markup_line {
2460                 $$ = $1;
2461         }
2462         | MARKUP_HEAD_LIST0 markup_list {
2463                 $$ = scm_list_2 ($1,$2);
2464         }
2465         | MARKUP_HEAD_SCM0 embedded_scm {
2466                 $$ = scm_list_2 ($1, $2);
2467         }
2468         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2469                 $$ = scm_list_4 ($1, $2, $3, $4);
2470         }
2471         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2472                 $$ = scm_list_4 ($1, $2, $3, $4);
2473         }
2474         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2475                 $$ = scm_list_3 ($1, $2, $3);
2476         }
2477         | MARKUP_IDENTIFIER {
2478                 $$ = $1;
2479         }
2480         | STRING_IDENTIFIER {
2481                 $$ = $1;
2482         }
2483         | SCORE {
2484                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2485                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2486         } '{' score_body '}' {
2487                 Score * sc = $4;
2488                 $$ = scm_list_2 (ly_scheme_function ("score-markup"), sc->self_scm ());
2489                 scm_gc_unprotect_object (sc->self_scm ());
2490                 THIS->lexer_->pop_state ();
2491         }
2492         ;
2493
2494 markup_list:
2495         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2496         ;
2497
2498 markup_line:
2499         '{' markup_list_body '}' {
2500                 SCM line = ly_scheme_function ("line-markup");
2501
2502                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2503         }
2504         ;
2505
2506 markup_list_body:
2507         /**/ {  $$ = SCM_EOL; }
2508         | markup_list_body markup {
2509                 $$ = scm_cons ($2, $1);
2510         }
2511         ;
2512
2513
2514 %%
2515
2516 void
2517 My_lily_parser::set_yydebug (bool )
2518 {
2519 #if 0
2520         yydebug = 1;
2521 #endif
2522 }
2523
2524 void
2525 My_lily_parser::do_yyparse ()
2526 {
2527         yyparse ((void*)this);
2528 }
2529
2530
2531 /*
2532 Should make this optional?    It will also complain when you do
2533
2534         [s4]
2535
2536 which is entirely legitimate.
2537
2538 Or we can scrap it. Barchecks should detect wrong durations, and
2539 skipTypesetting speeds it up a lot.
2540 */
2541
2542 void
2543 My_lily_parser::beam_check (SCM dur)
2544 {
2545   Duration *d = unsmob_duration (dur);
2546   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2547     {
2548       Music *m = unsmob_music (last_beam_start_);
2549       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2550     }
2551   last_beam_start_ = SCM_EOL;
2552 }
2553
2554
2555
2556
2557 /*
2558
2559 It is a little strange to have this function in this file, but
2560 otherwise, we have to import music classes into the lexer.
2561
2562 */
2563 int
2564 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2565 {
2566         if (ly_c_string_p (sid)) {
2567                 *destination = sid;
2568                 return STRING_IDENTIFIER;
2569         } else if (ly_c_number_p (sid)) {
2570                 *destination = sid;
2571                 return NUMBER_IDENTIFIER;
2572         } else if (unsmob_context_def (sid)) {
2573                 *destination = unsmob_context_def (sid)->clone_scm ();
2574                 return CONTEXT_DEF_IDENTIFIER;
2575         } else if (unsmob_score (sid)) {
2576                 Score *score = new Score (*unsmob_score (sid));
2577                 *destination = score->self_scm ();
2578                 return SCORE_IDENTIFIER;
2579         } else if (Music *mus = unsmob_music (sid)) {
2580                 mus = mus->clone ();
2581                 *destination = mus->self_scm ();
2582                 unsmob_music (*destination)->
2583                         set_property ("origin", make_input (last_input_));
2584                 return dynamic_cast<Event*> (mus)
2585                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2586         } else if (unsmob_duration (sid)) {
2587                 *destination = unsmob_duration (sid)->smobbed_copy ();
2588                 return DURATION_IDENTIFIER;
2589         } else if (unsmob_output_def (sid)) {
2590                 Output_def *p = unsmob_output_def (sid);
2591                 p = p->clone ();
2592
2593                 *destination = p->self_scm ();
2594                 return OUTPUT_DEF_IDENTIFIER;
2595         } else if (Text_item::markup_p (sid)) {
2596                 *destination = sid;
2597                 return MARKUP_IDENTIFIER;
2598         }
2599
2600         return -1;
2601 }
2602
2603 Music *
2604 property_op_to_music (SCM op)
2605 {
2606         Music *m = 0;
2607         SCM tag = ly_car (op);
2608         SCM symbol = ly_cadr (op);
2609         SCM args = ly_cddr (op);
2610         SCM grob_val = SCM_UNDEFINED;
2611         SCM grob_sym = SCM_UNDEFINED;
2612         SCM val = SCM_UNDEFINED;
2613
2614         if (tag == ly_symbol2scm ("assign"))
2615                 {
2616                 m = MY_MAKE_MUSIC ("PropertySet");
2617                 val = ly_car (args);
2618                 }
2619         else if (tag == ly_symbol2scm ("unset"))
2620                 m = MY_MAKE_MUSIC ("PropertyUnset");
2621         else if (tag == ly_symbol2scm ("poppush")
2622                  || tag == ly_symbol2scm ("push"))
2623                 {
2624                 m = MY_MAKE_MUSIC ("OverrideProperty");
2625                 grob_sym = ly_car (args);
2626                 grob_val = ly_cadr (args);
2627                 }
2628         else if (tag == ly_symbol2scm ("pop")) {
2629                 m = MY_MAKE_MUSIC ("RevertProperty");
2630                 grob_sym = ly_car (args);
2631                 }
2632
2633         m->set_property ("symbol", symbol);
2634
2635         if (val != SCM_UNDEFINED)
2636                 m->set_property ("value", val);
2637         if (grob_val != SCM_UNDEFINED)
2638                 m->set_property ("grob-value", grob_val);
2639
2640         if (grob_sym != SCM_UNDEFINED)
2641                 {
2642                 bool itc = internal_type_checking_global_b;
2643                 /* UGH.
2644                 */
2645                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2646                 if (autobeam)
2647                         internal_type_checking_global_b = false;
2648                 m->set_property ("grob-property", grob_sym);
2649                 if (autobeam)
2650                         internal_type_checking_global_b = itc;
2651                 }
2652
2653         if (tag == ly_symbol2scm ("poppush"))
2654                 m->set_property ("pop-first", SCM_BOOL_T);
2655
2656
2657         return m;
2658 }
2659
2660 Music*
2661 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2662 {
2663         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2664
2665         csm->set_property ("element", m->self_scm ());
2666         scm_gc_unprotect_object (m->self_scm ());
2667
2668         csm->set_property ("context-type",
2669                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2670         csm->set_property ("property-operations", ops);
2671
2672         if (ly_c_string_p (id))
2673                 csm->set_property ("context-id", id);
2674         return csm;
2675 }
2676
2677 SCM
2678 get_next_unique_context ()
2679 {
2680         static int new_context_count;
2681         char s[1024];
2682         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2683         return scm_makfrom0str (s);
2684 }
2685