t/06_mail_handling.t

   1 # -*- mode: cperl;-*-
   2 # $Id: 05_mail.t,v 1.1 2005/08/17 21:46:17 don Exp $
   3
   4 use Test::More tests => 31;
   5
   6 use warnings;
   7 use strict;
   8
   9 # Here, we're going to shoot messages through a set of things that can
  10 # happen.
  11
  12 # First, we're going to send mesages to receive.
  13 # To do so, we'll first send a message to submit,
  14 # then send messages to the newly created bugnumber.
  15
  16 use IO::File;
  17 use File::Temp qw(tempdir);
  18 use Cwd qw(getcwd);
  19 use Debbugs::MIME qw(create_mime_message);
  20 use File::Basename qw(dirname basename);
  21 # The test functions are placed here to make things easier
  22 use lib qw(t/lib);
  23 use DebbugsTest qw(:all);
  24 use Data::Dumper;
  25
  26 my %config;
  27 eval {
  28      %config = create_debbugs_configuration(debug => exists $ENV{DEBUG}?$ENV{DEBUG}:0);
  29 };
  30 if ($@) {
  31      BAIL_OUT($@);
  32 }
  33
  34 my $sendmail_dir = $config{sendmail_dir};
  35 my $spool_dir = $config{spool_dir};
  36 my $config_dir = $config{config_dir};
  37
  38 END{
  39      if ($ENV{DEBUG}) {
  40           diag("spool_dir:   $spool_dir\n");
  41           diag("config_dir:   $config_dir\n");
  42           diag("sendmail_dir: $sendmail_dir\n");
  43      }
  44 }
  45
  46 # We're going to use create mime message to create these messages, and
  47 # then just send them to receive.
  48
  49 send_message(to=>'submit@bugs.something',
  50              headers => [To   => 'submit@bugs.something',
  51                          From => 'foo@bugs.something',
  52                          Subject => 'Submiting a bug',
  53                         ],
  54              body => <<EOF) or fail('Unable to send message');
  55 Package: foo
  56 Severity: normal
  57
  58 This is a silly bug
  59 EOF
  60
  61 # now we check to see that we have a bug, and nextnumber has been incremented
  62 ok(-e "$spool_dir/db-h/01/1.log",'log file created');
  63 ok(-e "$spool_dir/db-h/01/1.summary",'sumary file created');
  64 ok(-e "$spool_dir/db-h/01/1.status",'status file created');
  65 ok(-e "$spool_dir/db-h/01/1.report",'report file created');
  66
  67 # next, we check to see that (at least) the proper messages have been
  68 # sent out. 1) ack to submitter 2) mail to maintainer
  69
  70 # This keeps track of the previous size of the sendmail directory
  71 my $SD_SIZE_PREV = 0;
  72 my $SD_SIZE_NOW = dirsize($sendmail_dir);
  73 ok($SD_SIZE_NOW-$SD_SIZE_PREV >= 2,'submit messages appear to have been sent out properly');
  74 $SD_SIZE_PREV=$SD_SIZE_NOW;
  75
  76 # now send a message to the bug
  77
  78 send_message(to => '1@bugs.something',
  79              headers => [To   => '1@bugs.something',
  80                          From => 'foo@bugs.something',
  81                          Subject => 'Sending a message to a bug',
  82                         ],
  83              body => <<EOF) or fail('sending message to 1@bugs.someting failed');
  84 Package: foo
  85 Severity: normal
  86
  87 This is a silly bug
  88 EOF
  89
  90 $SD_SIZE_NOW = dirsize($sendmail_dir);
  91 ok($SD_SIZE_NOW-$SD_SIZE_PREV >= 2,'1@bugs.something messages appear to have been sent out properly');
  92 $SD_SIZE_PREV=$SD_SIZE_NOW;
  93
  94 # just check to see that control doesn't explode
  95 send_message(to => 'control@bugs.something',
  96              headers => [To   => 'control@bugs.something',
  97                          From => 'foo@bugs.something',
  98                          Subject => 'Munging a bug',
  99                         ],
 100              body => <<EOF) or fail 'message to control@bugs.something failed';
 101 severity 1 wishlist
 102 retitle 1 new title
 103 thanks
 104 EOF
 105
 106 $SD_SIZE_NOW = dirsize($sendmail_dir);
 107 ok($SD_SIZE_NOW-$SD_SIZE_PREV >= 1,'control@bugs.something messages appear to have been sent out properly');
 108 $SD_SIZE_PREV=$SD_SIZE_NOW;
 109 # now we need to check to make sure the control message was processed without errors
 110 ok(system("sh -c 'find ".$sendmail_dir.q( -type f | xargs grep -q "Subject: Processed: Munging a bug"')) == 0,
 111    'control@bugs.something message was parsed without errors');
 112 # now we need to check to make sure that the control message actually did anything
 113 # This is an eval because $ENV{DEBBUGS_CONFIG_FILE} isn't set at BEGIN{} time
 114 eval "use Debbugs::Status qw(read_bug);";
 115 my $status = read_bug(bug=>1);
 116 ok($status->{subject} eq 'new title','bug 1 retitled');
 117 ok($status->{severity} eq 'wishlist','bug 1 wishlisted');
 118
 119 # now we're going to go through and methododically test all of the control commands.
 120 my @control_commands =
 121      (severity_wishlist => {command => 'severity',
 122                             value   => 'wishlist',
 123                             status_key => 'severity',
 124                             status_value => 'wishlist',
 125                            },
 126       'found_1.0'        => {command => 'found',
 127                              value   => '1.0',
 128                              status_key => 'found_versions',
 129                              status_value => ['1.0'],
 130                             },
 131       'notfound_1.0'     => {command => 'notfound',
 132                              value   => '1.0',
 133                              status_key => 'found_versions',
 134                              status_value => [],
 135                             },
 136       submitter_foo      => {command => 'submitter',
 137                              value   => 'foo@bar.com',
 138                              status_key => 'originator',
 139                              status_value => 'foo@bar.com',
 140                             },
 141
 142       forwarded_foo      => {command => 'forwarded',
 143                              value   => 'foo@bar.com',
 144                              status_key => 'forwarded',
 145                              status_value => 'foo@bar.com',
 146                             },
 147       owner_foo          => {command => 'owner',
 148                              value   => 'foo@bar.com',
 149                              status_key => 'owner',
 150                              status_value => 'foo@bar.com',
 151                             },
 152       noowner      => {command => 'noowner',
 153                        value   => '',
 154                        status_key => 'owner',
 155                        status_value => '',
 156                       },
 157
 158      );
 159
 160 while (my ($command,$control_command) = splice(@control_commands,0,2)) {
 161      # just check to see that control doesn't explode
 162      $control_command->{value} = " $control_command->{value}" if length $control_command->{value}
 163           and $control_command->{value} !~ /^\s/;
 164      send_message(to => 'control@bugs.something',
 165                   headers => [To   => 'control@bugs.something',
 166                               From => 'foo@bugs.something',
 167                               Subject => "Munging a bug with $command",
 168                              ],
 169                   body => <<EOF) or fail 'message to control@bugs.something failed';
 170 $control_command->{command} 1$control_command->{value}
 171 thanks
 172 EOF
 173                                   ;
 174      $SD_SIZE_NOW = dirsize($sendmail_dir);
 175      ok($SD_SIZE_NOW-$SD_SIZE_PREV >= 1,'control@bugs.something messages appear to have been sent out properly');
 176      $SD_SIZE_PREV=$SD_SIZE_NOW;
 177      # now we need to check to make sure the control message was processed without errors
 178      ok(system("sh -c 'find ".$sendmail_dir.q( -type f | xargs grep -q "Subject: Processed: Munging a bug with $command"')) == 0,
 179         'control@bugs.something'. "$command message was parsed without errors");
 180      # now we need to check to make sure that the control message actually did anything
 181      my $status = read_bug(bug=>1);
 182      is_deeply($status->{$control_command->{status_key}},$control_command->{status_value},"bug 1 $command")
 183           or fail(Dumper($status));
 184 }