configure.in

   1 dnl configure.in   -*-shell-script-*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 # Bootstrap the init proces.
   5 AC_INIT
   6
   7 # Bootstrap StepMake configure
   8 # For user package:
   9 AC_CONFIG_AUX_DIR([stepmake/bin])
  10
  11 # For stepmake package:
  12 # AC_CONFIG_AUX_DIR(bin)
  13
  14
  15 STEPMAKE_INIT
  16
  17 # List a file that identifies your package.
  18 AC_CONFIG_SRCDIR([lily/main.cc])
  19
  20 # Move to aclocal.m4?
  21 AC_CONFIG_HEADER([$CONFIGFILE.hh:config.hh.in])
  22
  23 # Uncomment the configuration options your package needs.
  24
  25 DOCUMENTATION=yes
  26 AC_ARG_ENABLE(documentation,
  27     [  --enable-documentation  build Documentation.  Default: on],
  28     [DOCUMENTATION=$enableval])
  29 AC_SUBST(DOCUMENTATION)
  30
  31 gui_b=no
  32 AC_ARG_ENABLE(gui,
  33     [  --enable-gui            compile with experimental GNOME output.  Default: off],
  34     [gui_b=$enableval])
  35
  36
  37 AC_ARG_WITH(ncsb-dir,
  38     [  --with-ncsb-dir=DIR     location of Century Schoolbook fonts.],
  39     [NCSB_DIR=$withval],
  40     [NCSB_DIR=""])
  41
  42 reloc_b=no
  43 AC_ARG_ENABLE(relocation,
  44     [  --enable-relocation     compile with dynamic relocation.  Default: off],
  45     [reloc_b=$enableval])
  46
  47 rpath_b=no
  48 AC_ARG_ENABLE(rpath,
  49     [  --enable-rpath          hardcode runtime library path.  Default: off],
  50     [rpath_b=$enableval])
  51
  52 LINK_GXX_STATICALLY=no
  53 AC_ARG_ENABLE(static-gxx,
  54     [  --enable-static-gxx     link libstdc++.a statically. Default: off],
  55     [LINK_GXX_STATICALLY=$enableval])
  56 AC_SUBST(LINK_GXX_STATICALLY)
  57
  58 # must come before any header checks
  59 STEPMAKE_COMPILE
  60
  61 AC_CHECK_PROG(FCMATCH, fc-match, fc-match)
  62 AC_MSG_CHECKING([New Century Schoolbook PFB files])
  63 AC_SUBST(NCSB_SOURCE_FILES)
  64 if test "$NCSB_DIR" != "" ;  then
  65   NCSB_SOURCE_FILES=""
  66   for f in c059013l c059016l c059033l c059036l; do
  67     if test ! -f "$NCSB_DIR/$f.pfb"; then
  68       STEPMAKE_WARN($NCSB_DIR does not contain $f.pfb.)
  69     else
  70       NCSB_SOURCE_FILES="$NCSB_DIR/$f.pfb $NCSB_SOURCE_FILES"
  71     fi
  72   done
  73 else
  74   if test "$FCMATCH" != ""; then
  75     for style in Roman Italic "Bold Italic" Bold; do
  76       NCSB_FILE=`$FCMATCH --verbose "Century Schoolbook L:style=$style:foundry=urw" | grep 'file:' | grep -v "\.ttf"`
  77
  78       NCSB_FILE=`echo $NCSB_FILE | sed 's/^.*"\(.*\)".*$/\1/g'`
  79       NCSB_FILE=`$PYTHON "$srcdir/scripts/auxiliar/readlink.py" $NCSB_FILE`
  80       NCSB_SOURCE_FILES="$NCSB_FILE $NCSB_SOURCE_FILES"
  81     done
  82   else
  83     AC_MSG_RESULT(not found)
  84     echo "Can't find Century Schoolbook files. Install FontConfig's fc-match,"
  85     echo "or use --with-ncsb-dir"
  86   fi
  87 fi
  88 AC_MSG_RESULT($NCSB_SOURCE_FILES)
  89
  90
  91
  92 STEPMAKE_PYTHON(REQUIRED, 2.4)
  93 STEPMAKE_GCC(REQUIRED, 3.4)
  94
  95 STEPMAKE_CXX(REQUIRED)
  96 STEPMAKE_GXX(REQUIRED, 3.4)
  97 STEPMAKE_CXXTEMPLATE
  98 STEPMAKE_STL_DATA_METHOD
  99 STEPMAKE_LIB(REQUIRED)
 100 STEPMAKE_DLOPEN
 101 # Do not use bison 1.50 and 1.75.
 102 # 1.29 is required fr %locations, but I'm not sure it's enough --ns
 103 STEPMAKE_BISON(OPTIONAL, 1.29)
 104 STEPMAKE_FLEX(REQUIRED)
 105 STEPMAKE_FLEXLEXER(REQUIRED)
 106 STEPMAKE_FLEXLEXER_LOCATION
 107 AC_LANG_C
 108 STEPMAKE_LOCALE
 109 STEPMAKE_GETTEXT
 110 STEPMAKE_MSGFMT(REQUIRED)
 111 STEPMAKE_TEXMF(REQUIRED)
 112 STEPMAKE_TEXMF_DIRS
 113
 114 ## should check for 1.8.2 ?
 115 STEPMAKE_GUILE_DEVEL(REQUIRED, 1.8.0)
 116
 117
 118 ## check rational bugfix.
 119 save_CPPFLAGS="$CPPFLAGS"
 120 CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 121 AC_MSG_CHECKING(GUILE rational bugfix)
 122 AC_TRY_CPP(
 123 #include <libguile.h>
 124 #ifdef SCM_FRACTION_REDUCED_BIT
 125 #error
 126 #endif
 127 ,
 128 AC_MSG_RESULT(ok),
 129 REQUIRED="$REQUIRED GUILE-with-rational-bugfix"
 130 AC_MSG_RESULT(Must have patched GUILE rational support. See INSTALL.txt))
 131 CPPFLAGS="$save_CPPFLAGS"
 132
 133
 134 STEPMAKE_PYTHON_DEVEL(REQUIRED)
 135
 136 STEPMAKE_PATH_PROG(GHOSTSCRIPT, gs, OPTIONAL, 8.15)
 137
 138 STEPMAKE_PATH_PROG(FONTFORGE, fontforge, REQUIRED, 20050624)
 139
 140 STEPMAKE_PATH_PROG(T1ASM, t1asm, REQUIRED)
 141
 142 AC_CHECK_HEADERS([assert.h grp.h libio.h pwd.h sys/stat.h wchar.h fpu_control.h])
 143 AC_LANG_PUSH(C++)
 144 AC_CHECK_HEADERS([sstream boost/lambda/lambda.hpp])
 145 AC_LANG_POP(C++)
 146 AC_HEADER_STAT
 147 AC_FUNC_MEMCMP
 148 AC_FUNC_VPRINTF
 149 AC_CHECK_FUNCS([chroot fopencookie funopen gettext isinf mbrtowc memmem snprintf vsnprintf wcrtomb])
 150 AC_CHECK_HEADERS([utf8/wchar.h], LIBS="$LIBS -lutf8")
 151 AC_SEARCH_LIBS(mbrtowc, [mingwex msvcp60])
 152
 153 STEPMAKE_PROGS(PKG_CONFIG, pkg-config, REQUIRED, 0.9.0)
 154
 155 if test "$gui_b" = "yes"; then
 156     STEPMAKE_GTK2(gtk+-2.0, REQUIRED, 2.4.0)
 157 fi
 158
 159 AC_MSG_CHECKING(whether to enable dynamic relocation)
 160 if test "$reloc_b" = "yes"; then
 161     AC_DEFINE(ARGV0_RELOCATION)
 162 fi
 163 AC_MSG_RESULT($reloc_b)
 164
 165 AC_MSG_CHECKING(for rpath linkage)
 166 if test "$rpath_b" = "yes"; then
 167     LDFLAGS="$LDFLAGS -Wl,-rpath -Wl,\\\$\$ORIGIN/../lib"
 168 elif test "$rpath_b" != "no"; then
 169     LDFLAGS="$LDFLAGS -Wl,-rpath -Wl,$rpath_b"
 170 fi
 171 AC_MSG_RESULT($rpath_b)
 172
 173 HOST_ARCH=`$CC -dumpmachine`
 174 AC_SUBST(HOST_ARCH)
 175
 176 STEPMAKE_PANGO_FT2(pangoft2, REQUIRED, 1.6.0)
 177 #STEPMAKE_PANGO(pango, REQUIRED, 1.6.0)
 178 STEPMAKE_FONTCONFIG(fontconfig, REQUIRED, 2.2.0)
 179 STEPMAKE_FREETYPE2(freetype2, REQUIRED, 2.1.10)
 180
 181 STEPMAKE_WINDOWS
 182
 183 ## Optional tools for building documentation, website, extra fonts.
 184
 185 # guile executable for some scripts
 186 STEPMAKE_GUILE(OPTIONAL)
 187
 188 # perl for help2man.
 189 STEPMAKE_PERL(OPTIONAL)
 190
 191 STEPMAKE_PROGS(MAKEINFO, makeinfo, REQUIRED, 4.11)
 192 STEPMAKE_PROGS(TEXI2HTML, texi2html, OPTIONAL, 1.80)
 193
 194 AC_DEFINE_UNQUOTED(FLOWER_VERSION, "${FULL_FLOWER_VERSION}")
 195
 196 # must also have local.make if configure fails.
 197 touch local.make
 198
 199 if test "$reloc_b$rpath_b" = "yesno"; then
 200     STEPMAKE_WARN([Using --enable-relocation without --enable-rpath.  LilyPond may have trouble finding libraries.])
 201 fi
 202
 203 # Gather requirements and generate output.
 204 STEPMAKE_END
 205
 206 test -n "$CONFIGURATION" && mc=" conf=$CONFIGURATION" || mc=""
 207
 208 cat <<EOF
 209
 210 Type:
 211     make$mc all       to build LilyPond
 212     make$mc install   to install LilyPond
 213     make$mc help      to see all possible targets
 214
 215 Edit local.make for local Makefile overrides.
 216
 217
 218 EOF