guile18/guile-readline/configure.in

   1 AC_PREREQ(2.50)
   2
   3 dnl Don't use "echo -n", which is not portable (e.g., not available on
   4 dnl MacOS X).  Instead, use `patsubst' to remove the newline.
   5 AC_INIT(guile-readline,
   6         patsubst(m4_esyscmd(. ../GUILE-VERSION && echo ${GUILE_VERSION}), [
   7 ]),
   8         [bug-guile@gnu.org])
   9
  10 AC_CONFIG_AUX_DIR([.])
  11 AC_CONFIG_SRCDIR(readline.c)
  12 AM_CONFIG_HEADER([guile-readline-config.h])
  13 AM_INIT_AUTOMAKE([foreign no-define])
  14
  15 . $srcdir/../GUILE-VERSION
  16
  17 AC_PROG_INSTALL
  18 AC_PROG_CC
  19 AM_PROG_CC_STDC
  20 AC_LIBTOOL_WIN32_DLL
  21 AC_PROG_LIBTOOL
  22
  23 dnl
  24 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
  25 dnl
  26 AC_CYGWIN
  27 AC_MINGW32
  28 EXTRA_DEFS=""
  29 if test "$MINGW32" = "yes" ; then
  30     if test $enable_shared = yes ; then
  31       EXTRA_DEFS="-DSCM_IMPORT"
  32     fi
  33 fi
  34 AC_SUBST(EXTRA_DEFS)
  35
  36 for termlib in ncurses curses termcap terminfo termlib ; do
  37    AC_CHECK_LIB(${termlib}, tgoto,
  38                 [LIBS="-l${termlib} $LIBS"; break])
  39 done
  40
  41 AC_CHECK_LIB(readline, readline)
  42 if test $ac_cv_lib_readline_readline = no; then
  43   AC_MSG_WARN([libreadline was not found on your system.])
  44 fi
  45
  46 AC_CHECK_FUNCS(siginterrupt rl_clear_signals rl_cleanup_after_signal)
  47
  48 dnl Check for modern readline naming
  49 AC_CHECK_FUNCS(rl_filename_completion_function)
  50
  51 dnl Check for rl_get_keymap.  We only use this for deciding whether to
  52 dnl install paren matching on the Guile command line (when using
  53 dnl readline for input), so it's completely optional.
  54 AC_CHECK_FUNCS(rl_get_keymap)
  55
  56 AC_CACHE_CHECK([for rl_getc_function pointer in readline],
  57                  ac_cv_var_rl_getc_function,
  58                  [AC_TRY_LINK([
  59 #include <stdio.h>
  60 #include <readline/readline.h>],
  61                               [printf ("%ld", (long) rl_getc_function)],
  62                               [ac_cv_var_rl_getc_function=yes],
  63                               [ac_cv_var_rl_getc_function=no])])
  64 if test "${ac_cv_var_rl_getc_function}" = "yes"; then
  65   AC_DEFINE(HAVE_RL_GETC_FUNCTION, 1,
  66     [Define if your readline library has the rl_getc_function variable.])
  67 fi
  68
  69 if test $ac_cv_lib_readline_readline = yes \
  70         -a $ac_cv_var_rl_getc_function = no; then
  71   AC_MSG_WARN([*** libreadline is too old on your system.])
  72   AC_MSG_WARN([*** You need readline version 2.1 or later.])
  73 fi
  74
  75 AC_CHECK_FUNCS(strdup)
  76
  77 . $srcdir/LIBGUILEREADLINE-VERSION
  78 AC_SUBST(LIBGUILEREADLINE_MAJOR)
  79 AC_SUBST(LIBGUILEREADLINE_INTERFACE_CURRENT)
  80 AC_SUBST(LIBGUILEREADLINE_INTERFACE_REVISION)
  81 AC_SUBST(LIBGUILEREADLINE_INTERFACE_AGE)
  82 AC_SUBST(LIBGUILEREADLINE_INTERFACE)
  83
  84 AC_SUBST(GUILE_EFFECTIVE_VERSION)
  85
  86 AC_CONFIG_FILES(Makefile ice-9/Makefile)
  87 AC_OUTPUT