configure.in

   1 dnl configure.in   -*-shell-script-*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 # Bootstrap the init proces.
   5 AC_INIT
   6
   7 # Bootstrap StepMake configure
   8 # For user package:
   9 AC_CONFIG_AUX_DIR([stepmake/bin])
  10 # For stepmake package:
  11 # AC_CONFIG_AUX_DIR(bin)
  12
  13
  14 STEPMAKE_INIT
  15
  16 # List a file that identifies your package.
  17 AC_CONFIG_SRCDIR([lily/main.cc])
  18
  19 # Move to aclocal.m4?
  20 AC_CONFIG_HEADER([$CONFIGFILE.hh:config.hh.in])
  21
  22 # Uncomment the configuration options your package needs.
  23
  24
  25 gui_b=no
  26 AC_ARG_ENABLE(gui,
  27     [  --enable-gui            compile with experimental GNOME output module.  Default: off],
  28     [gui_b=$enableval])
  29
  30 reloc_b=no
  31 AC_ARG_ENABLE(relocation,
  32     [  --enable-relocation     compile with dynamic relocation.  Default: off],
  33     [reloc_b=$enableval])
  34
  35
  36 AC_SUBST(LINK_GXX_STATICALLY)
  37 LINK_GXX_STATICALLY=no
  38 AC_ARG_ENABLE(static-gxx,
  39     [  --enable-static-gxx     link libstdc++.a statically. Default: off],
  40     [LINK_GXX_STATICALLY=$enableval])
  41
  42 # must come before any header checks
  43 STEPMAKE_COMPILE
  44
  45 STEPMAKE_KPATHSEA
  46
  47 STEPMAKE_PYTHON(REQUIRED, 2.1)
  48 STEPMAKE_GCC(REQUIRED, 2.8)
  49 STEPMAKE_CXX(REQUIRED)
  50 STEPMAKE_GXX(REQUIRED, 3.0.5)
  51 STEPMAKE_CXXTEMPLATE
  52 STEPMAKE_LIB(REQUIRED)
  53 STEPMAKE_DLOPEN
  54 # Do not use bison 1.50 and 1.75.
  55 # 1.29 is required fr %locations, but I'm not sure it's enough --ns
  56 STEPMAKE_BISON(OPTIONAL, 1.29)
  57 STEPMAKE_FLEX(REQUIRED)
  58 STEPMAKE_FLEXLEXER(REQUIRED)
  59 STEPMAKE_FLEXLEXER_LOCATION
  60 AC_LANG_C
  61 STEPMAKE_LOCALE
  62 STEPMAKE_GETTEXT
  63 STEPMAKE_MSGFMT(REQUIRED)
  64 STEPMAKE_TEXMF(REQUIRED)
  65 STEPMAKE_TEXMF_DIRS
  66 STEPMAKE_GUILE_DEVEL(REQUIRED, 1.6.5)
  67 STEPMAKE_MAKEINFO(REQUIRED)
  68 STEPMAKE_PYTHON_DEVEL(OPTIONAL)
  69
  70 STEPMAKE_PATH_PROG(GHOSTSCRIPT, gs, OPTIONAL, 8.14)
  71
  72 STEPMAKE_PROGS(MFTRACE, mftrace, REQUIRED, 1.1.1)
  73 STEPMAKE_PATH_PROG(FONTFORGE, fontforge, REQUIRED, 20050624)
  74
  75 AC_CHECK_HEADERS([assert.h grp.h libio.h pwd.h sys/stat.h wchar.h])
  76 AC_LANG_PUSH(C++)
  77 AC_CHECK_HEADERS([sstream])
  78 AC_LANG_POP(C++)
  79 AC_HEADER_STAT
  80 AC_FUNC_MEMCMP
  81 AC_FUNC_VPRINTF
  82 AC_CHECK_FUNCS([chroot fopencookie funopen gettext isinf mbrtowc memmem snprintf vsnprintf wcrtomb])
  83 AC_CHECK_HEADERS([utf8/wchar.h], LIBS="$LIBS -lutf8")
  84 AC_SEARCH_LIBS(mbrtowc, [mingwex msvcp60])
  85
  86 STEPMAKE_PROGS(PKG_CONFIG, pkg-config, REQUIRED, 0.9.0)
  87 if test "$gui_b" = "yes"; then
  88     STEPMAKE_GTK2(gtk+-2.0, REQUIRED, 2.4.0)
  89 fi # $gui_b
  90
  91 if test "$reloc_b" = "yes"; then
  92     AC_DEFINE(ARGV0_RELOCATION)
  93 fi # $reloc_b
  94
  95 STEPMAKE_FREETYPE2(freetype2, REQUIRED, 0)
  96 #STEPMAKE_PANGO(pango, REQUIRED, 1.6.0)
  97 STEPMAKE_PANGO_FT2(pangoft2, REQUIRED, 1.6.0)
  98 STEPMAKE_FONTCONFIG(fontconfig, REQUIRED, 2.2.0)
  99
 100 STEPMAKE_WINDOWS
 101
 102 ## Optional tools for building documentation, website, extra fonts.
 103
 104 # guile executable for some scripts
 105 STEPMAKE_GUILE(OPTIONAL)
 106
 107 # perl for help2man.
 108 STEPMAKE_PERL(OPTIONAL)
 109
 110 # New makeinfo for multi-page website docs Simply always require new
 111 # makeinfo should avoid bug reports; if people want to build lily
 112 # without the docs, they can find this comment and use an older
 113 # makeinfo -- but hopefully won't report makeinfo problems.
 114 STEPMAKE_PROGS(MAKEINFO, makeinfo, REQUIRED, 4.7)
 115
 116 if test "$optimise_b" = yes; then
 117     DEFINES="$DEFINES -DSTRING_UTILS_INLINED"
 118     AC_DEFINE(STRINGS_UTILS_INLINED)
 119 fi
 120
 121 AC_DEFINE_UNQUOTED(FLOWER_VERSION, "${FULL_FLOWER_VERSION}")
 122
 123 # Gather requirements and generate output.
 124 STEPMAKE_END
 125
 126 test -n "$CONFIGURATION" && mc=" conf=$CONFIGURATION" || mc=""
 127
 128 cat <<EOF
 129
 130 Type:
 131     make$mc all       to build LilyPond
 132     make$mc install   to install LilyPond
 133     make$mc help      to see all possible targets
 134
 135 EOF